home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / ENTERPRS / CPM / UTILS / A / BIOSR4.ARC / CXIO.ASM < prev    next >
Assembly Source File  |  1987-04-26  |  24KB  |  1,279 lines
  1. ; code in this module was modified to set the screen up for 80 col 
  2. ; automaticly, all 40 column code has been deleted.  the label NULL40 is
  3. ; still maintained in the device table as removing it would change
  4. ; the subsequent device numbers, affecting the use of RS-232 (it would
  5. ; require rewrites of all modem programs)
  6. ; code at the label ?rlccp has been added to reset the feel and repeat
  7. ; rate at every warm start, this corrects problems that arise after 
  8. ; terminating a modem program. 
  9. ;
  10. ; Code has been added to allow setting the cursor flash rate and shape,
  11. ; set the temporary drive, and the drive search chain.
  12. ; 
  13. ; Code has been added to require a password to be entered before the
  14. ; system finishes initialization, 3 trys are allowed, the system locks
  15. ; up if you fail all three.
  16. ;
  17. ; A label has been added to allow the 6551 init code to install baud
  18. ; rates based on the value in DEVTBL.
  19. ;
  20. ; User assumes _ALL_ liability for the use of this module. Original 
  21. ; Copyright is still maintained by Commodore
  22. ;
  23. ; Code to set cursor and drive chain; Copyright April 26, 1987 by
  24. ;    James W. Waltrip IV
  25. ;
  26.     title    'C128 BIOS, main I/O and sys functions    26 April 87'
  27.  
  28. ;
  29. ;    This module contains CXIO,CXINIT,CXMOVE and CXTIME.
  30. ;
  31.     maclib    cpm3
  32.  
  33.     maclib    z80
  34.  
  35.     maclib    cxequ
  36.  
  37.     maclib    modebaud
  38.  
  39. ;**********************************************************
  40.  
  41.     extrn    repeat            ; repeat rate
  42.  
  43. repeat$amt    equ    3
  44.  
  45.     extrn    delay            ; delay before repeat
  46.  
  47. delay$amt    equ    24
  48.  
  49.  
  50. printnum    equ    08        ; printer device to init
  51.                     ; other printer is 010h (16 decimal)
  52.  
  53. pass        equ    false        ; set to 'false' if password
  54.                      ;protection not wanted
  55.  
  56. pass$word    macro
  57.  
  58.     db    'PASS'                ; password is defined here
  59. ;                                       ; if using lower case letters
  60. ;                    ; use the HEX values rather than
  61. ;                    ; the characters themselves
  62. ;                    ; ie.-> 061h  instead of 'a'
  63.         endm
  64.  
  65. ;*************************************************************
  66.     public    ?init,?ldccp,?rlccp
  67.  
  68.     public    ?user,?di$int
  69.  
  70.     extrn    ?sysint
  71.  
  72. bdos    equ    5    
  73.     
  74.     extrn    @civec,@covec,@aivec,@aovec,@lovec
  75.     extrn     ?bnksl
  76.  
  77.     public    ?cinit,?ci,?co,?cist,?cost
  78.     public    @ctbl
  79.     extrn    ?kyscn
  80.  
  81. ; Utility routines in standard BIOS
  82.     extrn    ?wboot        ; warm boot vector
  83.     extrn    ?pmsg        ; print message @<HL> up to 00
  84.                 ; saves <BC> & <DE>
  85.     extrn    ?pdec        ; print binary number in <A> from 0 to 99.
  86.     extrn    ?pderr        ; print BIOS disk error header
  87.     extrn    ?conin,?cono    ; con in and out
  88.     extrn    ?const        ; get console status
  89.  
  90.     extrn    @hour,@min,@sec,@date,?bnksl
  91.     public    ?time
  92.  
  93.     page
  94. ;
  95. ;    keyboard scanning routine 
  96. ;
  97.     extrn    ?get$key,?int$cia
  98.     extrn    Fx$V$tbl
  99. ;
  100. ;    links to 80 column display
  101. ;
  102.     extrn    ?out80,?int80
  103.  
  104.     extrn    ?pt$i$1101,?pt$o$1,?pt$o$2
  105.  
  106. ;
  107. ;    bios8502 function routines
  108. ;
  109.     public    ?fun65
  110.  
  111. ;
  112. ;
  113. ;
  114.     public    X6551$baud
  115.     extrn    ?int65,?in65,?ins65,?out65
  116.     extrn    @drcha,@drchb,@drchc,@drchd,@tpdrv
  117.  
  118.  
  119.     DSEG
  120. ?fun65:
  121.     sta    vic$cmd            ; save the command passed in A
  122.  
  123. fun$di$wait:
  124.     lda    RS232$status
  125.     ani    01000010b        ; transmitting or receiving ?
  126.     jrnz    fun$di$wait        ; yes, wait for int to clean up
  127.     di
  128.     lda    force$map        ; get current MMU configuration
  129.     push    psw            ; save it
  130.     sta    io$0            ; make I/O 0 current
  131.     
  132.     lxi    d,1            ; D=0,  E=1
  133.     lxi    b,page$1$h
  134.     outp    d
  135.     dcr    c
  136.     outp    e            ; page 1, 0-1
  137.     dcr    c
  138.     outp    d
  139.     dcr    c
  140.     outp    d            ; page 0, 0-0
  141.     call    enable$6502+6        ; go run the 8502
  142.     mvi    c,low(page$1$h)
  143.     outp    e
  144.     dcr    c
  145.     outp    e            ; page 1, 1-1
  146.     dcr    c
  147.     outp    e
  148.     dcr    c
  149.     outp    d            ; page 0, 1-0
  150.  
  151.     pop    psw            ; recover the MMU config.
  152.     sta    force$map        ; restore it
  153.     ei                ; turn interrupts back on
  154.     lda    vic$data        ; get command results
  155.     ora    a            ; set the zero flag if A=0
  156.     ret
  157.  
  158. ?di$int:
  159.     push    psw
  160. di$int$1:
  161.     lda    RS232$status
  162.     ani    01000010b        ; transmitting or receiving ?
  163.     jrnz    di$int$1        ; yes, wait for int to clean up
  164.     pop    psw
  165.     di
  166.     ret
  167.  
  168.     page
  169. ;
  170. ;    set up the MMU for CP/M Plus
  171. ;
  172.     DSEG            ; init done from banked memory
  173. ?init:
  174.     mvi    a,3eh            ; force MMU into I/O space
  175.     sta    force$map        ;
  176.     lxi    h,mmu$table+11-1    ; table of 11 values
  177.     lxi    b,mmu$start+11-1    ; to to MMU registers
  178.     mvi    d,11            ; move all 11 bytes to the MMU
  179.  
  180. init$mmu$loop:
  181.     mov    a,m
  182.     outp    a
  183.     dcx    h
  184.     dcx    b
  185.     dcr    d
  186.     jrnz    init$mmu$loop
  187.  
  188.     mvi    a,1            ; enable track and sector status
  189.     sta    stat$enable        ; on the status line
  190.  
  191. ;    mvi    a,1h            ; no parity, 8 bits, 1 stop bit    
  192.     sta    XxD$config
  193.  
  194.     lxi    h,Fx$V$tbl
  195.     shld    key$FX$function
  196. ;*********************************************************
  197. ;
  198. ; install I/O assignments
  199. ;
  200.     lxi    h,4000h            ; 80 and 40 column drivers
  201.     shld    @covec
  202.     mvi    h,80h
  203.     shld    @civec            ; assign console input to keys
  204.     mvi    h,printnum        ; device # 4
  205.     shld    @lovec            ; assign printer to LPT:
  206.     mvi    h,00h
  207.     shld    @aivec
  208.     shld    @aovec            ; assign rdr/pun port
  209.  
  210. ;
  211. ; init SCB
  212. ;
  213.     mvi    a,4            ; The following instr. set up the
  214.     sta    @drcha            ; Drive Serch Chain, and the Temp. 
  215.     sta    @tpdrv            ; Drive.  This replaces the SETDEF
  216.     mvi    a,1            ; method of setting this up.
  217.     sta    @drchb
  218.     mvi    a,2
  219.     sta    @drchc
  220.     mvi    a,3
  221.     sta    @drchd
  222. ;
  223. ; Where are the bytes for COM/SUB execution?
  224. ;
  225. ; 80 Col. screen cursor attributes
  226. ;
  227.     lxi    b,0D600h    ; 80 col cmd reg
  228.     mvi    a,010        ; reg 10 of 8563 (cursor type, start scan line)
  229.     outp    a        ; tell 8563 you want reg 10
  230. lx1:                
  231.     inp    a        ; get status
  232.     jp    lx1        ; loop until status good
  233.     lxi    b,0D601h    ; 80 col data reg
  234.     mvi    a,01100011b    ; slow cursor, scan line 4 lines from top
  235.     outp    a
  236. ;
  237.     lxi    b,0D600h
  238.     mvi    a,011        ; reg 11 of 8563 (cursor end scan line)
  239.     outp    a
  240. lx2:
  241.     inp    a
  242.     jp    lx2
  243.     lxi    b,0D601h
  244.     mvi    a,00000101b    ; Scan line 5 lines from top
  245.     outp    a
  246.     lxi    b,0D011h    ; Vic controll reg 1
  247.     mvi    a,00001000b    ; turn off Vic
  248.     outp    a
  249. ;
  250.     page
  251. ;
  252. ; print sign on message
  253. ;
  254.     call    prt$msg            ; print signon message
  255.     db    'Z'-'@'            ; home and clear screen (to BG color)
  256.     db    esc,esc,esc,21h,esc,esc,esc,30    ; black back, white char
  257.     db    'Z'-'@'
  258.     db    esc,'=',32+2,32+37,'CP/M 3.0'
  259.     db    esc,'=',32+3,32+31,'On the Commodore 128 '
  260.     db    esc,'=',32+4,32+22,'6 Dec 85 System -*- Modified 26 Apr 87'
  261.     db    cr,lf,lf,lf,lf,0
  262. ;;*********************************************************
  263.     page
  264.  
  265. ;
  266. ;
  267.     mvi    a,-1            ; set block move to NORMAL mode
  268.     sta    source$bnk
  269. ;
  270. ;    install mode 2 page vectors
  271. ;
  272.     mvi    a,JMP
  273.     sta    INT$vector        ; install a JMP at vector location
  274.     lxi    h,?sysint
  275.     shld    INT$vector+1        ; install int$handler adr
  276. ;
  277. ; A software fix is  required for the lack of hardware to force the
  278. ; LSB of the INT vector to 0. If the bus floats INT VECT could be
  279. ; read as 0FFh; thus ADRh=I (I=0FCh) ADRl=FF for first read, and
  280. ; ADRh=I+1 ADRl=00 for second, to ensure that control is retained
  281. ; 0FD00h will also have FDh in it.
  282. ;
  283.     lxi    h,int$block        ; FC00h
  284.     lxi    d,int$block+1        ; FC01h
  285.     lxi    b,256-1+1        ; interrupt pointer block
  286.     mvi    m,INT$vector/256    ; high and low are equal (FD)
  287.     ldir
  288.     mvi    a,INT$block/256
  289.     stai                ; set interrupt page pointer
  290.     im2                ; enable mode 2 interrupts
  291.  
  292.     page
  293. ;
  294. ;
  295.     mvi    a,vicinit        ; null command just to setup BIOS8502
  296.     call    ?fun65
  297. ;
  298. ;
  299. ;
  300.     lda    sys$freq        ; 0=60Hz 0FFh=50Hz
  301.     ani    80h            ; 0=60Hz 080h=50Hz
  302.     mov    l,a            ; save in L
  303.     lxi    b,cia$1+0eh        ; point to CRA
  304.     inp    a            ; get old config
  305.     ani    7fh            ; clear freq bit
  306.     ora    l            ; add in new freq bit
  307.     outp    a            ; set new config
  308.  
  309.     mvi    c,8            ; start RTC
  310.     outp    a
  311.  
  312.     lxi    h,date$hex
  313.     shld    @date            ; set date to system data
  314.  
  315. ;
  316. ;    setup the sound variables
  317. ;
  318.     lhld    key$tbl
  319.     lxi    d,58*4
  320.     dad    d
  321.     mov    e,m
  322.     inx    h
  323.     mov    d,m
  324.     inx    h
  325.     xchg
  326.     shld    sound1            ; H=SID reg 24, L=SID reg 5
  327.     xchg
  328.     mov    e,m
  329.     inx    h
  330.     mov    d,m
  331.     xchg
  332.     shld    sound2            ; H=SID reg 6, L=SID reg 1
  333.     lxi    h,9
  334.     dad    d
  335.     mov    e,m
  336.     inx    h
  337.     mov    d,m
  338.     xchg
  339.     shld    sound3            ; H=SID reg 4 then L=SID reg 4 
  340. ;
  341. ;    set-up key click sound registers
  342. ;
  343.     lxi    b,sid+7
  344.     lxi    h,0040h
  345.     outp    l            ; (sid+7)=40h
  346.     inr    c
  347.     outp    l            ; (sid+8)=40h
  348.     mvi    c,low(sid+12)
  349.     outp    h            ; (sid+12)=0  Attack=2ms, Decay=6ms
  350.     inr    c
  351.     outp    h            ; (sid+13)=0  Sustain=0,  Release=6ms
  352.     mvi    a,6
  353.     sta    tick$vol        ; set keyclick volumn level
  354.  
  355. ;**********************************************
  356. ;  Password protection routine
  357. ;**********************************************
  358. ;
  359. if    pass
  360. ;
  361.     mvi    a,0
  362.     sta    count
  363. loop1:
  364.     lda    count
  365.     inr    a
  366.     sta    count
  367.     cpi    4
  368.     jnz    over
  369.     call    prt$msg
  370.     db    cr,lf,lf,esc,'G2','Password Error,  System Aborting....',0
  371. there:
  372.     jmp    there
  373. over:
  374.     lxi    h,cmp$string
  375.     push    h
  376.     call    prt$msg
  377.     db    cr,lf,'Password: ',0
  378. lz1:
  379.     call    key$board$in
  380.     pop    h
  381.     cmp    m
  382.     jnz    loop1
  383.     inx    h
  384.     push    h
  385.     mov    a,m
  386.     cpi    0
  387.     jnz    lz1
  388.     call    prt$msg
  389.     db    cr,lf,lf,0
  390. ;
  391. endif
  392. ;
  393.     ret
  394. ;
  395. if    pass
  396. ;
  397. cmp$string:
  398.     pass$word        ;password macro
  399.     db    0
  400. count:
  401.     ds    1
  402. ;
  403. endif
  404. ;
  405. ;***************************************************
  406. ;
  407.  
  408. mmu$table:
  409.     mmu$tbl$M
  410.  
  411.     page
  412. ;
  413. ;
  414. ;
  415.     CSEG
  416. prt$msg:
  417.     xthl
  418.     call    ?pmsg
  419.     xthl
  420.     ret
  421.  
  422.  
  423. ;
  424. ;    placed in common memory to keep IO from stepping on this code
  425. ;        always called from bank 0
  426. ;
  427.     CSEG
  428. read$d505:
  429.     sta    io$0            ; enable MMU (not RAM)
  430.     lxi    b,0d505h
  431.     inp    a            ; read 40/80 column screen
  432.     sta    bank$0            ; re-enable RAM
  433.     ret
  434.  
  435.     page
  436. ;
  437. ;
  438. ;
  439.     DSEG
  440. init$RS232:
  441.     di
  442.  
  443.     xra    a
  444.     sta    RS232$status
  445.     lxi    h,RxD$buf$count        ; clear the count
  446.     mvi    m,0
  447.     inr    l            ; point to RxD$buf$put
  448.     mvi    m,low(RxD$buffer)
  449.     inr    l            ; point to RxD$buf$get
  450.     mvi    m,low(RxD$buffer)
  451.     lxi    h,NTSC$baud$table
  452.  
  453. ;***************************************
  454. ; code to check for NTSC or PAL removed here, system now assumes 
  455. ; that you are using a north american 128 at 60 hz.
  456. ; ***************************************
  457.  
  458. use$NTSC:
  459.     lda    RS232$baud
  460.     cpi    baud$1200        ; baud rate less then 1200 baud
  461.     jrc    baud$ok            ; yes, go set it
  462.     mvi    a,baud$1200        ; no, 1200 baud is the max
  463.     sta    RS232$baud        ; (change to 1200 baud)
  464.  
  465. baud$ok:
  466.     mov    e,a
  467.     mvi    d,0
  468.     dad    d            ; +1X
  469.     dad    d            ; +1X
  470.     dad    d            ; +1X = +3X
  471.     mov    e,m
  472.     inx    h
  473.     mov    d,m
  474.     inx    h            ;
  475.     mov    a,m            ; get rate #
  476.     sta    int$rate        ;
  477.  
  478.     lxi    b,CIA1+timer$b$low    ;
  479.     outp    e            ;
  480.     inr    c            ; point to timer$b$high
  481.     outp    d            ;
  482.  
  483.     mvi    a,11h            ;
  484.     mvi    c,CIA$ctrl$b        ; turn on timer B
  485.     outp    a            ;
  486.  
  487.     lxi    b,CIA2+data$b        ; setup user port for RS232
  488.     inp    a            ; get old data
  489.     ori    6            ; set CTS and DTR
  490.     outp    a            ; update it
  491.     ei
  492.     ret
  493.  
  494.     page
  495. ;
  496. ;    NTSC rates (1.02273 MHz)
  497. ;
  498. NTSC$baud$table:
  499.     dw    6818            ; no baud rate     (6666.47)
  500.     db    1
  501.     dw    6818            ; 50    6666.7us (6666.47)
  502.     db    1
  503.     dw    4545            ; 75    4444.4us (4443.99)
  504.     db    1
  505.     dw    3099            ; 110    3030.3us (3030.13)
  506.     db    1
  507.     dw    2544            ; 134    2487.6us (2487.46)
  508.     db    1
  509.     dw    2273            ; 150    2222.2us (2222.48)
  510.     db    2
  511.     dw    1136            ; 300    1111.1us (1110.75)
  512.     db    3
  513.     dw    568            ; 600     555.6us ( 555.38)
  514.     db    6
  515.     dw    284            ; 1200     277.8us ( 277.69)
  516.     db    12
  517.  
  518. ;****************************************************
  519. ; PAL baud table removed from here (redundant, as it is not checked for
  520. ; or used)
  521. ;******************************************************
  522.  
  523.     page
  524. ;
  525. ;
  526. ;
  527. out$RS232:
  528.     lda    RS232$status
  529.     ani    80h
  530.     jrnz    out$RS232
  531.     mov    a,c
  532.     sta    xmit$data        ; get character to send in A
  533.     lxi    h,RS232$status
  534.     setb    7,m            ; set Xmit request bit
  535.     ret
  536.  
  537. ;
  538. ;
  539. ;
  540. out$st$RS232:
  541.     lda    RS232$status
  542.     ani    80h            ; bit 8 set if busy
  543.     xri    80h            ; A cleared if busy (=80h if not)
  544.     rz
  545.     ori    0ffh            ; A=ff if ready (not busy)
  546.     ret
  547.  
  548. ;
  549. ;
  550. ;
  551. in$RS232:
  552.     lda    RS232$status
  553.     ani    1
  554.     jrz    in$RS232
  555.     lda    recv$data
  556.     lxi    h,RS232$status
  557.     res    0,m
  558.     ret
  559.  
  560. ;
  561. ;
  562. ;
  563. in$st$RS232:
  564.     lda    RS232$status
  565.     ani    1
  566.     rz
  567.     ori    0ffh            ; set data ready (-1)
  568.     ret
  569.  
  570.     page
  571. ;
  572. ;    this routine is used to provide the user with a method
  573. ;    of interfacing with low level system functions
  574. ;
  575.     CSEG
  576. ;
  577. ;    input:
  578. ;        all registers except HL and A are passed to function
  579. ;
  580. ;    output:
  581. ;        all resisters from function are preserved
  582. ;
  583. ?user:
  584.     shld    user$hl$temp
  585.     xchg
  586.     shld    de$temp            ; save DE for called function
  587.  
  588.     mov    e,a            ; place function number in E
  589.     mvi    a,num$user$fun-1    ; last legal function number
  590.  
  591.     call    vector            ; function
  592. usr$tb:    dw    read$mem$0        ; 0
  593.     dw    write$mem$0        ; 1
  594.     dw    ?kyscn            ; 2
  595.     dw    do$rom$fun        ; 3  (L=function #)     
  596.     dw    do$6502$fun        ; 4  (L=function #)
  597.     dw    read$d505        ; 5  returns MMU reg in A
  598.     dw    code$error        ; not 0 to 5 ret version number in HL
  599.  
  600. num$user$fun    equ    ($-usr$tb)/2
  601.  
  602.     page
  603. ;
  604. ;    address in DE is read and returned in C
  605. ;    A=0 if no error
  606. ;
  607.     DSEG
  608. read$mem$0:
  609.     ldax    d            ; read location addressed by DE
  610.     mov    c,a            ; value returned in C
  611.     xra    a            ; clear error flag
  612.     ret
  613.  
  614. ;
  615. ;    address in DE is written to with value in C
  616. ;    A=0 if no errors
  617. ;
  618. write$mem$0:
  619.     mvi    a,-1            ; get error flag and 0ffh value
  620.     cmp    d            ; do not allow write from FF00 to FFFF
  621.                     ;   this is 8502 space, MMU direct reg.
  622.     rz
  623.     mov    a,d
  624.     cpi    10h            ; do not allow write from 0000 to 0FFF
  625.                     ;   this is ROM space
  626.     mvi    a,-1            ; get error flag
  627.     rc                ; return if 00h to 0fh
  628.     mov    a,c
  629.     stax    d
  630.     xra    a            ; clear error flag 
  631.     ret
  632.  
  633.     page
  634. ;
  635. ;    This is the function code entry point for direct execution
  636. ;    of driver functions. If the MSB of the function number is
  637. ;    set, the 40 column driver is used; else the 80 column drive 
  638. ;    is used.
  639. ;
  640. do$rom$fun:
  641.     lhld    user$hl$temp        ; get HL (L=fun #)
  642.  
  643.     mvi    a,7eh            ; only allow even functions
  644.     ana    l
  645.     cpi    79h
  646.     jrc    no$hl$req
  647.     lhld    @dma            ; HL will be passed in @dma by
  648.     push    h            ; ..the user
  649. no$hl$req:
  650.     mov    l,a
  651.     rst    5            ; call rom functon (RCALL) L=fun #    
  652.     ret
  653.  
  654. ;    mvi    a,7eh            ; only allow even functions
  655. ;    ana    l
  656. ;    sta    no$hl$req+1
  657. ;    cpi    79h
  658. ;    jrc    no$hl$req
  659. ;    lhld    @dma            ; HL will be passed in @dma by
  660. ;    push    h            ; ..the user
  661. ;no$hl$req:
  662. ;    will be changed to RCALL xx   RET for next release (ROM FN 7A, 7C
  663. ;        and 7E will not function with current code, they expect
  664. ;        a return address on the stack
  665. ;
  666. ;    RJMP    5Eh            ; unused function, real fun# installed
  667.                     ; ..above
  668.  
  669. do$6502$fun:
  670.     lhld    user$hl$temp
  671.     mov    a,l
  672.     jmp    ?fun65
  673. ;
  674. ;
  675. ;
  676. code$error:
  677.     lxi    h,date$hex
  678.     mvi    a,-1
  679.     ret
  680.  
  681.     page
  682. ;
  683. ;
  684. ;
  685.     CSEG
  686. ?rlccp:
  687. ;
  688. ;******************************************************************
  689.     mvi    a,01            ; sets feel, put here to set it
  690.     sta    0fd52h            ; on every warm start
  691.     mvi    a,repeat$amt        ; set at 3
  692.     sta    repeat
  693.     mvi    a,delay$amt        ; set at 24
  694.     sta    delay
  695. ;******************************************************************
  696.     lxi    h,ccp$buffer
  697.     lxi    b,0c80h
  698.  
  699. load$ccp:
  700.     sta    bank$0
  701.     mov    a,m
  702.     sta    bank$1
  703.     lxi    d,-ccp$buffer+100h
  704.     dad    d
  705.     mov    m,a
  706.     lxi    d,ccp$buffer-100h+1
  707.     dad    d
  708.     dcx    b
  709.     mov    a,b
  710.     ora    c
  711.     jrnz    load$ccp
  712.     ret
  713.  
  714.     page
  715. ;
  716. ;
  717. ;
  718.     CSEG
  719. ?ldccp:
  720.     xra    a
  721.     sta    ccp$fcb+15    ; zero extent
  722.     lxi    h,0
  723.     shld    fcb$nr        ; start at beginning of file
  724.     lxi    d,ccp$fcb
  725.     call    open        ; open file containing CCP
  726.     inr    a
  727.     jrz    no$CCP        ; error if no file...
  728.     lxi    d,0100h
  729.     call    setdma        ; start of TPA
  730.     lxi    d,128
  731.     call    setmulti    ; allow up to 16K bytes
  732.     lxi    d,ccp$fcb
  733.     call    read
  734.  
  735.     lxi    h,0100h
  736.     lxi    b,0c80h
  737.     lda    force$map
  738.     push    psw
  739.  
  740. ;
  741. ;
  742. save$ccp:
  743.     sta    bank$1
  744.     mov    a,m
  745.     sta    bank$0
  746.     lxi    d,ccp$buffer-100h
  747.     dad    d
  748.     mov    m,a
  749.     lxi    d,-ccp$buffer+100h+1
  750.     dad    d
  751.     dcx    b
  752.     mov    a,b
  753.     ora    c
  754.     jrnz    save$ccp
  755.  
  756.     pop    psw
  757.     sta    force$map
  758.     ret
  759.  
  760.  
  761.  
  762.     page 
  763. ;
  764. ;
  765. ;
  766. no$CCP:                ; here if we couldn't find the file
  767.     call    prtmsg        ; report this...
  768.     db    cr,lf,'BIOS Err on A: No CCP.COM file',0
  769.     call    ?conin        ; get a response
  770.     jr    ?ldccp        ; and try again
  771.  
  772.  
  773. ;
  774. ; CP/M BDOS Function Interfaces
  775. ;
  776.     CSEG
  777. open:
  778.     mvi    c,15        ; open file control block
  779.  
  780.     db    21h        ; lxi h,(mvi c,26)
  781. setdma:
  782.     mvi    c,26        ; set data transfer address
  783.  
  784.     db    21h        ; lxi h,(mvi c,44)    
  785. setmulti:
  786.     mvi    c,44        ; set record count
  787.  
  788.     db    21h        ; lxi h,(mvi c,20)
  789. read:
  790.     mvi    c,20        ; read records
  791.     jmp    bdos
  792.  
  793. ;               12345678901
  794. ccp$fcb        db    1,'CCP     COM',0,0,0
  795. fcb$rc        db    0
  796.         ds    16
  797. fcb$nr        db    0,0,0
  798.  
  799.  
  800.     page
  801. ;
  802. ;    CXIO.ASM and CXEM.ASM
  803. ;
  804. ;==========================================================
  805. ;        ROUITINE TO VECTOR TO HANDLER
  806. ;==========================================================
  807. ;    CP/M IO routines    b=device : c=output char : a=input char
  808. ;
  809.     CSEG
  810. ;*********************************************************************
  811. ; code in the following vector tables has been altered to null the 40
  812. ; column screen
  813. ;--------------------------------------------------
  814.  
  815. ?cinit:                ; initialize usarts
  816.     mov    b,c
  817.     call    vector$io    ; jump with table adr on stack
  818. number$drivers:
  819.     dw    ?int$cia    ; keys
  820.     dw    ?int80        ; 80col
  821.     dw    rret          ; 40col
  822.     dw    ?pt$i$1101    ; prt1
  823.     dw    ?pt$i$1101    ; prt2
  824.     dw    ?int65        ; 6551
  825.     dw    init$RS232    ; software RS232
  826.     dw    rret        ;
  827. max$devices    equ    (($-number$drivers)/2)-1
  828.  
  829. ;
  830. ;
  831. ;
  832. ?ci:                ; character input
  833.     call    vector$io    ; jump with table adr on stack
  834.     dw    key$board$in    ; keys
  835.     dw    rret        ; 80col
  836.     dw    rret        ; 40col
  837.     dw    rret        ; ptr1
  838.     dw    rret        ; prt2
  839.     dw    ?in65        ; 6551
  840.     dw    in$RS232    ; software RS232
  841.     dw    null$input
  842.  
  843. ;
  844. ;
  845. ;
  846. ?cist:                ; character input status
  847.     call    vector$io    ; jump with table adr on stack
  848.     dw    key$board$stat    ; keys
  849.     dw    rret        ; 80col
  850.     dw    rret        ; 40col
  851.     dw    rret        ; prt1
  852.     dw    rret        ; prt2
  853.     dw    ?ins65        ; 6551
  854.     dw    in$st$RS232    ; software RS232
  855.     dw    rret
  856.  
  857. ;
  858. ;
  859. ;
  860. ?co:                ; character output
  861.     call    vector$io    ; jump with table adr on stack
  862.     dw    rret        ; keys
  863.     dw    ?out80        ; 80col
  864.     dw    rret        ; 40col
  865.     dw    ?pt$o$1        ; prt1
  866.     dw    ?pt$o$2        ; prt2
  867.     dw    ?out65        ; 6551
  868.     dw    out$RS232    ; software RS232
  869.     dw    rret
  870.  
  871. ;
  872. ;
  873. ;
  874. ?cost:                ; character output status
  875.     call    vector$io    ; jump with table adr on stack
  876.     dw    ret$true    ; keys
  877.     dw    ret$true    ; 80col
  878.     dw    ret$true    ; 40col
  879.     dw    ret$true    ; prt1    ?pt$s$1101
  880.     dw    ret$true    ; prt2
  881.     dw    ret$true    ; 6551
  882.     dw    out$st$RS232    ; software RS232
  883.     dw    ret$true
  884.  
  885. ;************************************************************
  886.  
  887.     page
  888. ;
  889. ;    This entry does not care about values of DE
  890. ;
  891. vector$io:
  892.     mvi    a,max$devices    ; check for device # to high
  893.     mov    e,b        ; get devive # in E
  894. ;
  895. ;
  896. ;    INPUT:
  897. ;        Vector # in E, Max device in A
  898. ;        passes value in DE$TEMP in DE
  899. ;        HL has routine's address in it on entering routine
  900. ;
  901. ;    OUTPUT:
  902. ;        ALL registers of returning routine are passed
  903. ;
  904. vector:
  905.     pop    h        ; get address vector list
  906.     mvi    d,0        ; zero out the MSB
  907.     cmp    e        ; is it too high?
  908.     jrnc    exist        ; no, go get the handler address
  909.  
  910.     mov    e,a        ; yes, set to max$dev$handler(last one) 
  911. exist:
  912.     dad    d        ; 
  913.     dad    d        ; point into table
  914.  
  915.      mov    a,m
  916.     inx    h
  917.     mov    h,m
  918.     mov    l,a        ; get routine adr in HL
  919.  
  920.     shld    hl$temp        ; save exec adr
  921.     lxi    h,0
  922.     dad    sp
  923.     lxi    sp,bios$stack
  924.     push    h        ; save old stack
  925.  
  926.     lhld    de$temp
  927.     xchg
  928.     lhld    hl$temp        ; recover exec adr
  929.  
  930.     lda    force$map    ; get current bank
  931.     push    psw        
  932.     sta    bank$0        ; set bank 0 as current
  933.  
  934.     call    ipchl
  935.  
  936.     sta    a$temp        ; save value to return
  937.     pop    psw
  938.     sta    force$map    ; set old bank back
  939.     lda    a$temp        ; recover value to return
  940.  
  941.     shld    hl$temp
  942.     pop    h        ; recover old stack
  943.     sphl            ; set new stack
  944.     lhld    hl$temp
  945.     ret
  946.  
  947. ipchl:
  948.     pchl            ; jmp to handler
  949.  
  950.     ds    30h
  951. bios$stack:
  952.  
  953.  
  954.     page
  955. ;==========================================================
  956. ;        CHARACTER INPUT ROUTINES
  957. ;==========================================================
  958.  
  959.     DSEG
  960. ;
  961. ;
  962. ;
  963. key$board$in:
  964.     call    key$board$stat    ; test if key is available
  965.     jrz    key$board$in    
  966.  
  967.     lda    key$buf
  968.     push    psw        ; save on stack
  969.     xra    a        ; clear key 
  970.     sta    key$buf
  971.     pop    psw        ; recover current key
  972. rret:
  973.     ret
  974.  
  975. ;
  976. ;
  977. ;
  978. null$input:        ; return a ctl-Z for no device
  979.     mvi    a,1Ah
  980.     ret
  981.  
  982.  
  983.     page
  984.  
  985. ;==========================================================
  986. ;    CHARACTER DEVICE INPUT STATUS
  987. ;==========================================================
  988.  
  989.     DSEG
  990. ;
  991. ;
  992. ;
  993. key$board$stat:
  994.     lda    key$buf
  995.     ora    a
  996.     jrnz    ret$true
  997.  
  998.     call    ?get$key
  999.     ora    a        ; =0 if none
  1000.     rz            ; return character not advailable
  1001.  
  1002.     sta    key$buf        ; was one, save in key buffer
  1003.  
  1004. ret$true:
  1005.     ori    0ffh        ; and return true
  1006.     ret
  1007.  
  1008.     page
  1009.  
  1010.     cseg
  1011. @ctbl
  1012.     db    'KEYBRD'    ; device 0, internal keyboard
  1013.     db    mb$input
  1014.     db    baud$none
  1015.  
  1016.     db    '80-COL'    ; device 1, 80 column display
  1017.     db    mb$output
  1018.     db    baud$none
  1019.  
  1020.     db    'NULL40'    ; device 2, 40 column display
  1021.     db    mb$output
  1022.     db    baud$none
  1023.  
  1024.     db    'PRT-LQ'    ; device 3, serial bus printer (device 4)
  1025.     db    mb$output
  1026.     db    baud$none
  1027.  
  1028.     db    'PRT-MX'    ; device 4, serial bus printer (device 5)
  1029.     db    mb$output
  1030.     db    baud$none
  1031.  
  1032.     db    '6551  '    ; device 5, EXT CRT
  1033.     db    mb$in$out+mb$serial+mb$softbaud+mb$xonxoff
  1034. X6551$baud:
  1035.     db    baud$9600
  1036.  
  1037.     db    'RS-232'    ; device 6, software RS232 device
  1038.     db    mb$in$out+mb$serial+mb$xonxoff+mb$softbaud
  1039. RS232$baud:
  1040.     db    baud$300
  1041.  
  1042.     db    0        ; mark end of table
  1043.  
  1044.     page
  1045. ;
  1046. ;    TIME.ASM
  1047. ;
  1048.     cseg
  1049. ;
  1050. ;    HL and DE must be presevered
  1051. ;
  1052. ?time:
  1053.     inr    c
  1054.     lxi    b,cia$hours
  1055.     jrz    set$time
  1056. ;
  1057. ;    update SCB time  (READ THE TIME)
  1058. ;
  1059.     inp    a            ; read HR (sets sign flag)
  1060.     jp    is$am            ; jmp if AM (positive)
  1061.     ani    7fh
  1062.     adi    12h            ; noon=24(PM), midnight=12(AM)
  1063.     daa
  1064.     cpi    24h            ; check for noon (12+12 PM)
  1065.     jrnz    set$hr
  1066.     mvi    a,12h
  1067.     jr    set$hr
  1068.  
  1069. is$am:
  1070.     cpi    12h            ; check for midnight (AM)
  1071.     jrnz    set$hr
  1072.     xra    a            ; becomes 00:00
  1073. set$hr:
  1074.     sta    @hour
  1075.     mov    b,a
  1076.     lda    old$hr
  1077.     mov    c,a
  1078.     mov    a,b
  1079.     sta    old$hr
  1080.     cmp    c            ; if @hour<old$hr
  1081.     jrnc    same$day
  1082.  
  1083.     push    h
  1084.     lhld    @date
  1085.     inx    h
  1086.     shld    @date
  1087.     pop    h
  1088.  
  1089. same$day:
  1090.     lxi    b,cia$hours-1
  1091.     inp    a            ; read MIN
  1092.     sta    @min
  1093.  
  1094.     dcr    c
  1095.     inp    a            ; read SEC
  1096.     sta    @sec
  1097.  
  1098.     dcr    c
  1099.     inp    a            ; read 1/10 of SEC (a must to free
  1100.     ret                ; the holding register)
  1101.  
  1102. old$hr:
  1103.     ds    1
  1104.     page
  1105. ;
  1106. ;
  1107. ;
  1108. set$time
  1109.     lda    @hour
  1110.     cpi    12h            ; test for noon
  1111.     jrz    set$as$is
  1112.     ana    a            ; test for 00:xx
  1113.     jrnz    not$zero$hundred
  1114.     mvi    a,80h+12h            ; set to midnight
  1115.     jr    set$as$is
  1116.  
  1117. not$zero$hundred:
  1118.      cpi    11h+1            ; test for 1 to 11 AM
  1119.     jrc    set$as$is
  1120.     sui    12h
  1121.     daa                ; decimal adjust
  1122. set$msb:
  1123.     ori    80h            ; set PM
  1124.  
  1125. set$as$is:
  1126.     outp    a
  1127.     dcr    c
  1128.     lda    @min
  1129.     outp    a
  1130.     dcr    c
  1131.     lda    @sec
  1132.     outp    a
  1133.     dcr    c
  1134.     xra    a
  1135.     outp    a
  1136.     ret
  1137.  
  1138.     page
  1139.  
  1140. ;
  1141.     page
  1142. ;
  1143. ; CXMOVE.ASM
  1144. ;
  1145.     public ?move,?xmove,?bank
  1146.  
  1147. ;
  1148. ;    Move a block of data from DE to HL
  1149. ;    count is in BC (within current bank)
  1150. ;
  1151. ;
  1152.     cseg            ; place code in common
  1153. ?move:
  1154.     xchg            ;*
  1155.     lda    source$bnk    ; =FFh if normal block move 
  1156.     inr    a        ; 
  1157.     jrnz    inter$bank$move
  1158.  
  1159.     LDIR            ;* do block move    
  1160.     xchg            ;*
  1161.     ret
  1162.  
  1163.  
  1164. ;
  1165. ;
  1166. ;
  1167. ?xmove:                ; can be in bank 0    
  1168.     mov    a,c
  1169.     sta    source$bnk
  1170.     mov    a,b
  1171.     sta    dest$bnk
  1172.     ret            ;*
  1173.  
  1174.     page
  1175. ;
  1176. ;
  1177. ;
  1178. inter$bank$move:
  1179.     shld    @buffer        ; save HL TEMP
  1180.     lxi    h,0
  1181.     dad    sp
  1182.     lxi    sp,bios$stack
  1183.     push    h        ; save old stack  ;**1
  1184.     lhld    @buffer
  1185.  
  1186.     mov    a,b        ; get msb of count
  1187.     ora    a
  1188.     jrz    count$less$than$256
  1189.  
  1190.     push    b        ; save the count  ;**2
  1191.     push    d        ; save the dest   ;**3
  1192.     lxi    d,@buffer    ; make buffer the dest
  1193.     lxi    b,256        ; move 256 bytes
  1194.     lda    source$bnk
  1195.     call    ?bank
  1196.     ldir            ; move source to buffer
  1197.  
  1198.     pop    d        ; recover dest    ;**2
  1199.     push    h        ; save updated source ;**3
  1200.     lxi    h,@buffer    ; make the buffer the source
  1201.     lxi    b,256        ; move 256 bytes
  1202.     lda    dest$bnk
  1203.     call    ?bank
  1204.     ldir            ; move buffer to dest
  1205.  
  1206.     pop    h        ; recover updated source ;**2
  1207.     pop    b        ; recover count          ;**1
  1208.     dcr    b        ; subtract 256 from count
  1209.     jr    inter$bank$move
  1210.  
  1211.     page
  1212. ;
  1213. ;
  1214. ;
  1215. count$less$than$256:
  1216.     ora    c        ; BC=0  [A (0) or'ed with C]
  1217.      jrz    exit$move
  1218.  
  1219.     push    d        ; save count for 2nd half  ;**2
  1220.     push    b        ; save dest adr            ;**3
  1221.     lxi    d,@buffer
  1222.     lda    source$bnk
  1223.     call    ?bank
  1224.     ldir            ; move source to buffer
  1225.  
  1226.     pop    b        ; recover count          ;**2
  1227.     pop    d        ; recover dest          ;**1
  1228.     push    h        ; save updated dest      ;**2
  1229.     lxi    h,@buffer
  1230.     lda    dest$bnk
  1231.     call    ?bank
  1232.     ldir            ; move buffer to dest
  1233.     pop    h                        ;**1
  1234.  
  1235. ;
  1236. ;
  1237. ;
  1238. exit$move:
  1239.     xchg
  1240.     mvi    a,-1
  1241.     sta    source$bnk    ; set MOVE back to normal
  1242.     lda    @cbnk
  1243.  
  1244.     shld    @buffer
  1245.     pop    h        ; recover old stack    ;**0
  1246.     sphl
  1247.     lhld    @buffer
  1248.  
  1249. ; call    ?bank        ; set current bank
  1250. ; ret
  1251.  
  1252.     page
  1253. ;
  1254. ;    switch bank to bank number in A
  1255. ;
  1256.     cseg            ; (must be in common)
  1257. ?bank:                
  1258.     ora    a        ; bank 0 ?
  1259.     jrnz    not$bank$0    ; go check for bank 1
  1260.  
  1261.     sta    bank$0        ; set bank 0
  1262.     ret
  1263.  
  1264. ;
  1265. ;
  1266. not$bank$0:
  1267.     dcr    a        ; bank 1 ?
  1268.     rnz            ; if not a valid bank just return
  1269.     sta    bank$1        ; set bank 1
  1270.     ret
  1271.  
  1272.     end
  1273. t
  1274.  
  1275. ;
  1276. ;
  1277. not$bank$0:
  1278.     dcr    a        ; bank 1 ?
  1279.     rnz            ; if not a valid ban