home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.barnyard.co.uk
/
2015.02.ftp.barnyard.co.uk.tar
/
ftp.barnyard.co.uk
/
cpm
/
walnut-creek-CDROM
/
MBUG
/
MBUG013.ARC
/
HILBERT2.PAS
< prev
next >
Wrap
Pascal/Delphi Source File
|
1979-12-31
|
3KB
|
116 lines
program HILBERT2;
{ Demonstration program in Turbo Pascal for
the MicroBee by Bob Burt
Program to set up PCG on the MicroBee for
LORES graphics and PLOT between any pair
of x,y coordinates, assuming a screen with
80 x 24 format. This version operates with
a plot routine with integer variables - so
limiting the maximum acceptable coordinate
to 128. Thus
x coordinate range: 0 to 128
y coordinate range: 0 to 71
0,0 at top left of screen
IMPORTANT : Compiler switch A must be set
to negative for the RECURSIVE procedures
and MAIN code ONLY ! }
{$C-}
const
w0 = 128; h0 = 64;
title = '*** Hilbert Curves ***';
var
i,n : byte;
h,t,w,x,y,x0,y0 : integer;
{$I normal.pro}
{$I lores80.pro}
{$I draw.pro}
{$I ploti.pro}
{$A-}
procedure B(i : byte); forward;
procedure C(i : byte); forward;
procedure D(i : byte); forward;
procedure A(i : byte);
begin if i > 0 then
begin
D(i - 1); t := x-w; plot(x,y,t,y); x := t;
A(i - 1); t := y-h; plot(x,y,x,t); y := t;
A(i - 1); t := x+w; plot(x,y,t,y); x := t;
B(i - 1)
end
end; {A(i)}
procedure B;
begin if i > 0 then
begin
C(i - 1); t := y+h; plot(x,y,x,t); y := t;
B(i - 1); t := x+w; plot(x,y,t,y); x := t;
B(i - 1); t := y-h; plot(x,y,x,t); y := t;
A(i - 1)
end
end; {B(i)}
procedure C;
begin if i > 0 then
begin
B(i - 1); t := x+w; plot(x,y,t,y); x := t;
C(i - 1); t := y+h; plot(x,y,x,t); y := t;
C(i - 1); t := x-w; plot(x,y,t,y); x := t;
D(i - 1)
end
end; {C(i)}
procedure D;
begin if i > 0 then
begin
A(i - 1); t := y-h; plot(x,y,x,t); y := t;
D(i - 1); t := x-w; plot(x,y,t,y); x := t;
D(i - 1); t := y+h; plot(x,y,x,t); y := t;
C(i - 1)
end
end; {D(i)}
begin {main}
clrscr;
gotoxy(24,8);
writeln(title);
repeat
gotoxy(10,11);
write(^G,'What order of Curve do you require (1 to 4 only) : ');
readln(n)
until (n > 0) and (n <5 );
gotoxy(44,24); {establish cursor position clear of graphics}
i := 0; h := h0; w := w0; x0 := w div 2; y0 := h div 2;
lores80;
plot(0,0,127,0); {plot frame}
plot(128,0,128,64);
plot(127,64,0,64);
plot(0,64,0,0);
repeat
i := i + 1; h := h div 2; w := w div 2;
x0 := x0 + (w div 2); y0 := y0 + (h div 2);
x := x0; y := y0;
A(i)
until i = n;
gotoxy(22,24);
write(title);
repeat until keypressed;
clrscr; {replace chr(128) with chr(32)}
normal;
writeln(^G)
end. {main}