home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / MBUG / MBUG075.ARC / BUTCH.BAS < prev    next >
BASIC Source File  |  1979-12-31  |  9KB  |  207 lines
  1. 1 PRINT CHR$(26);TAB(28);"BUTCH":CLEAR 2000
  2. 2 PRINT TAB(20);"COMPUTER IDIOCY, INC."
  3. 3 PRINT TAB(20);"HOOPERVILLE, KENTUCKY"
  4. 4 PRINT "TALK YOUR PROBLEMS OUT WITH BUTCH- BUT DON'T USE COMMAS!"
  5. 5 PRINT:PRINT:PRINT:PRINT
  6. 80 REM     -----INITIALIZATION-----
  7. 100 DIM S(36),R(36),N(36)
  8. 110 N1=36:N2=12:N3=112
  9. 120 FOR X=1 TO N1+N2+N3:READ Z$:NEXT X:REM SAME AS RESTORE
  10. 130 FOR X=1 TO N1
  11. 140 READ S(X),L:R(X)=S(X):N(X)=S(X)+L-1
  12. 150 NEXT X
  13. 160 PRINT "HI! I'M BUTCH THE BARTENDER. WHAT'S YER BEEF?"
  14. 170 REM
  15. 180 REM     -----USER INPUT SECTION-----
  16. 190 REM
  17. 200 INPUT I$
  18. 201 I$=" "+I$+"  "
  19. 210 REM  GET RID OF APOSTROPHES
  20. 220 FOR L=1 TO LEN(I$)
  21. 230 IF MID$(I$,L,1)="'"THEN I$=LEFT$(I$,L-1)+RIGHT$(I$,LEN(I$)-L):GOTO 230
  22. 240 IF L+4<=LEN(I$)THEN IF MID$(I$,L,4)="SHUT"THEN PRINT"SHUT UP...":END
  23. 250 NEXT L
  24. 255 IF I$=P$ THEN PRINT "DON'T REPEAT YOURSELF, JERKOFF!":GOTO 170
  25. 260 REM
  26. 270 REM     -----FIND KEYWORD IN I$-----
  27. 280 REM
  28. 290 RESTORE
  29. 295 S=0
  30. 300 FOR K=1 TO N1
  31. 310 READ K$
  32. 315 IF S>0 THEN 360
  33. 320 FOR L=1 TO LEN(I$)-LEN(K$)+1
  34. 340 IF MID$(I$,L,LEN(K$))=K$THEN S=K:T=L:F$=K$
  35. 350 NEXT L
  36. 360 NEXT K
  37. 365 IF S>0 THEN K=S:L=T:GOTO 390
  38. 370 K=36:GOTO 570:REM  WE DIDN'T FIND ANY KEYWORDS
  39. 380 REM
  40. 390 REM     TAKE RIGHT PART OF STRING AND CONJUGATE IT
  41. 400 REM     USING THE LIST OF STRINGS TO BE SWAPPED
  42. 410 REM
  43. 420 RESTORE:FOR X=1 TO N1:READ Z$:NEXT X:REM SKIP OVER KEYWORDS
  44. 430 C$=" "+RIGHT$(I$,LEN(I$)-LEN(F$)-L+1)
  45. 440 FOR X=1 TO N2/2
  46. 450 READ S$,R$
  47. 460 FOR L= 1 TO LEN(C$)
  48. 470 IF L+LEN(S$)>LEN(C$) THEN 510
  49. 480 IF MID$(C$,L,LEN(S$))<>S$ THEN 510
  50. 490 C$=LEFT$(C$,L-1)+R$+RIGHT$(C$,LEN(C$)-L-LEN(S$)+1)
  51. 495 L=L+LEN(R$)
  52. 500 GOTO 540
  53. 510 IF L+LEN(R$)>LEN(C$)THEN 540
  54. 520 IF MID$(C$,L,LEN(R$))<>R$ THEN 540
  55. 530 C$=LEFT$(C$,L-1)+S$+RIGHT$(C$,LEN(C$)-L-LEN(R$)+1)
  56. 535 L=L+LEN(S$)
  57. 540 NEXT L
  58. 550 NEXT X
  59. 555 IF MID$(C$,2,1)=" "THEN C$=RIGHT$(C$,LEN(C$)-1):REM ONLY 1 SPACE
  60. 560 REM
  61. 570 REM     NOW USING THE KEYWORD NUMBER (K) GET REPLY
  62. 580 REM
  63. 590 RESTORE:FOR X= 1 TO N1+N2:READ Z$:NEXT X
  64. 600 FOR X=1 TO R(K):READ F$:NEXT X:REM  READ RIGHT REPLY
  65. 610 R(K)=R(K)+1: IF R(K)>N(K) THEN R(K)=S(K)
  66. 620 IF RIGHT$(F$,1)<>"*" THEN PRINT F$:P$=I$:GOTO 170
  67. 630 PRINT LEFT$(F$,LEN(F$)-1);C$
  68. 640 P$=I$:GOTO 170
  69. 1000 REM
  70. 1010 REM     -----PROGRAM DATA FOLLOWS-----
  71. 1020 REM
  72. 1030 REM     KEYWORDS
  73. 1040 REM
  74. 1050 DATA "CAN YOU","CAN I","YOU ARE","YOURE","I DONT","I FEEL"
  75. 1060 DATA "WHY DONT YOU","WHY CANT I","ARE YOU","I CANT","I AM","IM "
  76. 1070 DATA "YOU ","I WANT","WHAT","HOW","WHO","WHERE","WHEN","WHY"
  77. 1080 DATA "NAME","CAUSE","SORRY","DREAM","HELLO","HI ","MAYBE"
  78. 1090 DATA " NO","YOUR","ALWAYS","THINK","ALIKE","YES","FRIEND"
  79. 1100 DATA "COMPUTER","NOKEYFOUND"
  80. 1200 REM
  81. 1210 REM     STRING DATA FOR CONJUGATIONS
  82. 1220 REM
  83. 1230 DATA " ARE "," AM ","WERE ","WAS "," YOU "," I ","YOUR ","MY "
  84. 1235 DATA " IVE "," YOUVE "," IM "," YOURE "
  85. 1300 REM
  86. 1310 REM     REPLIES
  87. 1320 REM
  88. 1330 DATA "LOOK CHUMP, DON'CHA THINK I CAN*"
  89. 1340 DATA "MAYBE YOU WANNA*"
  90. 1350 DATA "HEY, YOU WANT ME TO BLE TO*"
  91. 1360 DATA "MAYBE YOU DON'T WANNA*"
  92. 1365 DATA "DO YOU WANT TO BE ABLE TO*"
  93. 1370 DATA "WHERE THE HELL DIDJA GET THE IDEA I'M*"
  94. 1380 DATA "SO BIG DEAL. YOU GET OFF THINKIN' THAT I'M*"
  95. 1390 DATA "MAYBE YOU JUST WANNA*"
  96. 1400 DATA "HEY, DIDJA EVER WISH YOU WAS*"
  97. 1410 DATA "DON'CHA REALLY*"
  98. 1420 DATA "WHY DON'CHA*"
  99. 1430 DATA "WELL, DO YOU WANNA*"
  100. 1440 DATA "DOES THAT SCREW YOUR HEAD UP ANY?"
  101. 1450 DATA "HEY THAT'S RICH. TELL ME MORE ABOUT DAT."
  102. 1460 DATA "IZZIT REAL REGULAR-LIKE THAT YA FEEL*"
  103. 1470 DATA "DO YOU GET OFF ON FEELIN'*"
  104. 1480 DATA "GIMME A FRIGGIN' BREAK. YOU THINK I DON'T*"
  105. 1490 DATA "MAYBE WHEN I'M GOOD AND READY I'LL*"
  106. 1500 DATA "HEY, I JUST WORK HERE. YOU WANT ME TO*"
  107. 1510 DATA "GEEZ! YOU THINK YOU OUGHTA BE ABLE TO*"
  108. 1520 DATA "WHY THE HELL CAN'T YOU*"
  109. 1530 DATA "WHY ARE YOU SO FRIGGIN' CURIOUS ABOUT WHETHER I'M*"
  110. 1540 DATA "WOULD'JA RATHER I WEREN'T*"
  111. 1550 DATA "MAYBE IN YOUR WILDEST FRIGGIN' DREAMS I'M*"
  112. 1560 DATA "YOU'RE A REAL DOWNER, JERKOFF. WHY CAN'T YOU*"
  113. 1570 DATA "OH SURE. HAVE YOU EVEN TRIED?"
  114. 1580 DATA "HEY, MIRACLES HAPPEN. MAYBE NOW YOU CAN*"
  115. 1590 DATA "YEAH? TELL ME ANOTHER ONE!"
  116. 1600 DATA "WHOA- THAT'S HEAVY! HOW LONG YOU BEEN*"
  117. 1610 DATA "HEY, TAKES ALL KINDS. YOU THINK IT'S NORMAL TO BE*"
  118. 1620 DATA "SO DO YOU GET OFF ON BEIN'*"
  119. 1630 DATA "YOU WRITIN' MY FRIGGIN' BIOGRAPHY? WE'RE TALKIN' ABOUT YOU."
  120. 1640 DATA "LEMME GET THIS STRAIGHT- I*"
  121. 1650 DATA "THINK REAL HARD. YOU DIDN'T REALLY MEAN ME DIDJA?"
  122. 1660 DATA "INNERESTING. WHAT WOULD IT MEAN IF YOU GOT*"
  123. 1670 DATA "HAW HAW HAW! NOW WHY DO YOU WANT*"
  124. 1680 DATA "HEY, JUST MAKE BELIEVE YOU REALLY GOT*"
  125. 1690 DATA "WELL YOU AIN'T WORKIN' WITH MUCH. WHAT IF YOU NEVER GOT*"
  126. 1700 DATA "Y'KNOW, I USED TO WANT*"
  127. 1710 DATA "THAT'S PRETTY PERSONAL CRAP. WHY DO YOU WANNA KNOW?"
  128. 1720 DATA "IZZAT SOMETHIN' YOU FEEL WEIRD ABOUT?"
  129. 1730 DATA "WELL WHAT THE HELL D'YA YOU WANT ME TO SAY?"
  130. 1740 DATA "HEY, WHADDA YOU THINK?"
  131. 1750 DATA "ROD SERLING SHOULDA HEARD THIS BULLCRAP. REALLY!"
  132. 1760 DATA "HEY, WHADDA YOU REALLY GETTIN' AT?"
  133. 1770 DATA "YOU EVER ASKED ANYONE BUT A BARTENDER?"
  134. 1780 DATA "YOU ASK PEOPLE THIS KINDA STUFF REAL OFTEN?"
  135. 1790 DATA "WHAT'RE YOU REALLY THINKIN' WHEN YOU ASK THAT?"
  136. 1800 DATA "HEY, I GOTTA BUSINESS TO RUN. DON'T TELL ME NAMES!"
  137. 1810 DATA "OH YEAH- THINK I HEARD THAT NAME IN A RAPE TR TELL ME MORE."
  138. 1820 DATA "GET OUTTA HERE. IS THAT THE REAL REASON?"
  139. 1830 DATA "DON'T NOTHIN' ELSE COME TO MIND?"
  140. 1840 DATA "DON'T THAT SUGGEST SOMETHIN' TO YOU?"
  141. 1850 DATA "WELL WHAT THE HELL ELSE COULD IT BE?"
  142. 1860 DATA "HEY, DON'T SNIVEL AT THE BAR!"
  143. 1870 DATA "TURN OFF THE FRIGGIN' WATERWORKS- I'LL GET OVER IT."
  144. 1880 DATA "I NEVER APOLOGIZE FOR NOTHIN'. WHAT'S IT FEEL LIKE?"
  145. 1890 DATA "HEY, ANYTHING YOU SAY."
  146. 1900 DATA "BOY, THAT'S A REAL SHEET CHANGER. WHADDA YOU THINK IT MEANS?"
  147. 1910 DATA "DO YOU DREAM REAL REGULAR?"
  148. 1920 DATA "WHO SHOWS UP IN YER DREAMS?"
  149. 1930 DATA "LOOK, DO YOUR DREAMS MAKE YOU FEEL NUTS SOMETIMES?"
  150. 1940 DATA "YEAH, YEAH, PLEASED TO MEETCHA. WHAT'S ON YER MIND?"
  151. 1950 DATA "DON'T SOUND LIKE YOU'D WANTA PLACE NO BETS ON THAT"
  152. 1960 DATA "PRETTY WISHY-WASHY. SCARED TO ADMIT THE TRUTH?"
  153. 1970 DATA "WOOF- YOU SURE CAN BE A DOWNER!"
  154. 1980 DATA "AIN'CHA SURE?"
  155. 1990 DATA "DON'CHA KNOW?"
  156. 2000 DATA "HEY, YOU TRYIN' TO BE A JERKOFF?"
  157. 2010 DATA "YOU'RE BEIN' A REAL JERKOFF ABOUT THIS, AIN'CHA?"
  158. 2020 DATA "WHY THE HELL NOT?"
  159. 2030 DATA "YOU SURE ABOUT DAT?"
  160. 2040 DATA "HOW COME?"
  161. 2050 DATA "WHAT'S THE BIG DEAL ABOUT MY*"
  162. 2060 DATA "WELL WHAT ABOUT YOUR OWN*"
  163. 2070 DATA "I DON'T FOLLOW YA. GIMME A FR'INSTANCE."
  164. 2080 DATA "OH YEAH? WHEN?"
  165. 2090 DATA "HEY, WHAT THE HECK ARE YOU THINKIN' ABOUT?"
  166. 2100 DATA "COME ON! ALWAYS?"
  167. 2110 DATA "YOU REALLY THINK THAT?"
  168. 2120 DATA "BUT'CHER NOT SURE YOU*"
  169. 2130 DATA "HUH. YOU GOT DOUBTS YOU*"
  170. 2140 DATA "YEAH? IN WHAT WAY?"
  171. 2150 DATA "G'WAN! TELL ME HOW."
  172. 2160 DATA "OKAY, SHERLOCK- WHAT'ZAT MEAN TO YOU?"
  173. 2170 DATA "WHAT ELSE DO YOU THINK IS GOIN' ON HERE?"
  174. 2180 DATA "YOU THINK THERE COULD BE SOME KINDA CONNECTION?"
  175. 2190 DATA "OH YEAH? HOW?"
  176. 2200 DATA "YOU SEEM PRETTY FRIGGIN' SURE OF THAT."
  177. 2210 DATA "NAH, THAT CAN'T BE RIGHT. YOU SURE?"
  178. 2220 DATA "UH HUH, UH HUH."
  179. 2230 DATA "BULLCRAP."
  180. 2240 DATA "FRIENDS? YOU? WHADDA YOU KNOW ABOUT FRIENDS?"
  181. 2250 DATA "DO YOUR FRIENDS KINDA GIVE YOU THE CREEPS?"
  182. 2260 DATA "DO EVEN YOUR SO-CALLED FRIENDS PICK ON YOU?"
  183. 2270 DATA "YOU SURE YOU EVEN GOT ANY FRIENDS?"
  184. 2280 DATA "ARE YOU A PAIN IN THE ASS FOR YOUR FRIENDS?"
  185. 2290 DATA "HEY, MAYBE YOU WORRY ABOUT GETTIN' TOO CLOSE TO YER FRIENDS"
  186. 2300 DATA "DO COMPUTERS GIVE YOU THE WILLIES?"
  187. 2310 DATA "HEY ARE YOU TALKIN' ABOUT ME? YOU TALKIN' ABOUT ME?!"
  188. 2320 DATA "DO MACHINES SCARE THE PISS OUTTA YOU?"
  189. 2330 DATA "HEY, WHADDA COMPUTERS GOT TO DO WITH ANYTHING?"
  190. 2340 DATA "HOW COME YOU THINK YOU CAN BLAME MACHINES FOR YOUR PROBLEM?"
  191. 2350 DATA "DON'CHA THINK COMPUTERS CAN HELP PEOPLE WITH STUFF?"
  192. 2360 DATA "WHAT'S SO CRAPPY ABOUT MACHINES?"
  193. 2370 DATA "SAY, DO YOU GOT SOMETHING WRONG UPSTAIRS?"
  194. 2380 DATA "PUT'CHER THINKIN' HAT ON. WHADDA YOU THINK THAT MEANS?"
  195. 2390 DATA "OH RIGHT, RIGHT. SURE."
  196. 2400 DATA "WAITAMINNIT- I AIN'T GETTIN' YOUR DRIFT"
  197. 2410 DATA "COME ON, SPIT IT OUT SO I CAN UNNERSTAND IT."
  198. 2420 DATA "TELL ME MORE ABOUT DAT."
  199. 2430 DATA "YOU DON'T FRIGGIN' SAY..."
  200. 2500 REM
  201. 2510 REM     DATA FOR FINDING RIGHT REPLIES
  202. 2520 REM
  203. 2530 DATA 1,3,4,2,6,4,6,4,10,4,14,3,17,3,20,2,22,3,25,3
  204. 2540 DATA 28,4,28,4,32,3,35,5,40,9,40,9,40,9,40,9,40,9,40,9
  205. 2550 DATA 49,2,51,4,55,4,59,4,63,1,63,1,64,5,69,5,74,2,76,4
  206. 2560 DATA 80,3,83,7,90,3,93,6,99,7,106,6
  207. UTERS GIVE YOU THE WIL