home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / MBUG / MBUG061.ARC / LIBADD.CMD < prev    next >
OS/2 REXX Batch file  |  1979-12-31  |  3KB  |  99 lines
  1. *************************************** LIBADD.CMD
  2. *************************************** Add new data.
  3. ************** Open Data Files
  4. SELECT PRIMARY
  5. USE LIBRARY INDEX AUTHORS,DATES
  6. SELECT SECONDARY
  7. USE KEYWORDS INDEX KEYWORDS
  8. SET EXACT ON
  9. ************** Initialize memory variables.
  10. STORE "               " TO K1,K2,K3,K4,K5,K6,K7
  11.  
  12. SELECT PRIMARY
  13. GO BOTT
  14. DO WHILE AUTHOR <> " " .OR. # <= 1
  15.    ************ Display custom APPEND screen, (which
  16.    ************ was created with ZIP).
  17.    ERASE
  18.    APPEND BLANK
  19.    @  1, 3 SAY "Record No. "+STR(#,3)+" Enter new Data, ^Q to Quit"
  20.    @  2, 0 SAY "--------------------------------------------------"
  21.    @  2,50 SAY "------------------------------"
  22.    @  4, 3 SAY "Author"
  23.    @  4,12 GET AUTHOR
  24.    @  5, 3 SAY "Title"
  25.    @  5,12 GET TITLE
  26.    @  6, 3 SAY "Pub."
  27.    @  6,12 GET PUB
  28.    @  7, 3 SAY "Date"
  29.    @  7,12 GET DATE PICT "99/99/99"
  30.    @  7,26 SAY "Pages"
  31.    @  7,32 GET PAGES
  32.    @  9, 3 SAY "Abstract"
  33.    @  9,12 GET ABSTRACT
  34.    @ 13, 3 SAY "Keyword 1"
  35.    @ 13,13 GET K1
  36.    @ 14, 3 SAY "Keyword 2"
  37.    @ 14,13 GET K2
  38.    @ 15, 3 SAY "Keyword 3"
  39.    @ 15,13 GET K3
  40.    @ 16, 3 SAY "Keyword 4"
  41.    @ 16,13 GET K4
  42.    @ 17, 3 SAY "Keyword 5"
  43.    @ 17,13 GET K5
  44.    @ 18, 3 SAY "Keyword 6"
  45.    @ 18,13 GET K6
  46.    @ 19, 3 SAY "Keyword 7"
  47.    @ 19,13 GET K7
  48.    @ 21, 0 SAY "--------------------------------------------------"
  49.    @ 21,50 SAY "------------------------------"
  50.    READ
  51.  
  52.  
  53.    ****************** ONLY perform this step if not exiting this program.
  54.    IF AUTHOR <> " "
  55.  
  56.       ****************** Update the Keyword File.
  57.       SELECT SECONDARY
  58.       STORE " " TO TEMPKEY
  59.       STORE 1 TO COUNT
  60.       STORE STR(COUNT,1) TO MAC
  61.  
  62.       DO WHILE K&MAC <> " " .AND. COUNT < 8
  63.          STORE !(K&MAC) TO K&MAC
  64.          FIND &K&MAC
  65.          IF # > 0
  66.             REPLACE KEYNO WITH KEYNO+1
  67.          ELSE
  68.             APPEND BLANK
  69.             REPLACE KEYWORD WITH K&MAC
  70.             REPLACE KEYNO WITH 1
  71.          ENDIF (# > 0)
  72.          *** Put keyword into temporary TEMPKEY string.
  73.          STORE TEMPKEY+TRIM(K&MAC)+", " TO TEMPKEY
  74.  
  75.          **** Clear out K&MAC memory variables, and increment count.
  76.          STORE "               " TO K&MAC
  77.          STORE COUNT +1 TO COUNT
  78.          STORE STR(COUNT,1) TO MAC
  79.       ENDDO (k&mac<>" ")
  80.  
  81.    ENDIF [not exiting this program (author <> "")]
  82.  
  83.  
  84. SELECT PRIMARY
  85. *********************** Put tempkey into keywords on Primary file.
  86. REPLACE KEYWORDS WITH TEMPKEY
  87.  
  88. ENDDO (while author <> " ")
  89.  
  90. *********************** Get rid of any "blank" records.
  91. DELETE ALL FOR AUTHOR = " " .AND. TITLE = " "
  92. PACK
  93. *********************** Return to Main Menu.
  94. SET EXACT OFF
  95. RETURN
  96.  
  97.  
  98.  
  99.