home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / ENTERPRS / CPM / UTILS / A / BIOS-R62.LZH / CXIO.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  25KB  |  1,311 lines
  1. ; BIOS-R6
  2. ; 1/27/93
  3. ; Randy Winchester
  4. ;
  5. ; code in this module was modified to set the screen up for 80 col 
  6. ; automaticly, all 40 column code has been deleted.  the label NULL40 is
  7. ; still maintained in the device table as removing it would change
  8. ; the subsequent device numbers, affecting the use of RS-232 (it would
  9. ; require rewrites of all modem programs)
  10. ; code at the label ?rlccp has been added to reset the feel and repeat
  11. ; rate at every warm start, this corrects problems that arise after 
  12. ; terminating a modem program. 
  13. ;
  14. ; Code has been added to allow setting the cursor flash rate and shape,
  15. ; set the temporary drive, and the drive search chain.
  16. ; 
  17. ; Code has been added to require a password to be entered before the
  18. ; system finishes initialization, 3 trys are allowed, the system locks
  19. ; up if you fail all three.
  20. ;
  21. ; A label has been added to allow the 6551 init code to install baud
  22. ; rates based on the value in DEVTBL.
  23. ;
  24. ; User assumes _ALL_ liability for the use of this module. Original 
  25. ; Copyright is still maintained by Commodore
  26. ;
  27. ; Code to set cursor and drive chain; Copyright April 26, 1987 by
  28. ;    James W. Waltrip IV
  29. ;------------------------------------------------------------------------
  30. ; *ADDITIONS BY Randy Winchester, 5/6/89
  31. ;
  32. ; Default printer is device 4.
  33. ;
  34. ; Set up for non-flashing block cursor
  35. ;
  36. ; Drive Search chain/temp drive default values:  
  37. ; A:,logged drive, temp drive = A:
  38. ;
  39. ; Drive F: is reserved for a Quick Brown Box battery powered RAM cartridge.
  40. ; The QBB is initialized with QD.COM from Herne Data Systems, Ltd.
  41. ;
  42. ; No password protection for booting the system.
  43. ;
  44. ; Colors set in sign-on message.  Background=light grey, character=blue
  45. ;
  46. ; Default system baud rate set for 75 baud.  This speeds up normal operation
  47. ; considerably.
  48. ;
  49. ; Printer names set to PRT-D4 and PRT-D5 (devices 4 and 5)
  50. ;
  51. ; 1/27/93
  52. ; Added code to reset default baud rate on reload of CCP.  See
  53. ; code at ?rlccp.
  54. ;
  55. ;-------------------------------------------------------------------------
  56. ;
  57.     title    'C128 BIOS, main I/O and sys functions     6 May   89'
  58.  
  59. ;
  60. ;    This module contains CXIO,CXINIT,CXMOVE and CXTIME.
  61. ;
  62.     maclib    cpm3
  63.  
  64.     maclib    z80
  65.  
  66.     maclib    cxequ
  67.  
  68.     maclib    modebaud
  69.  
  70. ;**********************************************************
  71.  
  72.     extrn    repeat            ; repeat rate
  73.  
  74. repeat$amt    equ    2
  75.  
  76.     extrn    delay            ; delay before repeat
  77.  
  78. delay$amt    equ    16
  79.  
  80.  
  81. printnum    equ    010h        ; printer device to init
  82.                     ; Device 4 = 010h (16 decimal)
  83.                     ; Device 5 = 08
  84.  
  85. pass        equ    false        ; set to 'false' if password
  86.                      ; protection not wanted
  87.  
  88. pass$word    macro
  89.  
  90.     db    'PASS'                ; password is defined here
  91. ;                                       ; if using lower case letters
  92. ;                    ; use the HEX values rather than
  93. ;                    ; the characters themselves
  94. ;                    ; ie.-> 061h  instead of 'a'
  95.         endm
  96.  
  97. ;*************************************************************
  98.     public    ?init,?ldccp,?rlccp
  99.  
  100.     public    ?user,?di$int
  101.  
  102.     extrn    ?sysint
  103.  
  104. bdos    equ    5    
  105.     
  106.     extrn    @civec,@covec,@aivec,@aovec,@lovec
  107.     extrn     ?bnksl
  108.  
  109.     public    ?cinit,?ci,?co,?cist,?cost
  110.     public    @ctbl
  111.     extrn    ?kyscn
  112.  
  113. ; Utility routines in standard BIOS
  114.     extrn    ?wboot        ; warm boot vector
  115.     extrn    ?pmsg        ; print message @<HL> up to 00
  116.                 ; saves <BC> & <DE>
  117.     extrn    ?pdec        ; print binary number in <A> from 0 to 99.
  118.     extrn    ?pderr        ; print BIOS disk error header
  119.     extrn    ?conin,?cono    ; con in and out
  120.     extrn    ?const        ; get console status
  121.  
  122.     extrn    @hour,@min,@sec,@date,?bnksl
  123.     public    ?time
  124.  
  125.     page
  126. ;
  127. ;    keyboard scanning routine 
  128. ;
  129.     extrn    ?get$key,?int$cia
  130.     extrn    Fx$V$tbl
  131. ;
  132. ;    links to 80 column display
  133. ;
  134.     extrn    ?out80,?int80
  135.  
  136.     extrn    ?pt$i$1101,?pt$o$1,?pt$o$2
  137.  
  138. ;
  139. ;    bios8502 function routines
  140. ;
  141.     public    ?fun65
  142.  
  143. ;
  144. ;
  145. ;
  146.     public    X6551$baud
  147.     extrn    ?int65,?in65,?ins65,?out65
  148.     extrn    @drcha,@drchb,@drchc,@drchd,@tpdrv
  149.  
  150.  
  151.     DSEG
  152. ?fun65:
  153.     sta    vic$cmd            ; save the command passed in A
  154.  
  155. fun$di$wait:
  156.     lda    RS232$status
  157.     ani    01000010b        ; transmitting or receiving ?
  158.     jrnz    fun$di$wait        ; yes, wait for int to clean up
  159.     di
  160.     lda    force$map        ; get current MMU configuration
  161.     push    psw            ; save it
  162.     sta    io$0            ; make I/O 0 current
  163.     
  164.     lxi    d,1            ; D=0,  E=1
  165.     lxi    b,page$1$h
  166.     outp    d
  167.     dcr    c
  168.     outp    e            ; page 1, 0-1
  169.     dcr    c
  170.     outp    d
  171.     dcr    c
  172.     outp    d            ; page 0, 0-0
  173.     call    enable$6502+6        ; go run the 8502
  174.     mvi    c,low(page$1$h)
  175.     outp    e
  176.     dcr    c
  177.     outp    e            ; page 1, 1-1
  178.     dcr    c
  179.     outp    e
  180.     dcr    c
  181.     outp    d            ; page 0, 1-0
  182.  
  183.     pop    psw            ; recover the MMU config.
  184.     sta    force$map        ; restore it
  185.     ei                ; turn interrupts back on
  186.     lda    vic$data        ; get command results
  187.     ora    a            ; set the zero flag if A=0
  188.     ret
  189.  
  190. ?di$int:
  191.     push    psw
  192. di$int$1:
  193.     lda    RS232$status
  194.     ani    01000010b        ; transmitting or receiving ?
  195.     jrnz    di$int$1        ; yes, wait for int to clean up
  196.     pop    psw
  197.     di
  198.     ret
  199.  
  200.     page
  201. ;
  202. ;    set up the MMU for CP/M Plus
  203. ;
  204.     DSEG            ; init done from banked memory
  205. ?init:
  206.     mvi    a,3eh            ; force MMU into I/O space
  207.     sta    force$map        ;
  208.     lxi    h,mmu$table+11-1    ; table of 11 values
  209.     lxi    b,mmu$start+11-1    ; to to MMU registers
  210.     mvi    d,11            ; move all 11 bytes to the MMU
  211.  
  212. init$mmu$loop:
  213.     mov    a,m
  214.     outp    a
  215.     dcx    h
  216.     dcx    b
  217.     dcr    d
  218.     jrnz    init$mmu$loop
  219.  
  220.     mvi    a,1            ; enable track and sector status
  221.     sta    stat$enable        ; on the status line
  222.  
  223. ;    mvi    a,1h            ; no parity, 8 bits, 1 stop bit    
  224.     sta    XxD$config
  225.  
  226.     lxi    h,Fx$V$tbl
  227.     shld    key$FX$function
  228. ;*********************************************************
  229. ;
  230. ; install I/O assignments
  231. ;
  232.     lxi    h,4000h            ; 80 and 40 column drivers
  233.     shld    @covec
  234.     mvi    h,80h
  235.     shld    @civec            ; assign console input to keys
  236.     mvi    h,printnum        ; device # 4
  237.     shld    @lovec            ; assign printer to LPT:
  238.     mvi    h,00h
  239.     shld    @aivec
  240.     shld    @aovec            ; assign rdr/pun port
  241.  
  242. ;
  243. ; init SCB
  244. ;
  245.     mvi    a,01h            ; The following instr. set up the
  246.     sta    @drcha            ; Drive Search Chain, and the Temp. 
  247.     sta    @tpdrv            ; Drive.  This replaces the command
  248.     mvi    a,0            ; SETDEF A:,* [TEMP=A:]
  249.     sta    @drchb            ; A: = 01h, B: = 02h, C: = 03h, etc.
  250.     mvi    a,0ffh            ; 0ffh = filler byte
  251.     sta    @drchc
  252.     mvi    a,0ffh            ;
  253.     sta    @drchd
  254. ;
  255. ; Where are the bytes for COM/SUB execution?
  256. ;
  257. ; 80 Col. screen cursor attributes
  258. ;
  259.     lxi    b,0D600h    ; 80 col cmd reg
  260.     mvi    a,010        ; reg 10 of 8563 (cursor type, start scan line)
  261.     outp    a        ; tell 8563 you want reg 10
  262. lx1:                
  263.     inp    a        ; get status
  264.     jp    lx1        ; loop until status good
  265.     lxi    b,0D601h    ; 80 col data reg
  266.     mvi    a,00000000b    ; solid cursor, top scan line
  267.     outp    a
  268. ;
  269.     lxi    b,0D600h
  270.     mvi    a,011        ; reg 11 of 8563 (cursor end scan line)
  271.     outp    a
  272. lx2:
  273.     inp    a
  274.     jp    lx2
  275.     lxi    b,0D601h
  276.     mvi    a,00000111b    ; Bottom scan line = 7
  277.     outp    a
  278. ;
  279.     lxi    b,0D011h    ; Vic controll reg 1
  280.     mvi    a,00001000b    ; turn off Vic
  281.     outp    a
  282. ;
  283.     page
  284. ;
  285. ; print sign on message
  286. ;
  287.     call    prt$msg            ; print signon message
  288.     db    'Z'-'@'            ; home and clear screen (to BG color)
  289.      db    esc,esc,esc,blue+020h    ; blue characters
  290.         db      esc,esc,esc,lt$grey+030h ; light grey background
  291. ;                    123456789012345678901234567890123456789
  292.     db    esc,'=',32+2,32+28,'ZPM3 CP/M+ Compatible OS'
  293.     db    esc,'=',32+3,32+33,'by Simeon Cran'
  294.     db    esc,'=',32+5,32+27,'C128 BIOS Rev 6, 27 Jan 93'
  295.     db    cr,lf,lf,0
  296. ;;*********************************************************
  297.     page
  298.  
  299. ;
  300. ;
  301.     mvi    a,-1            ; set block move to NORMAL mode
  302.     sta    source$bnk
  303. ;
  304. ;    install mode 2 page vectors
  305. ;
  306.     mvi    a,JMP
  307.     sta    INT$vector        ; install a JMP at vector location
  308.     lxi    h,?sysint
  309.     shld    INT$vector+1        ; install int$handler adr
  310. ;
  311. ; A software fix is  required for the lack of hardware to force the
  312. ; LSB of the INT vector to 0. If the bus floats INT VECT could be
  313. ; read as 0FFh; thus ADRh=I (I=0FCh) ADRl=FF for first read, and
  314. ; ADRh=I+1 ADRl=00 for second, to ensure that control is retained
  315. ; 0FD00h will also have FDh in it.
  316. ;
  317.     lxi    h,int$block        ; FC00h
  318.     lxi    d,int$block+1        ; FC01h
  319.     lxi    b,256-1+1        ; interrupt pointer block
  320.     mvi    m,INT$vector/256    ; high and low are equal (FD)
  321.     ldir
  322.     mvi    a,INT$block/256
  323.     stai                ; set interrupt page pointer
  324.     im2                ; enable mode 2 interrupts
  325.  
  326.     page
  327. ;
  328. ;
  329.     mvi    a,vicinit        ; null command just to setup BIOS8502
  330.     call    ?fun65
  331. ;
  332. ;
  333. ;
  334.     lda    sys$freq        ; 0=60Hz 0FFh=50Hz
  335.     ani    80h            ; 0=60Hz 080h=50Hz
  336.     mov    l,a            ; save in L
  337.     lxi    b,cia$1+0eh        ; point to CRA
  338.     inp    a            ; get old config
  339.     ani    7fh            ; clear freq bit
  340.     ora    l            ; add in new freq bit
  341.     outp    a            ; set new config
  342.  
  343.     mvi    c,8            ; start RTC
  344.     outp    a
  345.  
  346.     lxi    h,date$hex
  347.     shld    @date            ; set date to system data
  348.  
  349. ;
  350. ;    setup the sound variables
  351. ;
  352.     lhld    key$tbl
  353.     lxi    d,58*4
  354.     dad    d
  355.     mov    e,m
  356.     inx    h
  357.     mov    d,m
  358.     inx    h
  359.     xchg
  360.     shld    sound1            ; H=SID reg 24, L=SID reg 5
  361.     xchg
  362.     mov    e,m
  363.     inx    h
  364.     mov    d,m
  365.     xchg
  366.     shld    sound2            ; H=SID reg 6, L=SID reg 1
  367.     lxi    h,9
  368.     dad    d
  369.     mov    e,m
  370.     inx    h
  371.     mov    d,m
  372.     xchg
  373.     shld    sound3            ; H=SID reg 4 then L=SID reg 4 
  374. ;
  375. ;    set-up key click sound registers
  376. ;
  377.     lxi    b,sid+7
  378.     lxi    h,0040h
  379.     outp    l            ; (sid+7)=40h
  380.     inr    c
  381.     outp    l            ; (sid+8)=40h
  382.     mvi    c,low(sid+12)
  383.     outp    h            ; (sid+12)=0  Attack=2ms, Decay=6ms
  384.     inr    c
  385.     outp    h            ; (sid+13)=0  Sustain=0,  Release=6ms
  386.     mvi    a,6
  387.     sta    tick$vol        ; set keyclick volumn level
  388.  
  389. ;**********************************************
  390. ;  Password protection routine
  391. ;**********************************************
  392. ;
  393. if    pass
  394. ;
  395.     mvi    a,0
  396.     sta    count
  397. loop1:
  398.     lda    count
  399.     inr    a
  400.     sta    count
  401.     cpi    4
  402.     jnz    over
  403.     call    prt$msg
  404.     db    cr,lf,lf,esc,'G2','Password Error,  System Aborting....',0
  405. there:
  406.     jmp    there
  407. over:
  408.     lxi    h,cmp$string
  409.     push    h
  410.     call    prt$msg
  411.     db    cr,lf,'Password: ',0
  412. lz1:
  413.     call    key$board$in
  414.     pop    h
  415.     cmp    m
  416.     jnz    loop1
  417.     inx    h
  418.     push    h
  419.     mov    a,m
  420.     cpi    0
  421.     jnz    lz1
  422.     call    prt$msg
  423.     db    cr,lf,lf,0
  424. ;
  425. endif
  426. ;
  427.     ret
  428. ;
  429. if    pass
  430. ;
  431. cmp$string:
  432.     pass$word        ;password macro
  433.     db    0
  434. count:
  435.     ds    1
  436. ;
  437. endif
  438. ;
  439. ;***************************************************
  440. ;
  441.  
  442. mmu$table:
  443.     mmu$tbl$M
  444.  
  445.     page
  446. ;
  447. ;
  448. ;
  449.     CSEG
  450. prt$msg:
  451.     xthl
  452.     call    ?pmsg
  453.     xthl
  454.     ret
  455.  
  456.  
  457. ;
  458. ;    placed in common memory to keep IO from stepping on this code
  459. ;        always called from bank 0
  460. ;
  461.     CSEG
  462. read$d505:
  463.     sta    io$0            ; enable MMU (not RAM)
  464.     lxi    b,0d505h
  465.     inp    a            ; read 40/80 column screen
  466.     sta    bank$0            ; re-enable RAM
  467.     ret
  468.  
  469.     page
  470. ;
  471. ;
  472. ;
  473.     DSEG
  474. init$RS232:
  475.     di
  476.  
  477.     xra    a
  478.     sta    RS232$status
  479.     lxi    h,RxD$buf$count        ; clear the count
  480.     mvi    m,0
  481.     inr    l            ; point to RxD$buf$put
  482.     mvi    m,low(RxD$buffer)
  483.     inr    l            ; point to RxD$buf$get
  484.     mvi    m,low(RxD$buffer)
  485.     lxi    h,NTSC$baud$table
  486.  
  487. ;***************************************
  488. ; code to check for NTSC or PAL removed here, system now assumes 
  489. ; that you are using a north american 128 at 60 hz.
  490. ; ***************************************
  491.  
  492. use$NTSC:
  493.     lda    RS232$baud
  494.     cpi    baud$1200        ; baud rate less then 1200 baud
  495.     jrc    baud$ok            ; yes, go set it
  496.     mvi    a,baud$1200        ; no, 1200 baud is the max
  497.     sta    RS232$baud        ; (change to 1200 baud)
  498.  
  499. baud$ok:
  500.     mov    e,a
  501.     mvi    d,0
  502.     dad    d            ; +1X
  503.     dad    d            ; +1X
  504.     dad    d            ; +1X = +3X
  505.     mov    e,m
  506.     inx    h
  507.     mov    d,m
  508.     inx    h            ;
  509.     mov    a,m            ; get rate #
  510.     sta    int$rate        ;
  511.  
  512.     lxi    b,CIA1+timer$b$low    ;
  513.     outp    e            ;
  514.     inr    c            ; point to timer$b$high
  515.     outp    d            ;
  516.  
  517.     mvi    a,11h            ;
  518.     mvi    c,CIA$ctrl$b        ; turn on timer B
  519.     outp    a            ;
  520.  
  521.     lxi    b,CIA2+data$b        ; setup user port for RS232
  522.     inp    a            ; get old data
  523.     ori    6            ; set CTS and DTR
  524.     outp    a            ; update it
  525.     ei
  526.     ret
  527.  
  528.     page
  529. ;
  530. ;    NTSC rates (1.02273 MHz)
  531. ;
  532. NTSC$baud$table:
  533.     dw    6818            ; no baud rate     (6666.47)
  534.     db    1
  535.     dw    6818            ; 50    6666.7us (6666.47)
  536.     db    1
  537.     dw    4545            ; 75    4444.4us (4443.99)
  538.     db    1
  539.     dw    3099            ; 110    3030.3us (3030.13)
  540.     db    1
  541.     dw    2544            ; 134    2487.6us (2487.46)
  542.     db    1
  543.     dw    2273            ; 150    2222.2us (2222.48)
  544.     db    2
  545.     dw    1136            ; 300    1111.1us (1110.75)
  546.     db    3
  547.     dw    568            ; 600     555.6us ( 555.38)
  548.     db    6
  549.     dw    284            ; 1200     277.8us ( 277.69)
  550.     db    12
  551.  
  552. ;****************************************************
  553. ; PAL baud table removed from here (redundant, as it is not checked for
  554. ; or used)
  555. ;******************************************************
  556.  
  557.     page
  558. ;
  559. ;
  560. ;
  561. out$RS232:
  562.     lda    RS232$status
  563.     ani    80h
  564.     jrnz    out$RS232
  565.     mov    a,c
  566.     sta    xmit$data        ; get character to send in A
  567.     lxi    h,RS232$status
  568.     setb    7,m            ; set Xmit request bit
  569.     ret
  570.  
  571. ;
  572. ;
  573. ;
  574. out$st$RS232:
  575.     lda    RS232$status
  576.     ani    80h            ; bit 8 set if busy
  577.     xri    80h            ; A cleared if busy (=80h if not)
  578.     rz
  579.     ori    0ffh            ; A=ff if ready (not busy)
  580.     ret
  581.  
  582. ;
  583. ;
  584. ;
  585. in$RS232:
  586.     lda    RS232$status
  587.     ani    1
  588.     jrz    in$RS232
  589.     lda    recv$data
  590.     lxi    h,RS232$status
  591.     res    0,m
  592.     ret
  593.  
  594. ;
  595. ;
  596. ;
  597. in$st$RS232:
  598.     lda    RS232$status
  599.     ani    1
  600.     rz
  601.     ori    0ffh            ; set data ready (-1)
  602.     ret
  603.  
  604.     page
  605. ;
  606. ;    this routine is used to provide the user with a method
  607. ;    of interfacing with low level system functions
  608. ;
  609.     CSEG
  610. ;
  611. ;    input:
  612. ;        all registers except HL and A are passed to function
  613. ;
  614. ;    output:
  615. ;        all resisters from function are preserved
  616. ;
  617. ?user:
  618.     shld    user$hl$temp
  619.     xchg
  620.     shld    de$temp            ; save DE for called function
  621.  
  622.     mov    e,a            ; place function number in E
  623.     mvi    a,num$user$fun-1    ; last legal function number
  624.  
  625.     call    vector            ; function
  626. usr$tb:    dw    read$mem$0        ; 0
  627.     dw    write$mem$0        ; 1
  628.     dw    ?kyscn            ; 2
  629.     dw    do$rom$fun        ; 3  (L=function #)     
  630.     dw    do$6502$fun        ; 4  (L=function #)
  631.     dw    read$d505        ; 5  returns MMU reg in A
  632.     dw    code$error        ; not 0 to 5 ret version number in HL
  633.  
  634. num$user$fun    equ    ($-usr$tb)/2
  635.  
  636.     page
  637. ;
  638. ;    address in DE is read and returned in C
  639. ;    A=0 if no error
  640. ;
  641.     DSEG
  642. read$mem$0:
  643.     ldax    d            ; read location addressed by DE
  644.     mov    c,a            ; value returned in C
  645.     xra    a            ; clear error flag
  646.     ret
  647.  
  648. ;
  649. ;    address in DE is written to with value in C
  650. ;    A=0 if no errors
  651. ;
  652. write$mem$0:
  653.     mvi    a,-1            ; get error flag and 0ffh value
  654.     cmp    d            ; do not allow write from FF00 to FFFF
  655.                     ;   this is 8502 space, MMU direct reg.
  656.     rz
  657.     mov    a,d
  658.     cpi    10h            ; do not allow write from 0000 to 0FFF
  659.                     ;   this is ROM space
  660.     mvi    a,-1            ; get error flag
  661.     rc                ; return if 00h to 0fh
  662.     mov    a,c
  663.     stax    d
  664.     xra    a            ; clear error flag 
  665.     ret
  666.  
  667.     page
  668. ;
  669. ;    This is the function code entry point for direct execution
  670. ;    of driver functions. If the MSB of the function number is
  671. ;    set, the 40 column driver is used; else the 80 column drive 
  672. ;    is used.
  673. ;
  674. do$rom$fun:
  675.     lhld    user$hl$temp        ; get HL (L=fun #)
  676.  
  677.     mvi    a,7eh            ; only allow even functions
  678.     ana    l
  679.     cpi    79h
  680.     jrc    no$hl$req
  681.     lhld    @dma            ; HL will be passed in @dma by
  682.     push    h            ; ..the user
  683. no$hl$req:
  684.     mov    l,a
  685.     rst    5            ; call rom functon (RCALL) L=fun #    
  686.     ret
  687.  
  688. ;    mvi    a,7eh            ; only allow even functions
  689. ;    ana    l
  690. ;    sta    no$hl$req+1
  691. ;    cpi    79h
  692. ;    jrc    no$hl$req
  693. ;    lhld    @dma            ; HL will be passed in @dma by
  694. ;    push    h            ; ..the user
  695. ;no$hl$req:
  696. ;    will be changed to RCALL xx   RET for next release (ROM FN 7A, 7C
  697. ;        and 7E will not function with current code, they expect
  698. ;        a return address on the stack
  699. ;
  700. ;    RJMP    5Eh            ; unused function, real fun# installed
  701.                     ; ..above
  702.  
  703. do$6502$fun:
  704.     lhld    user$hl$temp
  705.     mov    a,l
  706.     jmp    ?fun65
  707. ;
  708. ;
  709. ;
  710. code$error:
  711.     lxi    h,date$hex
  712.     mvi    a,-1
  713.     ret
  714.  
  715.     page
  716. ;
  717. ;
  718. ;
  719.     CSEG
  720. ?rlccp:
  721. ;
  722. ;******************************************************************
  723.     mvi    a,01            ; sets feel, put here to set it
  724.     sta    0fd52h            ; on every warm start
  725.     mvi    a,repeat$amt        ; set at 3
  726.     sta    repeat
  727.     mvi    a,delay$amt        ; set at 24
  728.     sta    delay
  729. ;
  730.     mvi    a,baud$75        ; Default baud rate reset
  731.     sta    RS232$baud        ; on reload of CCP
  732. ;
  733. ;******************************************************************
  734.     lxi    h,ccp$buffer
  735.     lxi    b,0c80h
  736. ;
  737. load$ccp:
  738.     sta    bank$0
  739.     mov    a,m
  740.     sta    bank$1
  741.     lxi    d,-ccp$buffer+100h
  742.     dad    d
  743.     mov    m,a
  744.     lxi    d,ccp$buffer-100h+1
  745.     dad    d
  746.     dcx    b
  747.     mov    a,b
  748.     ora    c
  749.     jrnz    load$ccp
  750.     ret
  751.  
  752.     page
  753. ;
  754. ;
  755. ;
  756.     CSEG
  757. ?ldccp:
  758.     xra    a
  759.     sta    ccp$fcb+15    ; zero extent
  760.     lxi    h,0
  761.     shld    fcb$nr        ; start at beginning of file
  762.     lxi    d,ccp$fcb
  763.     call    open        ; open file containing CCP
  764.     inr    a
  765.     jrz    no$CCP        ; error if no file...
  766.     lxi    d,0100h
  767.     call    setdma        ; start of TPA
  768.     lxi    d,128
  769.     call    setmulti    ; allow up to 16K bytes
  770.     lxi    d,ccp$fcb
  771.     call    read
  772.  
  773.     lxi    h,0100h
  774.     lxi    b,0c80h
  775.     lda    force$map
  776.     push    psw
  777.  
  778. ;
  779. ;
  780. save$ccp:
  781.     sta    bank$1
  782.     mov    a,m
  783.     sta    bank$0
  784.     lxi    d,ccp$buffer-100h
  785.     dad    d
  786.     mov    m,a
  787.     lxi    d,-ccp$buffer+100h+1
  788.     dad    d
  789.     dcx    b
  790.     mov    a,b
  791.     ora    c
  792.     jrnz    save$ccp
  793.  
  794.     pop    psw
  795.     sta    force$map
  796.     ret
  797.  
  798.  
  799.  
  800.     page 
  801. ;
  802. ;
  803. ;
  804. no$CCP:                ; here if we couldn't find the file
  805.     call    prtmsg        ; report this...
  806.     db    cr,lf,'BIOS Err on A: No CCP.COM file',0
  807.     call    ?conin        ; get a response
  808.     jr    ?ldccp        ; and try again
  809.  
  810.  
  811. ;
  812. ; CP/M BDOS Function Interfaces
  813. ;
  814.     CSEG
  815. open:
  816.     mvi    c,15        ; open file control block
  817.  
  818.     db    21h        ; lxi h,(mvi c,26)
  819. setdma:
  820.     mvi    c,26        ; set data transfer address
  821.  
  822.     db    21h        ; lxi h,(mvi c,44)    
  823. setmulti:
  824.     mvi    c,44        ; set record count
  825.  
  826.     db    21h        ; lxi h,(mvi c,20)
  827. read:
  828.     mvi    c,20        ; read records
  829.     jmp    bdos
  830.  
  831. ;               12345678901
  832. ccp$fcb        db    1,'CCP     COM',0,0,0
  833. fcb$rc        db    0
  834.         ds    16
  835. fcb$nr        db    0,0,0
  836.  
  837.  
  838.     page
  839. ;
  840. ;    CXIO.ASM and CXEM.ASM
  841. ;
  842. ;==========================================================
  843. ;        ROUITINE TO VECTOR TO HANDLER
  844. ;==========================================================
  845. ;    CP/M IO routines    b=device : c=output char : a=input char
  846. ;
  847.     CSEG
  848. ;*********************************************************************
  849. ; code in the following vector tables has been altered to null the 40
  850. ; column screen
  851. ;--------------------------------------------------
  852.  
  853. ?cinit:                ; initialize usarts
  854.     mov    b,c
  855.     call    vector$io    ; jump with table adr on stack
  856. number$drivers:
  857.     dw    ?int$cia    ; keys
  858.     dw    ?int80        ; 80col
  859.     dw    rret          ; 40col
  860.     dw    ?pt$i$1101    ; prt1
  861.     dw    ?pt$i$1101    ; prt2
  862.     dw    ?int65        ; 6551
  863.     dw    init$RS232    ; software RS232
  864.     dw    rret        ;
  865. max$devices    equ    (($-number$drivers)/2)-1
  866.  
  867. ;
  868. ;
  869. ;
  870. ?ci:                ; character input
  871.     call    vector$io    ; jump with table adr on stack
  872.     dw    key$board$in    ; keys
  873.     dw    rret        ; 80col
  874.     dw    rret        ; 40col
  875.     dw    rret        ; ptr1
  876.     dw    rret        ; prt2
  877.     dw    ?in65        ; 6551
  878.     dw    in$RS232    ; software RS232
  879.     dw    null$input
  880.  
  881. ;
  882. ;
  883. ;
  884. ?cist:                ; character input status
  885.     call    vector$io    ; jump with table adr on stack
  886.     dw    key$board$stat    ; keys
  887.     dw    rret        ; 80col
  888.     dw    rret        ; 40col
  889.     dw    rret        ; prt1
  890.     dw    rret        ; prt2
  891.     dw    ?ins65        ; 6551
  892.     dw    in$st$RS232    ; software RS232
  893.     dw    rret
  894.  
  895. ;
  896. ;
  897. ;
  898. ?co:                ; character output
  899.     call    vector$io    ; jump with table adr on stack
  900.     dw    rret        ; keys
  901.     dw    ?out80        ; 80col
  902.     dw    rret        ; 40col
  903.     dw    ?pt$o$1        ; prt1
  904.     dw    ?pt$o$2        ; prt2
  905.     dw    ?out65        ; 6551
  906.     dw    out$RS232    ; software RS232
  907.     dw    rret
  908.  
  909. ;
  910. ;
  911. ;
  912. ?cost:                ; character output status
  913.     call    vector$io    ; jump with table adr on stack
  914.     dw    ret$true    ; keys
  915.     dw    ret$true    ; 80col
  916.     dw    ret$true    ; 40col
  917.     dw    ret$true    ; prt1    ?pt$s$1101
  918.     dw    ret$true    ; prt2
  919.     dw    ret$true    ; 6551
  920.     dw    out$st$RS232    ; software RS232
  921.     dw    ret$true
  922.  
  923. ;************************************************************
  924.  
  925.     page
  926. ;
  927. ;    This entry does not care about values of DE
  928. ;
  929. vector$io:
  930.     mvi    a,max$devices    ; check for device # to high
  931.     mov    e,b        ; get devive # in E
  932. ;
  933. ;
  934. ;    INPUT:
  935. ;        Vector # in E, Max device in A
  936. ;        passes value in DE$TEMP in DE
  937. ;        HL has routine's address in it on entering routine
  938. ;
  939. ;    OUTPUT:
  940. ;        ALL registers of returning routine are passed
  941. ;
  942. vector:
  943.     pop    h        ; get address vector list
  944.     mvi    d,0        ; zero out the MSB
  945.     cmp    e        ; is it too high?
  946.     jrnc    exist        ; no, go get the handler address
  947.  
  948.     mov    e,a        ; yes, set to max$dev$handler(last one) 
  949. exist:
  950.     dad    d        ; 
  951.     dad    d        ; point into table
  952.  
  953.      mov    a,m
  954.     inx    h
  955.     mov    h,m
  956.     mov    l,a        ; get routine adr in HL
  957.  
  958.     shld    hl$temp        ; save exec adr
  959.     lxi    h,0
  960.     dad    sp
  961.     lxi    sp,bios$stack
  962.     push    h        ; save old stack
  963.  
  964.     lhld    de$temp
  965.     xchg
  966.     lhld    hl$temp        ; recover exec adr
  967.  
  968.     lda    force$map    ; get current bank
  969.     push    psw        
  970.     sta    bank$0        ; set bank 0 as current
  971.  
  972.     call    ipchl
  973.  
  974.     sta    a$temp        ; save value to return
  975.     pop    psw
  976.     sta    force$map    ; set old bank back
  977.     lda    a$temp        ; recover value to return
  978.  
  979.     shld    hl$temp
  980.     pop    h        ; recover old stack
  981.     sphl            ; set new stack
  982.     lhld    hl$temp
  983.     ret
  984.  
  985. ipchl:
  986.     pchl            ; jmp to handler
  987.  
  988.     ds    30h
  989. bios$stack:
  990.  
  991.  
  992.     page
  993. ;==========================================================
  994. ;        CHARACTER INPUT ROUTINES
  995. ;==========================================================
  996.  
  997.     DSEG
  998. ;
  999. ;
  1000. ;
  1001. key$board$in:
  1002.     call    key$board$stat    ; test if key is available
  1003.     jrz    key$board$in    
  1004.  
  1005.     lda    key$buf
  1006.     push    psw        ; save on stack
  1007.     xra    a        ; clear key 
  1008.     sta    key$buf
  1009.     pop    psw        ; recover current key
  1010. rret:
  1011.     ret
  1012.  
  1013. ;
  1014. ;
  1015. ;
  1016. null$input:        ; return a ctl-Z for no device
  1017.     mvi    a,1Ah
  1018.     ret
  1019.  
  1020.  
  1021.     page
  1022.  
  1023. ;==========================================================
  1024. ;    CHARACTER DEVICE INPUT STATUS
  1025. ;==========================================================
  1026.  
  1027.     DSEG
  1028. ;
  1029. ;
  1030. ;
  1031. key$board$stat:
  1032.     lda    key$buf
  1033.     ora    a
  1034.     jrnz    ret$true
  1035.  
  1036.     call    ?get$key
  1037.     ora    a        ; =0 if none
  1038.     rz            ; return character not advailable
  1039.  
  1040.     sta    key$buf        ; was one, save in key buffer
  1041.  
  1042. ret$true:
  1043.     ori    0ffh        ; and return true
  1044.     ret
  1045.  
  1046.     page
  1047.  
  1048.     cseg
  1049. @ctbl
  1050.     db    'KEYBRD'    ; device 0, internal keyboard
  1051.     db    mb$input
  1052.     db    baud$none
  1053.  
  1054.     db    '80-COL'    ; device 1, 80 column display
  1055.     db    mb$output
  1056.     db    baud$none
  1057.  
  1058.     db    'NULL40'    ; device 2, 40 column display
  1059.     db    mb$output
  1060.     db    baud$none
  1061.  
  1062.     db    'PRT-D4'    ; device 3, serial bus printer (device 4)
  1063.     db    mb$output
  1064.     db    baud$none
  1065.  
  1066.     db    'PRT-D5'    ; device 4, serial bus printer (device 5)
  1067.     db    mb$output
  1068.     db    baud$none
  1069.  
  1070.     db    '6551  '    ; device 5, EXT CRT
  1071.     db    mb$in$out+mb$serial+mb$softbaud+mb$xonxoff
  1072. X6551$baud:
  1073.     db    baud$9600
  1074.  
  1075.     db    'RS-232'    ; device 6, software RS232 device
  1076.     db    mb$in$out+mb$serial+mb$xonxoff+mb$softbaud
  1077. RS232$baud:
  1078.     db    baud$75
  1079.  
  1080.     db    0        ; mark end of table
  1081.  
  1082.     page
  1083. ;
  1084. ;    TIME.ASM
  1085. ;
  1086.     cseg
  1087. ;
  1088. ;    HL and DE must be presevered
  1089. ;
  1090. ?time:
  1091.     inr    c
  1092.     lxi    b,cia$hours
  1093.     jrz    set$time
  1094. ;
  1095. ;    update SCB time  (READ THE TIME)
  1096. ;
  1097.     inp    a            ; read HR (sets sign flag)
  1098.     jp    is$am            ; jmp if AM (positive)
  1099.     ani    7fh
  1100.     adi    12h            ; noon=24(PM), midnight=12(AM)
  1101.     daa
  1102.     cpi    24h            ; check for noon (12+12 PM)
  1103.     jrnz    set$hr
  1104.     mvi    a,12h
  1105.     jr    set$hr
  1106.  
  1107. is$am:
  1108.     cpi    12h            ; check for midnight (AM)
  1109.     jrnz    set$hr
  1110.     xra    a            ; becomes 00:00
  1111. set$hr:
  1112.     sta    @hour
  1113.     mov    b,a
  1114.     lda    old$hr
  1115.     mov    c,a
  1116.     mov    a,b
  1117.     sta    old$hr
  1118.     cmp    c            ; if @hour<old$hr
  1119.     jrnc    same$day
  1120.  
  1121.     push    h
  1122.     lhld    @date
  1123.     inx    h
  1124.     shld    @date
  1125.     pop    h
  1126.  
  1127. same$day:
  1128.     lxi    b,cia$hours-1
  1129.     inp    a            ; read MIN
  1130.     sta    @min
  1131.  
  1132.     dcr    c
  1133.     inp    a            ; read SEC
  1134.     sta    @sec
  1135.  
  1136.     dcr    c
  1137.     inp    a            ; read 1/10 of SEC (a must to free
  1138.     ret                ; the holding register)
  1139.  
  1140. old$hr:
  1141.     ds    1
  1142.     page
  1143. ;
  1144. ;
  1145. ;
  1146. set$time
  1147.     lda    @hour
  1148.     cpi    12h            ; test for noon
  1149.     jrz    set$as$is
  1150.     ana    a            ; test for 00:xx
  1151.     jrnz    not$zero$hundred
  1152.     mvi    a,80h+12h            ; set to midnight
  1153.     jr    set$as$is
  1154.  
  1155. not$zero$hundred:
  1156.      cpi    11h+1            ; test for 1 to 11 AM
  1157.     jrc    set$as$is
  1158.     sui    12h
  1159.     daa                ; decimal adjust
  1160. set$msb:
  1161.     ori    80h            ; set PM
  1162.  
  1163. set$as$is:
  1164.     outp    a
  1165.     dcr    c
  1166.     lda    @min
  1167.     outp    a
  1168.     dcr    c
  1169.     lda    @sec
  1170.     outp    a
  1171.     dcr    c
  1172.     xra    a
  1173.     outp    a
  1174.     ret
  1175.  
  1176.     page
  1177.  
  1178. ;
  1179.     page
  1180. ;
  1181. ; CXMOVE.ASM
  1182. ;
  1183.     public ?move,?xmove,?bank
  1184.  
  1185. ;
  1186. ;    Move a block of data from DE to HL
  1187. ;    count is in BC (within current bank)
  1188. ;
  1189. ;
  1190.     cseg            ; place code in common
  1191. ?move:
  1192.     xchg            ;*
  1193.     lda    source$bnk    ; =FFh if normal block move 
  1194.     inr    a        ; 
  1195.     jrnz    inter$bank$move
  1196.  
  1197.     LDIR            ;* do block move    
  1198.     xchg            ;*
  1199.     ret
  1200.  
  1201.  
  1202. ;
  1203. ;
  1204. ;
  1205. ?xmove:                ; can be in bank 0    
  1206.     mov    a,c
  1207.     sta    source$bnk
  1208.     mov    a,b
  1209.     sta    dest$bnk
  1210.     ret            ;*
  1211.  
  1212.     page
  1213. ;
  1214. ;
  1215. ;
  1216. inter$bank$move:
  1217.     shld    @buffer        ; save HL TEMP
  1218.     lxi    h,0
  1219.     dad    sp
  1220.     lxi    sp,bios$stack
  1221.     push    h        ; save old stack  ;**1
  1222.     lhld    @buffer
  1223.  
  1224.     mov    a,b        ; get msb of count
  1225.     ora    a
  1226.     jrz    count$less$than$256
  1227.  
  1228.     push    b        ; save the count  ;**2
  1229.     push    d        ; save the dest   ;**3
  1230.     lxi    d,@buffer    ; make buffer the dest
  1231.     lxi    b,256        ; move 256 bytes
  1232.     lda    source$bnk
  1233.     call    ?bank
  1234.     ldir            ; move source to buffer
  1235.  
  1236.     pop    d        ; recover dest    ;**2
  1237.     push    h        ; save updated source ;**3
  1238.     lxi    h,@buffer    ; make the buffer the source
  1239.     lxi    b,256        ; move 256 bytes
  1240.     lda    dest$bnk
  1241.     call    ?bank
  1242.     ldir            ; move buffer to dest
  1243.  
  1244.     pop    h        ; recover updated source ;**2
  1245.     pop    b        ; recover count          ;**1
  1246.     dcr    b        ; subtract 256 from count
  1247.     jr    inter$bank$move
  1248.  
  1249.     page
  1250. ;
  1251. ;
  1252. ;
  1253. count$less$than$256:
  1254.     ora    c        ; BC=0  [A (0) or'ed with C]
  1255.      jrz    exit$move
  1256.  
  1257.     push    d        ; save count for 2nd half  ;**2
  1258.     push    b        ; save dest adr            ;**3
  1259.     lxi    d,@buffer
  1260.     lda    source$bnk
  1261.     call    ?bank
  1262.     ldir            ; move source to buffer
  1263.  
  1264.     pop    b        ; recover count          ;**2
  1265.     pop    d        ; recover dest          ;**1
  1266.     push    h        ; save updated dest      ;**2
  1267.     lxi    h,@buffer
  1268.     lda    dest$bnk
  1269.     call    ?bank
  1270.     ldir            ; move buffer to dest
  1271.     pop    h                        ;**1
  1272.  
  1273. ;
  1274. ;
  1275. ;
  1276. exit$move:
  1277.     xchg
  1278.     mvi    a,-1
  1279.     sta    source$bnk    ; set MOVE back to normal
  1280.     lda    @cbnk
  1281.  
  1282.     shld    @buffer
  1283.     pop    h        ; recover old stack    ;**0
  1284.     sphl
  1285.     lhld    @buffer
  1286.  
  1287. ; call    ?bank        ; set current bank
  1288. ; ret
  1289.  
  1290.     page
  1291. ;
  1292. ;    switch bank to bank number in A
  1293. ;
  1294.     cseg            ; (must be in common)
  1295. ?bank:                
  1296.     ora    a        ; bank 0 ?
  1297.     jrnz    not$bank$0    ; go check for bank 1
  1298.  
  1299.     sta    bank$0        ; set bank 0
  1300.     ret
  1301.  
  1302. ;
  1303. ;
  1304. not$bank$0:
  1305.     dcr    a        ; bank 1 ?
  1306.     rnz            ; if not a valid bank just return
  1307.     sta    bank$1        ; set bank 1
  1308.     ret
  1309.  
  1310.     end
  1311.