home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / ENTERPRS / CPM / UTILS / A / CRLZH20.LBR / CRLZH20.ZY0 / CRLZH20.ZY0
Text File  |  2000-06-30  |  25KB  |  750 lines
  1.     .SALL
  2.     TITLE 'CRrunch LZH v2.0  20 July 1991'
  3. ;************************************************************************
  4. ;*                                    *
  5. ;*                CRunch LZH v2.0                *
  6. ;*                  20 July 1991                *
  7. ;*                           - Roger Warren    *
  8. ;************************************************************************
  9. ;
  10. ;    With the kind permission of Mr. Steven Greenberg, author of 
  11. ;    CRunch, this program was generated from his CRunch v2.4 code
  12. ;    dated 15 Sept 1987.  Accordingly, the following notifications
  13. ;    are in order:
  14. ;
  15. ;     Portions Copyright (c)   S. Greenberg  09/15/87
  16. ;     Portions Copyright (c)   R. Warren     07/20/91
  17. ;    May be reproduced for non-profit use only
  18. ;
  19. ;    You can distribute it AS IS or modify it for your OWN use,
  20. ;    but public release of modified versions (source or object
  21. ;    files) without permission is prohibited, nor can it be sold.
  22.  
  23. ;CRLZH HISTORY:
  24. ; v2.0 Re-released because of new CRLZH algorithm changes.  Version 2.0
  25. ;    of CRLZH is 10% FASTER and compresses further than V1.1.  The output
  26. ;    files must be de-compressed with UCRLZH version 2.0, which replaces
  27. ;    UNCRLZH 1.1.  UNCRLZH 2.0 handles LZH encoded files of both versions
  28. ;    as well as CRUCNCHED and SQUEEZED files.
  29. ;    With the kind permission of Gene Pizzetta, changes made to CRUNCH
  30. ;    thru version 2.8 have been incorporated into this stripped down
  31. ;    driver taken from Steve Greenberg's version 2.4.  This program will
  32. ;    NOW handle date stamps ala ZSDOS.
  33. ;
  34. ; v1.1 Official first release.  No functional changes from Beta version.
  35. ;     Merely stepped version for differentiation.
  36. ;
  37. ; v1.0 Beta test version
  38. ; 
  39.  
  40. VERS    EQU    20
  41. SUBVERS    EQU    ' '        ; modification level
  42.  
  43.     .Z80
  44.  
  45.     CSEG
  46.  
  47. NO    EQU    0
  48. YES    EQU    NOT NO
  49. N    EQU    NO
  50. Y    EQU    YES
  51. CRUNCH    EQU    YES        ; Yes for CRLZH, No for UNCRLZH (for common)
  52. ;ZSYS    EQU    NO        ; Yes if exclusively for Z-System
  53. .ACCEPT    'ZCPR3-Only Version [Y/N] ? ',ZSYS
  54.  
  55. ;=======================================================================
  56.  
  57.   IF ZSYS
  58. MEMPAG    EQU    1F00H        ; <== set! [see comment near end of program]
  59.   ELSE    ; ZSYS
  60. MEMPAG    EQU    2100H        ; <== set! [see comment near end of program]
  61.   ENDIF    ; ZSYS
  62.  
  63. ;=======================================================================
  64.  
  65. REV    EQU    (VERS/10*16)+(VERS MOD 10) ; Program revision level in BCD
  66. SIGREV    EQU    20H        ; "Significant" revision level (compatibility)
  67.  
  68. NOPRED    EQU    0FFFFH        ; "no predecessor"
  69. SCRUPT1    EQU    03H        ; Screen update speeds
  70. SCRUPT2    EQU    0FH
  71.  
  72. ; --- Ascii equates ---
  73.  
  74. CTRLC    EQU    03H        ; ^c
  75. BELL    EQU    07H        ; Beep
  76. BS    EQU    08H        ; Backspace
  77. LF    EQU    0AH        ; Linefeed
  78. CR    EQU    0DH        ; Carriage return
  79.  
  80. ; --- CP/M address equates ---
  81.  
  82. DFCB    EQU    5CH        ; Default FCB #1
  83. DFCB2    EQU    6CH        ; Default FCG #2
  84. DDMA    EQU    80H        ; Default DMA address
  85. BDOS    EQU    0005H        ; BDOS entry point
  86.  
  87. ; --- BDOS function equates ---
  88.  
  89. CONIN    EQU    1        ; Input a character from the console
  90. CONOUT    EQU    2        ; Output single char to console
  91. PRTSTR    EQU    9        ; Print string to console
  92. CONST    EQU    11        ; Get console status
  93. GETVER    EQU    12        ; Get CP/M version #
  94. SELDSK    EQU    14        ; Select disk
  95. OPEN    EQU    15        ; Open file
  96. CLOSE    EQU    16        ; Close file
  97. SFIRST    EQU    17        ; Search for first file
  98. SNEXT    EQU    18        ; Search for next file
  99. ERASE    EQU    19        ; Erase file
  100. READ    EQU    20        ; Read file (sequential)
  101. WRITE    EQU    21        ; Write file (sequential)
  102. MAKE    EQU    22        ; Make file
  103. GETDSK    EQU    25        ; Get currently logged drive
  104. SETDMA    EQU    26        ; Set DMA address
  105. SETATR    EQU    30        ; Set file attributes
  106. GSUSER    EQU    32        ; Get/set user code
  107. RSTDRV    EQU    37        ; Reset disk drive
  108. SETMS    EQU    44        ; Set multi-sector count (CP/M+ only)
  109. GETDMA    equ    47        ; get current DMA address
  110. EXDOSV    equ    48        ; extended BDOS version
  111. GETFSTP    equ    102        ; get file stamp
  112. SETFSTP    equ    103        ; set file stamp
  113.  
  114. ;.......................................................................
  115.  
  116.   IF NOT ZSYS
  117.     EXTRN    PARSEU
  118.   ENDIF    ; NOT ZSYS
  119.  
  120.     EXTRN    CRLZH        ; CRLZH module
  121.     PUBLIC    GLZHEN        ; CRLZH 'gets' thru this routine
  122.     PUBLIC     PLZHEN        ; CRLZH 'puts' thru this routine
  123.  
  124. ;.......................................................................
  125.  
  126. START:    JP    STRT        ; <--- entry
  127.     DB    'Z3ENV',01h    ; ZCPR3 environment descriptor
  128. Z3ED:    DW    00h
  129.  
  130. ;-----------------------------------------------------------------------
  131.  
  132.     DW    0        ; filler
  133.     DB    'CRLZH'        ; for ZCNFG
  134.     DB    VERS/10+'0',VERS MOD 10+'0'
  135.     DB    ' '        ; Filler
  136. ARCHIV:    DB    0        ; Archive bit mode flag
  137. QUIFL:    DB    0        ; Quiet mode flag
  138. NPROFL:    DB    0        ; No prompt before overwrite flag
  139. TRBOFL:    DB    0        ; Defeat multi-sector i/o flag
  140. CNFRFL:    DB    0        ; Confirm every file flag
  141. WRMFLG:    DB    0        ; Warm boot flag
  142. BIGFLG:    DB    0        ; Bigger file prompt flag
  143. MAXUSR:    DB    31        ; Maximum user # allowed by program
  144. MAXDRV:    DB    16        ; Maximum drive allowed by program
  145. SYSFL:    DB    0        ; System file inclusion flag
  146. TYPFL:    DB    ' '        ; Default filetype (UNCR only)
  147.  
  148. ;.......................................................................
  149. ;
  150. ; File type exclusion list. Must end with zero.
  151. ;           |<-1->|<-2->|<-3->|<-4->|<-5->|
  152. EXTBL:    DB    'ARC','ARK','LBR','FOR','ARK'
  153. ;           |<-6->|<-7->|<-8->|<-9->|<10->|
  154.     DB    'ARK','ARK','ARK','ARK','ARK'
  155.     DB    0        ; Must leave this terminating zero.
  156.  
  157. ;=*=-=*=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=
  158.  
  159. CPYRT:    DB    'CRLZH '
  160.   IF ZSYS
  161.     DB    'Z-'
  162.   ENDIF    ; ZSYS
  163.     DB    'Version ',VERS/10+'0','.',VERS MOD 10+'0',SUBVERS
  164.     DB    ' Copyright (c) 1987 by S. Greenberg',CR,LF
  165.         DB    '      Portions  Copyright (c) 1991 by R. Warren',CR,LF
  166.     DB    ' May be used/reproduced for non-profit use only',CR,LF,LF,'$'
  167.  
  168. ;=*=-=*=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=
  169.  
  170. STRT:
  171.   IF ZSYS
  172.     LD    HL,(Z3ED)    ; check for ZCPR3
  173.     LD    A,H
  174.     OR    L
  175.     JP    NZ,Z80
  176.   ELSE    ; ZSYS
  177.     SUB    A        ; Z-80 test [RAF]
  178.     JP    PO,Z80        ;
  179.   ENDIF    ; ZSYS
  180.     LD    DE,WRNGUP    ; "Program requires Z-80 Processor"
  181.     JP    MESS80        ; Special no frills exit w/ message
  182.  
  183. Z80:    LD    (OLDSTK),SP    ; Save os's stack
  184.     LD    SP,TOPSTK    ; Set local stack
  185.     CALL    STRTUP        ; Does a lot of stuff
  186.  
  187. ;.......................................................................
  188. ;
  189. ;    *****    Re-enter here for each matching file *****
  190. ;
  191. ; General wildcard operation:  When the program is first invoked, all
  192. ; matching filenames are put end to end in FNBUFF, 12 bytes each, in
  193. ; alphabetical order.  Since a filename is only 11 characters long the
  194. ; spare byte, which precedes each filename, is used as a "tag/flag".  By
  195. ; the time file processing starts (now), a number of routines have al-
  196. ; ready run (parts of the STRTUP routine).  These routines set the tag-
  197. ; flag which indicates to us now in what manner the file should be pro-
  198. ; cessed: "00" = "skip it", "01" = process it", "02" = "perform a direct
  199. ; copy (if possible)", "FF" = "no more files".
  200.  
  201. NXTFIL:    LD    SP,TOPSTK    ; Reset SP
  202.     XOR    A        ; clear embedded date stamp flag
  203.     LD    (DATFLG),A
  204.     LD    DE,INFCB    ; Input file's fcb
  205.     CALL    CLRFCB        ; Init it to blanks and zeroes
  206.     INC    DE        ; Leave "DE" pointing at "INFCB+1" for below
  207.     LD    HL,(BUFPTR)    ; Pntr to name of next file from expansion bfr
  208. NXTSEL:    LD    A,(HL)
  209.     OR    A        ; If zero, the file is "unselected"
  210.     JR    NZ,ISSEL    ; Br if it is selected
  211.     LD    BC,12        ; Else just quietly skip to the next file
  212.     ADD    HL,BC
  213.     LD    (BUFPTR),HL
  214.     JR    NXTSEL
  215.  
  216. ;...............................
  217. ;
  218. ; The file is "selected"; prepare to process it
  219.  
  220. ISSEL:    CP    0FFH        ; (FF means done)
  221.     JP    Z,RETCCP    ; Br if that is the case
  222.     PUSH    AF        ; Save stat (to see if file is "excluded" blw)
  223.     INC    HL        ; Skip to 1st filename char
  224.     LD    BC,11        ; Filename character count
  225.     LDIR            ; Put next file name into input fcb
  226.     LD    (BUFPTR),HL    ; Save new pointer for next file
  227.     CALL    INTRAM        ; Initialize all ram
  228.     LD    A,01H        ; This loc req's diff init for crunch vs uncr
  229.     LD    (CSAVE),A    ; Goes there
  230.     POP    AF        ; Get file's status byte back again
  231.  
  232.     CP    02H        ; 02 if file matched the "exclusion" list
  233.     JR    NZ,COPNIN    ; If not, definitely attempt to compress it
  234.     LD    A,(WLDFLG)    ; If so, see if prgm was invoked w/ wildcards
  235.     OR    A
  236.     JR    Z,COPNIN    ; If not, go attempt compression
  237.     LD    A,(DIFDU)    ; Else see if a direct copy is in order
  238.     OR    A        ; (flag set if data flow is to distinct DU:'s)
  239.     JP    Z,NXTFIL    ; If not, forget the whole thing
  240.  
  241. ;.......................................................................
  242. ;
  243. ; Perform a direct straight copy of the file
  244.  
  245.     LD    A,(QUIFM)
  246.     OR    A
  247.     LD    DE,DASHES    ; "-----" for visual separation
  248.     CALL    Z,MESAG2
  249.     JP    COPY9        ; Performs the copy
  250.  
  251. ;.......................................................................
  252. ;
  253. ; Normal Processing;  Prepare to compress the input file.  First, open
  254. ; the input file.  A failure here is unusual, since the file existed at
  255. ; the time the filename expansion took place.  There are "normal" series
  256. ; of events which could lead up to this, however.
  257.  
  258. COPNIN:    LD    A,(QUIFM)
  259.     OR    A
  260.     LD    DE,DASHES    ; "-----" for visual separation
  261.     CALL    Z,MESAG2
  262.     CALL    OPNIN        ; Attempt to open the next input file "INFCB"
  263.     JR    NC,OPOK        ; Br if ok
  264.     LD    DE,ERR1        ; "input file not found"
  265.     JP    SKIP1        ; Skip to next file
  266.  
  267. OPOK:    CALL    GETCHR        ; Start input machine
  268.     JR    NC,NOTMT    ; If carry is set on 1st byte, file is empty
  269.     LD    DE,ERR0        ; "input file empty"
  270.     JP    SKP991
  271. ; If file starts with 76FFh, it's already squeezed.  If it starts with 76FEh,
  272. ; it's already crunched (LZW, by us).  If it starts with 76FDh, it's already
  273. ; crunched (LZH).
  274. NOTMT:    CP    76H        ; does it start with 76h?
  275.     JR    NZ,CBL        ; (no, it's not compressed..is it?)
  276.     PUSH    AF        ; 1st byte was "76H", take advance peek at 2nd
  277.     EXX            ; Carefully check next byte, w/o norm call
  278.     LD    A,(HL)
  279.     EXX
  280.     INC    A        ; Well?  FFh?
  281.     JR    Z,ALRDSQ    ; Br if already squeezed
  282.     INC    A        ; FEh?
  283.     JR    Z,ALRDCR    ; Br if already crunched
  284.     INC    A        ; FDh?
  285.     JR    Z,ALRDLZ    ; Br if already crunched (LZH)
  286.     POP    AF
  287.  
  288. NOTSQ:    JR    CBL        ; Continue below
  289.  
  290. ;.......................................................................
  291.  
  292. ALRDCR:    POP    AF
  293.     LD    DE,MSGCR    ; "Already crunched"
  294.     JP    SKP991
  295.  
  296. ALRDSQ:    POP    AF
  297.     LD    DE,MSGSQ    ; "Already squeezed"
  298.     JP    SKP991
  299.  
  300. ALRDLZ:    POP    AF
  301.     LD    DE,MSGLZH    ; "Already LZH encoded"
  302.     JP    SKP991
  303.  
  304. ;.......................................................................
  305. ;
  306. ; So far the input file is open. The output file is not.
  307.  
  308. CBL:    LD    A,' '        ; For aesthetic alignment purposes
  309.     CALL    TYPE
  310.     LD    HL,INFCB    ; Print input filename to console
  311.     CALL    PRNFIL
  312.     LD    DE,OUTFCB    ; Now for the output fcb
  313.     CALL    CLRFCB        ; Clear it
  314.     INC    DE        ; Leave "DE" pointing at filename area
  315.     CALL    CPYNAM        ; Copies filename from input fcb to output fcb
  316.  
  317. ; The following routine allows files with a "Y" as the second character
  318. ; of their filetype to have a compressed filetype of "xYY".  This code
  319. ; was released to the public domain as a patch for CRUNCH24.  The
  320. ; author is unknown.
  321.  
  322.     LD    HL,OUTFCB+9    ; point to first filetype character
  323.     LD    A,' '        ; see if filetype is blank
  324.     CP    (HL)
  325.     LD    A,'Y'        ; we'll need a Y later
  326.     JR    Z,ZZZ        ; (yes, force a filetype of "YYY"
  327.     INC    HL        ; point to second filetype character
  328.     CP    (HL)        ; is middle character a "Y"
  329.     JR    NZ,XZY        ; (no, so make type "1Y3"
  330.     INC    HL        ; point to last filetype character
  331.     CP    (HL)        ; is last character a "Y"
  332.     JR    NZ,XZZ        ; (no, so make type "1YY")
  333.     DEC    HL        ; point back to first character
  334.     DEC    HL
  335.     CP    (HL)        ; is first character a "Y"?
  336.     JR    NZ,ZZZ        ; (no, "YYY" is okay)
  337.     LD    DE,ERR7        ; it's "YYY", so we can't do it
  338.     JP    SKP991        ; ..but make a straight copy anyway
  339. ZZZ:    LD    (HL),A        ; make first character "Y"
  340.     INC    HL
  341.     LD    (HL),A        ; make second character "Y"
  342.     INC    HL
  343. XZY:
  344. XZZ:    LD    (HL),A        ; make pointed-to character "Y"
  345.  
  346. ;.......................................................................
  347. ;
  348. ; Now open the output file. "OPNOUT" will check for duplicate filenames,
  349. ; and prompt if indicated.  If carry is set on return, the file was not
  350. ; opened.  DE points to an appropriate error message, if any.  The rou-
  351. ; tine also types an arrow to the screen, followed by a "PRNFIL" call to
  352. ; type the DU: and filename to the screen.
  353.  
  354.     CALL    OPNOUT        ; Do all that
  355.     JP    C,SKIP2A    ; Skips to next file if so deemed by "OPNOUT"
  356.  
  357. ;.......................................................................
  358. ;
  359. ; Now both files are open. Eventually either both will be closed, or the
  360. ; input closed and the output deleted.
  361.  
  362.     LD    A,76H        ; Output the "76FE" header
  363.     CALL    OUTB        ; Each call to "OUTB" outputs one byte
  364.     LD    A,0FDH
  365.     CALL    OUTB
  366.     LD    HL,INFCB    ; Pointer to original (input) file's name
  367.     CALL    OUTFIL        ; Embed it into the output file at bytes 2+
  368.     CALL    OUTDAT        ; Include date stamp, if available
  369.     LD    HL,STAMP    ; Pointer to possible additional "stamp" chars
  370.  
  371. IDOULP:    LD    A,(HL)        ; Possibly get a stamp char
  372.     INC    HL        ; Incr bfr pntr
  373.     CALL    OUTB        ; (output at least one zero no matter what)
  374.     OR    A        ; End of stamp bfr?
  375.     JR    NZ,IDOULP    ; Loop till so
  376.  
  377. ;.......................................................................
  378.  
  379.     LD    A,(QUIFM)    ; Print "heading" if in verbose mode
  380.     OR    A
  381.     JR    NZ,QUIET1
  382.     LD    DE,HEADNG    ; (the "in / out  ca  cr" stuff)
  383.     CALL    MESAGE
  384.  
  385. QUIET1:
  386.     LD    A,0FFH        ; Flag as 'old' to COMMON.LIB
  387.     LD    (OLDFLG),A
  388.  
  389. ;=======================================================================
  390. ;
  391. ;            *** Main encoding loop ***
  392. ;
  393. ; --- End-of file processing ---
  394.  
  395.     EXX            ; Go back to the start of file (already
  396.                 ; read some)
  397.     LD    HL,IBUF        ; Point 
  398.     EXX
  399.     LD    HL,SECNT    ; Bugger up sector counter since we just
  400.     INC    (HL)        ; - reset the input pointer
  401.     LD    HL,(INCTR)    ; Decr INCTR for same reason
  402.     DEC    HL
  403.     LD    (INCTR),HL
  404.     LD    A,'0'        ; Reset ASCII display to '0'
  405.     LD    (PROGBF+5),A
  406.  
  407.     LD    HL,TABLE    ; Point to large data space
  408.     LD    A,0        ; ZERO (Actually xx00xxxx) for
  409.                 ; Normal checksum flag to CRLZH
  410.  
  411.     CALL    CRLZH        
  412.     JP    C,INSUFF    ; Only error can be insufficient memory
  413.  
  414. ONBND:    LD    A,(CHKSUM+0)    ; Now output the checksum
  415.     CALL    OUTB        ; (lo byte)
  416.     LD    A,(CHKSUM+1)
  417.     CALL    OUTB        ; (high byte). This completes all output.
  418.  
  419.     CALL    DONE        ; Writes out partial output bfr, thru cur loc
  420.     CALL    CLSOUT        ; Close the output file
  421.     CALL    CLSIN        ; Close the input file (prevents inadvertent
  422.                 ; Accumulation of open files).
  423.  
  424. ;.......................................................................
  425. ;
  426. ; Now we are done with the file.  The size of the resulting file will be
  427. ; compared with the original.  If the resulting file is larger, the file
  428. ; will be erased and the original will be copied in uncompressed format
  429. ; instead.  This will only be done if the source and destination DU:'s
  430. ; are different (obviously a direct copy to the same drive and user is
  431. ; nonsensical).  When this is the case, the user will be given the op-
  432. ; tion of saving the "crunched" file - if he doesn't, then it will be
  433. ; erased.
  434.  
  435.     LD    A,(BIGFLG)    ; Get size question override flag
  436.     AND    A        ; Check if non-0, clear carry at same time
  437.     JP    NZ,NEXT        ; Skip if bigger
  438.     LD    DE,(INCTR)    ; Size of input file
  439.     LD    HL,(OUTCTR)    ; Size of resulting file
  440.     SBC    HL,DE        ; Compare
  441.     JP    C,NEXT        ; (normally the case)
  442.  
  443.     LD    A,(DIFDU)    ; Dest du: differ from origin?
  444.     OR    A
  445.     JP    Z,ASKHIM    ; If not, give option of saving larger file
  446.  
  447.     LD    DE,MSG998    ; "not smaller..."
  448.     CALL    MESAG2
  449.     CALL    ERAOUT        ; Erase the output file
  450.  
  451. COPY9:    CALL    COPY        ; Perform a straight copy
  452.     JP    C,NXTFIL    ; If the copy did not actually take place
  453.     JR    NEXT        ; If it did, count it
  454.  
  455. ;.......................................................................
  456.  
  457. SKP991:    CALL    MESAG2        ; Type predefined message
  458.     CALL    CRLF        ; Pretty up line
  459.     LD    A,(DIFDU)    ; Dest du: differ from origin?
  460.     OR    A
  461.     JP    Z,NXTFIL
  462.     JR    COPY9
  463.  
  464. ;.......................................................................
  465.  
  466. ASKHIM:    LD    DE,QUES1    ; Result file not smaller than original
  467.     CALL    MESAGE        ; Ask the guy if he wants it anyway
  468.     CALL    RSPNSE        ; Get his response
  469.     PUSH    AF        ; Nec?
  470.     CALL    CRLF
  471.     POP    AF
  472.     JR    NZ,SKIP4A    ; "skip4a" erases output file, goes to next
  473.  
  474. ;.......................................................................
  475.  
  476. NEXT:    LD    HL,(NFP)    ; Increment # of files processed
  477.     INC    HL
  478.     LD    (NFP),HL
  479.     CALL    ARCIT        ; Flag input file as archived
  480.     CALL    DATSTP        ; Move date stamp
  481.     JP    NXTFIL        ; Repeat if still more files
  482.  
  483. ;.......................................................................
  484.  
  485. SKIP1:    CALL    MESAGE        ; Entry if neither input nor output files
  486.                 ;   have been opened yet
  487. SKIP1A:    JP    NXTFIL        ; (Entry here if no error text desired)
  488.  
  489. ;...............................
  490.  
  491. SKIP2A:    CALL    CLSIN        ; (Entry here for no message)
  492.     JP    NXTFIL
  493.  
  494. ;...............................
  495.  
  496. SKIP4A:    CALL    CLSOUT        ; (Entry here for no message)
  497.     LD    DE,OUTFCB    ; Close, then erase output file
  498.     LD    C,ERASE
  499.     CALL    BDOSAV
  500.     CALL    CLSIN        ; Close input file as well
  501.     JP    NXTFIL
  502.  
  503. ;=======================================================================
  504. ;
  505. ; Subroutine gets a character from the input stream and adds its value
  506. ; to running checksum.
  507.  
  508. GETC:    CALL    GETCHR        ; Get a character into A
  509.     RET    C        ; Don't add in the garbage char recv'd on eof
  510.     CALL    CKSUM        ; Add it in
  511.     AND    A        ; Guarantee clear carry when no eof
  512.     RET            ; That's it
  513.  
  514. ;-----------------------------------------------------------------------
  515. ;
  516. ; Like "PRNFIL", but send chars to the output stream instead of typing.
  517. ; This routine WILL explicitly output blanks in the filename extension.
  518.  
  519. OUTFIL:    LD    BC,0C20H    ; B = loop counter, c = blank character
  520.  
  521. CHARL2:    INC    HL        ; Pre-incr pointer
  522.     LD    A,(HL)        ; Get a char
  523.     CP    C        ; Blank?
  524.     JR    Z,SKPTY2    ; Suppress them (but not in the .ext)
  525.  
  526. TYPEI2:    CALL    OUTB        ; Send char to the output stream
  527.  
  528. SKPTY2:    DEC    B        ; Loop counter
  529.     RET    Z        ; Return when done
  530.  
  531.     LD    A,B        ; Check loop counter
  532.     CP    4        ; At this point, type a "."
  533.     JR    NZ,CHARL2
  534.     LD    A,"."        ; This is also a convenient char to set "C" to
  535.     LD    C,A        ; A "." cannot be found in an fcb filename
  536.     JR    TYPEI2        ; Type the ".".  do no incr hl.
  537.  
  538. ;.......................................................................
  539. ;
  540. ; Like OUTFIL, but outputs date stamp to the output stream
  541.  
  542. OUTDAT:    LD    A,(DATFLG)    ; do we have a date stamp?
  543.     OR    A
  544.     RET    Z        ; (no, do nothing)
  545.     LD    A,1        ; a 1 byte is the date stamp lead-in
  546.     CALL    OUTB
  547.     LD    HL,DATBUF    ; point to date stamp buffer
  548.     LD    B,15        ; 15 bytes
  549. OUTDT2:    LD    A,(HL)        ; get date byte
  550.     OR    A        ; zero?
  551.     JR    NZ,OUTDT3    ; (no)
  552.     CPL            ; yes, make it FFh
  553. OUTDT3:    CALL    OUTB
  554.     INC    HL        ; increment pointer
  555.     DJNZ    OUTDT2        ; and loop
  556.     RET
  557.  
  558. ;=======================================================================
  559. ;
  560. ; "Stamp" processing.
  561.  
  562. PRCSTM:    PUSH    DE        ; Called w/ "HL" pointing to text of "stamp"
  563.     LD    DE,STAMP    ; Buffer for holding the date stamp or text
  564.     LD    B,7FH        ; Put a limit on its length
  565.  
  566. STMPLP:    LD    A,(HL)        ; Get a character
  567.     LD    (DE),A        ; Put it in the buffer
  568.     INC    DE
  569.     OR    A        ; Zero denotes end of cmnd tail, ending stamp
  570.     JR    Z,PRCDN1
  571.     INC    HL
  572.     SUB    ']'        ; The "proper" way the stamp should end
  573.     JR    Z,PRCDN2
  574.     DJNZ    STMPLP        ; Get more chars
  575.  
  576. ERR8:    LD    DE,PRSER8    ; Stamp overflow, probably impossible
  577.     JP    FATALU
  578.  
  579. PRCDN1:    POP    DE        ; Come here if null terminated the stamp
  580.     RET            ; Return with the null in "A" & z set
  581.  
  582. PRCDN2:    LD    (DE),A        ; Make sure a null (a has one now) gets here
  583.  
  584. NBLP:    LD    A,(HL)        ; Advance to first non-blank after stamp
  585.     CP    ' '
  586.     JR    NZ,NBC        ; Branch if we have one
  587.     INC    HL        ; Else advance
  588.     DJNZ    NBLP        ; And continue
  589.     JR    ERR8        ; Overflow error
  590.  
  591. NBC:    POP    DE        ; Rtn with "HL" pointing to 1st non-blank char
  592.     OR    A        ; (Return z stat if that character is null)
  593.     RET
  594.  
  595. ;.......................................................................
  596. ;
  597. ; Flag files matching the "exclusion list"
  598.  
  599. EXCLUD:    LD    BC,12        ; Leave 12 in bc for incrementing ix
  600.     LD    IX,FNBUFF    ; Points to beg of filenames
  601.  
  602. OUTLP:    LD    A,(IX+0)    ; Get flag byte for this entry
  603.     CP    0FFH        ; Final [non-] entry?
  604.     RET    Z        ; (return if so)
  605.     OR    A        ; Is it an untagged filename?
  606.     JR    Z,NXTFN        ; If so, leave it that way & move to next
  607.     LD    HL,EXTBL-3    ; Beginning of "exclusion" list
  608.  
  609. INRLP0:    INC    HL
  610.  
  611. INRLP1:    INC    HL        ; (If HL already incremnted once)
  612.  
  613. INRLP2:    INC    HL        ; ( "          "    twice)
  614.     LD    A,(HL)        ; Get a char from list
  615.     OR    A        ; End of list?
  616.     JR    Z,NXTFN        ; If so, move on to next filename in "fnbuff"
  617.     CP    '?'        ; Wildcard?
  618.     JR    Z,AUTOM1    ; Yes, automatically matches
  619.     CP    (IX+9)        ; Else see if it matches first ft char
  620.     JR    NZ,INRLP0    ; No match, forget it and move to next filename
  621.  
  622. AUTOM1:    INC    HL
  623.     LD    A,(HL)        ; Repeat twice more for other 2 chars
  624.     CP    '?'
  625.     JR    Z,AUTOM2
  626.     CP    (IX+10)
  627.     JR    NZ,INRLP1
  628.  
  629. AUTOM2:    INC    HL
  630.     LD    A,(HL)        ; As above
  631.     CP    '?'
  632.     JR    Z,AUTOM3
  633.     CP    (IX+11)
  634.     JR    NZ,INRLP2
  635.  
  636. AUTOM3:    LD    A,02H        ; File type matches; flag file as "excluded"
  637.     LD    (IX+0),A
  638.  
  639. NXTFN:    ADD    IX,BC        ; Move to next filename in "fnbuff"
  640.     JR    OUTLP
  641.  
  642. ;=======================================================================
  643. ;
  644. ; All ASCII centralized here as a service to disassembly hobbyists.
  645.  
  646. INTRO:    DB    'LZH Cruncher  Version ',VERS/10+'0','.',VERS MOD 10+'0'
  647.     DB    SUBVERS,CR,LF,'$'
  648. ERR7:    DB    ' [ Can''t compress .YYY files ]$'
  649. MSGCR:    DB    ' [ Already crunched ] $'
  650. MSGSQ:    DB    ' [ Already squeezed ] $'
  651. MSGLZH:    DB    ' [ Already LZH encoded ] $'
  652. MSG998:    DB    ' [ Result not smaller ] $'
  653. QUES1:    DB    'Result not smaller--Save anyway (Y/[N])? ',BELL,'$'
  654. USAGE:    DB    'Usage:',CR,LF
  655.     DB    '   $'
  656. PRGNAM:    DB    'CRLZH  '    ; must end in space, if < 8 characters
  657. COMNAM:    DB    '        '
  658. SYNTX1:    DB    ' {d$'
  659. SYNTX2:    DB    ':}afn {d$'
  660. USAGE1:    DB    ':} {[text]} {/options}',CR,LF
  661.     DB    'Second parameter is destination.',CR,LF
  662.     DB    '"[text]" is any text enclosed in brackets.',CR,LF
  663.     DB    'Options following slash:',CR,LF
  664.     DB    '   Q   Quiet mode o$'
  665. USAGE2:    DB    CR,LF
  666.     DB    '   I   Inspect (Tag) mode o$'
  667. USAGE3:    DB    CR,LF
  668.     DB    '   T   Same as I',CR,LF
  669.     DB    '   E   $'
  670. USAGE4:    DB    'Erase existing files',CR,LF
  671.     DB    '   A   Archive mode o$'
  672. USAGE5:    DB    CR,LF
  673.     DB    '   S   $'
  674. USAGE6:    DB    'clude System files$'
  675.  
  676. ;=======================================================================
  677.  
  678. ; ** Include file begins here **
  679.  
  680.     INCLUDE    COMMONLZ.LIB
  681.  
  682. ; ** Include file ends here **
  683.  
  684. ;=======================================================================
  685. ; File I/O For LZH
  686. ;
  687.  
  688. PLZHEN    EQU    OUTB
  689. GLZHEN    EQU    GETC
  690.  
  691. ;=======================================================================
  692.  
  693. ; Additional misc ram locs which need not be initialized, or are init-
  694. ; ialized by the routines which use them.
  695.  
  696. CSAVE:    DS    1
  697.  
  698. ;...............................
  699.  
  700. SAFETY:    DS    16        ; Safety region beyond stack limit check
  701. ENDPRG    EQU    $        ; (approx bottom of stack)
  702.  
  703. ;_______________________________________________________________________
  704.  
  705. STKSZ    EQU    8        ; Minimum stack size (pages)
  706. IBUFSZ    EQU    8        ; Input buffer size (pages)
  707.  
  708. ;=======================================================================
  709. ;
  710. ; ===> All tables will begin at "MEMPAG", defined at the top of the
  711. ;      program.  This should be set to a page aligned value i.e., ad-
  712. ;      dress that ends in "00")  which is ABOVE the end all program and
  713. ;      data segments.  You may have to do one test link to determine the
  714. ;      proper value (changing "MEMPAG" will not change the length of the
  715. ;      segments on the subsequent link).
  716. ;
  717. ; "MEMPAG" is defined at the beginning of this program to remind you to
  718. ; set it properly.  If you set it higher than necessary, there will be
  719. ; no negative effect other than an increase in the TPA required to run
  720. ; the program.    If you set it too low, you will be in big trouble.  The
  721. ; value must be set manually because most linkers cannot resolve an
  722. ; "and", "shift" or "hi" byte extraction at link time to determine the
  723. ; page boundary.
  724. ;
  725. ;=======================================================================
  726.  
  727. ; "MAXFLS" is  buffer size (in files) for wildcard expansions.    Room for
  728. ; this many files will be allocated.
  729.  
  730. MAXFLS    EQU    256
  731.  
  732. TOPSTK    EQU    MEMPAG+(STKSZ*256) ; Top of stack
  733. IBUF    EQU    TOPSTK           ; (= beginning of input buffer)
  734. EIBUF    EQU    IBUF+(IBUFSZ*256)  ; End of input buffer
  735. TABLE    EQU    EIBUF           ; (= beginning of table)
  736. EOTBL    EQU    TABLE+(5*20*256)   ; End of table
  737. FNBUFF    EQU    EOTBL           ; (= beginning of wildcard expansion buffer)
  738. ENDFNB    EQU    FNBUFF+(12*MAXFLS) ; End of expansion buffer
  739.  
  740. STAMP    EQU    ENDFNB           ; File "stamp" buffer ** size temp ***
  741. ENDALL    EQU    STAMP+100H       ; End of everything, except output buffer
  742. OBUF    EQU    ENDALL           ; Beginning of dynamically sized output buffer
  743.  
  744. ;-----------------------------------------------------------------------
  745.  
  746. ENDHI    EQU    HIGH ENDALL    ;
  747. OBUFHI    EQU    HIGH OBUF    ; Output buffer addrress, high byte likewise
  748.  
  749.     END
  750.