home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / KAYPRO / HOTKEY11.LBR / HK101-U.AZM / HK101-U.ASM
Assembly Source File  |  2000-06-30  |  13KB  |  416 lines
  1. ;
  2. ; *****************************************************************************
  3. ;
  4. ;                 H O T K E Y S
  5. ;                   v. 1.01-U
  6. ;                  (c) 1988 J.W. Olsen
  7. ;                          15 May 1988
  8. ;
  9. ;       May be used for noncommercial purposes without permission
  10. ;             Inquire for all other purposes
  11. ; If given or sold with any other product, the price for which is more than $10
  12. ; inclusive of all charges, including but not limited to "shipping & handling,"
  13. ; such gift or sale is considered commercial use for purposes of the above.
  14. ;
  15. ; *****************************************************************************
  16. ;
  17. ; Allows redefintion of arrow and numeric-keypad keys. Two sets of redefinition
  18. ; are permitted in a single, assembled HK program. A run-time, command-line
  19. ; toggle key determines which redefinition will be activated. You may freely
  20. ; switch between the two configurations at any time. 
  21.  
  22. ; HK simply pokes the copy of CP/M in memory. Thus, it's transitory and won't
  23. ; affect disks. When you turn off the computer or press the reset button, the
  24. ; effects of HK are gone until you run the program again.
  25. ;
  26. ; HK is run by typing its name, followed by a "toggle" key of your choice, as
  27. ; in "HK W" (e.g., I use "HK B" to run my BBS, "HK W" for word processing with
  28. ; with  WordStar or VDE.) You may want to set one configuration for "vanilla" 
  29. ; CP/M--info to do so is provided.
  30. ;
  31. ; This version works on CP/M Kaypros with U-ROMs. Those with other CP/M Kaypros
  32. ; should use HKxxx.ASM, distributed with this file. For other machines, see 
  33. ; the HKxxx.INF file. The "non-U-ROM" version employs some checks when invoked 
  34. ; not contained herein due to some elusiveness in the logic (maybe illogic) of 
  35. ; the U-ROM. But try it. If it works once on your U-ROM Kaypro, it can be 
  36. ; expected to work consistently.
  37. ;
  38. ; You can reassign one character for each of the normal arrow keys above your
  39. ; main keyboard. And you can assign strings up to EIGHTY characters for each of
  40. ; your numeric-keypad keys--up to a maximum of 225 total characters for all
  41. ; 14 numeric keys together.
  42. ;
  43. ; Run your favorite assembler/linker. ASM and MLOAD work fine. 
  44. ;
  45. ; After assembling, test by first invoking your newly configured "period" key 
  46. ; on the numeric keypad. If that works, HK will work on your machine. If it 
  47. ; misbehaves, you may have a U-ROM version sufficiently different from mine 
  48. ; that some recoding may be needed. If so, outline your experiences and I'll 
  49. ; try to help. If ANYTHING doesn't seem to work correctly, RESET YOUR MACHINE
  50. ; BEFORE USING AGAIN. An unintended area in high memory will have been
  51. ; overwritten, and could consistently or unpredictably produce weird results.
  52. ;
  53. ; NOTE: Only the arrow keys above the main keyboard and the numeric keypad
  54. ; keys are redefined. All other keys are unaffected, including the number keys
  55. ; on the main keypad.
  56. ;
  57. ; This was a quickie effort to meet a special need, but performs its function
  58. ; fully. Experienced 8080 programmers (of which it will be readily apparent
  59. ; I'm not one) undoubtedly will be able to reduce the code further and suggest
  60. ; further improvements. That would be welcomed. But if in the meantime you
  61. ; too find HK useful, enjoy. Please direct comments, or check for any updates
  62. ; on my BBS.
  63. ; 
  64. ;       Jerry Olsen
  65. ;    Sysop, The Advocate/NOWAR RCP/M
  66. ;    312.939.4411
  67. ;    24 hrs., 300/1200/2400, 8/n/1
  68. ; 
  69. ; ----- Preliminaries
  70. ; 
  71. ;    ASEG            ; Comment out if assembling with other than M80
  72. ;
  73. NO    EQU    0        ; Leave these alone
  74. YES    EQU    NOT NO
  75. ;
  76. ; ----- User-settable equates
  77. ;
  78. TOGGLE1 EQU    'B'        ; Specify two characters as command-line
  79. TOGGLE2    EQU    'W'        ; toggles for configurations you desire.
  80.                 ; A toggle may be any single letter, number
  81.                 ; or punctuation. LOWER CASE letters are NOT
  82.                 ; allowed. You might want to set one to "V"
  83.                 ; for "vanilla" CP/M settings.
  84. ; *** You also need to set up the arrays toward the end of this file ***
  85. ;
  86. ; ----- System-specific equates (change ONLY if these prove incorrect for
  87. ;       your system after testing)
  88. ;
  89. AROVEC    EQU    0F143H        ; Location of first byte of arrow keys
  90.                 ; are stored.
  91. NUMVEC    EQU    0F060H        ; Similarly, for numeric keys
  92. NUMLEN    EQU    0F044H        ; Lengths of each numeric-keypad definition
  93.                 ; are poked beginning here, skipping one byte
  94.                 ; between addresses to poke (i.e., F044H,
  95.                 ; F046H, etc.)
  96. MAXLEN    EQU    225        ; Max. # of all numeric-keypad reconfiguration
  97.                 ; strings combined as allowed by U-ROM Kaypros
  98. ;
  99. ; ----- Miscellaneous equates (leave alone)
  100. ;
  101. BDOS    EQU    5        ; BDOS entry point
  102. PRINTF    EQU    9        ; Print-a-string function
  103. BUFF    EQU    80H        ; Command line buffer
  104. CR    EQU    0DH        ; Carriage return
  105. LF    EQU    0AH        ; Linefeed
  106. SPACE    EQU    20H        ; Ordinary blank space
  107. NULL    EQU    0        ; May be used in arrays if desired
  108. ;
  109. ; ----- Begin
  110. ;
  111.     ORG    100H        ; Normal TPA entry point
  112. ;
  113.     LXI    D,SIGNON    ; Point to sign-on msg
  114.     MVI    C,PRINTF    ; Tell BDOS we want to print a string
  115.     CALL    BDOS        ; and do it
  116. ;
  117. ;    LXI    H,BUFF        ; Get address of command-line buffer
  118.     MOV    A,M        ; Get buffer length
  119.     CPI    NULL        ; Is it a null?
  120.     JZ    ERROR1        ; Yep, so print error msg & quit
  121. ;
  122.     MOV    B,A        ; Nope, so save command-line length
  123.     LXI    H,BUFF+1    ; Point to first char of command line
  124. GETIT:    DCR    B        ; Decrement our length counter
  125.     MVI    A,NULL        ; Prepare for comparison
  126.     CMP    B        ; Is counter now a null?
  127.     JZ    ERROR1        ; Yep, so print error msg & quit
  128.     MOV    A,M        ; Nope, so fetch char
  129.     INX    H        ; & increment pointer
  130.     CPI    SPACE        ; Is it a space?
  131.     JZ    GETIT        ; Yep, try again
  132. ;
  133.     CPI    TOGGLE1        ; Is it first legal toggle?
  134.     JZ    SAVEIT        ; Yep, so skip loop
  135.     CPI    TOGGLE2        ; Is it second legal toggle?
  136.     JZ    SAVEIT        ; Yep
  137.     JMP    ERROR1        ; Nope,so print error msg & quit
  138. ;
  139. SAVEIT:    STA    OPTION        ; Save it for later
  140. ;
  141.     LXI    D,AROVEC    ; Point to first location to poke with
  142.                 ; arrow configuration
  143.     LDA    OPTION        ; Get user choice back
  144.     CPI    TOGGLE1        ; Was it first choice?
  145.     JNZ    ALT        ; Nope, so skip to it
  146.     LXI    H,ARO1        ; Yep, so point to first set-up
  147.     JMP    DOIT        ; and begin
  148. ALT:    LXI    H,ARO2        ; Point to second set-up
  149. ;
  150. DOIT:    MVI    B,4        ; Counter for # of arrow keys
  151. DOIT2:    MOV    A,M        ; Fetch first byte
  152.     STAX    D        ; and poke it
  153.     DCR    B        ; See if counter is done
  154.     MVI    A,NULL
  155.     CMP    B        ; If done...
  156.     JZ    DOIT3        ; go deal with numeric-keypad configurations
  157. ;
  158.     INX    D        ; If not done 
  159.     INX    H        ; increment both pointers
  160.     JMP    DOIT2        ; and keep truckin' 
  161. ;
  162. DOIT3:    LXI    D,NUMVEC    ; Point to first location to poke with
  163.                 ; numeric keypad strings
  164.     LDA    OPTION        ; Get choice back
  165.     CPI    TOGGLE1        ; First choice?
  166.     JNZ    ALT2        ; Nope
  167.     LXI    H,NUM1        ; Yep, so point to its numeric configs
  168.     JMP    DOIT4
  169. ALT2:    LXI    H,NUM2        ; Point to 2nd numeric configs
  170. ;
  171. DOIT4:    MVI    B,NULL        ; We'll use (B) as a counter
  172. DOIT5:    MOV    A,M        ; Fetch first byte
  173.     CPI    0FFH        ; Reached our end-of-strings indicator?
  174.     JZ    DOIT6        ; Yep
  175.     STAX    D        ; Nope, so poke it
  176.     INR    B        ; Count # of bytes poked,
  177.     INX    D        ; increment both pointers,
  178.     INX    H        ; 
  179.     JMP    DOIT5        ; & continue
  180. ;
  181. DOIT6:    MVI    A,0FFH        ; The U-ROM expects 2 0FFh chars after our
  182.     STAX    D        ; string
  183.     INX    D
  184.     STAX    D
  185. ;
  186.     MOV    A,B        ; Prepare to save counter
  187.     STA    COUNT        ; & do it
  188. ;
  189.     LXI    D,NUMLEN    ; Point to first location to poke with LENGTH
  190.                 ; of each numeric-keypad definition
  191.     LDA    OPTION        ; Get choice back
  192.     CPI    TOGGLE1        ; First choice?
  193.     JNZ    ALT3        ; Nope
  194.     LXI    H,NLEN1        ; Yep, so point to 1st set of string lengths
  195.     JMP    DOIT7
  196. ALT3:    LXI    H,NLEN2        ; Point to 2nd set
  197. ;
  198. DOIT7:    MVI    B,NULL        ; Again, our counter
  199. ;
  200.     MOV    A,M        ; Fetch first byte
  201.     PUSH    A        ; Save it for a moment
  202.     ADD    B        ; Our # of bytes counter
  203.     MOV    B,A        ; Save byte counter
  204.     POP    A        ; Get our character back again
  205.     MOV    C,A        ; Start an offset value CP/M needs
  206.     STAX    D        ; Poke it
  207.     INX    D        ; Increment both of our pointers
  208.     INX    H        ; 
  209.     LDAX    D        ; Grab following byte
  210.     ADD    C        ; Add it to CP/M's offset value 
  211.     MOV    C,A        ; & save it
  212.     INX    D        ; Bump (DE) once again
  213. ;
  214. ; Repeat for succeeding bytes, with variations on the theme
  215. ;
  216. DOIT8:    MOV    A,M        ; Fetch next byte
  217.     CPI    0FFH        ; Reached our end-of-strings indicator?
  218.     JZ    DOIT9        ; Yep
  219.     PUSH    A        ; Nope, so deal with our byte counter 
  220.     ADD    B
  221.     MOV    B,A
  222.     POP    A
  223.     STAX    D        ; Poke our NLEN byte
  224.     PUSH    A        ; Save again
  225.     MOV    A,C        ; Get CP/M's current running offset
  226.     INX    D        ; Increment our pointer
  227.     STAX    D        ; & poke CP/M's offset now
  228.     POP    A        ; OK, get value back
  229.     ADD    C        ; & add it to the running CP/M offset
  230.     MOV    C,A        ; ... which needs to be saved again
  231.     INX    H        ; Now increment (HL) pointer
  232.     INX    D        ; & bump (DE) again
  233.     JMP    DOIT8        ; ... & finally, time to fetch next
  234. ;
  235. DOIT9:    LDA    COUNT        ; Get our 1st counter back
  236.     CMP    B         ; Is it the same?
  237.     JNZ    ERROR2        ; Nope, so tell 'em & quit
  238.     MVI    A,MAXLEN    ; Max. # of bytes allowed for all numeric-
  239.                 ; keypad reconfigs allowed by U-ROM Kaypros
  240.     CMP    B        ; Too many bytes? 
  241.     JC    ERROR3        ; Yep, so tell 'em & quit
  242.     LXI    D,OKMSG        ; Otherwise, point to "all's OK" sign-off msg
  243.                 ; and...
  244. ;
  245. EXIT:    MVI    C,PRINTF    ; Tell BDOS to print a string
  246.     CALL    BDOS        ; & do it
  247.     RET            ; then quit
  248. ;    
  249. ; ----- Subroutine to print error msg if invalid command-line toggle
  250. ;
  251. ERROR1:    LXI    D,ERR1        ; Point to error msg
  252.     JMP    EXIT        ; Go print it & quit
  253. ;
  254. ; ----- Exit routines if assembly-time error detected
  255. ;
  256. ERROR2:    LXI    D,ERR2        ; Point to error msg
  257.     JMP    EXIT        ; Go print & exit
  258. ;
  259. ERROR3:    LXI    D,ERR3        ; Point to error msg and...
  260.     JMP    EXIT        ; Go print & exit
  261. ;
  262. ; ----- Storage Area
  263. ;
  264. SIGNON:    DB    CR,LF,'HOTKEYS v. 1.00U, (c) 1988, J.W. Olsen',CR,LF,'$'
  265. ERR1:    DB    CR,LF,'Syntax: HK ',TOGGLE1,' or HK ',TOGGLE2,CR,LF,'$'
  266. ERR2    DB    CR,LF,7,'ASSEMBLY-TIME ERROR: For the selected option,'
  267.     DB    CR,LF,'number of bytes for "NUM" and "NLEN" don''t match'
  268.     DB    CR,LF,'$'
  269. ERR3:    DB    CR,LF,7,'ASSEMBLY-TIME ERROR: For the selected option,'
  270.     DB    CR,LF,'combined length of numeric-keypad definitions too long'
  271.     DB    CR,LF,'$'
  272. OKMSG:    DB    '"'    ; Printing of exit msg begins here, continues thru...
  273. OPTION: DS    1    ; User choice (filled when TOGGLE1 or TOGGLE2 selected)
  274. OKMSG2:    DB    '" configuration INSTALLED',CR,LF
  275.     DB    '$'    ; ...end of exit msg (used only if HK is successful)
  276. COUNT:    DS    1    ; Will be filled with # of numeric-keypad bytes poked
  277. ;
  278. ; Enter your 1-character preferences for each arrow key below. (For nonprintable
  279. ; characters, which you'll almost sure want, use hex. For others, use either hex
  280. ; or alphanumeric. Alphanumeric characters may be placed within SINGLE quote
  281. ; marks, as in: DB    'A'.)
  282. ;
  283. ; FOR TOGGLE1
  284. ;
  285. ARO1:    DB    05H    ; Value for UP arrow key
  286.     DB    18H    ; DOWN arrow
  287.     DB    13H    ; LEFT arrow
  288.     DB    04H    ; RIGHT arrow
  289.     DB    0FFH    ; Don't alter this
  290. ;
  291. ; FOR TOGGLE2
  292. ;
  293. ARO2:    DB    05H    ; UP arrow
  294.     DB    18H    ; DOWN arrow
  295.     DB    13H    ; LEFT arrow
  296.     DB    04H    ; RIGHT arrow
  297.     DB    0FFH    ; Don't alter this
  298. ;
  299. ; Enter your strings for each numeric-keypad character below. For alphanumeric
  300. ; redefinitions, place between single quote marks. For control characters,
  301. ; enter hex values. They may be combined, if separated by commas. Example:
  302. ; 'this is a sample of alphanumeric characters',0DH,0AH,'separated by hex'
  303. ; The MAXIMUM length of EACH string is 80 characters. The maximum TOTAL length
  304. ; of ALL strings for "NUM1" strings is 225 characters. Same for "NUM2" strings.
  305. ; Enter each string on the line following the comment designating the key that
  306. ; it will redefine.
  307. ;
  308. ; FOR TOGGLE1
  309. ;
  310. ; "0" key on numeric keypad:
  311. NUM1:    DB    '0'
  312. ; "1":
  313.     DB    '1'
  314. ; "2":
  315.     DB    '2'
  316. ; "3":
  317.     DB    '3'
  318. ; "4":
  319.     DB    '4'
  320. ; "5":
  321.     DB    '5'
  322. ; "6":
  323.     DB    '6'
  324. ; "7":    
  325.     DB    '7'
  326. ; "8"
  327.     DB    '8'
  328. ; "9":
  329.     DB    '9'
  330. ; Hyphen key on numeric keypad:
  331.     DB    '-'
  332. ; Comma:
  333.     DB    ','
  334. ; Enter key:
  335.     DB    0DH
  336. ; Period:
  337.     DB    '.'
  338. ; Don't alter next line
  339.     DB    0FFH
  340. ;
  341. ; FOR TOGGLE2
  342. ;
  343. ; "0" key on numeric keypad:
  344. NUM2:    DB    '0'
  345. ; "1":
  346.     DB    '1'
  347. ; "2":
  348.     DB    '2'
  349. ; "3":
  350.     DB    '3'
  351. ; "4":
  352.     DB    '4'
  353. ; "5":
  354.     DB    '5'
  355. ; "6":
  356.     DB    '6'
  357. ; "7":    
  358.     DB    '7'
  359. ; "8"
  360.     DB    '8'
  361. ; "9":
  362.     DB    '9'
  363. ; Hyphen key on numeric keypad:
  364.     DB    '-'
  365. ; Comma:
  366.     DB    ','
  367. ; Enter key:
  368.     DB    0DH
  369. ; Period:
  370.     DB    '.'
  371. ; Don't alter next line
  372.     DB    0FFH
  373. ;
  374. ; Enter the LENGTH of each "NUM1" string above, in HEX. Be sure the total
  375. ; doesn't exceed 225 bytes.
  376. ;
  377. ; FOR TOGGLE1:
  378. ;
  379. NLEN1:    DB    01H    ; For 0 key
  380.     DB    01H    ; For 1 key
  381.     DB    01H    ; For 2 key
  382.     DB    01H    ; For 3 key
  383.     DB    01H    ; For 4 key
  384.     DB    01H    ; For 5 key
  385.     DB    01H    ; For 6 key
  386.     DB    01H    ; For 7 key
  387.     DB    01H    ; For 8 key
  388.     DB    01H    ; For 9 key
  389.     DB    01H    ; For hyphen
  390.     DB    01H    ; For comma 
  391.     DB    01H    ; For enter 
  392.     DB    01H    ; For period 
  393.     DB    0FFH    ; Don't alter this
  394. ;
  395. ; FOR TOGGLE2:
  396. ;
  397. NLEN2:    DB    01H    ; For 0 key
  398.     DB    01H    ; For 1 key
  399.     DB    01H    ; For 2 key
  400.     DB    01H    ; For 3 key
  401.     DB    01H    ; For 4 key
  402.     DB    01H    ; For 5 key
  403.     DB    01H    ; For 6 key
  404.     DB    01H    ; For 7 key
  405.     DB    01H    ; For 8 key
  406.     DB    01H    ; For 9 key
  407.     DB    01H    ; For hyphen
  408.     DB    01H    ; For comma 
  409.     DB    01H    ; For enter 
  410.     DB    01H    ; For period 
  411.     DB    0FFH    ; Don't alter this
  412. ;
  413. ; ----- That's all, folks
  414. ;
  415.     END
  416.