home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / SIMTEL / CPMUG / CPMUG026.ARK / CLIMATES.ASC < prev    next >
Text File  |  1984-04-29  |  6KB  |  198 lines
  1. 100 REM--E.A.GALLETTA,PATCHOGUE-H.S.,4/22/69 EARTH SIENCE (BIICAC)
  2. 110 REM--PROGRAM ON CLIMATES  
  3. 120 REM--REWRITTEN--7/28/69--BASIC--<ROD> 
  4. 130 REM REVISED BY TONY PEREZ, WALT WHITMAN HS, 8-69 
  5. 140 REM RE-REVISED BY C.LOSIK 8-26-70
  6. 150 DIML(56)  
  7. 160 READN,L(N) 
  8. 170 IFN<>56THEN 160
  9. 180 T=0 
  10. 190 PRINT"O.K., HERE ARE SOME VALUES FOR THE PRECIPIATION (P) AND FOR
  11. 200 PRINT"THE POTENTIAL EVAPOTRANSPIRATION (PE) OF AN AREA:"  
  12. 210 PRINT 
  13. 220 PRINT" ","MONTH"," P"," PE" 
  14. 230 PRINT" ","=====","=====","======" 
  15. 240 P=INT(10*RND(1))
  16. 250 IFP>6THEN240  
  17. 260 IFP<1THEN240  
  18. 270 E=INT(10*RND(1))
  19. 280 IFE>4THEN270  
  20. 290 IFE<1THEN270  
  21. 300 Z=5*E+6*P  
  22. 310 IF (Z-21)*(Z-22)*(Z-17)*(Z-38)=0 THEN 240 
  23. 320 FORI=1TO12 
  24. 330 PRINT" ",I,
  25. 340 IFP>1THEN360  
  26. 350 P1=12*COS(.261*I)^2+2*RND(1)
  27. 360 IFP<>2THEN380 
  28. 370 P1=12*SIN(.261*I)+2*RND(1) 
  29. 380 IFP<>3THEN400 
  30. 390 P1=2+3*RND(1)  
  31. 400 IFP<>4THEN420 
  32. 410 P1=2*RND(1) 
  33. 420 IFP<>5THEN440 
  34. 430 P1=7+10*RND(1) 
  35. 440 IFP<>6THEN460 
  36. 450 P1=3*COS(.5+.15*I)^2
  37. 460 PRINTINT(P1), 
  38. 470 IFE>1THEN490  
  39. 480 E1=10*SIN(.261*I)^2 
  40. 490 IFE<>2THEN510 
  41. 500 E1=12*SIN(.261*I)^2 
  42. 510 IFE<>3THEN530 
  43. 520 E1=2*SIN(.5+.15*I)^2
  44. 530 IFE<>4THEN550 
  45. 540 E1=8+4*RND(1)  
  46. 550 T=T+INT(P1) 
  47. 560 PRINTINT(E1+(E1/10)*2) 
  48. 570 NEXTI 
  49. 580 PRINT 
  50. 590 PRINT"TOTAL PRECIPITATION =";T;"INCHES"
  51. 600 PRINT 
  52. 610 PRINT"O.K., PLOT YOUR GRAPH ON THE PAPER PROVIDE YOU" 
  53. 620 PRINT"AND WHEN YOU ARE READY TO CONTINUE.... MEREY TYPE" 
  54. 630 PRINT"ANY NUMBER AND THE RETURN KEY.      "; 
  55. 640 INPUTQ 
  56. 650 PRINT 
  57. 660 PRINT"READY? GOOD, NOW TELL ME . . . DOES YOUR GRAPH SHOW THAT"  
  58. 670 PRINT"THE CLIMATE HAS DEFINITE WET AND DRY SEASONS (1=YES, 0=NO) "
  59. 680 INPUT S
  60. 690 PRINT 
  61. 700 IFS=0THEN880  
  62. 710 IF S<>1 THEN 660  
  63. 720 IFP<3THEN990  
  64. 730 B=0
  65. 740 GOSUB 1960
  66. 750 PRINT"TELL ME, IS THE CLIMATE [1] WET, [2] DRY, R [3] MODERATE ALL"  
  67. 760 PRINT"YEAR";  
  68. 770 INPUT S
  69. 780 PRINT 
  70. 790 IFS=1THEN920  
  71. 800 IFS=3THEN960  
  72. 810 IF S<>2 THEN 750  
  73. 820 IFT<13THEN1130 
  74. 830 IFT>80THEN860 
  75. 840 GOSUB1950 
  76. 850 GOTO1140
  77. 860 GOSUB1910 
  78. 870 GOTO1140
  79. 880 IFP>2THEN750  
  80. 890 IFP=2THEN820  
  81. 900 GOSUB1910 
  82. 910 GOTO990
  83. 920 IFT>80THEN1130 
  84. 930 IFT>=13THEN840 
  85. 940 GOSUB1930 
  86. 950 GOTO1140
  87. 960 IF(T-13)*(80-T)>=0THEN1130 
  88. 970 IFT<13THEN940 
  89. 980 IFT>80THEN860 
  90. 990 PRINT"TELL ME, WHICH IS THE WET SEASON, [1] THE WINTER OR [2] THE" 
  91. 1000 PRINT"SUMMER"; 
  92. 1010 PRINT 
  93. 1020 INPUT S
  94. 1030 PRINT 
  95. 1040 IFS=1THEN1090  
  96. 1050 IF S<>2 THEN 990  
  97. 1060 IFP=2THEN1130  
  98. 1070 GOSUB1910 
  99. 1080 GOTO1140
  100. 1090 IFP=1THEN1130  
  101. 1100 GOSUB1910 
  102. 1110 GOTO1140
  103. 1120 PRINT 
  104. 1130 PRINT"NICE GOING, SMARTY PANTS. KEEP UP THE GOODWORK."  
  105. 1140 PRINT"BY CHECKING THE PE CURVE ON YOUR GRAPH, WOUD YOU SAY THAT THE" 
  106. 1150 PRINT"SUMMERS ARE [1] HOT, [2] WARM, OR [3] COOL" 
  107. 1160 INPUT S
  108. 1170 PRINT 
  109. 1180 IFS=2THEN1260  
  110. 1190 IFS=3THEN1300  
  111. 1200 IF S<>1 THEN 1130  
  112. 1210 IFE=2THEN1320  
  113. 1220 IFE=4THEN1320  
  114. 1230 IF E=1 THEN 1320
  115. 1240 GOSUB1910 
  116. 1250 GOTO1330
  117. 1260 IFE=1THEN1320  
  118. 1270 IFE<>3THEN1240 
  119. 1280 GOSUB1950 
  120. 1290 GOTO1330
  121. 1300 IFE=3THEN1320  
  122. 1310 IFE<>3THEN1240 
  123. 1320 PRINT"YOU HAVE RESTORED MY FAITH IN TEENAGERS."
  124. 1330 PRINT"FROM THE SAME INFORMATION (PE GRAPH), WOULD YOU SAY THAT THE"
  125. 1340 PRINT"WINTERS ARE [1] COLD, [2] MILD, OR [3] WARM";
  126. 1350 INPUT S
  127. 1360 PRINT 
  128. 1370 IFS=2THEN1450  
  129. 1380 IFS=3THEN1490  
  130. 1390 IF S<>1 THEN 1330  
  131. 1400 IFE<3THEN1520  
  132. 1410 GOSUB1930 
  133. 1420 GOTO1530
  134. 1430 GOSUB1950 
  135. 1440 GOTO1530
  136. 1450 IFE=3THEN1520  
  137. 1460 IFE=4THEN1430  
  138. 1470 GOSUB1910 
  139. 1480 GOTO1530
  140. 1490 IFE=3THEN1410  
  141. 1500 IFE=4THEN1530  
  142. 1510 GOTO1470
  143. 1520 PRINT"IT WARMS MY HEART TO HEAR YOU SAY THAT. GOOD GOING."
  144. 1530 PRINT 
  145. 1540 PRINT"WELL, BY NOW YOU MUST HAVE AN INKLING AS TO THE TYPE OF" 
  146. 1550 PRINT"CLIMATE WE HAVE HERE. BELOW IS A COMPLETE LISTING OF ALL THE  
  147. 1560 PRINT"CLIMATES IN THE WORLD. REFER TO THEM BY THEIR NUMBER ONLY." 
  148. 1570 PRINT 
  149. 1580 PRINT 
  150. 1590 PRINT"NUMBER","NAME OF CLIMATE"
  151. 1600 PRINT"======","==============="
  152. 1610 PRINT"1","TROPICAL RAINFOREST" 
  153. 1620 PRINT"2","TROPICAL EAST COAST" 
  154. 1630 PRINT"3","TROPICAL MONSOON"
  155. 1640 PRINT"4","TROPICAL SAVANNA"
  156. 1650 PRINT"5","TROPICAL DESERT" 
  157. 1660 PRINT"6","MEDITERRANEAN"  
  158. 1670 PRINT"7","MARINE WEST COAST"  
  159. 1680 PRINT"8","HUMID CONTINENTAL"  
  160. 1690 PRINT"9","HUMID SUBTROPICAL"  
  161. 1700 PRINT"10","MIDDLE LATITUDE GRASSLANDS" 
  162. 1710 PRINT"11","MIDDLE LATITUDE DESERT" 
  163. 1720 PRINT"12","SUBARTIC CLIMATES" 
  164. 1730 PRINT"13 OR 14","HIGHLAND CLIMATES"
  165. 1740 PRINT" ","(TROPICAL OR MIDDLE LATITUDES)" 
  166. 1750 PRINT"15","POLAR TUNDRA"  
  167. 1760 PRINT"16","POLAR ICECAP"  
  168. 1770 PRINT 
  169. 1780 PRINT"WHAT IS THE NUMBER OF THE CLIMATE WE HAVE (WE'LL ACCEPT THE" 
  170. 1790 PRINT "FACT THAT THEY MAY OVERLAP)";  
  171. 1800 INPUTS 
  172. 1810 PRINT 
  173. 1820 PRINT 
  174. 1830 PRINT 
  175. 1840 IFS=L(Z)THEN1880  
  176. 1850 PRINT"MY SUGGESTION - STICK TO LANGUAGES OR SOCIAL STUDIES."  
  177. 1860 PRINT"YOU SHOULD HAVE SAID";L(Z);". GOOD DAY TO YOU." 
  178. 1870 STOP  
  179. 1880 PRINT"YOUR FORTUNE AS A METEOROLOGIST IS BUDDING. IT WAS" 
  180. 1890 PRINT"VERY NICE TO WORK WITH YOU. SO LONG."  
  181. 1900 STOP  
  182. 1910 B=1 
  183. 1920 GOTO1960  
  184. 1930 B=2 
  185. 1940 GOTO1960  
  186. 1950 B=3 
  187. 1960 PRINT"AW C'MON, YOU COULDN'T POSSIBLY MEAN THAT..."  
  188. 1970 PRINT"YOU SHOULD HAVE SAID";B 
  189. 1980 PRINT 
  190. 1990 RETURN 
  191. 2000 DATA11,6,16,7,23,10,26,3,27,15 
  192. 2010 DATA28,8,29,11,32,3,33,13,34,11
  193. 2020 DATA 35,9,39,16,40,8,41,13,44,5
  194. 2030 DATA46,10,45,16,50,1,51,12,56,4
  195. 2040 DATA39,4,44,5,35,9,40,8,45,1,41,15,46,12,51,5,56,16
  196. 2050 DATA0,0
  197. 2060 END
  198.