home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / MBUG / MBUG016.ARC / WORDBEE1.WSF < prev    next >
Text File  |  1979-12-31  |  5KB  |  178 lines
  1. ;    WORDBEE  MODIFICATIONS
  2. ;
  3. ;  Listing 1 which implements additional dot commands for
  4. ;  printing enhancements using Alpha-80 or similar.
  5. ;
  6.     DEFR    16
  7. LINE    EQU    0CC6EH    ;  Line space, Left margin, etc
  8. HEAD    EQU    0CCE1H    ;  Page header
  9. PAGE    EQU    0CCA9H    ;  Page number, length, gap
  10. CRLF    EQU    0CD04H    ;  Line feed suppression (.ZN)
  11. ES    EQU    0CD14H    ;  .ES 
  12.     ORG    0CBDCH    ;  Where the existing test routine                           is located
  13. CJUST    CP    'J'    ;  .JY ?
  14.     JR    Z,JUST
  15. CNEW    CP    'N'    ;  .NP ?
  16.     JR    Z,NEW
  17. CLINE    CP    'L'    ;  .LS#xx, .LM#xx, .LL#xx ?
  18.     JP    Z,LINE
  19. ;   To add a .LH letterhead, amend line 210 to read                    JP    Z,LHEAD - refer text
  20. CHEAD    CP    'H'    ;  .HE ?
  21.     JP    Z,HEAD
  22. CPAGE    CP    'P'    ;  .PN#xx ?
  23.     JP    Z,PAGE
  24. CCRLF    CP    'Z'    ;  .ZN ?
  25.     JP    Z,CRLF
  26. CUNDR    CP    'U'    ;  Underline ?
  27.     JR    Z,UNDR
  28. CITAL    CP    'I'    ;  Italics ?
  29.     JR    Z,ITAL
  30. CEMPH    CP    'M'    ;  eMphasised ?
  31.     JR    Z,EMPH
  32. CDUBL    CP    'D'    ;  Double strike ?
  33.     JR    Z,DUBL
  34. ;
  35.     JP    CFORM    ;  Tests are continued at another                           location ( C039 )
  36. ;
  37.     NOP        ;  a few spare bytes
  38.     NOP
  39.     NOP
  40. CONTIN    POP    HL    ;  an unchanged part of the                                 original program @ CC0E
  41.     LD    (0521H),IY  ; put back pointer
  42.     RET        ; to the normal printing routine
  43. ;
  44. JUST    LD    A,(IY+2)    ;  Get the next char
  45.     CP    'Y'        ; is it .JY ?
  46.     JR    Z,JY        ; if yes
  47.     XOR    A        ; else it must be .JN
  48. JY      LD    (0512H),A   ; flag for Justify ( 0 if no )
  49.     RET
  50. ; The justify routine has been shortened by deleting the                  test for .JN assuming it must be, if it was not a .JY
  51. ;
  52. NEW    LD    A,(IY+2)  ; Get next char
  53.     CP    'P'      ; .NP ?
  54.     JR    NZ,CONTIN ; if no then the test failed
  55.     JP    0CA0EH    ; the .NP routine has not changed
  56. ;
  57. ITAL    LD    A,(IY+2)  ; Get next char
  58.     LD    B,34H      ; ESC 34 turns italics on
  59. ;
  60. ; The following short OUT routine sends ESC and the
  61. ; contents of B to the print routine if YES or else
  62. ; the B register is increased by 1 before sending
  63. SOUT    CP    'Y'      ; is char 'Y' in register A ?
  64.     JR    Z,PRINT   ; if yes
  65.     INC    B      ; else increase B register
  66.     JR    PRINT      ; and then send it
  67. ;
  68. EMPH    LD    A,(IY+2)  ; Get next char
  69.     LD    B,45H      ; eMphasised on is ESC 45
  70.     JR    SOUT      ; use same routine as italics
  71. ;
  72. DUBL    LD    A,(IY+2)  ; Get next char
  73.     LD    B,47H       ; Double on is ESC 47
  74.     JR    SOUT      ; as above, increases B for no
  75. ;
  76. PRINT    LD    A,1BH      ; the ESC char
  77.     CALL    0CD54H      ; actually send it to printer
  78.     LD    A,B      ; ready to send contents of B
  79. PRINT2    CALL    0CD54H      ; send that to printer too
  80.     RET  ; printer codes have now been sent, continue
  81. PRINT3    LD    B,C      ; if there are more codes to go
  82.     JR    PRINT      ; send them too
  83. ;
  84. BIG    LD    A,(IY+2)  ; Get next char
  85.     LD    BC,5701H  ; ESC 57 1 for on, ESC 57 0 off
  86.     JR    LOUT      ; a longer OUT routine below
  87. ;
  88. UNDR    LD    A,(IY+2)  ; Get next char
  89.     LD    BC,2D01H  ; ESC 2D 1 - on, ESC 2D 0 - off
  90. ;
  91. ; This longer OUT routine sends (if yes) ESC, contents
  92. ; of B, contents of C.   If no, C is decreased by 1.
  93. ;
  94. LOUT    CP    'Y'      ; is it yes ?
  95.     JR    Z,LPRINT  ; if yes, print ESC, (B), (C)
  96.     DEC    C      ; must be no, decrease C
  97. LPRINT    CALL    PRINT      ; print ESC, (B)
  98.     LD    A,C      ; ready with next code
  99.     JR    PRINT2      ; now print that too
  100. ;
  101.     NOP
  102.     NOP
  103.     NOP
  104.     NOP
  105. ; 
  106. ;
  107. ;
  108.     ORG    0C017    ; The start of 'Checking . . .
  109. ;
  110.     CALL    0C1C8    ; switches on parallel port
  111.     LD    A,2    ; but is no longer required
  112.     LD    (00E3),A ; as parallel is now default.
  113. ;
  114. ; The next part is just a copy of C057 - C068 which has
  115. ; in effect been moved to C01F
  116. ;
  117.     LD    HL,0500
  118.     LD    A,(HL)
  119.     CP    55
  120.     JP    Z,0C1D5    ; Top of file
  121.     LD    (HL),55
  122.     LD    B,0E1
  123. AGAIN    INC    HL
  124.     LD    (HL),0
  125.     DJNZ    AGAIN
  126.     JP    0C069    ; which used to follow this
  127. ; a few NOPs to fill a hole
  128.     NOP
  129.     NOP
  130.     NOP
  131.     NOP
  132.     NOP
  133. ;
  134. CFORM    CP    'F'    ; Form feed ?
  135.     JR    NZ,CCOND
  136.     LD    A,0CH    ; FF character
  137.     CALL    0CD54    ; send it to printer
  138.     RET        ; finished
  139. ;
  140. CCOND    CP    'C'    ; Condensed ?
  141.     JR    Z,COND
  142. CSUBP    CP    'S'    ; Subscript or Superscript ?
  143.     JP    Z,SUBP
  144. CES    CP    'E'    ; .ES command ?
  145.     JP    Z,ES
  146. CBIG    CP    'B'    ; Big (enlarged) ?
  147.     JP    Z,BIG
  148. ; No more tests, so must have been a wrong command.
  149.     JP    CONTIN    ; Continue on with printing
  150. ;
  151. COND    LD    A,(IY+2)  ; Get next char
  152.     CP    'Y'      ; is it .CY ?
  153.     LD    A,0FH      ; it may be
  154.     JR    Z,CONOUT  ; if it was
  155.     LD    A,12      ; must be no
  156. CONOUT    JP    0CD54 ; send char 0F for yes or 12 for no
  157.     NOP
  158.     NOP        ; a few more gaps
  159. ;
  160. ; Out of space so jump to another hole
  161. ;
  162.     ORG    0C138    ; Where 'Are you sure' used to be
  163. ;
  164. SUBP    LD    A,(IY+2)  ; Get next char
  165.     LD    BC,5301      ; Subscript perhaps
  166.     CP    'B'      ; is it ?
  167.     JR    Z,SUB      ; if so
  168.     CP    'P'      ; suPerscript ?
  169.     JR    Z,SUPER      ; if correct
  170.     LD    BC,4854      ; must be a cancellation
  171.     CALL    PRINT      ; to send ESC (B)
  172.     JP    PRINT3      ; to send ESC (C)
  173. SUPER    DEC    C      ; change BC to 5300
  174. SUB    JP    LPRINT      ; which sends ESC (B) (C)
  175. ; Note how the contents of BC vary for each condition.
  176. ;
  177.     END          ; of listing 1
  178.