home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / ENTERPRS / CPM / UTILS / A / BSHOW32.LZH / BISHOW32.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  49KB  |  1,931 lines
  1. ;
  2. ;    title    'BISHOW v3.02 - buffered bidirectional file scroll utility'
  3. ;
  4. ; Ver 3.02, 3 Nov 85, Rod Clark, Seattle WA
  5. ;       - added Wordstar cursor pad (^C now = page down).
  6. ;    - ESC exits, clears screen. Q exits, leaves screen.
  7. ;    - Wrong keys are ignored.  H = brief help. ? = help.
  8. ;    - SHORT  +  SQUEEZE  +  LIBRARY = .COM file < 2k.
  9. ;    - SHORT, no SQUEEZE, no LIBRARY = .COM file < 1k.
  10. ;    - SHORT disables setting each margin interactively
  11. ;      (the command line still sets the right margin and
  12. ;      the page length), but it does let you scroll back
  13. ;      and forth horizontally by tab stops within a file.
  14. ;      The SHORT version gives two sets of cursor keys
  15. ;      (Wordstar and CR/SP etc), but no help display.
  16. ;    - BISHOW (no filename) tells whether it works on .LBR
  17. ;      or squeezed files, or both, or just on plain files.
  18. ;    - and fixed jumbled multiple-line .LBR directory.
  19. ;    
  20. ; Ver 3.01, 15 Jan 84, Frans van Duinen, Toronto, Ont
  21. ;    - made unsqueeze message optional
  22. ;    - added library capability
  23. ;    - fixed bug in conditional assembly of CLRSCR
  24. ;
  25. ; Ver 2.09, 7 Jan 84, Frans van Duinen, Toronto, Ont
  26. ;    - Modified USQ routines for higher speed (+10%) and
  27. ;         less memory usage.
  28. ;    - made USQ code optional through conditional assembly
  29. ;    - fixed a bug introduced with 2.08 and SHORT=TRUE 
  30. ;      (resulted from ASM's inability to nest IF/ENDIF) 
  31. ;    - fixed a bug  that reset FCBEX after open, whenever
  32. ;      sector 0 was read, (this resulted in BDOS assuming that
  33. ;      the current extent, whose allocation group nos were still
  34. ;      in the FCB, was the correct one. 
  35. ;    - Changed exit to clear screen only on Q or ^C exit,
  36. ;      to leave any messages visible
  37. ;    - Made wait after clear screen a cond assembly option
  38. ;
  39. ; Ver 2.08, 2 Jan 84, Frans van Duinen, Toronto, Ont
  40. ;    - added squeezed file capability
  41. ;    - added sidewise scrolling on ^I, ^L, steps of 8
  42. ;    - Osborne support for cursor keys, clr scr & scr size
  43. ;    - Changed FILBAK rtn to recognize top of file
  44. ;    - Set up flag to avoid unnecessary re-reading of
  45. ;      top of file 
  46. ;
  47. ;    The unsqueeze code was lifted from the USQ base code
  48. ;    by Dave Rand (Edmonton, Alberta) as adapted for LTYPE1
  49. ;    by S.Kluger (El Paso,Texas)
  50. ;    The code was lifted to allow continued use of ASM.COM 
  51. ;
  52. ; Ver 1.07, 1 Aug 83, Ted H. Emigh  ...!unc!tucc!emigh
  53. ;    - added screen width specification
  54. ;    - added screen definition commands (see notes below)
  55. ;
  56. ; Ver 1.06, 2 Jul 83, Chuck Forsberg
  57. ;    - added commands for more, mince, vi familiarity.
  58. ;      Bad cmd gives help
  59. ;
  60. ; Ver 1.051, 26 June 83, Dick Mead
  61. ;    - added "?" for help on commands.
  62. ;
  63. ; Ver 1.05, 31 May 83, Bruce Ratoff
  64. ;    - added 'N' (next line) and 'P' (previous line) cmds
  65. ;    - decreased buffer from 8k to 4k (8k takes too long)
  66. ;
  67. ; Ver 1.04, 15 May 83, Keith Petersen, W8SDZ
  68. ;    - fixed bug which caused display past end-of-file
  69. ;        and added bogus eof in case none at file end
  70. ;    - added strip of high-order bit in line count routine
  71. ;    - added exit clear of any left-over keyboard character
  72. ;
  73. ; Ver 1.03, 11 May 83, Keith Petersen, W8SDZ
  74. ;    - fixed to allow assembly with ASM.COM
  75. ;    - fixed screen clear bug when crossing read boundries
  76. ;    - added strip for high-order bit in character before
  77. ;        printing (needed for WordStar files)
  78. ;    - improved stack routines
  79. ;    - fixed bug in console input routine
  80. ;    - removed Z80 dependant code (now works on 8080 too)
  81. ;
  82. ; Ver 1.02, 06 May 83, Lucien Pan, Toronto, Canada
  83. ;     - fixed some minor bugs
  84. ;     - returns to ccp w/o warm boot
  85. ;     - filters form-feeds (useful in .PRN files)
  86. ;     - scrolls foward/backwards by same number of lines
  87. ;     - disable/enable cursor during scroll for H-19
  88. ;
  89. ; Ver 1.01, 30 Mar 83 - added BDOS function  6.  W.F.Mcgee
  90. ;
  91. ; Ver 1.00, 23 Aug 82 Phil Cary, 748 Kenilworth Parkway, Baton
  92. ; Rouge, LA  70808
  93. ;
  94. ; BISHOW is a  buffered,  bidirectional  version  of  SHOW.ASM
  95. ; which first appeared in Interface Age, November, 1981.  That
  96. ; program  could  only  scroll  forward  in  a  file, and read
  97. ; sectors from disk one at a time as they  were  sent  to  the
  98. ; console.   I  used SHOW frequently to take a quick look at a
  99. ; file without loading a  big  text  editor,  and  to  examine
  100. ; another  file  with the RUN command while in Wordstar.  TYPE
  101. ; does not work since it is not a file that Wordstar can  load
  102. ; and run.
  103. ;
  104. ; This  bidirectional  version  uses  random access  reads. In
  105. ; addition, buffering was added so that  the  number  of  disk
  106. ; reads  would  be  reduced,  and  moving  back and forth in a
  107. ; moderate sized file would be speeded up.  There is  a  trade
  108. ; off between the size of the buffer and the length of time it
  109. ; takes to refill the buffer which should be set to the user's
  110. ; preference.
  111. ;
  112. ; There are several customizing items in this program.  One is 
  113. ; the equate "maxsec" which sets the buffer size.   Another is 
  114. ; the  string  in the subroutine "clrscr" just after  the  org 
  115. ; statement.   This should be changed to erase the screen  and 
  116. ; home  the cursor for the user's terminal.   The program,  as 
  117. ; written,  requires a terminal with an erase screen and  home 
  118. ; cursor  function.   Some  terminals  do not allow  the  80th 
  119. ; column  to be filled without going to the  next  line.   For 
  120. ; this reason, the screen width ("maxchr") initially is set to 
  121. ; 79.   The screen sizes can be changed using the "S" (screen) 
  122. ; command.  The parameters that can be changed are the maximum 
  123. ; column  displayed ("maxchr"),  the minimum column  displayed 
  124. ; (allowing  you  to "window" the output),  and the number  of 
  125. ; lines ("scroln").   A zero for the maximum column  displayed 
  126. ; will  give and unlimited screen width.   The maximum  column 
  127. ; displayed  and  the number of lines can be set when  calling 
  128. ; BISHOW,  e.g.,  "BISHOW file.nam 79 24" will give 79 columns 
  129. ; and 24 lines,  and "BISHOW file.nam 79" will give 79 columns 
  130. ; with the default number of lines.  The last customizing item 
  131. ; is the "short" equate.   If this is chosen, the multiplicity 
  132. ; of command forms is not allowed (see the beginning to change 
  133. ; the  commands  used),  and certain messages  are  shortened.  
  134. ; This will allow  BISHOW  to fit into a  1K area.  Direct I/O 
  135. ; to the console is used to avoid echoing the commands to  the 
  136. ; console as the CP/M write console function does.
  137. ;
  138. ; Just  a  small contribution to the public domain software as
  139. ; partial payment for the many fine and  educational  programs
  140. ; the system has given me.  Phil Cary.
  141. ;
  142. ;Define version number for help message
  143. ;
  144. VERS    EQU    3        ;Note current use in DB constrains VERS & 
  145. REVS    EQU    02        ; REVS to be one and two digits respectively
  146. ;
  147. FALSE    EQU    0
  148. TRUE    EQU    NOT FALSE
  149. ;
  150. ;    ASCII equates
  151. ;
  152. ENDMSG    EQU    0        ;null
  153. BS    EQU    8        ;Backspace
  154. TAB    EQU    9        ;tab
  155. LF    EQU    0AH        ;line feed
  156. FEED    EQU    0CH        ;form feed
  157. CR    EQU    0DH        ;carriage return
  158. EOF    EQU    1AH        ;end of file
  159. ESC    EQU    1BH        ;escape
  160. SPACE    EQU    20H        ;space
  161. ;
  162. ;------------------------------------------------------------------------------
  163. ; @@@@@
  164. ;    /////////////////////  User settings  ///////////////////////
  165. ;
  166. HEATH    EQU    FALSE        ;assemble for H-19 terminal
  167. OSBORNE    EQU    FALSE        ;assemble for 52-column screen
  168. ;
  169. SHORT    EQU    TRUE        ;no SQ or LBR = 1k / with SQ and LBR = 2k
  170. LONG    EQU    NOT SHORT    ;duplicate keys, includes help, margin set
  171.  
  172. SQUEEZE    EQU    TRUE        ;Optional, to handle squeezed files 
  173. LIBRARY    EQU    TRUE        ;Optional, to handle .LBR files
  174. ;
  175. NOWAIT    EQU    TRUE        ;true = no wait after screen clear 
  176. SILENT    EQU    TRUE        ;true = no superfluous "unsqueezing text" msg
  177. ;
  178.     IF     NOT OSBORNE
  179. SCROLN    EQU    24        ;number of lines per scroll
  180. MAXCHR    EQU    79        ;number of characters per line
  181.     ENDIF
  182. ;
  183.     IF    OSBORNE
  184. SCROLN    EQU    24        ;number of lines per scroll
  185. MAXCHR    EQU    51        ;number of characters per line
  186.     ENDIF
  187. ;
  188. ;     /////////  change the help tables if you change keys  //////////
  189. ;
  190. ;    command keys - short version
  191. ;
  192. LINE    EQU    'X'-40H
  193. LINE2    EQU     CR
  194. PAGE    EQU    'C'-40H
  195. PAGE2    EQU     SPACE
  196. LINEUP    EQU    'E'-40H
  197. LINEUP2    EQU    'P'
  198. PAGEUP    EQU    'R'-40H
  199. PAGEUP2    EQU    'B'
  200. ARWLFT    EQU    'S'-40H
  201. ARWLFT2 EQU    'H'-40H
  202. ARWRT    EQU    'D'-40H
  203. ARWRT2    EQU    TAB
  204. TOP    EQU    'T'
  205. TOP2    EQU    '1'
  206. QUIT    EQU    'Q'
  207. QUITCL    EQU    ESC
  208. ;
  209. ;    additional command keys - long version
  210. ;
  211.     IF    LONG
  212. LINE3    EQU    LF 
  213. LINE4    EQU    '+'
  214. LINE5    EQU    'Z'-40H
  215. LINE6    EQU    'N'
  216. PAGE3    EQU    'F'
  217. PAGE4    EQU    'F'-40H
  218. PAGE5    EQU    'V'-40H
  219. LINEUP3    EQU    'K'-40H
  220. LINEUP4    EQU    '-'
  221. LINEUP5    EQU    'W'-40H
  222. PAGEUP3    EQU    'B'-40H
  223. ARWLFT3 EQU    'A'-40H
  224. ARWRT3    EQU    'L'-40H
  225. SETKEY    EQU    'S'
  226. HUH    EQU    'H'
  227. HUH2    EQU    '?'
  228.     ENDIF
  229. ;
  230. ;    //////  check help and clrscr routines at @@@@@  below  ////////
  231. ;
  232. ;------------------------------------------------------------------------------
  233. ;
  234. BASE    EQU    0        ;standard zero base CP/M
  235. ;
  236. ;    BDOS functions
  237. ;
  238. CONOUT    EQU    2        ;console write
  239. OPEN    EQU    15        ;open file
  240. CLOSE    EQU    16        ;close file
  241. READR    EQU    33        ;read file random access
  242. STDMA    EQU    26        ;set dma address
  243. ;
  244. ;    Page zero equates
  245. ;
  246. WBOOT    EQU    BASE        ;warm boot entry point
  247. BDOS    EQU    WBOOT+5        ;BDOS entry point
  248. FCB    EQU    WBOOT+5CH    ;default fcb drive number
  249. CMDTAIL    EQU    WBOOT+80H    ;location of command tail
  250. FCBFN    EQU    FCB+1        ;start of filename
  251. FCBFT    EQU    FCB+9        ;start of filetype
  252. FCBEX    EQU    FCB+12        ;current extent number
  253. FCBCRR    EQU    FCB+33        ;current record number, random access
  254. TPA    EQU    WBOOT+100H    ;transient program area
  255. ;
  256. ;    Operational equates
  257. ;
  258. MAXSEC    EQU    32        ;number of sectors in buffer
  259. SQSIGN    EQU    0FF76H        ;Signature for SQ files
  260. LBSIGN    EQU    2000H        ;Signature for library files
  261. DLE    EQU    090H        ;Char flag for run compression (SQ)
  262. ;
  263.     ORG    TPA
  264. ;
  265.     JMP    START        ;skip over next subroutines
  266. ;
  267. ;------------------------------------------------------------------------------
  268. ; @@@@@
  269. ;    /////////  change help tables to reflect key changes  /////////
  270. ;
  271.     IF    LONG AND NOT OSBORNE
  272. HELP3:                
  273.     CALL    CDISP
  274.     DB    CR,LF,LF
  275.     DB    '   ^E        ^X       ^R        ^C       T    ^S    ^D  '
  276.     DB    '   S    H     Q',CR,LF
  277.     DB    'up line  next line  up page  next page  top  left  right'
  278.     DB    '  set  help  quit',CR,LF    
  279.     DB    '  P  -      cr +       B       F sp      1    bs    tab '
  280.     DB    '   S    ?    ESC',CR,LF
  281.     DB    ' ^W ^K    ^Z lf N     ^B      ^F ^V           ^A    ^L',CR,LF
  282.     DB    ENDMSG
  283.     JMP    GETCMD
  284.     ENDIF
  285. ;
  286.     IF    LONG AND OSBORNE
  287. HELP3:    JMP    HELP2
  288.     ENDIF
  289. ;
  290.     IF    LONG AND NOT OSBORNE
  291. HELP2:
  292.     CALL    CDISP
  293.     DB    CR,LF,LF
  294.     DB    '     P  ^E line up     B  ^R page up     bs  ^S left '
  295.     DB    '     S   set    Q   quit',CR,LF
  296.     DB    '     cr ^X line        sp ^C page        tab ^D right'
  297.     DB    '     T 1 top    ESC clear',CR,LF
  298.     DB    ENDMSG
  299.     JMP    GETCMD
  300.     ENDIF
  301. ;
  302.     IF    LONG AND OSBORNE
  303. HELP2:
  304.     CALL    CDISP
  305.     DB    CR,LF,LF
  306.     DB    '^E line up  ^R page up  ^S left    T top   Q  quit',CR,LF
  307.     DB    '^X line     ^C page     ^D right   S set  ESC clear',CR,LF
  308.     DB    ENDMSG
  309.     JMP    GETCMD
  310.     ENDIF
  311. ;
  312. ;    //////////////////  check your clear code  ///////////////////
  313. ;
  314. CLRSCR:        
  315.     CALL    CDISP        ;command to erase screen and home cursor
  316. ;
  317.     IF    NOT (HEATH OR OSBORNE)
  318.     DB    ESC,'+',ENDMSG    ;put your screen clear string here
  319.     ENDIF
  320. ;
  321.     IF    HEATH
  322.     DB    ESC,'E',ENDMSG    ;for H/Z-19 terminal -- Change as required
  323.     ENDIF
  324. ;
  325.     IF    OSBORNE
  326.     DB    1AH,ENDMSG    ;for Osborne (& Televideo?)
  327.     ENDIF
  328. ;
  329. ;    ///////////////////  end of user settings  ////////////////////
  330. ;
  331. ;------------------------------------------------------------------------------
  332. ;
  333.     IF    NOT NOWAIT
  334. WAIT:    MVI    B,0        ;waste time (may or may not be necessary)
  335. WAIT1:    XTHL            ;good time gobbeler!
  336.     XTHL
  337.     DCR    B
  338.     JNZ    WAIT1
  339.     ENDIF
  340. ;
  341.     RET            ;return from clrscr
  342. ;
  343. START:    
  344.     IF    HEATH
  345.     CALL    CDISP
  346.     DB    ESC,'x5',ENDMSG    ;disable cursor
  347.     ENDIF
  348. ;
  349.     LXI    H,0        ;get ccp's stack
  350.     DAD    SP
  351.     SHLD    STACK        ;save old stack for reinstatement at exit
  352.     LXI    SP,STACK    ;set new stack
  353.     LXI    H,CMDTAIL    ;point to command tail
  354.     MOV    B,M        ;get number of char in tail
  355.     INX    H        ;point to first character
  356.     INR    B
  357. ;
  358.     CALL    EATSP        ;Step to next non-bl in input
  359.     JZ    OPENF        ;no more characters
  360. ;
  361.     CALL    FILNAM        ;Skip file name, returns <B>=0 or <A>=20H
  362.     JZ    OPENF        ;only file name in tail
  363. ;
  364. ;            Check if there is a member name
  365.     CALL    EATSP        ;Step to next non-bl in input
  366.     JZ    OPENF        ;no more characters
  367.     CPI    '9'+1        ;Numeric?
  368. ;
  369.     IF    LIBRARY
  370.     JNC    MEMB        ;No -
  371.     ENDIF
  372. ;
  373.     CPI    '0'
  374.     JNC    NUMBER        ;Yes - must be width & height
  375. ;
  376. ;
  377.     IF    LIBRARY        ;Have member name (at FCB+11H)
  378. MEMB:
  379.     STA    MEMNAM        ;No - have member name
  380.     PUSH    H        ;Posn in command line 
  381.     PUSH    B        ;# of chars remaining
  382.     LXI    H,FCB+11H    ;Source
  383.     LXI    D,MEMFCB+1    ;Destination
  384.     MVI    B,11        ;Move name + type
  385.     CALL    MOVE 
  386. ;                add LBR suffix if required
  387.     LXI    H,FCB+9        ;Is there a suffix
  388.     MOV    A,M
  389.     CPI    SPACE
  390.     JNZ    NUMBR2        ;Yes - leave
  391.     MVI    M,'L'
  392.     INX    H
  393.     MVI    M,'B'
  394.     INX    H
  395.     MVI    M,'R'
  396. NUMBR2:
  397.     POP    B
  398.     POP    H
  399.     CALL    FILNAM        ;Skip member name, returns <B>=0 or <A>=20H
  400.     JZ    OPENF        ;end
  401.     ENDIF            ;above section included in library ver. only
  402. ;
  403. ;            Handle screen width & height
  404. NUMBER:
  405.     LXI    D,CHRMAX    ;point to chr/line
  406.     CALL    GETNBR        ;get number of characters/line
  407.     JC    HELP        ;invalid number
  408.     LXI    D,LINMAX    ;point to number of lines
  409.     CNZ    GETNBR        ;call only if characters still in
  410.                 ;__command tail
  411.     JC    HELP        ;invalid number
  412. ;
  413. OPENF:    CALL    OPNFIL        ;open file in default fcb
  414. ;
  415.     IF    SQUEEZE
  416.     CALL    CHKSQ        ;Check for squeezed, init if
  417.     ENDIF            ;Returns first word in file in <HL>
  418. ;
  419.     IF    LIBRARY
  420.     CALL    FILBF0        ;fill the disk buffer with start of file
  421.     CALL    CHKLB        ;Check for library file
  422.     CALL    CLRSCR
  423.     JMP    WRTFW0        ;Buffer contains top sectors
  424.     ENDIF    
  425. ;
  426. WRTFWD:
  427.     CALL    CLRSCR        ;erase the screen
  428.     CALL    FILBF0        ;fill the disk buffer with start of file
  429. WRTFW0:
  430.     LXI    H,DSKBUF    ;point to beginning of buffer
  431. ;
  432. WRTFW1:
  433.     MOV    A,M        ;get a character
  434.     CPI    EOF        ;see if eof
  435.     JZ    GETCMD        ;yes, wait for command
  436.     INX    H        ;bump pointer
  437.     ANI    7FH        ;strip high bit
  438.     CPI    FEED        ;filter form-feeds
  439.     JZ    FILTER        ;__commonly found in .PRN files
  440.     CALL    CO1        ;put it on console
  441.     CPI    CR        ;see if end of line
  442.     JZ    FWDCNT        ;yes, adjust line count
  443. ;
  444. WRTFW2:    LXI    D,ENDBUF    ;get end of buffer address
  445.     CALL    cmphlde        ;Is HL> gt DE> (end of buff)
  446. ;                ; Note test is LT now, not NE (v1.81)
  447.     JC    WRTFW1        ;continue with next character
  448.     CALL    FILBUF        ;fill the disk buffer with next sectors
  449.     JMP    WRTFW0        ;start over
  450. ;
  451. HELP:    CALL    CDISP
  452.     DB    CR,LF,'BISHOW '
  453.     DB    (VERS MOD 10)+'0','.'
  454.     DB    REVS/10+'0',(REVS MOD 10)+'0',CR,LF
  455. ;    
  456.     IF    LIBRARY AND SQUEEZE
  457.     DB    'bishow d:ANYsqFIL.lbr '
  458.     ENDIF
  459. ;
  460.     IF    LIBRARY AND NOT SQUEEZE
  461.     DB    'bishow a:FILnotSQ.lbr '
  462.     ENDIF
  463. ;
  464.     IF    SQUEEZE AND NOT LIBRARY
  465.     DB    'bishow a:SQZorNOT.fil '    
  466.         ENDIF
  467. ;    
  468.     IF     (NOT SQUEEZE) AND (NOT LIBRARY)
  469.     DB    'bishow d:anyPLAIN.fil ' 
  470.     ENDIF
  471. ;
  472.     IF    LIBRARY
  473.     DB    '[member] '
  474.     ENDIF
  475. ; 
  476.     DB    '[cols [lines]]',CR,LF,ENDMSG
  477.     JMP    EXIT1
  478. ;
  479. FILTER:    PUSH    PSW        ;save status
  480.     MVI    A,'^'        ;print '^' in front
  481.     CALL    CO1        ;__of control character
  482.     POP    PSW        ;restore status
  483.     ADI    40H        ;mask into displayable char
  484.     CALL    CO1        ;display filtered control char
  485. ;
  486. FWDCNT:    LDA    LINCNT        ;get number of lines displayed
  487.     INR    A        ;bump it
  488.     STA    LINCNT        ;__and store it
  489.     MOV    D,A        ;save lincnt
  490.     LDA    LINMAX        ;get max number of line
  491.     CMP    D        ;compare with line count
  492.     JNZ    WRTFW2        ;if not there, continue, else get command
  493.     XRA    A        ;zero the
  494.     STA    LINCNT        ;__line count
  495. ;
  496. GETCMD:    PUSH    H
  497.     PUSH    D
  498.     PUSH    B
  499. ;
  500. GETCM1:    CALL    GETIN        ;Get input char if any
  501.     ORA    A        ;loop till char avail
  502.     JZ    GETCM1
  503.     POP    B
  504.     POP    D
  505.     POP    H
  506.     CPI    'a'        ;change command to
  507.     JC    GETCM2        ;__upper case
  508.     CPI    'z'+1
  509.     JNC    GETCM2
  510.     XRI    20H        ;is lower case, make upper case
  511. ;
  512. GETCM2:        
  513. ;    ///////////////  commands for short version  /////////////////
  514. ;
  515.     CPI    LINE        ;scroll next line
  516.     JZ    WRTNXT
  517.     CPI    LINE2
  518.     JZ    WRTNXT
  519.     CPI    PAGE        ;scroll next page
  520.     JZ    WRTFW1
  521.     CPI    PAGE2        
  522.     JZ    WRTFW1
  523.     CPI    LINEUP        ;scroll prev line
  524.     JZ    WRTPRV
  525.     CPI    LINEUP2
  526.     JZ    WRTPRV
  527.     CPI    PAGEUP        ;scroll page backward
  528.     JZ    WRTBAK
  529.     CPI    PAGEUP2
  530.     JZ    WRTBAK
  531.     CPI    ARWLFT        ;scroll left
  532.     JZ    ADJMM
  533.     CPI    ARWLFT2
  534.     JZ    ADJMM        
  535.     CPI    ARWRT        ;scroll right
  536.     JZ    ADJMM
  537.     CPI    ARWRT2
  538.     JZ    ADJMM
  539.     CPI    TOP        ;go to 1st line of file
  540.     JZ    WRTTOP
  541.     CPI    TOP2
  542.     JZ    WRTTOP
  543.     CPI    QUIT        ;does not clear screen
  544.     JZ    EXIT        
  545.     CPI    QUITCL        ;clears screen
  546.     JZ    EXITCL        
  547. ;
  548. ;    ////////////////  commands for long version  /////////////////
  549. ;
  550.     IF    LONG
  551. ;
  552.     CPI    LINE3
  553.     JZ    WRTNXT
  554.     CPI    LINE4
  555.     JZ    WRTNXT
  556.     CPI    LINE5
  557.     JZ    WRTNXT
  558.     CPI    LINE6
  559.     JZ    WRTNXT
  560. ;
  561.     CPI    PAGE3
  562.     JZ    WRTFW1
  563.     CPI    PAGE4
  564.     JZ    WRTFW1
  565.     CPI    PAGE5
  566.     JZ    WRTFW1
  567. ;
  568.     CPI    LINEUP3
  569.     JZ    WRTPRV
  570.     CPI    LINEUP4
  571.     JZ    WRTPRV
  572.     CPI    LINEUP5
  573.     JZ    WRTPRV
  574. ;
  575.     CPI    PAGEUP3
  576.     JZ    WRTBAK
  577. ;
  578.     CPI    ARWLFT3
  579.     JZ    ADJMM        
  580. ;
  581.     CPI    ARWRT3
  582.     JZ    ADJMM
  583. ;
  584.     CPI    SETKEY
  585.     JZ    SETSCR
  586. ;
  587.     CPI    HUH
  588.     JZ    HELP2        ;brief table of commands
  589.     CPI    HUH2
  590.     JZ    HELP3        ;full table of commands
  591. ;
  592.     ENDIF
  593. ;
  594.     JMP    GETCMD
  595. ;
  596. ;
  597. ;            Go to top of file
  598. WRTTOP:
  599.     LDA    TOPBUF        ;Get top in buffer flag
  600.     ORA    A
  601.     JNZ    WRTFWD        ;No - the hard way
  602.     CALL    CLRSCR        ;erase the screen
  603. WRTTO1:
  604.     XRA    A
  605.     STA    LINCNT        ;Clear lines put so far
  606.     JMP    WRTFW0        ;Buffer contains top sectors
  607. ;
  608. ;            Write one more line
  609. WRTNXT:    LDA    LINMAX
  610.     DCR    A        ;fool wrtfw1 to only write one line
  611.     STA    LINCNT
  612.     JMP    WRTFW1
  613. ;            Back up one line
  614. WRTPRV:    LDA    LINMAX        ;back up one screen + 1 line
  615.     INR    A
  616.     JMP    WRTBK0
  617. ;            Back up full screen
  618. WRTBAK:    LDA    LINMAX        ;get screen line count
  619.     ADD    A        ;__multiply by 2
  620. ;
  621. WRTBK0:    INR    A        ;__and add 1
  622.     STA    LINCNT        ;__to backup to previous page
  623.     CALL    CLRSCR        ;clear the screen
  624. ;
  625. WRTBK1:    LXI    D,DSKBUF    ;get address of start of buffer start
  626.     CALL    cmphlde        ;Is HL> LT DE> (start of buff)
  627. ;                ; Note test is LT now, not NE (v1.81)
  628.     JC    FILBAK        ;Go refill buffer
  629. ;
  630. WRTBK2:    MOV    A,M        ;get a character
  631.     ANI    7FH        ;strip high bit
  632.     DCX    H        ;decrement buffer
  633.     CPI    CR        ;see if end of line
  634.     JZ    BAKCNT        ;__or form-feed
  635.     CPI    FEED        ;__and adjust line count if so
  636.     JNZ    WRTBK1        ;else, loop if not
  637. ;
  638. BAKCNT:    LDA    LINCNT        ;else, get number of lines to move back
  639.     DCR    A        ;__and decrement it
  640.     STA    LINCNT        ;__store it
  641.     JNZ    WRTBK1        ;__and loop if not there
  642.     INX    H        ;else bump pointer
  643.     INX    H        ;__to account for dcx
  644.     JMP    WRTFW1        ;and go write a screen
  645. ;
  646. FILBAK:
  647. ;            Test for top of file
  648.     LDA    TOPBUF        ;Get top in buffer flag
  649.     ORA    A
  650.     JZ    WRTTO1        ;Yes - start of file in buffer
  651. ;            Start of file not in buffer, step back
  652.     LHLD    SECCNT        ;Get no of sectors last read
  653.     LXI    D,MAXSEC    ;get the buffer size
  654.     DAD    D        ;add them
  655.     XCHG            ;__and put them in DE
  656.     LDA    FCBCRR        ;subtract low order byte 
  657.     SUB    E        ;__from current record count
  658.     STA    FCBCRR        ;__and store in current record count
  659.     LDA    FCBCRR+1    ;same with high order byte
  660.     SBB    D        ;__but with borrow
  661.     JM    WRTFWD        ;if beyond beginning of file, start over
  662.     STA    FCBCRR+1    ;else, store high order byte
  663.     CALL    FILBUF        ;fill the buffer
  664.     LXI    H,ENDBUF    ;__and point to end of buffer
  665.     CALL    CLRSCR        ;clear the screen
  666.     JMP    WRTBK2        ;continue moving back in file
  667. ;
  668. ;            Fill buffer with top of file 
  669. FILBF0:
  670.     XRA    A        ;get a 0
  671.     STA    LINCNT        ;store in line count
  672.     STA    CHRCNT        ;store in character count
  673. ;                Do not reset the current extent!!!
  674. ;                BDOS will switch extents only if the no
  675. ;                specified ( <FCBEX> ) does NOT agree with
  676. ;                the wanted no <FCBCRR>. 
  677.     STA    FCBCRR        ;Reset to sector zero
  678. ;
  679.     IF    NOT LIBRARY
  680.     STA    FCBCRR+1    ;
  681.     STA    FCBCRR+2    ;__and clear the overflow
  682.     ENDIF
  683. ;
  684.     IF    LIBRARY
  685.     LHLD    SCZERO        ;Set to sector zero for file/member
  686.     SHLD    FCBCRR
  687.     ENDIF
  688. ;
  689. ;            ;Fill buffer from spec'd sector
  690. FILBUF:
  691.     MVI    B,MAXSEC    ;number of sectors to resd
  692. FILB1S:
  693. ;
  694.     IF    LIBRARY
  695.     LHLD    SCZERO        ;Get top sector for member
  696.     XCHG 
  697.     LHLD    FCBCRR        ;Is this top of file?
  698.     CALL    cmphlde        ;This it? (<A>=0 if equal)
  699.     ENDIF
  700. ;
  701.     IF    NOT LIBRARY    
  702.     LHLD    FCBCRR        ;Is this top of file?
  703.     MOV    A,H
  704.     ORA    L
  705.     ENDIF
  706. ;
  707.     STA    TOPBUF        ;Set top of file in buffer flag
  708.     LXI    D,DSKBUF    ;load start of disk buffer
  709.     LXI    H,0        ;zero out the
  710.     SHLD    SECCNT        ;__number of sectors in buffer
  711. ;                ; Z - top, NZ - not top 
  712.     IF    SQUEEZE
  713.     LDA    SQFLG        ;Is this a squeezed file
  714.     ORA    A
  715.     JNZ    FILSQ        ;Yes -
  716.     ENDIF
  717. ;
  718. FILBU1:
  719.     PUSH    H        ;save all
  720.     PUSH    D        ;__registers from
  721.     PUSH    B        ;__BDOS clobber
  722.     MVI     C,STDMA        ;set dma to
  723.     CALL    BDOS        ;__disk buffer
  724. ;
  725.     LXI    D,FCB        ;set up to read
  726.     MVI    C,READR        ;__a record
  727.     CALL    BDOS        ;do it
  728.     ORA    A        ;read OK?
  729.     LHLD    FCBCRR        ;get current record number
  730.     INX    H        ;__bump it
  731.     SHLD    FCBCRR        ;__and save it
  732.     LHLD    SECCNT        ;get sectors in buffer
  733.     INX    H        ;bump it
  734.     SHLD    SECCNT        ;store it
  735.     POP    B
  736.     POP    D
  737.     POP    H
  738.     JNZ    RDERR        ;no, last sector read
  739. ;
  740.     IF    LIBRARY
  741.     PUSH    D        ;Save sector buffer pointer
  742.     LHLD    FCBCRR        ;get current record number
  743.     XCHG
  744.     LHLD    SCLAST        ;& get last sector for member (or FFFF)
  745.     CALL    cmphlde        ;Are we within member 
  746.     POP    D
  747.     JC    RDERR        ;no, last sector read
  748.     ENDIF
  749. ;
  750.     DCR    B        ;decrement it
  751.     RZ            ;if done return
  752.     LXI    H,128        ;else, add 128 to
  753.     DAD    D        ;__dma address
  754.     XCHG            ;put it in de
  755.     JMP    FILBU1        ;read another sector
  756. ;
  757.     IF    SQUEEZE
  758. ;            Fill buffer from squeezed file
  759. ;            This rtn handles mapping from unsq sector #
  760. ;            to sector, byte & bit in sq stream
  761. ;            on input FCBCRR contains wanted sector no,
  762. ;            ( no allowance made for sectors # over 65535)
  763. ;            <B> contains no of sectors wanted
  764. ;            DE> buffer where sectors wanted,
  765. ;             ignored in this version, always full DSKBUF
  766. FILSQ:
  767.     LHLD    FCBCRR        ;Get # for 1st sector wanted
  768.     XCHG
  769.     PUSH    D        ;Save to restore after unsq
  770.     LHLD    NXTSEC        ; & 1st sector after buffered ones  
  771.     CALL    cmphlde        ;Consecutive?
  772.     JZ    USQNXT        ;Yes - fine
  773.     JNC    USQBAK        ;No - lower
  774. ;    Next sect after latest but not consec
  775.     CALL    CDISP
  776.     DB    CR,LF,'Disjoint sectors',CR,LF,0
  777.     JMP    EXIT        ;Should never happen
  778. USQBAK:            ;Going backward
  779.     ENDIF
  780. ;
  781.     IF    SQUEEZE AND LIBRARY
  782.     LHLD    SCZERO        ;Get 1st sector for member
  783.     CALL    cmphlde        ;All the way back to start?
  784.     ENDIF
  785. ;
  786.     IF    SQUEEZE AND NOT LIBRARY
  787.     MOV    A,D        ;All the way?
  788.     ORA    E
  789.     ENDIF
  790. ;
  791.     IF    SQUEEZE
  792.     JNZ    USQNO1        ;No - MUST be prev!!!
  793.     LXI    H,SQMAP+2+8    ;Yes - reset SQMAP index to #3
  794.     SHLD    SQMAP
  795. USQNO1:
  796.     LHLD    SQMAP        ;Get index into mapping table
  797.     LXI    D,-8        ;Step back from next, past current to prev
  798.     DAD    D
  799.     SHLD    SQMAP        ; & save updated index for next
  800.     MOV    E,M        ;Get SQ sector no
  801.     INX    H
  802.     MOV    D,M
  803.     INX    H
  804.     MOV    C,M        ;Get byte offset
  805.     INX    H
  806.     MOV    A,M        ; & bit offset
  807.     STA    bitlft
  808.     XRA    A
  809.     STA    rcnt        ;No runs in progress
  810. ;                (assumption)
  811.     STA    SQBYT+1        ;Set offset 1st data byte
  812.     MOV    A,C
  813.     STA    SQBYT        ;For now offset within sector only
  814.     LHLD    SQBSC1        ;Get no of first SQ sector now in buffer
  815.     XCHG            ;<HL> wanted 1st sector, <DE> actual 1st
  816.     CALL    cmphlde        ;Is 1st buffer sector low/equal 1st data sect?
  817.     JNC    USQ1OK        ;Yes - first wanted sector SQ in buffer
  818. ;                 Max header 1035 bytes + file name)
  819. ;            Force reload of SQ buffer
  820.     SHLD    NXTSQS        ;No - 1st data sector b/4 1st buffer sect
  821. ;                 (note is probab not sector 0
  822. ;                 because of header, eg decoding tree)
  823.     MVI    A,1        ;Set rewind with I/O
  824.     STA    SQREWD        ;Set rewind flag
  825. ;                 SQBYT contains offset of 1st data byte
  826.     XRA    A
  827.     STA    SQEOF        ;Reset end of file on SQ
  828. ;                Leave current extent alone. This is how
  829. ;                BDOS knows how to switch extents. It checks
  830. ;                if the current extent no agrees with
  831. ;                the wanted record.
  832.     STA    FCBCRR+2    ; & count overflow, should not be necessary
  833.     MOV    D,A
  834.     JMP    USQNX1        ;Go adj buffer pointer
  835. ;                (NOP since <DE>=0
  836. ;            ;SQ text still in buffer
  837. USQ1OK:
  838. ;                <DE> # of 1st sector in SQ buf
  839. ;                <HL> # of wanted SQ sector 
  840. ;                (Max 100H SQ sectors in buffer)
  841.     MOV    A,L
  842.     SUB    E
  843.     RAR            ;Convert to pages (100H)
  844. ;                 Know Cy=0 in
  845. ;                 leaves Cy if odd no of sects
  846.     MOV    D,A
  847.     MVI    A,0        ;Do not disturb Cy
  848.     RAR            ;Pu carry (now 80H or 00H) 
  849. USQNX1:
  850.     MOV    E,A
  851.     LHLD    SQBYT        ;Get offset of 1st data byte in wanted sect
  852.     DAD    D        ; --> offset in buffer
  853.     LXI    D,SQBUF
  854.     DAD    D        ;Convert to absolute addr
  855.     SHLD    inbufs        ;& set as next byte to unsqueeze
  856. ;
  857. USQNXT:            ;Next sector consecutive
  858.     LHLD    NXTSQS        ;Get no of next SQ sector 
  859. ;                (in case read reqd)
  860.     SHLD    FCBCRR
  861. ;            Build mapping table entry
  862.     LHLD    inbufs        ;Calc offset in buffer
  863.     LXI    D,-SQBUF
  864.     DAD    D
  865.     MOV    C,L        ;Keep offset within sector
  866.     LDA    bitlft        ;Get bit offset
  867.     MOV    B,A
  868.     ORA    A        ;On byte boundary?
  869.     MOV    A,C
  870.     JNZ    NOTBBY        ;No -
  871.     INR    A        ;Yes - no adj reqd
  872. NOTBBY:
  873.     ANI    7FH        ;Ensure sector relative
  874.     DAD    H        ;Convert to sector no
  875.     ORA    A        ;Is next byte at start of sect?
  876.     JNZ    SECTOK
  877.     DCR    H        ;Yes - step back one sector
  878. SECTOK:
  879.     DCR    A
  880.     ANI    7FH        ;& adj byte index
  881.     MOV    E,H
  882.     MVI    D,0
  883.     LHLD    SQBSC1        ;# of 1st sector in buffer
  884.     DAD    D
  885.     XCHG            ;<D> absolute SQ sector no
  886.     LHLD    SQMAP        ;Get index
  887.     MOV    M,E        ;Save abs SQ sector no
  888.     INX    H
  889.     MOV    M,D
  890.     INX    H
  891.     MOV    M,A        ;Save sector relative byte offset
  892.     INX    H
  893.     MOV    M,B        ;Save bitlft
  894.     INX    H
  895.     SHLD    SQMAP        ;Save new index
  896.     ENDIF
  897. ;
  898.     IF    SQUEEZE AND NOT SILENT
  899.     CALL    CDISP        ;Show msg where is
  900.     DB    '>>> Unsqueezing Text <<<',ENDMSG
  901.         ;Corrupts display if after CR but before LF
  902.     ENDIF
  903. ;
  904.     IF    SQUEEZE
  905.     CALL    FILUSQ        ;fills unsq buffer
  906.     ENDIF            ;SQEOF set as well then
  907. ;
  908.     IF    SQUEEZE AND NOT SILENT
  909.     CALL    CDISP        ;Remove msg just displayed, assumes
  910.                 ;BS works across start of line if reqd
  911.     DB    BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,BS
  912.     DB    BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,BS
  913.     DB    '                        '
  914.     DB    BS,BS,BS,BS,BS,BS,BS,BS    ,BS,BS,BS,BS
  915.     DB    BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,0
  916.     ENDIF
  917. ;
  918.     IF    SQUEEZE
  919.     LHLD    FCBCRR        ;Get no of next SQ sector
  920.     SHLD    NXTSQS
  921.     LHLD    nxtadr        ;Calc # of unsq sectors in buf
  922.     LXI    D,-DSKBUF    ;(as neg no)
  923.     DAD    D        ;Calc length
  924.     DAD    H        ; & convert to sectors in <H>
  925.     MOV    L,H
  926.     MVI    H,0
  927.     SHLD    SECCNT        ;Save # of sectors in DSKBUF
  928.     POP    D        ;Get FCBCRR as passed by calling rtn
  929.     DAD    D        ; & calc new one
  930.     SHLD    FCBCRR
  931.     SHLD    NXTSEC
  932.     RET
  933.     ENDIF
  934. ;
  935. ;
  936. ;We only get here if end of file
  937. ;
  938. RDERR:    MVI    A,EOF        ;get bogus eof
  939.     STAX    D        ;save at buffer end in case no eof in file
  940.     XRA    A        ;get a zero to direct to start of buffer
  941.     RET            ;__on ret
  942. ;
  943. OPNFIL:    LDA    FCBFN        ;point to first letter of filename
  944.     CPI    ' '        ;anything there?
  945.     JZ    HELP        ;no, give help message
  946.     XRA    A        ;get a 0
  947.     STA    FCBEX        ;zero current extent
  948.                 ;MUST open file on extent zero
  949.     LXI    D,FCB        ;file name in default fcb
  950.     MVI    C,OPEN        ;set up to open
  951.     CALL    BDOS        ;do it
  952.     INR    A        ;open OK?
  953.     RNZ            ;yes
  954.     CALL    CDISP        ;else, give error msg and quit
  955.     DB    'No File',ENDMSG
  956.     JMP    EXIT1        ;leave msg on screen on exit
  957. ;
  958. GETNBR:    MOV    A,M        ;get first digit
  959.     INX    H
  960.     DCR    B        ;b=number of characters left in buffer
  961.     RZ            ;no digit
  962.     CPI    SPACE
  963.     JZ    GETNBR        ;wait until next non-space
  964.     PUSH    D        ;save location to save number
  965.     MVI    D,0        ;initialize number
  966. ;
  967. GNUM1:    SUI    30H        ;change ASCII to number
  968.     JC    INVNUM        ;not a number
  969.     CPI    10
  970.     CMC
  971.     JC    INVNUM        ;not a number
  972.     PUSH    PSW        ;save number
  973.     MOV    A,D        ;multiply old number by 10
  974.     ADD    A        ;*2
  975.     ADD    A        ;*4
  976.     ADD    A        ;*8
  977.     ADD    D        ;*9
  978.     ADD    D        ;*10
  979.     MOV    D,A
  980.     POP    PSW        ;restore new digit
  981.     ADD    D
  982.     MOV    D,A
  983.     MOV    A,M        ;get next digit
  984.     INX    H
  985.     DCR    B
  986.     JZ    ENDNUM        ;end of number
  987.     CPI    SPACE
  988.     JNZ    GNUM1
  989. ;
  990. ENDNUM:    MOV    A,D        ;save number
  991.     DCR    A        ;correct number for co routines
  992.     XCHG            ;set to restore save location
  993.     POP    H        ;restore save location
  994.     MOV    M,A        ;save digit
  995.     XCHG            ;put buffer location where it belongs
  996.     MOV    A,B        ;see if any characters left in buffer
  997.     ORA    A        ;zero if no characters in buffer
  998.     RET
  999. ;
  1000. INVNUM:    POP    D        ;correct stack
  1001.     RET
  1002. ;
  1003.     IF LONG
  1004. ASCIIN:    MVI    B,100        ;divide by 100, then change
  1005.     CALL    DIVIDE        ;__digit to ASCII and store at hl
  1006.     MVI    B,10        ;divide by 10, then change
  1007.     CALL    DIVIDE        ;__digit to ASCII and store at hl+1
  1008.     MVI    B,30H        ;change ones place number
  1009.     ADD    B        ;__to ASCII and store at hl+2
  1010.     MOV    M,A
  1011.     DCX    H        ;delete leading zeroes
  1012.     DCX    H        ;__in the number
  1013.     MVI    C,SPACE        ;__and replace with spaces
  1014.     MOV    A,B
  1015.     CMP    M        ;check first digit for '0'
  1016.     JNZ    CDISP        ;not zero
  1017.     MOV    M,C        ;replace with space
  1018.     INX    H
  1019.     CMP    M        ;check second digit for '0'
  1020.     JNZ    CDISP        ;not zero
  1021.     MOV    M,C        ;replace with space
  1022.     ENDIF
  1023. ;
  1024. CDISP:    XTHL            ;exchange top of stack and HL
  1025. ;
  1026. CDIS1:    MOV    A,M        ;HL now pointing to db message
  1027.     ORA    A        ;see if 0 at end of message
  1028.     INX    H
  1029.     JZ    CDIS2        ;yes, restore stack and return
  1030.     CALL    CO        ;no, print the character
  1031.     JMP    CDIS1        ;__and loop
  1032. ;
  1033. CDIS2:    XTHL            ;get return address on top of stack
  1034.     RET            ;__and return
  1035. ;
  1036. CO:    PUSH    B        ;Save the registers
  1037.     PUSH    D        ;__from bdos
  1038.     PUSH    H        ;__clobber
  1039. CO2:    PUSH    PSW
  1040.     MOV    E,A        ;set up character
  1041.     MVI    C,CONOUT    ;__to send to console
  1042.     CALL    BDOS        ;do it
  1043.     POP    PSW
  1044. CO5:    POP    H        ;restore
  1045.     POP    D        ;__the registers
  1046.     POP    B
  1047.     RET
  1048. ;
  1049. CO1:    PUSH    B        ;Save the registers
  1050.     PUSH    D
  1051.     PUSH    H
  1052.     MOV    E,A
  1053.     LXI    H,CHRCNT    ;Get address of character count
  1054.     CPI    CR        ;see if end of line
  1055.     JZ    ENDLIN        ;update line information
  1056.     CPI    LF        ;ignore linefeed
  1057.     JZ    CO2
  1058.     LDA    CHRMAX        ;get maximum characters per line
  1059.     CMP    M        ;see if too many char
  1060.     JC    CO5        ;don't print character
  1061.     MOV    A,E        ;restore and print character
  1062.     CPI    TAB        ;fix chrcnt for tabs
  1063.     JZ    TABFIX
  1064.     INR    M        ;increment character count
  1065.     LDA    CHRMIN        ;see if up to minimum display yet
  1066.     CMP    M
  1067.     MOV    A,E        ;restore character
  1068.     JNC    CO5        ;do not display character
  1069.     JMP    CO2        ;finally, display character
  1070. ;
  1071. ENDLIN:    MVI    M,0        ;reset character count
  1072.     JMP    CO2        ;print cr
  1073. ;
  1074. TABFIX:    MVI    A,08H        ;fix chrcnt for tabs
  1075.     ADD    M        ;increment to next 8-count
  1076.     ANI    0F8H        ;make into multiple of 8
  1077. ;
  1078. TAB2:    SUB    M        ;get number of space to go
  1079.     MOV    B,A
  1080. ;
  1081. TAB1:    MVI    A,SPACE        ;expand tab
  1082.     CALL    CO1
  1083.     DCR    B
  1084.     JNZ    TAB1        ;still more spaces
  1085.     JMP    CO5        ;exit routine
  1086. ;
  1087. ;
  1088.     IF    LONG
  1089. SETSCR:    PUSH    H
  1090.     PUSH    D
  1091.     PUSH    B
  1092. ;
  1093. GETMAX:    LDA    CHRMAX        ;get maximum number of characters
  1094.     INR    A
  1095.     LXI    H,HUNS
  1096.     CALL    ASCIIN        ;put ASCII number in message        
  1097.     DB    CR,LF,'Max Column: '
  1098. ;
  1099. HUNS:    DB    30H
  1100.     DB    30H
  1101.     DB    30H
  1102.     DB    ' New? ',ENDMSG
  1103.     CALL    GETINP        ;read input from console
  1104.     LXI    D,CHRMAX    ;set new chrmax in memory
  1105.     CALL    GETNBR
  1106.     JC    GETMAX        ;if error, repeat last message
  1107. ;
  1108. GETMIN:    LDA    CHRMIN        ;get minimum character display
  1109.     INR    A
  1110.     LXI    H,HUN
  1111.     CALL    ASCIIN        ;put ASCII number in message        
  1112.     DB    LF,'Min Column: '
  1113. ;
  1114. HUN:    DB    30H
  1115.     DB    30H
  1116.     DB    30H
  1117.     DB    ' New? ',ENDMSG
  1118.     CALL    GETINP        ;read input from console
  1119.     LXI    D,CHRMIN    ;set new chrmax in memory
  1120.     CALL    GETNBR
  1121.     JC    GETMIN        ;if error, repeat last message
  1122. ;
  1123. GETLIN:    LDA    LINMAX        ;get number of lines per display
  1124.     LXI    H,HUND
  1125.     CALL    ASCIIN        ;put ASCII number in message        
  1126.     DB    LF,'Lines per Page: '
  1127. ;
  1128. HUND:    DB    30H
  1129.     DB    30H
  1130.     DB    30H
  1131.     DB    ' New? ',ENDMSG
  1132.     CALL    GETINP        ;read input from console
  1133.     LXI    D,LINMAX    ;set new chrmax in memory
  1134.     CALL    GETNBR
  1135.     JC    GETLIN        ;if error, repeat last message
  1136.      POP    B
  1137.     POP    D
  1138.     POP    H
  1139. ;
  1140. WRTSAM:    LDA    LINMAX        ;write the same screen
  1141.     JMP    WRTBK0
  1142. ;
  1143. GETINP:    MVI    A,5        ;get set to read new maximum column
  1144.     STA    CMDTAIL
  1145.     MVI    C,0AH
  1146.     LXI    D,CMDTAIL
  1147.     CALL    BDOS        ;get maximum column
  1148.     LXI    H,CMDTAIL+1    ;now, change to ASCII
  1149.     MOV    B,M
  1150.     INX    H
  1151.     INR    B
  1152.     RET            ;return with input in buffer
  1153. ;
  1154.     ENDIF    ;above code (flying set) only if long
  1155. ;
  1156. ADJMM:                ;Adjust char min/max on cursor left/rt
  1157.     PUSH    H
  1158.     CPI    ARWLFT        ;Move left (decrease)?
  1159.     JZ    ADJM1        ; set flag
  1160.     CPI    ARWLFT2
  1161.     JZ    ADJM1
  1162. ;
  1163.     IF LONG
  1164.     CPI    ARWLFT3
  1165.     JZ    ADJM1
  1166.     ENDIF
  1167. ;
  1168. ADJM1:    LDA    CHRMAX        ;rightmost char to display
  1169.     MOV    H,A
  1170.     LDA    CHRMIN        ;leftmost char to display
  1171.     MVI    L,8        ;Scroll by 8
  1172.     JZ    ADJMMD        ;OK - adjust to left
  1173.     ADD    L        ;No - increase min, no limit
  1174.     PUSH    PSW
  1175.     MOV    A,L
  1176.     ADD    H        ;increase  max
  1177.     JMP    ADJMMS        ;OK - adjust to right
  1178. ADJMMD:
  1179.     SUB    L        ;adjust to left
  1180.     PUSH    PSW
  1181.     MOV    A,H
  1182.     SUB    L
  1183. ADJMMS:                ;adjust to right
  1184.     MOV    H,A        ;<H> max
  1185.     POP    PSW        ;<A> min
  1186.     CMP    H        ;Wrap, (max< min)
  1187.     JNC    ADJMMX        ;OK - leave unchanged
  1188.     STA    CHRMIN
  1189.     MOV    A,H
  1190.     STA    CHRMAX
  1191. ADJMMX:
  1192.     POP    H
  1193.     LDA    LINMAX        ;write the same screen
  1194.     JMP    WRTBK0        ;same effect as WRTSAM above
  1195. ; 
  1196. ;
  1197.     IF LONG
  1198. DIVIDE:    MVI    C,'0'-1        ;extract dividend of a div c
  1199. ;
  1200. DIV1:    INR    C        ;__and store in location pointed
  1201.     SUB    B        ;__to by hl
  1202.     JNC    DIV1
  1203.     ADD    B
  1204.     MOV    M,C        ;save ASCII digit
  1205.     INX    H        ;bump pointer to next location
  1206.     RET
  1207. ;
  1208.     ENDIF
  1209. ;
  1210. EXITCL:
  1211. ;            Clear screen only on <ESC> exit
  1212.     CALL    CLRSCR        ;clear the screen
  1213. ;
  1214. EXIT:
  1215. ;    CALL    GETIN        ;__get any waiting character
  1216. ;    CALL    GETIN        ;and a possible second character
  1217. ;
  1218.     IF    HEATH
  1219.     CALL    CDISP        ;re-enable cursor
  1220.     DB    ESC,'y5',ENDMSG
  1221.     ENDIF
  1222. ;
  1223.     LXI    D,FCB        ;close file
  1224.     MVI    C,CLOSE        ;--in case this is MP/M
  1225.     CALL    BDOS
  1226. ;
  1227. EXIT1:
  1228.     LHLD    STACK        ;get old stack
  1229.     SPHL
  1230.     RET            ;return to CCP
  1231. ;
  1232. ;
  1233.     IF    LIBRARY
  1234. CHKLB:                ;Check for Library file
  1235.     xra    a
  1236.     sta    memfcb
  1237.     sta    lbflg        ;Clear library flag
  1238.     LHLD    DSKBUF        ;Get 1st word in file
  1239.     lxi    d,lbsign    ;Get expected value
  1240.     call    cmphlde
  1241.     jz    islb
  1242. ;            Not library
  1243. ;
  1244.     lda    memnam        ;Was member specified
  1245.     ora    a
  1246.     rz            ;No - ok
  1247.     call    CDISP
  1248.     db    cr,lf,'Not LBR',cr,lf,0
  1249.     jmp    EXIT        ;Get out to leave msg visible
  1250. ;
  1251. ;            Is library
  1252. islb:
  1253.     mvi    a,1
  1254.     sta    LBFLG        ;Yes - set library flag
  1255.     LXI    H,DSKBUF+14    ;Set to dir size (in sectors)
  1256.     mov    a,m        ;Assume <255 entries
  1257.     RAL
  1258.     RAL            ;Convert # sectors to # entries
  1259.     DCR    A        ;Less 1 for file descriptor
  1260.     sta    dirsiz        ;directory size in entries
  1261.     mov    b,a        ;Save no of entries for loop
  1262.     LXI    H,DSKBUF+20H    ;Set 1st member entry
  1263.  
  1264.     CALL    CDISP        ;write a blank line before first dir line
  1265.     DB    CR,LF,0
  1266. ;
  1267. ;            Loop through directory entries
  1268. dirlp:
  1269.     push    b        ;Save no of entries remaining
  1270.     MOV    A,M        ;Get entry status
  1271.     ORA    A        ;Deleted?
  1272.     JNZ    nyet        ;Yes - skp to next
  1273.     LDA    MEMNAM        ;Do we have member name on command line?
  1274.     ORA    A
  1275.     JZ    DISPM        ;No - display member name routine
  1276. ;
  1277. ;        See if this is the requested member
  1278. ;
  1279.     mvi    b,12        ;Length of names + 00H in front
  1280.     lxi    d,memfcb
  1281.     call    cpstr        ;Compare names
  1282.     jz    found
  1283.     jmp    nyet
  1284. ;
  1285. ;        Display rather than look for the member
  1286. ;
  1287. DISPM:    mvi    b,11        ;Length of names
  1288.     push    h
  1289.     inx    h        ;Step to actual name
  1290. DSPMLP:
  1291.     mov    a,m
  1292.     call    CO        ;Display one char
  1293.     inx    h
  1294.     dcr    b        ;Reduce count remaining
  1295.     jz    nmend        ;end of name
  1296. ;
  1297.     ENDIF
  1298. ;
  1299.     IF    LIBRARY AND NOT OSBORNE
  1300. ;                (Bypass for Ozzys narrow screen)
  1301.     mov    a,b
  1302.     cpi    3        ;only 3 more?
  1303.     jnz    DSPMLP        ;No -
  1304.     mvi    a,'.'        ;Yes - put out dot
  1305.     call    CO
  1306. ;
  1307.     ENDIF
  1308. ;
  1309.     IF    LIBRARY 
  1310.     jmp    DSPMLP        ;Go for next char
  1311. ;
  1312.         ;Have now displayed member name
  1313. nmend:
  1314. ;                In later versions multiple across
  1315.     lxi    h,namexc    ;Max no of names across sofar
  1316.     mov    a,m
  1317.     inx    h        ;Step to names across sofar
  1318.     inr    m        ;Count current
  1319.     cmp    m        ;Over max?
  1320.     jnc    notmax        ;not yet
  1321.     mvi    m,0        ;Yes - reset
  1322.     call    CDISP
  1323.     DB    CR,LF,0
  1324.     jmp    nyet1
  1325. notmax:
  1326.     call    CDISP
  1327.     ENDIF
  1328.  
  1329.     IF    LIBRARY AND NOT OSBORNE
  1330.     DB    ' '
  1331.     ENDIF
  1332.  
  1333.     IF    LIBRARY
  1334.     DB    '| ',0
  1335. nyet1:
  1336.     POP    H        ;Reset to start of this entry
  1337. ;            
  1338. nyet:
  1339.     lxi    b,20h        ;Length of each entry
  1340.     dad    b        ;Step to next
  1341.     pop    b        ;Get entry count (remaining)
  1342.     dcr    b
  1343.     jnz    dirlp        ;More members
  1344.     LDA    MEMNAM        ;Do we have member name on command line?
  1345.     ORA    A
  1346.     JZ    EXIT        ;if not, we have shown dir, now exit
  1347.     call    CDISP
  1348.     db    'Not in LBR',cr,lf,0
  1349.     jmp    EXIT        ;and show the poor schmuck the directory
  1350. ;
  1351. ;            Found the member name
  1352. found:
  1353.     pop    b        ;Clear stack
  1354.     lxi    d,12
  1355.     dad    d
  1356.     push    h        ;save pointer for now,
  1357.     inx    h        ;point to size
  1358.     inx    h
  1359.     mov    a,m        ;get low byte
  1360.     inx    h
  1361.     mov    h,m
  1362.     mov    l,a
  1363.     ora    h        ;if a=0 then file is 0k
  1364.     jz    nullen        ;go complain
  1365.     xthl            ;get pointer back, save size
  1366.     mov    a,m        ;get file address
  1367.     inx    h
  1368.     mov    h,m
  1369.     mov    l,a
  1370.     SHLD    SCZERO        ;Save as first file sector
  1371.     POP    D        ; & get size back
  1372.     DAD    D        ;Convert to last sector no (inclusive)
  1373.     SHLD    SCLAST
  1374.     ENDIF
  1375. ;
  1376.     IF    LIBRARY AND SQUEEZE
  1377.     LDA    SQFLG        ;Get SQ flag in case of double squeeze
  1378.     ORA    A
  1379.     JZ    NOLBSQ        ;Ok, library itself not squeezed
  1380.     CALL    CDISP
  1381.     DB    'unSQ LBR',CR,LF,0
  1382.     JMP    EXIT
  1383. NOLBSQ:
  1384.     CALL    CHKSQ        ;Check if  member squeezed
  1385.     ENDIF
  1386. ;
  1387.     IF    LIBRARY
  1388.     CALL    FILBF0        ;Refill buffer, now for member
  1389. ;                 (FILBUF handles member offset in library)
  1390.     ret
  1391. ;
  1392. ;            ;Member is empty
  1393. nullen:
  1394.     CALL    CDISP
  1395.     DB    'Empty',CR,LF,0
  1396.     JMP    EXIT
  1397.     ENDIF
  1398. ;
  1399. ;            Get input if any
  1400. GETIN:
  1401.     MVI    C,6        ;direct console I/O
  1402.     MVI    E,0FFH        ;__set up for input
  1403.     CALL    BDOS        ;Get char
  1404.     RET
  1405. ;
  1406. ;            Compare strings HL> to DE> over <B> 
  1407. ;            <DE> and <B> are changed, <HL> kept     
  1408. cpstr:
  1409.     push    h
  1410. cp$lp:
  1411.     ldax    d
  1412.     cmp    m
  1413.     jnz    cp$ex        ;No match
  1414.     inx    d
  1415.     inx    h
  1416.     dcr    b
  1417.     jnz    cp$lp
  1418. cp$ex:
  1419.     pop    h
  1420.     ret
  1421. ;
  1422. ;            Compare <HL> to <DE>
  1423. ;             Z - equal; C - <HL> less than <DE> 
  1424. ;             if equal returns <A>=0
  1425. cmphlde:
  1426.     mov    a,h
  1427.     sub    d
  1428.     rnz
  1429.     mov    a,l
  1430.     sub    e
  1431.     ret
  1432. ;
  1433. ;            Skip blanks in input
  1434. ;
  1435. EATSP:    MOV    A,M        ;get character if there is one
  1436.     INX    H
  1437.     DCR    B        ;b=number of characters left
  1438.     RZ            ;no more characters
  1439.     CPI    SPACE        ;ignore spaces
  1440.     JZ    EATSP
  1441.     DCX    H        ;Step back to 1st non-blank
  1442.     INR    B
  1443.     ORA    A        ;Force NZ
  1444.     RET
  1445. ;
  1446. ;            Skip name in input
  1447. ;
  1448. FILNAM:    MOV    A,M        ;get characters in file name
  1449.     INX    H
  1450.     DCR    B        ;b=number of characters left
  1451.     RZ            ;only file name in tail
  1452.     CPI    SPACE        ;wait for next space
  1453.     JNZ    FILNAM
  1454.     ORA    A        ;Force NZ
  1455.     RET            ;Blank
  1456. ;
  1457. ;            Move from HL> to DE> over <B>
  1458. ;
  1459. MOVE:
  1460.     MOV    A,M
  1461.     STAX    D
  1462.     INX    H        ;Step to next source
  1463.     INX    D        ; & destination
  1464.     DCR    B        ;Reduce count (00=256)
  1465.     JNZ    MOVE
  1466.     RET
  1467. ;
  1468. ;
  1469.     IF    SQUEEZE
  1470. *******************************************************
  1471. * USQ support code                      *
  1472. * 10/12/83 by Dave Rand                      *
  1473. *******************************************************
  1474. ;
  1475. ;            Check for SQ file, init tree if so
  1476. CHKSQ:
  1477. ;            Initialize
  1478.     xra    a
  1479.     mov    l,a
  1480.     mov    h,l        ;clear <hl>
  1481.     STA    SQFLG        ;Make sure not set as squeezed yet 
  1482.     sta    SQEOF        ; end of file on SQ
  1483.     sta    SQREWD        ;Clear "rewinding" SQ file 
  1484.     sta    bitlft        ;force init char read
  1485.     sta    rcnt        ;and zero repeats
  1486.     sta    FCBCRR+2    ; and overflow
  1487.     shld    numvals        ;Clear # nodes
  1488.     ENDIF
  1489. ;
  1490.     IF    SQUEEZE AND LIBRARY
  1491.     LHLD    SCZERO        ;Get 1st sector for member
  1492.     SHLD    NXTSEC        ;& save as next sector
  1493.     ENDIF
  1494. ;
  1495.     IF    SQUEEZE
  1496.     shld    FCBCRR        ;Clear next record
  1497.     lxi    h,SQBUF        ;Set to input (squeezed) buffer 
  1498.     shld    inbufs
  1499.     shld    inbufu
  1500.     lxi    d,128
  1501.     dad    d
  1502.     shld    SQBUFE        ;Force exit on full buff aft 1 sect
  1503. ;                 causes the SQ buffer to contain
  1504. ;                 sectors 1+ only (not zero),
  1505. ;                 normally fine since sector 0 contains only
  1506. ;                 header info. Sector 0 will be reread
  1507. ;                 if contains data and needed  
  1508. ;        Read and validate signature word
  1509.     call    getw        ;Read  1st word in file
  1510.     lxi    d,sqsign    ;Get expected value
  1511.     call    cmphlde
  1512.     rnz
  1513.     mvi    a,1
  1514.     STA    SQFLG        ;Yes - set flag
  1515.     lhld    0006        ;Get top of memory
  1516.     lxi    d,sqbuf+100H*128 ;Limit buffer to max 100H
  1517.     call    cmphlde        ; sectors (FILBUF uses 8 bit count <B>)
  1518.     JC    toplow        ;use top
  1519.     xchg            ;use limit 
  1520. toplow:
  1521.     shld    SQBUFE        ;& store as full address 
  1522.     call    namlp        ;Skip past name
  1523.     call    usqtbl        ;Validate & load decoding tree
  1524.     jz    oak        ;tree ok
  1525.     call    CDISP
  1526.     db    cr,lf,'Bad SQ tree',cr,lf,0
  1527.     jmp    EXIT
  1528. oak:
  1529.     lxi    h,SQMAP+2    ;Point to 1st entry 
  1530.     shld    SQMAP        ;Set to 1at entry in SQ mapper
  1531.     ret
  1532. ;
  1533. ;            Read & save checksum
  1534. rdchks:
  1535.     call    getw        ;get cksum, and store
  1536.     shld    filchks
  1537.     ret
  1538. ;            Read & skip name
  1539. namlp:    call    getc        ;Loop to skip name
  1540.     jnz    erext        ;I/O error or unexpected EOF
  1541.     ora    a
  1542.     jnz    namlp        ;Not yet end of name
  1543.     ret
  1544. ;
  1545. ;            Load decoding tree
  1546. ;            This version uses 1 byte abslute node indices
  1547. ;            (1-ffH) and is thus limited to 255 nodes and 255
  1548. ;            characters represented in the squeezed file.
  1549. ;            (All different characters present in the original
  1550. ;            file as well as any added through run encoding.
  1551. ;            Runs of 3 or more consecutive identical characters
  1552. ;            are encoded as char, DLE, count, where count
  1553. ;            is a one byte field 00 - FFH) 
  1554. ;
  1555. usqtbl:
  1556.      call    getw        ;Get no of nodes
  1557.     mov    a,h
  1558.     ora    l
  1559.     jz    nzexit        ;Null tree
  1560.     shld    numvals
  1561.     mov    a,h        ;Max 257, 256 char & spec eof
  1562. ;                in this version allow for only 256
  1563. ;                diff codes, every ASCII and non-ASCII
  1564. ;                char would have to be present, or
  1565. ;                run repeat counts 128-255 (every one)
  1566.     ora    a        ;H/o byte should be zero
  1567.     jnz    nzexit
  1568.     lxi    d,SQTREE    ;Set to decoding tree
  1569. nodelp:    shld    nxtadr        ;Save no of nodes
  1570.     mov    a,h
  1571.     ora    l
  1572.     rz            ;Done all nodes
  1573.     call    cvnode        ;get node, falg byte in <H>,
  1574. ;                 index/char in <L>
  1575.     push    h
  1576.     call    cvnode        ;get second child/char
  1577.     pop    b
  1578.     mov    a,b
  1579.     ral            ;Shift flags to 8, 4 posns 
  1580.     ora    h        ;Combine in 1st child flags 
  1581.     xchg            ;HL> SQTREE, <A>,<C>,<E> node 
  1582.     mov    m,a        ;Store flags in table
  1583.     inx    h
  1584.     mov    m,c
  1585.     inx    h
  1586.     mov    m,e
  1587.     inx    h
  1588.     xchg            ;DE> SQTREE
  1589.     lhld    nxtadr        ;Nodes remaining
  1590.     dcx    h
  1591.     jmp    nodelp
  1592. ;            Get encoded node
  1593. ;            Our nodes contain 3 bytes:
  1594. ;            - flag byte,
  1595. ;            - left child index/char
  1596. ;            - right child index/char
  1597. ;            Nodes on input are 4 bytes,
  1598. ;            with each half containing
  1599. ;            an index (1-100h) or character,
  1600. ;            where characters are encoded as
  1601. ;            negative values -(char+1)
  1602. ;            Eof is encoded as -(100h+1)
  1603. cvnode:
  1604.     push    d
  1605.     call    getw        ;Get word, chld ptr or char
  1606.     pop    d
  1607.     mov    a,h
  1608.     ora    a
  1609.     rz            ;Child index, <H>=0,<L>=index
  1610.     mov    a,l
  1611.     cma
  1612.     mov    l,a        ;convert char to reg form
  1613.     mov    a,h        ;get h/o byte again
  1614.     cma
  1615.     inr    a        ;Conv to 1 if char, 2 if EOF
  1616.     mov    h,a
  1617.     cpi    1        ;Was that reg char?
  1618.     rz            ;Yes - complete
  1619.     adi    3        ;No convert EOF flag to 0100
  1620.     mov    h,a
  1621.     ret
  1622.  
  1623. ;            Exit with NZ flag
  1624. nzexit:
  1625.     mvi    a,2        ;tree error
  1626.     ora    a        ;Set NZ flag
  1627.     ret
  1628. ;
  1629. ;            Fill output buffer (unsqueezed char)
  1630. ;
  1631. FILUSQ:
  1632.     lda    SQREWD        ;Rewinding SQ input?
  1633.     ora    a
  1634.     jz    norewd        ;No
  1635. ;            Reload SQ buffer
  1636.     lhld    inbufs
  1637.     push    h        ;getrf resets
  1638.     call    getrf        ;Yes - reload buffer & get 1st 8 bits
  1639.     pop    h
  1640.     shld    inbufs        ;Set to first data byte to use
  1641. badj:
  1642.     mov    c,a
  1643.     lda    bitlft        ;Get preset 1st wanted bit no
  1644.     mov    c,a
  1645.     mvi    a,8
  1646.     sub    b        ; Calc adjmt reqd  
  1647. badjlp:
  1648.     dcr    a
  1649.     jz    badjfn        ; bit adjust finished
  1650.     mov    b,a
  1651.     mov    a,c
  1652.     rrc
  1653.     mov    c,a
  1654.     mov    a,b
  1655.     jmp    badjlp
  1656. badjfn:
  1657.     sta    bitbuf
  1658.     xra    a
  1659.     sta    SQREWD        ; & clear rewind flag
  1660. norewd:
  1661.     lxi    h,DSKBUF    ;reset buffer pointer
  1662.     xra    a
  1663. buflp:
  1664.     shld    nxtadr        ;Save as next byte in buffer
  1665.     rnz            ;End of file (NZ flag)
  1666. ;                 as set by GETNXT rtn below
  1667.     lxi    d,SQTREE    ;Get end of input
  1668.     call    cmphlde        ;buffer full (de < hl - not full)
  1669.     jnc    full        ;buffer is full
  1670.     call    getnxt        ;Get next decoded char
  1671.                 ;No checksum taken
  1672.     lhld    nxtadr        ;Next out buffer posn
  1673.     mov    m,a        ;Store char returned, may be EOF char
  1674.     inx    h
  1675.     jmp    buflp
  1676. ;
  1677. full:
  1678.     xra    a        ;Ensure Z
  1679.     ret            ;Return on full buffer
  1680. ;
  1681. ;
  1682. ;            Get next decoded character
  1683. ;
  1684. getnxt:    lda    rcnt        ;see if in the middle of
  1685.     ora    a        ;repeat sequence...
  1686.     jz    norpt
  1687.     dcr    a        ;Yes - reduce repeat remaining 
  1688.     sta    rcnt
  1689.     lda    last        ;Get latest char again
  1690.     cmp    a
  1691.     ret            ;Return with Z for ok
  1692. norpt:    call    decode
  1693.     rnz            ;EOF? <A>=1AH
  1694.     cpi    dle        ;Run encoding flag?
  1695.     jnz    norun
  1696. ;            Handle DLE
  1697.     call    decode        ;get count
  1698.     rnz            ;EOF? (is really error after DLE)
  1699.     ora    a
  1700.     jnz    run        ;Non-zero, real run 
  1701.     mvi    a,dle        ;dle is encoded as dle,0
  1702.     cmp    a
  1703.     ret
  1704. ;            ;Run encoding found
  1705. run:    dcr    a        ;Allow for char already retnd
  1706.     dcr    a        ; & this one
  1707.     sta    rcnt        ;Keep count yet to be retd
  1708.     lda    last        ;return second time
  1709.     cmp    a
  1710.     ret
  1711. ;            ;Normal char, no run active 
  1712. norun:    sta    last        ;This may be the start
  1713.     cmp    a
  1714.     ret
  1715. ;
  1716. ;
  1717. ;            Read bits and decode to char
  1718. ;             note this version uses 3 bytes per node
  1719. ;             not 4.
  1720. ;             The first byte in each node is a flag byte
  1721. ;              .... x... - left node contains EOF marker
  1722. ;              .... .x.. - right node contains EOF marker
  1723. ;              .... ..x. - left node contains char
  1724. ;              .... ...x - right node contains char
  1725. ;
  1726. decode:    lxi    d,0        ;Set to node zero in table
  1727.     lda    bitbuf        ;Get bits from bit buffer
  1728.     mov    c,a
  1729. bitlp:    lda    bitlft        ;Any bits remaining? 
  1730.     ora    a
  1731.     jnz    nxtbit        ;Yes - go use
  1732.     push    d
  1733.     call    getc        ;No - replenish bit buffer
  1734.     jnz    badr        ;Unexpected eof
  1735.     pop    d
  1736.     mov    c,a
  1737.     mvi    a,8        ;Set as 8 bits inbuffer 
  1738. nxtbit:    dcr    a
  1739.     sta    bitlft        ;Save no of bit remaining 
  1740.     lxi    h,SQTREE    ;Set to node 0, left child ptr
  1741.     dad    d
  1742.     dad    d
  1743.     dad    d        ;Add in node no (4 bytes/node)
  1744.     mov    b,m        ;Get flag byte
  1745.     inx    h        ;Step to left child pointer
  1746.     mov    a,c        ;Get input bits 
  1747.     rrc            ;Shuffle LOW-ORDER bit to Carry
  1748.     mov    c,a
  1749.     mov    a,b        ;Get flag byte 
  1750.     jnc    getn3        ;Zero input bit,leave at left
  1751.     inx    h        ;add 1 to point to right child pointer
  1752.     add    b        ;Normalize wanted flags to .... x.x.
  1753. getn3:
  1754.     mov    e,m        ;Pick up child or char
  1755. ;                <D> should always remain zero 
  1756.     ani    1010B        ;Mask unwanted bits
  1757.     jz    bitlp        ;Reg child pointer
  1758. ;            Got to char or eof
  1759.     ani    1000B        ;End of file marker?
  1760.     jnz    goteof        ;Yes - get out with eof
  1761.     mov    a,c
  1762.     sta    bitbuf        ;Save bit buffer
  1763.     mov    a,e        ;Get decoded char (neg)
  1764.     ret
  1765. ;
  1766. ;            Exit on reg eof
  1767. goteof:
  1768.     mvi    a,eof
  1769.     ora    a
  1770.     ret
  1771. ;
  1772. ;            ;Get input word (lo/hi, unencoded)
  1773. getw:    call    getc
  1774.     jnz    badr        ;Unexpected eof
  1775.     push    psw
  1776.     call    getc
  1777.     jnz    badr        ;Unexpected eof
  1778.     mov    h,a
  1779.     pop    psw
  1780.     mov    l,a
  1781.     ret
  1782. ;
  1783. erext:
  1784. badr:    call    CDISP
  1785.     db    cr,lf,'EOF?',cr,lf,0
  1786.     jmp    EXIT
  1787. ;
  1788. ;            Get single (unencoded) char
  1789. getc:    lhld    inbufu
  1790.     xchg
  1791.     lhld    inbufs
  1792.     call    cmphlde        ;End of input buffer?
  1793.     jz    getrf        ;Yes
  1794. getc1:
  1795.     mov    a,m        ;No get next byte
  1796.     inx    h
  1797.     shld    inbufs        ;Save addr of next byte
  1798.     cmp    a
  1799.     ret
  1800. ;
  1801. ;            Refill input buffer
  1802. ;
  1803. getrf:
  1804.     lda    SQEOF        ;Is there anything else?
  1805.     ora    a
  1806.     jz    getok
  1807.     call    CDISP
  1808.     db    cr,lf,'EOF',cr,lf,0
  1809.     jmp    EXIT
  1810. getok:
  1811.     lhld    SECCNT        ;Save sector count (decoded buffer only)
  1812.     push    h
  1813.     lxi    h,SQBUF        ;Set input buffer as empty,
  1814.     shld    inbufs        ;_and start of buffer
  1815.     xchg            ;DE> buffer, next sector locn
  1816.     lhld    SQBUFE        ;End of input buffer
  1817.     shld    inbufu        ;Assume no end of file for now
  1818.     mov    a,l
  1819.     sub    e
  1820.     mov    l,a
  1821.     mov    a,h
  1822.     sbb    d        ;Calc buffer size
  1823.     mov    h,a
  1824.     dad    h        ;Convert to no of sectors
  1825.     mov    b,h        ;No of sectors to read
  1826. ;                # sectors limited to 100 max (<B>=0)
  1827.     lhld    FCBCRR        ;No of 1st sector to read
  1828.     shld    SQBSC1
  1829.     call    FILBU1        ;Read sector into SQBUF
  1830. ;                <B> no of sectors not read if eof
  1831. ;                HL> 128
  1832. ;                DE> last sector read, or after if eof
  1833.     lhld    FCBCRR        ;Get next SQ sector no
  1834.     shld    NXTSQS
  1835.     mov    a,b        ;Did we fill buffer?
  1836.     ora    a
  1837.     jz    getrf2        ;yes - no eof
  1838.     xchg            ;Eof, adjust buffer end marker
  1839.     shld    inbufu        ;Mark end of buffer used
  1840.     sta    SQEOF        ;& flag eof
  1841. ;
  1842. ;            Input buffer re-filled
  1843. getrf2:
  1844.     pop    h
  1845.     shld    SECCNT        ;Restore sector count (decoded buffer only)
  1846.     lhld    inbufu        ;Get end of buffer
  1847.     xchg
  1848.     lhld    inbufs        ;Get start of buffer
  1849.     call    cmphlde        ;Something there?
  1850.     jc    getc1        ;Yes - go for char
  1851.     jmp    erext        ;No - read past eof or empty file
  1852. ;
  1853. ;end of baseline USQ code
  1854. ;
  1855. otbufe:    dw    0        ;End of decoded char buffer
  1856. inbufs:    dw    0        ;Start of input buffer
  1857. inbufu:    dw    0        ;End of used part input buffer
  1858. SQBUFE:    dw    0        ;End of input buffer
  1859. ;
  1860. nxtadr:    dw    DSKBUF        ;Next byte in output buffer 
  1861.                 ; also used when loading tree
  1862. bitlft:    ds    1        ;No of bits left in bit buffer
  1863. rcnt:    ds    1        ;Run count remaining (DLE)
  1864. filchks:ds    2        ;Checksum read from file
  1865. last:    ds    1        ;Last reg char decoded
  1866. bitbuf:    ds    1        ;Latest 8 bits (encoded) from input file
  1867. numvals:ds    2        ;No of nodes in encodng tree
  1868.     ENDIF
  1869. ;
  1870. ;    Memory allocation
  1871. ;
  1872. SECCNT:    DW    0        ;number of sectors read into buffer
  1873. LINMAX:    DB    SCROLN        ;number of write lines on console
  1874. CHRMAX:    DB    MAXCHR-1    ;number of characters to display per line
  1875. CHRMIN:    DB    0        ;character to start displaying on line
  1876. CHRCNT:    DS    1        ;character number in line
  1877. LINCNT:    DS    1        ;line number on write or move back in buffer
  1878. TOPBUF:    DB    0        ;Top of file is now in buffer
  1879. ;                 Z - yes, NZ - no
  1880. ;
  1881.     IF    SQUEEZE
  1882. NXTSEC:    DW    0        ;Next (unsqueezed) sector not yet in BSKBUF
  1883. ;                 set (and used) only by FILSQ
  1884. SQFLG:    DB    0        ;File is squeezed
  1885. SQEOF:    DB    0        ;End of file on squeezed file
  1886. SQREWD:    DB    0        ;Flag the SQ input file is being re-read
  1887. ;                 buffer refill rtn (getrf) to set inbufs
  1888. ;                 as per offset in SQBYT, and pre-load
  1889. ;                 bit buffer. Bit buffer to be adj
  1890. ;                 as per Bitlft
  1891. SQBYT:    DW    0        ;Offset of first data byte in SQ buffer
  1892. SQBSC1:    DW    0        ;No of 1st sector in SQ buffer
  1893. NXTSQS:    DW    0        ;No of last sector in SQ buffer
  1894.     ENDIF
  1895. ;
  1896. ;
  1897.     IF    LIBRARY
  1898. namexc:    db    (MAXCHR/14)-1    ;No of directory names across display
  1899.     db    0        ;No of names so far
  1900. dirsiz:    db    0        ;# of members possible in directory
  1901. memnam    db    0        ;Member name specified on command line
  1902. SCZERO:    DW    0        ;First sector for member
  1903. SCLAST:    DW    0FFFFH        ;Last sector for member (included in member)
  1904. ;                 SCZERO and SCLAST are relative in file
  1905. LBFLG:    DB    0        ;File is a library file
  1906. memfcb:    DS    12        ;Member name here
  1907.     ENDIF
  1908. ;
  1909.     DS    60        ;stack area
  1910. STACK:    DS    2        ;old stack saved here
  1911. DSKBUF:    EQU    $        ;disk buffer area above the program
  1912. ;
  1913. ENDBUF    EQU    DSKBUF+MAXSEC*128
  1914. ;
  1915.     IF    SQUEEZE
  1916. SQTREE    EQU    ENDBUF        ;Space for SQ decoding tree
  1917. SQMAP    EQU    SQTREE+256*3
  1918. ;                Space for SQ buffer mapping table
  1919. ;                contains sq sect #, sq byte & bit offset
  1920. ;                for every time DSKBUF was filled
  1921. ;                1st entry contains index to latest mapping
  1922. ;                triplet
  1923. ;                To handle run compr straddling buffer end,
  1924. ;                should also store rcnt & last 
  1925. SQBUF    EQU    SQMAP+100*4    ;(allows for 100 8k buffers)
  1926. ;                Input (squeezed) buffer
  1927. ;                Runs up to top of free mem 
  1928.     ENDIF
  1929. ;
  1930.     END    TPA
  1931.