home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / SIMTEL / CPMUG / CPMUG021.ARK / TRAP.ASC < prev    next >
Text File  |  1984-04-29  |  1KB  |  51 lines
  1.  
  2.  
  3. 5 OUT 2,26
  4. 7 PRINT "                       ---- T R A P ----":PRINT:PRINT:PRINT
  5. 10 G=6
  6. 20 N=100
  7. 30 REM-TRAP
  8. 40 REM STEVE ULLMAN 8-1-72
  9. 50 PRINT "WANT INSTRUCTIONS (0 FOR NO)"
  10. 60 INPUT Z
  11. 70 IF Z=0 THEN 180
  12. 80 PRINT "I AM THINKING OF A NUMBER BETWEEN 1 AND ";N
  13. 90 PRINT "TRY TO GUESS MY NUMBER.  ON EACH GUESS,"
  14. 100 PRINT "YOU ARE TO ENTER 2 NUMBERS TRYING TO TRAP"
  15. 110 PRINT "MY NUMBER BETWEEN THE TWO NUMBERS.  I WILL"
  16. 120 PRINT "TELL YOU IF YOU HAVE TRAPPED MY NUMBER, IF MY"
  17. 130 PRINT "NUMBER IS LARGER THAN YOUR TWO NUMBERS, OR IF"
  18. 140 PRINT "MY NUMBER IS SMALLER THAN YOUR TWO NUMBERS."
  19. 150 PRINT "IF YOU WANT TO GUESS ONE SINGLE NUMBER, TYPE"
  20. 160 PRINT "YOUR GUESS FOR BOTH YOUR TRAP NUMBERS."
  21. 170 PRINT "YOU GET ";G;"GUESSES TO GET MY NUMBER."
  22. 180 X=INT(N*RND(Z))+1
  23. 190 FOR Q=1 TO G
  24. 200 PRINT
  25. 210 PRINT "GUESS #";Q
  26. 220 INPUT A,B
  27. 230 IF A<>B THEN 240
  28. 235 IF X=A THEN 400
  29. 240 IF A <= B THEN 260
  30. 250 GOSUB 360
  31. 260 IF X<A THEN 300
  32. 270 IF X<=B THEN 320
  33. 280 PRINT "MY NUMBER IS LARGER THAN YOUR TRAP NUMBERS."
  34. 290 GOTO 330
  35. 300 PRINT "MY NUMBER IS SMALLER THAN YOUR TRAP NUMBERS."
  36. 310 GOTO 330
  37. 320 PRINT "YOU HAVE TRAPPED MY NUMBER."
  38. 330 NEXT Q
  39. 340 PRINT "SORRY, THAT'S";G;"GUESSES.  MY NUMBER WAS";X
  40. 350 GOTO 410
  41. 360 R=A
  42. 370 A=B
  43. 380 B=R
  44. 390 RETURN
  45. 400 PRINT "YOU GOT IT!!!!!"
  46. 410 PRINT
  47. 420 PRINT "TRY AGAIN."
  48. 430 PRINT 
  49. 440 GOTO 180
  50. 450 END
  51.