home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / KAYPRO / KBSHW321.LBR / KBSHW321.AQM / KBSHW321.ASM
Assembly Source File  |  2000-06-30  |  40KB  |  1,483 lines
  1. ;  Kaypro BISHOW v3.21 - buffered bi-directional file scroll utility
  2. ;
  3. ; KPBISHOW is now completely compatible with standard Wordstar control
  4. ; keys and uses the Kaypro arrow keys for +/- scrolling and right and
  5. ; left margin control
  6. ;
  7. ; Ver 3.21, 8 Dec 84, Steve Sanders, Tampa, FL
  8. ;       - Oops, my mistake with the filename printing twice.
  9. ;         Removed (sic) code that I had added (it was late folks).
  10. ;         Call status line in one shot now like it should be.
  11. ;         Future rev planned to display current memory page number
  12. ;         and allow going directly to any given page number with
  13. ;         a CTRL-G nn  command.  Also go all the way to the back
  14. ;         of the file.
  15. ;
  16. ; Ver 3.20, 8 Dec 84, Steve Sanders, Tampa, FL
  17. ;       - Added the name of file being displayed on 25th line
  18. ;         
  19. ; Ver 3.10, 5 Dec 84, Steve Sanders, Tampa, Fl
  20. ;       - Added 25th line display of program name, vers #, and
  21. ;         "enter ? for help menu".  Stripped out all non-Kaypro
  22. ;         equates and short version code.
  23. ;
  24. ; Ver 3.00kp, 2 Dec 84, Steve Sanders, Tampa, Fl
  25. ;       - This version is for video-able Kaypros only
  26. ;         Made command structure the same as Wordstar for scrolling
  27. ;         forward and backward and also for advancing one line forward
  28. ;         or backward.  Text scroll is completely controlled by the
  29. ;         Kaypro cursor keys now - up, down, left, and right.
  30. ;         Changed help menu accordingly, added commands to menu that
  31. ;         were always in the old code but not documented.  Removed the
  32. ;         GRAF toggles as there are no line drawing routines for the
  33. ;         Kaypro used and other graphics don't need the GRAF byte toggled.
  34. ; 
  35. ; Ver 2.09KP, 25 Sep 84, Jim Gronek, Phoenix, Arizona 
  36. ;    - Added equates for Kaypro 2/4/10, reverse video codes on help
  37. ;      command (?), modified exit routines to re-enable cursor
  38. ;         even if filename not specified to BISHOW, added automatic
  39. ;      toggle for GRAF byte with ZCPR2/3 on K10's
  40. ;
  41. ; Ver 2.09, 7 Jan 84, Frans van Duinen, Toronto, Ont
  42. ;    - Modified USQ routines for higher speed (+10%) and
  43. ;     less memory usage.
  44. ;    - made USQ code optional through conditional assembly
  45. ;    - fixed a bug introduced with 2.08 and SHORT=TRUE 
  46. ;      (resulted from ASM's inability to nest IF/ENDIF) 
  47. ;    - fixed a bug  that reset FCBEX after open, whenever
  48. ;      sector 0 was read, (this resulted in BDOS assuming that
  49. ;      the current extent, whose allocation group nos were still
  50. ;      in the FCB, was the correct one. 
  51. ;    - Changed exit to clear screen only on Q or ^C exit,
  52. ;      to leave any messages visible
  53. ;    - Made wait after clear screen a cond assembly option
  54. ;
  55. ; Ver 2.08, 2 Jan 84, Frans van Duinen, Toronto, Ont
  56. ;    - added squeezed file capability
  57. ;    - added sidewise scrolling on ^I, ^L, steps of 8
  58. ;    - Osborne support for cursor keys, clr scr & scr size
  59. ;    - Changed FILBAK rtn to recognize top of file
  60. ;    - Set up flag to avoid unnecessary re-reading of
  61. ;      top of file 
  62. ;
  63. ;    The unsqueeze code was lifted from the USQ base code
  64. ;    by Dave Rand (Edmonton, Alberta) as adapted for LTYPE1
  65. ;    by S.Kluger (El Paso,Texas)
  66. ;    The code was lifted to allow continued use of ASM.COM 
  67. ;
  68. ; ** Original program code written by Phil Cary  23 Aug 82
  69. ;
  70. ; BISHOW is a  buffered,  bidirectional  version  of  SHOW.ASM
  71. ; which first appeared in Interface Age, November, 1981.  That
  72. ; program  could  only  scroll  forward  in  a  file, and read
  73. ; sectors from disk one at a time as they  were  sent  to  the
  74. ; console.   I  used SHOW frequently to take a quick look at a
  75. ; file without loading a  big  text  editor,  and  to  examine
  76. ; another  file  with the RUN command while in Wordstar.  TYPE
  77. ; does not work since it is not a file that Wordstar can  load
  78. ; and run.
  79. ;
  80. ; It was annoying when I went past the point I was looking for
  81. ; in a file with SHOW, and could not go backwards.  Thus, this
  82. ; bidirectional  version  which  uses  random access reads. In
  83. ; addition, buffering was added so that  the  number  of  disk
  84. ; reads  would  be  reduced,  and  moving  back and forth in a
  85. ; moderate sized file would be speeded up.  There is  a  trade
  86. ; off between the size of the buffer and the length of time it
  87. ; takes to refill the buffer which should be set to the user's
  88. ; preference.
  89. ;
  90. ; There are several customizing items in this program.  One is 
  91. ; the equate "maxsec" which sets the buffer size.   Another is 
  92. ; the  string  in the subroutine "clrscr" just after  the  org 
  93. ; statement.   This should be changed to erase the screen  and 
  94. ; home  the cursor for the user's terminal.   The program,  as 
  95. ; written,  requires a terminal with an erase screen and  home 
  96. ; cursor  function.   Some  terminals  do not allow  the  80th 
  97. ; column  to be filled without going to the  next  line.   For 
  98. ; this reason, the screen width ("maxchr") initially is set to 
  99. ; 79.   The screen sizes can be changed using the "S" (screen) 
  100. ; command.  The parameters that can be changed are the maximum 
  101. ; column  displayed ("maxchr"),  the minimum column  displayed 
  102. ; (allowing  you  to "window" the output),  and the number  of 
  103. ; lines ("scroln").   A zero for the maximum column  displayed 
  104. ; will  give and unlimited screen width.   The maximum  column 
  105. ; displayed  and  the number of lines can be set when  calling 
  106. ; BISHOW,  e.g.,  "BISHOW file.nam 79 24" will give 79 columns 
  107. ; and 24 lines,  and "BISHOW file.nam 79" will give 79 columns 
  108. ; with the default number of lines.  The last customizing item 
  109. ; is the "short" equate.   If this is chosen, the multiplicity 
  110. ; of command forms is not allowed (see the beginning to change 
  111. ; the  commands  used),  and certain messages  are  shortened.  
  112. ; This will allow BISHOW to fit into a 1K area.  If "short" is 
  113. ; false, the program is slightly over 1K.  Finally, direct I/O 
  114. ; to the console is used to avoid echoing the commands to  the 
  115. ; console as the CP/M write console function does.
  116. ;
  117. ; Just  a  small contribution to the public domain software as
  118. ; partial payment for the many fine and  educational  programs
  119. ; the system has given me.  Phil Cary.
  120. ;.........
  121. ;
  122. FALSE    EQU    0
  123. TRUE    EQU    NOT FALSE
  124. ;
  125. ; this code is now for Kaypro only -
  126. ;
  127. KAYPRO    EQU    TRUE        ;assemble for Kaypro 2/4/10
  128. ;
  129. SQUEEZE    EQU    TRUE        ;Generate code to handle squeezed files 
  130. NOWAIT    EQU    TRUE        ;Do not wait after clear screen
  131. ;
  132. ;    Operational equates
  133. ;
  134. MAXSEC    EQU    32        ;number of sectors in buffer
  135. SIGNAT    EQU    0FF76H        ;Signature for SQ files
  136. DLE    EQU    090H        ;Char flag for run compression (SQ)
  137. ;
  138. ;
  139.     IF    KAYPRO
  140. SCROLN    EQU    24        ;number of lines per scroll
  141. MAXCHR    EQU    79        ;number of characters per line
  142. ARWLFT    EQU    08H        ;Cursor left key (backspace)
  143. ARWUP    EQU    0BH        ;Cursor up key (vert tab)
  144. arwdwn    equ    0ah        ;cursor down key (linefeed)
  145. ARWRT    EQU    0CH        ;Cursor right key (formfeed)
  146.     ENDIF
  147. ;
  148. ;
  149. BASE    EQU    0        ;standard zero base CP/M
  150. ;
  151. ;    BDOS functions
  152. ;
  153. CONOUT    EQU    2        ;console write
  154. OPEN    EQU    15        ;open file
  155. CLOSE    EQU    16        ;close file
  156. READR    EQU    33        ;read file random access
  157. STDMA    EQU    26        ;set dma address
  158. ;
  159. ;    Page zero equates
  160. ;
  161. WBOOT    EQU    BASE        ;warm boot entry point
  162. BDOS    EQU    WBOOT+5        ;BDOS entry point
  163. FCB    EQU    WBOOT+5CH    ;default fcb drive number
  164. CMDTAIL    EQU    WBOOT+80H    ;location of command tail
  165. FCBFN    EQU    FCB+1        ;start of filename
  166. FCBFT    EQU    FCB+9        ;start of filetype
  167. FCBEX    EQU    FCB+12        ;current extent number
  168. FCBCRR    EQU    FCB+33        ;current record number, random access
  169. TPA    EQU    WBOOT+100H    ;transient program area
  170. ;
  171. ;    ASCII equates
  172. ;
  173. ENDMSG    EQU    0        ;null
  174. BELL    EQU    7        ;bell
  175. BS    EQU    8        ;Backspace
  176. TAB    EQU    9        ;tab
  177. LF    EQU    0AH        ;line feed
  178. CR    EQU    0DH        ;carriage return
  179. EOF    EQU    1AH        ;end of file
  180. ESC    EQU    1BH        ;escape
  181. SPACE    EQU    20H        ;space
  182. ;
  183. ;
  184.     ORG    TPA
  185. ;
  186.     JMP    START        ;skip over next subroutine
  187. ;
  188. CLRSCR: CALL    CDISP        ;command to home cursor and clear to
  189.     DB    1EH,17H,ENDMSG    ;end of screen for Kaypro 2/4/10
  190. ;
  191.     IF    NOWAIT
  192. ;
  193. WAIT:    MVI    B,0        ;waste time (may or may not be necessary)
  194. ;
  195. WAIT1:    XTHL            ;good time gobbeler!
  196.     XTHL
  197.     DCR    B
  198.     JNZ    WAIT1
  199.     RET            ;return from clrscr
  200. ;
  201.     ENDIF
  202. ;
  203. HELP2:    ; very fancy graphical help menu for the Kaypro
  204.     CALL    CDISP
  205.     DB    cr,lf
  206.     DB    ESC,'B0'
  207.     db    '     KPBISHOW v 3.21   Available Commands (same as Wordstar)   '
  208.     db    '  ',cr,lf,' ',esc,'B1'
  209.     db    ' ^C,Space bar,F, or C/R=forward a page     ^R or B=back 1 page '
  210.     DB    esc,'C1',' ',cr,lf,' ',esc,'B1'
  211.     DB    ' ^Z,+,arrow-down=forward 1 line      ^W,-,arrow-up=back 1 line '
  212.     db    esc,'C1',' ',cr,lf,' ',esc,'B1'
  213.     db    ' ^L or arrow-right=8 cols right   ^H or arrow-left=8 cols left '
  214.     db    esc,'C1',' ',cr,lf,' ',esc,'B1' 
  215.     db    ' ^S or S=set the screen parameters       Q or X=exits program  '
  216.     DB    ESC,'C1',' ',cr,lf,' ',esc,'B1'
  217.     db    '      Any other keys pressed will display this help menu       '
  218.     db    esc,'C1',' ',cr,lf
  219.     db    '                 Steven L. Sanders   08 Dec 84                 '
  220.     db    '  '
  221.     DB    esc,'C0',CR,LF,ENDMSG
  222.     JMP    GETCMD
  223. ;
  224. STATUS:        ; status line display for the Kaypro
  225.     CALL    CDISP
  226.     DB    ESC,'C7',1AH    ;disable status line and clear screen
  227.     DB    ESC,'B6'    ;save cursor position
  228.     DB    ESC,'B7'    ;enable status line
  229.     DB    ESC,'=8 '    ;position cursor to 25,0
  230.     DB    ESC,'B0'    ;inverse video mode
  231.     DB    ESC,'B1'    ;dim mode
  232.     DB    ' *KPBISHOW* '
  233.     DB    ESC,'C1'    ;dim off
  234.     DB    ' Viewing file:'
  235.     DB    endmsg
  236.  
  237. ; print filename routine
  238. ;
  239.     lxi    h,cmdtail    ;get filename from command tail
  240.     mov    b,m        ;get number of chrs
  241.     inx    h        ;point at first chr
  242.     inr    b
  243. prtfn1: mov    a,m        ;get the chr
  244.     call    co        ;output it
  245.     inx    h        ;move pointer
  246.     dcr    b        ;decrement the b reg
  247.     jnz    prtfn1        ;if not 0 then loop till done
  248. ;
  249.     call    cdisp        ;now finish rest of status line
  250.     db    ' '
  251.     db    esc,'B1'    ;dim mode
  252.     db    esc,'B2'    ;blink on 
  253.     db    '   ? for help '
  254.     db    esc,'C2'    ;blink off
  255.     db    '  S. Sanders  12/08/84 '
  256.     db    esc,'C1'    ;dim off
  257.     DB    ESC,'C0'    ;inverse video off
  258.     DB    ESC,'C6'    ;recall cursor position
  259.     DB    ENDMSG
  260.     ret
  261.  
  262. ;
  263. ; start of program (finally)
  264. ;
  265. START:    LXI    H,0        ;get ccp's stack
  266.     DAD    SP
  267.     SHLD    STACK        ;save old stack for later
  268.     LXI    SP,STACK    ;set new stack
  269.     LXI    H,CMDTAIL    ;point to command tail
  270.     MOV    B,M        ;get number of char in tail
  271.     INX    H        ;point to first character
  272.     INR    B
  273. ;
  274. EATSP:    MOV    A,M        ;get character if there is one
  275.     INX    H
  276.     DCR    B        ;b=number of characters left
  277.     JZ    OPENF        ;no more characters
  278.     CPI    SPACE        ;ignore spaces
  279.     JZ    EATSP
  280. ;
  281. FILNAM:    MOV    A,M        ;get characters in file name
  282.     INX    H
  283.     DCR    B        ;b=number of characters left
  284.     JZ    OPENF        ;only file name in tail
  285.     CPI    SPACE        ;wait for next space
  286.     JNZ    FILNAM
  287.     LXI    D,CHRMAX    ;point to chr/line
  288.     CALL    GETNBR        ;get number of characters/line
  289.     JC    HELP        ;invalid number
  290.     LXI    D,LINMAX    ;point to number of lines
  291.     CNZ    GETNBR        ;call only if characters still in
  292.                 ;__command tail
  293.     JC    HELP        ;invalid number
  294. ;
  295. OPENF:    CALL    OPNFIL        ;open file in default fcb
  296. ;
  297.     CALL    STATUS        ;display status line if file open ok
  298. ;
  299. OPENF1:
  300.     IF    SQUEEZE
  301. ;
  302.     CALL    CHKSQ        ;Check for squeezed, init if
  303. ;
  304.     ENDIF
  305. ;
  306. WRTFWD:    XRA    A        ;get a 0
  307.     STA    LINCNT        ;store in line count
  308.     STA    CHRCNT        ;store in character count
  309. ;                Do not reset the current extent!!!
  310. ;                BDOS will switch extents only if the no
  311. ;                specified ( <FCBEX> ) does NOT agree with
  312. ;                the wanted no <FCBCRR>. 
  313.     STA    FCBCRR        ;zero current record
  314.     STA    FCBCRR+1    ;__both bytes
  315.     STA    FCBCRR+2    ;__and the overflow
  316.     CALL    CLRSCR        ;erase the screen
  317. ;
  318. WRTFW0:    CALL    FILBUF        ;fill the disk buffer
  319. WRTFW3:
  320.     LXI    H,DSKBUF    ;point to beginning of buffer
  321. ;
  322. WRTFW1:
  323.     MOV    A,M        ;get a character
  324.     CPI    EOF        ;see if eof
  325.     JZ    GETCMD        ;yes, wait for command
  326.     INX    H        ;bump pointer
  327.     ANI    7FH        ;strip high bit
  328.     CPI    'L'-40H        ;filter form-feeds
  329.     JZ    FILTER        ;__commonly found in .PRN files
  330.     CALL    CO1        ;put it on console
  331.     CPI    CR        ;see if end of line
  332.     JZ    FWDCNT        ;yes, adjust line count
  333. ;
  334. WRTFW2:    LXI    D,ENDBUF    ;get end of buffer address
  335.     CALL    cmphlde        ;Is HL> gt DE> (end of buff)
  336. ;                ; Note test is LT now, not NE (v1.81)
  337.     JNC    WRTFW0        ;refill buffer and start over
  338.     JMP    WRTFW1        ;else, continue with next character
  339. ;
  340. HELP:    CALL    CDISP
  341.     DB    1ah,ESC,'B0'
  342.     DB    '  Kaypro BISHOW vers 3.21  '
  343.     DB    ESC,'C0',CR,LF,LF
  344.     DB    'Usage:  BISHOW d:filename.typ [cols [lines]]',CR,LF,cr,lf
  345.     DB    'Specify entire filename.typ - no wildcards allowed',cr,lf,lf
  346.     DB    'Columns default to  79',cr,lf
  347.     DB    'Lines per screen to 24',cr,lf
  348.     DB    ENDMSG
  349.     JMP    EXIT1
  350. ;
  351. FILTER:    PUSH    PSW        ;save status
  352.     MVI    A,'^'        ;print '^' in front
  353.     CALL    CO1        ;__of control character
  354.     POP    PSW        ;restore status
  355.     ADI    40H        ;mask into displayable char
  356.     CALL    CO1        ;display filtered control char
  357. ;
  358. FWDCNT:    LDA    LINCNT        ;get number of lines displayed
  359.     INR    A        ;bump it
  360.     STA    LINCNT        ;__and store it
  361.     MOV    D,A        ;save lincnt
  362.     LDA    LINMAX        ;get max number of line
  363.     CMP    D        ;compare with line count
  364.     JNZ    WRTFW2        ;if not there, continue, else get command
  365.     XRA    A        ;zero the
  366.     STA    LINCNT        ;__line count
  367. ;
  368. GETCMD:    PUSH    H
  369.     PUSH    D
  370.     PUSH    B
  371. ;
  372.     IF    KAYPRO
  373.     CALL    CDISP
  374.     DB    ESC,'C4',ENDMSG    ;disable cursor
  375.     ENDIF
  376. ;
  377. GETCM1:    MVI    C,6        ;direct console I/O
  378.     MVI    E,0FFH        ;__set up for input
  379.     CALL    BDOS
  380.     ORA    A        ;loop till char avail
  381.     JZ    GETCM1
  382.     POP    B
  383.     POP    D
  384.     POP    H
  385.     CPI    'a'        ;change command to
  386.     JC    GETCM2        ;__upper case
  387.     CPI    'z'+1
  388.     JNC    GETCM2
  389.     XRI    20H        ;is lower case, make upper case
  390. ;
  391. GETCM2:        ; get the command from keyboard
  392. ;
  393. ; go to top of the file?
  394. ;
  395.     CPI    '1'        ; 1 means goto 1st line
  396.     JZ    WRTTOP        ;Test if top in buffer
  397. ;
  398. ; help?
  399. ;
  400.     CPI    '?'        ;help request
  401.     JZ    HELP2
  402. ;
  403. ; forward a page ( Space bar, F, ^C, or C/R )
  404. ;
  405.     CPI    ' '        ;more use space
  406.     JZ    WRTFW1
  407.     CPI    'F'        ;scroll forward?
  408.     JZ    WRTFW1        ;br if yes
  409.     CPI    'C'-40H        ;wordstar uses ^C
  410.     JZ    WRTFW1
  411.     cpi    cr        ;also c/r goes forward a page
  412.     jz    wrtfw1
  413. ;
  414. ; back a page ( B or ^R )
  415. ;
  416.     CPI    'B'        ;scroll backward?
  417.     JZ    WRTBAK
  418.     CPI    'R'-40H        ;wordstar uses ^R
  419.     JZ    WRTBAK
  420. ;
  421. ; next line forward ( +, ^Z, or Arrow-down key )
  422. ;
  423.     cpi    '+'        ;1 for 1 more line?
  424.     jz    wrtnxt
  425.     cpi    'Z'-40H        ;wordstar uses ^Z
  426.     JZ    WRTNXT
  427.     cpi    arwdwn        ;cursor down?
  428.     jz    wrtnxt
  429. ;
  430. ; back a line ( -, ^W, or Arrow-up key )
  431. ;
  432.     cpi    '-'        ;minus key?
  433.     jz    wrtprv
  434.     CPI    'W'-40H        ;scroll prev line?
  435.     JZ    WRTPRV
  436.     CPI    ARWUP        ;Cursor up?
  437.     JZ    WRTPRV        ;yes, back-up a line
  438. ;
  439. ;
  440. ; exit program, clear screen ( Q or X )
  441. ;
  442.     CPI    'Q'        ;Q for quit?
  443.     JZ    EXITCL
  444.     cpi    'X'        ;was it an X
  445.     jz    exitcl
  446. ;
  447. ; set new screen paramaters ( S or ^S )
  448. ;
  449.     CPI    'S'        ;set screen parameters
  450.     JZ    SETSCR
  451.     cpi    'S'-40H
  452.     jz    setscr
  453. ;
  454. ; adjust margins ( Arrow-left, Arrow-right, or M )
  455. ;
  456.     CPI    ARWLFT        ;Cursor left?
  457.     JZ    ADJMM
  458.     CPI    ARWRT        ;Cursor right?
  459.     JZ    ADJMM
  460.     cpi    'M'        ; m for margins?
  461.     jz    adjmm
  462. ;
  463.     JMP    HELP2        ;if none of these, display built-in help menu
  464. ;
  465. ;...........
  466. ;            Go to top of file
  467. WRTTOP:
  468.     LDA    TOPBUF        ;Get top in buffer flag
  469.     ORA    A
  470.     JNZ    WRTFWD        ;No - the hard way
  471.     CALL    CLRSCR        ;erase the screen
  472. WRTTO1:
  473.     XRA    A
  474.     STA    LINCNT        ;Clear lines put so far
  475.     JMP    WRTFW3        ;Buffer contains top sectors
  476. ;
  477. ;            Write one more line
  478. WRTNXT:    LDA    LINMAX
  479.     DCR    A        ;fool wrtfw1 to only write one line
  480.     STA    LINCNT
  481.     JMP    WRTFW1
  482. ;            Back up one line
  483. WRTPRV:    LDA    LINMAX        ;back up one screen + 1 line
  484.     INR    A
  485.     JMP    WRTBK0
  486. ;            Back up full screen
  487. WRTBAK:    LDA    LINMAX        ;get screen line count
  488.     ADD    A        ;__multiply by 2
  489. ;
  490. WRTBK0:    INR    A        ;__and add 1
  491.     STA    LINCNT        ;__to backup to previous page
  492.     CALL    CLRSCR        ;clear the screen
  493. ;
  494. WRTBK1:    LXI    D,DSKBUF    ;get address of start of buffer start
  495.     CALL    cmphlde        ;Is HL> LT DE> (start of buff)
  496. ;                ; Note test is LT now, not NE (v1.81)
  497.     JC    FILBAK        ;Go refill buffer
  498. ;
  499. WRTBK2:    MOV    A,M        ;get a character
  500.     ANI    7FH        ;strip high bit
  501.     DCX    H        ;decrement buffer
  502.     CPI    CR        ;see if end of line
  503.     JZ    BAKCNT        ;__or form-feed
  504.     CPI    'L'-40H        ;__and adjust line count if so
  505.     JNZ    WRTBK1        ;else, loop if not
  506. ;
  507. BAKCNT:    LDA    LINCNT        ;else, get number of lines to move back
  508.     DCR    A        ;__and decrement it
  509.     STA    LINCNT        ;__store it
  510.     JNZ    WRTBK1        ;__and loop if not there
  511.     INX    H        ;else bump pointer
  512.     INX    H        ;__to account for dcx
  513.     JMP    WRTFW1        ;and go write a screen
  514. ;
  515. FILBAK:
  516. ;            Test for top of file
  517.     LDA    TOPBUF        ;Get top in buffer flag
  518.     ORA    A
  519.     JZ    WRTTO1        ;Yes - start of file in buffer
  520. ;            Start of file not in buffer, step back
  521.     LHLD    SECCNT        ;Get no of sectors last read
  522.     LXI    D,MAXSEC    ;get the buffer size
  523.     DAD    D        ;add them
  524.     XCHG            ;__and put them in DE
  525.     LDA    FCBCRR        ;subtract low order byte 
  526.     SUB    E        ;__from current record count
  527.     STA    FCBCRR        ;__and store in current record count
  528.     LDA    FCBCRR+1    ;same with high order byte
  529.     SBB    D        ;__but with borrow
  530.     JM    WRTFWD        ;if beyond beginning of file, start over
  531.     STA    FCBCRR+1    ;else, store high order byte
  532.     CALL    FILBUF        ;fill the buffer
  533.     LXI    H,ENDBUF    ;__and point to end of buffer
  534.     CALL    CLRSCR        ;clear the screen
  535.     JMP    WRTBK2        ;continue moving back in file
  536. ;
  537. ;            ;Fill buffer from spec'd sector
  538. FILBUF:
  539.     MVI    B,MAXSEC    ;number of sectors to resd
  540. FILB1S:
  541.     LXI    D,DSKBUF    ;load start of disk buffer
  542.     LXI    H,0        ;zero out the
  543.     SHLD    SECCNT        ;__number of sectors in buffer
  544.     LHLD    FCBCRR        ;Is this top of file?
  545.     MOV    A,H
  546.     ORA    L
  547.     STA    TOPBUF        ;Set top of file in buffer flag
  548. ;                ; Z - top, NZ - not top 
  549.     IF    SQUEEZE
  550.     LDA    SQFLG        ;Is this a squeezed file
  551.     ORA    A
  552.     JNZ    FILSQ        ;Yes -
  553.     ENDIF
  554. ;
  555. FILBU1:    PUSH    H        ;save all
  556.     PUSH    D        ;__registers from
  557.     PUSH    B        ;__BDOS clobber
  558.     MVI     C,STDMA        ;set dma to
  559.     CALL    BDOS        ;__disk buffer
  560.     LXI    D,FCB        ;set up to read
  561.     MVI    C,READR        ;__a record
  562.     CALL    BDOS        ;do it
  563.     ORA    A        ;read OK?
  564.     LHLD    FCBCRR        ;get current record number
  565.     INX    H        ;__bump it
  566.     SHLD    FCBCRR        ;__and save it
  567.     LHLD    SECCNT        ;get sectors in buffer
  568.     INX    H        ;bump it
  569.     SHLD    SECCNT        ;store it
  570.     POP    B
  571.     POP    D
  572.     POP    H
  573.     JNZ    RDERR        ;no, last sector read
  574.     DCR    B        ;decrement it
  575.     RZ            ;if done return
  576.     LXI    H,128        ;else, add 128 to
  577.     DAD    D        ;__dma address
  578.     XCHG            ;put it in de
  579.     JMP    FILBU1        ;read another sector
  580. ;
  581.     IF    SQUEEZE
  582. ;
  583. ;            Fill buffer from squeezed file
  584. ;            This rtn handles mapping from unsq sector #
  585. ;            to sector, byte & bit in sq stream
  586. ;            on input FCBCRR contains wanted sector no,
  587. ;            ( no allowance made for sectors # over 65535)
  588. ;            <B> contains no of sectors wanted
  589. ;            DE> buffer where sectors wanted,
  590. ;             ignored in this version, always full DSKBUF
  591. FILSQ:
  592.     LHLD    FCBCRR        ;Get # for 1st sector wanted
  593.     XCHG
  594.     PUSH    D        ;Save to restore after unsq
  595.     LHLD    NXTSEC        ; & 1st sector after buffered ones  
  596.     CALL    cmphlde        ;Consecutive?
  597.     JZ    USQNXT        ;Yes - fine
  598.     JNC    USQBAK        ;No - lower
  599. ;            ;Next sect after latest but not consec
  600.     CALL    CDISP
  601.     DB    CR,LF,'Program failure, non-contiguous sectors requested'
  602.     DB    CR,LF,'from unsqueeze rtn',CR,LF,0
  603.     JMP    EXIT        ;Should never happen
  604. USQBAK:            ;Going backward
  605.     MOV    A,D        ;All the way?
  606.     ORA    E
  607.     JNZ    USQNO1        ;No - MUST be prev!!!
  608.     LXI    H,SQMAP+2+8    ;Yes - reset SQMAP index to #3
  609.     SHLD    SQMAP
  610. USQNO1:
  611.     LHLD    SQMAP        ;Get index into mapping table
  612.     LXI    D,-8        ;Step back from next, past current to prev
  613.     DAD    D
  614.     SHLD    SQMAP        ; & save updated index for next
  615.     MOV    E,M        ;Get SQ sector no
  616.     INX    H
  617.     MOV    D,M
  618.     INX    H
  619.     MOV    C,M        ;Get byte offset
  620.     INX    H
  621.     MOV    A,M        ; & bit offset
  622.     STA    bitlft
  623.     XRA    A
  624.     STA    rcnt        ;No runs in progress
  625. ;                (assumption)
  626.     STA    SQBYT+1        ;Set offset 1st data byte
  627.     MOV    A,C
  628.     STA    SQBYT        ;For now offset within sector only
  629.     LHLD    SQBSC1        ;Get no of first SQ sector now in buffer
  630.     XCHG            ;<HL> wanted 1st sector, <DE> actual 1st
  631.     CALL    cmphlde        ;Is 1st buffer sector low/equal 1st data sect?
  632.     JNC    USQ1OK        ;Yes - first wanted sector SQ in buffer
  633. ;                 Max header 1035 bytes + file name)
  634. ;            Force reload of SQ buffer
  635.     SHLD    NXTSQS        ;No - 1st data sector b/4 1st buffer sect
  636. ;                 (note is probab not sector 0
  637. ;                 because of header, eg decoding tree)
  638.     MVI    A,1        ;Set rewind with I/O
  639.     STA    SQREWD        ;Set rewind flag
  640. ;                 SQBYT contains offset of 1st data byte
  641.     XRA    A
  642.     STA    SQEOF        ;Reset end of file on SQ
  643. ;                Leave current extent alone. This is how
  644. ;                BDOS knows how to switch extents. It checks
  645. ;                if the current extent no agrees with
  646. ;                the wanted record.
  647.     STA    FCBCRR+2    ; & count overflow, should not be necessary
  648.     MOV    D,A
  649.     JMP    USQNX1        ;Go adj buffer pointer
  650. ;                (NOP since <DE>=0
  651. ;            ;SQ text still in buffer
  652. USQ1OK:
  653. ;                <DE> # of 1st sector in SQ buf
  654. ;                <HL> # of wanted SQ sector 
  655. ;                (Max 100H SQ sectors in buffer)
  656.     MOV    A,L
  657.     SUB    E
  658.     RAR            ;Convert to pages (100H)
  659. ;                 Know Cy=0 in
  660. ;                 leaves Cy if odd no of sects
  661.     MOV    D,A
  662.     MVI    A,0        ;Do not disturb Cy
  663.     RAR            ;Pu carry (now 80H or 00H) 
  664. USQNX1:
  665.     MOV    E,A
  666.     LHLD    SQBYT        ;Get offset of 1st data byte in wanted sect
  667.     DAD    D        ; --> offset in buffer
  668.     LXI    D,SQBUF
  669.     DAD    D        ;Convert to absolute addr
  670.     SHLD    inbufs        ;& set as next byte to unsqueeze
  671. ;
  672. USQNXT:            ;Next sector consecutive
  673.     LHLD    NXTSQS        ;Get no of next SQ sector 
  674. ;                (in case read reqd)
  675.     SHLD    FCBCRR
  676. ;            Build mapping table entry
  677.     LHLD    inbufs        ;Calc offset in buffer
  678.     LXI    D,-SQBUF
  679.     DAD    D
  680.     MOV    C,L        ;Keep offset within sector
  681.     LDA    bitlft        ;Get bit offset
  682.     MOV    B,A
  683.     ORA    A        ;On byte boundary?
  684.     MOV    A,C
  685.     JNZ    NOTBBY        ;No -
  686.     INR    A        ;Yes - no adj reqd
  687. NOTBBY:
  688.     ANI    7FH        ;Ensure sector relative
  689.     DAD    H        ;Convert to sector no
  690.     ORA    A        ;Is next byte at start of sect?
  691.     JNZ    SECTOK
  692.     DCR    H        ;Yes - step back one sector
  693. SECTOK:
  694.     DCR    A
  695.     ANI    7FH        ;& adj byte index
  696.     MOV    E,H
  697.     MVI    D,0
  698.     LHLD    SQBSC1        ;# of 1st sector in buffer
  699.     DAD    D
  700.     XCHG            ;<D> absolute SQ sector no
  701.     LHLD    SQMAP        ;Get index
  702.     MOV    M,E        ;Save abs SQ sector no
  703.     INX    H
  704.     MOV    M,D
  705.     INX    H
  706.     MOV    M,A        ;Save sector relative byte offset
  707.     INX    H
  708.     MOV    M,B        ;Save bitlft
  709.     INX    H
  710.     SHLD    SQMAP        ;Save new index
  711.     CALL    CDISP        ;Show msg where is
  712.     DB    '>>> Unsqueezing text <<<',ENDMSG
  713. ;                Corrupts display if aft CR but b/4 LF
  714.     CALL    filusq        ;Fill unsq buffer
  715. ;                returns NZ on EOF
  716. ;                SQEOF set as well then
  717.     CALL    CDISP        ;Remove msg just displayed,
  718. ;                 assumes BS across start of line if reqd
  719.     DB    BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,BS
  720.     DB    BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,BS
  721.     DB    '                        '
  722.     DB    BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,BS
  723.     DB    BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,0
  724.     LHLD    FCBCRR        ;Get no of next SQ sector
  725.     SHLD    NXTSQS
  726.     LHLD    nxtadr        ;Calc # of unsq sectors in buf
  727.     LXI    D,-DSKBUF    ;(as neg no)
  728.     DAD    D        ;Calc length
  729.     DAD    H        ; & convert to sectors in <H>
  730.     MOV    L,H
  731.     MVI    H,0
  732.     SHLD    SECCNT        ;Save # of sectors in DSKBUF
  733.     POP    D        ;Get FCBCRR as passed by calling rtn
  734.     DAD    D        ; & calc new one
  735.     SHLD    FCBCRR
  736.     SHLD    NXTSEC
  737.     RET
  738. ;
  739.     ENDIF
  740. ;
  741. ;
  742. ;We only get here if end of file
  743. ;
  744. RDERR:    MVI    A,EOF        ;get bogus eof
  745.     STAX    D        ;save at buffer end in case no eof in file
  746.     XRA    A        ;get a zero to direct to start of buffer
  747.     RET            ;__on ret
  748. ;
  749. OPNFIL:    LDA    FCBFN        ;point to first letter of filename
  750.     CPI    ' '        ;anything there?
  751.     JZ    HELP        ;no, give help message
  752.     XRA    A        ;get a 0
  753.     STA    FCBEX        ;zero current extent
  754. ;                MUST open file on extent zero
  755.     LXI    D,FCB        ;file name in default fcb
  756.     MVI    C,OPEN        ;set up to open
  757.     CALL    BDOS        ;do it
  758.     INR    A        ;open OK?
  759.     RNZ            ;yes
  760.     CALL    CDISP        ;else, give error msg and quit
  761.     DB    cr,lf,'File not found - check the DIR',7,cr,lf,ENDMSG
  762.     JMP    EXIT1        ;leave msg on screen on exit
  763. ;
  764. GETNBR:    MOV    A,M        ;get first digit
  765.     INX    H
  766.     DCR    B        ;b=number of characters left in buffer
  767.     RZ            ;no digit
  768.     CPI    SPACE
  769.     JZ    GETNBR        ;wait until next non-space
  770.     PUSH    D        ;save location to save number
  771.     MVI    D,0        ;initialize number
  772. ;
  773. GNUM1:    SUI    30H        ;change ASCII to number
  774.     JC    INVNUM        ;not a number
  775.     CPI    10
  776.     CMC
  777.     JC    INVNUM        ;not a number
  778.     PUSH    PSW        ;save number
  779.     MOV    A,D        ;multiply old number by 10
  780.     ADD    A        ;*2
  781.     ADD    A        ;*4
  782.     ADD    A        ;*8
  783.     ADD    D        ;*9
  784.     ADD    D        ;*10
  785.     MOV    D,A
  786.     POP    PSW        ;restore new digit
  787.     ADD    D
  788.     MOV    D,A
  789.     MOV    A,M        ;get next digit
  790.     INX    H
  791.     DCR    B
  792.     JZ    ENDNUM        ;end of number
  793.     CPI    SPACE
  794.     JNZ    GNUM1
  795. ;
  796. ENDNUM:    MOV    A,D        ;save number
  797.     DCR    A        ;correct number for co routines
  798.     XCHG            ;set to restore save location
  799.     POP    H        ;restore save location
  800.     MOV    M,A        ;save digit
  801.     XCHG            ;put buffer location where it belongs
  802.     MOV    A,B        ;see if any characters left in buffer
  803.     ORA    A        ;zero if no characters in buffer
  804.     RET
  805. ;
  806. INVNUM:    POP    D        ;correct stack
  807.     RET
  808. ;
  809. ASCIIN:    MVI    B,100        ;divide by 100, then change
  810.     CALL    DIVIDE        ;__digit to ASCII and store at hl
  811.     MVI    B,10        ;divide by 10, then change
  812.     CALL    DIVIDE        ;__digit to ASCII and store at hl+1
  813.     MVI    B,30H        ;change ones place number
  814.     ADD    B        ;__to ASCII and store at hl+2
  815.     MOV    M,A
  816. ;
  817. CDISP:    XTHL            ;exchange top of stack and HL
  818. ;
  819. CDIS1:    MOV    A,M        ;HL now pointing to db message
  820.     ORA    A        ;see if 0 at end of message
  821.     INX    H
  822.     JZ    CDIS2        ;yes, restore stack and return
  823.     CALL    CO        ;no, print the character
  824.     JMP    CDIS1        ;__and loop
  825. ;
  826. CDIS2:    XTHL            ;get return address on top of stack
  827.     RET            ;__and return
  828. ;
  829. CO:    PUSH    B        ;Save the registers
  830.     PUSH    D        ;__from bdos
  831.     PUSH    H        ;__clobber
  832. CO2:    PUSH    PSW
  833. CO4:    MOV    E,A        ;set up character
  834.     MVI    C,CONOUT    ;__to send to console
  835.     CALL    BDOS        ;do it
  836. CO3:    POP    PSW
  837. CO5:    POP    H        ;restore
  838.     POP    D        ;__the registers
  839.     POP    B
  840.     RET
  841. ;
  842. CO1:    PUSH    B        ;Save the registers
  843.     PUSH    D
  844.     PUSH    H
  845.     PUSH    PSW
  846.     LXI    H,CHRCNT    ;Get address of character count
  847.     CPI    CR        ;see if end of line
  848.     JZ    ENDLIN        ;update line information
  849.     CPI    LF        ;ignore linefeed
  850.     JZ    CO4
  851.     LDA    CHRMAX        ;get maximum characters per line
  852.     CMP    M        ;see if too many char
  853.     JC    CO3        ;don't print character
  854.     POP    PSW        ;__and print character
  855.     CPI    TAB        ;fix chrcnt for tabs
  856.     JZ    TABFIX
  857.     INR    M        ;increment character count
  858.     MOV    E,A
  859.     LDA    CHRMIN        ;see if up to minimum display yet
  860.     CMP    M
  861.     MOV    A,E        ;restore character
  862.     JNC    CO5        ;do not display character
  863.     JMP    CO2        ;finally, display character
  864. ;
  865. ENDLIN:    MVI    M,0        ;reset character count
  866.     JMP    CO4        ;print cr
  867. ;
  868. TABFIX:    MVI    A,08H        ;fix chrcnt for tabs
  869.     ADD    M        ;increment to next 8-count
  870.     ANI    0F8H        ;make into multiple of 8
  871. ;
  872. TAB2:    SUB    M        ;get number of space to go
  873.     MOV    B,A
  874. ;
  875. TAB1:    MVI    A,SPACE        ;expand tab
  876.     CALL    CO1
  877.     DCR    B
  878.     JNZ    TAB1        ;still more spaces
  879.     JMP    CO5        ;exit routine
  880. ;
  881. SETSCR:    PUSH    H
  882.     PUSH    D
  883.     PUSH    B
  884. ;
  885. GETMAX:    LDA    CHRMAX        ;get maximum number of characters
  886.     INR    A
  887.     LXI    H,HUNS
  888.     CALL    ASCIIN        ;put ASCII number in message        
  889. ;
  890.     DB    CR,LF,'Maximum Column: '
  891. ;
  892. HUNS:    DB    30H
  893.     DB    30H
  894.     DB    30H
  895.     DB    ' New? ',ENDMSG
  896.     CALL    GETINP        ;read input from console
  897.     LXI    D,CHRMAX    ;set new chrmax in memory
  898.     CALL    GETNBR
  899.     JC    GETMAX        ;if error, repeat last message
  900. ;
  901. GETMIN:    LDA    CHRMIN        ;get minimum character display
  902.     INR    A
  903.     LXI    H,HUN
  904.     CALL    ASCIIN        ;put ASCII number in message        
  905. ;
  906.     DB    LF,'Minimum Column: '
  907. ;
  908. HUN:    DB    30H
  909.     DB    30H
  910.     DB    30H
  911.     DB    ' New? ',ENDMSG
  912.     CALL    GETINP        ;read input from console
  913.     LXI    D,CHRMIN    ;set new chrmax in memory
  914.     CALL    GETNBR
  915.     JC    GETMIN        ;if error, repeat last message
  916. ;
  917. GETLIN:    LDA    LINMAX        ;get number of lines per display
  918.     LXI    H,HUND
  919.     CALL    ASCIIN        ;put ASCII number in message        
  920.     DB    LF,'Lines Displayed: '
  921. ;
  922. HUND:    DB    30H
  923.     DB    30H
  924.     DB    30H
  925.     DB    ' New? ',ENDMSG
  926.     CALL    GETINP        ;read input from console
  927.     LXI    D,LINMAX    ;set new chrmax in memory
  928.     CALL    GETNBR
  929.     JC    GETLIN        ;if error, repeat last message
  930.      POP    B
  931.     POP    D
  932.     POP    H
  933. ;
  934. WRTSAM:    LDA    LINMAX        ;write the same screen
  935.     JMP    WRTBK0
  936. ;
  937. ;
  938. GETINP:    MVI    A,5        ;get set to read new maximum column
  939.     STA    CMDTAIL
  940.     MVI    C,0AH
  941.     LXI    D,CMDTAIL
  942.     CALL    BDOS        ;get maximum column
  943.     LXI    H,CMDTAIL+1    ;now, change to ASCII
  944.     MOV    B,M
  945.     INX    H
  946.     INR    B
  947.     RET            ;return with input in buffer
  948. ;
  949. ;            Adjust char min/max on cursor left/rt
  950. ADJMM:
  951.     PUSH    H
  952.     CPI    ARWLFT        ;Move left (decrease)?
  953.                 ; set flag
  954.     LDA    CHRMAX        ;What is last char on line t/b displ
  955.     MOV    H,A
  956.     LDA    CHRMIN        ; & 1st char to display
  957.     MVI    L,8        ;Scroll by 8
  958.     JZ    ADJMMD        ;Yes - adjust down
  959.     ADD    L        ;No - increase min, no limit
  960.     PUSH    PSW
  961.     MOV    A,L
  962.     ADD    H        ; & max
  963.     JMP    ADJMMS
  964. ADJMMD:
  965.     SUB    L        ;Display more to the left
  966.     PUSH    PSW
  967.     MOV    A,H
  968.     SUB    L
  969. ADJMMS:
  970.     MOV    H,A        ;<H> max
  971.     POP    PSW        ;<A> min
  972.     CMP    H        ;Wrap, (max< min)
  973.     JNC    ADJMMX        ;Yes - leave unchanged
  974.     STA    CHRMIN
  975.     MOV    A,H
  976.     STA    CHRMAX
  977. ADJMMX:
  978.     POP    H
  979.     JMP    WRTSAM        ;Go write same screen
  980. ;
  981. ; 
  982. DIVIDE:    MVI    C,'0'-1        ;extract dividend of a div c
  983. ;
  984. DIV1:    INR    C        ;__and store in location pointed
  985.     SUB    B        ;__to by hl
  986.     JNC    DIV1
  987.     ADD    B
  988.     MOV    M,C        ;save ASCII digit
  989.     INX    H        ;bump pointer to next location
  990.     RET
  991. ;
  992. EXITCL:
  993. ;            Clear screen only on reg exit
  994.     CALL    CLRSCR        ;clear the screen
  995. ;
  996. EXIT:    MVI    E,0FFH        ;clear console of characters
  997.     MVI    C,6        ;direct console I/O
  998.     CALL    BDOS        ;__get any waiting characters
  999. ;
  1000.     IF    KAYPRO
  1001.     CALL    CDISP
  1002.     DB    ESC,'C7'    ;disable status line
  1003.     DB    ESC,'B4',ENDMSG    ;enable cursor display
  1004.     CALL    CLRSCR        ;now clear whole screen
  1005.     ENDIF
  1006. ;
  1007.     LXI    D,FCB        ;close file
  1008.     MVI    C,CLOSE        ;--in case this is MP/M
  1009.     CALL    BDOS
  1010. ;
  1011. EXIT1:
  1012.         IF    KAYPRO
  1013.     CALL    CDISP        ;re-enable cursor even if no file
  1014.     DB    ESC,'B4',ENDMSG    ;specified to BISHOW
  1015.         ENDIF
  1016. ;
  1017.     LHLD    STACK        ;get old stack
  1018.     SPHL
  1019.     RET            ;return to CCP
  1020. ;
  1021. ;
  1022. ;            Compare <HL> to <DE>
  1023. ;             Z - equal; C - <HL> less than <DE> 
  1024. cmphlde:
  1025.     mov    a,h
  1026.     cmp    d
  1027.     rnz
  1028.     mov    a,l
  1029.     cmp    e
  1030.     ret
  1031. ;
  1032.     IF    SQUEEZE
  1033. *******************************************************
  1034. * USQ support code                      *
  1035. * 10/12/83 by Dave Rand                      *
  1036. *******************************************************
  1037. ;
  1038. ;            Check for SQ file, init tree if so
  1039.  CHKSQ:
  1040. ;            Initialize
  1041.     xra    a
  1042.     mov    l,a
  1043.     mov    h,l        ;clear <hl>
  1044.     STA    SQFLG        ;Make sure not set as squeezed yet 
  1045.     sta    SQEOF        ; end of file on SQ
  1046.     sta    SQREWD        ;Clear "rewinding" SQ file 
  1047.     sta    bitlft        ;force init char read
  1048.     sta    rcnt        ;and zero repeats
  1049.     shld    FCBCRR        ;Clear next record
  1050.     sta    FCBCRR+2    ; and overflow
  1051.     shld    numvals        ;Clear # nodes
  1052. ;
  1053.     lxi    h,SQBUF        ;Set to input (squeezed) buffer 
  1054.     shld    inbufs
  1055.     shld    inbufu
  1056.     lxi    d,128
  1057.     dad    d
  1058.     shld    SQBUFE        ;Force exit on full buff aft 1 sect
  1059. ;                 causes the SQ buffer to contain
  1060. ;                 sectors 1+ only (not zero),
  1061. ;                 normally fine since sector 0 contains only
  1062. ;                 header info. Sector 0 will be reread
  1063. ;                 if contains data and needed  
  1064.     call    usqsig        ;Read & val signature word
  1065.     RNZ            ;Not SQ
  1066.     STA    SQFLG        ;Yes - set flag
  1067.     lhld    0006        ;Get top of memory
  1068.     lxi    d,sqbuf+100H*128 ;Limit buffer to max 100H
  1069.     call    cmphlde        ; sectors (FILBUF uses 8 bit count <B>)
  1070.     JC    toplow        ;use top
  1071.     xchg            ;use limit 
  1072. toplow:
  1073.     shld    SQBUFE        ;& store as full address 
  1074.     call    namlp        ;Skip past name
  1075.     call    usqtbl        ;Validate & load decoding tree
  1076.     jz    oak        ;tree ok
  1077.     call    CDISP
  1078.     db    cr,lf,'Invalid decode tree size',cr,lf,0
  1079.     jmp    EXIT
  1080. oak:
  1081.     lxi    h,SQMAP+2    ;Point to 1st entry 
  1082.     shld    SQMAP        ;Set to 1at entry in SQ mapper
  1083.     ret
  1084. ;            Read and validate signature word
  1085. usqsig:
  1086.     call    getw        ;Read  1st word in file
  1087.     lxi    d,signat    ;Get expected value
  1088.     call    cmphlde
  1089.     mvi    a,1        ;Set code in case of error
  1090.     ret            ;Exit with Z/NZ
  1091. ;
  1092. ;            Read & save checksum
  1093. rdchks:
  1094.     call    getw        ;get cksum, and store
  1095.     shld    filchks
  1096.     ret
  1097. ;            Read & skip name
  1098. namlp:    call    getc        ;Loop to skip name
  1099.     jnz    erext        ;I/O error or unexpected EOF
  1100.     ora    a
  1101.     jnz    namlp        ;Not yet end of name
  1102.     ret
  1103. ;
  1104. ;            Load decoding tree
  1105. ;            This version uses 1 byte abslute node indices
  1106. ;            (1-ffH) and is thus limited to 255 nodes and 255
  1107. ;            characters represented in the squeezed file.
  1108. ;            (All different characters present in the original
  1109. ;            file as well as any added through run encoding.
  1110. ;            Runs of 3 or more consecutive identical characters
  1111. ;            are encoded as char, DLE, count, where count
  1112. ;            is a one byte field 00 - FFH) 
  1113. ;
  1114. usqtbl:
  1115.      call    getw        ;Get no of nodes
  1116.     mov    a,h
  1117.     ora    l
  1118.     jz    nzexit        ;Null tree
  1119.     shld    numvals
  1120.     mov    a,h        ;Max 257, 256 char & spec eof
  1121. ;                in this version allow for only 256
  1122. ;                diff codes, every ASCII and non-ASCII
  1123. ;                char would have to be present, or
  1124. ;                run repeat counts 128-255 (every one)
  1125.     ora    a        ;H/o byte should be zero
  1126.     jnz    nzexit
  1127.     lxi    d,SQTREE    ;Set to decoding tree
  1128. nodelp:    shld    nxtadr        ;Save no of nodes
  1129.     mov    a,h
  1130.     ora    l
  1131.     rz            ;Done all nodes
  1132.     call    cvnode        ;get node, falg byte in <H>,
  1133. ;                 index/char in <L>
  1134.     push    h
  1135.     call    cvnode        ;get second child/char
  1136.     pop    b
  1137.     mov    a,b
  1138.     ral            ;Shift flags to 8, 4 posns 
  1139.     ora    h        ;Combine in 1st child flags 
  1140.     xchg            ;HL> SQTREE, <A>,<C>,<E> node 
  1141.     mov    m,a        ;Store flags in table
  1142.     inx    h
  1143.     mov    m,c
  1144.     inx    h
  1145.     mov    m,e
  1146.     inx    h
  1147.     xchg            ;DE> SQTREE
  1148.     lhld    nxtadr        ;Nodes remaining
  1149.     dcx    h
  1150.     jmp    nodelp
  1151. ;            Get encoded node
  1152. ;            Our nodes contain 3 bytes:
  1153. ;            - flag byte,
  1154. ;            - left child index/char
  1155. ;            - right child index/char
  1156. ;            Nodes on input are 4 bytes,
  1157. ;            with each half containing
  1158. ;            an index (1-100h) or character,
  1159. ;            where characters are encoded as
  1160. ;            negative values -(char+1)
  1161. ;            Eof is encoded as -(100h+1)
  1162. cvnode:
  1163.     push    d
  1164.     call    getw        ;Get word, chld ptr or char
  1165.     pop    d
  1166.     mov    a,h
  1167.     ora    a
  1168.     rz            ;Child index, <H>=0,<L>=index
  1169.     mov    a,l
  1170.     cma
  1171.     mov    l,a        ;convert char to reg form
  1172.     mov    a,h        ;get h/o byte again
  1173.     cma
  1174.     inr    a        ;Conv to 1 if char, 2 if EOF
  1175.     mov    h,a
  1176.     cpi    1        ;Was that reg char?
  1177.     rz            ;Yes - complete
  1178.     adi    3        ;No convert EOF flag to 0100
  1179.     mov    h,a
  1180.     ret
  1181.  
  1182. ;            Exit with NZ flag
  1183. nzexit:
  1184.     mvi    a,2        ;tree error
  1185.     ora    a        ;Set NZ flag
  1186.     ret
  1187.  
  1188. ;
  1189. ;
  1190. ;            Fill output buffer (unsqueezed char)
  1191. ;
  1192. filusq:
  1193.     lda    SQREWD        ;Rewinding SQ input?
  1194.     ora    a
  1195.     jz    norewd        ;No
  1196. ;            Reload SQ buffer
  1197.     lhld    inbufs
  1198.     push    h        ;getrf resets
  1199.     call    getrf        ;Yes - reload buffer & get 1st 8 bits
  1200.     pop    h
  1201.     shld    inbufs        ;Set to first data byte to use
  1202. badj:
  1203.     mov    c,a
  1204.     lda    bitlft        ;Get preset 1st wanted bit no
  1205.     mov    c,a
  1206.     mvi    a,8
  1207.     sub    b        ; Calc adjmt reqd  
  1208. badjlp:
  1209.     dcr    a
  1210.     jz    badjfn        ; bit adjust finished
  1211.     mov    b,a
  1212.     mov    a,c
  1213.     rrc
  1214.     mov    c,a
  1215.     mov    a,b
  1216.     jmp    badjlp
  1217. badjfn:
  1218.     sta    bitbuf
  1219.     xra    a
  1220.     sta    SQREWD        ; & clear rewind flag
  1221. norewd:
  1222.     lxi    h,DSKBUF    ;reset buffer pointer
  1223.     xra    a
  1224. buflp:
  1225.     shld    nxtadr        ;Save as next byte in buffer
  1226.     rnz            ;End of file (NZ flag)
  1227. ;                 as set by GETNXT rtn below
  1228.     lxi    d,SQTREE    ;Get end of input
  1229.     call    cmphlde        ;buffer full (de < hl - not full)
  1230.     jnc    full        ;buffer is full
  1231.     call    getnxt        ;Get next decoded char
  1232.                 ;No checksum taken
  1233.     lhld    nxtadr        ;Next out buffer posn
  1234.     mov    m,a        ;Store char returned, may be EOF char
  1235.     inx    h
  1236.     jmp    buflp
  1237. ;
  1238. full:
  1239.     xra    a        ;Ensure Z
  1240.     ret            ;Return on full buffer
  1241. ;
  1242. ;
  1243. ;            Get next decoded character
  1244. ;
  1245. getnxt:    lda    rcnt        ;see if in the middle of
  1246.     ora    a        ;repeat sequence...
  1247.     jz    norpt
  1248.     dcr    a        ;Yes - reduce repeat remaining 
  1249.     sta    rcnt
  1250.     lda    last        ;Get latest char again
  1251.     cmp    a
  1252.     ret            ;Return with Z for ok
  1253. norpt:    call    decode
  1254.     rnz            ;EOF? <A>=1AH
  1255.     cpi    dle        ;Run encoding flag?
  1256.     jnz    norun
  1257. ;            Handle DLE
  1258.     call    decode        ;get count
  1259.     rnz            ;EOF? (is really error after DLE)
  1260.     ora    a
  1261.     jnz    run        ;Non-zero, real run 
  1262.     mvi    a,dle        ;dle is encoded as dle,0
  1263.     cmp    a
  1264.     ret
  1265. ;            ;Run encoding found
  1266. run:    dcr    a        ;Allow for char already retnd
  1267.     dcr    a        ; & this one
  1268.     sta    rcnt        ;Keep count yet to be retd
  1269.     lda    last        ;return second time
  1270.     cmp    a
  1271.     ret
  1272. ;            ;Normal char, no run active 
  1273. norun:    sta    last        ;This may be the start
  1274.     cmp    a
  1275.     ret
  1276. ;
  1277. ;
  1278. ;            Read bits and decode to char
  1279. ;             note this version uses 3 bytes per node
  1280. ;             not 4.
  1281. ;             The first byte in each node is a flag byte
  1282. ;              .... x... - left node contains EOF marker
  1283. ;              .... .x.. - right node contains EOF marker
  1284. ;              .... ..x. - left node contains char
  1285. ;              .... ...x - right node contains char
  1286. ;
  1287. decode:    lxi    d,0        ;Set to node zero in table
  1288.     lda    bitbuf        ;Get bits from bit buffer
  1289.     mov    c,a
  1290. bitlp:    lda    bitlft        ;Any bits remaining? 
  1291.     ora    a
  1292.     jnz    nxtbit        ;Yes - go use
  1293.     push    d
  1294.     call    getc        ;No - replenish bit buffer
  1295.     jnz    badr        ;Unexpected eof
  1296.     pop    d
  1297.     mov    c,a
  1298.     mvi    a,8        ;Set as 8 bits inbuffer 
  1299. nxtbit:    dcr    a
  1300.     sta    bitlft        ;Save no of bit remaining 
  1301.     lxi    h,SQTREE    ;Set to node 0, left child ptr
  1302.     dad    d
  1303.     dad    d
  1304.     dad    d        ;Add in node no (4 bytes/node)
  1305.     mov    b,m        ;Get flag byte
  1306.     inx    h        ;Step to left child pointer
  1307.     mov    a,c        ;Get input bits 
  1308.     rrc            ;Shuffle LOW-ORDER bit to Carry
  1309.     mov    c,a
  1310.     mov    a,b        ;Get flag byte 
  1311.     jnc    getn3        ;Zero input bit,leave at left
  1312.     inx    h        ;add 1 to point to right child pointer
  1313.     add    b        ;Normalize wanted flags to .... x.x.
  1314. getn3:
  1315.     mov    e,m        ;Pick up child or char
  1316. ;                <D> should always remain zero 
  1317.     ani    1010B        ;Mask unwanted bits
  1318.     jz    bitlp        ;Reg child pointer
  1319. ;            Got to char or eof
  1320.     ani    1000B        ;End of file marker?
  1321.     jnz    goteof        ;Yes - get out with eof
  1322.     mov    a,c
  1323.     sta    bitbuf        ;Save bit buffer
  1324.     mov    a,e        ;Get decoded char (neg)
  1325.     ret
  1326. ;
  1327. ;            Exit on reg eof
  1328. goteof:
  1329.     mvi    a,eof
  1330.     ora    a
  1331.     ret
  1332. ;
  1333. ;            ;Get input word (lo/hi, unencoded)
  1334. getw:    call    getc
  1335.     jnz    badr        ;Unexpected eof
  1336.     push    psw
  1337.     call    getc
  1338.     jnz    badr        ;Unexpected eof
  1339.     mov    h,a
  1340.     pop    psw
  1341.     mov    l,a
  1342.     ret
  1343. ;
  1344. erext:
  1345. badr:    call    CDISP
  1346.     db    cr,lf,'Unexpected EOF on squeezed file',cr,lf,0
  1347.     jmp    EXIT
  1348. ;
  1349. ;            Get single (unencoded) char
  1350. getc:    lhld    inbufu
  1351.     xchg
  1352.     lhld    inbufs
  1353.     call    cmphlde        ;End of input buffer?
  1354.     jz    getrf        ;Yes
  1355. getc1:
  1356.     mov    a,m        ;No get next byte
  1357.     inx    h
  1358.     shld    inbufs        ;Save addr of next byte
  1359.     cmp    a
  1360.     ret
  1361. ;
  1362. ;            Refill input buffer
  1363. ;
  1364. getrf:
  1365.     lda    SQEOF        ;Is there anything else?
  1366.     ora    a
  1367.     jz    getok
  1368.     call    CDISP
  1369.     db    cr,lf,'Read past EOF on SQ file',cr,lf,0
  1370.     jmp    EXIT
  1371. getok:
  1372.     lhld    SECCNT        ;Save sector count (decoded buffer only)
  1373.     push    h
  1374.     lxi    h,SQBUF        ;Set input buffer as empty,
  1375.     shld    inbufs        ;_and start of buffer
  1376.     xchg            ;DE> buffer, next sector locn
  1377.     lhld    SQBUFE        ;End of input buffer
  1378.     shld    inbufu        ;Assume no end of file for now
  1379.     mov    a,l
  1380.     sub    e
  1381.     mov    l,a
  1382.     mov    a,h
  1383.     sbb    d        ;Calc buffer size
  1384.     mov    h,a
  1385.     dad    h        ;Convert to no of sectors
  1386.     mov    b,h        ;No of sectors to read
  1387. ;                # sectors limited to 100 max (<B>=0)
  1388.     lhld    FCBCRR        ;No of 1st sector to read
  1389.     shld    SQBSC1
  1390.     call    FILBU1        ;Read sector into SQBUF
  1391. ;                <B> no of sectors not read if eof
  1392. ;                HL> 128
  1393. ;                DE> last sector read, or after if eof
  1394.     lhld    FCBCRR        ;Get next SQ sector no
  1395.     shld    NXTSQS
  1396.     mov    a,b        ;Did we fill buffer?
  1397.     ora    a
  1398.     jz    getrf2        ;yes - no eof
  1399.     xchg            ;Eof, adjust buffer end marker
  1400.     shld    inbufu        ;Mark end of buffer used
  1401.     sta    SQEOF        ;& flag eof
  1402. ;
  1403. ;            Input buffer re-filled
  1404. getrf2:
  1405.     pop    h
  1406.     shld    SECCNT        ;Restore sector count (decoded buffer only)
  1407.     lhld    inbufu        ;Get end of buffer
  1408.     xchg
  1409.     lhld    inbufs        ;Get start of buffer
  1410.     call    cmphlde        ;Something there?
  1411.     jc    getc1        ;Yes - go for char
  1412.     jmp    erext        ;No - read past eof or empty file
  1413. ;
  1414. ;end of baseline USQ code
  1415. ;
  1416. otbufe:    dw    0        ;End of decoded char buffer
  1417. inbufs:    dw    0        ;Start of input buffer
  1418. inbufu:    dw    0        ;End of used part input buffer
  1419. SQBUFE:    dw    0        ;End of input buffer
  1420. ;
  1421. nxtadr:    dw    DSKBUF        ;Next byte in output buffer 
  1422.                 ; also used when loading tree
  1423. bitlft:    ds    1        ;No of bits left in bit buffer
  1424. rcnt:    ds    1        ;Run count remaining (DLE)
  1425. filchks:ds    2        ;Checksum read from file
  1426. last:    ds    1        ;Last reg char decoded
  1427. bitbuf:    ds    1        ;Latest 8 bits (encoded) from input file
  1428. numvals:ds    2        ;No of nodes in encodng tree
  1429. ;
  1430.     ENDIF
  1431. ;
  1432. ;    Memory allocation
  1433. ;
  1434. SECCNT:    DW    0        ;number of sectors read into buffer
  1435. LINMAX:    DB    SCROLN        ;number of to write lines on console
  1436. CHRMAX:    DB    MAXCHR-1    ;number of characters to display per line
  1437. CHRMIN:    DB    0        ;character to start displaying on line
  1438. CHRCNT:    DS    1        ;character number in line
  1439. LINCNT:    DS    1        ;line number on write or move back in buffer
  1440. TOPBUF:    DB    0        ;Top of file is now in buffer
  1441. ;                 Z - yes, NZ - no
  1442. ;
  1443.     IF    SQUEEZE
  1444. ;
  1445. NXTSEC:    DW    0        ;Next (unsqueezed) sector not yet in BSKBUF
  1446. ;                 set (and used) only by FILSQ
  1447. SQFLG:    DB    0        ;File is squeezed
  1448. SQEOF:    DB    0        ;End of file on squeezed file
  1449. SQREWD:    DB    0        ;Flag the SQ input file is being re-read
  1450. ;                 buffer refill rtn (getrf) to set inbufs
  1451. ;                 as per offset in SQBYT, and pre-load
  1452. ;                 bit buffer. Bit buffer to be adj
  1453. ;                 as per Bitlft
  1454. SQBYT:    DW    0        ;Offset of first data byte in SQ buffer
  1455. SQBSC1:    DW    0        ;No of 1st sector in SQ buffer
  1456. NXTSQS:    DW    0        ;No of last sector in SQ buffer
  1457. ;
  1458.     ENDIF
  1459. ;
  1460.     DS    60        ;stack area
  1461. STACK:    DS    2        ;old stack saved here
  1462. DSKBUF:    EQU    $        ;disk buffer area above the program
  1463. ;
  1464. ENDBUF    EQU    DSKBUF+MAXSEC*128
  1465. ;
  1466.     IF    SQUEEZE
  1467. ;
  1468. SQTREE    EQU    ENDBUF        ;Space for SQ decoding tree
  1469. SQMAP    EQU    SQTREE+257*3
  1470. ;                Space for SQ buffer mapping table
  1471. ;                contains sq sect #, sq byte & bit offset
  1472. ;                for every time DSKBUF was filled
  1473. ;                1st entry contains index to latest mapping
  1474. ;                triplet
  1475. ;                To handle run compr straddling buffer end,
  1476. ;                should also store rcnt & last 
  1477. SQBUF    EQU    SQMAP+100*4    ;(allows for 100 8k buffers)
  1478. ;                Input (squeezed) buffer
  1479. ;                Runs up to top of free mem 
  1480.     ENDIF
  1481. ;
  1482.     END    TPA
  1483.