home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / OSBORNE / CLOCK.LBR / OCLOCKRV.AZM / OCLOCKRV.ASM
Assembly Source File  |  2000-06-30  |  6KB  |  190 lines
  1. ; OCLOCK.ASM - disassembled from OCLOCK.COM by Mike Rubenstein
  2. ;
  3. ; When LASMed and MLOADed, produces code identical to the
  4. ; Mike Rubenstein original, which was freely distributed with 
  5. ; his copyright (q.v., below) and the associated OCLOCK.DOC.
  6. ; 
  7. ; As noted in the document, this program is intended for use as
  8. ; a profiler, when testing applications written in Software Toolworks
  9. ; C-80.  It also provides valuable insights into the OCC1 ROM BIOS
  10. ; clock. 
  11. ;
  12. ; Initial disassembley, using REVAS and DSD, by Walt Wheeler, Y.O.U., 
  13. ; with major cleanup and clarification by Barry Siegfried, K2MF. 12/87
  14. ;
  15. BDOS    EQU    5
  16. TICNTR    EQU    0BH        ;two bytes at 0BH & 0CH for TICNTR
  17. TSTACK    EQU    13H        ;temp stack for use while back in RAM
  18. FCB    EQU    5CH        ;default FCB
  19. INTJVC    EQU     0EFF8H        ;int jump vector addr stored here
  20. ;
  21.     ORG     100H
  22. ;
  23.     JMP    START
  24. ;
  25. NAME:    DB    'OCLOCK Version 1.0',0DH,0AH
  26. ;
  27. CPYWR:    DB    'Copyright 1982  '
  28.     DB    'Michael M Rubenstein',0DH,0AH
  29.     DB    '$'
  30. ;
  31. START:    LXI    H,0        ;zero HL so that...
  32.     DAD    SP        ;...CCP stack pointer now in HL
  33.     LXI    SP,STACK    ;top of new stack
  34.     PUSH    H        ;save CCP stack pointer
  35. ;
  36.     LXI    H,FCB+1        ;look at command arg
  37.     LXI    D,OFFSW        ;point to 'OFF ' arg
  38.     LXI    B,4        ;arg count of 4
  39.     CALL    ARGTST        ;test for 'OFF ' arg
  40.     JZ    DEINST        ;turn off ticker
  41. ;
  42. ;This routine installs the ticker
  43. ;
  44. INST:    LHLD    INTJVC        ;int jump vector addr in HL
  45.     MOV    A,H        ;get int jump vector addr (high byte)
  46.     CPI    40H        ;does INTJVC point into ROM ( < 4000H )?
  47.     JRNC    ZERO        ;no, already installed
  48. ;
  49.     SHLD    NINT        ;yes, store orig int jump vector addr...
  50.                 ;...at new int jump vector
  51.     LHLD    BDOS+1        ;orig BDOS entry addr in HL
  52.     SHLD     NBDOS        ;store orig BDOS entry addr...
  53.                 ;...at new BDOS jump vector
  54. ;
  55. ;Calculate the dest addr of relocated code - BDOS minus 900H
  56. ;
  57.     MOV    A,H        ;get BDOS entry addr high byte
  58.     SUI    9        ;calculate - 900H (CCP is approx 800H ) 
  59.     MOV    H,A        ;put BDOS - 900H back in HL
  60.     MVI    L,0        ;zero L so that HL = dest addr
  61.     PUSH    H        ;save new BDOS jump vector
  62.                 ; this allows room for the relocated part of
  63.                 ; this code beneath the CCP, and protects both
  64.     XCHG            ;dest addr in DE
  65.     LXI    H,TICKER    ;source addr in HL
  66.     LXI    B,PROGLEN    ;program length in BC
  67.     LDIR            ;move ticker code to BDOS - 900H
  68.     POP    H        ;get back new BDOS jump vector
  69.     LXI    D,3        ;3 in DE so that...
  70.     SHLD    BDOS+1        ;store new BDOS jump vector at BDOS JMP
  71.     DAD    D        ;...HL = ticker code
  72.     SHLD    INTJVC        ;ticker code addr = new int jump vector
  73. ;
  74. ZERO:    LXI    H,0        ;zero HL to...
  75.     SHLD    TICNTR        ;...reset tick counter
  76. ;
  77. EXIT:    POP H            ;restore CCP stack pointer
  78.     SPHL            ;top of CCP stack
  79.     RET            ;return to CCP, ticker installed
  80. ;
  81. ;This routine de-installs the ticker
  82. ;
  83. DEINST:    LHLD    INTJVC        ;int jump vector addr in HL
  84.     MOV    A,H        ;get int jump vector addr high byte
  85.     CPI    40H        ;does INTJVC point to addr in ROM ( < 4000H )
  86.     JRC    EXIT        ;yes, already not-installed
  87. ;
  88.     MVI    L,NINTOFF    ;no, new int jump vector in HL
  89.     MOV    E,M        ;orig int jump...
  90.     INX    H        ;...vector addr...
  91.     MOV    D,M        ;...in DE
  92.     SDED    INTJVC        ;restore orig int jump vector addr
  93.     MVI    L,1        ;new BDOS jump vector in HL
  94.     MOV    E,M        ;orig BDOS...
  95.     INX    H        ;...entry addr...
  96.     MOV    D,M        ;...in DE
  97.     SDED    BDOS+1        ;restore orig BDOS entry addr
  98. ;
  99.     POP H            ;restore CCP stack pointer
  100.     SPHL            ;top of CCP stack
  101.     RET            ;return to CCP, ticker de-installed
  102. ;
  103. ARGTST:    LDAX    D        ;get 'OFF ' arg byte
  104.     CCI            ;A-[HL], HL=HL+1, BC=BC-1
  105.     RNZ            ;no match, ZF not set
  106.     RPO            ;BC=0, done with arg test, ZF set
  107.     INX    D        ;bump pointer
  108.     JR    ARGTST        ;loop until done
  109. ;
  110. ;---------------------------------------------------------------------
  111. ;This is the beginning of code to be moved up to BDOS - 900H
  112. ;---------------------------------------------------------------------
  113. ;
  114. TICKER    EQU    $
  115. ;
  116. NBDOS    EQU    $+1        ;addr for the following new BDOS...
  117.                 ;...jump filled in at runtime
  118. ;
  119.     JMP    0        ;jump to orig BDOS entry addr
  120. ;
  121. ;Actual ticker code starts here - this routine gets executed any
  122. ;    time the interrupt jump vector, which points to an address that
  123. ;    is buried in the ROM, would normally get executed
  124. ;
  125. ;---------------------------------------------------------------------
  126. ;This is the beginning of code which must be ported to any other
  127. ;    code that performs real-time functions
  128. ;
  129.     DI            ;disable interrupts
  130.     OUT    1        ;switch in RAM bank
  131.     SSPD    TSTACK        ;save ROM stack pointer...
  132.     LXI    SP,TSTACK    ;...at top of temp stack in RAM
  133.     PUSH    H        ;save regs
  134.     PUSH    D        ;
  135.     PUSH    PSW        ;
  136. ;
  137. ;---------------------------------------------------------------------
  138. ;The following code is meant to check that the new BDOS jump is
  139. ;    still installed - if it isn't it fixes it
  140. ;
  141. ;It will not be necessary to port this part of the code
  142. ;
  143.     LDED    INTJVC        ;new int jump vector in DE
  144.     MVI    E,0        ;new BDOS jump in DE
  145.     LHLD    BDOS+1        ;new BDOS jump vector in HL...
  146.                 ;...so that HL = DE if all OK
  147.     STC            ;set CF
  148.     DSBB    D        ;subtract DE from HL
  149.     JRC    TICKUP        ;HL = DE, CF still set
  150.     SDED    BDOS+1        ;CF cleared, HL > DE, refresh BDOS jump
  151. ;
  152. ;2 bytes beginning at 000BH for TICNTR
  153. ;
  154. ;The following code is equivalent to your real time code to which
  155. ;    the appropriate code above and below must be ported
  156. ;
  157. TICKUP:    LHLD    TICNTR        ;get the tick counter...
  158.     INX    H        ;...increment it and...
  159.     SHLD    TICNTR        ;...store it back
  160. ;
  161. ;---------------------------------------------------------------------
  162. ;This is the end of code which must be ported to any other
  163. ;    code that performs real-time functions
  164. ;
  165.     POP    PSW        ;restore regs
  166.     POP    D        ;
  167.     POP    H        ;
  168.     LSPD    TSTACK        ;restore ROM stack pointer
  169.     OUT    0        ;switch ROM bank back in
  170. ;
  171. NINT    EQU    $+1        ;addr for the following new int...
  172.                 ;...jump vector filled in at runtime
  173. ;
  174.     JMP    0        ;jump to orig int jump vector addr
  175. ;
  176. ;---------------------------------------------------------------------
  177. ;
  178. NINTOFF    EQU    NINT-TICKER    ;offset of orig int jump vector...
  179.                 ;...addr in relocated code
  180. ;
  181. PROGLEN    EQU    $-TICKER
  182. ;
  183. OFFSW:    DB    'OFF '        ;'OFF ' arg
  184. ;
  185.     DS    20        ;stack area
  186. ;
  187. STACK:                ;top of new stack
  188. ;
  189.     END
  190.