home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / MBUG / MBUG115.ARC / MXSET23.MAC < prev    next >
Text File  |  1979-12-31  |  27KB  |  1,307 lines
  1. ;MXSET  Ver 2.3  19 May 84
  2. ;**********************************************************
  3. ;
  4. ;This program will set/reset all of the major functions of the
  5. ;Epson MX80 or MX-100 printer with or without Graftrax
  6. ;The program uses Z80 Zilog mnemonics and calls are made to 
  7. ;Richard Conn's excellent SYSLIB.REL file. 
  8. ;Microsoft's M80 macro assembler is needed 
  9. ;
  10. ;***********************************************************
  11. ;
  12. ;Note - sub menu A, 0/1 options correct?
  13. ; grafics
  14. ;Rev  2.3  19 May 84   Frans Van Duinen
  15. ;  modified for 8080 compatibility
  16. ;  added hex keypad to printer function
  17. ;  in typewriter & keypad functions maintain condensed
  18. ;   mode across CR/LF
  19. ;
  20. ;Rev  2.2  21 April 84   Frans Van Duinen
  21. ;  and some more bugs
  22. ;
  23. ;Rev  2.2  21 April 84   Frans Van Duinen
  24. ;  fixed some bugs introduced with ver 2.1
  25. ;  capability to run under WS
  26. ;
  27. ;Rev  2.1  20 April 84   Frans Van Duinen, Toronto
  28. ;  set up for MX80 or 100 with or without Graftrax,
  29. ;  cleaned up coding
  30. ; 
  31. ;Rev  2.0  16 April 84   David C. Naylor, Halton Hills
  32. ;  set up for MX100 without graftrax 
  33. ;
  34. ;Rev. 1.2 by Simon J. Ewins, Toronto, Ontario, Canada.
  35. ; June 28, 1983.   Toronto, Ontario.
  36. ;
  37. ;
  38. ; Legend:
  39. ;
  40. ;  <DE> - refers to content of registers, e.g. <A>
  41. ;   DE> - refers to memory location pointed to be register pair
  42. ;   <>  - not equal
  43. ;
  44. ; SYSLIB functions used
  45.     EXTRN    BBLINE        ;Get input line, returns HL>line
  46. ;                 <A> count; on input <A><>0 - capitalize
  47.     EXTRN    EVAL10        ;Convert decimal number at HL> to binary
  48. ;                 returns <DE> number, HL> next char
  49. ;                 handling of nos>65535 unknown
  50. ;                 returns zero if no valid digits
  51. ;
  52. ;Note that CIN, COUT PRINT CCOUT are not compatible with WS
  53. ;
  54. ;Conditional assembly
  55. ;
  56. FALSE    EQU    0
  57. TRUE    EQU    NOT FALSE
  58. ;
  59. MX100    EQU    TRUE    ;Set true if using wider printer
  60. GTRAX    EQU    FALSE    ;Set true if printer graftrax equiped
  61. ;
  62. ;
  63. ; Equated symbols
  64. BELL    EQU    07    ;Bell
  65. BS    EQU    08    ;Backspace
  66. LF    EQU    0AH    ;Linefeed
  67. FF    EQU    0CH    ;Formfeed
  68. CR    EQU    0DH    ;Carriage return
  69. SO    EQU    0EH    ;Turn on double width
  70. SI    EQU    0FH    ;Shift in (activates compressed)
  71. DC2    EQU    12H    ;Turn off compressed
  72. DC4    EQU    14H    ;Turn off double width
  73. EOF    EQU    1AH    ;End of file (^Z)
  74. ESC    EQU    1BH    ;Escape char
  75. ;
  76. OFF    EQU    0    ;Off flag
  77. ON    EQU    1    ;On flag for printer
  78. ;
  79. ;
  80. BDOS    EQU    5    ;Entry for BDOS
  81. ;
  82.     IF    MX100
  83. ;
  84. ; MX100 related values
  85. ;
  86. MAXWDTH    EQU    233    ;Max page width
  87. MAXGMED    EQU    816    ;Max no of dots - med graphics
  88. MAXGHI    EQU    1632    ;Max no of dots - hi graphics
  89. ;
  90.     ELSE
  91. ;
  92. ; MX80  related values
  93. ;
  94. MAXWDTH    EQU    132    ;Max page width
  95. MAXGMED    EQU    480    ;Max no of dots - med graphics
  96. MAXGHI    EQU    960    ;Max no of dots - hi graphics
  97. ;
  98.     ENDIF
  99. ;
  100. ;Techniques:
  101. ;
  102. ;Note the sequence 
  103. ;    CALL LPRINT
  104. ;    DB   ESC,...,0
  105. ;
  106. ; The routine LPRINT never returns control. 
  107. ; instead it exits to label START, a call is used
  108. ; to pass the return address as the addr of the string
  109. ; to print. String must terminate on 00H
  110. ;
  111. ;
  112. ;Note that the sequence 
  113. ;    CALL RPRINT
  114. ;    DB   ESC,...,0
  115. ;
  116. ; does return control
  117. ;
  118. ;
  119.     .Z80
  120.     CSEG
  121. ;
  122.     JP    START        ;Skip subrtn
  123. CLR:
  124.     DB    FF,0,0,0,0,0,0    ;Clear screen & home cursor
  125. ;                Set to sequence for your computer:
  126. ;                Osborne    - 1AH,0
  127. ;                Televideo  - 1AH,0
  128. ;                Superbrain -  FF,0
  129. ;                Heath      - ESC,'E',0
  130. ;                If not wanted set to CR,LF,LF,LF...
  131. ;
  132. ; Constants & Workfields
  133. ;
  134. ;
  135. OPTIONS: DB    0        ;Printer options activated in this session
  136. ;                ; 0 - Condensed  
  137. ;                ;  is used for typewriter function
  138. ;                ;  set/reset by condensed on/off & reset  
  139. ;
  140. START:
  141.     CALL    CPRINT        ;Cls & display
  142.     DB    'EPSON SET-UP ver 2.2',CR,LF
  143. ;
  144.     IF    MX100
  145. ;
  146.     DB    'For MX100 '
  147. ;
  148.     ELSE
  149. ;
  150.     DB    'For MX80 '
  151. ;
  152.     ENDIF
  153. ;
  154.     IF    GTRAX
  155. ;
  156.     DB    'with Graftrax '
  157. ;
  158.     ELSE
  159. ;
  160.     DB    'without Graftrax '
  161. ;
  162.     ENDIF
  163. ;
  164.     DB    CR,LF
  165.     DB    'OPTIONS:',CR,LF
  166.     DB    'A: Select character font',CR,LF
  167. ;
  168.     IF    GTRAX
  169. ;
  170.     DB    'B: Reset printer to defaults',CR,LF
  171. ;
  172.     ELSE
  173. ;
  174.     DB    'B: Select character set',CR,LF
  175. ;
  176.     ENDIF
  177. ;
  178.     DB    'C: Set line spacing',CR,LF
  179.     DB    'D: Set page size',CR,LF
  180. ;
  181.     IF    GTRAX
  182. ;
  183.     DB    'E: Set uni-directional print ON/OFF',CR,LF
  184. ;
  185.     ELSE
  186. ;
  187.     DB    'E: Set vertical tabs',CR,LF
  188. ;
  189.     ENDIF
  190. ;
  191.     DB    'F: Set horizontal tabs',CR,LF
  192.     DB    'G: Set to top of form (FF)',CR,LF
  193.     DB    'H: Turn ON perforation skip',CR,LF
  194.     DB    'I: Turn OFF perforation skip',CR,LF
  195.     DB    'J: Enable out of paper signal',CR,LF
  196.     DB    'K: Disable out of paper signal',CR,LF
  197.     DB    'L: Set graphics mode',CR,LF
  198.     DB    'M: Print test',CR,LF
  199. ;
  200.     IF    GTRAX
  201. ;
  202.     DB    'N: Set bit 8 handling',CR,LF
  203.     DB    'O: Home printhead',CR,LF
  204. ;
  205.     ENDIF
  206. ;
  207.     DB    'X: Hex keypad to printer',CR,LF 
  208.     DB    'Z: Keyboard to printer',CR,LF 
  209.     DB    '^C: Quit to CP/M',CR,LF,LF,0
  210.     CALL    CHOICE        ;Complete menu, get input
  211. ;
  212.     CP    'A'
  213.     JP    Z,LA        ;Select type font
  214.     CP    'B'
  215.     JP    Z,LB        ;Select character set/reset printer
  216.     CP    'C'
  217.     JP    Z,LC        ;Set line spacing 
  218.     CP    'D'
  219.     JP    Z,LD        ;Set page size
  220.     CP    'E'
  221.     JP    Z,LE        ;Set vertical tabs/reset
  222.     CP    'F'
  223.     JP    Z,LBLF        ;Set horizontal tabs
  224.     CP    'G'
  225.     JP    Z,LG        ;Force formfeed
  226.     CP    'H'
  227.     JP    Z,LH        ;Set perf skip on
  228.     CP    'I'
  229.     JP    Z,LI        ;Set perf skip off
  230.     CP    'J'
  231.     JP    Z,LJ        ;Enable paper-out detector (signal only)
  232.     CP    'K'
  233.     JP    Z,LK        ;Disable paper-out detector
  234.     CP    'L'
  235.     JP    Z,LL        ;Set graphics
  236.     CP    'M'
  237.     JP    Z,LM        ;Print test
  238. ;
  239.     IF    GTRAX
  240. ;
  241.     CP    'N'
  242.     JP    Z,LN        ;Handling of h/o bit
  243.     CP    'O'
  244.     JP    Z,LO        ;Home print head
  245. ;
  246.     ENDIF
  247. ;
  248.     CP    'X'
  249.     JP    Z,LX        ;Hex keypad to printer
  250.     CP    'Z'
  251.     JP    Z,LZ        ;Keyboard to printer
  252. ;
  253. ;            Invalid response
  254. ERROR:
  255.     CALL    PRINT
  256.     DB    BELL,0
  257.     JP    START
  258. ;
  259. ;
  260. ;
  261. ;            Select font
  262. LA:
  263.     CALL    CPRINT        ;Cls & display
  264.     DB    CR,LF,LF
  265.     DB    '1:  Set condensed ON',CR,LF
  266.     DB    '2:  Set condensed OFF',CR,LF
  267.     DB    '3:  Set enlarged ON',CR,LF
  268.     DB    '4:  Set enlarged OFF',CR,LF
  269.     DB    '5:  Set emphasized ON',CR,LF
  270.     DB    '6:  Set emphasized OFF',CR,LF
  271. ;
  272.     IF    GTRAX
  273. ;
  274.     DB    '7:  Set Italics ON',CR,LF
  275.     DB    '8:  Set Italics OFF',CR,LF
  276.     DB    '9:  Set double strike ON',CR,LF
  277.     DB    '10: Set double strike OFF',CR,LF
  278.     DB    '11: Set to subscript',CR,LF
  279.     DB    '12: Set to superscript',CR,LF
  280.     DB    '13: Set super/subscript OFF',CR,LF
  281.     DB    '14: Set permanent enlarged ON',CR,LF
  282.     DB    '15: Set permanent enlarged OFF',CR,LF
  283. ;
  284.     ENDIF
  285. ;
  286.     DB    LF,0        ;Extra LF & terminating null
  287. ;
  288.     CALL    CHOICE        ;Get response 
  289.     LD    B,1        ;Set minimum
  290. ;
  291.     IF    GTRAX
  292. ;
  293.     LD    C,16        ;Get max+1
  294. ;
  295.     ELSE
  296. ;
  297.     LD    C,7        ;Get max+1
  298. ;
  299.     ENDIF
  300. ;
  301.     CALL    NUMBER
  302.     CP    1        ;Test flag
  303.     JP    Z,START        ;Get out on thru
  304.     JP    NC,LA        ;Out of range
  305. ;    CP    2        ;Condensed on/off? 
  306.     JP    Z,CONDOFF    ;Yes -
  307.     JP    NC,NOCOND    ;No -
  308.     LD    C,80H        ;Yes - set flag
  309.     CALL    SETOPT
  310.     JP    NOCOND
  311. CONDOFF:
  312.     LD    C,7FH        ;Set flag off
  313.     CALL    RESOPT        ;Reset option flag
  314. NOCOND:
  315. ;
  316. ;                 Note that different selections
  317. ;                 have differing formats:
  318. ;                 1 - SI  - no ESC
  319. ;                 2 - DC2 - no ESC
  320. ;                 3 - SO  - no ESC
  321. ;                 4 - DC4 - no ESC
  322. ;                 5 - ESC,'E' 
  323. ;                 6 - ESC,'F'
  324. ;                 7 - ESC,'4'
  325. ;                 8 - ESC,'5'
  326. ;                 9 - ESC,'G'
  327. ;                10 - ESC,'H'
  328. ;                11 - ESC,'S',OFF
  329. ;                12 - ESC,'S',ON
  330. ;                13 - ESC,'T'
  331. ;                14 - ESC,'W',ON
  332. ;                15 - ESC,'W',OFF
  333. ;
  334.     LD    A,E        ;Get index
  335.     LD    HL,ATABL-1    ;Index table (offset for ascii char index)
  336.      ADD    A,L        ;Combine with index char
  337.     JP    NC,LA1        ;No carry to high byte
  338.     INC    H
  339. LA1:
  340.     LD    L,A        ;Complete index
  341. ;
  342.  
  343.     LD    A,(HL)        ;Get byte at HL>
  344.     PUSH    AF        ; & save
  345.     LD    A,E        ;Get selection back
  346.     CP    5
  347.     JP    C,LA2        ; 1-4 no ESC
  348.     LD    A,ESC
  349.     CALL    LOUT
  350. LA2:
  351.     POP    AF
  352.     CALL    LOUT        ;Byte from table
  353. ;
  354. ;
  355.     IF    GTRAX
  356. ;
  357.     LD    A,11
  358.     SUB    E        ;Normalize '11' & '12' to 0 & 1
  359.     CP    2        ;Is this option 11 or 12?
  360.     JP    C,LA3        ;Yes - put normalized
  361.     OR    A        ;Was this #1 - #10 (positive now)
  362.     JP    P,START        ;Yes - get out
  363.     CP    255        ;No - was it #13 
  364.     JP    Z,START        ;Yes - is complete
  365.     ADD    A,4        ;No - adjust 14 - 15 to 1 - 0
  366. LA3:
  367.     CALL    LOUT        ;Output 0 (option 11/14) or 1 (12/15)
  368. ;
  369.     ENDIF 
  370. ;
  371.     JP    START
  372. ;
  373. ;
  374. ATABL:    DB    SI,DC2        ;Condensed on/off - no ESC
  375.     DB    SO,DC4        ;Enlarged (double width) on/off - no ESC
  376.     DB    'E','F'        ;Emphasized on/off 
  377. ;
  378.     IF    GTRAX
  379. ;
  380.     DB    '4','5'        ;Italics on/off
  381.     DB    'G','H'        ;Double strike on/off
  382.     DB    'S','S'        ;Super/subscr - with ESC & 1,0
  383.     DB    'T'        ;Super/sub off - with Esc
  384.     DB    'W','W'        ;Double width on/off - With ESC & 1,0
  385. ;
  386.     ENDIF
  387. ;
  388. ;
  389. ;
  390. LB:
  391. ;
  392.     IF    GTRAX
  393. ;            Reset printer to default
  394.     LD    C,0        ;Reset options
  395.     CALL    RESOPT
  396. ;
  397.     CALL    LPRINT        ;Print & exit
  398.     DB    ESC,'@',0
  399. ;
  400. ;
  401.     ELSE
  402. ;
  403.                 ;Select character set
  404.     CALL    CPRINT        ;Cls & display
  405.     DB    CR,LF,LF
  406.     DB    '1:  North American',CR,LF
  407.     DB    '2:  British',CR,LF
  408.     DB    '3:  French',CR,LF
  409.     DB    '4:  German',CR,LF
  410.     DB    '5:  Spanish',CR,LF
  411.     DB    '6:  Italian',CR,LF
  412.     DB    '7:  Danish',CR,LF
  413.     DB    '8:  Swedish',CR,LF,LF,0
  414. ;
  415.     CALL    CHOICE        ;Get response
  416.     LD    B,1        ;Set minimum
  417.     LD    C,9        ; & max+1
  418.     CALL    NUMBER
  419.     CP    1        ;Test flag
  420.     JP    Z,START        ;Get out on thru
  421.     JP    NC,LB        ;Out of range
  422.     LD    A,E        ;Get index
  423.     LD    HL,BTABL-1    ;Index table (offset for ascii char index)
  424.      ADD    A,L        ;Combine with index char
  425.     JP    NC,LB1        ;No carry to high byte
  426.     INC    H
  427. LB1:    
  428.     LD    L,A        ;Complete index
  429. ;
  430.     CALL    RPRINT
  431.     DB    ESC,'R',0    ;Put out 1st part
  432.     LD    A,(HL)        ;Get language/ char set code
  433.     CALL    LOUT        ;May be zero
  434.     JP    START
  435. ;
  436. ;
  437. ;
  438. BTABL:    DB    0        ;North American
  439.     DB    3        ;British
  440.     DB    1        ;French
  441.     DB    2        ;German
  442.     DB    7        ;Spanish
  443.     DB    6        ;Italian
  444.     DB    4        ;Danish
  445.     DB    5        ;Swedish
  446. ;
  447. ;
  448.     ENDIF
  449. ;
  450. ;
  451. ;
  452. LC:            ;Set line spacing
  453.     CALL    CPRINT        ;Cls & display
  454.     DB    '1: Select 6 lines per inch',CR,LF
  455.     DB    '2: Select 8 lines per inch',CR,LF
  456.     DB    '3: Set line spacing in 1/72" increments',CR,LF
  457. ;
  458.     IF    GTRAX
  459. ;
  460.     DB    '4: Set line spacing in 1/216" increments',CR,LF
  461. ;
  462.     ENDIF
  463. ;
  464.     DB    LF,0        ;Mark end of string
  465. ;
  466.     CALL    CHOICE        ;Get input
  467.     LD    B,1        ;Set minimum
  468. ;
  469.     IF    GTRAX
  470. ;
  471.     LD    C,5        ; & max+1
  472. ;
  473.     ELSE
  474. ;
  475.     LD    C,4        ; & max+1
  476. ;
  477.     ENDIF
  478. ;
  479.     CALL    NUMBER
  480.     CP    1        ;Test flag
  481.     JP    Z,START        ;Get out on thru
  482.     JP    NC,LC        ;Out of range
  483.     LD    A,E        ;Get index
  484.     CP    2        ;Which one?
  485.     JP    Z,LC2        ;#2
  486.     JP    NC,LC3        ;#3 (or 4 if GTRAX)
  487. ;
  488.             ;Select 6 lines per inch
  489.     CALL    LPRINT        ;Print & exit
  490.     DB    ESC,'2',0    ;Set 6 lines/inch
  491. ;
  492. ;
  493. LC2:            ;Select 8 lines per inch
  494.     CALL    LPRINT        ;Print & exit
  495.     DB    ESC,'0',0    ;Set 8 lines/inch
  496. ;
  497. ;
  498. LC3:            ;Set variable line spacing
  499. ;
  500.     IF    GTRAX
  501. ;
  502.     CP    4        ;Item 4 (1/216)    
  503.     JP    NZ,LC5        ;No -
  504. ;
  505. LC4:
  506.     CALL    PRINT
  507.     DB    CR,LF,LF,'Enter quantity of 1/216 inches (max 85): ',CR,LF
  508.     DB    '---> ? ',0
  509. ;
  510.     LD    A,0        ;No capitals reqd
  511.     CALL    BBLINE        ;Get input line
  512.     LD    B,1        ;Set minimum
  513.     LD    C,0        ; & max+1 (256)
  514.     CALL    NUMBER
  515.     CP    1        ;Test flag
  516.     JP    Z,START        ;Get out on thru
  517.     JP    NC,LC4        ;Out of range
  518.     LD    A,E        ;Get index
  519.     LD    (LC42),A
  520.     CALL    LPRINT        ;Print & exit
  521.     DB    ESC,'3'        ;Set spacing in 1/216" increments
  522. LC42:    DB    1,0
  523. ;
  524. ;
  525. ;
  526.     ENDIF
  527. ;
  528. LC5:
  529.     CALL    PRINT
  530.     DB    CR,LF,LF,'Enter quantity of 1/72 inches (max 85): ',CR,LF
  531.     DB    '---> ? ',0
  532. ;
  533.     LD    A,0        ;No capitals reqd
  534.     CALL    BBLINE        ;Get input line
  535.     LD    B,1        ;Set minimum
  536.     LD    C,86        ; & max+1
  537.     CALL    NUMBER
  538.     CP    1        ;Test flag
  539.     JP    Z,START        ;Get out on thru
  540.     JP    NC,LC5        ;Out of range
  541.     LD    A,E        ;Get index
  542.     LD    (LC52),A
  543.     CALL    LPRINT        ;Print & exit
  544.     DB    ESC,'A'        ;Set LF spacing in 1/72" increments
  545. LC52:    DB    1,0
  546. ;
  547. ;
  548. LD:            ;Set page dimensions
  549.     CALL    CPRINT        ;Cls & display
  550.     DB    '1: Set form length in lines',CR,LF
  551.     DB    '2: Set form length in inches',CR,LF
  552.     DB    '3: Set width',CR,LF,0
  553. ;
  554.     CALL    CHOICE
  555.     LD    B,1        ;Set minimum
  556.     LD    C,4        ; & max+1
  557.     CALL    NUMBER
  558.     CP    1        ;Test flag
  559.     JP    Z,START        ;Get out on thru
  560.     JP    NC,LD        ;Out of range
  561.     LD    A,E        ;Get index
  562.     CP    2        ;Which one?
  563.     JP    NC,LD3        ;#3
  564.     JP    Z,LD2        ;#2
  565. ;
  566.             ;Set page length in lines
  567. LD1:
  568.     CALL    PRINT
  569.     DB    CR,LF,LF,'Enter length in lines (max 127): ',CR,LF
  570.     DB    '---> ? ',0
  571. ;
  572.     LD    A,0
  573.     CALL    BBLINE
  574.     LD    B,1        ;Set minimum
  575.     LD    C,128        ; & max+1
  576.     CALL    NUMBER
  577.     CP    1        ;Test flag
  578.     JP    Z,START        ;Get out on thru
  579.     JP    NC,LD1        ;Out of range
  580.     LD    A,E        ;Get index
  581.     LD    (LD12),A
  582.     CALL    LPRINT        ;Print & exit
  583.     DB    ESC,'C'
  584. LD12:    DB    1,0
  585. ;
  586. ;
  587. ;
  588. LD2:            ;Set page length in inch increments
  589.     CALL    PRINT
  590.     DB    CR,LF,LF,'Enter length in inches (max 22): ',CR,LF
  591.     DB    '---> ? ',0
  592. ;
  593.     LD    A,0
  594.     CALL    BBLINE
  595.     LD    B,1        ;Set minimum
  596.     LD    C,23        ; & max+1
  597.     CALL    NUMBER
  598.     CP    1        ;Test flag
  599.     JP    Z,START        ;Get out on thru
  600.     JP    NC,LD2        ;Out of range
  601.     LD    A,E        ;Get index
  602.     LD    (LD22),A
  603. ;
  604.     CALL    RPRINT
  605.     DB    ESC,'C',0
  606.     XOR    A        ;Force null
  607.     CALL    LOUT        ; & put
  608. ;
  609.     CALL    LPRINT        ;Print & exit
  610. LD22:    DB    1,0
  611. ;
  612. ;
  613. LD3:            ;Set page width
  614.     CALL    PRINT
  615.     DB    CR,LF,LF,'Enter width: ',CR,LF
  616. ;
  617.     IF    MX100
  618. ;
  619.     DB    'Up to 136 in normal or emphasized mode.',CR,LF
  620.     DB    '      233 in condensed mode.',CR,LF
  621.     DB    '       68 in enlarged mode.',CR,LF
  622.     DB    '      116 in enlarged-condensed mode',CR,LF
  623. ;
  624.     ELSE
  625. ;
  626.     DB    'Up to  80 in normal or emphasized mode.',CR,LF
  627.     DB    '      132 in condensed mode.',CR,LF
  628.     DB    '       40 in enlarged mode.',CR,LF
  629.     DB    '       60 in enlarged-condensed mode',CR,LF
  630. ;
  631.     ENDIF
  632. ;
  633.  
  634.  
  635.     DB    '---> ? ',0
  636. ;
  637.     LD    A,0
  638.     CALL    BBLINE
  639.     LD    B,1        ;Set minimum
  640.     LD    C,MAXWDTH+1    ; & max+1
  641.     CALL    NUMBER
  642.     CP    1        ;Test flag
  643.     JP    Z,START        ;Get out on thru
  644.     JP    NC,LD3        ;Out of range
  645.     LD    A,E        ;Get index
  646.     LD    (LD32),A
  647.     CALL    LPRINT        ;Print & exit
  648.     DB    ESC,'Q'
  649. LD32:    DB    1,0
  650. ;
  651. ;
  652. ;
  653. ;
  654. ;
  655. LE:
  656. ;
  657.     IF    GTRAX
  658. ;
  659. ;            Set uni-directional print on/off
  660.     CALL    CPRINT        ;Cls & display
  661.     DB    '1:  Set uni-directional print ON',CR,LF
  662.     DB    '2:  Set uni-directional print OFF',CR,LF,0
  663. ;
  664.     CALL    CHOICE        ;Ask & get input
  665.     LD    B,1        ;Set minimum
  666.     LD    C,3        ; & max+1
  667.     CALL    NUMBER
  668.     CP    1        ;Test flag
  669.     JP    Z,START        ;Get out on thru
  670.     JP    NC,LE        ;Out of range
  671.     CALL    RPRINT
  672.     DB    ESC,'U',0
  673.     LD    A,2        ;Convert index to 1/0 flag
  674.     SUB    E        ;1 now 1; 2 now 0
  675.     CALL    LOUT
  676.     JP    START
  677. ;
  678. ;
  679.     ELSE
  680. ;
  681. ;            ;Set vertical tabs
  682.     CALL    CPRINT        ;Cls & display
  683.     DB    CR,LF,LF,'Enter vertical tab positions (max 8)',CR,LF
  684.     DB    '(in ascending order) ---> ? ',0
  685. ;
  686.     LD    A,0
  687.     CALL    BBLINE        ;Get line of tabs, terminated by 00h
  688.     LD    DE,VTABS    ;Set to tab list
  689.     LD    A,1        ;Set minimum tab
  690.     LD    (DE),A        ;Prime tab list
  691.     LD    C,128        ;Set max tab+1 (we dont know page len)    
  692.     LD    B,8        ;Set loop count
  693.     CALL    TABS        ;Handle tabs, returns flag in <A>
  694.     OR    A        ;OK?
  695.     JP    Z,LE2        ;Yes
  696.     DEC    A        ;No - exit?
  697.     JP    Z,START        ;Yes -
  698.     JP    LE        ;No - ask new input
  699. ;
  700. ;            Output tab string
  701. LE2:
  702.     LD    HL,VTABS-2    ;Set to string to put
  703.     JP    HTBS2        ; & go put
  704. ;
  705. ;
  706. ;
  707.     DB    ESC,'B'        ;Vertical tabs
  708. VTABS:    DB    1,0,0,0,0,0,0,0,0  ;8 tabs & null
  709. ;
  710. ;
  711. ;
  712.     ENDIF
  713. ;
  714. ;
  715. LBLF:            ;Set horizontal tabs
  716.     CALL    CPRINT        ;Cls & display
  717.     DB    CR,LF,LF,'Enter horizontal tab positions (max 12)',CR,LF
  718.     DB    '(in ascending order) ---> ? ',0
  719. ;
  720.     LD    A,0
  721.     CALL    BBLINE
  722.     LD    DE,HTABS    ;Set to tab list
  723.     LD    A,1        ;Set minimum tab
  724.     LD    (DE),A        ;Prime tab list
  725.     LD    C,MAXWDTH+1    ;Set max tab+1 (we dont know page width)
  726.     LD    B,12        ;Set loop count
  727.     CALL    TABS        ;Handle tabs, returns flag in <A>
  728.     OR    A        ;OK?
  729.     JP    Z,LBLF2        ;Yes
  730.     DEC    A        ;No - exit?
  731.     JP    Z,START        ;Yes -
  732.     JP    LBLF        ;No - ask new input
  733. ;
  734. ;            Output tab string
  735. LBLF2:
  736.     LD    HL,HTABS-2    ;Set to string to put
  737. HTBS2:
  738.     CALL    LPR        ;Put string at HR>
  739. ;                 Is safer than RPRINT due to variable len
  740. ;                 past null may be garbage
  741.     XOR    A        ;Force null after tabs
  742.     CALL    LOUT
  743.     JP    START
  744. ;
  745. ;
  746.     DB    ESC,'D'
  747. HTABS:    DB    1,0,0,0,0,0,0,0,0,0,0,0,0  ; 12 tabs & null
  748. ;
  749. ;
  750. ;
  751. LG:            ;Set top of form (FF)
  752.     CALL    LPRINT        ;Print & exit
  753.     DB    FF,0        ;Output formfeed
  754. ;
  755. ;
  756. LH:            ;Turn on perf. skip-over
  757.     CALL    CPRINT        ;Cls & display
  758.     DB    CR,LF,LF
  759.     DB    'Enter no of lines to skip over perforation'
  760.     DB    ' (max 127)',CR,LF
  761.     DB    '---> ? ',0
  762. ;
  763.     LD    A,0
  764.     CALL    BBLINE
  765.     LD    B,1        ;Set minimum
  766.     LD    C,128        ; & max+1
  767.     CALL    NUMBER
  768.     CP    1        ;Test flag
  769.     JP    Z,START        ;Get out on thru
  770.     JP    NC,LH        ;Out of range
  771.     LD    A,E        ;Get index
  772.     LD    (LH2),A
  773.     CALL    LPRINT        ;Print & exit
  774.     DB    ESC,'N'
  775. LH2:    DB    0,0        ;Skip n lines
  776. ;
  777. ;
  778. ;
  779. LI:            ;Turn off perf. skip-over
  780.     CALL    LPRINT        ;Print & exit
  781.     DB    ESC,'O',0
  782. ;
  783. ;
  784. ;
  785. LJ:            ;Enable paper-out signal
  786.     CALL    LPRINT        ;Print & exit
  787.     DB    ESC,'9',0
  788. ;
  789. ;
  790. ;
  791. LK:            ;Disable paper-out signal
  792.     CALL    LPRINT        ;Print & exit
  793.     DB    ESC,'8',0    ;Disable paper-out sensor
  794. ;
  795. ;
  796. ;
  797. LL:            ;Set graphics 
  798. ; Note that non-graftrax also supports graphics
  799. ; 
  800.     CALL    CPRINT        ;Cls & display
  801.     DB    '1:  Set medium density graphics',CR,LF
  802.     DB    '2:  Set high density graphics',CR,LF,0
  803. ;
  804.     CALL    CHOICE        ;Ask & get input
  805.     LD    B,1        ;Set minimum
  806.     LD    C,3        ; & max+1
  807.     CALL    NUMBER
  808.     CP    1        ;Test flag
  809.     JP    Z,START        ;Get out on thru
  810.     JP    NC,LL        ;Out of range
  811.     LD    A,E        ;Get index
  812.     CP    1        ;Medium density?
  813.     JP    NZ,LL2        ;No - high
  814. ;
  815. ;            Set medium density
  816. LL1:
  817.     LD    HL,MAXGMED    ;Set max no acceptable
  818.     CALL    GETBITS        ;Get no of bits 
  819.     CP    1        ;Test flag
  820.     JP    Z,START        ;Get out on thru
  821.     JP    NC,LL1        ;Out of range
  822.     LD    (LL12),HL    ;Save wanted no bits
  823.     CALL    LPRINT        ;Print & exit
  824.     DB    ESC,'K'
  825. ;
  826. ;
  827. LL12:    DB    0,0,0
  828. ;
  829. ;
  830. ;
  831. LL2:            ;Set graphics - high density
  832.     LD    HL,MAXGHI    ;Set max no acceptable
  833.     CALL    GETBITS        ;Get no of bits 
  834.     CP    1        ;Test flag
  835.     JP    Z,START        ;Get out on thru
  836.     JP    NC,LL2        ;Out of range
  837.     LD    (LL22),HL    ;Save wanted no bits
  838.     CALL    LPRINT        ;Print & exit
  839.     DB    ESC,'L'
  840. LL22:    DB    0,0,0
  841. ;
  842. ;
  843. LM:            ;Print test
  844.     CALL    LPRINT
  845. ;    DB    CR,LF,LF       ;Removed re double width SO
  846.     DB    'ABCDEFGHIJKLMNOPQRSTUVWXYZ  '
  847.     DB    'abcdefghijklmnopqrstuvwxyz',CR,LF,0
  848. ;            ; LF turns off condensed
  849.     CALL    SETCOND        ;Re-activate condensed if reqd
  850. ;
  851.     CALL    LPRINT
  852.     DB    "1234567890-=['\;,./"
  853.     DB    '!@#$%^&*()_+]"|:<>?',CR,LF,LF,0
  854. ;            ; LF turns off condensed 
  855.     CALL    SETCOND        ;Re-activate condensed if reqd
  856. ;
  857. ;
  858.     IF    GTRAX
  859. ;
  860. LN:            ;Set handling of 8th bit
  861.     CALL    CPRINT        ;Cls & display
  862.     DB    '1:  Bit 8 as is',CR,LF
  863.     DB    '2:  Bit 8 always ON',CR,LF
  864.     DB    '3:  Bit 8 always OFF',CR,LF,0
  865. ;
  866.     CALL    CHOICE        ;Ask & get input
  867.     LD    B,1        ;Set minimum
  868.     LD    C,4        ; & max+1
  869.     CALL    NUMBER
  870.     CP    1        ;Test flag
  871.     JP    Z,START        ;Get out on thru
  872.     JP    NC,LN        ;Out of range
  873.     LD    A,E        ;Get index
  874.     LD    HL,NTABL-1    ;Index table (offset for ascii char index)
  875.      ADD    A,L        ;Combine with index char
  876.     JP    NC,LN1        ;No carry to high byte
  877.     INC    H
  878. LN1:
  879.     LD    L,A        ;Complete index
  880. ;
  881.     LD    A,(HL)        ;Get byte at HL>
  882.     LD    (LNBYT),A    ; & store in string
  883.     CALL    LPRINT        ;Print & exit
  884.     DB    ESC
  885. LNBYT:    DB    0,0
  886. ;
  887. ;
  888. NTABL:    DB    '#','>','='    ;As is, on, off        
  889. ;
  890. ;
  891. ;
  892. LO:            ;Home print head
  893.     CALL    LPRINT        ;Print & exit
  894.     DB    ESC,'<',0
  895. ;
  896. ;
  897.     ENDIF
  898. ;
  899. ;
  900. ;            Hex keypad to printer
  901. LX:
  902.     CALL    CPRINT        ;Cls & display
  903.     DB    'Only keys 0-9 and A-F are accepted',CR,LF
  904.     DB    'For every pair of hex digits a character',CR,LF
  905.     DB    'passed to the printer',CR,LF
  906.     DB    'Use ^Z (single keystroke) to end',CR,LF,CR,LF,0
  907. ;
  908. LXLP:
  909.     CALL    XIN        ;Get one hex digit (or ^Z)
  910.     CALL    CCOUT        ;& display, control char as ^. 
  911.     CP    EOF        ;^Z?
  912.     JP    Z,START        ;Yes - get out
  913.     LD    D,C        ;Keep 1st hex digit
  914.     CALL    XIN        ;Get second hex digit (or ^Z)
  915.     CALL    CCOUT        ;& display, control char as ^. 
  916.     CP    EOF        ;^Z?
  917.     JP    Z,START        ;Yes - get out
  918.     LD    A,' '        ;Blank between digit pairs
  919.     CALL    CCOUT
  920. ;            Combine hex digits
  921. ;                Low-order digit in <C>
  922.     LD    A,D        ;
  923.     ADD    A,A        ; 2x
  924.     ADD    A,A        ; 4x
  925.     ADD    A,A        ; 8x
  926.     ADD    A,A        ;16x 
  927.     ADD    A,C        ;Combine digits
  928. ;
  929.     CALL    LOUT        ;No - put to printer
  930.     CP    LF        ;Line feed?
  931.     JP    Z,CHKCNDX    ;Yes - check condensed
  932.     CP    CR        ;Or carriage return (may not be necessary)
  933.     JP    NZ,LXLP        ;No - go for next char
  934. CHKCNDX:
  935.     CALL    SETCOND        ;Re-activate condensed if reqd
  936.     JP    LXLP        ;Go for next char
  937. ;
  938. ;
  939. ;            Get Hex digit
  940. ;             Returns hex digit in <C>,
  941. ;             original char entered in <A>
  942. ;
  943. XIN:
  944.     CALL    DIN        ;Get one char
  945.     OR    A        ;Anything?
  946.     JP    Z,XIN        ;No - try again
  947.     CP    EOF        ;^Z?
  948.     RET    Z        ;Yes - return
  949.     LD    B,A        ;Keep actual char
  950.     CP    '0'        ;Validate 0 - 9
  951.     JP    C,XIN
  952.     CP    '9'
  953.     JP    C,XIN2        ;Yes - digit 0 -9
  954.     CP    'A'        ;Lower case A - F? 
  955.     JP    C,XIN
  956.     CP    'F'
  957.     JP    C,XIN3        ;Yes - A - F
  958.     CP    'a'        ;Upper case A - F 
  959.     JP    C,XIN
  960.     CP    'f'+1
  961.     JP    NC,XIN        ;No - ignore
  962. XIN3:            ;Alpha A-F/a-f
  963.     AND    07H        ;Convert to 01-06
  964.     ADD    A,9        ;now 0A-0FH
  965. XIN2:    AND    0FH        ;Strip zone for 0-9, noop for alpha
  966.     LD    C,A        ;Hex digit
  967.     LD    A,B        ;Original char
  968.     RET
  969. ;
  970. ;
  971. ;            Re-activate condensed if selected 
  972. SETCOND:
  973.     LD    A,(OPTIONS)    ;Get current options
  974.     AND    80H        ;Condensed on?
  975.     JP    Z,LXLP        ;No - go for next char
  976.     LD    A,SI        ;Set condensed on again
  977.     CALL    LOUT        ; to printer
  978.     RET
  979. ;
  980. ;
  981. ;            Keyboard to printer
  982. LZ:
  983.     CALL    CPRINT        ;Cls & display
  984.     DB    'All keys pressed are passed to the printer',CR,LF
  985.     DB    'This includes all control keys, except ^Z',CR,LF
  986.     DB    'Use ^Z to end',CR,LF,CR,LF,0
  987. ;
  988. LZLP:
  989.     CALL    DIN        ;Get one char
  990.     OR    A        ;Anything?
  991.     JP    Z,LZLP        ;No - try again
  992.     CALL    CCOUT        ;& display, control char as ^. 
  993.     CP    EOF        ;^Z?
  994.     JP    Z,START        ;Yes - get out
  995.     CALL    LOUT        ;No - put to printer
  996.     CP    LF        ;Line feed?
  997.     JP    Z,CHKCOND    ;Yes - check condensed
  998.     CP    CR        ;Or carriage return (may not be necessary)
  999.     JP    NZ,LZLP        ;No - go for next char
  1000. CHKCOND:
  1001.     CALL    SETCOND        ;Re-activate condensed if reqd
  1002.     JP    LZLP        ;Go for next char
  1003.  
  1004. ;
  1005. ;
  1006. ;    Print string on printer & exit
  1007. LPRINT:
  1008.     EX    (SP),HL        ;Save <HL> & get string addr
  1009.     CALL    LPR        ;Print string at HL>
  1010.     POP    HL        ;Restore register used 
  1011.     JP    START
  1012. ;
  1013. ;    Print string on printer & return
  1014. RPRINT:
  1015.     EX    (SP),HL        ;Save <HL> & get string addr
  1016.     CALL    LPR        ;Print string at HL>
  1017.     EX    (SP),HL        ;Restore register used & return addr
  1018.     RET
  1019. ;
  1020. ;            Print string at HL>
  1021. ;
  1022. LPR:
  1023.     PUSH    AF
  1024. LPRLP:
  1025.     LD    A,(HL)        ;Get next char
  1026.     INC    HL        ; & step past
  1027.     OR    A        ;End?
  1028.     JP    Z,LPREX        ;Yes
  1029.     CALL    LOUT        ;Output byte in <A>
  1030.     JP    LPRLP        ;Go for next byte
  1031. ;
  1032. LPREX:
  1033.     POP    AF
  1034.     RET
  1035. ;
  1036. ;    Print string on Console & return
  1037. PRINT:
  1038.     EX    (SP),HL        ;Save <HL> & get string addr
  1039.     CALL    PR        ;Print string at HL>
  1040.     EX    (SP),HL        ;Restore register used & return addr
  1041.     RET
  1042. ;
  1043. ;            Print string at HL> on console
  1044. ;
  1045. PR:
  1046.     PUSH    AF
  1047. PRLP:
  1048.     LD    A,(HL)        ;Get next char
  1049.     INC    HL        ; & step past
  1050.     OR    A        ;End?
  1051.     JP    Z,PREX        ;Yes
  1052.     CALL    COUT        ;Output byte in <A>
  1053.     JP    PRLP        ;Go for next byte
  1054. ;
  1055. PREX:
  1056.     POP    AF
  1057.     RET
  1058. ;
  1059. ;
  1060. ;            loop through all tabs
  1061. ;                ;HL> tab source string
  1062. ;                ;DE> tab destination list
  1063. ;                ;<B> max no of tabs
  1064. ;                ;<C> max allowed tab
  1065. ;                ;Returns <A> 0 - ok, 1 zero tab found, 2 error 
  1066. TABS:
  1067.     PUSH    DE        ;Save tab destination pointer
  1068.     PUSH    BC        ;Save no of tabs
  1069.     LD    A,(DE)        ;Get minimum
  1070.     LD    B,A
  1071.     CALL    NUMBER        ;Get next number in <E>, flag in <A>
  1072.     POP    BC
  1073.     LD    A,E        ;Save tab # (2x)
  1074.     LD    B,E        ;Save tab #
  1075.     POP    DE        ;Restore dest'n pointer
  1076.     LD    (DE),A        ;Save tab
  1077.     INC    DE        ;Step to next posn
  1078.     OR    A        ;Test flag
  1079.     RET    NZ        ; On null response & on error     
  1080.     LD    A,(HL)        ;Was current no last?
  1081.     OR    A        ;(i.e. terminating null)
  1082.     JP    Z,TABT        ;Yes - thru
  1083.     LD    A,B        ;Get save tab no
  1084.     INC    A        ;Set as new minimum
  1085.     LD    (DE),A        ; & save tab+1 for minimum check
  1086.     DJNZ    TABS        ;Continue if count not out
  1087. ;                 max no tabs - ignore rest
  1088. TABT:            ;Thru all tabs
  1089.     XOR    A
  1090.     LD    (DE),A        ;Ensure last posn zero
  1091.     RET            ;With <A> zero
  1092. ;
  1093. ;
  1094. ;            :Get number from HL>,
  1095. ;             limited by , or 00H
  1096. ;             test min in <B>, max in <C>
  1097. ;             returned in <E>, 
  1098. ;             flag in <A> 0 - ok, 1 end input, 2 error
  1099. ;             returns HL> past comma if present
  1100. NUMBER:
  1101.     PUSH    HL        ;Save current posn for null check
  1102.     CALL    EVAL10        ;Get next number at HL> in <DE>
  1103.     EX    DE,HL        ;Put curr posn in <DE>
  1104.     EX    (SP),HL        ;Get prev posn in <HL>
  1105.     XOR    A        ;Turn off carry flag
  1106.     SBC    HL,DE        ;Did we move at all? (equal/not eq)
  1107.     POP    HL        ;Either way restore 
  1108.     EX    DE,HL        ;<DE> number, HL> next posn
  1109.     JP    Z,NUMEX        ;Didn't move - exit
  1110. ;            We picked up some number - may be zero
  1111.     LD    A,D
  1112.     OR    A
  1113.     JP    NZ,NUMER    ;Over 255
  1114.     LD    A,C        ;Get max if any
  1115.     OR    A        ;Set flag
  1116.     LD    A,E        ;Get number - leave flag 
  1117.     JP    Z,NUMMAX    ;No maximum
  1118.     CP    C        ;Over max?
  1119.     JP    NC,NUMER    ;Yes - get out
  1120. NUMMAX:
  1121.     CP    B        ;Less minimum 
  1122.     JP    C,NUMER        ;Invalid
  1123.     LD    A,(HL)        ;Get delimiter following tab
  1124.     OR    A        ;Null?
  1125.     JP    Z,NUMTRU    ;Yes - thru
  1126.     CP    ','        ;Valid delimiter?
  1127.     JP    NZ,NUMER    ;No - ask new input
  1128.     INC    HL        ;Step past comma
  1129.     LD    A,E        ;Get no again, now check for zero
  1130.     OR    A        ;Zero - treat as end
  1131.     RET    Z        ;Yes - get out with
  1132. ;            Number ok 
  1133. NUMTRU:
  1134.     XOR    A        ;Set ok flag
  1135.     RET
  1136. NUMEX:
  1137.     LD    A,(HL)        ;Get delimiter following tab
  1138.     OR    A        ;Null?
  1139.     JP    NZ,NUMER    ;No - invalid
  1140.     LD    A,1        ;Set exit flag
  1141.     RET
  1142. NUMER:
  1143.     CALL    PRINT        ;Put out error
  1144.     DB    BELL,CR,LF,LF,0
  1145. ;
  1146.     LD    A,2        ;Set error flag
  1147.     RET
  1148. ;
  1149. ;
  1150. ;             Get No of bits for graphics mode,
  1151. ;              in:  <HL> max 
  1152. ;              out: <HL> actual
  1153. GETBITS:
  1154.     PUSH    HL        ;Save max
  1155.     CALL    PRINT
  1156.     DB    'No of bits of graphics? ',0
  1157. ;
  1158.     LD    A,0
  1159.     CALL    BBLINE
  1160.     CALL    EVAL10
  1161.     EX    DE,HL        ;Put curr posn in <DE>
  1162.     EX    (SP),HL        ;Get prev posn in <HL>
  1163.     XOR    A        ;Turn off carry flag
  1164.     SBC    HL,DE        ;Did we move at all? (equal/not eq)
  1165.     POP    HL        ;Either way restore 
  1166.     EX    DE,HL        ;<DE> number, HL> max no
  1167.     JP    Z,NUMEX        ;Didn't move - exit with flag
  1168.     XOR    A        ;Turn off carry flag
  1169.     SBC    HL,DE        ;is entered over max?
  1170.     JP    C,NUMER        ;Yes - get out on error flag
  1171.     EX    DE,HL
  1172.      RET            ;No -ok, zero in <A>, numberin <HL> 
  1173. ;
  1174. ;            Ask for input - return 1 byte in <A>
  1175. CHOICE:
  1176.     CALL    PRINT        ;Show last line in menu
  1177.     DB    'Enter your choice: ',0
  1178. ;
  1179.     LD    A,1        ;Specify capitalization
  1180.     CALL    BBLINE        ;Wait for input line
  1181.     LD    A,(HL)        ;Get first char, all others ignored
  1182.     RET
  1183. ;
  1184. ;
  1185. ;            Set Options flags on
  1186. ;             <C> has bit mask
  1187. SETOPT:
  1188.     PUSH    HL
  1189.     PUSH    AF
  1190.     LD    A,(OPTIONS)    ;Get current options
  1191.     OR    C        ;Turn on bits
  1192.     LD    (OPTIONS),A    ;Save updated flags
  1193.     POP    AF
  1194.     POP    HL
  1195.     RET
  1196. ;
  1197. ;            Set Options flags off
  1198. ;             <C> has bit mask
  1199. RESOPT:
  1200.     PUSH    HL
  1201.     PUSH    AF
  1202.     LD    A,(OPTIONS)    ;Get current options
  1203.     AND    C        ;Turn off bits
  1204.     LD    (OPTIONS),A    ;Save updated flags
  1205.     POP    AF
  1206.     POP    HL
  1207.     RET
  1208. ;
  1209. ;
  1210. ;            Clear screen & display text
  1211. CPRINT:
  1212.     PUSH    HL
  1213.     PUSH    AF
  1214.     LD    HL,CLR        ;Set to clear screen string
  1215. CPRTLP:
  1216.     LD    A,(HL)        ;Get next char
  1217.     INC    HL
  1218.     OR    A        ;End of string?
  1219.     JP    Z,CPRT        ;Yes -
  1220.     CALL    COUT        ;No - display
  1221.     JP    CPRTLP
  1222. ;
  1223. CPRT:
  1224.     POP    AF
  1225.     POP    HL    
  1226.     JP    PRINT        ;Go print string whose addr now on stack
  1227. ;
  1228. ;
  1229. COUT:            ;Put char in <A> to CON:
  1230.     PUSH    AF
  1231.     PUSH    BC
  1232.     PUSH    DE
  1233.     PUSH    HL
  1234.     LD    E,A        ;Set char
  1235.     LD    C,2        ;Set CONOUT funtion
  1236.     CALL    BDOS
  1237.     POP    HL
  1238.     POP    DE
  1239.     POP    BC
  1240.     POP    AF
  1241.     RET
  1242. ;
  1243. LOUT:            ;Put char in <A> to LST:
  1244.     PUSH    AF
  1245.     PUSH    BC
  1246.     PUSH    DE
  1247.     PUSH    HL
  1248.     LD    E,A        ;Set char
  1249.     LD    C,5        ;Set LISTOUT funtion
  1250.     CALL    BDOS
  1251.     POP    HL
  1252.     POP    DE
  1253.     POP    BC
  1254.     POP    AF
  1255.     RET
  1256. ;
  1257. CCOUT:            ;Put char in <A> to CON:
  1258. ;            Show control chars
  1259.     PUSH    AF
  1260.     PUSH    BC
  1261.     CP    ' '        ;Control char?
  1262.     JP    NC,CCO2        ;No
  1263.     CP    CR        ;Special?
  1264.     JP    Z,CCO2        ;Yes - as is
  1265.     CP    LF        ;Special?
  1266.     JP    Z,CCO2        ;Yes - as is
  1267.     CP    BELL        ;Special?
  1268.     JP    Z,CCO2        ;Yes - as is
  1269.     CP    BS        ;Special?
  1270.     JP    Z,CCO2        ;Yes - as is
  1271. ;            Convert & display
  1272.     CP    ESC        ;Escape?
  1273.     JP    NZ,CCO3        ;Yes - spell
  1274.     LD    A,'E'
  1275.     CALL    COUT    
  1276.     LD    A,'S'
  1277.     CALL    COUT
  1278.     LD    A,'C'
  1279.     JP    CCO2
  1280. ;
  1281. CCO3:            ;Show ^
  1282.     OR    40H        ;Convert to alpha
  1283.     PUSH    AF
  1284.     LD    A,'^'
  1285.     CALL    COUT
  1286.     POP    AF        ;Get converted
  1287. CCO2:
  1288.     CALL    COUT        ;Put char in <A>
  1289.     POP    BC
  1290.     POP    AF
  1291.     RET
  1292. ;
  1293. DIN:            ;Get char - if available
  1294.     PUSH    BC
  1295.     PUSH    DE
  1296.     PUSH    HL
  1297.     LD    C,6        ;Set Direct CON I/O funtion
  1298.     LD    E,0FFH        ;Flag as input request
  1299.     CALL    BDOS
  1300.     POP    HL
  1301.     POP    DE
  1302.     POP    BC
  1303.     RET
  1304. ;
  1305. ;
  1306.     END
  1307.