home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / ENTERPRS / CPM / UTILS / S / UNERA31.ARC / UNERA31.A86 next >
Text File  |  1991-10-05  |  19KB  |  765 lines
  1. ; DATE 02/16/84  16:16       last update
  2. ; 02/16/84 the program has been converted to support both CP/M-86 ver 3.1
  3. ; and CCP/M-86 ver 3.1.
  4. ; MP/M is not supported but only because I don't have a way to test this
  5. ; version on the MPM operating system.
  6.  
  7.     TITLE    'UNERA     FOR CP/M-86 VER3.1'
  8.  
  9. ; UNERA31.A86
  10. ; by: H.H. Van Tassell, 120 Hill Hollow Rd, Watchung NJ  07060 (201)755-5272
  11. ;
  12. ; This is a program to recover erased files in CP/M-86 and is modelled on the
  13. ; UNERA program for CP/M-80 on SIG/M volume 76. See volumes 76 and 44 for 
  14. ; author credits and more information.
  15. ; 
  16. ; The program reads the directory, sector by sector, listing filenames that
  17. ; have been erase by placing an 0E5H as byte 0. The extent number is also
  18. ; listed. NO check is made to determine if the disk space has been re-allocated
  19. ; to another file after the file was erased. After listing the file names, the 
  20. ; user is asked if recovery is desired. A page of help is displayed if the
  21. ; program is invoked with // as the file name.
  22.  
  23. ; The direct BIOS disk call data structure was choosen for conversion to 
  24. ; CP/M-86 versions 3.0 and higher (CONCURRENT and PLUS).
  25. ;
  26. ; TO GENERATE PROGRAM:
  27. ;    RASM86 UNERA $SZPZ
  28. ;    LINK86 UNERA [data[add [100]]]
  29. ;
  30.  
  31. ;
  32. SLINES    EQU    22            ;LINES ON CONSOLE LESS 2
  33.  
  34. FALSE    EQU    0
  35. TRUE    EQU    NOT FALSE
  36.  
  37. CR    EQU    13
  38. LF    EQU    10
  39. TAB    EQU    9
  40.  
  41. CONIN    EQU    1        ;READ CONSOLE
  42. DCONIN    EQU    6        ;DIRECT CONSOLE READ
  43. RESET    EQU    13        ;SYSTEM RESET
  44. SELDSK    EQU    14        ;SELECT DISK
  45. GETDR    EQU    25        ;GET DRIVE
  46. DIRBIOS    EQU    50        ;DIRECT BIOS CALLS
  47.  
  48. ; DIRECT BIOS CALL PARAMETER BLOCK DATA STRUCTURE
  49. ;
  50. BPB_FUNC EQU    BYTE PTR 0[BX]
  51. BPB_CX     EQU    WORD PTR 1[BX]
  52. BPB_DX     EQU    WORD PTR 3[BX]
  53.  
  54. ; DISK BIOS CALLS DATA STRUCTURE
  55. ;
  56. SELECT_DISK    EQU  WORD PTR 0[BX]
  57. SET_TRACK    EQU  WORD PTR 2[BX]
  58. SET_DMASEG    EQU  WORD PTR 4[BX]
  59. SET_DMAOFF    EQU  WORD PTR 6[BX]
  60. SET_SECTOR    EQU  WORD PTR 8[BX]
  61. READ_SECTOR    EQU  WORD PTR 10[BX]
  62. WRITE_SECTOR    EQU  WORD PTR 12[BX]
  63. SECTOR_XLAT    EQU  WORD PTR 14[BX]
  64.  
  65.  
  66. TBUF    EQU    80H        ;TRANSIT DEFAULT BUFFER
  67. FCB    EQU    5CH        ;DEFAULT FILE CONTROL BLOCK
  68.                                     
  69. DRV_DPB        equ    31    ;BDOS call 31
  70.  
  71.  
  72. BIO_SELDSK     equ    9        ;BIOS function number
  73. BIO_READ      equ    10        ;BIOS function number
  74. BIO_WRITE      equ    11        ;BIOS function number
  75.  
  76. ; PARTIAL DATA STRUCTURE OF DPH
  77. ;
  78. LOG_SEQN    equ    byte ptr 6    ;to force reset of permanent media
  79. DPB_PTR31    equ    word ptr 8    ;offset of DPB pointer in DPH (v3.1)
  80. DPB_PTR11    equ    word ptr 10    ;offset in version 1.1
  81. DPB_SIZE    equ    17        ;size of Disk Parameter Block
  82.  
  83.  
  84. ; DPB DATA STRUCTURE 
  85. ;
  86. SPT        equ    word ptr 0[bx]
  87. BSH        equ    byte ptr 2[bx]
  88. BLM        equ    byte ptr 3[bx]
  89. EXM        equ    byte ptr 4[bx]
  90. DSM        equ    word ptr 5[bx]
  91. DRM        equ    word ptr 7[bx]
  92. AL0        equ    byte ptr 9[bx]
  93. AL1        equ    byte ptr 10[bx]
  94. CKS        equ    word ptr 11[bx]
  95. OFF        equ    word ptr 13[bx]
  96. PHYSHF        equ    byte ptr 15[bx]
  97. PHYMSK        equ    byte ptr 16[bx]
  98.  
  99.  
  100. BIOS_PTR      equ    dword ptr .28h    ;loc of BIOS entry in SYSDAT
  101. UDA_SEG          equ    word ptr .4eh    ;loc of UDA seg in system data area
  102.  
  103. ;------- for CCP/M -3.1 ----------------
  104. S_SYSDAT    equ    154        ;get system data area
  105. P_PDADR        equ    156        ;get PDA address
  106.  
  107. CCPM_31    equ    1431h            ;CCP/M-86 version number
  108.  
  109. P_UDA        equ    word ptr 10h    ;User Data Area
  110. ;-----------------------------------------
  111.  
  112.  
  113.     CSEG
  114.  
  115.     MOV    CX,DS        ;USING DATA SEGMENT
  116.     MOV    SS,CX        ;SET UP LOCAL STACK
  117.     LEA    SP,STACK    
  118.  
  119.     CALL    HELLO
  120.     CALL    PCHECK
  121.     CALL    TRYFIX
  122.     CMP    FIXCNT,0    ;WERE ANY FIXABLE FILES FOUND?
  123.     JZ    NO_RECOVER
  124.     CALL    RECOVER        ;YES, GO RECOVER EM
  125. NO_RECOVER:
  126.     CALL    BYE
  127. EXIT:
  128.     MOV    CL,SELDSK            ;RETURN TO CURRENT DISK
  129.     MOV    DL,BYTE PTR CURDR
  130.     INT    224
  131.     MOV    CL,RESET            ;RESET SYSTEM
  132.     INT    224
  133. QUIT:
  134.     MOV    CL,0
  135.     MOV    DL,0
  136.     INT    224
  137.  
  138. ; SAY WHO WE ARE
  139. HELLO:
  140.     MOV    DX,OFFSET HMSG            ;POINT TO HELLO MESSAGE
  141.     CALL    PRINT
  142.     RET
  143.  
  144. ; CHECK FOR VALID PARAMETERS
  145. PCHECK:
  146.     CALL    FCBCHK            ;MAKE SURE FILE IS SPECIFIED
  147.     CALL    CPMCHK            ;CHECK CP/M VERSION
  148.     RET
  149.  
  150. ; ASK IF THEY WANT TO RECOVER THE REVIEWED FILES
  151. RECOVER:
  152.     MOV    DX,OFFSET RVMSG        ;ASK IF RECOVERY WANTED
  153.     CALL    PRINT
  154.     MOV    CL,CONIN        ;GET ANSWER
  155.     INT    224
  156.     AND    AL,5FH            ;MAKE UPPER CASE
  157.     CMP    AL,'Y'
  158.     JNE    EXIT            ;EXIT UNLESS YES
  159.     MOV    VIEW_EM,0        ;RESET THE VIEW FLAG
  160.     MOV    FIX_EM,0FFH        ;SET THE FIX EM FLAG
  161.     MOV    AL,BYTE PTR MAXSEC    ;RESTORE MAXDIR
  162.     MOV    BYTE PTR MAXDIR,AL
  163.     MOV    SECTOR,0        ;SECTOR 
  164.     MOV    FIXCNT,0        ;AND FIXCOUNT
  165.     CALL    TRYFIX            ;AND FIXEM
  166.     RET
  167.  
  168. ; LOOK THROUGH THE DIRECTORY TRYING TO MATCH FCB FILENAME
  169. TRYFIX:
  170.     CALL    NXTSECT            ;GET A DIRECTORY SECTOR
  171.     JNZ    TRY_MORE        ;RETURNS ZERO SET IF NO MORE
  172.     RET
  173. TRY_MORE:
  174.     CALL    CHKENT            ;CHECK IT OUT AND MAYBE FIX
  175.     JMPS    TRYFIX            ;KEEP IT UP TILL DONE
  176.  
  177. ; SIGN OFF 
  178. BYE:
  179.     CMP    FIXCNT,0        ;CHECK FOR ACTIVITY    
  180.     JE    NOFIND
  181.     MOV    DX,OFFSET BMSG        ;WARN EM
  182.     CALL    PRINT
  183.     RET
  184. NOFIND:
  185.     MOV    DX,OFFSET NFMSG        ;SAY NOTHING FOUND
  186.     CALL    PRINT
  187.     RET
  188.  
  189. ; MAKE SURE A LEGAL FILENAME WAS FOUND
  190. FCBCHK:
  191.  
  192. ; scans tbuffer at 80h for a / as indication of help wanted
  193. ; returns with ZF set if '/' is found in buffer
  194. ;
  195.     push es ! push ds ! pop es    ;save ES, ES=DS
  196.     xor    cx,cx
  197.     mov    di,80h            ;point to tbuffer @ 80h
  198.     mov    cl,byte ptr[di]        ;CX=length of tbuf string
  199.     inc    cx
  200.     mov    al,'/'
  201.     repnz    scasb            ;scan for /
  202.     pop    es            ;ZF set if help signal
  203.     jz    help
  204.  
  205.     CMP    BYTE PTR .FCB+1,' '    ;IS 1ST BYTE A NON BLANK
  206.     JBE    NO_NAME
  207.  
  208.  
  209.     MOV    CL,GETDR        ;GET CURRENT DRIVE
  210.     INT    224
  211.     MOV    BYTE PTR CURDR,AL    ;SAVE IT
  212.  
  213.     MOV    AL,BYTE PTR .FCB    ;SEE IF DEFAULT DRIVE SPEC
  214.     CMP    AL,0
  215.     JZ    DEFAULT            ;YES, NO DEC
  216.     DEC    AL            ;ELSE DEC IT
  217.     PUSH    AX
  218.     MOV    CL,SELDSK        ;SELECT DISK
  219.     MOV    DL,AL
  220.     INT    224
  221.     POP    AX
  222.     JMPS    NOT_DEFAULT
  223. DEFAULT:
  224.     MOV    AL,CURDR
  225. NOT_DEFAULT:
  226.     MOV    BYTE PTR .FCB,AL    ;PUT IT BACK AND
  227.     MOV    DRIVE,AL
  228.  
  229.     ADD    AL,'A'            ;MAKE IT ASCII
  230.     MOV    BYTE PTR FILNAM0,AL    ;AND PUT IT IN FILNAM DATA
  231.     RET
  232. NO_NAME:
  233.     MOV    DX,OFFSET NOFMSG    ;CANT FIND A FILE NAME
  234.     CALL    PRINT
  235.     JMP    QUIT
  236.  
  237. ; GIVE EM SOME HELP AND QUIT
  238. HELP:
  239.     MOV    DX,OFFSET HLPMSG
  240.     CALL     PRINT
  241.     JMP    QUIT
  242.  
  243. IS_MPM:
  244.     MOV    DX,OFFSET MPMSG
  245.     CALL    PRINT
  246.     JMP    EXIT
  247.  
  248. UNK_VER:
  249.     MOV    DX,OFFSET WVMSG
  250.     CALL    PRINT
  251.     JMP    EXIT
  252.  
  253. ; CHECKS CPM VERSION AND INITIALIZES THINGS
  254. CPMCHK:
  255.     MOV    CL,12            ;GET VERSION NUMBER
  256.     INT    224
  257.     MOV    CPM_VERSION,AX        ;SAVE IT
  258.     TEST    AH,01H            ;IS IT MP/M ?
  259.     JNZ     IS_MPM
  260.     CMP    AL,22H            ;IS IT VERSION 11
  261.     JE    VER_11
  262.     CMP    AL,31H            ;IS IT VERSION 31
  263.     JE    VER_31
  264.     JMP    UNK_VER            ;UNKNOWN VERSION
  265.  
  266. VER_11:
  267.     MOV    CALL_TBL,OFFSET TABLE11
  268.     JMPS    VER_OK
  269. VER_31:
  270.     MOV    CALL_TBL,OFFSET TABLE31
  271. VER_OK:
  272.     MOV    CL,BYTE PTR .FCB    ;GET DRIVE
  273.     XOR    CH,CH
  274.     XOR    DX,DX            ;FIRST SELECTION
  275.     MOV    BX,CALL_TBL
  276.     CALL    SELECT_DISK        ;SELECT DISK
  277.     CMP    BX,0            ;IS DISK OK
  278.     JNZ    DISKOK            ;TELL IF NOT OK
  279.     CALL    ILDISK
  280. DISKOK:                    ;A CALL TO DISK SELECT COPYS
  281.     CMP    BYTE PTR CPM_VERSION,31H ! JE SETUP31
  282. SETUP11:
  283.     MOV    AX,ES:WORD PTR [BX]    ;XLAT TABLE ADDRESS IN BX
  284.     MOV    XLAT_ADR,AX
  285.     MOV    CL,31            ;GET DISK PARAMETERS
  286.     INT    224
  287.     MOV    AX,ES:WORD PTR 13[BX]    ;GET DIRECTORY TRACK
  288.     MOV    DX,ES:WORD PTR 7[BX]    ;DX=DRM
  289.     MOV    CL,2            ;SHIFT RIGHT TWICE
  290.     JMPS    COM_SETUP
  291. SETUP31:
  292.     MOV    BX,OFFSET DPB        ;THE DPB TO LOCAL STORAGE
  293.     MOV    AX,SPT
  294.     MOV    SEC_PER_TRK,AX
  295.     MOV    AL,4
  296.     MOV    CL,PHYSHF        ;GET PHYSICAL SHIFT
  297.     CMP    CL,0 ! JZ SSSD        ;PHYSHF IS ZERO FOR SSSD
  298.     SHL    AL,CL            ;SHIFT LEFT ? TIMES GIVES
  299. SSSD:
  300.     MOV    DIR_PER_SEC,AL        ;NUMBER DIR ENTRYS/SECTOR
  301.  
  302.     MOV    AX,OFF            ;GET DIRECTORY TRACK
  303.     MOV    DX,DRM            ;GET NUMBER OF DIR ENTRYS-1
  304.     MOV    CL,PHYSHF
  305.     ADD    CL,2            
  306. COM_SETUP:
  307.     INC    DX            ;ACCOUNT FOR -1
  308.     SHR    DX,CL            ;SHIFT RIGHT ? TIMES = SECTORS
  309.     MOV    MAXDIR,DX        ;SAVE NUMBER OF DIR SECTORS
  310.     MOV    MAXSEC,DX
  311.  
  312.     MOV    TRACK,AX        ;SAVE DIRECTORY TRACK
  313.     MOV    SECTOR,0        ;ZERO SECTOR COUNT
  314.     MOV    FIXCNT,0
  315.  
  316.     MOV    CX,DS
  317.     MOV    DMASEG,CX
  318.     MOV    BX,CALL_TBL
  319.     CALL    SET_DMASEG        ;SET DMA SEGMENT TO DATA SEG
  320.     MOV    CX,DMAOFF
  321.     MOV    BX,CALL_TBL
  322.     CALL    SET_DMAOFF        ;SET DMA TO DIR_BUF
  323.     RET
  324.  
  325. ; READS NEXT SECTOR (GROUP OF DIRECTORY ENTRIES)
  326. ; RETURN WITH ZERO SET IF NO MORE
  327. NXTSECT:
  328.     CMP    MAXDIR,0
  329.     JNZ    DO_SECT
  330.     RET                ;RET WITH ZERO SET
  331. DO_SECT:
  332.     MOV    CX,TRACK        ;SET TRACK
  333.     MOV    BX,CALL_TBL
  334.     CALL    SET_TRACK
  335.     MOV    CX,SECTOR
  336.     MOV    BX,CALL_TBL
  337.     CALL    SECTOR_XLAT        ;RETURNS XLATED SECT IN BX
  338.     MOV    CX,BX
  339.     MOV    BX,CALL_TBL
  340.     CALL    SET_SECTOR
  341.     MOV    BX,CALL_TBL
  342.     CALL    READ_SECTOR
  343.     AND    AL,1            ;REVERSE SENSE OF ERROR FLAG
  344.     XOR    AL,1            ;RETURN WITH ZERO SET IF BAD READ
  345.     RET                
  346.  
  347. ; CHECK THE CURRENT GROUP DIRECTORY ENTRIES AGAINST ARGUMENT
  348. ; IF MATCH, REWRITE SECTOR WITH REACTIVATED FIRST BYTE
  349. CHKENT:
  350.     MOV    REWRT,0            ;ASSUME NO REWRITE
  351.     MOV    CL,DIR_PER_SEC        ;# ENTRIES TO CHECK
  352.     MOV    BX,OFFSET DIR_BUF    ;THIS IS WHERE THEY ARE AT...
  353. CKLOOP:
  354.     CMP    BYTE PTR [BX],0E5H    ;IS IT UNUSED?
  355.     JNE     CKINC            ;NO, GO DO ANOTHER    
  356.     CMP    BYTE PTR 1[BX],0E5H    ;IF THIS IS AN E5 THEN ITS
  357.     JE    CKINC            ;...NOT A DIR NAME    
  358.     CMP    BYTE PTR 1[BX],00H    ;IF THIS IS AN 00 THEN ITS
  359.     JE    CKINC            ;...NOT A DIR NAME    
  360.     PUSH    BX
  361.     CALL    COMPAR            ;COMPARE WITH ARGUMENT
  362.     POP    BX
  363.     JNZ    CKINC            ;JMP IF ZERO NOT SET, NO MATCH
  364.     CMP    FIX_EM,0FFH        ;SHOULD WE FIX EM?
  365.     JNE    NO_FIX
  366.     MOV    BYTE PTR [BX],0        ;ELSE, REACTIVATE IT
  367.     MOV    REWRT,0FFH        ;SET REWRITE FLAG
  368. NO_FIX:
  369.     INC    FIXCNT            ;BUMP FIX COUNTER
  370.     CMP    VIEW_EM,0FFH        ;IS THE VIEW FLAG SET?
  371.     JNE    CKINC            ;NO,JMP OVER THE SHOW-OFF
  372.     PUSH    BX
  373.     CALL    SHOWIT            ;ELSE, TELL EM HOW GOOD YOU ARE
  374.     POP    BX
  375. CKINC:                    ;DO ANOTHER ENTRY    
  376.     ADD    BX,32
  377.     DEC    CL            ;ONE LESS TO DO    
  378.     JNZ    CKLOOP            ;GO DO IT
  379.     CMP    REWRT,0            ;NEED REWRITE 
  380.     JZ    CKDONE            ;NO, THEN DONE WITH CHECK
  381.  
  382. ; WRITE DIRECTORY ENTRY BACK TO THE DISK
  383.     MOV    CX,TRACK        ;SET TRACK
  384.     MOV    BX,CALL_TBL
  385.     CALL    SET_TRACK
  386.     MOV    CX,SECTOR
  387.     MOV    BX,CALL_TBL
  388.     CALL    SECTOR_XLAT        ;RETURNS XLATED SECT IN BX
  389.     MOV    CX,BX
  390.     MOV    BX,CALL_TBL
  391.     CALL    SET_SECTOR
  392.     MOV    BX,CALL_TBL
  393.     CALL    WRITE_SECTOR
  394.     CMP    AL,0    
  395.     JZ    CKDONE
  396.     JMP    ERRWRT            ;WOOPS
  397. CKDONE:
  398.     DEC    MAXDIR            ;REDUCE SECTORS LEFT
  399.     INC    SECTOR            ;BUMP TO NEXT SECTOR
  400.     RET
  401.  
  402. ; COMPARE 11 BYTES OF DIRECTORY ENTRY AGAINST ARGUMENT
  403. ; RETURN WITH ZERO FLAG SET IF MATCH IS MADE
  404. COMPAR:
  405.     MOV    CL,11            ;COMP 11 CHARS.
  406.     INC    BX            ;BX POINTS TO DIR ENTRY
  407.     MOV    SI,FCB+1        ;SI POINT TO FCB ARGUMENT
  408. CPLOOP:
  409.     MOV    AL,[BX]            ;GET DIR CHAR
  410.     AND    AL,7FH            ;STRIP PARITY
  411.     CMP    [SI],AL            ;ARE FCB & DIR ENTRY THE SAME?
  412.     JE    DO_MORE
  413.     CMP    BYTE PTR[SI],'?'    ;IF FCB IS A ?, ANY THING GOES
  414.     JE    DO_MORE
  415.     RET                ;RETURN ZERO NOT SET IF NOT SAME
  416. DO_MORE:
  417.     INC    BX
  418.     INC    SI
  419.     DEC    CL
  420.     JNZ    CPLOOP            ;LOOP FOR 11 CHARS.
  421.     RET                ;RET WITH ZERO SET IF SAME
  422.  
  423. ; MOVE FILE NAME TO DATA AREA AND SHOW IT ON CONSOLE
  424. ; ENTRY BX POINTS TO NAME-1 IN DIR_BUF
  425. SHOWIT:
  426.     PUSH    DS            ;MAKE SURE ES IS CORRECT
  427.     POP    ES
  428.     MOV    SI,BX            ;POINT TO FILE NAME
  429.     INC    SI            ;NOW ITS CORRECT
  430.     MOV    DI,OFFSET FILNAM1    ;PUT IT THERE
  431.     MOV    CX,8            ;FIRST MOVE NAME
  432.     CALL    MOVEIT            ;USE ROUTINE TO STRIP HI BIT
  433.     INC    DI            ;JUMP OVER DOT
  434.     MOV    CX,3            ;MOVE TYPE
  435.     CALL    MOVEIT
  436.     MOV    AL,[SI]            ;GET EXTENT
  437.     ADD    AL,'0'            ;MAKE IT ASCII
  438.     MOV    BYTE PTR FILNAM2,AL    ;PUT IN AWAY
  439.     MOV    DX,OFFSET FILNAM    ;GET READY TO PRINT
  440.     CMP    FIXCNT,1        ;IS IT THE FIRST RECOVERY?
  441.     JNE    NOT_FIRST
  442.     MOV    DX,OFFSET RCMSG        ;GIVE PRAMBLE
  443. NOT_FIRST:
  444.     CALL    PRINT
  445.     INC    LINES            ;BUMP LINE COUNT
  446.     CMP    LINES,SLINES
  447.     JB    NO_WAIT
  448.     CALL    WAIT
  449. NO_WAIT:
  450.     RET
  451.  
  452. ; MOVE CX BYTES FROM DS:SI TO ES:DI AND STRIP HI BIT
  453. MOVEIT: MOV     AL,[SI]
  454.     AND    AL,7FH
  455.     MOV    ES:[DI],AL
  456.     INC DI ! INC SI
  457.     LOOP    MOVEIT
  458.     RET
  459.  
  460. ; PRINT MESSAGE POINTED TO BY DX, terminated with either a 0 
  461. PRINT:    MOV    BX,DX
  462. PRN_LP:    MOV    DL,[BX]
  463.     CMP    DL,0 ! JE PRN_RET
  464.     INC    BX
  465.     MOV    CL,2
  466.     PUSH    BX
  467.     INT    224
  468.     POP    BX
  469.     JMPS    PRN_LP
  470. PRN_RET: RET
  471.  
  472. ; SPECIFIED ILLEGAL DISK
  473. ILDISK:
  474.     MOV    DX,OFFSET ILMSG
  475.     CALL    PRINT
  476.     JMP    EXIT
  477.  
  478. ; ERROR ON DISK WRITE
  479. ERRWRT:
  480.     MOV    DX,OFFSET WMSG
  481.     CALL    PRINT
  482.     JMP    EXIT
  483.  
  484. ; DISPLAY WAIT MESSAGE AND WAIT FOR KEY PRESS
  485. WAIT:
  486.     MOV    DX,OFFSET WTMSG0
  487.     CALL    PRINT
  488.     CALL    KEYPRESS
  489.     MOV    DX,OFFSET WTMSG1
  490.     CALL    PRINT
  491.     MOV    LINES,0
  492.     RET
  493.  
  494. ; WAIT FOR A KEY PRESS AND RETURN IT IN AL
  495. KEYPRESS:
  496.     MOV    CL,DCONIN        ;DIRECT CONSOLE IO
  497.     MOV    DL,0FFH            ;REQUEST AN INPUT CHECK
  498.     INT    224
  499.     CMP    AL,0
  500.     JE    KEYPRESS
  501.     RET
  502.  
  503. ; DIRECT BIOS CALL FOR CP/M-86 VERSION 1.1
  504. ;
  505. SELECT_DISK11:
  506.     MOV    AL,9            ;BIOS FUCN 9
  507.     JMPS    BIOS            ;RETURNS DPH ADDR IN ES:BX
  508. SET_TRACK11:
  509.     MOV    AL,10
  510.     JMPS    BIOS
  511. SET_DMASEG11:
  512.     MOV    AL,17
  513.     JMPS    BIOS
  514. SET_DMAOFF11:
  515.     MOV    AL,12
  516.     JMPS    BIOS
  517. SET_SECTOR11:
  518.     MOV    AL,11
  519.     JMPS    BIOS
  520. READ_SECTOR11:
  521.     MOV    AL,13
  522.     JMPS    BIOS
  523. WRITE_SECTOR11:
  524.     MOV    AL,14
  525.     JMPS    BIOS
  526. SECTOR_XLAT11:
  527.     MOV    AL,16
  528.     MOV    DX,XLAT_ADR        ;RETURN XLATED SECTOR IN BX
  529.     JMPS    BIOS
  530. BIOS:
  531.     MOV    BX,OFFSET BPB        ;FILL IN BIOS PARAMETER BLOCK
  532.     MOV    BPB_FUNC,AL
  533.     MOV    BPB_CX,CX
  534.     MOV    BPB_DX,DX
  535.     MOV    CL,DIRBIOS        ;BDOS FUNC 50
  536.     MOV    DX,BX
  537.     INT    224            ;CALL IT
  538.     RET
  539.  
  540.  
  541.  
  542. ; DIRECT BIOS CALLS FOR CP/M-86 VERSION 3.1
  543. ;
  544. SET_SECTOR31:
  545.     mov    sector,cx
  546.     ret
  547.  
  548. SET_TRACK31:
  549.     mov    track,cx
  550.     ret
  551.  
  552. SECTOR_XLAT31:
  553.     mov    bx,cx
  554.     ret
  555.  
  556. SET_DMASEG31:            ;DMA IS SET IN CPMCHK ROUTINE
  557. SET_DMAOFF31:
  558.         ret
  559.  
  560. ;++++++++++++++++++++++++++++++++++++++
  561. SELECT_DISK31:    ;selects a drive
  562. ;------
  563. ; resets login sequence number of drive to 0, to force
  564. ; permanent media to be logged in again on disk reset
  565. ;    Entry:    CL = drive to select
  566. ;        DL = 0 if initial select, else 1
  567.  
  568.     push es ! push ds        ;save context
  569.     push cx                ;save drive
  570.     call getsu            ;set up DS and ES
  571.     pop cx                ;restore drive
  572.     mov ax,BIO_SELDSK        ;do the BIOS SELDSK call
  573.     callf BIOS_ptr            ;call indirect BIOS
  574.     mov LOG_SEQN[bx],0        ;force disk reset: 0 login sequence no.
  575.  
  576.     pop es ! push es        ;get DS into ES
  577.     mov di,offset dpb        ;setup dest of dpb
  578.     mov si,DPB_PTR31[bx]        ;get the info from DPH
  579.     mov cx,DPB_SIZE
  580.     rep movsb            ;copy DPB into local storage
  581.     pop ds ! pop es            ;restore context
  582.     ret
  583.  
  584. READ_SECTOR31:    ;reads a physical sector
  585. ;----
  586.     mov bx,BIO_READ
  587.     jmp biosiopb
  588.  
  589. WRITE_SECTOR31:    ;writes a physical sector
  590. ;-----
  591.     mov bx,BIO_WRITE
  592.  
  593. biosiopb:    ;put the IOPB on the stack, call BIOS
  594.     push ds                ;ds will contain SYSDAT seg
  595.     push es                ;es will contain UDA seg
  596.                     ;push iopb onto stack
  597.     mov ah,mcnt
  598.     mov al,drive
  599.     push ax                ;drive and multi-sector count
  600.     push track            ;track #
  601.     push sector            ;sector # = 0
  602.     push dmaseg            ;track buffer DMA segment
  603.     push dmaoff            ;track buffer DMA offset = 0
  604.  
  605.     call getsu            ;set up DS-SYSDAT and ES-UDA
  606.     mov ax,bx            ;set I/O function into AX
  607.     callf BIOS_ptr            ;call indirect the BIOS
  608.                     ;AL,BL = return status
  609.     add sp,10            ;restore stack
  610.     pop es                ;restore original ES
  611.     pop ds                ;ditto for DS
  612.     ret
  613.  
  614. ;======
  615. GETSU:    
  616. ;======
  617.     CMP     CPM_VERSION,CCPM_31    ;IS IT CCP/M?
  618.     JNE    GETSU10
  619. getsu14:        ;get sysdat and uda addrs for CCP/M ver 1431
  620. ;-----
  621. ;    entry:    DS = local data seg
  622. ;    exit:    DS = SYSDAT seg, ES=UDA seg (for call to XIOS)
  623.  
  624.     mov ax,udaaddr            ;get the saved value
  625.     or ax,ax            ;set flags
  626.     jz getsu14a            ;uninitialized, go do the OS call
  627.       mov es,ax            ;we've been here before, just load regs
  628.       mov ds,sysaddr
  629.       ret
  630. getsu14a:
  631.     mov cl,S_SYSDAT            ;will return system data seg in ES
  632.     int 224 
  633.     mov sysaddr,es            ;save system data segment
  634.  
  635.     mov cl,P_PDADR            ;will return PDA address in BX
  636.     int 224
  637. ;    mov pdaddr,bx            ;and save it
  638.     mov ax,es:P_UDA[bx]        ;grab UDA_seg
  639.     mov udaaddr,ax            ;save for future calls
  640.     push ax                ;save uda_seg
  641.     mov ds,sysaddr
  642.     pop es                ;restore uda_seg
  643.     ret
  644.  
  645. ;----------------
  646. getsu10:    ;get sysdat and uda addrs
  647. ;-----
  648. ;    entry:    DS = local data seg
  649. ;    exit:    DS = SYSDAT seg, ES=UDA seg (for call to BIOS)
  650.  
  651.     mov ax,udaaddr            ;get the saved value
  652.     or ax,ax            ;set flags
  653.     jz getsu10a            ;uninitialized, go do the OS call
  654.       mov es,ax            ;we've been here before, just load regs
  655.       mov ds,sysaddr
  656.       ret
  657. getsu10a:
  658.     mov cl,DRV_DPB            ;will return segment of SYSDAT in ES
  659.     int 224
  660.     mov ax,es:UDA_seg        ;grab UDA_seg
  661.     mov udaaddr,ax            ;save for future calls
  662.     push ax                ;save uda_seg
  663.     mov ax,es
  664.     mov sysaddr,ax            ;save for future calls
  665.     mov ds,ax
  666.     pop es                ;restore uda_seg
  667.     ret
  668.  
  669. ; ***** DATA STORAGE AREA*****************
  670.     DSEG
  671.  
  672.  
  673. HLPMSG    DB    CR,LF,LF
  674.     DB    'USAGE: A>UNERA Dr:FILENAME.TYP',CR,LF,LF
  675.     DB    TAB,'Filename and/or type may be wildcards.',CR,LF
  676.     DB    TAB,'Wildcards may be either ? or *',CR,LF,LF
  677.     DB    TAB,'CAUTION! use the * wildcard with care.',CR,LF
  678.     DB    TAB,'Using *.* will recover ALL erased filenames.',CR,LF,LF
  679.     DB    TAB,'The recoverable file(s) matching the FILNAME.TYP',CR,LF
  680.     DB    TAB,'will be listed, you then have an option to quit.',CR,LF,LF
  681.     DB    TAB,'Be SURE to check recovered files before using to',CR,LF
  682.     DB    TAB,'confirm that they are OK and function properly.',CR,LF
  683.     DB    TAB,'If possible, make a CRC check on recovered files.',CR,LF,LF
  684.     DB    TAB,'HINT: for best results use UNERA immediately after',CR,LF
  685.     DB    TAB,'making an unwanted erasure, else the space may be',CR,LF
  686.     DB    TAB,'re-allocated to another file and recovery is impossible.'
  687.     DB    CR,LF,0
  688.  
  689. HMSG    DB    CR,LF,'UNERA ver 3.1 (2-16-84) for CP/M-86, CP/M-86+ & CCP/M-86   // for HELP',0
  690. WMSG    DB    CR,LF,'ERROR OCCURED DURING DISK WRITE - ABORTED',0
  691. ILMSG    DB    CR,LF,'SPECIFIED AN ILLEGAL DISK DRIVE - ABORTED',0
  692. BMSG    DB    CR,LF,'PLEASE! check recovered files before using them',0
  693. NOFMSG    DB    CR,LF,'NO FILE NAME SPECIFIED - ABORTED',0
  694. NFMSG    DB    CR,LF,'FILE NOT FOUND',0
  695. WVMSG    DB    CR,LF,'Only CP/M-86 ver 1.1 & 3.1 Plus and CCP/M ver 3.1 are Supported',0
  696. MPMSG    DB    CR,LF,'THE MP/M OPERATING SYSTEM IS NOT SUPPORTED',0
  697. RVMSG    DB    CR,LF,'Do you wish to recover the File(s) (Y/N)? ',0
  698. WTMSG0    DB    CR,LF,'  Press any key to continue ',0
  699. WTMSG1    DB    CR,'                             ',CR,0
  700.  
  701.  
  702. RCMSG    DB    CR,LF,LF,'Recovered File(s) will be on '
  703. FILNAM0    DB    'X: User 0'
  704. FILNAM    DB    CR,LF
  705. FILNAM1    DB    'FILENAME.TYP - Extent # '
  706. FILNAM2    DB    'X',0
  707.  
  708.  
  709. TABLE11    DW    OFFSET SELECT_DISK11    ;DIRECT BIOS CALLS FOR CP/M-11
  710.     DW    OFFSET SET_TRACK11
  711.     DW    OFFSET SET_DMASEG11
  712.     DW    OFFSET SET_DMAOFF11    
  713.     DW    OFFSET SET_SECTOR11
  714.     DW    OFFSET READ_SECTOR11    
  715.     DW    OFFSET WRITE_SECTOR11      
  716.     DW    OFFSET SECTOR_XLAT11    
  717.  
  718. TABLE31    DW    OFFSET SELECT_DISK31    ;DIRECT BIOS CALLS FOR CP/M-31
  719.     DW    OFFSET SET_TRACK31
  720.     DW    OFFSET SET_DMASEG31
  721.     DW    OFFSET SET_DMAOFF31    
  722.     DW    OFFSET SET_SECTOR31
  723.     DW    OFFSET READ_SECTOR31    
  724.     DW    OFFSET WRITE_SECTOR31      
  725.     DW    OFFSET SECTOR_XLAT31    
  726.  
  727. CURDR    DB    0            ;CURRENT DRIVE HERE
  728. LINES    DB    2            ;LINES PRINTED ON SCREEN COUNTER
  729. FIX_EM    DB    0            ;FIX FLAG
  730. VIEW_EM DB    0FFH            ;VIEW FLAG
  731.  
  732. BPB    RS    5            ;SPACE FOR BIOS PARAMETER BLOCK
  733.  
  734. CALL_TBL RW    1            ;ADDRESS OF BIOS CALL TABLE GOES HERE
  735. XLAT_ADR RW    1            ;ADDRESS OF TRANSLATION TABLE
  736.  
  737. FIXCNT    RB    1            ;NUMBER OF FIXES
  738. REWRT    RB    1            ;WRITE BACK TO DISK FLAG
  739. MAXDIR    RW    1
  740. MAXSEC    RW    1
  741.  
  742. DIR_PER_SEC    DB    4        ;number directory entrys per sector
  743. SEC_PER_TRK    DW    26
  744.  
  745. CPM_VERSION    DW    0        ;cpm version
  746.  
  747. sysaddr        dw    0        ;save location for sysdat addr
  748. udaaddr        dw    0        ;save location for process uda addr
  749.  
  750. mcnt    db    1            ;multi-sector count
  751. drive    rb    1            ;drive number (A:=1)
  752. track    rw    1            ;track number
  753. sector    rw    1            ;sector number
  754. dmaseg    rw    1            ;DMA segment for data
  755. dmaoff    dw    offset dir_buf        ;DMA offset for data
  756.  
  757. dpb    rb    DPB_SIZE
  758.  
  759.     RW    32            ;32 WORD LOCAL STACK
  760. STACK    RW    1
  761.  
  762. dir_buf    rs    0000            ;4K data buffer [add[100]] at link
  763.  
  764.     END
  765.