home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / KAYPRO / HOTKEY11.LBR / HK101.AZM / HK101.ASM
Assembly Source File  |  2000-06-30  |  12KB  |  333 lines
  1. ;
  2. ; *****************************************************************************
  3. ;
  4. ;                 H O T K E Y S
  5. ;                    v. 1.01
  6. ;                  (c) 1988 J.W. Olsen
  7. ;                          15 May 1988
  8. ;
  9. ;       May be used for noncommercial purposes without permission
  10. ;             Inquire for all other purposes
  11. ; If given or sold with any other product, the price for which is more than $10
  12. ; inclusive of all charges, including but not limited to "shipping & handling,"
  13. ; such gift or sale is considered commercial use for purposes of the above.
  14. ;
  15. ; *****************************************************************************
  16. ;
  17. ; Allows redefintion of arrow and numeric-keypad keys. Two sets of redefinition
  18. ; are permitted in a single, assembled HK program. A run-time, command-line
  19. ; toggle key determines which redefinition will be activated. You may freely
  20. ; switch between the two configurations at any time. 
  21.  
  22. ; HK simply pokes the copy of CP/M in memory. Thus, it's transitory and won't
  23. ; affect disk copies. When you turn off the computer or press the reset button,
  24. ; the effects of HK are gone until you run the program again.
  25. ;
  26. ; HK is run by typing its name, followed by a "toggle" key of your choice, as
  27. ; in "HK W" (e.g., I use "HK B" to run my BBS, "HK W" for word processing with
  28. ; with  WordStar or VDE.) You may want to set one configuration for "vanilla" 
  29. ; CP/M--info to do so is provided.
  30. ;
  31. ; This version works on CP/M Kaypros, except those with U-ROMS. Users with
  32. ; U-ROMs should use HKxxx-U.ASM. For other machines, see HKxxx.INF file.
  33. ;
  34. ; When invoked, HK first installs single-byte values for each of the 4 arrow 
  35. ; keys and the 14 numeric-keypad keys.
  36. ;
  37. ; Later Kaypros also permit assignment of 4-character strings to any or all of
  38. ; the arrow/numeric-keypad keys, activated if the "normal" byte for a given
  39. ; key is set to a null (00H). You'll have to see if this applies to you. My
  40. ; '83 Kaypro II (CP/M 2.2) doesn't permit this. My '84 Kaypro 10 (CP/M 2.2G) 
  41. ; does. If in doubt, first try it with the STRINGS equate set to YES. If the 
  42. ; strings work when you press corresponding keys, you're in business. If not, 
  43. ; RESET YOUR MACHINE BEFORE USING AGAIN. (An unintended area in high memory 
  44. ; will have been overwritten.) In that case, try again with STRINGS set to NO.
  45. ; If you have a non-U-ROM Kaypro, you should at least be able to get the
  46. ; 1-character redefinitions to work. (But if even this doesn't work on your
  47. ; hardware, RESET and feel free to contact me.)
  48. ;
  49. ; NOTE: Only the arrow keys above the main keyboard and the numeric keypad
  50. ; keys are redefined. All other keys are unaffected, including the number keys
  51. ; on the main keypad.
  52. ;
  53. ; Run your favorite assembler/linker. ASM and MLOAD work fine. 
  54. ;
  55. ; Thanx to Eric Bohlman for tips related to memory addresses on this version
  56. ; of HK.
  57. ;
  58. ; This was a quickie effort to meet a special need, but performs its function
  59. ; fully. Experienced 8080 programmers (of which it will be readily apparent
  60. ; I'm not one) undoubtedly will be able to reduce code size and suggest
  61. ; further improvements. That would be welcomed. But if in the meantime you
  62. ; too find HK useful, enjoy. Please direct comments, or check for any updates
  63. ; on my BBS.
  64. ; 
  65. ;       Jerry Olsen
  66. ;    Sysop, The Advocate/NOWAR RCP/M
  67. ;    312.939.4411
  68. ;    24 hrs., 300/1200/2400, 8/n/1
  69. ; 
  70. ; ----- Preliminaries
  71. ; 
  72. ;    ASEG            ; Comment out if assembling with other than M80
  73. ;
  74. NO    EQU    0        ; Leave these alone
  75. YES    EQU    NOT NO
  76. ;
  77. ; ----- User-settable equates
  78. ;
  79. TOGGLE1 EQU    'B'        ; Specify two characters as command-line
  80. TOGGLE2    EQU    'W'        ; toggles to invoke your configurations.
  81.                 ; A toggle may be any single letter, number
  82.                 ; or punctuation. But LOWER CASE letters are
  83.                 ; *NOT* allowed. You might want to set one
  84.                 ; to "V" for "vanilla" CP/M settings.
  85. OFFSET    EQU    35H        ; Offset to first byte of arrows configuration
  86.                 ; from the beginning of the first page of
  87.                 ; memory pointed to by location 02H.
  88.                 ; Neither OFFSET nor OFFST2 should require
  89.                 ; any change for non-U-ROM Kaypros. 
  90. STRINGS EQU    YES        ; *** See headnotes about this ***
  91. OFFST2    EQU    61H        ; Offset to where 4-char strings can be stored
  92.                 ; if bytes in area following OFFSET are nulls.
  93.                 ; (Only active if STRINGS is set YES--for later
  94.                 ; vintage Kaypros.)
  95. ;
  96. ; *** You also need to set up the arrays toward the end of this file ***
  97. ;
  98. ; ----- Miscellaneous equates (leave alone)
  99. ;
  100. WBOOT    EQU    0        ; Warm boot location
  101. BDOS    EQU    5        ; BDOS entry point
  102. PRINTF    EQU    9        ; Print-a-string function
  103. BUFF    EQU    80H        ; Command line buffer
  104. CR    EQU    0DH        ; Carriage return
  105. LF    EQU    0AH        ; Linefeed
  106. SPACE    EQU    20H        ; Ordinary blank space
  107. NULL    EQU    0        ; May be used in arrays if desired
  108. ;
  109. ; ----- Begin
  110. ;
  111.     ORG    100H        ; Normal TPA entry point
  112. ;
  113.     LXI    D,SIGNON    ; Point to sign-on msg
  114.     MVI    C,PRINTF    ; Tell BDOS we want to print a string
  115.     CALL    BDOS        ; and do it
  116. ;
  117. ;    LXI    H,BUFF        ; Get address of command-line buffer
  118.     MOV    A,M        ; Get buffer length
  119.     CPI    NULL        ; Is it a null?
  120.     JZ    ERROR1        ; Yep, so print error msg & quit
  121. ;
  122.     MOV    B,A        ; Nope, so save command-line length
  123.     LXI    H,BUFF+1    ; Point to first char of command line
  124. GETIT:    DCR    B        ; Decrement our length counter
  125.     MVI    A,NULL        ; Prepare for comparison
  126.     CMP    B        ; Is counter now a null?
  127.     JZ    ERROR1        ; Yep, so print error msg & quit
  128.     MOV    A,M        ; Nope, so fetch char
  129.     INX    H        ; & increment pointer
  130.     CPI    SPACE        ; Is it a space?
  131.     JZ    GETIT        ; Yep, try again
  132. ;
  133.     CPI    TOGGLE1        ; Is it first legal toggle?
  134.     JZ    SAVEIT        ; Yep, so skip loop
  135.     CPI    TOGGLE2        ; Is it second legal toggle?
  136.     JZ    SAVEIT        ; Yep
  137.     JMP    ERROR1        ; Nope,so print error msg & quit
  138. ;
  139. SAVEIT:    STA    OPTION        ; We need it later too
  140. ;
  141.     LHLD    WBOOT+1        ; See if we're really pointing to where should
  142.     MOV    L,NULL        ; Will look at first byte of memory page
  143.     MOV    A,M        ; Snatch the byte
  144.     CPI    0C3H        ; A JMP instruction?
  145.     JZ    ERROR2        ; Nope, something's wrong--abort (might be a
  146.                 ; problem with another program trapping WBOOT)
  147. ;
  148.     MVI    L,OFFSET    ; Offset to first arrow char byte    
  149.     XCHG            ; Save pointer while freeing (HL)
  150.     LDA    OPTION        ; Get user choice back
  151.     CPI    TOGGLE1        ; Was it first choice?
  152.     JNZ    ALT        ; Nope, so skip to it
  153.     LXI    H,KEYS1        ; Yep, so point to first set-up
  154.     JMP    DOIT        ; and begin
  155. ALT:    LXI    H,KEYS2        ; Point to second set-up
  156. ;
  157. DOIT:    MVI    B,18        ; Counter = # of arrow + numeric keypad keys
  158. DOIT2:    MOV    A,M        ; Fetch first byte
  159.     STAX    D        ; and poke it
  160.     DCR    B        ; See if counter is done
  161.     MVI    A,NULL
  162.     CMP    B        ; If done...
  163. ;
  164.     IF    STRINGS
  165.     JZ    DOIT3        ; all direct key values are poked
  166.                 ; so go do 4-char strings (if STRINGS YES)...
  167.     ENDIF            ; STRINGS
  168. ;
  169.     IF    NOT STRINGS
  170.     JZ    DONE        ; ... or tell 'em what we've done & quit
  171.     ENDIF            ; NOT STRINGS
  172. ;
  173.     INX    D        ; If not done with direct key values
  174.     INX    H        ; increment both pointers
  175.     JMP    DOIT2        ; and keep truckin' 
  176. ;
  177.     IF    STRINGS
  178. DOIT3:    LHLD    WBOOT+1        ; Set up pointer again--
  179.     MVI    L,OFFST2    ; this time to where CP/M stores strings
  180.     XCHG            ; Free up (HL)
  181.     LDA    OPTION        ; Get choice back
  182.     CPI    TOGGLE1        ; First choice?
  183.     JNZ    ALT2        ; Nope
  184.     LXI    H,STR1        ; Yep
  185.     JMP    DOIT4
  186. ALT2:    LXI    H,STR2
  187. ;
  188. DOIT4:    MVI    B,18*4        ; Counter = # keys * 4-char strings    
  189. DOIT5:    MOV    A,M        ; Fetch first byte
  190.     STAX    D        ; and poke it
  191.     DCR    B        ; See if counter is done
  192.     MVI    A,NULL
  193.     CMP    B        ; 
  194.     JZ    DONE        ; Yep, so tell 'em what we've done & quit
  195.     INX    D        ; If not
  196.     INX    H        ; increment both pointers
  197.     JMP    DOIT5        ; and continue
  198.     ENDIF            ; STRINGS
  199. ;
  200. DONE:    LXI    D,OKMSG        ; Point to successful sign-off msg & ...
  201. ;
  202. EXIT:    MVI    C,PRINTF    ; Tell BDOS to print a string
  203.     CALL    BDOS        ; & do it
  204.     RET            ; then quit
  205. ;    
  206. ; ----- Subroutine to print error msg if invalid command-line toggle
  207. ;
  208. ERROR1:    LXI    D,ERR1        ; Point to error msg
  209.     JMP    EXIT        ; Go print it & quit
  210. ;
  211. ; ---- Error msg if can't find correct page of memory to use
  212. ;
  213. ERROR2:    LXI    D,ERR2        ; Point to error msg
  214.     JMP    EXIT        ; Go print it & quit
  215. ;
  216. ; ----- Storage Area
  217. ;
  218. SIGNON:    DB    CR,LF,'HOTKEYS v. 1.01, (c) 1988, J.W. Olsen',CR,LF,'$'
  219. ERR1:    DB    CR,LF,'Syntax: HK ',TOGGLE1,' or HK ',TOGGLE2,CR,LF,'$'
  220. ERR2:    DB    7,CR,LF,'++ Valid memory locations not found ++',CR,LF,'$'
  221. OKMSG:    DB    '"'    ; Printing of exit msg begins here, continues thru...
  222. OPTION: DS    1    ; User choice (filled when TOGGLE1 or TOGGLE2 selected)
  223. OKMSG2:    DB    '" configuration INSTALLED',CR,LF
  224.     DB    '$'     ; ...end of exit msg (used only if HK is successful)
  225. ;
  226. ; Enter your 1-character preferences for each keystroke below. (For nonprintable
  227. ; characters, use hex. For others, use either hex or alphanumeric. Examples of
  228. ; both below.)
  229. ;
  230. ; "What Is" reflects current values. (Replace with your description if 
  231. ; changes are made.) "Original" indicates vanilla CP/M. "Name" describes the 
  232. ; function of the original key. 
  233. ;
  234. ; "KEYS1" relate to your TOGGLE1 selection, "KEYS2" to TOGGLE2. If you want
  235. ; to substitute a 4-character substitute for any key, enter 00H or NULL for
  236. ; it & see "STR" (string) discussion, below--IF you set "STRINGS" to YES. As
  237. ; released, TOGGLE1 represents my configuration for running a BBS. Toggle 2 
  238. ; is my personal, albeit at first glance seemingly weird preferences for word
  239. ; processing with WordStar/VDE.
  240. ;
  241. ;              What Is    Original    Name
  242. ;              =========    ========    ========
  243. KEYS1:    DB    NULL    ; Uses STR1    05H        Up arrow
  244.     DB    NULL    ; Uses STR1    18H        Down arrow
  245.     DB    NULL    ; Uses STR1    13H        Left arrow
  246.     DB    NULL    ; Uses STR1    04H        Right arrow
  247.     DB    '0'    ; keypad 0    30H        0 (keypad)
  248.     DB    '1'    ; 1        31H        1 "
  249.     DB    '2'    ; 2        32H        2 "
  250.     DB    '3'    ; 3        33H        3 "
  251.     DB    '4'    ; 4        34H        4 "
  252.     DB    '5'    ; 5        35H        5 "
  253.     DB    '6'    ; 6        36H        6 "
  254.     DB    '7'    ; 7        37H        7 "
  255.     DB    '8'    ; 8        38H        8 "
  256.     DB    '9'    ; 9        39H        9 "
  257.     DB    '-'    ; Hyphen    2DH        Hyphen (keypad)
  258.     DB    03H    ; control-C    2CH        Comma    "
  259.     DB    0DH    ; Enter        0DH        Enter    "
  260.     DB    '.'    ; period    2EH        Period    "
  261. ;
  262. ;              What Is    Original    Name
  263. ;              =========    ========    ========
  264. KEYS2:    DB    10H    ; control-P    05H        Up arrow
  265.     DB    0FH    ; control-O    18H        Down arrow
  266.     DB    0BH    ; control-K    13H        Left arrow
  267.     DB    02H    ; control-B    04H        Right arrow
  268.     DB    07H    ; control-G    30H        0 (on KEYPAD)
  269.     DB    19H    ; control-Y    31H        1    
  270.     DB    18H    ; control-X    32H        2    
  271.     DB    06H    ; control-F    33H        3
  272.     DB    13H    ; control-S    34H        4
  273.     DB    11H    ; control-Q    35H        5
  274.     DB    04H    ; control-D    36H        6
  275.     DB    15H    ; control-U    37H        7
  276.     DB    05H    ; control-E    38H        8
  277.     DB    01H    ; control-A    39H        9
  278.     DB    12H    ; control-R    2DH        Hyphen    "
  279.     DB    03H    ; control-C    2CH        Comma    "
  280.     DB    16H    ; control-V    0DH        Enter     "
  281.     DB    14H    ; control-T    2EH        Period    "
  282. ;
  283.     IF    STRINGS
  284. ; For anything that's a NULL above, the corresponding key is replaced by the
  285. ; related string below--if you set STRINGS to YES.
  286. ;
  287. ;              What Is    Original    Name
  288. ;              =========    ========    ========
  289. STR1:    DB    'BYE',CR ; [normally    [all NULLs]    Expands Up arrow
  290.     DB    'CHAT'    ; nulls, but               " downn arrow
  291.     DB    'HELP'    ; set as               " Left arrow
  292.     DB    '`SD '    ; blank spaces               " Right arrow
  293.     DB    '    '    ; here to                " KEYPAD 0
  294.     DB    '    '  ; facilitate                         1
  295.     DB    '    '  ; filling in                        2
  296.     DB    '    '  ; with alpha                    3
  297.     DB    '    '  ; characters]                      4
  298.     DB    '    '  ;                        5
  299.     DB    '    '  ;                        6
  300.     DB    '    '  ;                        7
  301.     DB    '    '  ;                        8
  302.     DB    '    '  ;                        9
  303.     DB    '    '  ;                   "    Hyphen
  304.     DB    '    '  ;                   "    Comma
  305.     DB    '    '  ;                   "    Enter 
  306.     DB    '    '  ;                   "    Period
  307. ;
  308. ;              What Is    Original    Name
  309. ;              =========    ========    ========
  310. STR2:    DB    '    '    ; [all unused]    [all NULLs]    Expands Up arrow
  311.     DB    '    '    ;                   " downn arrow
  312.     DB    '    '    ;                   " Left arrow
  313.     DB    '    '    ;                   " Right arrow
  314.     DB    '    '    ;                   " KEYPAD 0
  315.     DB    '    '  ;                            1
  316.     DB    '    '  ;                            2
  317.     DB    '    '  ;                        3
  318.     DB    '    '  ;                          4
  319.     DB    '    '  ;                        5
  320.     DB    '    '  ;                        6
  321.     DB    '    '  ;                        7
  322.     DB    '    '  ;                        8
  323.     DB    '    '  ;                        9
  324.     DB    '    '  ;                   "     Hyphen
  325.     DB    '    '  ;                   "     Comma
  326.     DB    '    '  ;                   "    Enter 
  327.     DB    '    '  ;                   "    Period
  328.     ENDIF        ; STRINGS
  329. ;
  330. ; ----- That's all, folks
  331. ;
  332.     END
  333.