home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / OSBORNE / CLOCK.LBR / CLOCK.AZM / CLOCK.ASM
Assembly Source File  |  2000-06-30  |  8KB  |  206 lines
  1. ; CLOCK.ASM - December 20, 1987 - Walt Wheeler, Yankee Osborne Users (CT) 
  2. ;
  3. ; This program uses the remnants of the software clock built into the earliest
  4. ; versions of the Osborne 1 BIOS.  Most of that code was removed in vers. 1.1 or
  5. ; 1.2.  However,  OCC left a routine (in ROM) thru vers. 1.44, which increments
  6. ; a two byte counter beginning at 0efccH (which is within the BIOS scratch area
  7. ; in high RAM).  The ROM routine bumps the counter each 1/60th of a second --
  8. ; i.e. each time VERTICAL_RETRACE generates an interrupt -- with some relatively
  9. ; minor exceptions, such as disk accesses.   The exceptions limit the accuracy 
  10. ; of this clock, but I have found that in my typical use (and with the machine
  11. ; "on" 24 hours a day, this clock tends to run only a few seconds/day slow. 
  12. ; That's good enough for my purposes, including use on our RCPM.
  13. ;
  14. ; This program owes its existance to the work of others.  Many of the routines
  15. ; here are adapted (or simply "lifted") from public domain contributions by
  16. ; such CP/M gurus as Ward Christensen, Irv Hoff (W6FFC), Sigi Kluger, George
  17. ; Peace, Keith Petersen (W8SDZ), and Kelley Smith.   Jim Enright's artical
  18. ; on the OCC timer routine, reprinted from TOGGLE in FOGHORN (VI, 12, p.50) 
  19. ; renewed a latent interest in the OCC clock and provided the starting point 
  20. ; for this effort by locating the tick_counter, TICNTR.  (You'll find additional
  21. ; information beyond the scope of these comments in his text.)  Next, a belated 
  22. ; disassembley and review of Michael Rubenstein's OCLOCK.COM (written early in 
  23. ; OCC's life, for use in profiling 'C' programs) led me to the interrupt_jump_
  24. ; vector, INTJVC.  INTJVC seems to be the only point at which one can reliably
  25. ; intercept ROM calls under all (most?) circumstances.  Other vectors into the 
  26. ; ROM -- including those testing CON_STATUS -- go "unused" at times for reasons
  27. ; that I can't explain (yet?).  OCLOCK.COM also provides a neat algorithm for
  28. ; relocating and protecting its working code just beneath the CCP, for those 
  29. ; who chose not to implement ZCPR3.X.  Finally, Barry Siegfried (K2MF) of NYC
  30. ; worked out most of the "hard parts" in the disassembley, and in this code.
  31. ; Without his considerable investment of time and genius, on this and prelim-
  32. ; inary efforts, CLOCK.ASM would not exist.   
  33. ;  
  34. ; As presented here, this code has these KNOWN DEPENDENCIES:  OCC1, 1.4x ROM, 
  35. ; my particular implementation of ZCPR3 and NON-USE of RST2, whose vector 
  36. ; occupies the basepage addresses at which this program keeps date and time in 
  37. ; BCD (binary coded decimal). 
  38. ;
  39. ; HOWEVER, NONE OF THESE DEPENDENCIES IS ABSOLUTE.  This should be readily 
  40. ; modifiable for any Z80-based machine which utilizes a clocked_interrupt for
  41. ; routines like SCAN_KEYBOARD. Addresses -- including the locations used here
  42. ; for the relocated "working" code and for data -- can be changed to suit
  43. ; your system.   As it stands, it IS COMPATIBLE with DATTIM.COM, a
  44. ; proprietary program bundled with SuperCalc as distributed with the O1.
  45. ; 
  46. ; PHILOSOPHICAL DIGRESSIONS:  First:  Z80-based computing still has a lot of 
  47. ; untapped potential, available at very low cost.  Second, good public domain
  48. ; code (of which this is NOT held out as an example, except as it derives from
  49. ; some VERY good code and the work of others) is widely available for inspir-
  50. ; ation, emulation, and modification to suit our current and future wishes.
  51. ; 
  52. ; LASM, a public domain improvement on ASM, will assemble this code.
  53. ;
  54. DATE    EQU    011H    ; Addresses nominally reserved ...
  55. TIME    EQU    013H    ;   ...for RST 2 but generally unused for that
  56.             ;   purpose, and used for this one by DATTIM.COM.
  57. DEST    EQU    0D980H  ; IMPLEMENTATION DEPENDANT: this just happens to ...
  58.             ;   ...be handily available in WCW's system.   
  59. TICNTR    EQU    0EFCCH  ; ABSOLUTE, non-relocatable address under... 
  60. INTJVC    EQU    0EFF8H    ;   ...1.4x OCC ROM BIOS 
  61. ;
  62.     ORG    100H
  63. ;
  64.     LHLD    INTJVC    ; get int jump vector addr in HL
  65.     MOV    A,H    ; get int jump vector addr (high byte)
  66.     CPI    40H    ; Does INTVJC point into ROM ( < 4000H )?
  67.     JRNC    ZERO    ; no, already installed
  68. ;
  69.     SHLD    NINT    ; yes, store orig int jump vector addr...
  70.             ; ...at new int jump vector
  71. ;
  72. MOVUP:    LXI    D,DEST    ; dest addr in DE
  73.     PUSH    D    ; save dest addr
  74.     LXI    H,BNDRY    ; source addr in HL
  75.     LXI    B,LEN    ; program length in BC
  76.     LDIR        ; move ticker code
  77.     POP    D    ; store new int jump vector...
  78.     SDED    INTJVC    ; ...at orig int jump vector addr
  79. ;
  80. ZERO:    LXI    H,0    ; Zero the tick counter when this is initially run
  81.     SHLD    TICNTR    ;  to avoid TICNTR > 0E10H (i.e., past 1 minute)
  82.     RET        ; quit -- done with this .COM file
  83. ;
  84. ;Code for relocation, which actually tracks the clock, follows...
  85. ;
  86. BNDRY    EQU    $    ; for explanation of this notation, see such
  87.             ; code as early versions of BYE.ASM
  88. ;
  89.     DI        ; disable interrupts
  90.     OUT    1    ; switch in RAM bank
  91. ;
  92. ;---------------------------------------------------------------------
  93. ;
  94. ;NEXT 2 STACK INSTRUCTIONS PERHAPS NOT NECESSARY
  95. ;
  96.     SSPD    STK    ; save ROM stack pointer...
  97.     LXI    SP,STK    ; ...at top of temp stack
  98. ;
  99. ;---------------------------------------------------------------------
  100. ;
  101.     PUSH    PSW    ; save regs
  102.     PUSH    H
  103.     LHLD    TICNTR    ; get the tick count
  104.     MOV    A,H    ; look at high byte
  105.     CPI    0EH    ; are we near 0E10H ticks which is 1 minute?
  106.     JRC    EXIT    ; no, exit if <A> less than 0EH
  107. ;
  108.     MOV    A,L    ; yes, look at low byte
  109.     CPI    10H    ; and have we reached or exceeded 1 minute?
  110.     JRC    EXIT    ; no, exit if <A> less than 10H
  111. ;
  112.     LXI    H,0    ; but if we have reached 1 minute...
  113.     SHLD    TICNTR    ; ...ZERO the TICK COUNTER
  114.     LHLD    TIME    ; now, get the old TIME (hrs & mins)
  115.     MOV    A,H    ; move MINS to <A>
  116.     INR    A    ; bump it up
  117.     MOV    H,A    ; store it back to <H> - it may be OK
  118.     ANI    0FH    ; look at LEAST SIG BCD digit
  119.     CPI    0AH    ; has it reached 10 decimal?
  120.     JRNZ    ZTICK    ; if not, store the new time
  121. ;
  122.     MOV    A,H    ; else, get the bad BCD MINS back from <L>
  123.     ANI    0F0H    ; mask off the low nibble - i.e. ZERO it
  124.     ADI    10H    ; bump the high nibble (TENS) up one 
  125.     MOV    H,A    ; store it back to <H> - it may be OK
  126.     CPI    60H    ; and see if we're up to an hour
  127.     JRNZ    ZTICK    ; if not, store the new time
  128. ;
  129.     XRA    A    ; zero <A> - eg. 1:60 AM will become 2:00 AM
  130.     MOV    H,A    ; and put the new MINS value back in <H>
  131.     MOV    A,L    ; now get the HOURS byte
  132.     INR    A    ; bump it
  133.     MOV    L,A    ; store it back to <L> - it may be OK
  134.     CPI    24H    ; and see if we're up to a new date
  135.     JRZ    ZDATE    ; if so, bump the date and zero the time
  136. ;
  137.     ANI    0FH    ; else, look at LEAST SIG BCD digit
  138.     CPI    0AH    ; has it reached 10 decimal?
  139.     JRNZ    ZTICK    ; if not, store the new time
  140. ;
  141.     MOV    A,L    ; else, get the bad BCD HOURS back from <L>
  142.     ANI    0F0H    ; mask off the low nibble - i.e. ZERO it
  143.     ADI    10H    ; bump the high nibble (TENS) up one
  144.     MOV    L,A    ; correct # of TENS, 0 units to <L>
  145.     JR    ZTICK    ; and store the time
  146. ;
  147. ZDATE:    LDA    DATE    ; get the DATE byte in <A>
  148.     INR    A    ; bump it
  149.     STA    DATE    ; store it to back
  150.     ANI    0fH    ; mask to LEAST SIG BCD digit
  151.     CPI    0AH    ; is it a legal decimal digit
  152.     JRNZ    DATEX    ; if ok, get out
  153.     LDA    DATE    ; but if not, get both BCD digits back
  154.     ANI    0f0H    ; mask off LEAST SIG BCD digit, i.e. 0 it
  155.     ADI    010H    ; and bump the MORE SIG BCD digit  
  156.     STA    DATE    ; and store it... 
  157.             ; DAY 32?  too bad --  LET THE USER RESET each month
  158.             ; ---->  could be tested & fixed, but requires more
  159.             ; code like that above AND adds necessity for
  160.             ; table of month_lengths, coding for leap years, etc. 
  161. ;
  162. DATEX:    LXI    H,0    ; and ZERO the <HL> register
  163. ;
  164. ZTICK:    SHLD    TIME    ; store the time from <HL>
  165. ;
  166. EXIT:    POP    H    ; restore regs
  167.     POP    PSW
  168. ;
  169. ;---------------------------------------------------------------------
  170. ;
  171. ;NEXT STACK INSTRUCTION PERHAPS NOT NECESSARY
  172. ;
  173.     LSPD    STK    ; restore ROM stack pointer
  174. ;
  175. ;---------------------------------------------------------------------
  176. ;
  177.     OUT    0    ; switch ROM bank back in
  178. ;
  179. NINT    EQU    $+1    ; addr for the following new int...
  180.             ; ...jump vector filled in at runtime
  181. ;
  182.     JMP    0    ; jump to orig int jump vector addr
  183. ;    
  184. ;---------------------------------------------------------------------
  185. ;
  186. ;TEMPORARY STACK DEFINITION PERHAPS NOT NECESSARY
  187. ;
  188.     DW    0    ; 10 deep temporary stack
  189.     DW    0
  190.     DW    0
  191.     DW    0
  192.     DW    0
  193.     DW    0
  194.     DW    0
  195.     DW    0
  196.     DW    0
  197.     DW    0
  198. ;
  199. STK    EQU    $-BNDRY+DEST
  200. ;
  201. ;---------------------------------------------------------------------
  202. ;
  203. LEN    EQU    $-BNDRY
  204. ;
  205.     END
  206.