home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / SIMTEL / CPMUG / CPMUG029.ARK / SAP.ASM < prev    next >
Assembly Source File  |  1984-04-29  |  4KB  |  264 lines
  1. ;    SAP - SORT AND PACK CP/M DISK DIRECTORY
  2. ;
  3. ;    L.E. HUGHES    8080SDC
  4. ;    MODIFIED 5/30/78 BY B.R. RATOFF
  5. ;        1) PICK UP VECTORS FOR ANY SIZE SYSTEM
  6. ;        2) HANDLE NULL EXTENTS OF NON-NULL FILES
  7. ;            PROPERLY
  8. ; 
  9.     ORG    100H
  10. ;*****
  11. ; OBTAIN BIOS VECTORS
  12. ;*****
  13. VECTRS:    JMP    GETVEC
  14.     DS    42
  15. WBOOTE    EQU    VECTRS+3
  16. CSTS    EQU    VECTRS+6
  17. CI    EQU    VECTRS+9
  18. CO    EQU    VECTRS+12
  19. LO    EQU    VECTRS+15
  20. PO    EQU    VECTRS+18
  21. RI    EQU    VECTRS+21
  22. HOME    EQU    VECTRS+24
  23. SELDSK    EQU    VECTRS+27
  24. SETTRK    EQU    VECTRS+30
  25. SETSEC    EQU    VECTRS+33
  26. SETDMA    EQU    VECTRS+36
  27. READ    EQU    VECTRS+39
  28. WRITE    EQU    VECTRS+42
  29. GETVEC:    LXI    D,WBOOTE
  30.     LHLD    1
  31.     MVI    B,42
  32. GETVE1:    MOV    A,M
  33.     STAX    D
  34.     INX    H
  35.     INX    D
  36.     DCR    B
  37.     JNZ    GETVE1
  38. ;
  39. SAP:    LXI    H,0
  40.     DAD    SP
  41.     SHLD    OLDSP
  42.     LXI    SP,STACK+64
  43.     MVI    C,0        ;SELECT DISK A
  44.     CALL    SELDSK
  45.     MVI    C,2        ;SET TO TRACK 2
  46.     CALL    SETTRK
  47.     MVI    A,1        ;SECNO=1
  48.     STA    SECNO
  49.     LXI    H,BUF        ;ADDR = FWA OF BUFFER
  50.     SHLD    ADDR
  51. SAP1:    LDA    SECNO        ;SET TO SECTOR "SECNO"
  52.     LXI    H,LPMAP-1
  53.     ADD    L
  54.     MOV    L,A
  55.     JNC    $+4
  56.     INR    H
  57.     MOV    C,M
  58.     CALL    SETSEC
  59.     LHLD    ADDR        ;SET DMA ADDRESS TO "ADDR"
  60.     MOV    B,H
  61.     MOV    C,L
  62.     CALL    SETDMA
  63.     CALL    READ        ;READ SECTOR INTO MEMORY
  64.     LHLD    ADDR        ;ADDR = ADDR + 80H
  65.     MOV    A,L
  66.     ADI    80H
  67.     MOV    L,A
  68.     JNC    $+4
  69.     INR    H
  70.     SHLD    ADDR
  71.     LDA    SECNO        ;SECNO = SECNO + 1
  72.     INR    A
  73.     STA    SECNO
  74.     CPI    17        ;LOOP UNTIL SECNO>16
  75.     JC    SAP1
  76.     CALL    CLEAN        ;CLEAN THE DIRECTORY
  77.     CALL    SORT        ;SORT THE DIRECTORY
  78.     CALL    PACK        ;PACK THE DIRECTORY
  79.     MVI    A,1        ;SECNO = 1
  80.     STA    SECNO
  81.     LXI    H,BUF        ;ADDR = FWA OF BUFFER
  82.     SHLD    ADDR
  83. SAP2:    LDA    SECNO        ;SET TO SECTOR "SECNO"
  84.     LXI    H,LPMAP-1
  85.     ADD    L
  86.     MOV    L,A
  87.     JNC    $+4
  88.     INR    H
  89.     MOV    C,M
  90.     CALL    SETSEC
  91.     LHLD    ADDR        ;SET DMA ADDRESS TO "ADDR"
  92.     MOV    B,H
  93.     MOV    C,L
  94.     CALL    SETDMA
  95.     CALL    WRITE        ;WRITE SECTOR TO DISK
  96.     LHLD    ADDR        ;ADDR = ADDR + 80H
  97.     MOV    A,L
  98.     ADI    80H
  99.     MOV    L,A
  100.     JNC    $+4
  101.     INR    H
  102.     SHLD    ADDR
  103.     LDA    SECNO        ;SECNO = SECNO + 1
  104.     INR    A
  105.     STA    SECNO
  106.     CPI    17        ;LOOP UNTIL SECNO > 16
  107.     JC    SAP2
  108.     LHLD    OLDSP        ;EXIT TO CP/M
  109.     SPHL
  110.     RET
  111.  
  112. CLEAN:    MVI    A,0        ;I = 0
  113. CLEAN1:    STA    I
  114.     CALL    INDEX        ;HL = BUF + 16 * I
  115.     MOV    A,M        ;JUMP IF THIS IS A DELETED FILE
  116.     CPI    0E5H
  117.     JZ    CLEAN2
  118.     MOV    A,L        ;HL = HL + 12
  119.     ADI    12
  120.     MOV    L,A
  121.     JNC    $+4
  122.     INR    H
  123.     MOV    A,M        ;CHECK EXTENT FIELD
  124.     ORA    A
  125.     JNZ    CLEAN4        ;SKIP IF NOT EXTENT ZERO
  126.     INX    H        ;POINT TO RECORD COUNT FIELD
  127.     INX    H
  128.     INX    H
  129.     MOV    A,M        ;CHECK RECORD COUNT FIELD
  130.     ORA    A
  131.     JNZ    CLEAN4        ;JUMP IF NON-ZERO
  132.     LDA    I        ;CLEAR ALL 32 BYTES OF
  133.     CALL    INDEX        ;  DIRECTORY ENTRY TO E5
  134. CLEAN2:    MVI    C,32
  135. CLEAN3:    MVI    M,0E5H
  136.     INX    H
  137.     DCR    C
  138.     JNZ    CLEAN3
  139. CLEAN4:    LDA    I        ;I = I + 1
  140.     INR    A
  141.     CPI    64        ;LOOP UNTIL I > 63
  142.     JC    CLEAN1
  143.     RET
  144.  
  145. LPMAP:    DB    01,07,13,19,25,05,11,17,23,03,09,15,21
  146.     DB    02,08,14,20,26,06,12,18,24,04,10,16,22
  147.  
  148. COMP:    LDA    I        ;HL = BUF + 16 * I
  149.     CALL    INDEX
  150.     PUSH    H
  151.     LDA    J        ;HL = BUF + 16 * J
  152.     CALL    INDEX
  153.     XCHG
  154.     POP    H
  155.     MVI    C,13        ;NUMBER OF BYTES TO COMPARE
  156. COMP1:    LDAX    D        ;COMPARE NEXT BYTE
  157.     CMP    M
  158.     RNZ            ;RETURN IF NOT EQUAL
  159.     INX    D
  160.     INX    H
  161.     DCR    C        ;LOOP THRU FIRST 13 BYTES
  162.     JNZ    COMP1
  163.     XRA    A        ;CLEAR FLAGS AND EXIT
  164.     RET
  165.  
  166. SORT:    MVI    A,0        ;I = 0
  167.     STA    I
  168. SORT1:    LDA    I        ;J = I + 1
  169.     INR    A
  170.     STA    J
  171. SORT2:    CALL    COMP        ;IF NAME(J)<NAME(I), SWAP
  172.     CC    SWAP
  173.     LDA    J        ;J = J + 1
  174.     INR    A
  175.     STA    J
  176.     CPI    64        ;IF J < 64 GOTO SORT2
  177.     JC    SORT2
  178.     LDA    I        ;I = I + 1
  179.     INR    A
  180.     STA    I
  181.     CPI    63        ;IF I < 63 GOTO SORT1
  182.     JC    SORT1
  183.     RET
  184.  
  185. SWAP:    LDA    I
  186.     CALL    INDEX
  187.     PUSH    H
  188.     LDA    J
  189.     CALL    INDEX
  190.     XCHG
  191.     POP    H
  192.     MVI    C,32
  193. SWAP1:    LDAX    D
  194.     MOV    B,A
  195.     MOV    A,M
  196.     STAX    D
  197.     MOV    M,B
  198.     INX    D
  199.     INX    H
  200.     DCR    C
  201.     JNZ    SWAP1
  202.     RET
  203.  
  204. INDEX:    MOV    L,A
  205.     MVI    H,0
  206.     DAD    H
  207.     DAD    H
  208.     DAD    H
  209.     DAD    H
  210.     DAD    H
  211.     LXI    D,BUF
  212.     DAD    D
  213.     RET
  214.  
  215. PACK:    MVI    A,0        ;I = 0
  216. PACK1:    STA    I
  217.     CALL    INDEX        ;HL = BUF + 16 * I
  218.     MOV    A,L        ;HL = HL + 9
  219.     ADI    9
  220.     MOV    L,A
  221.     JNC    $+4
  222.     INR    H
  223.     MOV    A,M        ;JUMP IF FILETYPE NOT 'X$$'
  224.     SUI    '0'        ;  WHERE 0.LE.X.LE.9
  225.     JC    PACK2
  226.     CPI    10
  227.     JNC    PACK2
  228.     STA    J
  229.     INX    H
  230.     MOV    A,M
  231.     CPI    '$'
  232.     JNZ    PACK2
  233.     INX    H
  234.     MOV    A,M
  235.     CPI    '$'
  236.     JNZ    PACK2
  237.     INX    H        ;SET EXTENT NUMBER TO X
  238.     LDA    J
  239.     MOV    M,A
  240.     DCX    H        ;SET FILETYPE TO '$$$'
  241.     MVI    M,'$'
  242.     DCX    H
  243.     MVI    M,'$'
  244.     DCX    H
  245.     MVI    M,'$'
  246. PACK2:    LDA    I        ;I = I + 1
  247.     INR    A
  248.     CPI    64        ;LOOP UNTIL I > 63
  249.     JC    PACK1
  250.     RET
  251.  
  252. ;    DATA AREA
  253.  
  254. OLDSP:    DS    2
  255. STACK:    DS    64
  256. SECNO:    DS    1
  257. ADDR:    DS    2
  258. BUF:    DS    64*32
  259.  
  260. I:    DS    1
  261. J:    DS    1
  262.  
  263.     END
  264.