home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / MBUG / MBUG115.ARC / MXSET22.MAC < prev    next >
Text File  |  1979-12-31  |  22KB  |  1,121 lines
  1. ;MXSET
  2. ;**********************************************************
  3. ;
  4. ;This program will set/reset all of the major functions of the
  5. ;Epson MX80 or MX-100 printer with or without Graftrax
  6. ;The program uses Z80 Zilog mnemonics and calls are made to 
  7. ;Richard Conn's excellent SYSLIB.REL file. 
  8. ;Microsoft's M80 macro assembler is needed 
  9. ;
  10. ;***********************************************************
  11. ;
  12. ;Rev  2.2  21 April 84   Frans Van Duinen
  13. ;  fixed some bugs introduced with ver 2.1
  14. ;  capability to run under WS
  15. ;
  16. ;Rev  2.1  20 April 84   Frans Van Duinen, Toronto
  17. ;  set up for MX80 or 100 with or without Graftrax,
  18. ;  cleaned up coding
  19. ; 
  20. ;Rev  2.0  16 April 84   David C. Naylor, Halton Hills
  21. ;  set up for MX100 without graftrax 
  22. ;
  23. ;Rev. 1.2 by Simon J. Ewins, Toronto, Ontario, Canada.
  24. ; June 28, 1983.   Toronto, Ontario.
  25. ;
  26. ;
  27. ; Legend:
  28. ;
  29. ;  <DE> - refers to content of registers, e.g. <A>
  30. ;   DE> - refers to memory location pointed to be register pair
  31. ;   <>  - not equal
  32. ;
  33. ; SYSLIB functions used
  34.     EXTRN    BBLINE        ;Get input line, returns HL>line
  35. ;                 <A> count; on input <A><>0 - capitalize
  36.     EXTRN    EVAL10        ;Convert decimal number at HL> to binary
  37. ;                 returns <DE> number, HL> next char
  38. ;                 handling of nos>65535 unknown
  39. ;                 returns zero if no valid digits
  40. ;
  41. ;Note that CIN, COUT PRINT CCOUT are not compatible with WS
  42. ;
  43. ;Conditional assembly
  44. ;
  45. FALSE    EQU    0
  46. TRUE    EQU    NOT FALSE
  47. ;
  48. MX100    EQU    TRUE    ;Set true if using wider printer
  49. GTRAX    EQU    FALSE    ;Set true if printer graftrax equiped
  50. ;
  51. ;
  52. ; Equated symbols
  53. BELL    EQU    07    ;Bell
  54. BS    EQU    08    ;Backspace
  55. LF    EQU    0AH    ;Linefeed
  56. FF    EQU    0CH    ;Formfeed
  57. CR    EQU    0DH    ;Carriage return
  58. SO    EQU    0EH    ;Turn on double width
  59. SI    EQU    0FH    ;Shift in (activates compressed)
  60. DC2    EQU    12H    ;Turn off compressed
  61. DC4    EQU    14H    ;Turn off double width
  62. EOF    EQU    1AH    ;End of file (^Z)
  63. ESC    EQU    1BH    ;Escape char
  64. ;
  65. OFF    EQU    0    ;Off flag
  66. ON    EQU    1    ;On flag for printer
  67. ;
  68. ;
  69. BDOS    EQU    5    ;Entry for BDOS
  70. ;
  71.     IF    MX100
  72. ;
  73. ; MX100 related values
  74. ;
  75. MAXWDTH    EQU    233    ;Max page width
  76. ;
  77.     ELSE
  78. ;
  79. ; MX80  related values
  80. ;
  81. MAXWDTH    EQU    132    ;Max page width
  82. ;
  83.     ENDIF
  84. ;
  85. ;Techniques:
  86. ;
  87. ;Note the sequence 
  88. ;    CALL LPRINT
  89. ;    DB   ESC,...,0
  90. ;
  91. ; The routine LPRINT never returns control. 
  92. ; instead it exits to label START, a call is used
  93. ; to pass the return address as the addr of the string
  94. ; to print. String must terminate on 00H
  95. ;
  96. ;
  97. ;Note that the sequence 
  98. ;    CALL RPRINT
  99. ;    DB   ESC,...,0
  100. ;
  101. ; does return control
  102. ;
  103. ;
  104.     .Z80
  105.     CSEG
  106. ;
  107.     JP    START        ;Skip subrtn
  108. CLR:
  109.     DB    1AH,0,0,0,0,0,0    ;Clear screen & home cursor
  110. ;                Set to sequence for your computer:
  111. ;                Osborne   - 1AH,0
  112. ;                Televideo - 1AH,0
  113. ;                Heath     - ESC,'E',0
  114. ;                If not wanted set to CR,LF,LF,LF...
  115. ;
  116. START:
  117.     CALL    CPRINT        ;Cls & display
  118.     DB    'EPSON SET-UP ver 2.2',CR,LF
  119. ;
  120.     IF    MX100
  121. ;
  122.     DB    'For MX100 '
  123. ;
  124.     ELSE
  125. ;
  126.     DB    'For MX80 '
  127. ;
  128.     ENDIF
  129. ;
  130.     IF    GTRAX
  131. ;
  132.     DB    'with Graftrax '
  133. ;
  134.     ELSE
  135. ;
  136.     DB    'without Graftrax '
  137. ;
  138.     ENDIF
  139. ;
  140.     DB    CR,LF
  141.     DB    'OPTIONS:',CR,LF
  142.     DB    'A: Select character font',CR,LF
  143. ;
  144.     IF    GTRAX
  145. ;
  146.     DB    'B: Reset printer to defaults',CR,LF
  147. ;
  148.     ELSE
  149. ;
  150.     DB    'B: Select character set',CR,LF
  151. ;
  152.     ENDIF
  153. ;
  154.     DB    'C: Set line spacing',CR,LF
  155.     DB    'D: Set page size',CR,LF
  156. ;
  157.     IF    GTRAX
  158. ;
  159.     DB    'E: Set uni-directional print ON/OFF',CR,LF
  160. ;
  161.     ELSE
  162. ;
  163.     DB    'E: Set vertical tabs',CR,LF
  164. ;
  165.     ENDIF
  166. ;
  167.     DB    'F: Set horizontal tabs',CR,LF
  168.     DB    'G: Set to top of form (FF)',CR,LF
  169.     DB    'H: Turn ON perforation skip',CR,LF
  170.     DB    'I: Turn OFF perforation skip',CR,LF
  171.     DB    'J: Enable out of paper signal',CR,LF
  172.     DB    'K: Disable out of paper signal',CR,LF
  173.     DB    'L: Print test',CR,LF
  174. ;
  175.     IF    GTRAX
  176. ;
  177.     DB    'M: Set bit 8 handling',CR,LF
  178.     DB    'N: Home printhead',CR,LF
  179.     DB    'O: Set graphics mode',CR,LF
  180. ;
  181.     ENDIF
  182. ;
  183.     DB    'Z: Keyboard to printer',CR,LF 
  184.     DB    '^C: Quit to CP/M',CR,LF,LF,0
  185.     CALL    CHOICE        ;Complete menu, get input
  186. ;
  187.     CP    'A'
  188.     JP    Z,LA        ;Select type font
  189.     CP    'B'
  190.     JP    Z,LB        ;Select character set/reset printer
  191.     CP    'C'
  192.     JP    Z,LC        ;Set line spacing 
  193.     CP    'D'
  194.     JP    Z,LD        ;Set page size
  195.     CP    'E'
  196.     JP    Z,LE        ;Set vertical tabs/reset
  197.     CP    'F'
  198.     JP    Z,LBLF        ;Set horizontal tabs
  199.     CP    'G'
  200.     JP    Z,LG        ;Force formfeed
  201.     CP    'H'
  202.     JP    Z,LH        ;Set perf skip on
  203.     CP    'I'
  204.     JP    Z,LI        ;Set perf skip off
  205.     CP    'J'
  206.     JP    Z,LJ        ;Enable paper-out detector (signal only)
  207.     CP    'K'
  208.     JP    Z,LK        ;Disable paper-out detector
  209.     CP    'L'
  210.     JP    Z,LL        ;Print test
  211. ;
  212.     IF    GTRAX
  213. ;
  214.     CP    'M'
  215.     JP    Z,LM        ;Handling of h/o bit
  216.     CP    'N'
  217.     JP    Z,LN        ;Home print head
  218.     CP    'O'
  219.     JP    Z,LO        ;Set graphics
  220. ;
  221.     ENDIF
  222. ;
  223.     CP    'Z'
  224.     JP    Z,LZ        ;Keyboard to printer
  225. ;
  226. ;            Invalid response
  227. ERROR:
  228.     CALL    PRINT
  229.     DB    BELL,0
  230.     JP    START
  231. ;
  232. ;
  233. ;
  234. ;            Select font
  235. LA:
  236.     CALL    CPRINT        ;Cls & display
  237.     DB    CR,LF,LF
  238.     DB    '1:  Set condensed ON',CR,LF
  239.     DB    '2:  Set condensed OFF',CR,LF
  240.     DB    '3:  Set enlarged ON',CR,LF
  241.     DB    '4:  Set enlarged OFF',CR,LF
  242.     DB    '5:  Set emphasized ON',CR,LF
  243.     DB    '6:  Set emphasized OFF',CR,LF
  244. ;
  245.     IF    GTRAX
  246. ;
  247.     DB    '7:  Set Italics ON',CR,LF
  248.     DB    '8:  Set Italics OFF',CR,LF
  249.     DB    '9:  Set double strike ON',CR,LF
  250.     DB    '10: Set double strike OFF',CR,LF
  251.     DB    '11: Set to subscript',CR,LF
  252.     DB    '12: Set to superscript',CR,LF
  253.     DB    '13: Set super/subscript OFF',CR,LF
  254.     DB    '14: Set permanent enlarged ON',CR,LF
  255.     DB    '15: Set permanent enlarged OFF',CR,LF
  256. ;
  257.     ENDIF
  258. ;
  259.     DB    LF,0        ;Extra LF & terminating null
  260. ;
  261.     CALL    CHOICE        ;Get response 
  262.     LD    B,1        ;Set minimum
  263. ;
  264.     IF    GTRAX
  265. ;
  266.     LD    C,16        ;Get max+1
  267. ;
  268.     ELSE
  269. ;
  270.     LD    C,7        ;Get max+1
  271. ;
  272.     ENDIF
  273. ;
  274.     CALL    NUMBER
  275.     CP    1        ;Test flag
  276.     JP    Z,START        ;Get out on thru
  277.     JP    NC,LA        ;Out of range
  278. ;
  279. ;                 Note that different selections
  280. ;                 have differing formats:
  281. ;                 1 - SI  - no ESC
  282. ;                 2 - DC2 - no ESC
  283. ;                 3 - SO  - no ESC
  284. ;                 4 - DC4 - no ESC
  285. ;                 5 - ESC,'E' 
  286. ;                 6 - ESC,'F'
  287. ;                 7 - ESC,'4'
  288. ;                 8 - ESC,'5'
  289. ;                 9 - ESC,'G'
  290. ;                10 - ESC,'H'
  291. ;                11 - ESC,'S',OFF
  292. ;                12 - ESC,'S',ON
  293. ;                13 - ESC,'T'
  294. ;                14 - ESC,'W',ON
  295. ;                15 - ESC,'W',OFF
  296. ;
  297.     LD    A,E        ;Get index
  298.     LD    HL,ATABL-1    ;Index table (offset for ascii char index)
  299.      ADD    A,L        ;Combine with index char
  300.     JR    NC,LA1        ;No carry to high byte
  301.     INC    H
  302. LA1:
  303.     LD    L,A        ;Complete index
  304. ;
  305.  
  306.     LD    A,(HL)        ;Get byte at HL>
  307.     PUSH    AF        ; & save
  308.     LD    A,E        ;Get selection back
  309.     CP    5
  310.     JR    C,LA2        ; 1-4 no ESC
  311.     LD    A,ESC
  312.     CALL    LOUT
  313. LA2:
  314.     POP    AF
  315.     CALL    LOUT        ;Byte from table
  316. ;
  317. ;
  318.     IF    GTRAX
  319. ;
  320.     LD    A,11
  321.     SUB    E        ;Normalize '11' & '12' to 0 & 1
  322.     CP    2        ;Is this option 11 or 12?
  323.     JP    C,LA3        ;Yes - put normalized
  324.     OR    A        ;Was this #1 - #10 (positive now)
  325.     JP    P,START        ;Yes - get out
  326.     CP    255        ;No - was it #13 
  327.     JP    Z,START        ;Yes - is complete
  328.     ADD    A,4        ;No - adjust 14 - 15 to 1 - 0
  329. LA3:
  330.     CALL    LOUT        ;Output 0 (option 11/14) or 1 (12/15)
  331. ;
  332.     ENDIF 
  333. ;
  334.     JP    START
  335. ;
  336. ;
  337. ATABL:    DB    SI,DC2        ;Condensed on/off - no ESC
  338.     DB    SO,DC4        ;Enlarged (double width) on/off - no ESC
  339.     DB    'E','F'        ;Emphasized on/off 
  340. ;
  341.     IF    GTRAX
  342. ;
  343.     DB    '4','5'        ;Italics on/off
  344.     DB    'G','H'        ;Double strike on/off
  345.     DB    'S','S'        ;Super/subscr - with ESC & 1,0
  346.     DB    'T'        ;Super/sub off - with Esc
  347.     DB    'W','W'        ;Double width on/off - With ESC & 1,0
  348. ;
  349.     ENDIF
  350. ;
  351. ;
  352. ;
  353. LB:
  354. ;
  355.     IF    GTRAX
  356. ;            Reset printer to default
  357.     CALL    LPRINT        ;Print & exit
  358.     DB    ESC,'@',0
  359. ;
  360. ;
  361.     ELSE
  362. ;
  363.                 ;Select character set
  364.     CALL    CPRINT        ;Cls & display
  365.     DB    CR,LF,LF
  366.     DB    '1:  North American',CR,LF
  367.     DB    '2:  British',CR,LF
  368.     DB    '3:  French',CR,LF
  369.     DB    '4:  German',CR,LF
  370.     DB    '5:  Spanish',CR,LF
  371.     DB    '6:  Italian',CR,LF
  372.     DB    '7:  Danish',CR,LF
  373.     DB    '8:  Swedish',CR,LF,LF
  374. ;
  375.     CALL    CHOICE        ;Get response
  376.     LD    B,1        ;Set minimum
  377.     LD    C,9        ; & max+1
  378.     CALL    NUMBER
  379.     CP    1        ;Test flag
  380.     JP    Z,START        ;Get out on thru
  381.     JP    NC,LB        ;Out of range
  382.     LD    A,E        ;Get index
  383.     LD    HL,BTABL-1    ;Index table (offset for ascii char index)
  384.      ADD    A,L        ;Combine with index char
  385.     JR    NC,LB1        ;No carry to high byte
  386.     INC    H
  387. LB1:    
  388.     LD    L,A        ;Complete index
  389. ;
  390.     CALL    RPRINT
  391.     DB    ESC,'R',0    ;Put out 1st part
  392.     LD    A,(HL)        ;Get language/ char set code
  393.     CALL    LOUT        ;May be zero
  394.     JP    START
  395. ;
  396. ;
  397. ;
  398. BTABL:    DB    0        ;North American
  399.     DB    3        ;British
  400.     DB    1        ;French
  401.     DB    2        ;German
  402.     DB    7        ;Spanish
  403.     DB    6        ;Italian
  404.     DB    4        ;Danish
  405.     DB    5        ;Swedish
  406. ;
  407. ;
  408.     ENDIF
  409. ;
  410. ;
  411. ;
  412. LC:            ;Set line spacing
  413.     CALL    CPRINT        ;Cls & display
  414.     DB    '1: Select 6 lines per inch',CR,LF
  415.     DB    '2: Select 8 lines per inch',CR,LF
  416.     DB    '3: Set line spacing in 1/72" increments',CR,LF
  417. ;
  418.     IF    GTRAX
  419. ;
  420.     DB    '4: Set line spacing in 1/216" increments',CR,LF
  421. ;
  422.     ENDIF
  423. ;
  424.     DB    LF,0        ;Mark end of string
  425. ;
  426.     CALL    CHOICE        ;Get input
  427.     LD    B,1        ;Set minimum
  428. ;
  429.     IF    GTRAX
  430. ;
  431.     LD    C,5        ; & max+1
  432. ;
  433.     ELSE
  434. ;
  435.     LD    C,4        ; & max+1
  436. ;
  437.     ENDIF
  438. ;
  439.     CALL    NUMBER
  440.     CP    1        ;Test flag
  441.     JP    Z,START        ;Get out on thru
  442.     JP    NC,LC        ;Out of range
  443.     LD    A,E        ;Get index
  444.     CP    2        ;Which one?
  445.     JR    Z,LC2        ;#2
  446.     JR    NC,LC3        ;#3 (or 4 if GTRAX)
  447. ;
  448.             ;Select 6 lines per inch
  449.     CALL    LPRINT        ;Print & exit
  450.     DB    ESC,'2',0    ;Set 6 lines/inch
  451. ;
  452. ;
  453. LC2:            ;Select 8 lines per inch
  454.     CALL    LPRINT        ;Print & exit
  455.     DB    ESC,'0',0    ;Set 8 lines/inch
  456. ;
  457. ;
  458. LC3:            ;Set variable line spacing
  459. ;
  460.     IF    GTRAX
  461. ;
  462.     CP    4        ;Item 4 (1/216)    
  463.     JR    NZ,LC5        ;No -
  464. ;
  465. LC4:
  466.     CALL    PRINT
  467.     DB    CR,LF,LF,'Enter quantity of 1/216 inches (max 85): ',CR,LF
  468.     DB    '---> ? ',0
  469. ;
  470.     LD    A,0        ;No capitals reqd
  471.     CALL    BBLINE        ;Get input line
  472.     LD    B,1        ;Set minimum
  473.     LD    C,0        ; & max+1 (256)
  474.     CALL    NUMBER
  475.     CP    1        ;Test flag
  476.     JP    Z,START        ;Get out on thru
  477.     JP    NC,LC4        ;Out of range
  478.     LD    A,E        ;Get index
  479.     LD    (LC42),A
  480.     CALL    LPRINT        ;Print & exit
  481.     DB    ESC,'3'        ;Set spacing in 1/216" increments
  482. LC42:    DB    1,0
  483. ;
  484. ;
  485. ;
  486.     ENDIF
  487. ;
  488. LC5:
  489.     CALL    PRINT
  490.     DB    CR,LF,LF,'Enter quantity of 1/72 inches (max 85): ',CR,LF
  491.     DB    '---> ? ',0
  492. ;
  493.     LD    A,0        ;No capitals reqd
  494.     CALL    BBLINE        ;Get input line
  495.     LD    B,1        ;Set minimum
  496.     LD    C,86        ; & max+1
  497.     CALL    NUMBER
  498.     CP    1        ;Test flag
  499.     JP    Z,START        ;Get out on thru
  500.     JP    NC,LC5        ;Out of range
  501.     LD    A,E        ;Get index
  502.     LD    (LC52),A
  503.     CALL    LPRINT        ;Print & exit
  504.     DB    ESC,'A'        ;Set LF spacing in 1/72" increments
  505. LC52:    DB    1,0
  506. ;
  507. ;
  508. LD:            ;Set page dimensions
  509.     CALL    CPRINT        ;Cls & display
  510.     DB    '1: Set form length in lines',CR,LF
  511.     DB    '2: Set form length in inches',CR,LF
  512.     DB    '3: Set width',CR,LF,0
  513. ;
  514.     CALL    CHOICE
  515.     LD    B,1        ;Set minimum
  516.     LD    C,4        ; & max+1
  517.     CALL    NUMBER
  518.     CP    1        ;Test flag
  519.     JP    Z,START        ;Get out on thru
  520.     JP    NC,LD        ;Out of range
  521.     LD    A,E        ;Get index
  522.     CP    2        ;Which one?
  523.     JP    NC,LD3        ;#3
  524.     JR    Z,LD2        ;#2
  525. ;
  526.             ;Set page length in lines
  527. LD1:
  528.     CALL    PRINT
  529.     DB    CR,LF,LF,'Enter length in lines (max 127): ',CR,LF
  530.     DB    '---> ? ',0
  531. ;
  532.     LD    A,0
  533.     CALL    BBLINE
  534.     LD    B,1        ;Set minimum
  535.     LD    C,128        ; & max+1
  536.     CALL    NUMBER
  537.     CP    1        ;Test flag
  538.     JP    Z,START        ;Get out on thru
  539.     JP    NC,LD1        ;Out of range
  540.     LD    A,E        ;Get index
  541.     LD    (LD12),A
  542.     CALL    LPRINT        ;Print & exit
  543.     DB    ESC,'C'
  544. LD12:    DB    1,0
  545. ;
  546. ;
  547. ;
  548. LD2:            ;Set page length in inch increments
  549.     CALL    PRINT
  550.     DB    CR,LF,LF,'Enter length in inches (max 22): ',CR,LF
  551.     DB    '---> ? ',0
  552. ;
  553.     LD    A,0
  554.     CALL    BBLINE
  555.     LD    B,1        ;Set minimum
  556.     LD    C,23        ; & max+1
  557.     CALL    NUMBER
  558.     CP    1        ;Test flag
  559.     JP    Z,START        ;Get out on thru
  560.     JP    NC,LD2        ;Out of range
  561.     LD    A,E        ;Get index
  562.     LD    (LD22),A
  563. ;
  564.     CALL    RPRINT
  565.     DB    ESC,'C',0
  566.     XOR    A        ;Force null
  567.     CALL    LOUT        ; & put
  568. ;
  569.     CALL    LPRINT        ;Print & exit
  570. LD22:    DB    1,0
  571. ;
  572. ;
  573. LD3:            ;Set page width
  574.     CALL    PRINT
  575.     DB    CR,LF,LF,'Enter width: ',CR,LF
  576. ;
  577.     IF    MX100
  578. ;
  579.     DB    'Up to 136 in normal or emphasized mode.',CR,LF
  580.     DB    '      233 in condensed mode.',CR,LF
  581.     DB    '       68 in enlarged mode.',CR,LF
  582.     DB    '      116 in enlarged-condensed mode',CR,LF
  583. ;
  584.     ELSE
  585. ;
  586.     DB    'Up to  80 in normal or emphasized mode.',CR,LF
  587.     DB    '      132 in condensed mode.',CR,LF
  588.     DB    '       40 in enlarged mode.',CR,LF
  589.     DB    '       60 in enlarged-condensed mode',CR,LF
  590. ;
  591.     ENDIF
  592. ;
  593.  
  594.  
  595.     DB    '---> ? ',0
  596. ;
  597.     LD    A,0
  598.     CALL    BBLINE
  599.     LD    B,1        ;Set minimum
  600.     LD    C,MAXWDTH+1    ; & max+1
  601.     CALL    NUMBER
  602.     CP    1        ;Test flag
  603.     JP    Z,START        ;Get out on thru
  604.     JP    NC,LD3        ;Out of range
  605.     LD    A,E        ;Get index
  606.     LD    (LD32),A
  607.     CALL    LPRINT        ;Print & exit
  608.     DB    ESC,'Q'
  609. LD32:    DB    1,0
  610. ;
  611. ;
  612. ;
  613. ;
  614. ;
  615. LE:
  616. ;
  617.     IF    GTRAX
  618. ;
  619. ;            Set uni-directional print on/off
  620.     CALL    CPRINT        ;Cls & display
  621.     DB    '1:  Set uni-directional print ON',CR,LF
  622.     DB    '2:  Set uni-directional print OFF',CR,LF,0
  623. ;
  624.     CALL    CHOICE        ;Ask & get input
  625.     LD    B,1        ;Set minimum
  626.     LD    C,3        ; & max+1
  627.     CALL    NUMBER
  628.     CP    1        ;Test flag
  629.     JP    Z,START        ;Get out on thru
  630.     JP    NC,LE        ;Out of range
  631.     CALL    RPRINT
  632.     DB    ESC,'U',0
  633.     LD    A,2        ;Convert index to 1/0 flag
  634.     SUB    E        ;1 now 1; 2 now 0
  635.     CALL    LOUT
  636.     JP    START
  637. ;
  638. ;
  639.     ELSE
  640. ;
  641. ;            ;Set vertical tabs
  642.     CALL    CPRINT        ;Cls & display
  643.     DB    CR,LF,LF,'Enter vertical tab positions (max 8)',CR,LF
  644.     DB    '(in ascending order) ---> ? ',0
  645. ;
  646.     LD    A,0
  647.     CALL    BBLINE        ;Get line of tabs, terminated by 00h
  648.     LD    IX,VTABS    ;Set to tab list
  649.     LD    A,1        ;Set minimum tab
  650.     LD    (IX),A        ;Prime tab list
  651.     LD    C,128        ;Set max tab+1 (we dont know page len)    
  652.     LD    B,8        ;Set loop count
  653.     CALL    TABS        ;Handle tabs, returns flag in <A>
  654.     OR    A        ;OK?
  655.     JR    Z,LE2        ;Yes
  656.     DEC    A        ;No - exit?
  657.     JP    Z,START        ;Yes -
  658.     JR    LE        ;No - ask new input
  659. ;
  660. ;            Output tab string
  661. LE2:
  662.     LD    HL,VTABS-2    ;Set to string to put
  663.     JP    HTBS2        ; & go put
  664. ;
  665. ;
  666. ;
  667.     DB    ESC,'B'        ;Vertical tabs
  668. VTABS:    DB    1,0,0,0,0,0,0,0,0  ;8 tabs & null
  669. ;
  670. ;
  671. ;
  672.     ENDIF
  673. ;
  674. ;
  675. LBLF:            ;Set horizontal tabs
  676.     CALL    CPRINT        ;Cls & display
  677.     DB    CR,LF,LF,'Enter horizontal tab positions (max 12)',CR,LF
  678.     DB    '(in ascending order) ---> ? ',0
  679. ;
  680.     LD    A,0
  681.     CALL    BBLINE
  682.     LD    IX,HTABS    ;Set to tab list
  683.     LD    A,1        ;Set minimum tab
  684.     LD    (IX),A        ;Prime tab list
  685.     LD    C,MAXWDTH+1    ;Set max tab+1 (we dont know page width)
  686.     LD    B,12        ;Set loop count
  687.     CALL    TABS        ;Handle tabs, returns flag in <A>
  688.     OR    A        ;OK?
  689.     JR    Z,LBLF2        ;Yes
  690.     DEC    A        ;No - exit?
  691.     JP    Z,START        ;Yes -
  692.     JR    LBLF        ;No - ask new input
  693. ;
  694. ;            Output tab string
  695. LBLF2:
  696.     LD    HL,HTABS-2    ;Set to string to put
  697. HTBS2:
  698.     CALL    LPR        ;Put string at HR>
  699. ;                 Is safer than RPRINT due to variable len
  700. ;                 past null may be garbage
  701.     XOR    A        ;Force null after tabs
  702.     CALL    LOUT
  703.     JP    START
  704. ;
  705. ;
  706.     DB    ESC,'D'
  707. HTABS:    DB    1,0,0,0,0,0,0,0,0,0,0,0,0  ; 12 tabs & null
  708. ;
  709. ;
  710. ;
  711. LG:            ;Set top of form (FF)
  712.     CALL    LPRINT        ;Print & exit
  713.     DB    FF,0        ;Output formfeed
  714. ;
  715. ;
  716. LH:            ;Turn on perf. skip-over
  717.     CALL    CPRINT        ;Cls & display
  718.     DB    CR,LF,LF
  719.     DB    'Enter no of lines to skip over perforation'
  720.     DB    ' (max 127)',CR,LF
  721.     DB    '---> ? ',0
  722. ;
  723.     LD    A,0
  724.     CALL    BBLINE
  725.     LD    B,1        ;Set minimum
  726.     LD    C,128        ; & max+1
  727.     CALL    NUMBER
  728.     CP    1        ;Test flag
  729.     JP    Z,START        ;Get out on thru
  730.     JP    NC,LH        ;Out of range
  731.     LD    A,E        ;Get index
  732.     LD    (LH2),A
  733.     CALL    LPRINT        ;Print & exit
  734.     DB    ESC,'N'
  735. LH2:    DB    0,0        ;Skip n lines
  736. ;
  737. ;
  738. ;
  739. LI:            ;Turn off perf. skip-over
  740.     CALL    LPRINT        ;Print & exit
  741.     DB    ESC,'O',0
  742. ;
  743. ;
  744. ;
  745. LJ:            ;Enable paper-out signal
  746.     CALL    LPRINT        ;Print & exit
  747.     DB    ESC,'9',0
  748. ;
  749. ;
  750. ;
  751. LK:            ;Disable paper-out signal
  752.     CALL    LPRINT        ;Print & exit
  753.     DB    ESC,'8',0    ;Disable paper-out sensor
  754. ;
  755. ;
  756. ;
  757. LL:            ;Print test
  758.     CALL    LPRINT
  759. ;    DB    CR,LF,LF       ;Removed re double width SO
  760.     DB    'ABCDEFGHIJKLMNOPQRSTUVWXYZ  '
  761.     DB    'abcdefghijklmnopqrstuvwxyz',CR,LF
  762.     DB    "1234567890-=['\;,./"
  763.     DB    '!@#$%^&*()_+]"|:<>?',CR,LF,LF,0
  764. ;
  765. ;
  766.     IF    GTRAX
  767. ;
  768. LM:            ;Set handling of 8th bit
  769.     CALL    CPRINT        ;Cls & display
  770.     DB    '1:  Bit 8 as is',CR,LF
  771.     DB    '2:  Bit 8 always ON',CR,LF
  772.     DB    '3:  Bit 8 always OFF',CR,LF,0
  773. ;
  774.     CALL    CHOICE        ;Ask & get input
  775.     LD    B,1        ;Set minimum
  776.     LD    C,4        ; & max+1
  777.     CALL    NUMBER
  778.     CP    1        ;Test flag
  779.     JP    Z,START        ;Get out on thru
  780.     JP    NC,LM        ;Out of range
  781.     LD    A,E        ;Get index
  782.     LD    HL,MTABL-1    ;Index table (offset for ascii char index)
  783.      ADD    A,L        ;Combine with index char
  784.     JR    NC,LM1        ;No carry to high byte
  785.     INC    H
  786. LM1:
  787.     LD    L,A        ;Complete index
  788. ;
  789.     LD    A,(HL)        ;Get byte at HL>
  790.     LD    (LMBYT),A    ; & store in string
  791.     CALL    LPRINT        ;Print & exit
  792.     DB    ESC
  793. LMBYT:    DB    0,0
  794. ;
  795. ;
  796. MTABL:    DB    '#','>','='    ;As is, on, off        
  797. ;
  798. ;
  799. ;
  800. LN:            ;Home print head
  801.     CALL    LPRINT        ;Print & exit
  802.     DB    ESC,'<',0
  803. ;
  804. ;
  805. LO:            ;Set graphics 
  806.     CALL    CPRINT        ;Cls & display
  807.     DB    '1:  Set medium density graphics',CR,LF
  808.     DB    '2:  Set high density graphics',CR,LF,0
  809. ;
  810.     CALL    CHOICE        ;Ask & get input
  811.     LD    B,1        ;Set minimum
  812.     LD    C,3        ; & max+1
  813.     CALL    NUMBER
  814.     CP    1        ;Test flag
  815.     JP    Z,START        ;Get out on thru
  816.     JP    NC,LO        ;Out of range
  817.     LD    A,E        ;Get index
  818.     CP    1        ;Medium density?
  819.     JR    NZ,LO2        ;No - high
  820. ;
  821. ;            Set medium density
  822.     CALL    LPRINT        ;Print & exit
  823.     DB    ESC,'K'
  824. ;
  825.     ENDIF
  826.     IF    GTRAX  AND  MX100
  827. ;    (nested conditionals dont work with ASM,
  828. ;     and I know M80 macros are  v e r y  flakey)
  829. ;
  830.     DB    03H,30H,0    ;816
  831. ;
  832.     ENDIF
  833.     IF    GTRAX  AND  NOT MX100
  834. ;
  835.     DB    01H,0E0H,0    ;460
  836. ;
  837.     ENDIF
  838.     IF    GTRAX
  839. ;
  840. ;
  841. ;
  842. LO2:            ;Set graphics - high density
  843.     CALL    LPRINT        ;Print & exit
  844.     DB    ESC,'L'
  845. ;
  846.     ENDIF
  847.     IF    GTRAX  AND  MX100
  848. ;
  849.     DB    06H,60H,0    ;1632
  850. ;
  851.     ENDIF
  852.     IF    GTRAX  AND  NOT MX100
  853. ;
  854.     DB    03H,0C0H,0    ;960
  855. ;
  856.     ENDIF
  857. ;
  858. ;
  859. ;            Keyboard to printer
  860. LZ:
  861.     CALL    CPRINT        ;Cls & display
  862.     DB    'All keys pressed are passed to the printer',CR,LF
  863.     DB    'This includes all control keys, except ^Z',CR,LF
  864.     DB    'Use ^Z to end',CR,LF,CR,LF,0
  865. ;
  866. LZLP:
  867.     CALL    DIN        ;Get one char
  868.     OR    A        ;Anything?
  869.     JR    Z,LZLP        ;No - try again
  870.     CALL    CCOUT        ;& display, control char as ^. 
  871.     CP    EOF        ;^Z?
  872.     JP    Z,START        ;Yes - get out
  873.     CALL    LOUT        ;No - put to printer
  874.     JR    LZLP        ;Go for next 
  875. ;
  876. ;
  877. ;    Print string on printer & exit
  878. LPRINT:
  879.     EX    (SP),HL        ;Save <HL> & get string addr
  880.     CALL    LPR        ;Print string at HL>
  881.     POP    HL        ;Restore register used 
  882.     JP    START
  883. ;
  884. ;    Print string on printer & return
  885. RPRINT:
  886.     EX    (SP),HL        ;Save <HL> & get string addr
  887.     CALL    LPR        ;Print string at HL>
  888.     EX    (SP),HL        ;Restore register used & return addr
  889.     RET
  890. ;
  891. ;            Print string at HL>
  892. ;
  893. LPR:
  894.     PUSH    AF
  895. LPRLP:
  896.     LD    A,(HL)        ;Get next char
  897.     INC    HL        ; & step past
  898.     OR    A        ;End?
  899.     JR    Z,LPREX        ;Yes
  900.     CALL    LOUT        ;Output byte in <A>
  901.     JR    LPRLP        ;Go for next byte
  902. ;
  903. LPREX:
  904.     POP    AF
  905.     RET
  906. ;
  907. ;    Print string on Console & return
  908. PRINT:
  909.     EX    (SP),HL        ;Save <HL> & get string addr
  910.     CALL    PR        ;Print string at HL>
  911.     EX    (SP),HL        ;Restore register used & return addr
  912.     RET
  913. ;
  914. ;            Print string at HL> on console
  915. ;
  916. PR:
  917.     PUSH    AF
  918. PRLP:
  919.     LD    A,(HL)        ;Get next char
  920.     INC    HL        ; & step past
  921.     OR    A        ;End?
  922.     JR    Z,PREX        ;Yes
  923.     CALL    COUT        ;Output byte in <A>
  924.     JR    PRLP        ;Go for next byte
  925. ;
  926. PREX:
  927.     POP    AF
  928.     RET
  929. ;
  930. ;
  931. ;            loop through all tabs
  932. ;                ;HL> tab source string
  933. ;                ;IX> tab destination list
  934. ;                ;<B> max no of tabs
  935. ;                ;<C> max allowed tab
  936. ;                ;Returns <A> 0 - ok, 1 zero tab found, 2 error 
  937. TABS:
  938.     PUSH    BC        ;Save no of tabs
  939.     LD    B,(IX)        ;Get minimum
  940.     CALL    NUMBER        ;Get next number in <E>, flag in <A>
  941.     POP    BC
  942.     LD    (IX),E        ;Save tab
  943.     INC    IX        ;Step to next posn
  944.     OR    A        ;Test flag
  945.     RET    NZ        ; On null response & on error     
  946.     LD    A,(HL)        ;Was current no last?
  947.     OR    A        ;(i.e. terminating null)
  948.     JR    Z,TABT        ;Yes - thru 
  949.     INC    E        ;Set as new minimum
  950.     LD    (IX),E        ; & save tab+1 for minimum check
  951.     DJNZ    TABS        ;Continue if count not out
  952. ;                 max no tabs - ignore rest
  953. TABT:            ;Thru all tabs
  954.     LD    (IX),0        ;Ensure last posn zero
  955.     RET            ;With <A> zero
  956. ;
  957. ;
  958. ;            :Get number from HL>,
  959. ;             limited by , or 00H
  960. ;             test min in <B>, max in <C>
  961. ;             returned in <E>, 
  962. ;             flag in <A> 0 - ok, 1 end input, 2 error
  963. ;             returns HL> past comma if present
  964. NUMBER:
  965.     PUSH    HL        ;Save current posn for null check
  966.     CALL    EVAL10        ;Get next number at HL> in <DE>
  967.     EX    DE,HL        ;Put curr posn in <DE>
  968.     EX    (SP),HL        ;Get prev posn in <HL>
  969.     XOR    A        ;Turn off carry flag
  970.     SBC    HL,DE        ;Did we move at all? (equal/not eq)
  971.     POP    HL        ;Either way restore 
  972.     EX    DE,HL        ;<DE> number, HL> next posn
  973.     JR    Z,NUMEX        ;Didn't move - exit
  974. ;            We picked up some number - may be zero
  975.     LD    A,D
  976.     OR    A
  977.     JR    NZ,NUMER    ;Over 255
  978.     LD    A,C        ;Get max if any
  979.     OR    A        ;Set flag
  980.     LD    A,E        ;Get number - leave flag 
  981.     JR    Z,NUMMAX    ;No maximum
  982.     CP    C        ;Over max?
  983.     JR    NC,NUMER    ;Yes - get out
  984. NUMMAX:
  985.     CP    B        ;Less minimum 
  986.     JR    C,NUMER        ;Invalid
  987.     LD    A,(HL)        ;Get delimiter following tab
  988.     OR    A        ;Null?
  989.     JR    Z,NUMTRU    ;Yes - thru
  990.     CP    ','        ;Valid delimiter?
  991.     JR    NZ,NUMER    ;No - ask new input
  992.     INC    HL        ;Step past comma
  993.     LD    A,E        ;Get no again, now check for zero
  994.     OR    A        ;Zero - treat as end
  995.     RET    Z        ;Yes - get out with
  996. ;            Number ok 
  997. NUMTRU:
  998.     XOR    A        ;Set ok flag
  999.     RET
  1000. NUMEX:
  1001.     LD    A,(HL)        ;Get delimiter following tab
  1002.     OR    A        ;Null?
  1003.     JR    NZ,NUMER    ;No - invalid
  1004.     LD    A,1        ;Set exit flag
  1005.     RET
  1006. NUMER:
  1007.     CALL    PRINT        ;Put out error
  1008.     DB    BELL,CR,LF,LF,0
  1009. ;
  1010.     LD    A,2        ;Set error flag
  1011.     RET
  1012. ;
  1013. ;
  1014. ;            Ask for input - return 1 byte in <A>
  1015. CHOICE:
  1016.     CALL    PRINT        ;Show last line in menu
  1017.     DB    'Enter your choice: ',0
  1018. ;
  1019.     LD    A,1        ;Specify capitalization
  1020.     CALL    BBLINE        ;Wait for input line
  1021.     LD    A,(HL)        ;Get first char, all others ignored
  1022.     RET
  1023. ;
  1024. ;
  1025. ;            Clear screen & display text
  1026. CPRINT:
  1027.     PUSH    HL
  1028.     PUSH    AF
  1029.     LD    HL,CLR        ;Set to clear screen string
  1030. CPRTLP:
  1031.     LD    A,(HL)        ;Get next char
  1032.     INC    HL
  1033.     OR    A        ;End of string?
  1034.     JR    Z,CPRT        ;Yes -
  1035.     CALL    COUT        ;No - display
  1036.     JR    CPRTLP
  1037. ;
  1038. CPRT:
  1039.     POP    AF
  1040.     POP    HL    
  1041.     JP    PRINT        ;Go print string whose addr now on stack
  1042. ;
  1043. ;
  1044. COUT:            ;Put char in <A> to CON:
  1045.     PUSH    AF
  1046.     PUSH    BC
  1047.     PUSH    DE
  1048.     PUSH    HL
  1049.     LD    E,A        ;Set char
  1050.     LD    C,2        ;Set CONOUT funtion
  1051.     CALL    BDOS
  1052.     POP    HL
  1053.     POP    DE
  1054.     POP    BC
  1055.     POP    AF
  1056.     RET
  1057. ;
  1058. LOUT:            ;Put char in <A> to LST:
  1059.     PUSH    AF
  1060.     PUSH    BC
  1061.     PUSH    DE
  1062.     PUSH    HL
  1063.     LD    E,A        ;Set char
  1064.     LD    C,5        ;Set LISTOUT funtion
  1065.     CALL    BDOS
  1066.     POP    HL
  1067.     POP    DE
  1068.     POP    BC
  1069.     POP    AF
  1070.     RET
  1071. ;
  1072. CCOUT:            ;Put char in <A> to CON:
  1073. ;            Show control chars
  1074.     PUSH    AF
  1075.     PUSH    BC
  1076.     CP    ' '        ;Control char?
  1077.     JR    NC,CCO2        ;No
  1078.     CP    CR        ;Special?
  1079.     JR    Z,CCO2        ;Yes - as is
  1080.     CP    LF        ;Special?
  1081.     JR    Z,CCO2        ;Yes - as is
  1082.     CP    BELL        ;Special?
  1083.     JR    Z,CCO2        ;Yes - as is
  1084.     CP    BS        ;Special?
  1085.     JR    Z,CCO2        ;Yes - as is
  1086. ;            Convert & display
  1087.     CP    ESC        ;Escape?
  1088.     JR    NZ,CCO3        ;Yes - spell
  1089.     LD    A,'E'
  1090.     CALL    COUT    
  1091.     LD    A,'S'
  1092.     CALL    COUT
  1093.     LD    A,'C'
  1094.     JR    CCO2
  1095. ;
  1096. CCO3:            ;Show ^
  1097.     OR    40H        ;Convert to alpha
  1098.     PUSH    AF
  1099.     LD    A,'^'
  1100.     CALL    COUT
  1101.     POP    AF        ;Get converted
  1102. CCO2:
  1103.     CALL    COUT        ;Put char in <A>
  1104.     POP    BC
  1105.     POP    AF
  1106.     RET
  1107. ;
  1108. DIN:            ;Get char - if available
  1109.     PUSH    BC
  1110.     PUSH    DE
  1111.     PUSH    HL
  1112.     LD    C,6        ;Set Direct CON I/O funtion
  1113.     LD    E,0FFH        ;Flag as input request
  1114.     CALL    BDOS
  1115.     POP    HL
  1116.     POP    DE
  1117.     POP    BC
  1118.     RET
  1119. ;
  1120.     END
  1121.