home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / ENTERPRS / CPM / UTILS / A / BIOS-R62.LZH / CXDISK.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  34KB  |  1,740 lines
  1. ;
  2. ;
  3. ;
  4. ;
  5. ;    *****************************************
  6. ;    *                    *
  7. ;    *    Commodore Disk    Controller    *
  8. ;    *    Module for CP/M 3.0 BIOS    *
  9. ;    *                    *
  10. ;    *****************************************
  11. ;
  12. ;
  13. ;
  14.     title 'CXDISK   Commodore C-128 Disk Controller    15 Apr 86'
  15.  
  16.  
  17.  
  18.  
  19. ; CP/M 3 Disk definition macros
  20.  
  21.     maclib    cpm3
  22.  
  23.     maclib    z80
  24.  
  25. ; C-128 system equates
  26.  
  27.     maclib    cxequ
  28.  
  29.     page
  30.  
  31. ; Disk drive dispatching tables for linked BIOS
  32.  
  33.     public    cmdsk0,cmdsk1,cmdsk2,cmdsk3,cmdsk4
  34.  
  35. ; System Control Block variables
  36.     extrn    @ermde        ; BDOS error mode
  37.  
  38. ; Utility routines in standard BIOS
  39.     extrn    ?wboot        ; warm boot vector
  40.     extrn    ?pmsg        ; print message @<HL> up to 00
  41.                 ; saves <BC> & <DE>
  42.     extrn    ?pdec        ; print binary number in <HL> from 0 to 65535
  43.     extrn    ?pderr        ; print BIOS disk error header
  44.     extrn    ?conin,?cono    ; con in and out
  45.     extrn    ?const        ; get console status
  46.     extrn    ?sctrn        ; sector translation routine
  47.     extrn    @covec
  48.  
  49. ;    status line calls
  50.  
  51.     extrn    ?save,?recov,?stat
  52.  
  53. ; System function call
  54.     extrn    ?kyscn
  55.     extrn    ?fun65
  56.     extrn    ?bank
  57.     extrn    ?di$int
  58.  
  59.     public    ?dskst
  60.     public    ?dkmov
  61.     extrn    ?stat
  62.  
  63.     page
  64. ;
  65. ; Initialization entry point.
  66. ; called for first time initialization.
  67. ;
  68.     DSEG
  69. init$154X:
  70.     xra    a
  71.     sta    fast
  72.     lxi    h,MFM$table
  73.     shld    MFM$tbl$ptr
  74.     ret
  75.  
  76.  
  77.     page
  78. ;
  79. ; This entry is called when a logical drive is about to
  80. ;  be logged into for the purpose of density and type determination.
  81. ;  It may adjust the parameters contained in the disk
  82. ;  parameter header pointed to by <DE>
  83. ;
  84.     DSEG
  85. ;
  86. ;    if disk type GCR or drive type 1541 or 1581(reports as GCR)
  87. ;       if sector size is 256 bytes
  88. ;          if 1st sector has 'CBM' (1st 3 bytes)
  89. ;             if last byte = -1 (0FFh)
  90. ;                set C128 double sided
  91. ;             else
  92. ;                set C128 single sided
  93. ;             endif
  94. ;          else
  95. ;             set C64 type
  96. ;          endif
  97. ;       else  (512 byte sector size)
  98. ;          set C1581 type
  99. ;       endif
  100. ;    else (must be MFM)
  101. ;       TEST MFM
  102. ;    endif
  103. ;
  104. login$154X:
  105.     call    get$drv$info    ; set the drive to check (DPH$pointer set)
  106.  
  107.     mvi    a,vic$test
  108.                 ; ***** add code to reset 1581 drive *****
  109.     call    ?fun65
  110.     mov    b,a
  111.     ani    0ch
  112.     cpi    0ch        ; fast drive ?
  113.     jrz    commodore$type    ; no, must be 1541 type
  114.     mov    a,b        ; yes, is a 1571 or 1581
  115.     rlc            ; MSB=1 if NON-Commodore disk 
  116.     jrc    MFM$type    ; 1571 NON-Commodore disk is MFM type
  117.  
  118.     page
  119. ;
  120. ;    Commodore Type disk is a disk that is in GCR format (1571)
  121. ;    Or Standard Commodore format for 1581 (Has a Commodore dir track)
  122. ;
  123. commodore$type:
  124.     lhld    DPH$pointer
  125.     dcx    h
  126.   if    use$1581
  127.     mov    a,b        ; get the status byte
  128.     ani    30h        ; save only the sector size info
  129.     cpi    20h        ; 512 byte sectors?
  130.     jrnz    set$15x1$type    ; no, set up as 1571 or 1541
  131.                 ; yes, set 1581 type drive
  132. ;
  133. ;
  134. ;
  135. set$1581$type:
  136.     mvi    m,dsk$1581    ; yes, set up as 1581 double sided
  137.     lxi    d,dpb$1581 
  138.     jr    set$dpb$only
  139.  
  140.   endif
  141.  
  142. set$15x1$type:
  143.     mvi    m,dsk$c64
  144.     lxi    d,dpb$c64$cpm    ; set DPB to C64
  145.     call    set$dpb$only
  146.  
  147.     xra    a
  148.     sta    vic$sect    ; set track 1 sector 0 (1st sector
  149.     inr    a        ; on the disk)
  150.     sta    vic$trk
  151.  
  152.     lxi    h,@buffer
  153.     shld    local$DMA    ; move DMA pointer to disk buffer
  154.     call    login$rd
  155.     ana    a        ; read error ?
  156.     rnz            ; yes, just return
  157.  
  158.     RCALL    FR$check$CBM
  159.     rnz            ; return if not 'CBM'
  160.                 ; A=0FFh if double sided
  161.     inr    a
  162.     lhld    DPH$pointer
  163.     dcx    h        ; does not affect flags
  164.     mvi    m,dsk$c128
  165.  
  166.     lxi    d,dpb$c128$SS
  167.     jrnz    set$dpb$only
  168.  
  169.     lxi    d,dpb$c128$DS
  170.  
  171.     page
  172. ;
  173. ;
  174. ;
  175. set$dpb$only:
  176.     lxi    b,0        ; set sector translation to zero
  177. set$format:
  178.     lhld    DPH$pointer
  179.     mov    m,c
  180.     inx    h
  181.     mov    m,b        ; install sector translation
  182.     lxi    b,25-1        ; ofset to DPB
  183.     dad    b        ; HL points to DPB now
  184.     lxi    b,17        ; dpb size
  185.     xchg            ; move to DPB location
  186.     ldir
  187.     ret
  188.  
  189.     page
  190. ;
  191. ;    TEST MFM()
  192. ;    save number bytes/sector
  193. ;       if double sided
  194. ;          mark two sided
  195. ;       endif
  196. ;       find start and end sector numbers
  197. ;       scan table of disk for match (if more then 1 match ask user) 
  198. ;
  199. MFM$type:
  200.     mvi    c,01100000b
  201.     ana    c            ; A = status(trk1) shifted left 1 
  202.     push    psw            ; save in case bad query
  203.     push    b            ; save BC
  204.  
  205.     call    get$max$num$B        ; used to set the pointer only
  206.     mov    b,m            ; get size, and disk lock flag
  207.     inx    h
  208.     mov    a,m
  209.     inx    h
  210.     mov    h,m            ; get last MFM$mactch$ptr
  211.     mov    l,a
  212.     mov    a,b            ; get lock flag in A
  213.     ani    80h            ; lock bit set ?
  214.     sta    lock$flag        ;   (save old lock status)
  215.     shld    last$match        ; save last match pointer
  216.     jrz    not$$locked$entry    ; yes, then set same disk type
  217. ; set$locked$entry
  218.     xra    a
  219.     sta    lock$flag
  220.     mvi    c,0B0h
  221.     lda    vic$data        ; get sector size info
  222.     ana    c
  223.     mov    b,a            ; save disk sector size info
  224.     xchg                ; save HL
  225.     lhld    DPH$pointer
  226.     dcx    h
  227.     mov    a,c
  228.     ana    m            ; get old disk sector size
  229.     cmp    b            ; are they the same?
  230.     jrnz    not$locked$entry    ; no, then unlock disk anyway
  231.  
  232.     xchg                ; get last match pointer (in DE)
  233.     pop    psw            ; yes, remove two data elements 
  234.     pop    psw            ; ..save on stack
  235.     jr    set$this$entry
  236.  
  237. not$locked$entry:
  238.     lxi    h,MFM$match$tbl        ; clear Match table
  239.     shld    MFM$cur$ptr
  240.     lxi    d,MFM$match$tbl+1
  241.     mvi    m,0
  242.     lxi    b,(MFM$tbl$entries*2)-1+1+1    ; table, offset and count
  243.     ldir
  244.     mvi    a,4
  245.     sta    vic$trk            ; do query on track 4
  246.     mvi    a,vic$query
  247.     call    ?fun65
  248.     pop    b            ; recover BC
  249.     ani    0eh            ; query error ?
  250.     jrnz    query$error        ; yes, use only bits 5 and 6 
  251.     lda    @buffer            ; get trk 4 status
  252.     mov    b,a            ; save in B
  253.     ani    0eh            ; trk 4 status error ?
  254.     jrnz    query$error        ; yes, use only bits 5 and 6
  255.     mov    a,b            ; recover B (trk 4 status)
  256.     add    a            ; shift left
  257.     ana    c            ; mask sector size bits
  258.     mov    b,a
  259.     pop    psw            ; get trk 1 sector size bits
  260.     cmp    b            ; same as trk 4 sector size?
  261.     mvi    c,01111111b
  262.     jrz    trk$1$trk$4        ; yes, (then test for mult format)
  263.     mvi    a,80h            ; set MSB to mean mult format
  264.     add    b            ; ..(track 0 different sector size
  265.                     ; ..then track 4) 
  266.     mov    b,a            ; save in B
  267.     mvi    c,11111111b
  268. trk$1$trk$4:
  269.     lda    @buffer+1        ; get number of sectors/track
  270.     sui    4            ; remove 4 to extend the range
  271.     add    a            ; shift    left
  272.     add    b            ; combine with rest of mask
  273.     mov    b,a            ; save in B for now
  274.  
  275.     lda    @buffer+3        ; minimum sector number
  276.     add    b            ; add in start sector #
  277.     push    psw            ; save on stack for a moment
  278.  
  279. query$error:
  280.     pop    psw            ; get value to match 
  281.     ana    c            ; test only those bits in the mask
  282.  
  283.     lhld    MFM$tbl$ptr
  284.     mvi    b,MFM$tbl$entries
  285. check$next:
  286.     push    b            ; save BC for a moment
  287.     mov    b,a            ; move compare value to 
  288.     mov    a,m            ; get type info
  289.     ana    c            ; test only the good info
  290.     cmp    b            ; match the current type byte
  291.     mov    a,b            ;   (recover A)
  292.     pop    b            ;   (recover BC)
  293.     jrnz    not$found        ; no, do not queue data
  294.                     ; yes queue table entry address
  295.  
  296.     xchg                ; save adr in DE
  297.     lhld    MFM$cur$ptr
  298.     mov    m,e
  299.     inx    h
  300.     mov    m,d
  301.     inx    h
  302.     shld    MFM$cur$ptr
  303.     lxi    h,MFM$count
  304.     inr    m            ; add one to counter
  305.     xchg
  306.  
  307.     page
  308. ;
  309. ;
  310. not$found:
  311.     lxi    d,32            ; table entry size
  312.     dad    d
  313.     djnz    check$next
  314.  
  315.     lda    MFM$count        ; number of matches in table 
  316.     ana    a            ; test for zero
  317.     jz    tell$user$no$entry    ; none, tell the user 
  318.  
  319.     dcr    a            ; only one ?
  320.     jrnz    user$select        ; no, go check with user (which one)
  321.     lhld    MFM$match$tbl        ; yes, use the only one found
  322.  
  323. ;
  324. ;    install data from pointer in HL
  325. ;
  326. set$this$entry:
  327.     push    h        ; save table pointer
  328.     inx    h
  329.     mov    a,m        ; get type info. 
  330.     xchg            ; save table address in DE
  331.     lhld    DPH$pointer
  332.     dcx    h
  333.     mov    m,a        ; save type code
  334.     xchg            ; get table adr to HL
  335.     inx    h        ; HL points to sector translation table 
  336.     mov    c,m        ; ..zero if none
  337.     inx    h
  338.     mov    b,m
  339.     inx    h        ; HL points to DPB
  340.     xchg            ; DE points to DPB (HL trash)
  341.     call    set$format
  342.     mov    b,m        ; get the number of sect/trk from MFM table
  343.     lda    lock$flag    ; get the current lock flag value
  344.     ora    b        ; combine with sect/trk
  345.     xchg            ; HL=to adr,  DE=from adr
  346.     mov    m,a        ; install sect/trk and lock flag
  347.     pop    d        ; recover table pointer
  348.     inx    h
  349.     mov    m,e
  350.     inx    h
  351.     mov    m,d        ; save MFM table pointer at end of DPH
  352.     ret
  353.  
  354.     page
  355. ;
  356. ;    let the user select the Disk type (s)he wants
  357. ;
  358. user$select:
  359.     inr    a            ; number of entries to try to match
  360.     mov    b,a            ; set in B as loop count
  361.     lhld    last$match        ; get value to match with
  362.     mov    d,h
  363.     mov    e,l            ; last match pointer is in DE
  364.  
  365.     lxi    h,MFM$match$tbl
  366.     shld    MFM$cur$ptr
  367.     mvi    c,0            ; start offset at zero
  368.  
  369. try$next$format:
  370.     mov    a,e
  371.     cmp    m
  372.     inx    h
  373.     jrnz    not$last$match
  374.     mov    a,d
  375.     cmp    m
  376.     jrnz    not$last$match
  377. ;
  378. ; match, set pointer
  379. ;
  380.     mov    a,c            ; get offset in A
  381.     push    psw
  382.     call    save$dsk$window
  383.     pop    psw
  384.     jr    set$offset
  385.  
  386. not$last$match:
  387.     inx    h            ; each pointer uses two bytes 
  388.     inr    c            ; advance the index
  389.     djnz    try$next$format        ; test for more, loop if so
  390.  
  391.     call    save$dsk$window
  392.  
  393.     lhld    MFM$cur$ptr
  394. user$loop:
  395.     mov    e,m            ; HL=(MFM$cur$ptr)
  396.     inx    h
  397.     mov    d,m
  398.     lxi    h,22            ; offset to NAME field
  399.     dad    d            ; point to Disk name
  400.     call    dsk$window$old
  401.  
  402. dsk$user$sel$wait:
  403.     call    ?kyscn
  404.     inr    b            ; test for key pressed
  405.     jrz    dsk$user$sel$wait
  406.     dcr    b            ; adjust back
  407.     mov    a,b            ; move matrix position to A
  408.     cpi    SF$exit
  409.     jrnz    CK$dsk$user$rt
  410.  
  411.     mov    a,c
  412.     ani    4            ; control key down ?
  413.     jrz    no$cntr$key        ; no, don't lock this selection
  414.     mvi    a,80h            ; yes, lock disk type to this drive
  415. no$cntr$key:
  416.     sta    lock$flag        ;
  417.     call    dsk$window$remove
  418.     lhld    MFM$cur$ptr
  419.     mov    e,m
  420.     inx    h
  421.     mov    d,m
  422.     xchg
  423.     jr    set$this$entry
  424.  
  425.     page
  426. ;
  427. ;
  428. ;
  429. CK$dsk$user$rt:
  430.     cpi    SF$right        ;
  431.     jrnz    CK$dsk$user$lf
  432.  
  433. ; move window down
  434.     lda    MFM$count        ; get number of items in list
  435.     mov    b,a            ; save in B
  436.     lda    MFM$offset        ; get current position
  437.     inr    a            ; advance position
  438.     cmp    b            ; at last position ? (n-1+1 =count)
  439.     jrnz    set$offset        ; no, then use A as new position
  440.     xra    a            ; yes, move back to start
  441.     jr    set$offset
  442.     
  443. CK$dsk$user$lf:
  444.     cpi    SF$left            ;
  445.     jrnz    dsk$user$sel$wait
  446.  
  447. ; move window up
  448.     lda    MFM$offset
  449.     dcr    a            ; back up offset (under flow?)
  450.     jp    set$offset        ; result positive, jump
  451.     lda    MFM$count        ; get last item number
  452.     dcr    a            ; pointer is 0 to n-1 (not 1 to n)
  453. set$offset:
  454.     sta    MFM$offset        ; set new list offset
  455.     inr    a            ; add one to adjust for DCR below
  456.     lxi    h,MFM$match$tbl        ; set to the beginning
  457.  
  458. adjust$dsk$loop:
  459.     shld    MFM$cur$ptr        ; set pointer here !
  460.     dcr    a            ; at offset yet?
  461.     jrz    user$loop        ; yes, go display name
  462.     inx    h
  463.     inx    h
  464.     jr    adjust$dsk$loop
  465.  
  466.     page
  467. ;
  468. ;
  469. ;
  470. tell$user$no$entry:
  471.     lda    vic$data        ; get disk test status
  472.     ani    0b0h            ; save only sector size and MFM flag
  473.     lhld    DPH$pointer
  474.     dcx    h
  475.     mov    m,a            ; set disk size and Type0 (MFM)
  476.  
  477.     lxi    h,dsk$window*256+buff$pos
  478.     lxi    d,no$dsk$msg
  479. disp$msg$DE$HL:
  480.     call    dsk$window$new
  481. dsk$no$entry$wait:
  482.     call    ?kyscn
  483.     inr    b
  484.     jrz    dsk$no$entry$wait
  485.     dcr    b
  486.     mov    a,b
  487.     cpi    SF$exit
  488.     jrnz    dsk$no$entry$wait
  489. ;    jr    dsk$window$remove
  490.  
  491.     page
  492. ;
  493. ;
  494. ;
  495. dsk$window$remove:
  496.     lhld    window$info
  497.     mov    b,h
  498.     mov    c,l
  499.     jmp    ?recov
  500. ;
  501. ;
  502. ;
  503. save$dsk$window:
  504.     lxi    h,dsk$window*256+buff$pos    ; H=size l=pos
  505.     shld    window$info
  506.     mov    b,h
  507.     mov    c,l
  508.     jmp    ?save
  509. ;
  510. ;
  511. ;
  512. dsk$window$new:
  513.     shld    window$info
  514.     xchg
  515.     mov    b,d
  516.     mov    c,e
  517.     push    h
  518.     call    ?save
  519.     pop    h
  520.  
  521. dsk$window$old:
  522.     lda    window$info        ; get start index
  523.     inr    a
  524.     mov    c,a            ; place in C
  525.  
  526. dsk$out$next:
  527.     push    h
  528.     lhld    window$info
  529.     mov    a,h
  530.     add    l            ; compute max index (start+size)
  531.     dcr    a            ; ..less 1
  532.     pop    h
  533.     cmp    c
  534.     rz    
  535.     mov    b,m
  536.     call    dsk$B$out
  537.     inx    h
  538.     jr    dsk$out$next
  539.  
  540. ;
  541. ;
  542. ;
  543. dsk$B$out:
  544.     mvi    a,01000000b            ; set reverse video attr
  545.     push    b
  546.     push    h
  547.     call    ?stat                ; display space
  548.     pop    h
  549.     pop    b                ; recover count
  550.     inr    c
  551.     ret
  552.  
  553.     page
  554. ;
  555. ; disk READ and WRITE entry points.
  556. ; These entries are called with the following arguments:
  557. ;    relative drive number in @rdrv (8 bits)
  558. ;    absolute drive number in @adrv (8 bits)
  559. ;    disk transfer address in @dma (16 bits)
  560. ;    disk transfer bank    in @dbnk (8 bits)
  561. ;    disk track address    in @trk (16 bits)
  562. ;    disk sector address    in @sect (16 bits)
  563. ;    pointer to XDPH in <DE>
  564. ;
  565. ;   return with an error code in <A>
  566. ;     A=0    no errors
  567. ;     A=1    non-recoverable error
  568. ;    A=2    disk write protected
  569. ;    A=FF    media change detected
  570. ;
  571.     DSEG
  572. read$154X:
  573.     call    get$drv$info
  574.     jm    mfm$rd
  575.     call    set$up$GCR        ; compute effective track and sector
  576. login$rd:
  577.     lda    vic$drv
  578.     mov    b,a
  579.     lda    fast            ; get fast flags
  580.     ana    b            ; isolate fast bit for this drive
  581.     jrnz    rd$fast            ; go handle fast drive
  582. rd$slow:
  583.     mvi    a,vicrd            ; read a sector of data (A=1)
  584.     call    dsk$fun            ; a=0 if no errors
  585.     jnz    test$error        ; check for disk error or media change
  586. ;
  587. ;
  588. ;
  589. buf$move:
  590.     xra    a            ; set direction to read
  591.     call    ?dkmov            ; go move buffer to DMA
  592.     lda    sect$cnt
  593.     ana    a
  594.     rz                ; a=0 means not read errors
  595.     call    set$up$next
  596.     jr    rd$slow
  597.  
  598.     page
  599. ;
  600. ;    A=drive type info
  601. ;
  602. mfm$rd:
  603.     call    set$up$MFM
  604.  
  605. rd$fast:
  606.     mvi    a,vic$rd$f
  607.     call    dsk$fun            ; go read the disk
  608.  
  609.     ani    0eh            ; mask off error bits
  610.     jrnz    test$error
  611.  
  612.     call    get$sector$size
  613.     inr    d
  614.     inr    e            ; adjust count for pre-decrement
  615.  
  616.     call    ?di$int
  617.     lxi    b,0DD00h        ; D2PRA
  618.     inp    a            ; get current clock polarity 
  619.     xri    10h            ; toggle clk$bit
  620.     outp    a            ; to have status sent (extra clock
  621.                     ; supplied by rd$1571$data for multi
  622.                     ; sector transfers)
  623.     lda    vic$count
  624. rd$multi$sect:
  625.     push    psw
  626.     push    d            ; save the sector size
  627.     call    rd$1571$data        ; read disk data to DMA address
  628.     pop    d
  629.  
  630.     lda    vic$data
  631.     ani    0eh
  632.     jrnz    test$error$pop        ; A=0 if no errors
  633.     pop    psw
  634.     dcr    a
  635.     jrnz    rd$multi$sect
  636.     ei
  637.     lda    sect$cnt
  638.     ana    a            ; any sectors left to read
  639.     jrz    done$rd$1571
  640.  
  641.     call    set$up$next
  642.     jr    rd$fast
  643.  
  644. done$rd$1571:
  645.     lxi    b,0DD00h        ;   D2PRA
  646.     inp    a
  647.     ani    not(10h)        ; set clk$bit hi
  648.     outp    a
  649.     xra    a            ; A=0 for no errors
  650.     ret
  651.  
  652.  
  653.     page
  654. ;
  655. ;
  656. ;
  657. write$154X:
  658.     call    get$drv$info
  659.     jm    mfm$wr
  660.     call    set$up$GCR
  661.     lda    vic$drv
  662.     mov    b,a
  663.     lda    fast            ; get fast flags
  664.     ana    b            ; isolate fast bit for this drive
  665.     jrnz    wr$fast$drive        ; go handle fast drive
  666. wr$slow:
  667.     mvi    a,-1            ; set direction to write
  668.     call    ?dkmov            ; go move DMA to buffer
  669.  
  670.     mvi    a,vicwr            ; write a sector of data
  671.     call    dsk$fun            ; a=0 if no errors
  672.     ani    0eh
  673.     jrnz    test$error
  674.     lda    sect$cnt
  675.     ana    a
  676.     rz
  677.     call    set$up$next
  678.     jr    wr$slow
  679.  
  680. test$error$pop:
  681.     pop    psw
  682. test$error:
  683.     ei
  684.     lda    vic$data
  685.     ani    0fh            ; check for disk error or media change
  686.     cpi    0bh            ; disk change ?
  687.     jrz    change$error
  688.     cpi    08h            ; test for write protect error
  689.     jrz    write$prot$error
  690.  
  691.     mvi    a,1            ;  get general error flag
  692.     ret
  693.  
  694. ;
  695. ;
  696. write$prot$error:
  697.     mvi    a,2
  698.     ret
  699.  
  700. ;
  701. ;
  702. change$error:
  703.     mvi    a,-1
  704.     ret
  705.  
  706.     page
  707. ;
  708. ;
  709. ;
  710. mfm$wr:
  711.     call    set$up$MFM
  712. wr$fast$drive:
  713.     mvi    a,vic$wr$f
  714.     call    dsk$fun            ; go send the write command
  715.  
  716.     call    get$sector$size        ; setup DMA adr and transfer count
  717.     lda    vic$count
  718. wr$multi$sect:
  719.     push    psw
  720.     push    d            ; save sector size
  721.     call    wr$1571$data        ; write data to disk from DMA address
  722.     pop    d
  723.     ani    0eh
  724.     jrnz    test$error$pop
  725.     pop    psw
  726.     dcr    a
  727.     jrnz    wr$multi$sect
  728.  
  729.     ei
  730.     lda    sect$cnt
  731.     ana    a
  732.     rz                ; return if no errors (A=0)
  733.     call    set$up$next
  734.     jr    wr$fast$drive
  735.  
  736.     page
  737. ;
  738. ;
  739. ;
  740. get$drv$info:
  741.     lhld    @dma
  742.     shld    local$dma
  743.     xchg
  744.     shld    DPH$pointer
  745.  
  746.     lda    @adrv            ; get drive number (0 to F)
  747.     dcx    h            ; point at drive mask
  748.     dcx    h
  749.     mov    a,m            ; get drive mask
  750.     mov    b,a            ; save in B
  751.     sta    vic$drv            ; save vic drive # (values 1,2,4,8)
  752.  
  753.     inx    h            ; point at disk type
  754.     xra    a
  755.     sta    sect$cnt        ; clear the count
  756.     inr    a
  757.     sta    vic$count
  758.     mov    a,m            ; get disk type
  759.     ana    a
  760.     ret
  761.  
  762.     page
  763. ;    
  764. ;
  765. ;
  766. get$max$num$b:
  767.     lhld    DPH$pointer
  768.     lxi    b,42            ; offset to number of sectors on track
  769.     dad    b
  770.     mov    a,m            ; get number sectors/track/side
  771.     ani    1fh
  772.     mov    b,a
  773.     ret
  774. ;
  775. ;
  776. ;
  777. get$sector$size:
  778.     lhld    DPH$pointer
  779.     dcx    h
  780.     mov    a,m            ; disk type in B (bit 5,4 size info)
  781.     rrc                ; ..00 = 080h byte sectors
  782.     rrc                ; ..01 = 100h byte sectors
  783.     rrc                ; ..10 = 200h byte sectors
  784.     rrc                ; ..11 = 400h byte sectors
  785.     ani    3
  786.     jrz    set$128
  787.     jpo    not$3            ; jump if (A=) 01b or 10b
  788.     inr    a            ; make A = 4
  789. not$3:
  790.     mvi    e,0            ; set E to zero
  791.     mov    d,a            ; set sector size (1,2 or 4)
  792. get$DMA:
  793.     lhld    local$DMA        ; get the current DMA pointer
  794.     ret
  795.  
  796. set$128:
  797.     lxi    d,128
  798.     jr    get$DMA 
  799.  
  800.     page
  801. ;
  802. ;
  803. ;
  804.     DSEG
  805. set$up$GCR:
  806.     cpi    dsk$c128
  807.     jnz    tst$next
  808.  
  809.     mvi    a,4
  810.     sta    sect$cnt
  811.     lxi    h,sect$buffer
  812.     shld    sect$buf$ptr
  813.  
  814.     lhld    @trk            ; 1 K sector pointer 
  815.     dad    h
  816.     dad    h            ; make 256 byte pointer
  817. ;
  818. ;    build a list of tracks and sectors
  819. ;
  820. next$sect:
  821.     shld    @trk
  822.     RCALL    FR$trk$sect
  823.     lhld    vic$trk            ; get trk(L) and sector(H) to HL
  824.     xchg
  825.     lhld    sect$buf$ptr
  826.     mov    m,e
  827.     inx    h
  828.     mov    m,d
  829.     inx    h
  830.     shld    sect$buf$ptr
  831.     lhld    @trk
  832.     inr    l            ; update saved above at next$sect
  833.     mov    a,l
  834.     ani    3
  835.     jrnz    next$sect
  836. ;
  837. ;    check list of trk-sectors for number of sectors on this trk
  838. ; 
  839.     lxi    h,sect$buffer
  840.     shld    sect$buf$ptr
  841.     lda    vic$drv
  842.     mov    b,a
  843.     lda    fast
  844.     ana    b            ; drive type 1571
  845.     jrz    handle$1541        ; no, handle as 1541
  846.  
  847.     lda    sect$cnt        ; number of sectors to rd/wr
  848.     mov    b,a
  849.     inx    h
  850.     mov    a,m            ; get 1st sector #
  851.     sta    vic$sect
  852.     dcx    h
  853.     mov    a,m            ; get 1st track #
  854.     sta    vic$trk
  855.  
  856. try$next:
  857.     cmp    m            ; test for same trk #
  858.     jrnz    exit$no$match
  859.     inx    h
  860.     inx    h            ; advance to next trk
  861.     shld    sect$buf$ptr
  862.     djnz    try$next    
  863.  
  864. exit$no$match:
  865.     lda    sect$cnt        ; number of sectors to rd/wr
  866.     sub    b            ; remove number left
  867.                     ; (leaving number matched)
  868.     sta    vic$count        ; save number to read
  869.     mov    a,b            ; get remaining count
  870.     sta    sect$cnt        ; save remaining count
  871.     ret
  872.  
  873.  
  874. set$up$next:
  875.     lda    vic$count        ; get number of sectors read
  876.     lhld    local$DMA        ; get current DMA pointer
  877.     add    h            ; advance pointer by number of
  878.     mov    h,a            ; sectors read
  879.     shld    local$DMA
  880. handle$1541:
  881.     lhld    sect$buf$ptr
  882.     mov    a,m
  883.     sta    vic$trk
  884.     inx    h
  885.     mov    a,m
  886.     sta    vic$sect
  887.     inx    h
  888.     shld    sect$buf$ptr
  889.     lda    vic$drv
  890.     mov    b,a
  891.     lda    fast
  892.     ana    b
  893.     jrz    set$up$next$slow
  894.     lda    sect$cnt
  895.     sta    vic$count
  896.     xra    a            ; two reads max with fast drive
  897.     jr    set$up$next$exit
  898.  
  899. set$up$next$slow:
  900.     lda    sect$cnt
  901.     dcr    a
  902. set$up$next$exit:
  903.     sta    sect$cnt
  904.     ret
  905. ;
  906. ;
  907. ;
  908. tst$next:
  909.   if    use$1581
  910.     cpi    dsk$1581
  911.     jrz    c1581$adj
  912.   endif
  913. tst$c64:
  914.     mvi    b,dir$track    ; set the dir track number
  915.     cpi    dsk$c64        ; C64 type disk?
  916.     lda    @sect        ;   get sector # to set
  917.     jrz    set$up$c64    ; yes, go set up for C64 CP/M disk format
  918.                 ; no, set up as no type(direct addressing)
  919. ;
  920. ;    This format is for direct track and sector addressing 
  921. ;
  922. do$type$7:
  923.     mvi    b,255        ; no dir sector
  924. ;
  925. ;    this routine will adjust the track number if necessary.
  926. ;    The C64 CP/M disk has the C64 directory in the center
  927. ;    of the disk. This routine checks and adds one to the track
  928. ;    number if we have reached or passed the directory track. 
  929. ;
  930. set$up$c64:
  931.     sta    VIC$sect    ;
  932.     lda    @trk        ;
  933.     cmp    b        ; carry=1 if A < dir$track
  934.     cmc            ; add one if dir$track or more (carry not set)
  935.     aci    0        ; add the carry bit in
  936.     sta    vic$trk
  937.     ret
  938.  
  939.   if    use$1581
  940. ;
  941. ;******    adjust to read multi-512 byte sectors (system sees 1K sector size)
  942. ;
  943. c1581$adj:
  944.     mvi    a,2        ; 2 512 byte sectors equ 1 1K sector
  945.     sta    vic$count
  946.  
  947.     lda    @trk        ;
  948.     cpi    C1581$dir$trk*2    ; carry=1 if A < dir$track
  949.     cmc            ; add one if dir$track or more (carry not set)
  950.     aci    0        ; add the carry bit in
  951.     rar            ; track=@trk/2 ; carry set if odd
  952.     sta    vic$trk        ;
  953.  
  954.     lda    @sect        ; sector # are 0 to 9 (10 sector/trk)
  955.     mov    b,a        ;
  956.     jrnc    bottom$1581    ;
  957.     adi    80h        ; set top of 1581
  958. bottom$1581:
  959.     add    b        ; make 0 to 8
  960.     inr    a        ; adjust to 1 to 9 (odd numbers only)
  961.     sta    VIC$sect    ;
  962.     ret            ;
  963.  
  964.   endif
  965.  
  966.  
  967.     page
  968. ;
  969. ;    A=dsk$info on entry
  970. ;
  971. set$up$MFM:
  972.     mvi    d,0        ; D=side # (0)
  973.     mov    e,a        ; save dsk$info in E
  974.     ani    TypeX        ; look at Type0 to Type7
  975.     jrz    do$type$0    ;
  976.     cpi    Type2
  977.     lda    @trk        ; used by Type1, Type2 and Type3
  978.     jrz    do$type$2
  979.     jrc    do$type$1
  980.  
  981. ;    cpi    Type6
  982. ;    jrz    do$type$6
  983. ;    jnc    do$type$7    ; MSB of sector(byte) set for 2nd side of disk
  984.  
  985.     cpi    Type7
  986.     jz    do$type$7    ; MSB of sector(byte) set for 2nd side of disk
  987. ;
  988. ;    only types 0 to 2 and 7 are currenty defined
  989. ;        Type3 to Type6 will do Type2
  990. ;do$type$3:
  991. ;do$type$6:
  992.  
  993. do$type$2:
  994.     mov    b,a        ; save a copy in B
  995.     sui    40
  996.     jrc    do$type$0    ; jump if still on side 0
  997.     mvi    a,79        ; on back side count 39,38,37,...,0
  998.     sub    b
  999. set$trk:
  1000.     mvi    d,80h        ; D=side # (1)
  1001.     sta    @trk
  1002.     jr    do$type$0
  1003.  
  1004.     page
  1005. ;
  1006. ;    divide the track number by two and if Head=1
  1007. ;        add #sect/side to @sect
  1008. ;
  1009. do$type$1:
  1010.     cmc            ; carry was set clear it
  1011.     rar            ; divide track by 2 (carry gets LSB)
  1012.     sta    @trk
  1013.     jrnc    do$type$0
  1014.     call    get$max$num$b    ; HL and C changed
  1015.     lda    @sect
  1016.     add    b
  1017.     sta    @sect
  1018.  
  1019. do$type$0:
  1020.     lda    @trk
  1021.     sta    vic$trk
  1022.     call    get$max$num$b    ; B=number of sectors per track per side
  1023.     lda    @sect        ; ..HL and C changed
  1024.     cmp    b
  1025.     jrc    is$side$0
  1026.     mvi    d,80h        ; D=side # (1)
  1027.     bit    C1$bit,e    ; dsk$info in E
  1028.                 ; sector numbering continues on side 1 ?
  1029.     jrnz    is$side$0    ; yes, do not remove side one bias
  1030.     sub    b        ; no, remove side one bias
  1031. is$side$0:
  1032.     mov    c,a        ; hold @sect in C    
  1033.     mov    a,e        ; get dsk$info to A
  1034.     ani    S1        ; A=Starting  sector number (0 or 1)
  1035.     add    c        ; add back @sect
  1036.     ora    d        ; add in the side bit
  1037.     sta    vic$sect
  1038.     ret
  1039.  
  1040.     page
  1041. ;
  1042. ;    input:
  1043. ;        DE = number bytes to read
  1044. ;        HL = DMA address
  1045. ;
  1046.     CSEG
  1047. rd$1571$data:
  1048.     lda    @dbnk            ; get the disk DMA bank
  1049.     call    ?bank            ; set it
  1050.  
  1051.     lxi    b,0DC0Dh        ; D1ICR
  1052. rd$1571$stat$wait:
  1053.     inp    a
  1054.     ani    8            ; data ready bit set?
  1055.     jrz    rd$1571$stat$wait    ; no, loop
  1056.  
  1057.     mvi    c,0ch            ; D1SDR
  1058.     inp    a            ; read the status byte
  1059.     sta    vic$data        ; save it
  1060.     ani    0eh            ; any errors ?
  1061.     jrnz    rd$1571$exit        ; yes, exit
  1062.  
  1063.     lxi    b,0DD00h
  1064.     inp    a            ; get current clock polarity
  1065.  
  1066. rd$1571$next:
  1067.     lxi    b,0DD00h        ; D2PRA
  1068.     xri    10h            ; toggle clk$bit
  1069.     outp    a            ; clock the 1571 for a byte
  1070.  
  1071.     dcr    e            ; DE=count
  1072.     jnz    rd$1571$more        ; leave as normal jump to keep
  1073.     dcr    d            ; the transfer speed at it's max
  1074.     jrz    rd$1571$exit        ; ...
  1075.  
  1076. ;
  1077. rd$1571$more:
  1078.     dcr    b
  1079. rd$1571$wait:
  1080.     mvi    c,0dh            ; D1ICR (DC0Dh)
  1081.     inp    c
  1082.     bit    3,c
  1083.     jz    rd$1571$wait
  1084.     mvi    c,0ch            ; D1SDR
  1085.     ini                ; (hl) <- (bc) ; hl <- hl+1 ; b <- b-1
  1086.     jmp    rd$1571$next
  1087.  
  1088.  
  1089. rd$1571$exit:
  1090.     sta    bank$0            ; restore current mem config
  1091.     ret
  1092.  
  1093.     page
  1094.  
  1095. clk$in    equ    40h
  1096. ;
  1097. ;    input:
  1098. ;        DE = number of bytes to write
  1099. ;        HL = DMA address
  1100. ;
  1101. wr$1571$data:
  1102.     call    ?di$int
  1103. ; do spout inline
  1104.     lxi    b,mode$reg
  1105.     mvi    a,fast$wr$en
  1106.     sta    io$0
  1107.     outp    a            ; set data direction to output
  1108.     sta    bank$0
  1109.  
  1110.     lxi    b,0dc05h        ; low (D1T1h)
  1111.     xra    a
  1112.     outp    a
  1113.     dcr    c            ; low(D1T1l)
  1114.     mvi    a,3            ; clk = osc/3
  1115.     outp    a            ;
  1116.  
  1117.     mvi    c,0eh            ; D1CRA
  1118.     inp    a
  1119.     ani    80h
  1120.     ori    55h
  1121.     outp    a
  1122.     dcr    c            ; D1ICR
  1123.     inp    a
  1124.  
  1125.     lda    @dbnk            ; get the disk DMA bank
  1126.     call    ?bank            ; set it
  1127.  
  1128.     mvi    a,clk$in
  1129.     sta    cur$clk
  1130.  
  1131.     page
  1132. ;
  1133. ;
  1134. clk$wait:
  1135.     lxi    b,0dd00h        ; D2PRA
  1136.     inp    a
  1137.     inp    c            ; debounce
  1138.     cmp    c
  1139.     jrnz    clk$wait
  1140.  
  1141.     lda    cur$clk            ; get old clk value
  1142.     xra    c            ; check if changed 
  1143.     ani    clk$in            ; (only clock in bit)
  1144.     jrz    clk$wait        ; loop if not
  1145.  
  1146.     mov    a,c            ; 
  1147.     sta    cur$clk            ; make this the current clk value
  1148.     lxi    b,0dc0ch        ; D1SDR
  1149.     mov    a,m
  1150.     outp    a            ; send character to drive
  1151.     inx    h            ; advance pointer
  1152.     dcx    d            ; dec the char count
  1153.  
  1154.     inr    c            ; D1ICR
  1155. send$wait:
  1156.     inp    a
  1157.     ani    8
  1158.     jz    send$wait
  1159.  
  1160.     mov    a,d
  1161.     ora    e
  1162.     jnz    clk$wait        ; go send the next byte
  1163.  
  1164. ; do spin
  1165.     lxi    b,0DC0Eh        ; D1CRA
  1166.     inp    a
  1167.     ani    80h
  1168.     ori    8
  1169.     outp    a
  1170.     lxi    b,mode$reg
  1171.     mvi    a,fast$rd$en
  1172.     sta    io$0            ; enable the MMU
  1173.     outp    a            ; set data direction to input
  1174.     sta    bank$0            ; disable MMU
  1175. ; spin done
  1176.  
  1177.     page
  1178.  
  1179.     lxi    b,0DC0Dh        ; D1ICR
  1180.     inp    a            ; clear data pending flag
  1181.  
  1182.     lxi    b,0DD00h        ; D2PRA
  1183.     inp    a
  1184.     ori    10h            ; set clk$bit low (hardware inverted)
  1185.     outp    a            ; 
  1186.  
  1187.     lxi    b,0DC0Dh        ; D1ICR
  1188. wait$status:
  1189.     inp    a
  1190.     ani    8
  1191.     jrz    wait$status
  1192.  
  1193.     lxi    b,0DC0Ch        ; D1SDR
  1194.     inp    d
  1195.  
  1196.     lxi    b,0DD00h        ; D2PRA
  1197.     inp    a
  1198.     ani    not(10h)        ; set clk$bit hi (hardware inverted)
  1199.     outp    a            ; 
  1200.  
  1201.     mov    a,d            ; recover the status byte
  1202.     sta    vic$data
  1203.  
  1204.     ei
  1205.     ret
  1206.  
  1207.     page
  1208. ;
  1209. ;    This routine is used to move a sector of data
  1210. ;     to/from the sector buffer and the DMA pointer.
  1211. ;         A=0 for buffer to DMA  (disk read)
  1212. ;         A<>0 for DMA to buffer (disk write)
  1213. ;
  1214.     CSEG
  1215. ?dkmov:
  1216.     lhld    local$DMA    ; current DMA adr
  1217.     lxi    d,@buffer    ; location of disk read/write buffer
  1218.     lxi    b,256        ; sector size
  1219. ;
  1220. ;
  1221. dk$cont:
  1222.     ora    a
  1223.     jrnz    dsk$read    ; swap pointer for read
  1224.     xchg
  1225. ;
  1226. ;
  1227. dsk$read:
  1228.     lda    @dbnk        ; get the disk bank
  1229.     call    ?bank
  1230.     ldir            ; do the data move
  1231.     sta    bank$0        ; current bank will ALWAYS be 0
  1232.     ret
  1233.  
  1234. ;
  1235. ;
  1236. ;
  1237.     DSEG
  1238. dsk$fun:
  1239.     sta    vic$cmd
  1240.     lda    stat$enable
  1241.     ani    1            ; display of disk info enabled?
  1242.     cnz    disp$dsk$info        ; yes, go display disk info
  1243.     jmp    ?fun65+3        ; go do the function
  1244.  
  1245.     page
  1246. ;
  1247. ;
  1248. ;
  1249.     DSEG
  1250. ?dskst:
  1251. disp$dsk$info:
  1252.     mvi    a,72            ; r/w in col 72 (col 0-79)
  1253.     sta    offset
  1254.     lda    vic$cmd
  1255.     mvi    b,'R'
  1256.     dcr    a            ; ?1 normal$rd
  1257.     jrz    out$cmd$rd
  1258.     dcr    a            ; ?2 normal$wr
  1259.     jrz    out$cmd$wr
  1260.     dcr    a            ; ?3 fast$rd
  1261.     jrz    out$cmd$rd
  1262.     dcr    a            ; ?4 fast$wr
  1263.     rnz
  1264. out$cmd$wr:
  1265.     mvi    b,'W'
  1266. out$cmd$rd:
  1267.     call    disp$B
  1268.     call    disp$space
  1269.     mvi    b,'A'-1
  1270.     lda    vic$drv
  1271. next$drv:
  1272.     inr    b
  1273.     rrc
  1274.     jrnc    next$drv
  1275.  
  1276.     call    disp$B
  1277.     lda    vic$trk
  1278.     call    disp$dec
  1279.     lda    vic$sect
  1280.     ani    80h
  1281.     cz    disp$space
  1282.     mvi    b,'-'
  1283.     cnz    disp$B
  1284.     lda    vic$sect    
  1285.     ani    7fh
  1286.  
  1287.     page
  1288. ;
  1289. ;
  1290. ;
  1291. disp$dec:
  1292.     mvi    b,'0'-1
  1293.  
  1294. conv$loop:
  1295.     inr    b
  1296.     sui    10
  1297.     jrnc    conv$loop
  1298.  
  1299.     adi    '0'+10
  1300.     push    psw
  1301.     call    disp$B
  1302.     pop    psw
  1303. disp$A:
  1304.     mov    b,a
  1305. disp$B:
  1306.     lda    offset
  1307.     mov    c,a            ; col # in C
  1308.     inr    a
  1309.     sta    offset            ; advance cursor position
  1310.     xra    a            ; no attribute to write
  1311.     call    ?stat
  1312.  
  1313.     xra    a
  1314.     ret
  1315.  
  1316. disp$space:
  1317.     mvi    b,' '
  1318.     jr    disp$B
  1319.  
  1320.     page
  1321. ;
  1322. ; Extended Disk Parameter Headers (XDPHs)
  1323. ;
  1324.     CSEG            ; place tables in common
  1325. ;
  1326. ;    1st disk drive on the system
  1327. ;
  1328.     dw    write$154X
  1329.     dw    read$154X
  1330.     dw    login$154X
  1331.     dw    init$154X
  1332.     db    1        ; bit 0 set (drive 0)
  1333.     db    dsk$c128    ; format type byte
  1334. cmdsk0:    
  1335.     dph    0,dpb$0
  1336.  
  1337. dpb$0:
  1338.     dpb    1024,5,159,2048,128,0
  1339.     db    0        ; max sector number and lock flag
  1340.     dw    0        ; MFM table pointer
  1341.  
  1342.     page
  1343. ;
  1344. ;    2nd disk Drive on the system
  1345. ;
  1346.     dw    write$154X
  1347.     dw    read$154X
  1348.     dw    login$154X
  1349.     dw    init$154X
  1350.     db    2        ; bit 1 set (drive 1)
  1351.     db    dsk$c128    ; format type byte 
  1352. cmdsk1:
  1353.     dph    0,dpb$1
  1354.  
  1355. dpb$1:
  1356.     dpb    1024,5,159,2048,128,0
  1357.     db    0        ; max sector number and lock flag
  1358.     dw    0        ; MFM table pointer
  1359.  
  1360.     page
  1361. ;
  1362. ;    3rd disk drive on the system
  1363. ;
  1364.     dw    write$154X
  1365.     dw    read$154X
  1366.     dw    login$154X
  1367.     dw    init$154X
  1368.     db    4        ; bit 2 set (drive 2)
  1369.     db    dsk$c128    ; format type byte
  1370. cmdsk2:    
  1371.     dph    0,dpb$2
  1372.  
  1373. dpb$2:
  1374.     dpb    1024,5,159,2048,128,0
  1375.     db    0        ; max sector number and lock flag
  1376.     dw    0        ; MFM table pointer
  1377.  
  1378.     page
  1379. ;
  1380. ;    4th disk drive on the system
  1381. ;
  1382.     dw    write$154X
  1383.     dw    read$154X
  1384.     dw    login$154X
  1385.     dw    init$154X
  1386.     db    8        ; bit 3 set (drive 3)
  1387.     db    dsk$c128    ; format type byte 
  1388. cmdsk3:
  1389.     dph    0,dpb$3
  1390.  
  1391. dpb$3:
  1392.     dpb    1024,5,159,2048,128,0
  1393.     db    0        ; max sector number and lock flag
  1394.     dw    0        ; MFM table pointer
  1395.  
  1396.     page
  1397. ;
  1398. ;    5th disk drive on the system
  1399. ;    (Drive E: will be used as Drive F: by the Quick Brown Box -RW)
  1400. ;
  1401.     dw    write$154X
  1402.     dw    read$154X
  1403.     dw    login$154X
  1404.     dw    init$154X
  1405.     db    16        ; bit 4 set (drive 4) (-RW)
  1406.     db    dsk$c128    ; format type byte
  1407. cmdsk4:
  1408.     dph    0,dpb$4
  1409.  
  1410. dpb$4:
  1411.     dpb    1024,1,1360,2048,128,0
  1412.     db    0        ; max sector number and lock flag
  1413.     dw    0        ; MFM table pointer
  1414.  
  1415.     page
  1416. ;
  1417. ;    NOTE: The blocking factor for all of these formats is
  1418. ;        1K (2K for double sided), thus the fractional
  1419. ;        parts are unusable by CP/M.  They can be accessed
  1420. ;        by absolute sector addressing.
  1421. ;
  1422. ;    NOTE: 1571 and 1541 disk drives use track numbers
  1423. ;        of 1 to 35 and sector numbers of 0 to nn
  1424.  
  1425. ;
  1426. ;        The method used to access the full disk
  1427. ;        is to tell the system that there is 1 sector
  1428. ;        per track and then to use the track # as an
  1429. ;        absolute sector address and do conversion in BIOS.
  1430. ;
  1431. ; 
  1432. ; DPB FOR C128 CP/M 3.0 disk        ( 170K, 34K larger then C64 CP/M)
  1433. ;    256 byte sectors        ( 170.75K )
  1434. ;    1 sectors/track
  1435. ;        up to 21 physical sectors (0 to 16,17,18 or 20)
  1436. ;    680 tracks/disk (usable, 683 real)
  1437. ;        35 physical tracks (0 to 34)
  1438. ;    1K allocation blocks
  1439. ;    64 directory entries
  1440. ;    track offset of 0
  1441. ;
  1442.     DSEG        ; these tables are moved to common when used
  1443. dpb$c128$SS:        ; (170 allocation units)
  1444.     dpb    1024,1,170,1024,64,0
  1445.  
  1446.     page
  1447. ;
  1448. ; DPB FOR C128 CP/M 3.0 double sided disk    ( 340K )
  1449. ;    1024 byte sectors (phy=256)        ( 341.5K )    
  1450. ;    1 sectors/track
  1451. ;        up to 21 physical sectors (0 to 16,17,18 or 20)
  1452. ;    340 tracks/disk (usable, 1366 real)
  1453. ;        70 physical tracks (0 to 34 side 0, 35 to 69 side 1)
  1454. ;    2K allocation units
  1455. ;    128 directory entrys
  1456. ;    track offset of 0
  1457. ;
  1458. dpb$c128$DS:        ; (170 allocation units)
  1459.     dpb    1024,1,340,2048,128,0
  1460.  
  1461.     page
  1462. ;
  1463. ; DPB FOR C64 CP/M 2.2 disk --             ( 136K )
  1464. ;    256 byte sectors
  1465. ;    17 sectors / tracks    (sector numbering 0-16)
  1466. ;        sector 18 to n on the outer tracks are unused
  1467. ;    34 tracks / disk
  1468. ;        tracks track 2 to 16    (track numbering 0-34)
  1469. ;        track 17 is the C128 directory track (not counted)
  1470. ;        track 19 to 34
  1471. ;    1K allocation blocks
  1472. ;    64 directory entrys
  1473. ;    track offset of 3 (1st two tracks used for CP/M 2.2 boot) plus
  1474. ;    one sector to adjust for sector numbering of 1 to 35 (not 0 to 34)
  1475. ;
  1476. dpb$c64$cpm:        ; (144 allocation units)
  1477.     dpb    256,17,34,1024,64,3
  1478.                 
  1479.     page
  1480. ;
  1481. ; DPB FOR C128 CP/M 3.0 C1581 DSDD (3.5")    (    K )
  1482. ;    512 byte sectors            ( 720K )
  1483. ;    10 sectors/track
  1484. ;    159 tracks/disk
  1485. ;        160 physical tracks 80 on top, 79 on bottom, 1 used for
  1486. ;        BAM and disk directory (1581 DOS) (10 sectors per track)
  1487. ;    2K allocation units
  1488. ;    128 directory entrys (2 allocation units)
  1489. ;
  1490.   if    use$1581
  1491. dpb$1581:        ; (xxx allocation units)
  1492.     dpb    1024,5,159,2048,128,0
  1493.   endif
  1494.  
  1495.     page
  1496. ;
  1497.     DSEG
  1498. MFM$table:
  1499.     db    S256*2+(16*2-8)+1    ; 256 byte sect, 16 sect/trk
  1500.     db    MFM+S256+Type0+C0+S1    ;     DSDD
  1501.     dw    0            ; start on track 2 sect 1 (2 alc)
  1502.     dpb    256,32,40,2048,128,2    ; sect# 1 to 16
  1503.     db    16            ; (top and bottom numbered the same)
  1504.     db    'Epson QX10'        ;1 Epson QX10
  1505.                     ; 160 allocation units
  1506.  
  1507.  
  1508.  
  1509.  
  1510.     db    80h+S512*2+(10*2-8)+1    ; 512 byte sect, 10 sect/trk
  1511. ;    db    S256*2            ; track 0 is 256 bytes/sector
  1512.     db    MFM+S512+Type0+C0+S1    ;    DSDD
  1513.     dw    0            ; start on track 2 sect 1 (2 alc)
  1514.     dpb    512,20,40,2048,128,2    ; sect# 1 to 10
  1515.     db    10            ; (top and bottom numbered the same)
  1516.     db    'Epson QX10'        ;2
  1517.                     ; 200 allocation units
  1518.  
  1519.     page
  1520.  
  1521.     db    S512*2+(8*2-8)+1    ; 512 byte sect 8 sect/trk
  1522.     db    MFM+S512+Type2+C0+S1    ;     SSDD
  1523.     dw    0            ; start on track 1 sector 1 (2 alc)
  1524.     dpb    512,8,40,1024,64,1    ; sect# 1 to 8
  1525.     db    8            ;
  1526.     db    ' IBM-8 SS '        ;3
  1527.                     ; 160 allocation units
  1528.  
  1529.  
  1530.  
  1531.  
  1532.     db    S512*2+(8*2-8)+1    ; 512 byte sect 8 sect/trk
  1533.     db    MFM+S512+Type2+C0+S1    ;     DSDD
  1534.     dw    0            ; start on track 1 sector 1 (1 alc)
  1535.     dpb    512,8,80,2048,64,1    ; sect# 1 to 8
  1536.     db    8            ; (top and bottom numbered the same)
  1537.     db    ' IBM-8 DS '        ;4
  1538.                     ; 160 allocation units
  1539.  
  1540.     page
  1541.  
  1542.     db    S512*2+(10*2-8)+0    ; 512 byte sector, 10 sect/trk
  1543.     db    MFM+S512+Type1+C1+S0    ;    DSDD
  1544.     dw    0            ; start on track 0 sector 10 (2 alc)
  1545.     dpb    512,10,80,2048,128,1    ; sect# 0 to 9 on top (even tracks)
  1546.     db    10            ; sect# 10 to 19 on bottom (odd tracks)
  1547.     db    'KayPro IV '        ;5
  1548.                     ; 200 allocation units
  1549.  
  1550.  
  1551.  
  1552.  
  1553.     db    S512*2+(10*2-8)+0    ; 512 byte sect, 10 sect/trk
  1554.     db    MFM+S512+Type0+C1+S0    ;     SSDD
  1555.     dw    0            ; start on track 1 sector 0 (4 alc)
  1556.     dpb    512,10,40,1024,64,1    ; sect# 0 to 9 
  1557.     db    10            ;
  1558.     db    'KayPro II '        ;6
  1559.                     ; 200 allocation units
  1560.  
  1561.     page
  1562.  
  1563.     db    S1024*2+(5*2-8)+1    ; 1024 byte sect, 5 sect/trk
  1564.     db    MFM+S1024+Type0+C0+S1    ;     SSDD
  1565.     dw    0            ; start on track 3 sector 1 (2 alc)
  1566.     dpb    1024,5,40,1024,64,3    ; sect# 1 to 5
  1567.     db    5            ;
  1568.     db    'Osborne DD'        ;7
  1569.                     ; 200 allocation units
  1570.  
  1571.  
  1572.     db    S512*2+(9*2-8)+1    ; 512 byte sect 9 sect/track (uses 8)
  1573.     db    MFM+S512+Type1+C0+S1    ;     DSDD
  1574.     dw    0            ; start on trk 0, sect 1, hd 1 (1 alc)
  1575.     dpb    512,8,80,2048,64,1    ; sect# 1 to 9
  1576.     db    8            ; (top and bottom numbered the same)
  1577.     db    '  Slicer  '        ;8
  1578.                     ; 160 allocation units
  1579.  
  1580.     page
  1581.  
  1582.     db    S256*2+(16*2-8)+1    ; 256 byte sect, 16 sect/trk
  1583.     db    MFM+S256+Type0+C0+S1    ;     DSDD
  1584.     dw    0            ; start on track 4 sect 1 (2 alc)
  1585.     dpb    256,32,40,2048,128,4    ; sect# 1 to 16
  1586.     db    16            ; (top and bottom numbered the same)
  1587.     db    'Epson Euro'        ;9 Epson European (MFCP/M ?)
  1588.                     ; 160 allocation units
  1589.  
  1590.     page
  1591.  
  1592.     db    -1
  1593.     db    MFM            ; 
  1594.     dw    0            ; 
  1595.     dpb    512,20,40,2048,128,2    ; 
  1596.     db    8            ;
  1597.     db    '   None   '        ;10
  1598.  
  1599.     page
  1600.  
  1601.     db    -1
  1602.     db    MFM            ; 
  1603.     dw    0            ; 
  1604.     dpb    512,20,40,2048,128,2    ; 
  1605.     db    8            ;
  1606.     db    '   None   '        ;11
  1607.  
  1608.     db    80h+S512*2+(10*2-8)+1    ; 256 byte sector, 16 sectors/track
  1609.     db    MFM+S512+Type0+C0+S1    ; DSDD
  1610.     dw    0            ; start on track 2 sect 1 (2 alc)
  1611.     dpb    512,20,80,2048,128,0    ; sect# 1 to 10
  1612.     db    10            ; (top and bottom numbered the same)
  1613.     db    ' 1581 GP  '        ;12 - Gene Pizzetta's 1581 format
  1614.  
  1615.  
  1616.  
  1617.     db    62h
  1618.     db    0b0h
  1619.     db    0
  1620.     db    0
  1621.     db    50h
  1622.     db    0
  1623.     db    04
  1624.     db    0fh
  1625.     db    01
  1626.     db    0c8h
  1627.     db    0
  1628.     db    7fh
  1629.     db    0
  1630.     db    0c0h
  1631.     db    0
  1632.     db    20h
  1633.     db    0
  1634.     db    0
  1635.     db    0
  1636.     db    03
  1637.     db    07
  1638.     db    05
  1639.         db      'Maxi 1571 '        ;13 -  M. Garamszeghy's 398K format
  1640.  
  1641.  
  1642.  
  1643.     db    -1
  1644.     db    MFM            ; 
  1645.     dw    0            ; 
  1646.     dpb    512,20,40,2048,128,2    ; 
  1647.     db    8            ;
  1648.     db    '   None   '        ;14
  1649.  
  1650.     page
  1651.  
  1652.     db    -1
  1653.     db    MFM            ; 
  1654.     dw    0            ; 
  1655.     dpb    512,20,40,2048,128,2    ; 
  1656.     db    8            ;
  1657.     db    '   None   '        ;15
  1658.  
  1659.     db    -1
  1660.     db    MFM            ; 
  1661.     dw    0            ; 
  1662.     dpb    512,20,40,2048,128,2    ; 
  1663.     db    8            ;
  1664.     db    '   None   '        ;16
  1665.  
  1666.     page
  1667. ;
  1668. ;    not functional yet
  1669. ;
  1670.  
  1671. ;    db    S1024*2+(5*2-8)+1    ; 1024 byte sect 5 sect/track
  1672. ;    db    MFM+S1024+Type0+C0+S1    ;     SSDD
  1673. ;    dw    0            ; start on trk 2, sect 1 (2 alc)
  1674. ;    dpb    1024,5,40,2048,128,2    ; sect# 1 to 5
  1675. ;    db    5            ;
  1676. ;    db    'Morrow MD2'        ; 
  1677.  
  1678.  
  1679.  
  1680.  
  1681.  
  1682. ;    db    S1024*2+(5*2-8)+1    ; 1024 byte sect  5 sect/trk
  1683. ;    db    MFM+S1024+Type0+C0+S1    ;     DSDD
  1684. ;    dw    0            ; start on trk 1, sect 1, hd 0 (3 alc)
  1685. ;    dpb    1024,10,40,2048,192,1    ; sect# 1 to 5
  1686. ;    db    5            ;
  1687. ;    db    'Morrow MD3'        ; 
  1688.  
  1689.  
  1690. MFM$tbl$entries    equ    ($-MFM$table)/32
  1691.  
  1692.     db    -1            ; mark end of table
  1693.     db    -1
  1694.  
  1695.     page
  1696.  
  1697.     cseg
  1698. cur$clk:    ds    1
  1699.  
  1700.     dseg
  1701. lock$flag    ds    1
  1702. last$match    ds    2
  1703. window$info:    ds    2
  1704.  
  1705. dsk$window    equ    12
  1706.  
  1707. no$dsk$msg:
  1708.         ;1234567890
  1709.     db    ' Missing  ' 
  1710.  
  1711.  
  1712. MFM$match$tbl:
  1713.     ds    2*MFM$tbl$entries    ; MFM$count MUST follow this parm
  1714. MFM$count:
  1715.     ds    1            ; MFM$offset MUST follow this parm
  1716. MFM$offset:
  1717.     ds    1
  1718.  
  1719. MFM$cur$ptr:
  1720.     ds    2
  1721.  
  1722. DPH$pointer:
  1723.     ds    2
  1724.  
  1725. sect$cnt:
  1726.     ds    1
  1727. sect$buf$ptr:
  1728.     ds    2
  1729. sect$buffer:
  1730.     ds    4*2
  1731.  
  1732. local$DMA:
  1733.     ds    2
  1734.  
  1735. status$atr    equ    0
  1736. offset:        db    0
  1737.  
  1738.     end
  1739.  
  1740.