home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / SIMTEL / CPMUG / CPMUG026.ARK / CHASE.ASC < prev    next >
Text File  |  1984-04-29  |  3KB  |  109 lines
  1. 100 PRINT "THIS IS THE GAME OF CHASE"
  2. 110 PRINT "WANT INSTRUCTIONS";
  3. 120 INPUT C$
  4. 130 IF LEFT$(C$,1)="N" THEN 230
  5. 140 IF LEFT$(C$,1)<>"Y" THEN 110
  6. 150 PRINT "YOU ARE '*' IN A HIGH VOLTAGE MAZE WITH 5"
  7. 160 PRINT "SECURITY MACHINES '+' TRYING TO DESTROY YOU"
  8. 170 PRINT "YOU MUST MANEUVER THE SECURITY MACHINES INTO"
  9. 180 PRINT "THE MAZE 'X' TO SURVIVE.  GOOD LUCK !!!"
  10. 190 PRINT "MOVES ARE 7,8,9"
  11. 200 PRINT "          4,5,6"
  12. 210 PRINT "          1,2,3   0 TO END THE GAME"
  13. 220 PRINT
  14. 230 DIM A(10,20),E(21),F(21)
  15. 240 LET G=0
  16. 250 FOR B=1 TO 10
  17. 260 FOR C=1 TO 20
  18. 270 LET A(B,C)=0
  19. 280 IF B=1 THEN 330
  20. 290 IF B=10 THEN 330
  21. 300 IF C=1 THEN 330
  22. 310 IF C=20 THEN 330
  23. 320 GOTO 340
  24. 330 LET A(B,C)=1
  25. 340 NEXT C
  26. 350 NEXT B
  27. 360 FOR D=1 TO 21
  28. 370 LET B=INT(RND(1)*8)+2
  29. 380 LET C=INT(RND(1)*18)+2
  30. 390 IF A(B,C)<>0 THEN 370
  31. 400 LET A(B,C)=1
  32. 410 IF D<6 THEN 430
  33. 420 GOTO 440
  34. 430 LET A(B,C)=2
  35. 440 IF D=6 THEN 460
  36. 450 GOTO 470
  37. 460 LET A(B,C)=3
  38. 470 LET E(D)=B
  39. 480 LET F(D)=C
  40. 490 NEXT D
  41. 500 FOR B=1 TO 10
  42. 510 FOR C=1 TO 20
  43. 520 IF A(B,C)<>0 THEN 550
  44. 530 PRINT " ";
  45. 540 GOTO 630
  46. 550 IF A(B,C)<>1 THEN 580
  47. 560 PRINT "X";
  48. 570 GOTO 630
  49. 580 IF A(B,C)<>2 THEN 610
  50. 590 PRINT "+";
  51. 600 GOTO 630
  52. 610 IF A(B,C)<>3 THEN 630
  53. 620 PRINT "*";
  54. 630 NEXT C
  55. 640 PRINT
  56. 650 NEXT B
  57. 660 LET B=E(6)
  58. 670 LET C=F(6)
  59. 680 LET A(B,C)=0
  60. 690 INPUT Y
  61. 700 ON Y+1 GOTO 1040,730,730,730,740,780,740,710,710,710
  62. 710 LET B=B-1
  63. 720 GOTO 740
  64. 730 LET B=B+1
  65. 740 ON Y GOTO 750,780,770,750,780,770,750,780,770
  66. 750 LET C=C-1
  67. 760 GOTO 780
  68. 770 LET C=C+1
  69. 780 IF A(B,C)=1 THEN 1060
  70. 790 IF A(B,C)=2 THEN 1080
  71. 800 LET A(B,C)=3
  72. 810 LET E(6)=B
  73. 820 LET F(6)=C
  74. 830 FOR D=1 TO 5
  75. 840 IF A(E(D),F(D))<>2 THEN 1020
  76. 850 LET A(E(D),F(D))=0
  77. 860 IF E(D)>=B THEN 890
  78. 870 LET E(D)=E(D)+1
  79. 880 GOTO 910
  80. 890 IF E(D)=B THEN 910
  81. 900 LET E(D)=E(D)-1
  82. 910 IF F(D)>=C THEN 940
  83. 920 LET F(D)=F(D)+1
  84. 930 GOTO 960
  85. 940 IF F(D)=C THEN 960
  86. 950 LET F(D)=F(D)-1
  87. 960 IF A(E(D),F(D))=3 THEN 1080
  88. 970 IF A(E(D),F(D))=0 THEN 1000
  89. 980 LET G=G+1
  90. 990 GOTO 1010
  91. 1000 LET A(E(D),F(D))=2
  92. 1010 IF G=5 THEN 1100
  93. 1020 NEXT D
  94. 1030 GOTO 500
  95. 1040 PRINT "SORRY TO SEE YOU QUIT"
  96. 1050 GOTO 1110
  97. 1060 PRINT "ZAP!!! YOU TOUCHED THE FENCE !!!!!"
  98. 1070 GOTO 1110
  99. 1080 PRINT "** YOU HAVE BEEN DESTROYED BY A LUCKY COMPUTER **"
  100. 1090 GOTO 1110
  101. 1100 PRINT "YOU ARE LUCKY **YOU DESTROYED ALL THE ENEMY**"
  102. 1110 PRINT "WANT TO PLAY AGAIN";
  103. 1120 INPUT C$
  104. 1130 IF LEFT$(C$,1)="Y" THEN 240
  105. 1140 IF LEFT$(C$,1)<>"N" THEN 1110
  106. 1150 PRINT "HOPE YOU DON'T FEEL FENCED IN."
  107. 1160 PRINT "TRY AGAIN SOMETIME"
  108. 1170 END
  109.