home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / SIMTEL / CPMUG / CPMUG001.ARK / VBIOS31.ASM < prev    next >
Assembly Source File  |  1984-04-29  |  16KB  |  783 lines
  1. ;***********************************************;
  2. ;
  3. ;   CBIOS FOR IMSAI WITH SIO2-2 AND TELETYPE
  4. ;           INCLUDES IOBYTE FUNCTION
  5. ;   AND DRIVER FOR PROCESSOR TECHNOLOGY VDM
  6. ;    WRITTEN BY JEFF KRAVITZ, 05/21/77
  7. ;
  8. ;***********************************************;
  9.  
  10. ;NOTE :  MSIZE DETERMINES WHERE THIS CBIOS IS LOCATED
  11. MSIZE    EQU    31    ;CP/M MEMORY SIZE IN KBYTES
  12. PATCH    EQU    MSIZE*1024-2*256  ;START OF THE CBIOS
  13. ;***********************************************;
  14. ;
  15. ;               I/O DEVICE VALUES
  16. ; 
  17. ;***********************************************;
  18.  
  19. IOBYT    EQU    0003H    ;I/O CONTROL BYTE
  20.  
  21. TTYD    EQU    02H    ;TELETYPE DATA PORT
  22. TTYS    EQU    03H    ;TELETYPE STATUS PORT
  23. TTYDA    EQU    02H    ;TTY DATA AVAIL BIT
  24. TTYBE    EQU    01H    ;TTY BUFER EMPTY BIT
  25.  
  26. CRTD    EQU    04H    ;CRT DATA PORT
  27. CRTS    EQU    05H    ;CRT STATUS PORT
  28. CRTDA    EQU    02H    ;CRT DATA AVAIL BIT
  29. CRTBE    EQU    01H    ;CRT BUFFER EMPTY BIT
  30.  
  31. TTYMD    EQU    0CEH    ;TTY MODE BYTE
  32. TTYCM    EQU    017H    ;TTY COMMAND BYTE
  33.  
  34. CRTMD    EQU    0CEH    ;CRT MODE BYTE
  35. CRTCM    EQU    017H    ;CRT COMMAND BYTE
  36.  
  37. ;************************************************;
  38. ;
  39. ;        MISC EQUATES
  40. ;
  41. ;************************************************;
  42.  
  43.  
  44. ;*************************************************;
  45. ;
  46. ;    WE WILL USE A SCRATCH AREA STARTING AT 40H
  47. ;     FOR HOLDING THE VALUES OF:
  48. ;        TRACK   =  LAST SELECTED TRACK
  49. ;        SECTOR  =  LAST SELECTED SECTOR
  50. ;        DMAAD   =  LAST SELECTED DMA ADDRESS
  51. ;        DISKNO  =  LAST SELECTED DISK NUMBER
  52. ;(NOTE THAT ALL ARE BYTE VALUES EXCEPT FOR DMAAD)
  53. ;
  54. ;*************************************************;
  55.  
  56. SCRAT    EQU    40H      ;START OF SCRATCH AREA
  57. TRACK    EQU    SCRAT      ;CURRENT TRACK ON DRIVE 0
  58. TRAK1    EQU    TRACK+1      ;CURRENT TRACK ON DRIVE 1
  59. SECTOR    EQU    SCRAT+2      ;CURRENTLY SELECTED SECTOR
  60. DMAAD    EQU    SCRAT+3      ;CURRENT DMA ADDRESS
  61. DISKNO    EQU    SCRAT+5      ;CURRENT DISK NUMBER
  62. DUMMY    EQU    DISKNO+1  ;MUST BE 0 FOR DOUBLE ADD
  63.  
  64.     ORG    PATCH    ;ORIGIN OF THIS PROGRAM
  65. CBASE    EQU    (MSIZE-16)*1024    ;BIAS FOR SYSTEMS>16K
  66. CPMB    EQU    CBASE+2900H    ;BASE OF CP/M 
  67. BDOS    EQU    CBASE+3206H    ;BASE OF RESIDENT CODE
  68. CPML    EQU    $-CPMB        ;LENGTH OF CP/M
  69. NSECTS    EQU    CPML/128    ;# OF SECTORS TO LOAD
  70.  
  71.  
  72. ;************************************************;
  73. ;
  74. ;    JUMP VECTOR FOR INDIVIDUAL SUBROUTINES
  75. ;
  76. ;************************************************;
  77.     JMP    SCPM        ;COLD START
  78. WBOTE:    JMP    WBOOT        ;WARM START
  79.     JMP    CONST        ;CONSOLE STATUS
  80.     JMP    CONIN        ;CONSOLE CHARACTER IN
  81.     JMP    CONOUT        ;CONSOLE CHARACTER OUT
  82.     JMP    LIST        ;LIST CHARACTER OUT
  83.     JMP    PUNCH        ;PUNCH CHARACTER OUT
  84.     JMP    READER        ;READER CHARACTER OUT
  85.     JMP    HOME        ;MOVE HEAD TO HOME 
  86.     JMP    SELDSK        ;SELECT DISK
  87.     JMP    SETTRK        ;SET TRACK NUMBER
  88.     JMP    SETSEC        ;SET SECTOR NUMBER
  89.     JMP    SETDMA        ;SET DMA ADDRESS
  90.     JMP    READ        ;READ DISK
  91.     JMP    WRITE        ;WRITE DISK
  92.  
  93. ;************************************************;
  94. ;
  95. ; INDIVIDUAL SUBROUTINES TO PERFORM EACH FUNCTION
  96. ;
  97. ;************************************************;
  98. WBOOT:    ;READ THE DISK UNTIL ALL SECTORS LOADED
  99.     LXI    SP,80H    ;STACK BELOW BUFFER
  100.     MVI    C,0    ;SELECT DISK 0
  101.     CALL    SELDSK
  102.     CALL    HOME    ;GO TO TRACK 00
  103.  
  104.     MVI    B,NSECTS    ;B = # SECTORS TO LOAD
  105.     MVI    C,0    ;C HAS THE CURRENT TRACK NUMBER
  106.     MVI    D,2    ;D HAS THE NEXT SECTOR TO READ
  107. ; NOTE THAT WE BEGIN BY READING TRACK 0, SECTOR 2 SINCE SECTOR 1
  108. ; CONTAINS THE COLD START LOADER, WHICH IS SKIPPED IN A WARM START
  109.     LXI    H,CPMB    ;BASE OF CP/M (INITIAL LOAD POINT)
  110. LOAD1:    ;LOAD ONE MORE SECTOR
  111.     PUSH    B    ;SAVE SECTOR COUNT, CURRENT TRACK
  112.     PUSH    D    ;SAVE NEXT SECTOR TO READ
  113.     PUSH    H    ;SAVE DMA ADDRESS
  114.     MOV    C,D    ;GET SECTOR ADDRESS TO REG. C
  115.     CALL    SETSEC    ;SET SECTOR ADDRESS FROM REG. C
  116.     POP    B    ;RECALL DMA ADDRESS TO B,C
  117.     PUSH    B    ;REPLACE ON STACK 
  118.     CALL    SETDMA    ;SET DMA ADDRESS FROM B,C
  119. ;
  120. ; DRIVE SET TO 0, TRACK SET, SECTOR SET, DMA ADDRESS SET
  121.     CALL    READ
  122.     ORA    A    ;ANY ERRORS?
  123.     JNZ    WBOOT    ;RETRY IF ERROR
  124. ;
  125. ;    NO ERROR, MOVE TO NEXT SECTOR
  126.     POP    H    ;RECALL DMA ADDRESS
  127.     LXI    D,128    ;DMA=DMA+128
  128.     DAD    D    ;NEW DMA ADDRESS IS IN H,L
  129.     POP    D    ;RECALL SECTOR ADDRESS
  130.     POP    B    ;GET NUM. SECTORS & TRACK
  131.     DCR    B    ;SECTORS=SECTORS-1
  132.     JZ    GOCPM    ;GOTO CPM WHEN DONE
  133. ;
  134. ; MORE SECTORS REMAIN TO LOAD, CHECK FOR TRACK CHANGE
  135.     INR    D
  136.     MOV    A,D    ;SEC=27?,IF SO,CHANGE TRACKS
  137.     CPI    27
  138.     JC    LOAD1    ;CARRY GENERATED IF SECTOR<27
  139. ;
  140. ;    END OF CURRENT TRACK, GO TO NEXT TRACK
  141.     MVI    D,1    ;1ST SEC OF NEXT TRACK
  142.     INR    C    ;TRACK=TRACK+1
  143. ;
  144. ;    SAVE REGISTER STATE, AND CHANGE TRACKS
  145.     PUSH    B
  146.     PUSH    D
  147.     PUSH    H
  148.     CALL    SETTRK    ;TRACK ADDR SET FROM REG C
  149.     POP    H
  150.     POP    D
  151.     POP    B
  152.     JMP    LOAD1    ;FOR ANOTHER SECTOR
  153. ;
  154. ;    END OF LOAD OPERATION, SET PARAMETERS AND GO TO CP/M
  155. GOCPM:    LXI    SP,80H
  156.     MVI    A,0C3H    ;C3 IS A JMP INSTRUCTION
  157.     STA    0    ;FOR JMP TO WBOOT
  158.     LXI    H,WBOTE    ;WBOOT ENTRY POINT
  159.     SHLD    1    ;SET ADDRESS FIELD FOR JMP AT 0
  160. ;
  161.     STA    5    ;FOR JMP TO BDOS
  162.     LXI    H,BDOS    ;BDOS ENTRY POINT
  163.     SHLD    6    ;ADDRESS FIELD OF JUMP AT 5 TO BDOS
  164. ;
  165.     LXI    B,80H    ;DEFAULT DMA ADDRESS IS 80H
  166.     CALL    SETDMA
  167. ;
  168. ;PUT ACTIVE DISK NUMBER (STORED IN LOCATION 4) IN C
  169.     LDA    04H
  170.     MOV    C,A
  171.     EI        ;ENABLE INTERRUPTS
  172.     JMP    CPMB    ;GO TO CP/M FOR FURTHER PROCESSING
  173.  
  174. ;**********************************************;
  175. ;
  176. ;        COLD START ROUTINE
  177. ;
  178. ;**********************************************;
  179.  
  180. SCPM:    XRA    A    ;INITIALIZE IOBYT
  181.     STA    IOBYT
  182.     MVI    A,0AAH    ;DUMMY MODE BYTE
  183.     OUT    TTYS    ;CLEAR TTY
  184.     MVI    A,040H    ;RESET COMMAND
  185.     OUT    TTYS
  186.     MVI    A,TTYMD
  187.     OUT    TTYS
  188.     MVI    A,TTYCM
  189.     OUT    TTYS    ;SET UP TTY USART
  190.     LXI    SP,80H    ;SET STACK
  191.     CALL    DSINT    ;INITIALIZE DISPLAY
  192.     LXI    D,CPMSG    ;POINT TO STARTUP MESSAGE
  193.     MVI    C,09    ;WRITE BUFFER
  194.     CALL    BDOS    ;CALL BDOS
  195.     JMP    GOCPM    ;CONTINUE INITIALIZATION
  196.  
  197. CPMSG:    DB    0DH,0AH,'CP/M V1-3.5 L0.1 31K$'
  198. ;*************************************************;
  199. ;
  200. ;
  201. ;    I/O DRIVERS FOR THE DISK 
  202. ;
  203. ;*************************************************;
  204.  
  205. HOME:    ;MOVE TO THE TRACK 00 POSITION OF CURRENT DRIVE
  206.     LDA    DISKNO    ;SELECTED DISK
  207.     MOV    C,A    ;FOLLOW PARAMETER CONVENTIONS
  208.     CALL    SELDSK    ;ROUTINE TO SELECT THE DISK
  209. ;SET UP H,L TO POINT TO WORD WITH TRACK FOR SELECTED DISK
  210.     LXI    D,TRACK
  211.     LHLD    DISKNO
  212.     DAD    D
  213. HOMEL:
  214.     MVI    M,00    ;SET CURRENT TRACK PTR BACK TO 0
  215.     IN    127    ;READ FDC STATUS
  216.     ANI    4    ;TEST TRACK 0 BIT
  217.     RNZ        ;RETURN IF AT 0
  218.     STC        ;DIRECTION=OUT
  219.     CALL    STEP    ;STEP ONE TRACK
  220.     JMP    HOMEL    ;LOOP
  221. ;
  222. SELDSK:    ;SELECT DISK GIVEN BY REGISTER C
  223. ;MAKE SURE DUMMY IS 0 (FOR USE IN DOUBLE ADD TO H,L)
  224.     XRA    A
  225.     STA    DUMMY
  226.     MOV    A,C
  227.     STA    DISKNO
  228.     RRC        ;PUT INTO BITS 4,5
  229.     RRC
  230.     RRC
  231.     RRC
  232.     ORI    08    ;ENABLE DISK SELECT
  233.     OUT    127    ;SELECT THE DISK
  234.     RET
  235. ;
  236. SETTRK:    ;SET TRACK GIVEN BY REGISTER C
  237. ;FIRST REFERENCE CORRECT TRACK INDICATOR ACCORDING TO
  238. ;SELECTED DISK
  239.     LXI    D,TRACK    ;ADDRESS OF TRACK FOR DISK 0
  240.     LHLD    DISKNO    ;FIND OUT WHICH DISK IS SELECTED
  241.     DAD    D
  242.     MOV    A,C    ;DESIRED TRACK
  243.     CMP    M
  244.     RZ        ;WE ARE ALREADY ON THE TRACK
  245. SETTKX:
  246.     CALL    STEP    ;STEP TRACK-CARRY HAS DIRECTION
  247.             ;STEP WILL UPDATE TRACK INDICATOR
  248.     MOV    A,C
  249.     CMP    M    ;ARE WE WHERE WE WANT TO BE
  250.     JNZ    SETTKX    ;NOT YET
  251. ;HAVE STEPPED ENOUGH
  252. SEEKRT:
  253. ;DELAY 18 MSEC FOR FINAL STEP TIME AND HEAD SETTLE TIME
  254.     MVI    A,18D
  255.     CALL    DELAY
  256.     RET        ;END OF SETTRK ROUTINE
  257. ;
  258. DELAY:    ;ROUTINE TO DELAY C(A) MILLISECONDS
  259.     MVI    C,82H    ;ADJUST FOR 1 MSEC LOOP DELAY
  260.             ;THIS IS THE VALUE FOR OUR IMSAI
  261. LDXA:
  262.     DCR    C
  263.     JNZ    LDXA    ;LOOP 1 MSEC
  264.     DCR    A
  265.     JNZ    DELAY
  266.     RET        ;END OF DELAY ROUTINE
  267. ;
  268. SETSEC:    ;SET SECTOR GIVEN BY REGISTER C
  269.     MOV    A,C
  270.     STA    SECTOR
  271.     RET
  272. ;
  273. SETDMA:    ;SET DMA ADDRESS GIVEN BY REGISTERS B AND C
  274.     MOV    L,C    ;LOW ORDER ADDRESS
  275.     MOV    H,B    ;HIGH ORDER ADDRESS
  276.     SHLD    DMAAD    ;SAVE THE ADDRESS
  277.     RET
  278. ;
  279. ;
  280. ERRORS:    DB    0    ;KEEP TRACK OF NUMBER OF ERRORS
  281. READ:    ;PERFORM READ OPERATION.
  282.     ;THIS IS SIMILAR TO WRITE, SO SET UP READ COMMAND AND USE
  283.     ;COMMON CODE IN WRITE
  284.     MVI    D,40H    ;SET READ FLAG
  285.     JMP    WAITIO    ;TO PERFORM THE ACTUAL I/O
  286. ;
  287. WRITE:    ;PERFORM A WRITE OPERATION
  288.     MVI    D,80H    ;SET WRITE COMMAND
  289. ;
  290. WAITIO:
  291. ;ENTER HERE FROM READ AND WRITE TO PERFORM THE ACTUAL I/O 
  292. ;OPERATION.  RETURN A 00H IN REGISTER A IF THE OPERATION COMPLETES
  293. ;PROPERLY, AND 01H IF AN ERROR OCCURS DURING THE READ OR WRITE
  294. ;
  295. ;IN THIS CASE, WE HAVE SAVED THE DISK NUMBER IN 'DISKNO' (0,1)
  296. ;    THE TRACK NUMBER IN 'TRACK' (0-76)
  297. ;    THE SECTOR NUMBER IN 'SECTOR' (1-26)
  298. ;    THE DMA ADDRESS IN 'DMAAD' (3-3F80H)
  299.             ;D STILL HAS R/W FLAG
  300.     MVI    A,10D    ;SET ERROR COUNT
  301.     STA    ERRORS    ;RETRY SOME FAILURES 10 TIMES
  302.             ;BEFORE GIVING UP
  303. TRYAGN:
  304. ;FIRST WE HAVE TO FIGURE OUT WHICH DRIVE IS SELECTED
  305. ;AND WHICH TRACK IS DESIRED
  306.     LXI    B,TRACK
  307.     LHLD    DISKNO
  308.     DAD    B    ;H,L POINT TO CORRECT TRACK INDICATOR
  309.     MOV    A,M
  310.     PUSH    PSW    ;NEED IT LATER
  311.     LHLD    DMAAD    ;GET BUFFER ADDRESS
  312.     DCX    H    ;SAVE AND REPLACE 3 BYTES BELOW
  313.             ;BUF WITH TRACK,SECTOR,ADDRESS MARK
  314.     MOV    B,M
  315.     MVI    A,0FBH    ;ADDRESS MARK
  316.     MOV    M,A
  317.     DCX    H
  318.     MOV    C,M
  319.     LDA    SECTOR    ;NOTE THAT INVALID SECTOR NUMBER
  320.             ;WILL RESULT IN HEAD UNLOADED
  321.             ;ERROR, SO DONT CHECK
  322.     MOV    M,A
  323.     DCX    H
  324.     MOV    E,M
  325.     POP    PSW
  326.     MOV    M,A
  327.     MOV    A,H    ;SET UP FDC DMA ADDRESS
  328.     OUT    126    ;HIGH BYTE
  329.     MOV    A,L
  330.     OUT    125    ;LOW BYTE
  331.     MOV    A,D    ;GET R/W FLAG
  332.     OUT    127    ;START DISK READ/WRITE
  333. RWWAIT:    IN    127    ;READ FDC STATUS
  334.     ANI    0F8H    ;TEST FOR ANY ERROR OR IOF
  335.     JZ    RWWAIT
  336.     MOV    M,E    ;RESTORE 3 BYTES BELOW BUF
  337.     INX    H
  338.     MOV    M,C
  339.     INX    H
  340.     MOV    M,B
  341.     IN    127    ;TEST FOR ERRORS
  342.     ANI    0F0H
  343.     RZ        ;A WILL BE 0 IF NO ERRORS
  344. ;COME HERE ON ERROR FROM DISK
  345.     PUSH    PSW    ;SAVE ERROR CONDITION
  346. ;CHECK FOR 10 ERRORS
  347.     LXI    H,ERRORS
  348.     DCR    M
  349.     JNZ    REDO    ;NOT TEN YET.  DO A RETRY
  350. ;WE HAVE TOO MANY ERRORS. PRINT OUT HEX NUMBER FOR LAST
  351. ;RECEIVED ERROR TYPE. CPM WILL PRINT PERM ERROR MESSAGE.
  352.     POP    PSW    ;GET CODE
  353.     RRC
  354.     RRC
  355.     RRC
  356.     RRC
  357. ;MAKE IT ASCII
  358.     ORI    030H
  359.     MOV    C,A
  360.     CALL    CONOUT
  361. ;SET ERROR RETURN FOR OPERATING SYSTEM
  362.     MVI    A,1
  363.     RET
  364. REDO:
  365. ;D STILL HAS READ/WRITE FLAG
  366.     POP    PSW    ;GET ERROR CODE
  367.     ANI    0E0H    ;RETRY IF NOT TRACK ERROR
  368.     JNZ    TRYAGN
  369. ;WAS A TRACK ERROR SO NEED TO RESEEK
  370.     PUSH    D    ;SAVE    READ/WRITE INDICATOR
  371. ;FIGURE OUT THE DESIRED TRACK
  372.     LXI    D,TRACK
  373.     LHLD    DISKNO    ;SELECTED DISK
  374.     DAD    D    ;POINT TO CORRECT TRACK INDICATOR
  375.     MOV    A,M    ;DESIRED TRACK
  376.     PUSH    PSW    ;SAVE IT
  377.     CALL    HOME
  378.     POP    PSW
  379.     MOV    C,A
  380.     CALL    SETTRK
  381.     POP    D    ;GET READ/WRITE INDICATOR
  382.     JMP    TRYAGN
  383. ;
  384. ;
  385. ;
  386. STEP:                ;STEP HEAD OUT TOWARDS ZERO
  387.                 ;IF CARRY IS SET; ELSE
  388.                 ;STEP IN
  389. ; H,L POINT TO CORRECT TRACK INDICATOR WORD
  390.     PUSH    PSW    ;SAVE DIRECTION
  391. STWAIT:    IN    127    ;INPUT FDC STATUS
  392.     ANI    2    ;TEST STEP READY BIT
  393.     JZ    STWAIT    ;WAIT FOR STEP READY(MAX 10 MSEC)
  394.     POP    PSW    ;GET DIRECTION TO STEP
  395.     JC    OUTX
  396.     INR    M    ;INCREMENT CURRENT TRACK BYTE
  397.     MVI    A,4    ;SET DIRECTION = IN
  398. DOSTEP:
  399.     OUT    127    ;SET DIRECTION BIT IN FDC
  400.     ORI    2
  401.     OUT    127    ;PULSE STEP BIT
  402.     ANI    0FDH
  403.     OUT    127    ;TURN OFF PULSE
  404.     RET
  405. ;
  406. OUTX:
  407.     DCR    M    ;UPDATE TRACK BYTE
  408.     XRA    A    ;SET DIRECTION = OUT
  409.     JMP    DOSTEP
  410.  
  411. ;*************************************************;
  412. ;
  413. ;        PERIPHERAL I/O DRIVERS
  414. ;
  415. ;*************************************************;
  416.  
  417. ;
  418. ;        CONSOLE STATUS
  419. ;
  420. CONST:    CALL    CONS    ;GET DEVICE STATUS
  421.     ORA    A    ;SET FLAGS
  422.     RZ        ;ZERO IF NO CHAR AVAIL
  423.     MVI    A,0FFH    ;FF IF CHAR OK
  424.     RET
  425.  
  426. CONS:    LDA    IOBYT    ;GET IOBYT
  427.     CALL    IOCAL    ;EXIT TO SELECTED ROUTINE
  428.     DW    TTYST    ;TELETYPE STATUS ROUTIE
  429.     DW    CRTST    ;CRT STATUS ROUTINE
  430.     DW    RDRST    ;READER STATUS ROUTINE
  431.     DW    NULST    ;NULL STATUS ROUTINE
  432.  
  433. ;
  434. ;        CONSOLE INPUT
  435. ;
  436. CONIN:    LDA    IOBYT    ;GET IOBYT
  437.     CALL    IOCAL    ;EXIT TO SELECTED ROUTINE
  438.     DW    TTYIN    ;TTY INPUT ROUTINE
  439.     DW    CRTIN    ;CRT INPUT ROUTINE
  440.     DW    RDRIN    ;READER INPUT ROUTINE
  441.     DW    NULIN    ;NULL INPUT ROUTINE
  442.  
  443. ;
  444. ;        CONSOLE OUTPUT
  445. ;
  446. CONOUT:    LDA    IOBYT    ;GET IOBYT
  447.     CALL    IOCAL    ;EXIT TO SELECTED ROUTINE
  448.     DW    TTYOUT    ;TTY OUTPUT ROUTINE
  449.     DW    CRTOUT    ;CRT OUTPUT ROUTINE
  450.     DW    PRTOUT    ;PRINTER OUTPUT ROUTINE
  451.     DW    NULOUT    ;NULL OUTPUT ROUTINE
  452.  
  453. ;
  454. ;        LISTING OUTPUT
  455. ;
  456. LIST:    LDA    IOBYT    ;GET IOBYT
  457.     RLC
  458.     RLC        ;SHIFT BITS
  459.     CALL    IOCAL    ;EXIT TO SELECTED ROUTINE
  460.     DW    TTYOUT    ;TTY OUTPUT ROUTINE
  461.     DW    CRTOUT    ;CRT OUTPUT ROUTINE
  462.     DW    PRTOUT    ;PRINTER OUTPUT ROUTINE
  463.     DW    NULOUT    ;NULL OUTPUT ROUTINE
  464.  
  465. ;
  466. ;        PUNCH OUTPUT
  467. ;
  468. PUNCH:    LDA    IOBYT    ;GET IOBYT
  469.     RRC
  470.     RRC
  471.     RRC        ;SHIFT BITS
  472.     RRC
  473.     CALL    IOCAL    ;EXIT TO SELECTED ROUTINE
  474.     DW    TTYOUT    ;TTY OUTPUT ROUTINE
  475.     DW    CRTOUT    ;CRT OUTPUT ROUTIE
  476.     DW    PUNOUT    ;PUNCH OUTPUT ROUTINE
  477.     DW    NULOUT    ;NULL OUTPUT ROUTINE
  478.  
  479. ;
  480. ;        READER INPUT
  481. ;
  482. READER:    LDA    IOBYT    ;GET IOBYT
  483.     RRC        ;SHIFT BITS
  484.     RRC
  485.     CALL    IOCAL    ;EXIT TO SELECTED ROUTINE
  486.     DW    TTYIN    ;TTY INPUT ROUTINE
  487.     DW    CRTIN    ;CRT INPUT ROUTINE
  488.     DW    RDRIN    ;READER INPUT ROUTINE
  489.     DW    NULIN    ;NULL INPUT ROUTINE
  490.  
  491. ;***************************************************;
  492. ;
  493. ;        I/O DISPATCHER
  494. ;
  495. ;***************************************************;
  496.  
  497. IOCAL:    RLC        ;SHIFT BITS
  498.     ANI    06H    ;MASK BITS
  499.     XTHL        ;SAVE HL, GET TABLE ADDRESS
  500.     PUSH    D    ;SAVE DE
  501.     MOV    E,A    ;GET SELECTION VALUE IN A
  502.     MVI    D,0
  503.     DAD    D    ;CALCULATE TABLE ENTRY ADDRESS
  504.     MOV    A,M    ;GET TABLE ENTRY
  505.     INX    H
  506.     MOV    H,M
  507.     MOV    L,A    ;INTO HL
  508.     POP    D    ;RESTORE DE
  509.     XTHL        ;PUT EXIT ADDR ON STACK, RESTORE HL
  510.     RET        ;EXIT TO ROUTINE
  511.  
  512. ;****************************************************;
  513. ;
  514. ;        PHYSICAL I/O ROUTINES
  515. ;
  516. ;***************************************************;
  517.  
  518. TTYST:    IN    TTYS
  519.     ANI    TTYDA    ;TEST FOR TTY DATA AVAIL.
  520.     RET        ;EXIT WITH ZERO IF NOT AVAIL
  521.  
  522. TTYIN:    CALL    TTYST    ;TEST FOR CHAR AVAIL
  523.     JZ    TTYIN    ;NOT YET, WAIT
  524.     IN    TTYD    ;GET DATA
  525.     ANI    7FH    ;STRIP PARITY
  526.     RET
  527.  
  528. TTYOUT:    IN    TTYS    ;GET TTY STATUS
  529.     ANI    TTYBE    ;TEST FOR XMIT BUFFER EMPTY
  530.     JZ    TTYOUT    ;WAIT TIL READY
  531.     MOV    A,C    ;GET OUTPUT CHAR
  532.     OUT    TTYD    ;OUTPUT CHAR
  533.     RET
  534.  
  535. CRTST:    CALL    TTYST
  536.     RET
  537.  
  538. CRTIN:    CALL    TTYIN    ;CRT KEYBOARD = TTY
  539.     RET        ;EXIT
  540.  
  541. CRTOUT:    MOV    A,C
  542.     PUSH    PSW    ;SAVE A
  543.     PUSH    B
  544.     PUSH    D
  545.     PUSH    H    ;SAVE REGS
  546.     CPI    0DH    ;CARRIAGE RETURN?
  547.     JZ    COCR    ;YES
  548.     CPI    0AH    ;LF?
  549.     JZ    COLF    ;YES
  550.     CPI    08H    ;BACKSPACE?
  551.     JZ    COBS
  552.     CPI    0CH    ;FORM FEED?
  553.     JZ    COFF    ;YES
  554.     CPI    7FH    ;RUBOUT?
  555.     JZ    CO4    ;YES, IGNORE IT
  556.     JNC    CO4    ;IGNORE CHARS>7F
  557.     CPI    20H    ;OTHER CONTROL CHAR
  558.     JC    CO4    ;YES, IGNORE
  559.     STA    CHR
  560.     CALL    DSWRT    ;DISPLAY CHARACTER
  561. CO4:    POP    H
  562.     POP    D
  563.     POP    B
  564.     POP    PSW
  565.     RET
  566.  
  567. COCR:    CALL    CSRET
  568.     JMP    CO4
  569. COLF:    CALL    CSDWN
  570.     JMP    CO4
  571. COBS:    CALL    CSLFT
  572.     JMP    CO4
  573. COFF:    CALL    CSHOM
  574.     CALL    DSERS
  575.     JMP    CO4
  576.  
  577. DSINT:    LXI    H,VDMLC
  578.     SHLD    DSPLOC
  579.     MVI    A,0
  580.     STA    CURVRT
  581.     STA    CURHOR
  582.     CALL    DSERS
  583.     CALL    CSON
  584.     MVI    A,00
  585.     OUT    0C8H        ;SET UP VDM PORT
  586.     RET
  587.  
  588. DSERS:    LHLD    DSPLOC
  589.     LDA    CURVRT
  590.     MOV    C,A
  591. D1001:    MVI    B,LINSIZ
  592.     MVI    A,' '
  593. D1002:    MOV    M,A
  594.     INX    H
  595.     DCR    B
  596.     JNZ    D1002
  597.     INR    C
  598.     MVI    A,DSPSIZ
  599.     CMP    C
  600.     JNZ    D1001
  601.     CALL    CSON
  602.     RET
  603.  
  604. DSWRT:    LDA    CHR
  605.     LHLD    DSPLOC
  606.     MOV    M,A
  607.     CALL    CSRGT
  608.     IN    0FFH    ;READ SWITCHES
  609.     ORA    A    ;TEST
  610.     RZ        ;ZERO, RUN FULL SPEED
  611.     MOV    H,A    ;PUT SWITCHES IN H
  612.     MVI    L,0
  613. DLLP:    DCX    H    ;CHECK HL
  614.     MOV    A,H
  615.     ORA    L
  616.     JNZ    DLLP
  617.     RET
  618.  
  619. DSSCR:    LXI    H,VDMLC
  620.     MOV    D,H
  621.     MOV    E,L
  622.     LXI    B,LINSIZ
  623.     DAD    B
  624.     MVI    B,DSPSIZ-1
  625. D7003:    MVI    C,LINSIZ
  626. D7004:    MOV    A,M
  627.     STAX    D
  628.     INX    H
  629.     INX    D
  630.     DCR    C
  631.     JNZ    D7004
  632.     DCR    B
  633.     JNZ    D7003
  634.     MVI    C,LINSIZ
  635.     MVI    A,' '
  636. D7005:    STAX    D
  637.     INX    D
  638.     DCR    C
  639.     JNZ    D7005
  640.     RET
  641.  
  642. CSRGT:    CALL    CSOFF
  643.     LDA    CURHOR
  644.     INR    A
  645.     CPI    LINSIZ
  646.     JC    D2001
  647.     CALL    CSRET
  648.     CALL    CSDWN
  649.     RET
  650. D2001:    STA    CURHOR
  651.     LHLD    DSPLOC
  652.     INX    H
  653.     SHLD    DSPLOC
  654.     CALL    CSON
  655.     RET
  656.  
  657. CSLFT:    CALL    CSOFF
  658.     LDA    CURHOR
  659.     CPI    00
  660.     JNZ    D3001
  661.     CALL    CSON
  662.     RET
  663. D3001:    DCR    A
  664.     STA    CURHOR
  665.     LHLD    DSPLOC
  666.     DCX    H
  667.     SHLD    DSPLOC
  668.     CALL    CSON
  669.     RET
  670.  
  671. CSRET:    CALL    CSOFF
  672.     LHLD    DSPLOC
  673.     LDA    CURHOR
  674.     MOV    B,A
  675.     MOV    A,L
  676.     SUB    B
  677.     MOV    L,A
  678.     MOV    A,H
  679.     SBI    0
  680.     MOV    H,A
  681.     SHLD    DSPLOC
  682.     XRA    A
  683.     STA    CURHOR
  684.     CALL    CSON
  685.     RET
  686.  
  687. CSDWN:    CALL    CSOFF
  688.     LDA    CURVRT
  689.     CPI    DSPSIZ-1
  690.     JNZ    D4001
  691.     CALL    DSSCR
  692.     CALL    CSON
  693.     RET
  694. D4001:    LDA    CURVRT
  695.     INR    A
  696.     STA    CURVRT
  697.     LHLD    DSPLOC
  698.     LXI    B,LINSIZ
  699.     DAD    B
  700.     SHLD    DSPLOC
  701.     CALL    CSON
  702.     RET
  703.  
  704. CSUP:    CALL    CSOFF
  705.     LDA    CURVRT
  706.     CPI    00
  707.     JNZ    D5001
  708.     CALL    CSON
  709.     RET
  710. D5001:    LDA    CURVRT
  711.     DCR    A
  712.     STA    CURVRT
  713.     LHLD    DSPLOC
  714.     LXI    B,LINSIZ
  715.     MOV    A,L
  716.     SUB    C
  717.     MOV    L,A
  718.     MOV    A,H
  719.     SBB    B
  720.     MOV    H,A
  721.     SHLD    DSPLOC
  722.     CALL    CSON
  723.     RET
  724.  
  725. CSHOM:    CALL    CSOFF
  726.     LXI    H,VDMLC
  727.     SHLD    DSPLOC
  728.     LXI    H,0000
  729.     SHLD    CURHOR
  730.     CALL    CSON
  731.     RET
  732.  
  733. CSON:    LHLD    DSPLOC
  734.     MOV    A,M
  735.     ORI    80H
  736.     MOV    M,A
  737.     RET
  738.  
  739. CSOFF:    LHLD    DSPLOC
  740.     MOV    A,M
  741.     ANI    7FH
  742.     MOV    M,A
  743.     RET
  744.  
  745. DSPLOC    EQU    0047H
  746. CURHOR    EQU    0049H
  747. CURVRT    EQU    004AH
  748. CHR    EQU    004BH
  749.  
  750. DSPSIZ    EQU    16
  751. LINSIZ    EQU    64
  752. VDMLC    EQU    0CC00H
  753.  
  754.  
  755. RDRST:    CALL    TTYST    ;NOTE: READER IS TTY
  756.     RET
  757.  
  758. RDRIN:    CALL    TTYIN    ;NOTE: READER IS TTY
  759.  
  760. NULST:    MVI    A,0FFH    ;IF NULL DEVICE IS CONSOLE, CHAR 
  761.             ;IS ALWAYS READY
  762.     ORA    A
  763.     RET
  764.  
  765. NULIN:    MVI    A,1AH    ;NULL INPUT RETURNS EOF CHARS
  766.     RET
  767.  
  768. NULOUT:    MOV    A,C    ;COPY C TO A
  769.     RET
  770.  
  771. PRTOUT:    CALL    TTYOUT    ;NOE: PRINTER IS TTY
  772.     RET
  773.  
  774. PUNOUT:    CALL    TTYOUT    ;NOTE: PUNCH IS TTY
  775.     RET
  776.  
  777. ;**************************************************;
  778. ;
  779. ;        END OF BIOS ROUTINES
  780. ;
  781. ;**************************************************;
  782.     END
  783.