home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / ENTERPRS / CPM / UTILS / A / BIOSR4.ARC / CXDISK.ASM < prev    next >
Assembly Source File  |  1987-04-26  |  31KB  |  1,641 lines
  1. ; changes made to this module were to remove test for 
  2. ; disk status line (it is displayed all of the time now), and
  3. ; to remove unecessary disk definitions ( only A, B, and C now)
  4. ; The virtual drive E: has been removed,  and the 40 column disk status
  5. ; display has been removed (previously it was always running no matter
  6. ; what.
  7. ;
  8. ; compare with an original copy of CXDISK.ASM if you want to
  9. ; find what the changes were
  10. ;
  11. ;  User assumes _ALL_ liability for use of this module.  Original
  12. ;  copyright is still maintained by Commodore
  13. ;
  14. ;
  15. ;
  16. ;
  17. ;    *****************************************
  18. ;    *                    *
  19. ;    *    Commodore Disk    Controller    *
  20. ;    *    Module for CP/M 3.0 BIOS    *
  21. ;    *                    *
  22. ;    *****************************************
  23. ;
  24. ;
  25. ;
  26.     title 'CXDISK   Commodore C-128 Disk Controller    26 April 87'
  27.  
  28.  
  29.  
  30.  
  31. ; CP/M 3 Disk definition macros
  32.  
  33.     maclib    cpm3
  34.  
  35.     maclib    z80
  36.  
  37. ; C-128 system equates
  38.  
  39.     maclib    cxequ
  40.  
  41.     page
  42.  
  43. ; Disk drive dispatching tables for linked BIOS
  44.  
  45.     public    cmdsk0,cmdsk1,cmdsk2
  46.  
  47. ; System Control Block variables
  48.     extrn    @ermde        ; BDOS error mode
  49.  
  50. ; Utility routines in standard BIOS
  51.     extrn    ?wboot        ; warm boot vector
  52.     extrn    ?pmsg        ; print message @<HL> up to 00
  53.                 ; saves <BC> & <DE>
  54.     extrn    ?pdec        ; print binary number in <HL> from 0 to 65535
  55.     extrn    ?pderr        ; print BIOS disk error header
  56.     extrn    ?conin,?cono    ; con in and out
  57.     extrn    ?const        ; get console status
  58.     extrn    ?sctrn        ; sector translation routine
  59.     extrn    @covec
  60.  
  61. ;    status line calls
  62.  
  63.     extrn    ?save,?recov,?stat
  64.  
  65. ; System function call
  66.     extrn    ?kyscn
  67.     extrn    ?fun65
  68.     extrn    ?bank
  69.     extrn    ?di$int
  70.  
  71.     public    ?dskst
  72.     public    ?dkmov
  73.     extrn    ?stat
  74.  
  75.     page
  76. ;
  77. ; Initialization entry point.
  78. ; called for first time initialization.
  79. ;
  80.     DSEG
  81. init$154X:
  82.     xra    a
  83.     sta    fast
  84.     lxi    h,MFM$table
  85.     shld    MFM$tbl$ptr
  86.     ret
  87.  
  88.  
  89.     page
  90. ;
  91. ; This entry is called when a logical drive is about to
  92. ;  be logged into for the purpose of density and type determination.
  93. ;  It may adjust the parameters contained in the disk
  94. ;  parameter header pointed to by <DE>
  95. ;
  96.     DSEG
  97. ;
  98. ;    if disk type GCR or drive type 1541
  99. ;       if 1st sector has 'CBM' (1st 3 bytes)
  100. ;          if last byte = -1 (0FFh)
  101. ;             set C128 double sided
  102. ;          else
  103. ;             set C128 single sided
  104. ;          endif
  105. ;       else
  106. ;          set C64 type
  107. ;       endif
  108. ;    else (must be MFM)
  109. ;       TEST MFM
  110. ;    endif
  111. ;
  112. login$154X:
  113.     call    get$drv$info    ; set the drive to check (DPH$pointer set)
  114.  
  115.     mvi    a,vic$test
  116.     call    ?fun65
  117.     mov    b,a
  118.     ani    0ch
  119.     cpi    0ch
  120.     jrz    GCR$type    ; jump if not a 1571
  121.  
  122.     mov    a,b
  123.     rlc
  124.     jrc    MFM$type
  125.  
  126.     page
  127. ;
  128. ;
  129. ;
  130. GCR$type:
  131.     lhld    DPH$pointer
  132.     dcx    h
  133.     mvi    m,dsk$c64
  134.     lxi    d,dpb$c64$cpm    ; set DPB to C64
  135.     call    set$dpb$only
  136.  
  137.     xra    a
  138.     sta    vic$sect    ; set track 1 sector 0 (1st sector
  139.     inr    a        ; on the disk)
  140.     sta    vic$trk
  141.  
  142.     lxi    h,@buffer
  143.     shld    local$DMA    ; move DMA pointer to disk buffer
  144.     call    login$rd
  145.     ana    a        ; read error ?
  146.     rnz            ; yes, just return
  147.  
  148.     RCALL    FR$check$CBM
  149.     rnz            ; return if not 'CBM'
  150.                 ; A=0FFh if double sided
  151.     inr    a
  152.  
  153.     lhld    DPH$pointer
  154.     dcx    h        ; does not affect flags
  155.     mvi    m,dsk$c128
  156.  
  157.     lxi    d,dpb$c128$SS
  158.     jrnz    set$dpb$only
  159.  
  160.     lxi    d,dpb$c128$DS
  161.  
  162.     page
  163. ;
  164. ;
  165. ;
  166. set$dpb$only:
  167.     lxi    b,0        ; set sector translation to zero
  168. set$format:
  169.     lhld    DPH$pointer
  170.     mov    m,c
  171.     inx    h
  172.     mov    m,b        ; install sector translation
  173.     lxi    b,25-1        ; ofset to DPB
  174.     dad    b        ; HL points to DPB now
  175.     lxi    b,17        ; dpb size
  176.     xchg            ; move to DPB location
  177.     ldir
  178.     ret
  179.  
  180.  
  181.     page
  182. ;
  183. ;    TEST MFM()
  184. ;    save number bytes/sector
  185. ;       if double sided
  186. ;          mark two sided
  187. ;       endif
  188. ;       find start and end sector numbers
  189. ;       scan table of disk for match (if more then 1 match ask user) 
  190. ;
  191. MFM$type:
  192.     mvi    c,01100000b
  193.     ana    c            ; A = status(trk1) shifted left 1 
  194.     push    psw            ; save in case bad query
  195.     push    b            ; save BC
  196.  
  197.     call    get$max$num$B        ; used to set the pointer only
  198.     mov    b,m            ; get size, and disk lock flag
  199.     inx    h
  200.     mov    a,m
  201.     inx    h
  202.     mov    h,m            ; get last MFM$mactch$ptr
  203.     mov    l,a
  204.     mov    a,b            ; get lock flag in A
  205.     ani    80h            ; lock bit set ?
  206.     sta    lock$flag        ;   (save old lock status)
  207.     shld    last$match        ; save last match pointer
  208.     jrz    not$$locked$entry    ; yes, then set same disk type
  209. ; set$locked$entry
  210.     xra    a
  211.     sta    lock$flag
  212.     mvi    c,0B0h
  213.     lda    vic$data        ; get sector size info
  214.     ana    c
  215.     mov    b,a            ; save disk sector size info
  216.     xchg                ; save HL
  217.     lhld    DPH$pointer
  218.     dcx    h
  219.     mov    a,c
  220.     ana    m            ; get old disk sector size
  221.     cmp    b            ; are they the same?
  222.     jrnz    not$locked$entry    ; no, then unlock disk anyway
  223.  
  224.     xchg                ; get last match pointer (in DE)
  225.     pop    psw            ; yes, remove two data elements 
  226.     pop    psw            ; ..save on stack
  227.     jr    set$this$entry
  228.  
  229. not$locked$entry:
  230.     lxi    h,MFM$match$tbl        ; clear Match table
  231.     shld    MFM$cur$ptr
  232.     lxi    d,MFM$match$tbl+1
  233.     mvi    m,0
  234.     lxi    b,(MFM$tbl$entries*2)-1+1+1    ; table, offset and count
  235.     ldir
  236.     mvi    a,4
  237.     sta    vic$trk            ; do query on track 4
  238.     mvi    a,vic$query
  239.     call    ?fun65
  240.     pop    b            ; recover BC
  241.     ani    0eh            ; query error ?
  242.     jrnz    query$error        ; yes, use only bits 5 and 6 
  243.     lda    @buffer            ; get trk 4 status
  244.     mov    b,a            ; save in B
  245.     ani    0eh            ; trk 4 status error ?
  246.     jrnz    query$error        ; yes, use only bits 5 and 6
  247.     mov    a,b            ; recover B (trk 4 status)
  248.     add    a            ; shift left
  249.     ana    c            ; mask sector size bits
  250.     mov    b,a
  251.     pop    psw            ; get trk 1 sector size bits
  252.     cmp    b            ; same as trk 4 sector size?
  253.     mvi    c,01111111b
  254.     jrz    trk$1$trk$4        ; yes, (then test for mult format)
  255.     mvi    a,80h            ; set MSB to mean mult format
  256.     add    b            ; ..(track 0 different sector size
  257.                     ; ..then track 4) 
  258.     mov    b,a            ; save in B
  259.     mvi    c,11111111b
  260. trk$1$trk$4:
  261.     lda    @buffer+1        ; get number of sectors/track
  262.     sui    4            ; remove 4 to extend the range
  263.     add    a            ; shift    left
  264.     add    b            ; combine with rest of mask
  265.     mov    b,a            ; save in B for now
  266.  
  267.     lda    @buffer+3        ; minimum sector number
  268.     add    b            ; add in start sector #
  269.     push    psw            ; save on stack for a moment
  270.  
  271. query$error:
  272.     pop    psw            ; get value to match 
  273.     ana    c            ; test only those bits in the mask
  274.  
  275.     lhld    MFM$tbl$ptr
  276.     mvi    b,MFM$tbl$entries
  277. check$next:
  278.     push    b            ; save BC for a moment
  279.     mov    b,a            ; move compare value to 
  280.     mov    a,m            ; get type info
  281.     ana    c            ; test only the good info
  282.     cmp    b            ; match the current type byte
  283.     mov    a,b            ;   (recover A)
  284.     pop    b            ;   (recover BC)
  285.     jrnz    not$found        ; no, do not queue data
  286.                     ; yes queue table entry address
  287.  
  288.     xchg                ; save adr in DE
  289.     lhld    MFM$cur$ptr
  290.     mov    m,e
  291.     inx    h
  292.     mov    m,d
  293.     inx    h
  294.     shld    MFM$cur$ptr
  295.     lxi    h,MFM$count
  296.     inr    m            ; add one to counter
  297.     xchg
  298.  
  299.     page
  300. ;
  301. ;
  302. not$found:
  303.     lxi    d,32            ; table entry size
  304.     dad    d
  305.     djnz    check$next
  306.  
  307.     lda    MFM$count        ; number of matches in table 
  308.     ana    a            ; test for zero
  309.     jz    tell$user$no$entry    ; none, tell the user 
  310.  
  311.     dcr    a            ; only one ?
  312.     jrnz    user$select        ; no, go check with user (which one)
  313.     lhld    MFM$match$tbl        ; yes, use the only one found
  314.  
  315. ;
  316. ;    install data form pointer in HL
  317. ;
  318. set$this$entry:
  319.     push    h        ; save table pointer
  320.     inx    h
  321.     mov    a,m        ; get type info. 
  322.     xchg            ; save table address in DE
  323.     lhld    DPH$pointer
  324.     dcx    h
  325.     mov    m,a        ; save type code
  326.     xchg            ; get table adr to HL
  327.     inx    h        ; HL points to sector translation table 
  328.     mov    c,m        ; ..zero if none
  329.     inx    h
  330.     mov    b,m
  331.     inx    h        ; HL points to DPB
  332.     xchg            ; DE points to DPB (HL trash)
  333.     call    set$format
  334.     mov    b,m        ; get the number of sect/trk from MFM table
  335.     lda    lock$flag    ; get the current lock flag value
  336.     ora    b        ; combine with sect/trk
  337.     xchg            ; HL=to adr,  DE=from adr
  338.     mov    m,a        ; install sect/trk and lock flag
  339.     pop    d        ; recover table pointer
  340.     inx    h
  341.     mov    m,e
  342.     inx    h
  343.     mov    m,d        ; save MFM table pointer at end of DPH
  344.     ret
  345.  
  346.     page
  347. ;
  348. ;    let the user select the Disk type s/he wants
  349. ;
  350. user$select:
  351.     inr    a            ; number of entries to try to match
  352.     mov    b,a            ; set in B as loop count
  353.     lhld    last$match        ; get value to match with
  354.     mov    d,h
  355.     mov    e,l            ; last match pointer is in DE
  356.  
  357.     lxi    h,MFM$match$tbl
  358.     shld    MFM$cur$ptr
  359.     mvi    c,0            ; start offset at zero
  360.  
  361. try$next$format:
  362.     mov    a,e
  363.     cmp    m
  364.     inx    h
  365.     jrnz    not$last$match
  366.     mov    a,d
  367.     cmp    m
  368.     jrnz    not$last$match
  369. ;
  370. ; match, set pointer
  371. ;
  372.     mov    a,c            ; get offset in A
  373.     push    psw
  374.     call    save$dsk$window
  375.     pop    psw
  376.     jr    set$offset
  377.  
  378. not$last$match:
  379.     inx    h            ; each pointer uses two bytes 
  380.     inr    c            ; advance the index
  381.     djnz    try$next$format        ; test for more, loop if so
  382.  
  383.     call    save$dsk$window
  384.  
  385.     lhld    MFM$cur$ptr
  386. user$loop:
  387.     mov    e,m            ; HL=(MFM$cur$ptr)
  388.     inx    h
  389.     mov    d,m
  390.     lxi    h,22            ; offset to NAME field
  391.     dad    d            ; point to Disk name
  392.     call    dsk$window$old
  393.  
  394. dsk$user$sel$wait:
  395.     call    ?kyscn
  396.     inr    b            ; test for key pressed
  397.     jrz    dsk$user$sel$wait
  398.     dcr    b            ; adjust back
  399.     mov    a,b            ; move matrix position to A
  400.     cpi    SF$exit
  401.     jrnz    CK$dsk$user$rt
  402.  
  403.     mov    a,c
  404.     ani    4            ; control key down ?
  405.     jrz    no$cntr$key        ; no, don't lock this selection
  406.     mvi    a,80h            ; yes, lock disk type to this drive
  407. no$cntr$key:
  408.     sta    lock$flag        ;
  409.     call    dsk$window$remove
  410.     lhld    MFM$cur$ptr
  411.     mov    e,m
  412.     inx    h
  413.     mov    d,m
  414.     xchg
  415.     jr    set$this$entry
  416.  
  417.     page
  418. ;
  419. ;
  420. ;
  421. CK$dsk$user$rt:
  422.     cpi    SF$right        ;
  423.     jrnz    CK$dsk$user$lf
  424.  
  425. ; move window down
  426.     lda    MFM$count        ; get number of items in list
  427.     mov    b,a            ; save in B
  428.     lda    MFM$offset        ; get current position
  429.     inr    a            ; advance position
  430.     cmp    b            ; at last position ? (n-1+1 =count)
  431.     jrnz    set$offset        ; no, then use A as new position
  432.     xra    a            ; yes, move back to start
  433.     jr    set$offset
  434.     
  435. CK$dsk$user$lf:
  436.     cpi    SF$left            ;
  437.     jrnz    dsk$user$sel$wait
  438.  
  439. ; move window up
  440.     lda    MFM$offset
  441.     dcr    a            ; back up offset (under flow?)
  442.     jp    set$offset        ; result positive, jump
  443.     lda    MFM$count        ; get last item number
  444.     dcr    a            ; pointer is 0 to n-1 (not 1 to n)
  445. set$offset:
  446.     sta    MFM$offset        ; set new list offset
  447.     inr    a            ; add one to adjust for DCR below
  448.     lxi    h,MFM$match$tbl        ; set to the beginning
  449.  
  450. adjust$dsk$loop:
  451.     shld    MFM$cur$ptr        ; set pointer here !
  452.     dcr    a            ; at offset yet?
  453.     jrz    user$loop        ; yes, go display name
  454.     inx    h
  455.     inx    h
  456.     jr    adjust$dsk$loop
  457.  
  458.     page
  459. ;
  460. ;
  461. ;
  462. tell$user$no$entry:
  463.     lda    vic$data        ; get disk test status
  464.     ani    0b0h            ; save only sector size and MFM flag
  465.     lhld    DPH$pointer
  466.     dcx    h
  467.     mov    m,a            ; set disk size and Type0 (MFM)
  468.  
  469.     lxi    h,dsk$window*256+buff$pos
  470.     lxi    d,no$dsk$msg
  471. disp$msg$DE$HL:
  472.     call    dsk$window$new
  473. dsk$no$entry$wait:
  474.     call    ?kyscn
  475.     inr    b
  476.     jrz    dsk$no$entry$wait
  477.     dcr    b
  478.     mov    a,b
  479.     cpi    SF$exit
  480.     jrnz    dsk$no$entry$wait
  481. ;    jr    dsk$window$remove
  482.  
  483.     page
  484. ;
  485. ;
  486. ;
  487. dsk$window$remove:
  488.     lhld    window$info
  489.     mov    b,h
  490.     mov    c,l
  491.     jmp    ?recov
  492. ;
  493. ;
  494. ;
  495. save$dsk$window:
  496.     lxi    h,dsk$window*256+buff$pos    ; H=size l=pos
  497.     shld    window$info
  498.     mov    b,h
  499.     mov    c,l
  500.     jmp    ?save
  501. ;
  502. ;
  503. ;
  504. dsk$window$new:
  505.     shld    window$info
  506.     xchg
  507.     mov    b,d
  508.     mov    c,e
  509.     push    h
  510.     call    ?save
  511.     pop    h
  512.  
  513. dsk$window$old:
  514.     lda    window$info        ; get start index
  515.     inr    a
  516.     mov    c,a            ; place in C
  517.  
  518. dsk$out$next:
  519.     push    h
  520.     lhld    window$info
  521.     mov    a,h
  522.     add    l            ; compute max index (start+size)
  523.     dcr    a            ; ..less 1
  524.     pop    h
  525.     cmp    c
  526.     rz    
  527.     mov    b,m
  528.     call    dsk$B$out
  529.     inx    h
  530.     jr    dsk$out$next
  531.  
  532. ;
  533. ;
  534. ;
  535. dsk$B$out:
  536.     mvi    a,01000000b            ; set reverse video attr
  537.     push    b
  538.     push    h
  539.     call    ?stat                ; display space
  540.     pop    h
  541.     pop    b                ; recover count
  542.     inr    c
  543.     ret
  544.  
  545.     page
  546. ;
  547. ; disk READ and WRITE entry points.
  548. ; These entries are called with the following arguments:
  549. ;    relative drive number in @rdrv (8 bits)
  550. ;    absolute drive number in @adrv (8 bits)
  551. ;    disk transfer address in @dma (16 bits)
  552. ;    disk transfer bank    in @dbnk (8 bits)
  553. ;    disk track address    in @trk (16 bits)
  554. ;    disk sector address    in @sect (16 bits)
  555. ;    pointer to XDPH in <DE>
  556. ;
  557. ;   return with an error code in <A>
  558. ;     A=0    no errors
  559. ;     A=1    non-recoverable error
  560. ;    A=2    disk write protected
  561. ;    A=FF    media change detected
  562. ;
  563.     DSEG
  564. read$154X:
  565.     call    get$drv$info
  566.     jm    mfm$rd
  567.     call    set$up$GCR        ; compute effective track and sector
  568. login$rd:
  569.     lda    vic$drv
  570.     mov    b,a
  571.     lda    fast            ; get fast flags
  572.     ana    b            ; isolate fast bit for this drive
  573.     jrnz    rd$fast            ; go handle fast drive
  574. rd$slow:
  575.     mvi    a,vicrd            ; read a sector of data (A=1)
  576.     call    dsk$fun            ; a=0 if no errors
  577.     jnz    test$error        ; check for disk error or media change
  578. ;
  579. ;
  580. ;
  581. buf$move:
  582.     xra    a            ; set direction to read
  583.     call    ?dkmov            ; go move buffer to DMA
  584.     lda    sect$cnt
  585.     ana    a
  586.     rz                ; a=0 means not read errors
  587.     call    set$up$next
  588.     jr    rd$slow
  589.  
  590.     page
  591. ;
  592. ;    A=drive type info
  593. ;
  594. mfm$rd:
  595.     call    set$up$MFM
  596.  
  597. rd$fast:
  598.     mvi    a,vic$rd$f
  599.     call    dsk$fun            ; go read the disk
  600.  
  601.     ani    0eh            ; mask off error bits
  602.     jrnz    test$error
  603.  
  604.     call    get$sector$size
  605.     inr    d
  606.     inr    e            ; adjust count for pre-decrement
  607.  
  608.     call    ?di$int
  609.     lxi    b,0DD00h        ; D2PRA
  610.     inp    a            ; get current clock polarity 
  611.     xri    10h            ; toggle clk$bit
  612.     outp    a            ; to have status sent (extra clock
  613.                     ; supplied by rd$1571$data for multi
  614.                     ; sector transfers)
  615.     lda    vic$count
  616. rd$multi$sect:
  617.     push    psw
  618.     push    d        ; save the sector size
  619.     call    rd$1571$data    ; read disk data to DMA address
  620.     pop    d
  621.  
  622.     lda    vic$data
  623.     ani    0eh
  624.     jrnz    test$error$pop    ; A=0 if no errors
  625.     pop    psw
  626.     dcr    a
  627.     jrnz    rd$multi$sect
  628.     ei
  629.     lda    sect$cnt
  630.     ana    a        ; any sectors left to read
  631.     jrz    done$rd$1571
  632.  
  633.     call    set$up$next
  634.     jr    rd$fast
  635.  
  636. done$rd$1571:
  637.     lxi    b,0DD00h        ;   D2PRA
  638.     inp    a
  639.     ani    not(10h)        ; set clk$bit hi
  640.     outp    a
  641.     xra    a            ; A=0 for no errors
  642.     ret
  643.  
  644.  
  645.     page
  646. ;
  647. ;
  648. ;
  649. write$154X:
  650.     call    get$drv$info
  651.     jm    mfm$wr
  652.     call    set$up$GCR
  653.     lda    vic$drv
  654.     mov    b,a
  655.     lda    fast            ; get fast flags
  656.     ana    b            ; isolate fast bit for this drive
  657.     jrnz    wr$fast$drive        ; go handle fast drive
  658. wr$slow:
  659.     mvi    a,-1            ; set direction to write
  660.     call    ?dkmov            ; go move DMA to buffer
  661.  
  662.     mvi    a,vicwr            ; write a sector of data
  663.     call    dsk$fun            ; a=0 if no errors
  664.     ani    0eh
  665.     jrnz    test$error
  666.     lda    sect$cnt
  667.     ana    a
  668.     rz
  669.     call    set$up$next
  670.     jr    wr$slow
  671.  
  672. test$error$pop:
  673.     pop    psw
  674. test$error:
  675.     ei
  676.     lda    vic$data
  677.     ani    0fh            ; check for disk error or media change
  678.     cpi    0bh            ; disk change ?
  679.     jrz    change$error
  680.     cpi    08h            ; test for write protect error
  681.     jrz    write$prot$error
  682.  
  683.     mvi    a,1            ;  get general error flag
  684.     ret
  685.  
  686. ;
  687. ;
  688. write$prot$error:
  689.     mvi    a,2
  690.     ret
  691.  
  692. ;
  693. ;
  694. change$error:
  695.     mvi    a,-1
  696.     ret
  697.  
  698.     page
  699. ;
  700. ;
  701. ;
  702. mfm$wr:
  703.     call    set$up$MFM
  704. wr$fast$drive:
  705.     mvi    a,vic$wr$f
  706.     call    dsk$fun            ; go send the write command
  707.  
  708.     call    get$sector$size        ; setup DMA adr and transfer count
  709.     lda    vic$count
  710. wr$multi$sect:
  711.     push    psw
  712.     push    d            ; save sector size
  713.     call    wr$1571$data        ; write data to disk from DMA address
  714.     pop    d
  715.     ani    0eh
  716.     jrnz    test$error$pop
  717.     pop    psw
  718.     dcr    a
  719.     jrnz    wr$multi$sect
  720.  
  721.     ei
  722.     lda    sect$cnt
  723.     ana    a
  724.     rz                ; return if no errors (A=0)
  725.     call    set$up$next
  726.     jr    wr$fast$drive
  727.  
  728.     page
  729. ;
  730. ;
  731. ;
  732. get$drv$info:
  733.     lhld    @dma
  734.     shld    local$dma
  735.     xchg
  736.     shld    DPH$pointer
  737.  
  738.     lda    @adrv            ; get drive number (0 to F)
  739.     dcx    h            ; point at drive mask
  740.     dcx    h
  741.     mov    a,m            ; get drive mask
  742.     mov    b,a            ; save in B
  743.     sta    vic$drv            ; save vic drive # (values 1,2,4,8)
  744.  
  745.     inx    h            ; point at disk type
  746.     xra    a
  747.     sta    sect$cnt        ; clear the count
  748.     inr    a
  749.     sta    vic$count
  750.     mov    a,m            ; get disk type
  751.     ana    a
  752.     ret
  753.  
  754. ;
  755. ;    
  756. ;
  757. ;
  758. get$max$num$b:
  759.     lhld    DPH$pointer
  760.     lxi    b,42            ; offset to number of sectors on track
  761.     dad    b
  762.     mov    a,m            ; get number sectors/track/side
  763.     ani    1fh
  764.     mov    b,a
  765.     ret
  766. ;
  767. ;
  768. ;
  769. get$sector$size:
  770.     lhld    DPH$pointer
  771.     dcx    h
  772.     mov    a,m            ; disk type in B (bit 5,4 size info)
  773.     rrc                ; ..00 = 080h byte sectors
  774.     rrc                ; ..01 = 100h byte sectors
  775.     rrc                ; ..10 = 200h byte sectors
  776.     rrc                ; ..11 = 400h byte sectors
  777.     ani    3
  778.     jrz    set$128
  779.     jpo    not$3            ; jump if (A=) 01b or 10b
  780.     inr    a            ; make A = 4
  781. not$3:
  782.     mvi    e,0            ; set E to zero
  783.     mov    d,a            ; set sector size (1,2 or 4)
  784. get$DMA:
  785.     lhld    local$DMA        ; get the current DMA pointer
  786.     ret
  787.  
  788. set$128:
  789.     lxi    d,128
  790.     jr    get$DMA 
  791.  
  792.     page
  793. ;
  794. ;
  795. ;
  796.     DSEG
  797. set$up$GCR:
  798.     cpi    dsk$c128
  799.     jnz    tst$c64
  800.  
  801.     mvi    a,4
  802.     sta    sect$cnt
  803.     lxi    h,sect$buffer
  804.     shld    sect$buf$ptr
  805.  
  806.     lhld    @trk            ; 1 K sector pointer 
  807.     dad    h
  808.     dad    h            ; make 256 byte pointer
  809. ;
  810. ;    build a list of tracks and sectors
  811. ;
  812. next$sect:
  813.     shld    @trk
  814.     RCALL    FR$trk$sect
  815.     lhld    vic$trk            ; get trk(L) and sector(H) to HL
  816.     xchg
  817.     lhld    sect$buf$ptr
  818.     mov    m,e
  819.     inx    h
  820.     mov    m,d
  821.     inx    h
  822.     shld    sect$buf$ptr
  823.     lhld    @trk
  824.     inr    l            ; update saved above at next$sect
  825.     mov    a,l
  826.     ani    3
  827.     jrnz    next$sect
  828. ;
  829. ;    check list of trk-sectors for number of sectors on this trk
  830. ; 
  831.     lxi    h,sect$buffer
  832.     shld    sect$buf$ptr
  833.     lda    vic$drv
  834.     mov    b,a
  835.     lda    fast
  836.     ana    b            ; drive type 1571
  837.     jrz    handle$1541        ; no, handle as 1541
  838.  
  839.     lda    sect$cnt        ; number of sectors to rd/wr
  840.     mov    b,a
  841.     inx    h
  842.     mov    a,m            ; get 1st sector #
  843.     sta    vic$sect
  844.     dcx    h
  845.     mov    a,m            ; get 1st track #
  846.     sta    vic$trk
  847.  
  848. try$next:
  849.     cmp    m            ; test for same trk #
  850.     jrnz    exit$no$match
  851.     inx    h
  852.     inx    h            ; advance to next trk
  853.     shld    sect$buf$ptr
  854.     djnz    try$next    
  855.  
  856. exit$no$match:
  857.     lda    sect$cnt        ; number of sectors to rd/wr
  858.     sub    b            ; remove number left
  859.                     ; (leaving number matched)
  860.     sta    vic$count        ; save number to read
  861.     mov    a,b            ; get remaining count
  862.     sta    sect$cnt        ; save remaining count
  863.     ret
  864.  
  865.  
  866. set$up$next:
  867.     lda    vic$count        ; get number of sectors read
  868.     lhld    local$DMA        ; get current DMA pointer
  869.     add    h            ; advance pointer by number of
  870.     mov    h,a            ; sectors read
  871.     shld    local$DMA
  872. handle$1541:
  873.     lhld    sect$buf$ptr
  874.     mov    a,m
  875.     sta    vic$trk
  876.     inx    h
  877.     mov    a,m
  878.     sta    vic$sect
  879.     inx    h
  880.     shld    sect$buf$ptr
  881.     lda    vic$drv
  882.     mov    b,a
  883.     lda    fast
  884.     ana    b
  885.     jrz    set$up$next$slow
  886.     lda    sect$cnt
  887.     sta    vic$count
  888.     xra    a            ; two reads max with fast drive
  889.     jr    set$up$next$exit
  890.  
  891. set$up$next$slow:
  892.     lda    sect$cnt
  893.     dcr    a
  894. set$up$next$exit:
  895.     sta    sect$cnt
  896.     ret
  897.  
  898. tst$c64:
  899.     cpi    dsk$c64    
  900.     jrnz    tst$none    ; compute adjusted track number
  901. ;
  902. ;    this routine will adjust the track number if necessary.
  903. ;    The C64 CP/M disk has the C64 directory in the center
  904. ;    of the disk. This routine checks and adds one to the track
  905. ;    number if we have reached or passed the directory track. 
  906. ;    An additional offset of is added to make the track number
  907. ;    range from 1 to N+1 instead of 0 to N.
  908. ;
  909. set$up$c64:
  910.     lda    @trk
  911.     inr    a
  912.     cpi    dir$track    ; carry=1 if A < dir$track
  913.     cmc            ; add one if dir$track or more (carry not set)
  914.     aci    0        ; add the carry bit in
  915.  
  916. set$up$cont:
  917.     sta    vic$trk
  918.     lda    @sect
  919.     sta    vic$sect
  920.     ret
  921. ;
  922. ;    This format is for direct track and sector addressing 
  923. ;
  924. tst$none:
  925. ;    cpi    dsk$none    ; don't test extras for now....??
  926. ;    rnz
  927. do$type$7:
  928.     lda    @trk
  929.     jr    set$up$cont
  930.  
  931.     page
  932. ;
  933. ;    A=dsk$info on entry
  934. ;
  935. set$up$MFM:
  936.     mvi    d,0        ; D=side # (0)
  937.     mov    e,a        ; save dsk$info in E
  938.     ani    TypeX        ; look at Type0 to Type7
  939.     jrz    do$type$0    ;
  940.     cpi    Type2
  941.     lda    @trk        ; used by Type1, Type2 and Type3
  942.     jrz    do$type$2
  943.     jrc    do$type$1
  944.  
  945. ;    cpi    Type6
  946. ;    jrz    do$type$6
  947. ;    jnc    do$type$7    ; MSB of sector(byte) set for 2nd side of disk
  948.  
  949.     cpi    Type7
  950.     jz    do$type$7    ; MSB of sector(byte) set for 2nd side of disk
  951. ;
  952. ;    only types 0 to 2 and 7 are currenty defined
  953. ;        Type3 to Type6 will do Type2
  954. ;do$type$3:
  955. ;do$type$6:
  956.  
  957. do$type$2:
  958.     mov    b,a        ; save a copy in B
  959.     sui    40
  960.     jrc    do$type$0    ; jump if still on side 0
  961.     mvi    a,79        ; on back side count 39,38,37,...,0
  962.     sub    b
  963. set$trk:
  964.     mvi    d,80h        ; D=side # (1)
  965.     sta    @trk
  966.     jr    do$type$0
  967.  
  968.     page
  969. ;
  970. ;    divide the track number by two and if Head=1
  971. ;        add #sect/side to @sect
  972. ;
  973. do$type$1:
  974.     cmc            ; carry was set clear it
  975.     rar            ; divide track by 2 (carry gets LSB)
  976.     sta    @trk
  977.     jrnc    do$type$0
  978.     call    get$max$num$b    ; HL and C changed
  979.     lda    @sect
  980.     add    b
  981.     sta    @sect
  982.  
  983. do$type$0:
  984.     lda    @trk
  985.     sta    vic$trk
  986.     call    get$max$num$b    ; B=number of sectors per track per side
  987.     lda    @sect        ; ..HL and C changed
  988.     cmp    b
  989.     jrc    is$side$0
  990.     mvi    d,80h        ; D=side # (1)
  991.     bit    C1$bit,e    ; dsk$info in E
  992.                 ; sector numbering continues on side 1 ?
  993.     jrnz    is$side$0    ; yes, do not remove side one bias
  994.     sub    b        ; no, remove side one bias
  995. is$side$0:
  996.     mov    c,a        ; hold @sect in C    
  997.     mov    a,e        ; get dsk$info to A
  998.     ani    S1        ; A=Starting  sector number (0 or 1)
  999.     add    c        ; add back @sect
  1000.     ora    d        ; add in the side bit
  1001.     sta    vic$sect
  1002.     ret
  1003.  
  1004.     page
  1005. ;
  1006. ;    input:
  1007. ;        DE = number bytes to read
  1008. ;        HL = DMA address
  1009. ;
  1010.     CSEG
  1011. rd$1571$data:
  1012.     lda    @dbnk            ; get the disk DMA bank
  1013.     call    ?bank            ; set it
  1014.  
  1015.     lxi    b,0DC0Dh        ; D1ICR
  1016. rd$1571$stat$wait:
  1017.     inp    a
  1018.     ani    8            ; data ready bit set?
  1019.     jrz    rd$1571$stat$wait    ; no, loop
  1020.  
  1021.     mvi    c,0ch            ; D1SDR
  1022.     inp    a            ; read the status byte
  1023.     sta    vic$data        ; save it
  1024.     ani    0eh            ; any errors ?
  1025.     jrnz    rd$1571$exit        ; yes, exit
  1026.  
  1027.     lxi    b,0DD00h
  1028.     inp    a            ; get current clock polarity
  1029.  
  1030. rd$1571$next:
  1031.     lxi    b,0DD00h        ; D2PRA
  1032.     xri    10h            ; toggle clk$bit
  1033.     outp    a            ; clock the 1571 for a byte
  1034.  
  1035.     dcr    e            ; DE=count
  1036.     jnz    rd$1571$more        ; leave as normal jump to keep
  1037.     dcr    d            ; the transfer speed at it's max
  1038.     jrz    rd$1571$exit        ; ...
  1039.  
  1040. ;
  1041. rd$1571$more:
  1042.     dcr    b
  1043. rd$1571$wait:
  1044.     mvi    c,0dh            ; D1ICR (DC0Dh)
  1045.     inp    c
  1046.     bit    3,c
  1047.     jz    rd$1571$wait
  1048.     mvi    c,0ch            ; D1SDR
  1049.     ini                ; (hl) <- (bc) ; hl <- hl+1 ; b <- b-1
  1050.     jmp    rd$1571$next
  1051.  
  1052.  
  1053. rd$1571$exit:
  1054.     sta    bank$0            ; restore current mem config
  1055.     ret
  1056.  
  1057.     page
  1058.  
  1059. clk$in    equ    40h
  1060. ;
  1061. ;    input:
  1062. ;        DE = number of bytes to write
  1063. ;        HL = DMA address
  1064. ;
  1065. wr$1571$data:
  1066.     call    ?di$int
  1067. ; do spout inline
  1068.     lxi    b,mode$reg
  1069.     mvi    a,fast$wr$en
  1070.     sta    io$0
  1071.     outp    a            ; set data direction to output
  1072.     sta    bank$0
  1073.  
  1074.     lxi    b,0dc05h        ; low (D1T1h)
  1075.     xra    a
  1076.     outp    a
  1077.     dcr    c            ; low(D1T1l)
  1078.     mvi    a,3            ; clk = osc/3
  1079.     outp    a            ;
  1080.  
  1081.     mvi    c,0eh            ; D1CRA
  1082.     inp    a
  1083.     ani    80h
  1084.     ori    55h
  1085.     outp    a
  1086.     dcr    c            ; D1ICR
  1087.     inp    a
  1088.  
  1089.     lda    @dbnk            ; get the disk DMA bank
  1090.     call    ?bank            ; set it
  1091.  
  1092.     mvi    a,clk$in
  1093.     sta    cur$clk
  1094.  
  1095.     page
  1096. ;
  1097. ;
  1098. clk$wait:
  1099.     lxi    b,0dd00h        ; D2PRA
  1100.     inp    a
  1101.     inp    c            ; debounce
  1102.     cmp    c
  1103.     jrnz    clk$wait
  1104.  
  1105.     lda    cur$clk            ; get old clk value
  1106.     xra    c            ; check if changed 
  1107.     ani    clk$in            ; (only clock in bit)
  1108.     jrz    clk$wait        ; loop if not
  1109.  
  1110.     mov    a,c            ; 
  1111.     sta    cur$clk            ; make this the current clk value
  1112.     lxi    b,0dc0ch        ; D1SDR
  1113.     mov    a,m
  1114.     outp    a            ; send character to drive
  1115.     inx    h            ; advance pointer
  1116.     dcx    d            ; dec the char count
  1117.  
  1118.     inr    c            ; D1ICR
  1119. send$wait:
  1120.     inp    a
  1121.     ani    8
  1122.     jz    send$wait
  1123.  
  1124.     mov    a,d
  1125.     ora    e
  1126.     jnz    clk$wait        ; go send the next byte
  1127.  
  1128. ; do spin
  1129.     lxi    b,0DC0Eh        ; D1CRA
  1130.     inp    a
  1131.     ani    80h
  1132.     ori    8
  1133.     outp    a
  1134.     lxi    b,mode$reg
  1135.     mvi    a,fast$rd$en
  1136.     sta    io$0            ; enable the MMU
  1137.     outp    a            ; set data direction to input
  1138.     sta    bank$0            ; disable MMU
  1139. ; spin done
  1140.  
  1141.     page
  1142.  
  1143.     lxi    b,0DC0Dh        ; D1ICR
  1144.     inp    a            ; clear data pending flag
  1145.  
  1146.     lxi    b,0DD00h        ; D2PRA
  1147.     inp    a
  1148.     ori    10h            ; set clk$bit low (hardware inverted)
  1149.     outp    a            ; 
  1150.  
  1151.     lxi    b,0DC0Dh        ; D1ICR
  1152. wait$status:
  1153.     inp    a
  1154.     ani    8
  1155.     jrz    wait$status
  1156.  
  1157.     lxi    b,0DC0Ch        ; D1SDR
  1158.     inp    d
  1159.  
  1160.     lxi    b,0DD00h        ; D2PRA
  1161.     inp    a
  1162.     ani    not(10h)        ; set clk$bit hi (hardware inverted)
  1163.     outp    a            ; 
  1164.  
  1165.     mov    a,d            ; recover the status byte
  1166.     sta    vic$data
  1167.  
  1168.     ei
  1169.     ret
  1170.  
  1171.     page
  1172. ;
  1173. ;    This routine is used to move a sector of data
  1174. ;     to/from the sector buffer and the DMA pointer.
  1175. ;         A=0 for buffer to DMA  (disk read)
  1176. ;         A<>0 for DMA to buffer (disk write)
  1177. ;
  1178.     CSEG
  1179. ?dkmov:
  1180.     lhld    local$DMA    ; current DMA adr
  1181.     lxi    d,@buffer    ; location of disk read/write buffer
  1182.     lxi    b,256        ; sector size
  1183. ;
  1184. ;
  1185. dk$cont:
  1186.     ora    a
  1187.     jrnz    dsk$read    ; swap pointer for read
  1188.     xchg
  1189. ;
  1190. ;
  1191. dsk$read:
  1192.     lda    @dbnk        ; get the disk bank
  1193.     call    ?bank
  1194.     ldir            ; do the data move
  1195.     sta    bank$0        ; current bank will ALWAYS be 0
  1196.     ret
  1197.  
  1198. ;
  1199. ;
  1200. ;
  1201.     DSEG
  1202. dsk$fun:
  1203.     sta    vic$cmd
  1204.     call    disp$dsk$info        ; yes, go display disk info
  1205.     jmp    ?fun65+3        ; go do the function
  1206.  
  1207.     page
  1208. ;
  1209. ;*****************************************************************
  1210. ;
  1211.     DSEG
  1212. ?dskst:
  1213. disp$dsk$info:
  1214.     mvi    a,72            ; r/w in col 72 (col 0-79)
  1215.     sta    offset
  1216.     lda    vic$cmd
  1217.     mvi    b,'R'
  1218.     dcr    a            ; ?1 normal$rd
  1219.     jrz    out$cmd$rd
  1220.     dcr    a            ; ?2 normal$wr
  1221.     jrz    out$cmd$wr
  1222.     dcr    a            ; ?3 fast$rd
  1223.     jrz    out$cmd$rd
  1224.     dcr    a            ; ?4 fast$wr
  1225.     rnz
  1226. out$cmd$wr:
  1227.     mvi    b,'W'
  1228. out$cmd$rd:
  1229.     call    disp$B
  1230.     call    disp$space
  1231.     mvi    b,'A'-1
  1232.     lda    vic$drv
  1233. next$drv:
  1234.     inr    b
  1235.     rrc
  1236.     jrnc    next$drv
  1237.  
  1238.     call    disp$B
  1239.     lda    vic$trk
  1240.     call    disp$dec
  1241.     lda    vic$sect
  1242.     ani    80h
  1243.     cz    disp$space
  1244.     mvi    b,'-'
  1245.     cnz    disp$B
  1246.     lda    vic$sect    
  1247.     ani    7fh
  1248.  
  1249.     page
  1250. ;
  1251. ;
  1252. ;
  1253. disp$dec:
  1254.     mvi    b,'0'-1
  1255.  
  1256. conv$loop:
  1257.     inr    b
  1258.     sui    10
  1259.     jrnc    conv$loop
  1260.  
  1261.     adi    '0'+10
  1262.     push    psw
  1263.     call    disp$B
  1264.     pop    psw
  1265. disp$A:
  1266.     mov    b,a
  1267. disp$B:
  1268.     lda    offset
  1269.     mov    c,a            ; col # in C
  1270.     inr    a
  1271.     sta    offset            ; advance cursor position
  1272.     xra    a            ; no attribute to write
  1273.     call    ?stat
  1274.  
  1275.     xra    a
  1276.     ret
  1277.  
  1278. disp$space:
  1279.     mvi    b,' '
  1280.     jr    disp$B
  1281.  
  1282.     page
  1283.  
  1284. ;*****************************************************************
  1285. ;
  1286. ; Extended Disk Parameter Headers (XDPHs)
  1287. ;
  1288.     CSEG            ; place tables in common
  1289. ;
  1290. ;    1st disk drive on the system
  1291. ;
  1292.     dw    write$154X
  1293.     dw    read$154X
  1294.     dw    login$154X
  1295.     dw    init$154X
  1296.     db    1        ; bit 0 set (drive 0)
  1297.     db    dsk$c128    ; format type byte
  1298. cmdsk0:    
  1299.     dph    0,dpb$0
  1300.  
  1301. dpb$0:
  1302.     dpb    1024,1,1360,2048,128,0
  1303.     db    0        ; max sector number and lock flag
  1304.     dw    0        ; MFM table pointer
  1305.  
  1306.     page
  1307. ;
  1308. ;    2nd disk Drive on the system
  1309. ;
  1310.     dw    write$154X
  1311.     dw    read$154X
  1312.     dw    login$154X
  1313.     dw    init$154X
  1314.     db    2        ; bit 1 set (drive 1)
  1315.     db    dsk$c128    ; format type byte 
  1316. cmdsk1:
  1317.     dph    0,dpb$1
  1318.  
  1319. dpb$1:
  1320.     dpb    1024,1,1360,2048,128,0
  1321.     db    0        ; max sector number and lock flag
  1322.     dw    0        ; MFM table pointer
  1323.  
  1324.     page
  1325. ;
  1326. ;    3rd disk drive on the system
  1327. ;
  1328.     dw    write$154X
  1329.     dw    read$154X
  1330.     dw    login$154X
  1331.     dw    init$154X
  1332.     db    4        ; bit 2 set (drive 2)
  1333.     db    dsk$c128    ; format type byte
  1334. cmdsk2:    
  1335.     dph    0,dpb$2
  1336.  
  1337. dpb$2:
  1338.     dpb    1024,1,1360,2048,128,0
  1339.     db    0        ; max sector number and lock flag
  1340.     dw    0        ; MFM table pointer
  1341.  
  1342.     page
  1343. ;
  1344. ;    NOTE: The blocking factor for all of these formats is
  1345. ;        1K (2K for double sided), thus the fractional
  1346. ;        parts are unusable by CP/M.  They can be accessed
  1347. ;        by absolute sector addressing.
  1348. ;
  1349. ;    NOTE: 1571 and 1541 disk drives use track numbers
  1350. ;        of 1 to 35 and sector numbers of 0 to nn
  1351.  
  1352. ;
  1353. ;        The method used to access the full disk
  1354. ;        is to tell the system that there is 1 sector
  1355. ;        per track and then to use the track # as an
  1356. ;        absolute sector address and do conversion in BIOS.
  1357. ;
  1358. ; 
  1359. ; DPB FOR C128 CP/M 3.0 disk        ( 170K, 34K larger then C64 CP/M)
  1360. ;    256 byte sectors        ( 170.75K )
  1361. ;    1 sectors/track
  1362. ;        up to 21 physical sectors (0 to 16,17,18 or 20)
  1363. ;    680 tracks/disk (usable, 683 real)
  1364. ;        35 physical tracks (0 to 34)
  1365. ;    1K allocation blocks
  1366. ;    64 directory entries
  1367. ;    track offset of 2 (2 sectors) (handled by set$up$c128)
  1368. ;
  1369.     DSEG        ; these tables are moved to common when used
  1370. dpb$c128$SS:
  1371.     dpb    1024,1,170,1024,64,0
  1372.  
  1373.     page
  1374. ;
  1375. ; DPB FOR C128 CP/M 3.0 double sided disk    ( 340K )
  1376. ;    256 byte sectors            ( 341.5K )    
  1377. ;    1 sectors/track
  1378. ;        up to 21 physical sectors (0 to 16,17,18 or 20)
  1379. ;    1360 tracks/disk (usable, 1366 real)
  1380. ;        70 physical tracks (0 to 34 side 0, 35 to 69 side 1)
  1381. ;    2K allocation units
  1382. ;    128 directory entrys
  1383. ;    track offset of 1 (1 sectors) taken care of in set$up$c128
  1384. ;
  1385. dpb$c128$DS:
  1386.     dpb    1024,1,340,2048,128,0
  1387.  
  1388.     page
  1389. ;
  1390. ; DPB FOR C64 CP/M 2.2 disk --             ( 136K )
  1391. ;    256 byte sectors
  1392. ;    17 sectors / tracks    (sector numbering 0-16)
  1393. ;        sector 18 to n on the outer tracks are unused
  1394. ;    34 tracks / disk
  1395. ;        tracks track 2 to 16    (track numbering 0-34)
  1396. ;        track 17 is the C128 directory track (not counted)
  1397. ;        track 19 to 34
  1398. ;    1K allocation blocks
  1399. ;    64 directory entrys
  1400. ;    track offset of 2 (1st two tracks used for CP/M 2.2 boot)
  1401. ;
  1402. dpb$c64$cpm:
  1403.     dpb    256,17,34,1024,64,2
  1404.                 
  1405.     page
  1406. ;
  1407.     DSEG
  1408. MFM$table:
  1409.     db    S256*2+(16*2-8)+1    ; 256 byte sect, 16 sect/trk
  1410.     db    MFM+S256+Type0+C0+S1    ;     DSDD
  1411.     dw    0            ; start on track 4 sect 1 (2 alc)
  1412.     dpb    256,32,40,2048,128,2    ; sect# 1 to 16
  1413.     db    16            ; (top and bottom numbered the same)
  1414.     db    'Epson QX10'        ;1 Epson QX10
  1415.  
  1416.  
  1417.  
  1418.  
  1419.  
  1420.     db    80h+S512*2+(10*2-8)+1    ; 512 byte sect, 10 sect/trk
  1421. ;    db    S256*2            ; track 0 is 256 bytes/sector
  1422.     db    MFM+S512+Type0+C0+S1    ;    DSDD
  1423.     dw    0            ; start on track 2 sect 1 (2 alc)
  1424.     dpb    512,20,40,2048,128,2    ; sect# 1 to 10
  1425.     db    10            ; (top and bottom numbered the same)
  1426.     db    'Epson QX10'        ;2
  1427.  
  1428.     page
  1429.  
  1430.     db    S512*2+(8*2-8)+1    ; 512 byte sect 8 sect/trk
  1431.     db    MFM+S512+Type2+C0+S1    ;     SSDD
  1432.     dw    0            ; start on track 1 sector 1 (2 alc)
  1433.     dpb    512,8,40,1024,64,1    ; sect# 1 to 8
  1434.     db    8            ;
  1435.     db    ' IBM-8 SS '        ;3
  1436.  
  1437.  
  1438.  
  1439.  
  1440.  
  1441.     db    S512*2+(8*2-8)+1    ; 512 byte sect 8 sect/trk
  1442.     db    MFM+S512+Type2+C0+S1    ;     DSDD
  1443.     dw    0            ; start on track 1 sector 1 (1 alc)
  1444.     dpb    512,8,80,2048,64,1    ; sect# 1 to 8
  1445.     db    8            ; (top and bottom numbered the same)
  1446.     db    ' IBM-8 DS '        ;4
  1447.  
  1448.     page
  1449.  
  1450.     db    S512*2+(10*2-8)+0    ; 512 byte sector, 10 sect/trk
  1451.     db    MFM+S512+Type1+C1+S0    ;    DSDD
  1452.     dw    0            ; start on track 0 sector 10 (2 alc)
  1453.     dpb    512,10,80,2048,128,1    ; sect# 0 to 9 on top (even tracks)
  1454.     db    10            ; sect# 10 to 19 on bottom (odd tracks)
  1455.     db    'KayPro IV '        ;5
  1456.  
  1457.  
  1458.  
  1459.  
  1460.  
  1461.     db    S512*2+(10*2-8)+0    ; 512 byte sect, 10 sect/trk
  1462.     db    MFM+S512+Type0+C1+S0    ;     SSDD
  1463.     dw    0            ; start on track 1 sector 0 (4 alc)
  1464.     dpb    512,10,40,1024,64,1    ; sect# 0 to 9 
  1465.     db    10            ;
  1466.     db    'KayPro II '        ;6
  1467.  
  1468.     page
  1469.  
  1470.     db    S1024*2+(5*2-8)+1    ; 1024 byte sect, 5 sect/trk
  1471.     db    MFM+S1024+Type0+C0+S1    ;     SSDD
  1472.     dw    0            ; start on track 3 sector 1 (2 alc)
  1473.     dpb    1024,5,40,1024,64,3    ; sect# 1 to 5
  1474.     db    5            ;
  1475.     db    'Osborne DD'        ;7
  1476.  
  1477.  
  1478.  
  1479.  
  1480.     db    S512*2+(9*2-8)+1    ; 512 byte sect 9 sect/track (uses 8)
  1481.     db    MFM+S512+Type1+C0+S1    ;     DSDD
  1482.     dw    0            ; start on trk 0, sect 1, hd 1 (1 alc)
  1483.     dpb    512,8,80,2048,64,1    ; sect# 1 to 9
  1484.     db    8            ; (top and bottom numbered the same)
  1485.     db    '  Slicer  '        ;8
  1486.  
  1487.     page
  1488.  
  1489.     db    S256*2+(16*2-8)+1    ; 256 byte sect, 16 sect/trk
  1490.     db    MFM+S256+Type0+C0+S1    ;     DSDD
  1491.     dw    0            ; start on track 4 sect 1 (2 alc)
  1492.     dpb    256,32,40,2048,128,4    ; sect# 1 to 16
  1493.     db    16            ; (top and bottom numbered the same)
  1494.     db    'Epson Euro'        ;1 Epson European (MFCP/M ?)
  1495.  
  1496.  
  1497.  
  1498.  
  1499.  
  1500.     db    -1
  1501.     db    MFM            ; 
  1502.     dw    0            ; 
  1503.     dpb    512,20,40,2048,128,2    ; 
  1504.     db    8            ;
  1505.     db    '   None   '        ;10
  1506.  
  1507.     page
  1508.  
  1509.     db    -1
  1510.     db    MFM            ; 
  1511.     dw    0            ; 
  1512.     dpb    512,20,40,2048,128,2    ; 
  1513.     db    8            ;
  1514.     db    '   None   '        ;11
  1515.  
  1516.     db    -1
  1517.     db    MFM            ; 
  1518.     dw    0            ; 
  1519.     dpb    512,20,40,2048,128,2    ; 
  1520.     db    8            ;
  1521.     db    '   None   '        ;12
  1522.  
  1523.     page
  1524.  
  1525.     db    -1
  1526.     db    MFM            ; 
  1527.     dw    0            ; 
  1528.     dpb    512,20,40,2048,128,2    ; 
  1529.     db    8            ;
  1530.     db    '   None   '        ;13
  1531.  
  1532.     db    -1
  1533.     db    MFM            ; 
  1534.     dw    0            ; 
  1535.     dpb    512,20,40,2048,128,2    ; 
  1536.     db    8            ;
  1537.     db    '   None   '        ;14
  1538.  
  1539.     page
  1540.  
  1541.     db    -1
  1542.     db    MFM            ; 
  1543.     dw    0            ; 
  1544.     dpb    512,20,40,2048,128,2    ; 
  1545.     db    8            ;
  1546.     db    '   None   '        ;15
  1547.  
  1548.     db    -1
  1549.     db    MFM            ; 
  1550.     dw    0            ; 
  1551.     dpb    512,20,40,2048,128,2    ; 
  1552.     db    8            ;
  1553.     db    '   None   '        ;16
  1554.  
  1555.  
  1556.     page
  1557. ;
  1558. ;    not functional yet
  1559. ;
  1560.  
  1561. ;    db    S1024*2+(5*2-8)+1    ; 1024 byte sect 5 sect/track
  1562. ;    db    MFM+S1024+Type0+C0+S1    ;     SSDD
  1563. ;    dw    0            ; start on trk 2, sect 1 (2 alc)
  1564. ;    dpb    1024,5,40,2048,128,2    ; sect# 1 to 5
  1565. ;    db    5            ;
  1566. ;    db    'Morrow MD2'        ; 
  1567.  
  1568.  
  1569.  
  1570.  
  1571.  
  1572. ;    db    S1024*2+(5*2-8)+1    ; 1024 byte sect  5 sect/trk
  1573. ;    db    MFM+S1024+Type0+C0+S1    ;     DSDD
  1574. ;    dw    0            ; start on trk 1, sect 1, hd 0 (3 alc)
  1575. ;    dpb    1024,10,40,2048,192,1    ; sect# 1 to 5
  1576. ;    db    5            ;
  1577. ;    db    'Morrow MD3'        ; 
  1578.  
  1579.  
  1580. MFM$tbl$entries    equ    ($-MFM$table)/32
  1581.  
  1582.     db    -1
  1583.     db    -1
  1584.  
  1585.     page
  1586.  
  1587.     cseg
  1588. cur$clk:    ds    1
  1589.  
  1590.     dseg
  1591. lock$flag    ds    1
  1592. last$match    ds    2
  1593. window$info:    ds    2
  1594.  
  1595. dsk$window    equ    12
  1596.  
  1597. no$dsk$msg:
  1598.         ;1234567890
  1599.     db    ' Missing  ' 
  1600.  
  1601.  
  1602. MFM$match$tbl:
  1603.     ds    2*MFM$tbl$entries    ; MFM$count MUST follow this parm
  1604. MFM$count:
  1605.     ds    1            ; MFM$offset MUST follow this parm
  1606. MFM$offset:
  1607.     ds    1
  1608.  
  1609. MFM$cur$ptr:
  1610.     ds    2
  1611.  
  1612. DPH$pointer:
  1613.     ds    2
  1614.  
  1615. sect$cnt:
  1616.     ds    1
  1617. sect$buf$ptr:
  1618.     ds    2
  1619. sect$buffer:
  1620.     ds    4*2
  1621.  
  1622. local$DMA:
  1623.     ds    2
  1624.  
  1625. status$atr    equ    0
  1626. offset:        db    0
  1627.  
  1628.     end
  1629.  
  1630. ct$cnt:
  1631.     ds    1
  1632. sect$buf$ptr:
  1633.     ds    2
  1634. sect$buffer:
  1635.     ds    4*2
  1636.  
  1637. local$DMA:
  1638.     ds    2
  1639.  
  1640. status$atr    equ    0
  1641. offse