home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / MBUG / MBUG055.ARC / CROSSREF.BAS < prev    next >
BASIC Source File  |  1979-12-31  |  5KB  |  158 lines
  1. 1 ESC$=CHR$(27):CS$=CHR$(26)
  2. 10 PRINT CS$"CROSSREF    -    BASIC-80 VERSION"
  3. 20 PRINT:PRINT"LISTS ALL VARIABLES AND REFERENCED LINE NUMBERS"
  4. 40 PRINT STRING$(47,"-")
  5. 60 DEFINT I-J:LW=80
  6. 70 ON ERROR GOTO 1480
  7. 80 DIM RW$(113),PT%(25),F$(10)
  8. 90 DIM VNXT%(290),V$(290),FRST%(200),LST%(200),RFL%(1000),NXT%(1000)
  9. 100 '
  10. 110 ' RESERVED WORDS
  11. 120 '
  12. 130 DATA ABS,AND,ASC,AS,ATN,AUTO,CDBL,CHR$,CINT,CLEAR,CLOSE
  13. 140 DATA CONT,COS,CSNG,CVD,CVI,CVS,DATA
  14. 150 DATA DEFDBL,DEFINT,DEFSNG,DEFSTR,DEFUSR,DEF,DIM,DSKI$,DSKO$
  15. 160 DATA DSKF,ELSE,END,EOF,EQV,ERASE,ERL,ERR,EXP,FIELD,FIX,FOR
  16. 170 DATA FRE,GET,GOSUB,GOTO,HEX$
  17. 180 DATA IF,IMP,INPUT,INPUT$,INP,INSTR,INT,KILL,LEFT$,LEN,LET
  18. 190 DATA LINE,LOC,LOF,LOG,LPRINT,LSET,MID$,MKD$,MKI$
  19. 200 DATA MKS$,MOD,NAME,NEXT,NOT,NULL,OCT$,ON,OPEN,OR,OUT
  20. 210 DATA PEEK,POKE,POS,PRINT,PUT
  21. 220 DATA READ,REM,RESET,RESTORE,RESUME,RETURN,RIGHT$,RND,RSET
  22. 230 DATA SGN,SIN,SPACE$,SPC(,SQR,STEP,STOP,STR$,STRING$,SWAP
  23. 240 DATA TAB(,TAN,THEN,TO
  24. 250 DATA USING,USR,VAL,VARPTR,WAIT,WEND,WHILE,WIDTH,XOR,"\"
  25. 260 '
  26. 270 'FILL ARRAY WITH RESERVED WORDS
  27. 280 '
  28. 290 RW=0
  29. 300 READ RW$
  30. 310 RW=RW+1:RW$(RW)=RW$:IF RW$="\"THEN 350
  31. 320 I=ASC(RW$)-ASC("A"):IF PT%(I)=0 THEN PT%(I)=RW
  32. 330 GOTO 300
  33. 340 '
  34. 350 FOR I= 0 TO 25:IF PT%(I)=0 THEN PT%(I)=RW
  35. 360 NEXT
  36. 370 '
  37. 380 ' GET LIST OF FILE NAMES
  38. 390 '
  39. 400 FX=0
  40. 410 PRINT:PRINT" ASCII SAVED PROGRAM  #"FX+1": ";:LINE INPUT L$
  41. 420 IF L$ ="" THEN IF FX<1 THEN 570 ELSE 480
  42. 430 IF INSTR(L$,".")=0 THEN L$=L$+".BAS"
  43. 440 NAME L$ AS L$
  44. 450 FX=FX+1:F$(FX)=L$
  45. 460 GOTO 410
  46. 470 '
  47. 480 PRINT:INPUT"DATE = ",D$
  48. 490 PRINT:PRINT"1) CROSS REFERENCE   2) LIST   3) BOTH : ";
  49. 495 M=VAL(INPUT$(1)):PRINT M
  50. 500 '
  51. 510 ' PROCESS LIST OF FILE NAMES
  52. 520 '
  53. 530 FOR F=1 TO FX
  54. 540 CLOSE:OPEN"I",1,F$(F):PRG$="'"+F$(F)+"   -   "+D$:GOSUB 610
  55. 550 NEXT
  56. 560 LPRINT STRING$(65-LZ,CHR$(10))
  57. 570 END
  58. 580 '
  59. 590 ' INITIALIZE FOR CROSS REFERENCE
  60. 600 '
  61. 610 LC=0:BC=0:PZ=0:V$="":C$="":VC=91:RC=-1
  62. 620 FOR I=0 TO 91:VNXT%(I)=-1:NEXT
  63. 630 IF M>1 THEN GOSUB 1520
  64. 640 '
  65. 650 ' INPUT LINE AND EXTRACT LINE NUMBBER
  66. 660 '
  67. 670 IF EOF(1) THEN 1200
  68. 680 LINE INPUT#1,L$:IF M>1 THEN GOSUB 1430:IF M=2 THEN 670
  69. 690 LG=LEN(L$):BRNCH=0:ER$="":LC=LC+1:BC=BC+LG
  70. 700 LP=INSTR(L$," "):LN=VAL(LEFT$(L$,LP)):PRINT LN,
  71. 710 IF LN>32767 THEN LN=LN-65536!
  72. 720 '
  73. 730 ' PARSE REST OF LINE
  74. 740 '
  75. 750 LP=LP+1:IF LP>LG THEN GOSUB 1010:GOTO 670
  76. 760 C$=MID$(L$,LP,1)
  77. 770 IF C$>="A"AND C$<="Z"THEN 890 ELSE IF C$>="0"AND C$<="9"THEN 1150
  78. 780 IF C$=" "THEN 750 ELSE IF C$<>","THEN BRNCH=0
  79. 790 IF C$=CHR$(34) THEN GOSUB 1010:LP=INSTR(LP+1,L$,C$):IF LP>0 THEN 750 ELSE 670
  80. 800 IF C$="'"THEN GOSUB 1010:GOTO 670
  81. 810 IF C$="&"THEN GOSUB 1010:V$=C$:GOTO 750
  82. 820 IF C$="$" OR C$="!"OR C$="%"OR C$="#"THEN GOSUB 1130:GOTO 750
  83. 830 IF C$="("THEN GOSUB 1130
  84. 840 GOSUB 1010:IF C$<>","THEN ER$=""
  85. 850 GOTO 750
  86. 860 '
  87. 870 ' TEST FOR COMMAND
  88. 880 '
  89. 890 C=ASC(C$):P=PT%(C-ASC("A")):BRNCH=0
  90. 900 IF C<ASC(RW$(P)) THEN 1160
  91. 910 IF INSTR(LP,L$,RW$(P))<>LP THEN P=P+1: GOTO 900
  92. 920 GOSUB 1010:RW$=RW$(P)
  93. 930 IF RW$="DATA" THEN LP=INSTR(LP,L$,":"):IF LP>0 THEN 750 ELSE 670
  94. 940 IF RW$="REM" THEN 670
  95. 950 IF RW$="GOTO" OR RW$="GOSUB" OR RW$="ELSE"OR RW$="RESUME" THEN BRNCH =1
  96. 960 IF RW$="ERASE"THEN ER$="("ELSE ER$=""
  97. 970 LP=LP+LEN(RW$)-1:GOTO 750
  98. 980 '
  99. 990 ' END VARIABLE
  100. 1000 '
  101. 1010 IF V$="" THEN RETURN
  102. 1020 IF V$>="A"THEN V$=V$+ER$:C=ASC(V$)+1 ELSE IF V$>="0" THEN V$= RIGHT$("    "+V$,5):C=VAL(LEFT$(V$,2)) ELSE 1090
  103. 1030 IL=-1:I=C
  104. 1040 IF V$>V$(I) THEN IL=I:I=VNXT%(I):IF I>0 THEN 1040 ELSE 1060
  105. 1050 IF V$=V$(I) THEN J=LST%(I-91):IF RFL%(J)=LN THEN 1090 ELSE RC=RC+1:NXT%(J)=RC:GOTO 1080
  106. 1060 VC=VC+1:IF IL>=0 THEN VNXT%(IL)=VC
  107. 1070 V$(VC)=V$:VNXT%(VC)=I:RC=RC+1:FRST%(VC-91)=RC:I=VC
  108. 1080 RFL%(RC)=LN:NXT%(RC)=-1:LST%(I-91)=RC
  109. 1090 V$="":RETURN
  110. 1100 '
  111. 1110 ' EXPAND VARIABLE
  112. 1120 '
  113. 1130 IF V$<>""THEN V$=V$+C$
  114. 1140 RETURN
  115. 1150 IF V$="" AND BRNCH=0 THEN 750
  116. 1160 V$=V$+C$:GOTO 750
  117. 1170 '
  118. 1180 ' LIST VARIABLES
  119. 1190 '
  120. 1200 IF M=2 THEN RETURN
  121. 1210 PZ=0:GOSUB 1400
  122. 1220 FOR J=0 TO 91:V=J
  123. 1230 V=VNXT%(V):IF V<0 THEN 1340
  124. 1240 IF LZ>56 THEN GOSUB 1400 ELSE SZ=SZ+1:IF SZ=3 THEN GOSUB 1410
  125. 1250 RZ=0:I=FRST%(V-91):LPRINT V$(V);
  126. 1260 IF RZ=0 THEN LPRINT TAB(16);
  127. 1270 LN=RFL%(I):IF LN<0 THEN LN=LN+65536!
  128. 1280 LPRINT USING"    #####";LN,
  129. 1290 RZ=RZ+1
  130. 1300 IF RZ>6 THEN RZ=0:LPRINT:LZ=LZ+1:IF LZ>56 THEN GOSUB 1400
  131. 1310 I=NXT%(I):IF I>0 THEN 1260
  132. 1320 IF RZ>0 THEN LPRINT:LZ=LZ+1
  133. 1330 GOTO 1230
  134. 1340 NEXT J
  135. 1350 '
  136. 1360 LPRINT STRING$(79,"=")
  137. 1370 LPRINT"LINES:"LC"     BYTES:"BC"     SYMBOLS:"VC-91"     REFERENCES:"RC+1
  138. 1380 LZ=LZ+2:RETURN
  139. 1390 '
  140. 1400 GOSUB 1520:LPRINT"SYMBOL"TAB(20)"REFERENCE LINE":LZ=LZ+1
  141. 1410 LPRINT STRING$(79,"-"):LZ=LZ+1:SZ=0:RETURN
  142. 1420 '
  143. 1430 X=1
  144. 1440 IF LZ>60 OR RIGHT$(L$,3)="'PG"THEN GOSUB 1520
  145. 1450 Y=INSTR(X,L$,CHR$(10)):IF Y>0 THEN LPRINT MID$(L$,X,Y-X):LZ=LZ+1:X=Y+1:GOTO 1450
  146. 1460 LPRINT MID$(L$,X,LW):LZ=LZ+1:X=X+LW:IF X<LEN(L$) THEN 1460 ELSE RETURN
  147. 1470 '
  148. 1480 IF ERR=53 THEN PRINT:PRINT"FILE NOT FOUND":RESUME 410
  149. 1490 IF ERR=58 THEN RESUME 450
  150. 1500 ON ERROR GOTO 0
  151. 1510 '
  152. 1520 LPRINT CHR$(140)
  153. 1530 PZ=PZ+1:LPRINT TAB(72)"PG#"PZ
  154. 1540 LPRINT PRG$:LPRINT
  155. 1550 LZ=3:RETURN
  156. ON ERROR GOTO 0
  157. 1510 '
  158. 1520 LPRINT CH