home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / SIMTEL / CPMUG / CPMUG006.ARK / SIZE.ASM < prev    next >
Assembly Source File  |  1984-04-29  |  5KB  |  209 lines
  1. ;
  2. ;
  3. ; PRINT SIZE OF A DISK FILE ARGUMENT IN K BYTES.
  4. ;
  5. ; ROBERT A. VAN VALZAH
  6. ;
  7. ; 7/16/77
  8. ;
  9. *
  10. *
  11. ***************************************************************
  12. *
  13. *    CP/M ASSEMBLER LIBRARY PROCEDURES
  14. *
  15. *    INITIALIZATION OF TRANSIENT PROGRAM
  16. *
  17. *    FILE NAME:    THEAD.LIB
  18. *
  19. *    7/16/77
  20. *
  21. *
  22. *    THIS LIBRARY CAN BE USED TO SET UP A STANDARD
  23. *  CP/M PROGRAM.  TO USE, TYPE THE PROGRAM HEADER AND 
  24. *  PROGRAM CONSTANTS (EQUATES), THEN READ IN THE LIBRARY.
  25. *  TO RETURN TO CP/M EXECUTE A JUMP TO EXIT.
  26. *  USERS MAIN PROGRAM MUST BE LABLED MAIN (OR CHANGE JMP)
  27. *  STACK SIZE IS SET TO 64 BYTES.
  28. *
  29. * 
  30. *    BDOS I/O EQUATES
  31. *
  32. INCON    EQU    1    ;READ CONSOLE FUNCTION NO.
  33. OUTCON    EQU    2    ;WRITE CONSOLE FUNCTION NO.
  34. INTAPE    EQU    3    ;INPUT FROM TAPE READER FUNCTION NO.
  35. OUTTAPE    EQU    4    ;OUTPUT TO PUNCH FUNCTION NO.
  36. OUTBUF    EQU    9    ;OUTPUT STRING TERMINATED BY $
  37. INBUF    EQU    10    ;INPUT BUFFER FUNCTION NO.
  38. BDOS    EQU    5    ;BDOS ENTRY POINT
  39. *
  40. *    CONTROL CHARACTERS
  41. *
  42. CR    EQU    0DH    ;CARRIAGE RETURN
  43. LF    EQU    0AH    ;LINE FEED
  44. CNTRL    EQU    -40H    ;CONTROL KEY OFFSET (I.E.  CNTRL+'C')
  45. *
  46. *    EXECUTION
  47. *
  48.     ORG    100H
  49. START:    LXI    H,0
  50.     DAD    SP
  51.     SHLD    OLDSP    ;SAVE CP/M'S STACK POINTER
  52.     LXI    SP,STKTOP
  53.     JMP    MAIN
  54. *
  55. *
  56. *    RETURN TO OPERATING SYSTEM
  57. EXIT:    LHLD    OLDSP    ;RETURN CP/M'S STACK POINTER
  58.     SPHL
  59.     RET        ;RETURN TO SYSTEM
  60. *
  61. *    STACKS
  62. *
  63. OLDSP    DS    2    ;RESERVED FOR SYSTEM STACK POINTER
  64. STACK    DS    64    ;SPACE FOR USER STACK
  65. STKTOP    EQU    $    ;STACK WORKS UP FROM HERE
  66. *
  67. *            END THEAD.LIB
  68. ***************************************************************
  69. *
  70. *
  71. *
  72. *
  73. ***************************************************************
  74. *
  75. *    CP/M ASSEMBLER LIBRARY PROCEDURES
  76. *
  77. *    DISK I/O EQUATES THRU CP/M
  78. *
  79. *    FILE NAME DISKIOEQ.LIB
  80. *
  81. *    7/16/77
  82. *
  83. *
  84. BUFF    EQU    0080H    ;DEFAULT DISK I/O BUFFER
  85. *
  86. *    FILE CONTROL BLOCK DEFINITION AND SUB-DEFINITIONS
  87. *
  88. FCB    EQU    005CH    ;DEFAULT FILE CONTROL BLOCK
  89. *
  90. FCBDN    EQU    FCB+0    ;DISK NAME, 0=LOGGED IN DISK, 1=A, 2=B
  91. FCBFN    EQU    FCB+1    ;FILE NAME (8 CHARACTERS)
  92. FCBFT    EQU    FCB+9    ;FILE TYPE (3 CHARACTERS)
  93. FCBEX    EQU    FCB+12    ;FILE EXTENT, 0=FIRST 16K, 1=NEXT 16K
  94. FCBRC    EQU    FCB+15    ;RECORD COUNT, 80H=FULL EXTENT
  95. FCBNR    EQU    FCB+32    ;NEXT RECORD TO BE READ
  96. *
  97. *    BDOS FUNCTION NUMBER EQUATES
  98. *
  99. OPENFF    EQU    15    ;OPEN FILE FUNCTION, 255=NOT FOUND
  100. CLOSFF    EQU    16    ;CLOSE FILE FUNCTION, 255=NOT FOUND
  101. SRCHF    EQU    17    ;SEARCH FOR FILE, 255=NO MATCH
  102. SRCHN    EQU    18    ;SEARCH FOR NEXT OCCURRENCE
  103. DELTFF    EQU    19    ;DELETE FILE FUNCTION
  104. READRF    EQU    20    ;READ NEXT RECORD FUNCTION, 0=READ OK,
  105.             ;1=READ PAST END OF FILE,
  106.             ;2=READING UNWRITTEN DATA IN RANDOM
  107.             ;ACCESS
  108. WRITRF    EQU    21    ;WRITE RECORD FUNCTION, 0=WRITE OK,
  109.             ;1=ERROR IN EXTENDING FILE,
  110.             ;2=NO MORE DISK DATA SPACE (>240K)
  111.             ;255=NO MORE DIRECTORY SPACE
  112. MAKEFF    EQU    22    ;MAKE FILE FUNCTION, 255=NO DIR. SPACE
  113. *
  114. *
  115. *            END DISKIOEQ.LIB
  116. ***************************************************************
  117. *
  118. *
  119. ;
  120. ; MESSAGES
  121. ;
  122. LENMES:    DB    'FILE LENGTH: $'
  123. KMES:    DB    'K$'
  124. NOFILM:    DB    'NO SUCH FILE$'
  125. ;
  126. MAIN:
  127.     MVI    B,0    ;CLEAR SIZE SUM REG
  128. OPEN:
  129.     PUSH    B    ;SAVE SUM SO FAR
  130.     LXI    D,FCB    ;OPEN AN EXTENT OF THE FILE
  131.     MVI    C,OPENFF
  132.     CALL    BDOS
  133.     POP    B    ;GET SUM SO FAR BACK
  134.     CPI    255    ;ABLE TO FIND THAT FILE?
  135.     JZ    NOTHER    ;NOPE - GIVE ERROR AND EXIT
  136. ;
  137. ;    FCBRC NOW CONTAINS THE NUMBER OF 128 BYTE RECORDS
  138. ;    IN THIS EXTENT OF THE FILE.  THUS, DIVIDING BY 8
  139. ;    WE CAN GET THE EXTENT LENGTH IN K BYTES.  BUT THE
  140. ;    DISK IS ALLOCATED IN 1K CHUNKS, SO A LENGTH OF 4.5K
  141. ;    BYTES REALLY HAS 5K BYTES ALLOCATED FOR IT.
  142. ;    THEREFORE, WE MUST ROUND UP TO GET THE TRUE AMMOUNT
  143. ;    OF DISK SPACE ALLOCATED FOR A FILE.
  144. ;
  145.     LDA    FCBRC    ;GET RECORD COUNT
  146.     ADI    0000$0111B    ;CAUSE CARRY INTO BIT 3 IF
  147.             ;LENGTH IS NOT AN EVEN K (ROUND UP).
  148.     ANI    1111$1000B    ;REMOVE ANY FRACTION LEFT
  149.     RRC        ;DIVIDE RESULT BY 8
  150.     RRC
  151.     RRC
  152.     ADD    B    ;ADD TO OLD SUM
  153.     MOV    B,A    ;UPDATE NEW SUM
  154.     LDA    FCBEX    ;PREPARE TO OPEN NEXT EXTENT IF THIS
  155.     INR    A    ;ONE IS FULL
  156.     STA    FCBEX
  157.     LDA    FCBRC    ;EXTENT IS FULL IF RC=128
  158.     CPI    128
  159.     JZ    OPEN    ;IS FULL - OPEN AND ADD NEXT EXTENT
  160. ;
  161. ;    REACHED LAST EXTENT, FILE LENGTH IN K BYTES IN IN B.
  162. ;
  163.     PUSH    B    ;SAVE LENGTH
  164.     LXI    D,LENMES    ;PRINT "FILE LENGTH: "
  165.     MVI    C,OUTBUF
  166.     CALL    BDOS
  167.     POP    B    ;GET LENGTH BACK
  168.     MOV    A,B    ;LENGTH -> A
  169.     CALL    DECA    ;PRINT A AS A NUMBER 0 - 255
  170.     LXI    D,KMES    ;PRINT "K"
  171.     JMP    PRARET    ;PRINT AND RETURN
  172. NOTHER:            ;COMES HERE IF FILE CAN'T BE FOUND
  173.     LXI    D,NOFILM
  174. PRARET:            ;PRINT MESSAGE AT DE AND EXIT
  175.     MVI    C,OUTBUF
  176.     CALL    BDOS
  177.     JMP    EXIT
  178. ;
  179. ;    DECA PRINTS THE NUMBER IN THE A REG AS A DECIMAL
  180. ;    NUMBER 0 - 255.  CLOBBERS A AND E.
  181. ;
  182. DECA:
  183.     MVI    E,-1 AND 255    ;INITIALIZE QUOTITENT
  184. ;
  185. ;    THIS LOOP DIVIDES THE A REG BY 10 THRU MULTIPLE
  186. ;    SUBTRACTION.  QUOTIENT IS LEFT IN E REG,
  187. ;    REMAINDER-10 IS LEFT IN A.
  188. ;
  189. LOOP:
  190.     INR    E    ;ADD ONE TO QUOTIENT FOR EACH SUBTRACT
  191.     SUI    10
  192.     JNC    LOOP    ;HAVEN'T UNDERFLOWED YET
  193. ;
  194.     ADI    '0' + 10    ;CONVERT REMAINDER TO ASCII
  195.     PUSH    PSW    ;PUT THIS DIGIT ON THE STACK
  196.     MOV    A,E    ;GET REMAINDER -> A
  197.     ORA    A    ;DONE WITH ALL DIGITS?
  198.     CNZ    DECA    ;NO - DO THIS AGAIN WITH THE REMAINDER
  199. ;
  200. ;    THE ASCII NUMBER IS NOW UP ON THE STACK, MSD FIRST
  201. ;    TO COME OFF.  BDOS WILL PROBABLY RETURN HERE.
  202. ;
  203.     POP    PSW
  204.     MOV    E,A
  205.     MVI    C,OUTCON
  206.     JMP    BDOS
  207. ;
  208.     END    ENTRY
  209.