home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / MBUG / MBUG121.ARC / CPMUTILS.ARK / LIFE.AQM / LIFE.ASM
Assembly Source File  |  1988-08-07  |  16KB  |  786 lines
  1. ; THIS PROGRAM WILL BE PERFORM THE NECESSARY ANALYSIS
  2. ; TO DO THE GAME OF LIFE.
  3. ; STARTED 4/2/83 LAST UPDATE 5/15/83
  4. ;
  5. ; MODIFIED FOR THE VT/180 STARTED 6/16/83
  6. ; MODIFIED TO MAKE RESPONSE CHARACTER EITH LOWER OR
  7. ; UPPER CASE. 5/10/84
  8. ;
  9. VT    EQU    000H    ;-1=VT/180;0=OSBORNE
  10. GRAPH    EQU    0FFH    ;0=NO GRAPHICS,-1=OSBORNE GRAPHICS
  11. ;
  12. BDOS    EQU    0005H        ;SYSTEM CALL ADDRESS
  13. ESC    EQU    27        ;'ESCAPE' CODE
  14. HOME    EQU    26        ; CLEAR SCREEN CODE
  15. ;
  16.     ORG    0100H        ;START
  17.     LXI    H,0
  18.     DAD    SP
  19.     SHLD    OLDSP        ;SAVE STACK POINTER
  20. INIT    LXI    SP,STACK
  21. IF NOT VT
  22.     MVI    E,HOME        ;GET CHARACTER TO CLEAR SCREEN
  23.     CALL    OUTCH        ;SEND IT
  24. ENDIF
  25. IF VT
  26.     MVI    E,ESC        ;GET CHARACTER TO CLEAR SCREEN
  27.     CALL    OUTCH        ;SEND IT
  28.     MVI    E,'['        
  29.     CALL    OUTCH        
  30.     MVI    E,'2'        
  31.     CALL    OUTCH        
  32.     MVI    E,'J'        
  33.     CALL    OUTCH        
  34. ENDIF
  35. ;
  36. ;CLEAR BUFFER
  37. ;
  38. CLEAR    LXI    D,BUFFER    ;GET BUFFER ADDRESS
  39.     LXI    B,2000H        ;GET BUFFER SIZE
  40. REPEAT    MVI    A,0        ;CLEAR A
  41.     STAX    D        ;STORE AT (DE)
  42.     INX    D        ;INCREMENT (DE)
  43.     DCX    B        ;DECREMENT (BC)
  44.     MOV    A,B        ;A < B
  45.     ORA    A        ;ARE WE DONE?
  46.     JNZ    REPEAT        ;IF NOT, REPEAT
  47. ;
  48.     LXI    B,0        ;CLEAR GENERATION COUNTER
  49.     PUSH    B        ;SAVE IT
  50. IF GRAPH
  51.     MVI    E,ESC        ;GET ESCAPE
  52.     CALL    OUTCH        ;SEND IT
  53.     MVI    E,'G'        ;GET END GRAPHICS
  54.     CALL    OUTCH        ;SEND IT
  55. ENDIF
  56.     CALL    START        ;ENTER PATTERN
  57. IF VT
  58.     MVI    E,ESC        ;GET CHARACTER TO CLEAR SCREEN
  59.     CALL    OUTCH        ;SEND IT
  60.     MVI    E,'['        
  61.     CALL    OUTCH        
  62.     MVI    E,'2'        
  63.     CALL    OUTCH        
  64.     MVI    E,'J'        
  65.     CALL    OUTCH        
  66. ENDIF
  67. IF GRAPH
  68.     MVI    E,ESC        ;GET ESCAPE
  69.     CALL    OUTCH        ;SEND IT
  70.     MVI    E,'g'        ;GET START GRAPHICS
  71.     CALL    OUTCH        ;SEND IT
  72. ENDIF
  73.     CALL     READ        ;PRINT INITIAL PATTERN
  74. DO    CALL     SCAN        ;PROCESS NEXT GENERATION
  75.     CALL    READ        ;PRINT RESULTS
  76.     POP    B        ;GET GEN COUNTER
  77.     INX    B        ;INCREMENT IT
  78.     PUSH    B        ;SAVE IT
  79.     CALL    DECODE        ;DECODE GENERATION
  80.     MOV    A,E        ;STORE ASCII
  81.     STA    GENN+3
  82.     MOV    A,D
  83.     STA    GENN+2
  84.     MOV    A,C
  85.     STA    GENN+1
  86.     MOV    A,B
  87.     STA    GENN
  88. IF NOT VT
  89.     MVI    H,23        ;SET SCREEN POSITION
  90.     MVI    L,0
  91.     CALL    POSCUR        ;MOVE TO BOTTOM OF SCREEN
  92. ENDIF
  93.     MVI    C,9        ;SET PRINT STRING
  94.     LXI    D,STRING    ;GET ADDRESS
  95.     CALL    BDOS        ;DO IT
  96.     MVI    C,0BH        ;TEST CONSOLE
  97.     CALL    BDOS
  98.     CPI    0        ;IF NOT (NOT READY)
  99.     CNZ    CONT        ;CALL CONTINUE
  100.     JMP    DO        ;REPEAT
  101. ;
  102. ;CONTINUE ?
  103. ;
  104. IF NOT VT
  105.  CONT    MVI    H,23        ;SET SCREEN POSITION
  106.     MVI    L,0
  107.     CALL    POSCUR        ;MOVE TO BOTTOM OF SCREEN
  108.     MVI    C,1        ;GET STOP CHARACTER
  109.     CALL    BDOS
  110.     CPI    03H        ;SEE IF ^C
  111.     JZ    STOP        ;IS SO STOP
  112.     MVI    H,23        ;SET SCREEN POSITION
  113.     MVI    L,0
  114.     MVI    E,'?'        ;SET CHARACTER '?'
  115.     CALL    POSCHR        ;MOVE TO BOTTOM OF SCREEN
  116. ENDIF
  117. IF VT
  118. CONT    MVI    C,9        ;SET PRINT STRING
  119.     LXI    D,STRING3    ;GET ADDRESS;
  120.     CALL    BDOS        ;DO IT
  121.     MVI    C,1        ;GET STOP CHARACTER
  122.     CALL    BDOS        
  123.     CPI    03H        ;SEE IF ^C
  124.     JZ    STOP        ;IS SO STOP
  125.     MVI    C,9        ;SET PRINT STRING
  126.     LXI    D,STRING2    ;GET ADDRESS
  127.     CALL    BDOS        ;DO IT
  128. ENDIF
  129.     MVI    H,0BAH        ;LOAD TIMER COUNTER
  130.     PUSH    H        ;STORE IT
  131. CONT3    MVI    C,0BH        ;SEE IF CONSOLE READY
  132.     CALL    BDOS
  133.     CPI    0        ;IF NOT (NOTREADY)
  134.     JNZ    CONT4        ;GET CHARACTER
  135.     POP    H        ;GET TIMER
  136.     INX    H        ;INCREMENT IT
  137.     MOV    A,H        ;TEST TIMER
  138.     CPI    0        ;IF FINISHED
  139.     RZ            ;RETURN
  140.     PUSH    H        ;IF NOT STORE TIMER
  141.     JMP    CONT3        ;REPEAT
  142. CONT4    POP    H        ;CLEAR STACK
  143.     MVI    C,1        ;MODE- CONSOLE READ    
  144.     CALL    BDOS        ;GET CHARACTER
  145.     CPI    03H        ;SEE IF ^C
  146.     JZ    STOP        ;IS SO STOP
  147.     ANI    4FH        ;MAKE UPPER CASE
  148.     CPI    4EH        ;SEE IF 'N'
  149.     JZ    CONT2        ;IF SO CONTINUE
  150.     RET            ;OTHERWISE RETURN
  151. CONT2    POP    H        ;CLEAR STACK RETURN ADD
  152. IF GRAPH
  153.     MVI    E,ESC        ;GET ESCAPE
  154.     CALL    OUTCH        ;SEND IT
  155.     MVI    E,'G'        ;GET END GRAPHICS
  156.     CALL    OUTCH        ;SEND IT
  157. ENDIF
  158.     JMP    INIT        ;GOTO START
  159. ;
  160. ;STOP
  161. ;
  162. STOP
  163. IF GRAPH
  164.     MVI    E,ESC        ;GET ESCAPE
  165.     CALL    OUTCH        ;SEND IT
  166.     MVI    E,'G'        ;GET END GRAPHICS
  167.     CALL    OUTCH        ;SEND IT
  168. ENDIF
  169.     MVI    H,23        ;SET SCREEN POSITION
  170.     MVI    L,0
  171.     CALL    POSCUR        ;MOVE TO BOTTOM OF SCREEN
  172.     LXI    D,NAME
  173.     MVI    C,9
  174.     CALL    BDOS
  175.     LHLD    OLDSP        ;GET OLD STACK ADDRESS
  176.     SPHL
  177.     RET
  178. ;
  179. ; SUBROUTINE TO PROCESS ARRAY
  180. ; 1 = REMAIN FROM PREVIOUS GENERATION
  181. ; 4 = CREATE IN NEXT GENERATION
  182. ; 5 = DIE IN NEXT GENERATION
  183. ;
  184. ;MOVE FIRST LINES TO BUFFER END
  185. ;
  186. SCAN    LXI    B,0100H        ;LOAD COUNTER
  187.     LXI    D,BUFFER+0800H    ;LOAD STORE ADDRESS
  188.     LXI    H,BUFFER    ;LOAD FIND ADDRESS
  189.     DB    0EDH    ;LDIR    ;MOVE BLOCK
  190.     DB    0B0H
  191. ;
  192.     LXI    H,BUFFER    ;GET BUFFER ADDRESS
  193. SCAN1    PUSH    H        ;STORE IT
  194.     LXI    D,03EH        ;GET OFFSET TO NEXT LINE
  195.     MVI    A,0        ;CLEAR COUNTER
  196.     MVI    B,0        ;CLEAR INDICATOR B=1 IF CENTER
  197.     DB    0CBH    ;BIT 0,(HL)
  198.     DB    046H        ;LOCATION -1,-1
  199.     CNZ    ADDA        ;TEST IF OCCUPIED IF SO CALL ADDA
  200.     INX    H        ;INDEX ADDRESS
  201.     DB    0CBH    ;BIT 0,(HL)
  202.     DB    046H        ;LOCATION -1,0
  203.     CNZ    ADDA
  204.     INX    H
  205.     DB    0CBH    ;BIT 0,(HL)
  206.     DB    046H        ;LOCATION -1, 1
  207.     CNZ    ADDA
  208.     DAD    D        ;GO TO NEXT LINE
  209.     DB    0CBH    ;BIT 0,(HL)
  210.     DB    046H        ;LOCATION  0,-1
  211.     CNZ    ADDA
  212.     INX    H
  213.     DB    0CBH    ;BIT 0,(HL)
  214.     DB    046H        ;LOCATION  0, 0
  215.     CNZ    ADDB
  216.     INX    H
  217.     DB    0CBH    ;BIT 0,(HL)
  218.     DB    046H        ;LOCATION  0, 1
  219.     CNZ    ADDA
  220.     DAD    D        ;GO TO NEXT LINE
  221.     DB    0CBH    ;BIT 0,(HL)
  222.     DB    046H        ;LOCATION  1,-1
  223.     CNZ    ADDA
  224.     INX    H
  225.     DB    0CBH    ;BIT 0,(HL)
  226.     DB    046H        ;LOCATION  1, 0
  227.     CNZ    ADDA
  228.     INX    H
  229.     DB    0CBH    ;BIT 0,(HL)
  230.     DB    046H        ;LOCATION  1, 1
  231.     CNZ    ADDA
  232.     DB    0CBH    ;BIT 0,B
  233.     DB    040H
  234.     JZ    BIRTH        ;CHECK TO SEE IF CREATE
  235.     SUI    5        ;SEE IF MORE THAN 3 NEIGHBORS
  236.     JP    KILL        ;IF SO KILL
  237.     ADI    2        ;SEE IF LESS THAN 2 NEIGHBORS
  238.     JP    SCAN5        ;IF NOT CONTINUE
  239. KILL    MVI    A,5        ;MARK KILL POSITION
  240.     JMP    CONTI        ;CONTINUE
  241. BIRTH    SUI    3        ;SEE IF EXACTLY 3 NEIGHBORS
  242.     JNZ    SCAN5        ;IF NOT CONTINUE
  243.     MVI    A,4        ;STORE RESULTS
  244. CONTI    POP    H        ;GET CURRENT ADDRESS
  245.     PUSH    H        ;STORE IT AGAIN
  246.     LXI    D,041H        ;OFF SET TO CENTER
  247.     DAD    D        ;ADD TO ADDRESS
  248.     MOV    M,A        ;STORE NEW CONTENTS
  249. SCAN5    POP    H        ;GET ADDRESS AGAIN
  250.     INX    H        ;INCREMENT IT
  251.     MOV    A,H
  252.     SUI    0EH        ;SEE IF GTREATER THAN 1A
  253.     JM    SCAN1        ;IF SO REPEAT
  254. ;
  255. ;MOVE FIRST LINE BACK TO BEGINNING OF BUFFER
  256. ;
  257.     LXI    B,041H        ;LOAD COUNTER
  258.     LXI    D,BUFFER    ;LOAD STORE ADDRESS
  259.     LXI    H,BUFFER+0800H    ;LOAD FIND ADDRESS
  260.     DB    0EDH    ;LDIR    ;MOVE BLOCK
  261.     DB    0B0H
  262.     RET            ;RETURN
  263. ;
  264. ADDB    MVI    B,1        ;MARK IF CENTER OCCUPIED
  265. ADDA    ADI    1        ;ADD IF OCCUPIED
  266.     RET            ;RETURN
  267. ;
  268. ;SUBROUTINE TO DECODE PATTERN AND DISPLAY
  269. ;IT READS BUFFER AND CALLS SETSCR
  270. ;NOTE: SCREEN SIZE IS LIMITED TO 24 IN THE Y DIRECTION
  271. ;AND 50 IN THE X DIRECTION
  272. ;
  273. READ    LXI    H,0        ;CLEAR SCREEN ADDRESS
  274.     LXI    B,0        ;CLEAR GENERATION COUNTER 
  275. READ1    PUSH    H        ;SAVE ADDRESS
  276.     LXI    D,BUFFER    ;GET OFFSET
  277.     DAD    D        ;ADD TO SCREEN ADDRESS
  278.     MOV    A,M        ;GET CONTENTS
  279.     ANI    0FFH        ;SEE IF OTHER THAN 0
  280.     JZ    READ2        ;IF SO DECODE AND PRINT
  281.     SUI    5        ;CHECK IF LOCATION IS TO DIE
  282.     JP    BLANK        ;IF SO, SEND BLANK
  283.     INX    B        ;INCREMENT COUNTER
  284.     ADI    2        ;CHECK IF NEW LOCATION
  285.     JM    READ2        ;IF NOT CONTINUE
  286.     MVI    A,1        ;REPLACE NEW LOCATION
  287.     MOV    M,A        ;STORE IT
  288. IF GRAPH
  289.     MVI    E,0DH        ;SET GRAPHICS DOT
  290. ENDIF
  291. IF NOT GRAPH
  292.     MVI    E,'*'        ;SET DISPLAY CHARACTER
  293. ENDIF
  294.     JMP    PRINT        ;PRINT IT
  295. BLANK    MVI    A,0        ;CLEAR LOCATION
  296.     MOV    M,A        ;STORE IT
  297.     MVI    E,' '        ;CLEAR CHARACTER
  298. PRINT    POP    H        ;GET SCREEN ADDRESS
  299.     PUSH    H        ;SAVE IT
  300.     MOV    A,H        ;FIND Y
  301.     RLC            ;SHIFT Y VALUES
  302.     RLC
  303.     DB    0CBH    ;BIT 6,L
  304.     DB    075H
  305.     JZ    PRINT1        ;IF BIT SET
  306.     ADI    1        ;INCREMENT Y ADDRESS
  307. PRINT1    DB    0CBH    ;BIT 7,L
  308.     DB    07DH
  309.     JZ    PRINT2        ;IF BIT SET
  310.     ADI    2        ;INCREMENT Y ADDRESS
  311. PRINT2    MOV    H,A        ;STORE Y
  312.     MOV    A,L        ;  GET X
  313.     ANI    03FH        ;CANCEL BITS MOVED TO H
  314.     MOV    L,A        ;SAVE X
  315.     SUI    79        ;SEE IF X GREATER THAN SCREEN
  316.     JP    READ2        ;IF SO CONTINUE        
  317.     MOV    A,H        ;SEE IF Y GREATER THEN SCREEN SIZE
  318.     SUI    23        
  319.     JP    READ2        ;IF SO CONTINUE
  320.     PUSH    B        ;SAVE COUNTER
  321.     CALL    POSCHR        ;IF NOT PRINT CHARACTER
  322.     POP    B        ;GET COUNTER BACK
  323. READ2    POP    H        ;RESTORE ADDRESS
  324.     INX    H        ;INDEX ADDRESS
  325.     MOV    A,H        ;SEE IF GREATER THEN 18H
  326.     SUI    0EH
  327.     JM    READ1        ;IF NOT REPEAT
  328.     PUSH    B        ;SAVE POPULATION
  329.     CALL    DECODE        ;DECODE POPULATION
  330.     MOV    A,E        ;MOVE ASCII TO STORAGE
  331.     STA    POPN+3
  332.     MOV    A,D
  333.     STA    POPN+2
  334.     MOV    A,C
  335.     STA    POPN+1
  336.     MOV    A,B
  337.     STA    POPN
  338.     POP    B        ;GET POPULATION
  339.     MOV    A,B        ;TEST UPPER BYTE
  340.     CPI    0        ;IF NOT ZERO RETURN
  341.     RNZ
  342.     MOV    A,C        ;TEST LOWER BYTE
  343.     CPI    0        ;IF NOT ZERO RETURN
  344.     RNZ            
  345.     POP    H        ;CLEAR STACK RETURN ADD
  346.     MVI    H,23        ;SET SCREEN POSITION
  347.     MVI    L,0
  348.     MVI    E,'?'        ;SET CHARACTER '?'
  349.     CALL    POSCHR        ;MOVE TO BOTTOM OF SCREEN
  350.     MVI    C,1        ;MODE- CONSOLE READ    
  351.     CALL    BDOS        ;GET CHARACTER
  352.     CPI    53H        ;SEE IF 'S'
  353.     JZ    STOP        ;IS SO STOP
  354. IF GRAPH
  355.     MVI    E,ESC        ;GET ESCAPE
  356.     CALL    OUTCH        ;SEND IT
  357.     MVI    E,'G'        ;GET END GRAPHICS
  358.     CALL    OUTCH        ;SEND IT
  359. ENDIF
  360.     JMP    INIT
  361. ;
  362. ;SUBROUTINE TO WRITE CHARACTER TO ANY SCREEN POSITION
  363. ;THE CHARATER CODE IS SENT IN REGISTER E
  364. ;THE Y POSITION IS SENT    IN REGISTER H
  365. ;THE X POSITION IS SENT    IN REGISTER L
  366. ; 
  367. POSCHR    PUSH    D        ;SAVE CHARATER
  368.     CALL    POSCUR
  369.     POP    D
  370. OUTCH    MVI    C,2        ;SET FUNCTION WRITE
  371.     CALL    BDOS        ;CALL BDOS
  372.     RET
  373. ;
  374. ;SUBROUTINE TO POSITION CURSOR
  375. ;THE Y POSITION IS SENT    IN REGISTER H
  376. ;THE X POSITION IS SENT    IN REGISTER L
  377. ; 
  378. IF NOT VT
  379. POSCUR    LXI    D,2020H        ;LOAD OFFSETS
  380.     DAD    D        ;ADD TO LOCATIONS
  381.     PUSH    H        ;SAVE LOCATIONS
  382.     MVI    E,ESC        ;LOAD 'ESCAPE'
  383.     CALL    OUTCH        ;SEND 'ESCAPE'
  384.     MVI    E,'='        ;LOAD  '='
  385.     CALL    OUTCH        ;SEND  '='
  386.     POP    H        ;GET Y LOCATION
  387.     MOV    E,H        ;LOAD Y LOCATION
  388.     PUSH    H        ;SAVE X LOCATION
  389.     CALL    OUTCH        ;SEND Y LOCATION
  390.     POP    D        ;GET  X LOCATION
  391.     CALL    OUTCH        ;SEND X LOCATION
  392.     RET            ;RETURN
  393. ENDIF
  394. ;
  395. ; A NOTE THE VT/180 HAS TO HAVE THE ADDRESS CODE SENT AS THE 
  396. ; ESC,[,A1,A2,;,A1,A2,H  WHERE A1 AND A2 ARE THE ASCII CODES 
  397. ; FOR THE SCREEN POSITION 
  398. ;
  399. IF VT
  400. POSCUR    INR    H
  401.     INR    H
  402.     INR    L
  403.     MOV    B,H
  404.     CALL    DEC        ;DECODE VERTICAL POSITION
  405.     MOV    A,E        ;STORE ASCII
  406.     STA    VP+1
  407.     MOV    A,D
  408.     STA    VP
  409.     MOV    B,L
  410.     CALL    DEC        ;DECODE VERTICAL POSITION
  411.     MOV    A,E        ;STORE ASCII
  412.     STA    HP+1
  413.     MOV    A,D
  414.     STA    HP
  415.     MVI    C,9
  416.     LXI    D,PSTRING
  417.     CALL    BDOS
  418.     RET            ;RETURN
  419. PSTRING    DB    1BH,'['
  420. VP    DB    '  '
  421.     DB    ';'
  422. HP    DB    '  '
  423.     DB    'H'
  424.     DB    '$'
  425. ;
  426. ;SUBROUTINE TO DECODE NUMBERS INTO DECIMAL ASCII
  427. ;NUMBER SENT IN REGISTER B
  428. ;ASCII RETURNED IN C,D,E
  429. ;
  430. DEC    MOV    A,B        ;GET NUMBER
  431.     LXI    B,0        ;CLEAR STORAGE
  432.     LXI    D,0        ;CLEAR STOIRAGE
  433. DC1    SBI    100        ;
  434.     JM    DC2        ;IF NOT GO ON
  435.     INR    C
  436.     JMP    DC1
  437. DC2    ADI    100
  438.     MOV    B,A
  439.     MOV    A,C
  440.     ADI    30H
  441.     MOV    C,A
  442.     MOV    A,B
  443. DC3    SBI    10        ;
  444.     JM    DC4        ;IF NOT GO ON
  445.     INR    D
  446.     JMP    DC3
  447. DC4    ADI    10
  448.     MOV    B,A
  449.     MOV    A,D
  450.     ADI    30H
  451.     MOV    D,A
  452.     MOV    A,B
  453. DC5    SBI    1        ;
  454.     JM    DC6        ;IF NOT GO ON
  455.     INR    E
  456.     JMP    DC5
  457. DC6    MOV    A,E
  458.     ADI    30H
  459.     MOV    E,A
  460.     RET
  461. ENDIF
  462. ;
  463. ;WRITE BUFFER - CREATE TEST PATTERN
  464. ;
  465. WRITE    MVI    E,HOME        ;GET CHARACTER TO CLEAR SCREEN
  466.     CALL    OUTCH        ;SEND IT
  467.     POP    H
  468.     MVI    A,4        ;CHARACTER FOR BUFFER
  469.     LXI    H,BUFFER    ;GET ADDRESS
  470.     LXI    D,0218H        ;GET OFFSET
  471.     DAD    D        ;ADD TO ADDRESS
  472.     PUSH    H        ;STORE ADDRESS FOR LATER
  473.     PUSH    H
  474.     MOV    M,A        ;STORE IT
  475.     INX    H        ;INDEX ADDRESS
  476.     MOV    M,A
  477.     INX    H
  478.     MOV    M,A
  479.     INX    H        ;INDEX ADDRESS
  480.     MOV    M,A
  481.     INX    H
  482.     MOV    M,A
  483.     INX    H        ;INDEX ADDRESS
  484.     MOV    M,A
  485.     INX    H
  486.     MOV    M,A
  487.     INX    H        ;INDEX ADDRESS
  488.     MOV    M,A
  489.     INX    H
  490.     MOV    M,A
  491.     LXI    D,0040H        ;INDEX IN Y DIRECTION
  492.     DAD    D        ;INDEX ADDRESS
  493.     MOV    M,A        ;STORE IT
  494.     DAD    D
  495.     MOV    M,A
  496.     DAD    D
  497.     MOV    M,A
  498.     DAD    D
  499.     MOV    M,A
  500.     DAD    D
  501.     MOV    M,A
  502.     DAD    D
  503.     MOV    M,A
  504.     LXI    D,003FH        ;INDEX IN X AND Y DIRECTION
  505.     POP    H        ;GET OLD START ADDRESS
  506.     DAD    D        ;INDEX ADDRESS
  507.     MOV    M,A        ;STORE IT
  508.     DAD    D
  509.     MOV    M,A
  510.     DAD    D
  511.     MOV    M,A
  512.     DAD    D
  513.     MOV    M,A
  514.     DAD    D
  515.     MOV    M,A
  516.     DAD    D
  517.     MOV    M,A
  518.     LXI    D,041H        ;INDEX IN X AND Y DIRECTION
  519.     POP    H        ;GET OLD START ADDRESS
  520.     MOV    A,L
  521.     SUI    7
  522.     MOV    L,A
  523.     MVI    A,4
  524.     DAD    D        ;INDEX ADDRESS
  525.     MOV    M,A        ;STORE IT
  526.     DAD    D
  527.     MOV    M,A
  528.     DAD    D
  529.     MOV    M,A
  530.     DAD    D
  531.     MOV    M,A
  532.     DAD    D
  533.     MOV    M,A
  534.     DAD    D
  535.     MOV    M,A
  536.     RET
  537. ;
  538. WRITE2    MVI    E,HOME        ;GET CHARACTER TO CLEAR SCREEN
  539.     CALL    OUTCH        ;SEND IT
  540.     POP    H
  541.     MVI    A,4        ;CHARACTER FOR BUFFER
  542.     DB    0DDH
  543.     LXI    H,BUFFER    ;GET ADDRESS
  544.     LXI    D,0206H        ;GET OFFSET
  545.     DB    0DDH
  546.     DAD    D        ;ADD TO ADDRESS
  547.     DB    0DDH
  548.     MOV    M,A        ;STORE IT
  549.     DB    0FEH
  550.     DB    0DDH
  551.     MOV    M,A
  552.     DB    0FFH
  553.     DB    0DDH
  554.     MOV    M,A
  555.     DB    0
  556.     DB    0DDH
  557.     MOV    M,A        ;STORE IT
  558.     DB    40H
  559.     DB    0DDH
  560.     MOV    M,A        ;STORE IT
  561.     DB    7FH
  562.     LXI    D,0420H        ;GET OFFSET
  563.     DB    0DDH
  564.     DAD    D        ;ADD TO ADDRESS
  565.     DB    0DDH
  566.     MOV    M,A        ;STORE IT
  567.     DB    0FEH
  568.     DB    0DDH
  569.     MOV    M,A
  570.     DB    0BFH
  571.     DB    0DDH
  572.     MOV    M,A
  573.     DB    0
  574.     DB    0DDH
  575.     MOV    M,A        ;STORE IT
  576.     DB    40H
  577.     DB    0DDH
  578.     MOV    M,A        ;STORE IT
  579.     DB    0C0H
  580.     RET
  581. ;
  582. ;SUBROUTINE TO ACCEPT SCREEN DISPLAY FOR PATTERN
  583. ;
  584. START    MVI    H,12        ;LOAD INITIAL Y
  585.     MVI    L,25        ;LOAD INITIAL X
  586.     MVI    A,4        ;SET INTIAL DIRECTION
  587.     STA    DIR        ;STORE IT
  588.     PUSH    H        ;SAVE IT
  589. IF VT
  590.     JMP    RIGHT
  591. ENDIF
  592. START0    CALL    POSCUR        ;POSITION CURSOR
  593. START1    MVI    C,1        ;MODE- CONSOLE READ    
  594.     CALL    BDOS        ;GET CHARACTER
  595.     CPI    0DH        ;SEE IF CR
  596.     JZ    DONE        ;IS SO RETURN
  597.     CPI    03H        ;SEE IF ^C
  598.     JZ    STOP        ;IS SO STOP
  599.     CPI    04H        ;SEE IF RIGHT
  600.     JZ    RIGHT
  601.     CPI    05H        ;SEE IF UP
  602.     JZ    UP
  603.     CPI    013H        ;SEE IF LEFT
  604.     JZ    LEFT
  605.     CPI    018H        ;SEE IF DOWN
  606.     JZ    DOWN
  607.     CPI    0CH        ;SEE IF RIGHT
  608.     JZ    RIGHT
  609.     CPI    0BH        ;SEE IF UP
  610.     JZ    UP
  611.     CPI    08H        ;SEE IF LEFT
  612.     JZ    LEFT
  613.     CPI    0AH        ;SEE IF DOWN
  614.     JZ    DOWN
  615.     CPI    050H        ;SEE IF P
  616.     JZ    WRITE
  617.     CPI    046H        ;SEE IF F
  618.     JZ    WRITE2
  619.     JMP    START2        ;IF NOT
  620. UP    MVI    A,1        ;SET DIRERCTION MARKER
  621.     STA    DIR        ;STORE IT
  622.     POP    H        ;GET ADDRESS
  623.     MOV    A,H        ;MOVE Y
  624.     SUI    1        ;SUBTRACT 1
  625.     CPI    0FFH        ;SEE IF ZERO
  626.     JNZ    UP1
  627.     MVI    A,22        ;IF SO SET OTHER LIMIT
  628. UP1    MOV    H,A        ;MOVE BACK
  629.     PUSH    H        ;STORE IT
  630.     JMP    START0        ;POSITION CURSOR
  631. LEFT    MVI    A,2        ;SET DIRERCTION MARKER
  632.     STA    DIR        ;STORE IT
  633.     POP    H
  634.     MOV    A,L
  635.     SUI    1
  636.     CPI    0FFH        ;SEE IF ZERO
  637.     JNZ    LEFT1
  638.     MVI    A,78
  639. LEFT1    MOV    L,A
  640.     PUSH    H
  641.     JMP    START0
  642. RIGHT    MVI    A,4        ;SET DIRERCTION MARKER
  643.     STA    DIR        ;STORE IT
  644.     POP    H
  645.     INR    L
  646.     MOV    A,L
  647.     CPI    79        ;SEE IF ZERO
  648.     JNZ    RIGHT1
  649.     MVI    L,0
  650. RIGHT1    PUSH    H
  651.     JMP    START0
  652. DOWN    MVI    A,8        ;SET DIRERCTION MARKER
  653.     STA    DIR        ;STORE IT
  654.     POP    H
  655.     INR    H
  656.     MOV    A,H
  657.     CPI    23        ;SEE IF ZERO
  658.     JNZ    DOWN1
  659.     MVI    H,0
  660. DOWN1    PUSH    H
  661.     JMP    START0
  662. START2    CPI    020H        ;SEE IF SPACE
  663.     JNZ    ST2        ;IF NOT GO ON
  664.     MVI    E,' '        ;SET CHR TO SPACE
  665.     JMP    ST3        ;GO ON
  666. ST2    MVI    E,'*'        ;SET DOT
  667. ST3    POP    H        ;GET ADDRESS
  668.     PUSH    H        ;STORE IT
  669.     PUSH    D        ;SAVE CHR WRITTEN
  670. IF VT
  671.     DCR    H    ;MARK
  672. ENDIF
  673.     CALL    POSCHR        ;PRINT CHARACTER
  674.     POP    D        ;GET CHARACTER
  675.     POP    H        ;GET ADDRESS
  676.     PUSH    H        ;SAVE IT
  677.     MOV    A,H
  678.     RAR            ;SHIFT RIGHT
  679.     JNC    START3        ;IF CLEAR GO ON
  680.     DB    0CBH    ;SET    ;IF NOT SET BIT
  681.     DB    0F5H    ;6,L
  682. START3    RAR            ;SHIFT RIGHT
  683.     JNC    START4        ;IF CLEAR GO ON
  684.     DB    0CBH    ;SET    ;IF NOT SET BIT
  685.     DB    0FDH    ;7,L
  686. START4    ANI    03FH        ;CLEAR UPPER BITS
  687.     MOV    H,A        ;SAVE Y LOCATION
  688.     LXI    B,BUFFER    ;FIND OFFSET
  689.     DAD    B        ;ADD TO ADDRESS
  690.     MOV    A,E        ;GET CHR
  691.     CPI    ' '        ;CAMPARE TO SPACE
  692.     JNZ    ST4        ;IF NOT    GO ON
  693.     MVI    A,0        ;IF SO CLEAR
  694.     JMP    ST5        ;GO ON
  695. ST4    MVI    A,4        ;IF NOT SPACE MARK LOCATION
  696. ST5    MOV    M,A        ;STORE IN BUFFER
  697.     LDA    DIR        ;RECALL DIR
  698.     CPI    1        ;CHECK UP
  699.     JZ    UP
  700.     CPI    2        ;CHECK LEFT
  701.     JZ    LEFT
  702.     CPI    4        ;CHECK RIGHT
  703.     JZ    RIGHT
  704.     CPI    8        ;CHECK DOWN
  705.     JZ    DOWN
  706.     JMP    START1
  707. DONE    POP    H        ;CLEAR STACK
  708.     RET            ;RETURN
  709. ;
  710. DIR    DS    1
  711. ;
  712. ;SUBROUTINE TO DECODE NUMBERS INTO ASCII
  713. ;NUMBER SENT IN REGISTER PAIR B,C
  714. ;ASCII RETURNED IN B,C,D,E
  715. DECODE    MOV    A,C        ;GET LOWEST NIBBLE
  716.     ANI    0FH        ;CLEAR ACCUMULATOR
  717.     ADI    30H        ;MAKE ASCII
  718.     CPI    3AH        ;SEE IF GREATER THEN 9
  719.     JM    D1        ;IF NOT GO ON
  720.     ADI    7        ;INCREMENT TO LETTER
  721. D1    MOV    E,A        ;SAVE LOWEST NIBBLE
  722.     MOV    A,C        ;GET NEXT NIBBLE
  723.     RAR            ;SHIFT OVER
  724.     RAR
  725.     RAR
  726.     RAR
  727.     ANI    0FH
  728.     ADI    30H
  729.     CPI    3AH
  730.     JM    D2
  731.     ADI    7
  732. D2    MOV    D,A
  733.     MOV    A,B        ;GET LOWEST NIBBLE UPPER BYTE
  734.     ANI    0FH
  735.     ADI    30H
  736.     CPI    3AH
  737.     JM    D3
  738.     ADI    7
  739. D3    MOV    C,A
  740.     MOV    A,B        ;GET HIGHEST BYTE
  741.     RAR
  742.     RAR
  743.     RAR
  744.     RAR
  745.     ANI    0FH
  746.     ADI    30H
  747.     CPI    3AH
  748.     JM    D4
  749.     ADI    7
  750. D4    MOV    B,A
  751.     RET
  752. ;
  753. OLDSP    DS    2
  754.     DS    30
  755. STACK    DS    2
  756.  
  757. ;
  758. ;PRINT BUFFER
  759. ;
  760. NAME    DB    0DH,0AH
  761.     DB    'LIFE R.A.R ver 1.61 5/10/84'
  762.     DB    0DH,0AH,'$'
  763. STRING
  764. IF VT
  765.     DB    1BH            
  766.     DB    '[24;0H'        
  767. ENDIF
  768.     DB    '       GENERATION: '
  769. GENN    DB    '    '
  770.     DB    '     POPULATION: '
  771. POPN    DB    '    '
  772. STREND    DB    '$'
  773. IF VT
  774. STRING2    DB    1BH            
  775.     DB    '[24;00H?'        
  776.     DB    '$'            
  777. STRING3    DB    1BH            
  778.     DB    '[24;00H'        
  779.     DB    '$'            
  780. ENDIF
  781. ;
  782. BUFFER    DS    2000H
  783. BUFEND    DS    2
  784. END
  785. END
  786.