home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.barnyard.co.uk
/
2015.02.ftp.barnyard.co.uk.tar
/
ftp.barnyard.co.uk
/
cpm
/
walnut-creek-CDROM
/
SIMTEL
/
CPMUG
/
CPMUG003.ARK
/
LOAN.BAS
< prev
next >
Wrap
BASIC Source File
|
1984-04-29
|
3KB
|
89 lines
REM LOAN AMORTIZATION PROGRAM
REM WRITTEN BY BOB SIMPSON , CARDIFF CA.
PRINT "* * * * LOAN AMORTIZATION PROGRAM * * * * "
PRINT
PRINT "TO USE THIS PROGRAM, ENTER THE LOAN DATA AS EACH FACTOR"
PRINT "IS REQUESTED. THE COMPUTER WILL REPEAT THE PERTINANT"
PRINT "INFORMATION AND GIVE THE PERIODIC PAYMENT. YOU WILL THEN BE ASKED"
PRINT "IF YOU WANT THE PAYMENT SCHEDULE. A 'Y' ANSWER WILL PRINT THE FULL"
PRINT "TABULATION, PAYMENT BY PAYMENT WITH ALL PERIODIC AND CUMULATIVE TOTALS"
PRINT
PRINT "YOU WILL THEN BE GIVEN A CHANCE TO MODIFY PARAMETERS. IF YOU WANT"
PRINT "TO RECALCULATE A LOAN CHANGING ONLY THE INTEREST RATE, TYPE"
PRINT "'I'. AFTER ENTERING THE NEW INTEREST RATE, ANSWER 'C' TO CONTINUE."
PRINT "IF OTHER PARAMETERS NEED CHANGING, SPECIFY THEM BEFORE THE 'C'."
PRINT "IF 'N' IS ANSWERED TO THE 'CHANGE PARAMETERS?' PROMPT, THE PROGRAM"
PRINT "WILL START FROM THE BEGINNING."
PRINT
PRINT
REM
10 GOSUB 700
20 GOSUB 750
28 GOSUB 800
30 GOSUB 850
40 D=N*Y
50 R=R1/(100*N)
52 IF R<>0 THEN 60
55 A1=P/D
57 GOTO 70
60 A1=(R/(1-(1+R)^(-D)))*P
70 A=INT(A1*100+.5)/100
100 PRINT "PAYMENT IS $";A;","; N;"TIMES PER YEAR FOR ";Y;"YEARS"
110 PRINT "FOR A LOAN OF $";P;"AT ";R1;"% INTEREST"
120 PRINT
130 PRINT "PAYMENT SCHEDULE";
140 INPUT Q$
150 IF Q$="Y" THEN 900
160 PRINT
200 PRINT "CHANGE PARAMETER N(O), I(NT), Y(EARS), P(AYMENTS), L(OAN), OR C(ONTINUE)"
210 INPUT Q$
220 IF Q$="N" THEN 10
270 IF Q$="I" THEN 350
280 IF Q$="P" THEN 400
290 IF Q$="Y" THEN 500
300 IF Q$="L" THEN 600
310 GOTO 40
350 GOSUB 700
360 GOTO 200
400 GOSUB 750
410 GOTO 200
500 GOSUB 800
510 GOTO 200
600 GOSUB 850
610 GOTO 200
700 PRINT "INTEREST RATE IN %";
710 INPUT R1
730 RETURN
750 PRINT "NUMBER OF PAYMENTS PER YEAR";
760 INPUT N
770 RETURN
800 PRINT "HOW MANY YEARS";
810 INPUT Y
820 RETURN
850 PRINT "LOAN IN $";
860 INPUT P
870 RETURN
900 B=P
905 P1=0:P2=0
906 I1=0:I2=0
907 PRINT "PMNT YR PER PMNT TOTAL PMNT TOTAL";
908 PRINT " BAL"
909 PRINT " NO.";TAB(19);"INT INT PRIN PRIN DUE"
910 PRINT "-----------------------------------------------------------";
911 PRINT "------"
913 FOR T=1 TO D
914 IF T=0 THEN 940
915 I1=INT(R*B*100+.5)/100
920 I2=I2+I1
925 P1=A-I1
930 P2=P2+P1
935 B=B-P1
940 Y1=INT(T/N)
945 T1=T-Y1*N
950 PRINT T;TAB(8);Y1;TAB(13);T1;TAB(19);I1;TAB(29);I2;TAB(39);P1;
953 PRINT TAB(49);P2;TAB(59);B
955 NEXT T
956 PRINT "PAYMENTS TOTAL $";D*A
960 GOTO 160
999 END