home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.barnyard.co.uk
/
2015.02.ftp.barnyard.co.uk.tar
/
ftp.barnyard.co.uk
/
cpm
/
walnut-creek-CDROM
/
SIMTEL
/
CPMUG
/
CPMUG013.ARK
/
WUMPAS.BAS
< prev
next >
Wrap
BASIC Source File
|
1984-04-29
|
6KB
|
198 lines
5 FOR I=1 TO 10:PRINT:NEXT I:PRINT TAB(30);"**** WUMPAS ****"
10 FOR I=1 TO 10:PRINT:NEXT I
15 DIM P(5)
20 INPUT"INSTRUCTIONS ";I$
40 IF LEFT$(I$,1)="N" THEN 70
50 IF LEFT$(I$,1)="Y" THEN 60
55 PRINT"YES OR NO":GOTO 20
60 GOSUB 1000
61 INPUT"MORE INSTRUCTIONS ? ";I$
62 IF LEFT$(I$,1)="N" THEN 70
63 IF LEFT$(I$,1)="Y" THEN 65
64 PRINT"YES OR NO":GOTO 61
65 GOSUB 1240
66 INPUT"DO YOU UNDERSTAND THE INSTRUCTIONS ?";I$
67 IF LEFT$(I$,1)="N" THEN 60
68 IF LEFT$(I$,1)="Y" THEN 70
69 PRINT"YES OR NO":GOTO 66
70 DIM S(20,3)
80 FOR J=1 TO 20
90 FOR K=1 TO 3
100 READ S(J,K)
110 NEXT K
120 NEXT J
130 DATA 2,5,8,1,3,10,2,4,12,3,5,14,1,4,6
140 DATA 5,7,15,6,8,17,1,7,9,8,10,18,2,9,11
150 DATA 10,12,19,3,11,13,12,14,20,4,13,15,6,14,16
160 DATA 15,17,20,7,16,18,9,17,19,11,18,20,13,16,19
170 DEF FNA(X)=INT(20*RND)+1
180 DEF FNB(X)=INT(3*RND)+1
190 DEF FNC(X)=INT(4*RND)+1
220 DIM L(6),M(6)
240 FOR J=1 TO 6
250 L(J)=FNA(1)
260 M(J)=L(J)
270 NEXT J
290 FOR J=1 TO 6
300 FOR K=J TO 6
310 IF J=K THEN 330
320 IF L(J)=L(K) THEN 240
330 NEXT K
340 NEXT J
360 A=5
365 LL=L(1)
375 PRINT"HUNT THE WUMPUS"
390 GOSUB 2000
410 GOSUB 2500
420 ON O GOTO 440,480
440 GOSUB 3000
450 IF F=0 THEN 390
460 GOTO 500
480 GOSUB 4000
490 IF F=0 THEN 390
500 IF F>0 THEN 550
520 PRINT"HA HA HA! YOU LOSE!!"
530 GOTO 560
550 PRINT"HEE HEE HEE - THE WUMPUS GETCHA NEXT TIME!!"
560 FOR J=1 TO 6
570 L(J)=M(J)
580 NEXT J
590 INPUT"SAME SET UP ";I$
595 IF LEFT$(I$,1)="N" THEN 240
600 IF LEFT$(I$,1)="Y" THEN 360
605 PRINT"YES OR NO":GOTO 590
1000 REM INSTRUCTIONS
1010 PRINT"WELCOME TO 'HUNT THE WUMPUS'"
1020 PRINT" THE WUMPUS LIVE IN A CAVE OF 20 ROOMS. EACH ROOM"
1030 PRINT"HAS THREE TUNNELS LEADING TO OTHER ROOMS."
1070 PRINT:PRINT" HAZARDS:"
1080 PRINT"BOTTOMLESS PITS - TWO ROOMS HAVE BOTTOMLESS PITS IN THEM"
1090 PRINT" IF YOU GO THERE YOU FALL INTO THE PIT (& LOSE!)"
1100 PRINT"SUPER BATS - TWO OF THE ROOMS HAVE SUPER BATS. IF YOU"
1110 PRINT" GO THERE, A BAT GRABS YOU AND TAKES YOU TO SOME OTHER"
1120 PRINT" ROOM AT RANDOM. (WHICH MIGHT BE TROUBLESOME)"
1140 PRINT:PRINT" WUMPUS:"
1150 PRINT"THE WUMPUS IS NOT BOTHERED BY THE HAZARDS (HE HAS SUCKER"
1160 PRINT"FEET AND IS TOO BIG FOR A BAT TO LIFT). USUALLY"
1170 PRINT"HE IS ASLEEP. TWO THINGS WAKE HIM UP: YOUR ENETRING"
1180 PRINT"HIS ROOM OR YOU SHOOTING AN ARROW."
1190 PRINT" IF THE WUMPUS WAKES, 75% OF THE TIME HE WILL MOVE ONE"
1200 PRINT"ROOM. THE REST OF THE TIME HE STAYS STILL. AFTER THAT"
1210 PRINT"IF HE IS WHERE YOU ARE, HE EATS YOU UP!! (& YOU LOSE!!)"
1230 PRINT
1235 RETURN
1238 PRINT" YOU:"
1240 PRINT"EACH TURN YOU MAY MOVE OR SHOOT A CROOKED ARROW."
1250 PRINT" MOVING: YOU CAN GO ONE ROOM (THROUGH ONE TUNNEL)"
1260 PRINT" ARROWS: YOU HAVE 5 ARROWS. YOU LOSE WHEN YOU RUN OUT."
1270 PRINT" EACH ARROW CAN GO FROM 1 TO 5 ROOMS. YOU AIM BY TELLING"
1280 PRINT" THE COMPUTER THE ROOM'S YOU WANT THE ARROW TO GO TO."
1290 PRINT" IF THE ARROW CAN'T GO THAT WAY (I.E. NO TUNNEL) IT MOVES"
1300 PRINT" AT RANDOM TO THE NEXT ROOM."
1310 PRINT" IF THE ARROW HITS THE WUMPUS, YOU WIN."
1320 PRINT" IF THE ARROW HITS YOU, YOU LOSE."
1340 PRINT:PRINT" WARNINGS:"
1350 PRINT" WHEN YOU ARE ONE ROOM AWAY FROM A WUMPUS OR HAZARD,"
1360 PRINT" THE COMPUTER SAYS:"
1370 PRINT"WUMPUS - 'I SMELL A WUMPUS'"
1380 PRINT"BAT - 'BATS NEARBY'"
1390 PRINT"PIT - 'I FEEL A DRAFT'"
1400 PRINT:RETURN
2000 REM
2010 PRINT
2020 FOR J=2 TO 6
2030 FOR K=1 TO 3
2040 IF S(L(1),K)<>L(J) THEN 2110
2050 ON J-1 GOTO 2060,2080,2080,2100,2100
2060 PRINT"I SMELL A WUMPUS"
2070 GOTO 2100
2080 PRINT"I FEEL A DRAFT"
2090 GOTO 2110
2100 PRINT"BATS NEARBY"
2110 NEXT K
2120 NEXT J
2130 PRINT"YOU ARE IN ROOM ";LL
2140 PRINT"TUNNELS LEAD TO ";S(LL,1);",";S(LL,2);",";S(LL,3)
2150 PRINT
2160 RETURN
2500 REM
2510 INPUT"SHOOT OR MOVE ";I$
2530 IF LEFT$(I$,1)<>"S" THEN 2560
2540 O=1
2550 RETURN
2560 IF LEFT$(I$,1)<>"M" THEN 2510
2570 O=2
2580 RETURN
2590 IF LEFT$(I$,1)<>"M" THEN 2510
3000 REM
3010 F=0
3040 INPUT"NUMBER OF ROOMS(1-5)";J9
3060 IF J9<1 OR J9>5 OR J9<>INT(J9) THEN 3040
3070 FOR K=1 TO J9
3080 INPUT"ROOM # ";P(K)
3095 IF K<=2 THEN 3115
3100 IF P(K)<>P(K-2) THEN 3115
3105 PRINT"ARROWS AREN'T THAT CROOKED. TRY ANOTHER ROOM.":GOTO 3080
3115 NEXT K
3120 REM
3130 LL=L(1)
3140 FOR K=1 TO J9
3150 FOR K1=1 TO 3
3160 IF S(LL,K1)=P(K) THEN 3295
3170 NEXT K1
3180 REM
3190 LL=S(LL,FNB(1))
3200 GOTO 3300
3210 NEXT K
3220 PRINT"MISSED"
3225 LL=L(1)
3230 REM
3240 GOSUB 3370
3250 REM
3260 A=A-1
3265 IF A>0 THEN 3280
3270 F=-1
3280 RETURN
3290 REM
3295 LL=P(K)
3300 IF LL<>L(2) THEN 3340
3310 PRINT"AHA! YOU GOT THE WUMPUS!"
3320 F=1
3330 RETURN
3340 IF LL<>L(1) THEN 3210
3350 PRINT"OUCH!! ARROW GOT YOU"
3360 GOTO 3270
3370 REM
3380 K=FNC(0)
3390 IF K=4 THEN 3410
3400 L(2)=S(L(2),K)
3410 IF L(2)<>LL THEN 3440
3420 PRINT"TSK TSK TSK - THE WUMPUS GOT YOU!"
3430 F=-1
3440 RETURN
4000 REM
4010 F=0
4020 INPUT"WHERE TO ";LL
4040 IF LL<1 OR LL>20 OR LL<>INT(LL) THEN 4020
4050 FOR K=1 TO 3
4070 IF S(L(1),K)=LL THEN 4130
4080 NEXT K
4090 IF LL=L(1) THEN 4130
4100 PRINT"NOT POSSIBLE -";
4110 GOTO 4020
4130 L(1)=LL
4150 IF LL<>L(2) THEN 4220
4160 PRINT"... OOPS! BUMPED A WUMPUS!!"
4180 GOSUB 3380
4190 IF F=0 THEN 4220
4200 RETURN
4220 IF LL<>L(3) AND LL<>L(4) THEN 4270
4230 PRINT"YYYIIIIEEEE . . . FELL INTO PIT"
4240 F=-1
4250 RETURN
4270 IF LL<>L(5) AND LL<>L(6) THEN 4310
4280 PRINT"SUPER BAT SNATCH! ELSEWHEREVILLE FOR YOU!"
4290 LL=FNA(1)
4300 GOTO 4130
4310 RETURN