home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.barnyard.co.uk
/
2015.02.ftp.barnyard.co.uk.tar
/
ftp.barnyard.co.uk
/
cpm
/
walnut-creek-CDROM
/
SIMTEL
/
CPMUG
/
CPMUG003.ARK
/
STRIKE9.BAS
< prev
next >
Wrap
BASIC Source File
|
1984-04-29
|
3KB
|
115 lines
90 DIM A(9),D(4),U(9)
110 PRINT
150 PRINT
160 PRINT
170 PRINT "DO YOU NEED INNSTRUCTIONS (YES/NO?)"
180 INPUT R$
185 RANDOMIZE
190 IF LEFT$(R$,1) = "N" THEN 340
200 IF LEFT$(R$,1) <> "Y" THEN 170
PRINT "BOARD WITH 9 NOS. : 1 2 3 4 5 6 7 8 9"
PRINT
250 PRINT "YOU WILL BE GIVEN A CHART OF THE NUMBERS YOU HAVE LEFT."
280 PRINT "TAKE OFF, ONE AT A TIME. THE NUMBERS YOU TAKE OFF"
290 PRINT "MUST ADD UP TO THE ROLL. YOU WIN BY REMOVING EVERY"
300 PRINT "NUMBER FROM THE BOARD. YOU LOSE IF YOU CANNOTT "
PRINT "REMOVE THE NUMBERS WITH THE ROLL YOU HAVE."
PRINT
340 PRINT
PRINT
350 PRINT "HERE IS THE BOARD: "
360 REM SET UP THE BOARD
370 FOR B=1 TO 9
380 PRINT B;
390 A(B)=B
400 NEXT B
405 PRINT
410 C=INT(RND*6+1)+INT(RND*6+1)
420 PRINT"YOUR ROLL IS",C
430 T=0
435 J=0
440 FOR X=1 TO 9
445 IF A(X) < 1 THEN 460
446 J=J+1
447 U(J)=A(X)
450 T=T+A(X)
460 NEXT X
465 REM CHECK FOR LOSS
470 IF C>T THEN 950
480 IF C=T THEN 1120
490 FOR K=1 TO J
500 FOR L=1 TO J
FOR M=1 TO J
FOR N=1 TO J
530 IF N=K THEN 630
IF N=L THEN 630
IF N=M THEN 630
IF M=K THEN 640
IF M=L THEN 640
IF L=K THEN 650
590 IF C-U(K)=0 THEN 680
IF C-U(K)=U(N) THEN 680
IF C-U(K)-U(L)=U(N) THEN 680
IF C-U(K)-U(L)-U(M)=U(N) THEN 680
630 NEXT N
640 NEXT M
650 NEXT L
660 NEXT K
670 GO TO 950
680 FOR X=1 TO 4
690 D(X)=0
700 NEXT X
710 PRINT"NO. OF NUMBERS TO REMOVE"
720 INPUT E
730 IF INT(E)<>E THEN 760
740 IF E<1 THEN 760
750 IF E>4 THEN 760
755 GO TO 770
760 PRINT"ANSWER 1,2,3, OR 4"
765 GO TO 710
770 PRINT"WHAT IS THE NUMBER"
780 FOR F=1 TO E
790 INPUT D(F)
800 Q=D(F)
805 IF A(Q) <>0 THEN 825
810 PRINT "YOU REMOVED IT BEFORE, TRY AGAIN"
820 GO TO 710
825 NEXT F
830 IF C<>(D(1)+D(2)+D(3)+D(4)) THEN 870
835 FOR F=1 TO E
840 A(D(F))=0
850 NEXT F
GO TO 880
870 PRINT "THOSE NUMBERS DONT ADD UP TO YOUR ROLL, TRY AGAIN"
GO TO 710
880 PRINT "THE NUMBERS YOU HAVE LEFT TO REMOVE ARE"
890 FOR B=1 TO 9
900 IF A(B)=0 THEN 920
910 PRINT A(B);
920 NEXT B
930 PRINT
GO TO 410
950 PRINT"SORRY, YOU LOST THIS TIME."
960 T=0
970 FOR B=1TO 9
980 IF A(B)=0 THEN 1000
990 T=T+1
1000 NEXT B
1010 PRINT"THERE ARE ";T;"NUMBERS LEFT ON THE BOARD: "
FOR X=1 TO 9
1030 IF A(X)=0 THEN 1050
1040 PRINT A(X);
1050 NEXT X
1060 PRINT
1070 GO TO 1140
1120 PRINT TAB(15);"*** CONGRATULATIONS ***"
1130 PRINT TAB(25);"* YOU WON *"
1140 PRINT
1150 PRINT
1160 PRINT "PLAY ANOTHER GAME (YES/NO)"
1170 INPUT H$
1180 IF LEFT$(H$,1)="Y" THEN 170
1190 IF LEFT$(H$,1)<>"N" THEN 1160
1200 STOP
1210 END