home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / ENTERPRS / CPM / TERMS / IMP245S.LBR / IMP245.AZM / IMP245.ASM
Assembly Source File  |  1991-09-01  |  182KB  |  7,829 lines
  1.  
  2. VERSION    EQU    245    ; IMP (05/22/87)  -    CP/M-80 MODEM PROGRAM
  3. ;
  4. ;-----------------------------------------------------------------------
  5. ;  o  05/22/87  Added BREAK tone routine, added BRKCHR:, J$BREAK and
  6. ;        SENDBRK: routines in each overlay, added a JZ SBREAK
  7. ;        to the main program if ESC-BRKCHR is typed, added the
  8. ;        STPCHR: and SBREAK: routines to the main program and
  9. ;        changed the DONETD: and BYEBYE: routines in main pgm.
  10. ;  o  02/07/87  Changed routine for sending batch header, constructs
  11. ;        the header BEFORE looking for a 'C' from remote, also
  12. ;        uses conventional "GTACK" routine, saving bytes.
  13. ;  o  02/04/87  Increased some "RECV" times for PC Pursuit satelite
  14. ;        networks, added a few manual abort calls, rewrote the
  15. ;        'JZ  CKCAN'  to  'CALL  CKCAN'.
  16. ;  o  01/12/87  Added 'TIG' option to toggle IGNORCTL on/off.  (For
  17. ;        David Cortesi).
  18. ;  o        Now shows file name being received or sent.
  19. ;-----------------------------------------------------------------------
  20. ; 
  21.     ASEG        ; Needed for M80, disregard error if using MAC
  22. ;
  23. ;
  24. ;     NOTE:  This program is written in Intel 8080 code.
  25. ;         It assembles with ASM, LASM, MAC or M80 and
  26. ;         will operate on 8080/8085 or Z80 computers.
  27. ;
  28. ;        COPYRIGHTED 1985,1987 BY IRVIN M. HOFF
  29. ;
  30. ; THIS TELEPHONE MODEM PROGRAM USES THE CHRISTENSEN PROTOCOL.  IT HAS
  31. ; BOTH 'CRC' AND CHECKSUM CAPABILITY FOR ERROR-DETECTION. IT SUPPORTS
  32. ; DIALING AND AUTO-REDIALING FOR 2400 BPS MODEMS USING THE HAYES PRO-
  33. ; TOCOL, AS WELL AS THE RACAL-VADIC 2400V, WITH ITS SUPERIOR PROGRESS
  34. ; REPORTING RESULT CODES.
  35. ;
  36. ;***********************************************************************
  37. ;
  38. ;       THIS PROGRAM IS COPYRIGHTED. IT MAY BE DISTRIBUTED 
  39. ;          WITH NO PREVIOUS WRITTEN PERMISSION WITH THE 
  40. ;          UNDERSTANDING THA╘ NO FINANCIAL GAIN WILL RESULT 
  41. ;          FROM SUCH TRANSACTION.
  42. ;
  43. ;***********************************************************************
  44. ;
  45. ;   GENERAL INTEREST:  When transferring files modem-to-modem, the batch
  46. ;   mode is extremely useful.  It allows automatic transmission of nu-
  47. ;   merous files while the operator at the receiving end does virtually
  48. ;   nothing.  It can be used for single files or with wildcards.  With
  49. ;   normal single program transfer, the receiving end switches from CRC
  50. ;   to checksum in one minute and times out completely in 120 seconds.
  51. ;   (In batch mode it times out in 3 minutes for receive.)  This offers
  52. ;   ample opportunity to transfer programs between individuals.
  53. ;
  54. ;      I2NM-1.ASM can be used to change the telephone overlay numbers
  55. ;         and/or set the alternate dialing system code (also used toè;         change SAVSIZ, mentioned below.)  It can also be used for
  56. ;         intially setting (or changing) any of the function key as-
  57. ;         signments.
  58. ;
  59. ;      I2LIB.COM  can be used to very easily and very quickly change
  60. ;         any of the telephone overlay numbers.
  61. ;
  62. ;      I2FUNC.COM can be used to quickly and easily change any of the
  63. ;         10 function key assignments (or the function key intercept
  64. ;         character itself, which is currently the '^' character.
  65. ;
  66. ;    Significant address changes now used:
  67. ;
  68. ;       0BFFH  -  SAVSIZ  20 = 4k file transfer buffer size
  69. ;                 40 = 8k file transfer buffer size
  70. ;                 80 = 16k file transfer buffer size
  71. ;       0C00H  -  NUMBLIB (start of telephone number library)
  72. ;
  73. ;***********************************************************************
  74. ;
  75. ;    In past years many people have contributed ideas for modem pro-
  76. ;    grams that I have adapted for use in the IMP2 series.  The list
  77. ;    below includes as many of those as I can recall.
  78. ;
  79. ;         Ward Christensen, Jim Mills, Mark Zeigler, Keith Petersen,
  80. ;         Paul Kelly, Bruce Ratoff, John Mahr, Rich Berg, Bob Clyne,
  81. ;         Bill Earnest, Paul Hansknecht, Ron Fowler, Fred Viles, Bob
  82. ;         Plouffe, Ben Bronson, Sigi Kluger, Frank Gaude' and likely
  83. ;         others.
  84. ;                    - Irv Hoff W6FFC
  85. ;
  86. ;***********************************************************************
  87. ;
  88. ; 05/22/87  Improved the GOODBYE routine, added BREAK routine, needs
  89. ;   v245    IMP245 to use it.            - Irv Hoff
  90. ;    
  91. ; 09/22/86  Eliminated converting a '/' to '_' in batch mode.  If send-
  92. ;   v245    ing a file that already exists in batch mode, KMD22 sends an
  93. ;        EOT which in turns displays a "File exists..." line in IMP
  94. ;        and then aborts.  Now accepts "CALL" in addition to "CAL" in
  95. ;        dial mode.            - Irv Hoff
  96. ;  
  97. ; 10/01/85  Fixed SMRESUL5 so autodial works normally with the Anchor
  98. ;   v244    modems.  Fixed DONETD to call J$DSCONT if using modems with
  99. ;        no DTR for disconnect.  (Set byte 011EH to other than 00 in
  100. ;        that case.)  SPDMSG now goes 0-36 ms for delay between char-
  101. ;        acters when sending ASCII files in terminal mode instead of
  102. ;        only 0-9 ms (needed by Osborne OS-1, etc.)  File length now
  103. ;        stored at end of header in hex rather than ASCII, saved 53
  104. ;        bytes.  Batch receive shows file name, length in records and
  105. ;        'k' and time to receive.  (Same feature added to KMD07 - no
  106. ;        longer shows file length at all, with earlier versions of
  107. ;        KMD.)  Fixed STDRV to permit using area 1, which it had pre-
  108. ;        viously ignored - although it allowed selecting all other
  109. ;        user areas.            - Irv Hoff
  110. ;
  111. ; 09/07/85  Found the one of the flags was not being reset after a batch
  112. ;   v243    file was received.  This would prevent subsequent files from
  113. ;        being received if the initial 'C' was garbled.  (This goes
  114. ;        clear back to when CRC was added to MODEM7 in October 1981,
  115. ;        that flag was never reset for batch receive.)  Also removed
  116. ;        a  "CALL  DSCONCT"  which slowed disconneting with ESC-N
  117. ;        or DSC.            - Irv Hoff
  118. ;
  119. ; 08/27/85  The YAM receive routine did not properly handle filenames
  120. ;   v242    with 8 characters and no extent.  Our system of storing file
  121. ;        length turned them into read-only files to which you could
  122. ;        not write.  Other minor changes.
  123. ;                    - Irv Hoff
  124. ;
  125. ; 08/20/85  Added YAM batch mode.  Use the command: TBM to select MODEM7
  126. ;   v241    batch mode if preferred.  Uses some routines adapted from
  127. ;        work done by Dennis Vallianos.
  128. ;                    - Irv Hoff
  129. ;
  130. ; 07/17/85  First version of IMP2, adapted from MDM740.  Supports 2400
  131. ;   v240    bps modems using auto-stepdown Racal-Vadic 2400V protocol or
  132. ;        Hayes 2400 protocol.  Companion overlays start with I2, such
  133. ;        as I2DP-1.ASM for the 8251 with CTC implemented into this
  134. ;        version.  These overlays only work with IMP2.
  135. ;                    - Irv Hoff
  136. ;
  137. ;***********************************************************************
  138. ;
  139. ; 05/07/84  Numerous small bugs fixed that have apparently been present
  140. ;  MDM740   since MODEM7 days.    Copyright notice added when the program
  141. ;        is brought up, to be legal.  Auto-linking added which gives
  142. ;        the ability to automatically redial a sequential list up to
  143. ;        32 numbers.  Two options:
  144. ;
  145. ;            B>>COMMAND:  A,F,4,G,Z
  146. ;                          or
  147. ;            B>>COMMAND:  A/F/4/G/Z
  148. ;
  149. ;        The '/' beeps just once when connected and then jumps auto-
  150. ;        matically to the terminal mode to catch any signon messages
  151. ;        from IBM or Unix systems, etc.  The first option beeps con-
  152. ;        tinuously until the operator hits any key.    This places the
  153. ;        program in the terminal mode.  These two options combine to
  154. ;        make MDM740 one of the most useful modem programs currently
  155. ;        available for dialing busy numbers.
  156. ;                    - Irv Hoff
  157. ;
  158. ; 01/01/83  First version.  Can be assembled with ASM.COM.  (Previously
  159. ;  MDM700   it was necessary to have the MODEM7.LIB file and use MAC.COM
  160. ;        to assemble the program.)  Selected MDM700 as a new program
  161. ;        to allow me to make changes that I felt might be beneficial.
  162. ;        This would not hinder others from updating existing programs
  163. ;        to their own satisfaction.    The name was also selected so it
  164. ;        would fit on databanks limiting file names to 6 characters.
  165. ;                    - Irv Hoff
  166. ;
  167. ;***********************************************************************
  168. ;
  169. ;
  170. YES    EQU    0FFH    ; Use in DB options, MVI  A,YES (8 bit values)
  171. NO    EQU    0    ;  "   "  "    "      "   "  "     "  "     "
  172. TRUE    EQU    0FFFFH    ; Use in all EQUs for conditionals (16 bits)
  173. FALSE    EQU    0    ;  "   "  "   "    "  "    "         "     "
  174. ;
  175. ;
  176. ; Values shown are for a 8251A I/O
  177. ;
  178. PORT    EQU    28H    ; Your base port (data or status)
  179. MDCTL1    EQU    PORT+1    ; Modem control port
  180. MDDATP    EQU    PORT    ; Modem data port
  181. MDRCV    EQU    02H    ; Modem receive ready
  182. MDSND    EQU    01H    ; Modem send ready bit
  183. MDTXE    EQU    05H    ; Modem send buffer empty, holding buffer empty
  184. ;
  185. BDPORTR    EQU    20H    ; CTC port for receive baudrate
  186. BDPORTS    EQU    1AH    ; CTC port for transmit baudrate
  187. ;
  188. MDMODE    EQU    82H    ; Insures 8251A I/O is out of mode with DTR high
  189. MDRSET    EQU    42H    ; Resets USART for additional commands
  190. MDSET1    EQU    4EH    ; 1 stop bit, no parity, 8 bits, x16
  191. MDSET2    EQU    0CEH    ; 2 stop bits, no parity, 8 bits, x16
  192. MDCOM    EQU    17H    ; Reset error flags, RCV, DTR, TX ready
  193. ;
  194. ;
  195. ;-----------------------------------------------------------------------
  196. ;
  197. ;
  198. BUFSIZ    EQU    16    ; Buffer size in Kbytes for ASCII capture to disk
  199.             ; (16k is one file extent)
  200. XFRSIZ    EQU    16    ; File transfer buffer in Kbytes.  Do not make
  201.             ; Any larger than BUFSIZ.  16k works fine on
  202.             ;   all but very slowest floppy systems
  203. STOPBIT    EQU    FALSE    ; Yes, if using 2 stop bits, no if using 1
  204. ;
  205. BDNMCH    EQU    75H    ; Bad name match
  206. ERRLIM    EQU    10    ; Maximum allowable consecutive errors
  207. ERRCRC    EQU    6    ; CRC tries, then switches to CHECKSUM
  208. LIBLEN    EQU    34    ; Length of each phone library entry
  209. RUB    EQU    7FH    ; Rub
  210. STRSPD    EQU    3CH    ; MSPEED location in low ram
  211. CRC    EQU    'C'    ; Requests 'CRC' instead of 'CKSUM'
  212. KSND    EQU    'K'    ; Requests 1k blocks
  213. ESC    EQU    '['-40H    ; ^[ = Escape
  214. SOH    EQU    'A'-40H    ; ^A = Start of header
  215. STX    EQU    'B'-40H    ; ^B = Start of text (for 1k blocks)
  216. EOT    EQU    'D'-40H    ; ^D = End of text
  217. ACK    EQU    'F'-40H    ; ^F = Acknowledge
  218. OKNMCH    EQU    'F'-40H    ; ^F = Ok name match
  219. BELL    EQU    'G'-40H    ; ^G = Bell character
  220. BKSP    EQU    'H'-40H    ; ^H = Backspace
  221. LF    EQU    'J'-40H    ; ^J = Linefeed
  222. NEXTRY    EQU    'K'-40H    ; ^K = Try next phone number, abort this try
  223. CR    EQU    'M'-40H    ; ^M = Carriage return
  224. XON    EQU    'Q'-40H    ; ^Q = XON character
  225. XOFF    EQU    'S'-40H    ; ^S = XOFF character
  226. NAK    EQU    'U'-40H    ; ^U = Not acknowledge
  227. CANCEL    EQU    'X'-40H    ; ^X = Cancel send or receive
  228. CLEARSC    EQU    'Z'-40H    ; ^Z = Clears screen, command mode
  229. EOFCHAR    EQU    'Z'-40H    ; ^Z = End of file
  230. ;
  231. ;
  232. ;-----------------------------------------------------------------------
  233. ;
  234. ;
  235.     ORG    0100H
  236. ;
  237. ;
  238.     JMP    START        ; Skip the data area below
  239. ;
  240. ;
  241. ; These routines and equates are at the beginning of the program so
  242. ; they can be patched by a monitor or overlay file without re-assembling
  243. ; the program.
  244. ;
  245. MSPEED:     DB    6    ; 0=110 1=300 2=450 3=600 4=710 5=1200        103H
  246.             ; 6=2400 7=4800 8=9600 9=19200 default
  247. HS2400:     DB    YES    ; Yes=2400 bps highest speed            104H
  248. HS1200:     DB    NO    ; Yes=1200 bps highest speed            105H
  249. RACAL:     DB    NO    ; Yes=Racal-Vadic 1200V or 2400V or 2400PA    106H
  250. PROMODM: DB    NO    ; Yes=Prometheus ProModem 1200 bps        107H
  251. RESVD1:     DB    NO    ; Reserved for special modems            108H
  252. RESVD2:     DB    NO    ; Reserved for special modems            109H
  253. ;
  254. ;
  255. CLEAR:     DB    1AH    ; Clear screen character (ESC not needed)    10AH
  256. CLOCK:     DB    37    ; Clock speed in MHz x10, 25.5 MHz max.     10BH
  257.             ; 20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  258. BYTDLY:     DB    2    ; 0=0 delay  1=10ms  5=50 ms - 9=90 ms        10CH
  259.             ;   default time to send character in ter-
  260.             ;   minal mode file transfer for slow BBS
  261. CRDLY:     DB    2    ; 0=0 delay 1=100 ms 5=500 ms - 9=900 ms    10DH
  262.             ;   default time for extra wait after CRLF
  263.             ;   in terminal mode file transfer
  264. NOFCOL:     DB    5    ; Number of directory columns shown        10EH
  265. TCHPUL:     DB    'T'    ; T=tone, P=Pulse ('AT' protocol only)        10FH
  266. ;.....
  267. ;
  268. ;
  269. ADDLFD:     DB    NO    ; Yes=add LF after CR to send file in terminal    110H
  270.             ;   mode (normally added by remote echo)
  271. CONVRUB: DB    YES    ; Yes=convert rub to backspace            111H
  272. CRCDFLT: DB    YES    ; Yes=default to CRC checking            112H
  273. IGNRCTL: DB    NO    ; Yes=CTL-chars above ^M not displayed        113H
  274. ;.....
  275. ;
  276. ;
  277. EXTCHR:     DB    '['-40H    ; ESC = preceeds local control character    114H
  278. EXITCHR: DB    'E'    ; Exit character                115H
  279. FILESND: DB    'F'    ; Send file when in terminal mode        116H
  280. NOCONCT: DB    'N'    ; Disconnect from phone line            117H
  281. LOGCHR:     DB    'L'    ; Send logon                    118H
  282. LSTCHR:     DB    'P'    ; Toggle printer                119H
  283. UNSAVCH: DB    'R'    ; Close input text buffer            11AH
  284. SAVECHR: DB    'Y'    ; Open input text buffer            11BH
  285. CLEARS:     DB    'Z'    ; Clears screen, terminal mode            11CH
  286. BRKCHR:     DB    'Q'    ; Send a break tone                11DH
  287. NODTR:     DB    0    ; For future development            11EH
  288. ;.....
  289. ;
  290. ;
  291. ; Handles in/out ports for data and status
  292. ;
  293. I$MDCTL1: IN    MDCTL1        ;                    11FH
  294.       RET            ; IN modem control port         121H
  295.       DB    0,0,0,0,0,0,0    ; Spares if needed            122H
  296. ;
  297. I$MDTXE:  IN    MDCTL1        ; (Needed for SIO or DART register 1    129H
  298.       RET            ;                    12BH
  299.       DB    0,0,0,0,0,0,0    ;                    12CH
  300. ;
  301. I$MDDATP: MVI    A,MDCOM        ;                    133H
  302.       OUT    MDCTL1        ;                    135H
  303.       IN    MDDATP        ;                    147H
  304.       RET            ;                    139H
  305.       DB    0,0,0        ; Spares if needed            13AH
  306. ;
  307. O$MDDATP: OUT    MDDATP        ;                    13DH
  308.       RET            ; OUT modem data port            13FH
  309.       DB    0,0,0,0,0,0,0    ; Spares if needed            140H
  310. ;
  311. A$MDRCV:  ANI    MDRCV        ;                    147H
  312.       RET            ;                    149H
  313. ;
  314. C$MDRCV:  CPI    MDRCV        ;                    14AH
  315.       RET            ;                    14CH
  316. ;
  317. A$MDSND:  ANI    MDSND        ;                    14DH
  318.       RET            ;                    14FH
  319. ;
  320. C$MDSND:  CPI    MDSND        ;                    150H
  321.       RET            ;                    152H
  322. ;
  323. A$MDTXE:  ANI    MDTXE        ;                    153H
  324.       RET            ;                    155H
  325. ;
  326. C$MDTXE:  CPI    MDTXE        ;                    156H
  327.       RET            ;                    158H
  328. ;.....
  329. ;
  330. ;
  331. ; Special exit vector, used by some computers to reset interrupt vectors
  332. ;
  333. J$EXITVEC:RET            ;                    159H
  334.       DB    0,0        ;                    15AH
  335. ;.....
  336. ;
  337. ;
  338. ; Jump vectors needed by each overlay
  339. ;
  340. J$GOODBYE:JMP    GOODBYE        ; Disconnects modem by dropping DTR    15CH
  341. J$INITMOD:JMP    INITMOD        ; Initializes modem, autosets baudrate    15FH
  342. J$STUPR:  JMP    STUPR        ; SET routine to change baudrate    162H
  343. J$SYSVR:  JMP    SYSVR        ; Signon message            165H
  344. ;.....
  345. ;
  346. ;
  347. ; "AT" command strings, can be replaced in individual overlay if needed
  348. ;
  349. J$STRNGA: JMP    STRNGA        ; 1200 bps "AT" string            168H
  350. J$STRNG1: JMP    STRNG1        ; 2400 bps "AT" string            16BH
  351. ;
  352. ;
  353. ; Next fourteen lines should not be changed by user overlay as these go
  354. ; to specific locations in the main program, not in the overlay.
  355. ;
  356. ;
  357. J$CMDSPL: JMP    CMDSPL        ; Allows entry of baudrate on CMD line    16EH
  358. J$CRLF:      JMP    CRLF        ; Turns up one new line on display    171H
  359. J$DIAL:      JMP    DIAL1        ; Start of dialing routine        174H
  360. J$DSCONT: JMP    DSCONT        ; Terminates modem use            177H
  361. J$GOLST:  JMP    GOLST        ; Printer routine, needed by Apple //e    17AH
  362. J$ILPRT:  JMP    ILPRT        ; Prints an inline string, 0 to end    17DH
  363. J$INBUF:  JMP    INBUF        ; Stores a keybd string for comparison    180H
  364. J$INLNCP: JMP    INLNCP        ; Inline "compare strings" routine    183H
  365. J$INMDM:  JMP    INMDM        ; Max .1 sec wait for modem character    186H
  366. J$RCVRSP: JMP    RCVRSP        ; For 3801 I/O use (TV-803)        189H
  367. J$SNDCHR: JMP    SNDCHR        ; Sends a character to the modem    18CH
  368. J$SNDSTR: JMP    SNDSTR        ; Sends a string to the modem, $ to end 18FH
  369. J$TIMER:  JMP    TIMER        ; .1 second timer (amount in 'B' reg.)    192H
  370. J$BREAK:  JMP    SENDBRK        ; Break routine                195H
  371. J$NEW2:      DB    0,0,0        ; For future needs            198H
  372. ;.....
  373. ;
  374. ;
  375. ; For 2400 bps auto-stepdown units
  376. ;
  377. MANUAL:      DB    0        ; For manual selection flag        19BH
  378. J$300:      JMP    OK300        ; Sets baudrate to 300 baud        19CH
  379. J$1200:      JMP    OK1200        ; Sets baudrate to 1200 bps        19FH
  380. J$2400:      JMP    OK2400        ; Sets baudrate to 2400 bps        1A2H
  381. ;.....
  382. ;
  383. ;
  384. LOGPTR:      DW    LOGON        ; Pointer to display LOGON message    1A5H
  385. ;
  386. SYSVR:      CALL    J$ILPRT        ; Display the following line        1A7H
  387.       DB    'Version for Datapoint 1560 modem port 28H' ;        1AAH
  388.       DB    CR,LF,0
  389.       RET
  390. ;.....
  391. ;
  392. ;
  393. ;-----------------------------------------------------------------------
  394. ;
  395. ; NOTE:  You can change the SYSVER message to be longer or shorter.  The
  396. ;     end of your last routine should terminate by 0400H (601 bytes
  397. ;     available after start of SYSVER).
  398. ;
  399. ;-----------------------------------------------------------------------
  400. ;
  401. ; You can put in a message at this location which can be called up with
  402. ; (special character-L).  You can put in several lines.  End with a 0.
  403. ;
  404. ;
  405. LOGON:    DB    '              - Irv Hoff (W6FFC) '
  406.     DB    'Los Altos Hills, CA 94022',CR,LF,0
  407. ;
  408. ;=======================================================================
  409. ;
  410. ; This routine sends a 300 ms break tone to the modem
  411. ;
  412. SENDBRK:
  413.     MVI    A,3FH        ; DTR normal, send break tone
  414.     JMP    GOODBYE+2
  415. ;.....
  416. ;
  417. ;
  418. ; This routine sets DTR low for 300 ms to disonnect the phone
  419. ;
  420. GOODBYE:
  421.     MVI    A,3DH        ; Send break, turn off DTR
  422.     OUT    MDCTL1        ; Send to status port
  423.     MVI    B,3        ; Delay 300 ms to hang up phone
  424.     CALL    J$TIMER
  425.     MVI    A,MDCOM        ; Normal send/receive with DTR
  426.     OUT    MDCTL1        ; Send to status port
  427.     RET
  428. ;.....
  429. ;
  430. ;
  431. ; Sets 8251 to 8 bits, DTR, RCV and TX ready
  432. ;
  433. INITMOD:
  434.     MVI    A,MDMODE    ; Insure 8251 is out of mode
  435.     OUT    MDCTL1
  436.     XTHL            ; Small delay to complete command
  437.     XTHL
  438.     MVI    A,MDRSET    ; Reset the 8251A for new command
  439.     OUT    MDCTL1
  440.     XTHL            ; Small delay to complete command
  441.     XTHL
  442.     MVI    A,MDSET1    ; Set stop pulse, no parity 8 bits, x16
  443.     OUT    MDCTL1
  444.     XTHL            ; Small delay to complete command
  445.     XTHL
  446.     MVI    A,MDCOM        ; Error reset, RCV, DTR, TX ready
  447.     OUT    MDCTL1
  448.     XTHL            ; Small delay to complete command
  449.     XTHL
  450. ;
  451.     LDA    MSPEED        ; Get the selected value
  452.     CPI    1        ; 300 bps
  453.     JZ    OK300
  454.     CPI    5        ; 1200 bps
  455.     JZ    OK1200
  456.     CPI    6        ; 2400 bps
  457.     JZ    OK2400
  458.     CPI    8        ; 9600 bps
  459.     JZ    OK9600
  460.     JMP    STUPR1        ; Else ask what is wanted
  461. ;.....
  462. ;
  463. ;
  464. STUPR:    CALL    J$CMDSPL    ; Gives us CMDBUF+6
  465.     JNC    STUPR2
  466. ;
  467. STUPR1:    CALL    J$ILPRT
  468.     DB    'Input Baud Rate (300, 1200, 2400, 9600): ',0
  469.     LXI    D,BAUDBUF    ; Point to new input buffer
  470.     CALL    J$INBUF
  471.     CALL    J$CRLF
  472.     LXI    D,BAUDBUF+2
  473. ;
  474. STUPR2:    CALL    J$INLNCP    ; Compare BAUDBUF+2 with chars. below
  475.     DB    '300',0
  476.     JNC    OK300        ; Go if got match
  477.     CALL    J$INLNCP
  478.     DB    '1200',0
  479.     JNC    OK1200
  480.     CALL    J$INLNCP
  481.     DB    '2400',0
  482.     JNC    OK2400
  483.     CALL    J$INLNCP
  484.     DB    '9600',0
  485.     JNC    OK9600
  486.     CALL    J$ILPRT        ; All matches failed, tell operator
  487.     DB    '++ Incorrect entry ++',CR,LF,BELL,CR,LF,0
  488.     JMP    STUPR1        ; Try again
  489. ;
  490. OK300:    MVI    A,1        ; MSPEED 300 baud value
  491.     MVI    B,BD300        ; Get 300 baud parameters in 'HL'
  492.     JMP    LOADBD        ; Go load them
  493. ;
  494. OK1200:    MVI    A,5
  495.     MVI    B,BD1200
  496.     JMP    LOADBD
  497. ;
  498. OK2400:    XRA    A
  499.     STA    MANUAL        ; Reset to maximum auto-speed
  500.     MVI    A,6
  501.     MVI    B,BD2400
  502.     JMP    LOADBD
  503. ;
  504. OK9600:    MVI    A,8
  505.     MVI    B,BD9600
  506. ;
  507. LOADBD:    STA    MSPEED        ; Change time-to-send to match baudrate
  508.     MVI    A,47H        ; CTC command word
  509.     OUT    BDPORTR        ; Give to both Tx and Rx sections
  510.     OUT    BDPORTS
  511.     MOV    A,B        ; Get baudrate byte
  512.     OUT    BDPORTR        ; Give to both Tx and Rx sections
  513.     OUT    BDPORTS
  514.     RET
  515. ;.....
  516. ;
  517. ;
  518. ; Table of baudrate parameters
  519. ;
  520. BD300    EQU    20H        ; 9600/300  converted to hex value
  521. BD1200    EQU    08H        ; 9600/1200
  522. BD2400    EQU    04H        ; 9600/2400
  523. BD9600    EQU    01H        ; 9600/9600
  524. ;
  525. BAUDBUF:DB    10,0,0,0,0,0
  526.     DB    0,0,0,0,0,0
  527. ;
  528. ;                   end
  529. ;=======================================================================
  530. ;
  531. ;         RACAL-VADIC/HAYES DIALING ROUTINES
  532. ;
  533. ;=======================================================================
  534. ;
  535. ;
  536.     ORG    400H
  537. ;
  538. ;
  539. ; Dialing routine
  540. ;
  541. DIAL1:    XRA    A
  542.     STA    AUTODIR        ; Zero the direct to terminal mode flag
  543.     STA    AUTOFL        ; Zero the auto-linking flag
  544.     STA    CRFLAG        ; Zero the continuous dial flag
  545.     LXI    H,0
  546.     SHLD    DIALCT        ; Zero the dial count
  547.     LXI    H,CMDBUF+1    ; Point to the number of characters in..
  548.     MOV    A,M        ; The buffer, then get the number
  549.     CPI    3+1        ; Anything typed after 'CAL'?
  550.     JC    DIAL2        ; If not, go through library routine
  551. ;
  552. ;
  553. ; If there were only 3 characters, then "CAL<RET>" was typed -- the user
  554. ; obviously expecting to get a phone number (or letter) from the library
  555. ; file.  If 4 or more, a number (or letter) was typed in from the menu
  556. ; command line, so move the characters down 4 to compensate.  Needed for
  557. ; auto-redialing of menu command line entries.
  558. ;
  559.     MOV    C,A        ; Put into the 'C' reg.
  560.     MVI    B,0        ; Will move original number down 4
  561.     SUI    4        ; Eliminate the 'CAL' portion
  562.     MOV    M,A        ; Store new count at CMDBUF+1
  563.     INX    H        ; CMDBUF+2 (first character of string)
  564.     XCHG            ; 'DE' now has CMDBUF+2
  565.     LXI    H,CMDBUF+6    ; Point to number (or letter) to dial
  566.     CALL    MOVER        ; Move the group down 4 places
  567.     JMP    DIAL4        ; Check if library number, then dial
  568. ;...
  569. ;
  570. ;
  571. ; Comes here if no phone number was manually entered after 'CAL' and if
  572. ; no phone library code was entered.  Displays the phone number library
  573. ; then asks for an entry.
  574. ;
  575. DIAL2:    MVI    C,18        ; Number of lines to move
  576.     LXI    H,NUMBLIB    ; Start of phone number library
  577.     LXI    D,BUFFER    ; Buffer add. to store them temporarily
  578.     CALL    NEWLINE        ; Start with CR/LF
  579.     STAX    D        ; +LF
  580.     INX    D        ; And bump it
  581. ;
  582. DIAL3:    MVI    B,LIBLEN    ; Number of bytes to move
  583.     CALL    MOVE        ; Move to buffer
  584.     CALL    SPACES        ; 2 entries + 3 spaces = 71 characters
  585.     PUSH    H        ; Save source address
  586.     PUSH    D        ; Save destination address
  587.     LXI    D,(17*LIBLEN)    ; Get offset of 17 times entry length
  588.     DAD    D        ; Add it to source address
  589.     POP    D        ; Restore destination address
  590.     MVI    B,LIBLEN    ; Get length of library entry
  591.     CALL    MOVE        ; Move another entry
  592.     POP    H        ; Restore source address
  593.     CALL    NEWLINE
  594.     DCR    C        ; One less line to print
  595.     JNZ    DIAL3        ; If not zero, print another
  596.     MVI    A,'$'        ; BDOS print routine terminate character
  597.     STAX    D        ; Store in buffer
  598.     CALL    CLRTST
  599.     MVI    C,PRINT
  600.     LXI    D,BUFFER    ; Print the library on the CRT
  601.     CALL    BDOS
  602.     CALL    J$ILPRT        ; Ask which one is wanted
  603.     DB    CR,LF,'Enter library code or phone number,',CR,LF
  604.     DB    'Hit RET to abort this function now or',CR,LF
  605.     DB    'CTL-X quits while dialing or ringing: ',0
  606.     LXI    D,CMDBUF
  607.     CALL    J$INBUF
  608. ;
  609. ;
  610. ; You now have either a library code or a manually entered phone num-
  611. ; ber.    These either came from the menu command line or from the library
  612. ; command line.  Next we see if a code, if so, get the corresponding
  613. ; line with phone number from the library.  If a number greater than
  614. ; one digit, we ignore the library look-up.  (Ringback numbers must end
  615. ; with letter 'R'.)
  616. ;
  617. DIAL4:    LXI    H,CMDBUF+1    ; Number of characters in buffer
  618.     MOV    A,M
  619.     ORA    A        ; Null means CR was typed
  620.     JZ    DIALEXIT    ; Abort dialing, return to menu
  621.     STA    NUMBER
  622.     LDA    CMDBUF+3    ; See if at least two characters entered
  623.     CPI    '/'        ; Slash for linking, direct to terminal..
  624.     CZ    AUTO        ; Mode on answer
  625.     CPI    ','        ; Comma used for linking
  626.     CZ    AUTO1        ; If yes, set it up for auto-linking
  627. ;
  628. ;
  629. ; Wait until now to initialize the modem in case they only wanted to see
  630. ; a number in the library.
  631. ;
  632.     CALL    SMIN1        ; Initialize the modem
  633. ;
  634. ;
  635. ; Check to see how many characters were typed.    If more than one, then
  636. ; it was a hand-entered phone number, so exit.
  637. ;
  638. DIAL5:    XRA    A
  639.     STA    ANSWFL        ; Clear the answer flag, just in case
  640.     LDA    AUTOFL        ; Auto-link flag set?
  641.     ORA    A
  642.     JNZ    AUTO2        ; If yes exit
  643.     LDA    NUMBER        ; Number of characters in buffer
  644.     STA    CMDBUF+1    ; Reset the character count, if needed
  645.     CPI    1+1        ; More than one character?
  646.     JNC    DIAL14        ; If more than one, hand-entered number
  647.     LXI    H,CMDBUF+2    ; First character in phone number line
  648. ;
  649. ;
  650. ; If just one character entered, see if a (A-Z) letter
  651. ;
  652. DIAL6:    MOV    A,M
  653.     MVI    B,'A'        ; First letter of alphabet
  654.     MVI    E,0        ; Counts number of letters to match
  655.     MVI    C,26        ; Number of letters in alphabet
  656. ;
  657. DIAL7:    CMP    B        ; Letter from table?
  658.     JZ    DIAL9        ; If yes, get phone number, else
  659.     INR    B        ; Make next letter (A-Z)
  660.     INR    E        ; Count up
  661.     DCR    C        ; Count down
  662.     JNZ    DIAL7        ; Try next one in (A-Z) table
  663. ;
  664. ;
  665. ; If not (A-Z) then should be (0-9)
  666. ;
  667.     MVI    B,'0'        ; First digit to check
  668.     MVI    E,26        ; Point past alpha codes
  669.     MVI    C,10        ; Number of digits in table
  670. ;
  671. DIAL8:    CMP    B        ; Number from table?
  672.     JZ    DIAL9        ; If yes, go dial, else
  673.     INR    B        ; Make next digit to compare
  674.     INR    E        ; Make next table line number
  675.     DCR    C        ; Count down - loop counter
  676.     JNZ    DIAL8        ; Loop
  677.     JMP    DIALBAD        ; Error if not a number or a letter
  678. ;
  679. ;
  680. ; Now have a match between the requested code and one in the library.
  681. ; E-reg. holds the library line number (1-36) that matches the requested
  682. ; code (A-Z or 0-9).
  683. ;
  684. DIAL9:    LXI    H,NUMBLIB    ; Phone number library
  685.     LXI    B,LIBLEN    ; Length of library entry
  686.     MOV    A,E        ; Number of times to library length to HL
  687.     ORA    A        ; Set flags
  688.     JZ    DIAL11
  689. ;
  690. DIAL10:    MOV    A,M        ; Get first char of selected lib entry
  691.     ORA    A        ; Set flags
  692.     JZ    DIALBAD        ; Send bad library msg and abort
  693.     DAD    B        ; Increment 'HL' by library length
  694.     DCR    E        ; Countdown
  695.     JNZ    DIAL10        ; Not there yet, loop
  696. ;
  697. ;
  698. ; Now have the line in the phone number library matching the requested
  699. ; letter so store that line starting at 'CMDBUF+1'
  700. ;
  701. DIAL11:    MVI    B,LIBLEN    ; Number of characters to get from table
  702.     LXI    D,CMDBUF+1    ; Point to buffer
  703.     XCHG            ; 'HL' points to CMDBUF+1
  704.     MOV    M,B        ; Length of each table entry
  705.     XCHG            ; Restore the registers
  706.     INX    D        ; Point to first char position in buffer
  707.     CALL    MOVE        ; Move the table entry to the buffer
  708. ;
  709. ;
  710. ; Now have the full line including phone number in 'CMDBUF' area.  Scan
  711. ; past the descriptive portion of library entry - terminate scan at the
  712. ; first '.'  This allows commas and numbers to be part of the text, such
  713. ; as:
  714. ;         'A=DataTech, Node 7..1-408-238-9621'
  715. ;
  716. DIAL12:    LXI    H,CMDBUF+1
  717.     MOV    E,M        ; Number of chars in buffer
  718.     INX    H        ; Point to 1st character in buffer
  719. ;
  720. DIAL13:    MOV    A,M        ; Get next character
  721.     CALL    TYPE        ; Show it
  722.     INX    H        ; Bump pointer
  723.     DCR    E        ; Decrement count
  724.     JZ    DIALEXIT    ; Exit if no '.' (bad library entry)
  725.     CPI    '.'        ; Dot?
  726.     JZ    DIAL15        ; Yes, go dial the phone
  727.     JMP    DIAL13        ; No, loop for next character
  728. ;.....
  729. ;
  730. ;
  731. ; There is a user entered phone number in 'CMDBUF' area
  732. ;
  733. DIAL14:    LXI    H,CMDBUF+1    ; Get the number of characters in buffer
  734.     MOV    A,M
  735.     MOV    E,M
  736.     INX    H        ; Point to 1st character to dial
  737. ;.....
  738. ;
  739. ;
  740. ; Loop to dial the phone number pointed to by 'HL', character count in
  741. ; the 'E' register.  First, set the modem to auto-dial mode.
  742. ;
  743. DIAL15:    PUSH    H
  744.     CALL    SMIN2        ; Put modem in dialing mode
  745.     POP    H
  746.  
  747. DIAL16:    MOV    A,M        ; Get first number from the buffer
  748.     ORA    A        ; Set flags
  749.     JZ    DIALBAD        ; Bad number if a null
  750. ;
  751. ;
  752. ; Dial a digit, check keyboard for abort
  753. ;
  754.     CALL    DIALA        ; Dial a digit, show on CRT
  755.     CALL    STAT        ; Key depressed?
  756.     JZ    DIAL18        ; If not, exit
  757.     CALL    KEYIN        ; See what it was
  758.     CPI    CANCEL        ; CTL-X to abort?
  759.     JZ    DIAL17        ; If yes, exit
  760.     MOV    B,A        ; Save the character momentarily
  761.     LDA    EXTCHR        ; Want to abort?
  762.     CMP    B
  763.     JNZ    DIAL18
  764. ;
  765. DIAL17:    MVI    B,CR        ; Terminate the dialing if needed
  766.     CALL    J$SNDCHR
  767.     JMP    DIALEXIT    ; Back to command mode
  768. ;
  769. DIAL18:    INX    H        ; Bump pointer
  770.     DCR    E        ; One less character to go
  771.     JNZ    DIAL16        ; If not done, send the next digit
  772.     MVI    B,CR        ; Modem needs a CR to enter the number
  773.     CALL    J$SNDCHR
  774.     CALL    CATCH        ; Catch the numbers the modem echoes
  775.     CALL    J$ILPRT
  776.     DB    ' - try #',0
  777.     LHLD    DIALCT        ; Increment the dial count
  778.     INX    H
  779.     SHLD    DIALCT
  780.     CALL    DECOUT        ; Show number of attempts so far
  781.     MVI    A,' '        ; Extra space to position cursor
  782.     CALL    TYPE
  783.     CALL    CATCH        ; Catch any output from the modem
  784.     JMP    SMRESULT    ; Number sent to modem, now get results
  785. ;
  786. ;
  787. ; Connection not made, see if a redial is desired
  788. ;
  789. DIALAGN:
  790.     LXI    SP,STACK    ; Reset the stack to normal just in case
  791.     XRA    A
  792.     STA    RINGFL        ; Reset the ring flag
  793.     LDA    CRFLAG        ; Continuous redial flag
  794.     ORA    A
  795.     JNZ    DIALAGN1    ; If already set, go dial again
  796.     CALL    J$ILPRT        ; See if we should keep trying
  797.     DB    CR,LF,CR,LF
  798.     DB    '     Redial? (C/Y/N): ',BELL,0
  799.     CALL    KBDCHR
  800.     PUSH    PSW        ; Save the answer
  801.     CALL    CRLF        ; Turn up a line
  802.     POP    PSW        ; Get the answer back
  803.     CPI    'Y'        ; Redial?
  804.     JZ    DIALAGN1    ; Yes, redial
  805.     CPI    'C'        ; Continuous redial?
  806.     JNZ    DIALEXIT1    ; None of these, quit
  807.     MVI    A,1
  808.     STA    CRFLAG        ; Continuous redial flag
  809. ;
  810. DIALAGN1:
  811.     CALL    CRLF        ; Start a new line
  812.     JMP    DIAL5        ; Redial entry point
  813. ;.....
  814. ;
  815. ;
  816. ; Connection has been made
  817. ;
  818. CONMADE:
  819.     CALL    J$ILPRT
  820.     DB    BELL,CR,LF,CR,LF,'     CONNECTED',0
  821.     LDA    AUTODIR        ; Going direct to terminal mode?
  822.     ORA    A
  823.     JNZ    RETRN
  824.     LDA    CRFLAG        ; Continuous redial or first time try?
  825.     ORA    A
  826.     JZ    RETRN        ; Go to terminal mode if first time
  827.     CALL    J$ILPRT
  828.     DB    ' - any key for terminal mode ',0
  829. ;
  830. CONMADE1:
  831.     MVI    E,10
  832. ;
  833. CONMADE2:
  834.     CALL    STAT        ; Keypress?
  835.     JZ    CONMADE3    ; Exit if no keys pressed
  836.     CALL    KEYIN
  837.     XRA    A
  838.     JMP    RETRN        ; Key pressed, go to terminal mode
  839. ;
  840. CONMADE3:
  841.     MVI    B,1        ; Wait 0.1 second
  842.     CALL    J$TIMER
  843.     DCR    E        ; One less loop to make
  844.     JNZ    CONMADE2    ; See if a keyboard character yet
  845.     MVI    A,BELL        ; Sound a bell
  846.     CALL    TYPE
  847.     JMP    CONMADE1    ; Reset the counter
  848. ;.....
  849. ;
  850. ;
  851. ; Automatic dialing routine, prints the number being dialed.
  852. ;
  853. DIALA:    CALL    TYPE        ; Print whatever character, dashes, etc.
  854.     MOV    B,A        ; Store the character for now
  855.     CALL    DIALAD        ; Check for alternate dialing like 'MCI'
  856.     MOV    A,B        ; Get the original character back
  857. ;
  858. DIALA1:    CPI    '*'        ; * is a valid dial digit
  859.     JZ    DIALA2
  860.     CPI    '#'        ; # is a valid dial digit
  861.     JZ    DIALA2
  862.     CPI    ','        ; Pause for all modems
  863.     JZ    DIALA2
  864.     CPI    'K'        ; K = Racal-Vadic dial tone wait
  865.     JZ    DIALA2
  866.     CPI    'T'        ; T = Tone dial request
  867.     JZ    DIALA2
  868.     CPI    'W'        ; W = Hayes or Robotics dial tone wait
  869.     JZ    DIALA2
  870.     CPI    '0'        ; Digits are (0-9)
  871.     RC            ; Exit if less than ASCII '0'
  872.     CPI    '9'+1
  873.     RNC            ; Exit if more than ASCII '9'
  874. ;
  875. ;
  876. ; Sends the digit to the modem.  Waits 100 ms. after each digit to in-
  877. ; sure it gets to the modem ok.
  878. ;
  879. DIALA2:    CALL    J$SNDCHR    ; Go send it
  880.     JMP    J$INMDM        ; Get the echo character and ignore
  881. ;.....
  882. ;
  883. ;
  884. ; Print bad library number message and abort if a null is encountered.
  885. ;
  886. DIALBAD:
  887.     CALL    J$ILPRT
  888.     DB    CR,LF,CR,LF,'++ Bad library number called ++',CR,LF,0
  889. ;
  890. DIALEXIT:
  891.     CALL    CRLF
  892. ;
  893. DIALEXIT1:
  894.     LXI    SP,STACK    ; Make sure the stack is normal again
  895.     CALL    SMIN4        ; Reset the modem
  896.     XRA    A
  897.     STA    CRFLAG        ; Reset the continuous redial flag
  898.     JMP    MENU
  899. ;.....
  900. ;
  901. ;
  902. ; Do any alternate dialing such as 'MCI' or 'SPRINT'
  903. ;
  904. DIALAD:    LDA    TCHPUL        ; Using touch tone dialing?
  905.     CPI    'T'
  906.     RNZ            ; If not, ignore
  907.     MOV    A,B        ; Get the character back
  908.     CPI    '<'        ; Alternate dialing system #1 (MCI?)
  909.     JNZ    DIALAD1        ; If not, exit
  910.     PUSH    H        ; Save the current values
  911.     LXI    H,ALTDL1    ; Alternate dialing area
  912.     JMP    DIALAD2
  913. ;
  914. DIALAD1:CPI    '>'        ; Alternate dialing system #2 (Sprint?)
  915.     RNZ            ; If neither, exit
  916.     PUSH    H        ; Save the current values
  917.     LXI    H,ALTDL2
  918. ;
  919. DIALAD2:MOV    A,M
  920.     CPI    '$'        ; Ready to terminate?
  921.     JZ    DIALAD3        ; If yes, exit
  922.     CALL    TYPE        ; Display the character
  923.     MOV    B,A        ; Need the char. in 'B' to send to modem
  924.     CALL    DIALA1        ; Send proper characters to the modem
  925.     INX    H        ; Next location
  926.     CALL    QUIT        ; Want to quit dialing?
  927.     JMP    DIALAD2        ; If not, handle the next character
  928. ;
  929. DIALAD3:MVI    A,' '
  930.     MOV    B,A        ; Clears 'B' from last digit sent
  931.     CALL    TYPE        ; Separate from the main number
  932.     POP    H        ; Restore the location
  933.     RET
  934. ;.....
  935. ;
  936. ;
  937. ; Disconnect the autodial modem from the phone line.  Sends 'I, CR' to
  938. ; the Racal-Vadic to return to IDLE mode
  939. ;
  940. ;
  941. DSCONT:    LDA    RACAL
  942.     ORA    A
  943.     JNZ    SMIN3        ; Reset modem to normal
  944. ;
  945.     MVI    B,15        ; 1 second pause
  946.     CALL    J$TIMER
  947.     LXI    H,STRNG5    ; Get into command mode
  948.     CALL    J$SNDSTR
  949.     MVI    B,15        ; Another 1 second pause
  950.     CALL    J$TIMER
  951.     JMP    SMIN3        ; Reset modem to normal
  952. ;.....
  953. ;
  954. ;
  955. ; Want to quit dialing?
  956. ;
  957. QUIT:    CALL    STAT        ; Keypress?
  958.     RZ            ; If not, do the next character
  959.     CALL    KEYIN        ; Yes, go get it
  960.     CPI    CANCEL        ; CTL-X?
  961.     JZ    QUIT1        ; Yes, quit dialing
  962.     MOV    B,A
  963.     LDA    EXTCHR
  964.     CMP    B
  965.     MOV    A,B        ; Get the character back again
  966.     JZ    QUIT1
  967.     CPI    NEXTRY        ; Special "dial next number" character
  968.     RNZ            ; None of these, proceed normally
  969.     MVI    B,CR
  970.     CALL    J$SNDCHR    ; Send to modem to stop dialing
  971.     MVI    B,10        ; Wait one second for new dial tone
  972.     CALL    J$TIMER        ; Let it abort any busy, dialing, etc.
  973.     POP    H
  974.     JMP    DIALAGN
  975. ;
  976. QUIT1:    POP    H        ; Reset stack for "CALL QUIT"
  977.     JMP    DIALEXIT    ; Terminate
  978. ;.....
  979. ;
  980. ;
  981. ; Insure the modem has completed its reply
  982. ;
  983. CATCH:    CALL    J$INMDM        ; Catch any output from the modem
  984.     JNC    CATCH        ; If you got one, see if any more
  985.     RET            ; Returns if no character in 100 ms.
  986. ;.....
  987. ;
  988. ;
  989. ; Clear the result buffer for slower 300 speed combined results
  990. ;
  991. EMPTY:    MVI    B,80
  992.     LXI    H,TBUF        ; TBUF area is not currently used
  993. ;
  994. EMPTY1:    MVI    M,' '
  995.     INX    H
  996.     DCR    B
  997.     JNZ    EMPTY1
  998.     RET
  999. ;.....
  1000. ;
  1001. ;
  1002. ; Initializaton
  1003. ;
  1004. SMIN1:    LDA    MANUAL        ; Manually selected 'SET' speed?
  1005.     ORA    A
  1006.     JNZ    SMIN11        ; Exit if set for manual selection
  1007. ;
  1008.     LDA    HS2400        ; High speed 2400 bps?
  1009.     ORA    A
  1010.     CNZ    J$2400        ; If yes, set to 2400 bps
  1011. ;
  1012.     LDA    HS1200        ; High speed 1200 bps?
  1013.     ORA    A
  1014.     CNZ    J$1200        ; If yes, set to 1200 speed
  1015. ;
  1016. SMIN11:    CALL    RATE        ; Show current baudrate
  1017.     CALL    CRLF        ; Turn up an extra line
  1018. ;
  1019. SMIN12:    LXI    H,RTRNG1    ; Set to auto-answer
  1020.     LDA    RACAL        ; Using the Racal-Vadic protocol?
  1021.     ORA    A
  1022.     JNZ    J$SNDSTR    ; If yes, use RTRNG1
  1023. ;
  1024.     LHLD    J$STRNG1+1
  1025.     LDA    HS2400        ; High speed 2400 bps?
  1026.     ORA    A
  1027.     JNZ    J$SNDSTR    ; If yes, modify basic "AT" string
  1028. ;
  1029.     LHLD    J$STRNGA+1    ; Else must be "AT" protocol
  1030.     CALL    J$SNDSTR    ; Send basic "AT" string
  1031. ;
  1032.     LDA    PROMODM        ; Using a 1200 bps Prometheus ProModem?
  1033.     ORA    A
  1034.     RZ            ; If not, finished
  1035.     LXI    H,STRNGP    ; If yes, send special ProModem string
  1036.     JMP    J$SNDSTR
  1037. ;.....
  1038. ;
  1039. ;
  1040. SMIN2:    LXI    H,RTRNG2    ; Set to disable auto-answer
  1041.     LDA    RACAL
  1042.     ORA    A
  1043.     JNZ    J$SNDSTR
  1044. ;
  1045.     LDA    TCHPUL        ; Touch or pulse dialing for autodial?
  1046.     STA    STRNG2+3    ; Store
  1047.     LXI    H,STRNG2
  1048.     JMP    J$SNDSTR
  1049. ;.....
  1050. ;
  1051. ;
  1052. SMIN3:    LXI    H,RTRNG3
  1053.     LDA    RACAL
  1054.     ORA    A
  1055.     JNZ    J$SNDSTR
  1056. ;
  1057.     LXI    H,STRNG3
  1058.     CALL    J$SNDSTR
  1059. ;
  1060. SMIN4:    LXI    H,RTRNG3
  1061.     LDA    RACAL
  1062.     ORA    A
  1063.     JNZ    J$SNDSTR
  1064. ;
  1065.     MVI    B,10        ; Wait 1 second to go on hook
  1066.     CALL    J$TIMER
  1067.     LXI    H,STRNG4    ; Set to auto-answer OFF
  1068.     JMP    J$SNDSTR
  1069. ;.....
  1070. ;
  1071. ;
  1072. ; Racal-Vadic mode
  1073. ;
  1074. RTRNG1:    DB    'E'-40H,CR,'##','I',CR,'##','E'-40H,CR,'##'
  1075.     DB    'O23121111212',CR,'####','$'
  1076. RTRNG2:    DB    'D','#','$'
  1077. RTRNG3:    DB    '#','I',CR,'#','E'-40H,CR,'#'
  1078.     DB    'O23121111212',CR,'####','I',CR,'$'
  1079. ;...
  1080. ;
  1081. ;
  1082. ; 1200 "AT" mode, start out with this string for both 1200 and 2400 bps
  1083. ;
  1084. STRNGA:    DB    'ATE1Q0V0X1H0'
  1085.     DB    CR,'####','$'    ; Delay to let modem accept commands
  1086. ;
  1087. ;
  1088. ; Special mode for Prometheus
  1089. ;
  1090. STRNGP:    DB    'ATV2',CR,'###','$'
  1091. ;
  1092. ;
  1093. ; 2400 "AT" mode
  1094. ;
  1095. STRNG1:    DB    'ATM3'        ; Loud speaker on after dialing
  1096.     DB    'L1',CR,'####'    ; Hayes 2400 speaker volume
  1097.     DB    'ATE1Q0V0X4H0'    ; Extended result codes (0-10)
  1098.     DB    CR,'####','$'    ; Delay to let modem accept commands
  1099. STRNG2:    DB    'ATDT','#','$'    ; Dial via Tone mode
  1100. STRNG3:    DB    'ATH0',CR,'#','$'
  1101. STRNG4:    DB    'ATS0=0',CR,'#','$'
  1102. STRNG5:    DB    '+++','$'
  1103. ;.....
  1104. ;
  1105. ;
  1106. ; Send the string pointed to by 'HL' to both the CRT and the modem.
  1107. ;
  1108. SNDSTR:    CALL    QUIT        ; Want to quit now?
  1109.     MOV    A,M
  1110.     CPI    '$'
  1111.     RZ
  1112. ;
  1113.     CPI    '#'        ; Special character to catch chars.?
  1114.     JNZ    SEND1        ; If not, exit
  1115.     CALL    CATCH        ; Else catch any/all characters
  1116.     JMP    SEND2        ; Get next char. in string and continue
  1117. ;
  1118. SEND1:    MOV    B,A        ; SNDCHR needs character in 'B' reg.
  1119.     CALL    J$SNDCHR
  1120. ;
  1121. SEND2:    INX    H        ; Next character in the string
  1122.     JMP    SNDSTR
  1123. ;.....
  1124. ;
  1125. ;
  1126. ; Checks for answer from the Racal-Vadic and stores it in the buffer.
  1127. ; Has a 30-second timer included, in case the Racal times out without
  1128. ; sending a "failed call", our timer will.
  1129. ;
  1130. SMRESULT:
  1131.     CALL    EMPTY        ; Clear the buffer
  1132.     LXI    H,TBUF        ; Put the modem result answer here
  1133.     PUSH    H        ; Save it
  1134. ;
  1135. SMRESUL1:
  1136.     LXI    D,330        ; Time out 33 seconds after dialing
  1137. ;
  1138. SMRESUL2:
  1139.     CALL    RCVRDY        ; See if a character is ready
  1140.     JZ    SMRESUL4    ; If yes, go get it
  1141.     CALL    QUIT        ; Want to quit dialing?
  1142.     CALL    J$INMDM        ; Wait up to 0.1 second for an answer
  1143.     JNC    SMRESUL5    ; If a character, fine, skip delay count
  1144.     DCX    D        ; One less loop
  1145.     MOV    A,D        ; See if both are zero, yet
  1146.     ORA    E
  1147.     JNZ    SMRESUL2    ; Make next loop
  1148.     POP    H        ; Restore the stack to normal
  1149.     CALL    SMIN12        ; Reinitialize the modem
  1150.     JMP    FAILED        ; Timed out
  1151. ;
  1152. SMRESUL4:
  1153.     CALL    J$INMDM        ; Wait for the character and get it
  1154.     JC    SMRESUL6    ; If done now, exit
  1155. ;
  1156. SMRESUL5:
  1157.     ANI    7FH        ; Remove any parity
  1158.     CPI    '*'+1        ; Catches spaces, nulls, CR, LF, Bell..
  1159.     JC    SMRESUL4    ; Asterisk and lesser characters
  1160.     POP    H        ; Get the address in the buffer
  1161.     MOV    M,A        ; Store the character there
  1162.     INX    H        ; Get the next address
  1163.     PUSH    H        ; Save it for now
  1164.     JMP    SMRESUL4    ; Get the next character, if any
  1165. ;
  1166. ;
  1167. ; Find what comment the Racal sent
  1168. ;
  1169. SMRESUL6:
  1170.     POP    H        ; Reset the stack
  1171.     LXI    D,TBUF
  1172. ;
  1173.     LDA    RACAL        ; Using the Racal-Vadic protocol?
  1174.     ORA    A
  1175.     JNZ    SMRESUL7    ; If yes, jump to other section
  1176. ;
  1177. ;
  1178. ; Handle the Hayes 0-5 result codes
  1179. ;
  1180.     CALL    INLNCP
  1181.     DB    '1',0        ; Connect 300 baud
  1182.     JNC    ON$3X        ; See if '1' for 300 or '10' for 2400
  1183.     CALL    INLNCP
  1184.     DB    '3',0        ; No Carrier
  1185.     JNC    NO$CAR
  1186.     CALL    INLNCP
  1187.     DB    '5',0        ; Connect 1200 bps
  1188.     JNC    ON$1200
  1189. ;
  1190. ;
  1191. ; See if using a Prometheus 1200 ProModem
  1192. ;
  1193.     LDA    PROMODM        ; Using a Prometheus ProModem?
  1194.     ORA    A
  1195.     JNZ    PROMDM        ; If yes, exit
  1196. ;
  1197. ;
  1198. ; See if running 1200 bps
  1199. ;
  1200.     LDA    HS1200        ; High speed 1200 bps?
  1201.     ORA    A
  1202.     JNZ    FAILED        ; If yes, no other result codes coming
  1203. ;
  1204. ;
  1205. ; Keep going if running 2400 bps with AT protocol
  1206. ;
  1207.     CALL    INLNCP
  1208.     DB    '6',0        ; No dial tone
  1209.     JNC    NO$DT
  1210.     CALL    INLNCP
  1211.     DB    '7',0        ; Busy
  1212.     JNC    BUSY
  1213.     CALL    INLNCP
  1214.     DB    '8',0        ; No answer
  1215.     JNC    FAILED
  1216.     CALL    INLNCP
  1217.     DB    '10',0        ; Connect 2400 bps
  1218.     JNC    ON$2400
  1219.     JMP    FAILED        ; If anything else, an error
  1220. ;...
  1221. ;
  1222. ;
  1223. PROMDM:    CALL    INLNCP
  1224.     DB    '43',0
  1225.     JNC    NO$DT        ; No dial tone
  1226.     CALL    INLNCP
  1227.     DB    '60',0
  1228.     JNC    DIALING        ; Dialing...
  1229.     CALL    INLNCP
  1230.     DB    '61',0
  1231.     JNC    RINGING        ; Ringing...
  1232.     JMP    FAILED        ; Anything else, call failed
  1233. ;...
  1234. ;
  1235. ;
  1236. ; Handle the Racal results
  1237. ;
  1238. SMRESUL7:
  1239.     CALL    INLNCP
  1240.     DB    'B',0        ; Busy
  1241.     JNC    BUSY
  1242.     CALL    INLNCP
  1243.     DB    'H',0        ; HELLO:I'M READY
  1244.     JNC    SMIN2
  1245.     CALL    INLNCP
  1246.     DB    'D',0        ; Dialing...
  1247.     JNC    DIALING
  1248.     CALL    INLNCP
  1249.     DB    'R',0        ; Ringing...
  1250.     JNC    RINGING
  1251.     CALL    INLNCP
  1252.     DB    'A',0        ; Answer tone
  1253.     JNC    ANSWER
  1254.     CALL    INLNCP
  1255.     DB    '1',0        ; On line
  1256.     JNC    ON$300
  1257.     CALL    INLNCP
  1258.     DB    '2',0        ; On line
  1259.     JNC    ON$1200
  1260.     CALL    INLNCP
  1261.     DB    '3',0        ; On line
  1262.     JNC    ON$2400
  1263.     CALL    INLNCP
  1264.     DB    'L',0        ; On line
  1265.     JNC    ON$LINE
  1266.     CALL    INLNCP
  1267.     DB    'F',0        ; Failed call - no answer, abort
  1268.     JNC    FAILED
  1269.     CALL    INLNCP
  1270.     DB    'T',0        ; Timed out
  1271.     JNC    FAILED
  1272.     CALL    INLNCP
  1273.     DB    'E',0        ; No dial tone
  1274.     JNC    NO$DT
  1275.     JMP    FAILED        ; Anything else, call failed
  1276. ;.....
  1277. ;
  1278. ;
  1279. ANSWER:    CALL    J$ILPRT
  1280.     DB    'answer, ',0
  1281.     INR    A
  1282.     STA    ANSWFL        ; Show it did answer at least
  1283. ;
  1284. ;
  1285. ; At 300 bps, the modems come back almost simultaneously with ANSWER and
  1286. ; ONLINE, so we check the buffer to see if both answers are stored now.
  1287. ;
  1288.     LDA    TBUF+1        ; For 300 baud and terse mode
  1289.     CPI    'L'
  1290.     JZ    ON$LINE
  1291.     CPI    '1'
  1292.     JZ    ON$300
  1293.     CPI    '2'
  1294.     JZ    ON$1200
  1295.     CPI    '3'
  1296.     JZ    ON$2400
  1297.     LDA    TBUF+12        ; For 300 bps and verbose mode
  1298.     CPI    'L'
  1299.     JZ    ON$LINE
  1300.     JMP    SMRESULT
  1301. ;.....
  1302. ;
  1303. ;
  1304. BUSY:    CALL    J$ILPRT
  1305.     DB    'busy! ',0
  1306.     LDA    DIALWT
  1307.     MOV    B,A
  1308.     CALL    J$TIMER        ; Slight pause to let phone hang up
  1309.     JMP    DIALAGN
  1310. ;.....
  1311. ;
  1312. ;
  1313. DIALING:CALL    J$ILPRT
  1314.     DB    'dial, ',0
  1315.     JMP    SMRESULT
  1316. ;.....
  1317. ;
  1318. ;
  1319. ; Failed call is usually caused by continuous ringing with no answer.
  1320. ; The modem times out (can be set to either 30 seconds or 60 seconds.)
  1321. ;
  1322. FAILED:    CALL    J$ILPRT
  1323.     DB    'abort ',0
  1324.     LDA    DIALWT
  1325.     MOV    B,A
  1326.     CALL    J$TIMER        ; Slight pause to let phone hang up
  1327.     JMP    DIALAGN
  1328. ;.....
  1329. ;
  1330. ;
  1331. NO$CAR:    LDA    PROMODM        ; Using a 1200 bps Prometheus ProModem?
  1332.     ORA    A
  1333.     JZ    FAILED        ; If not, handle as a failed call
  1334.     LDA    RINGFL        ; Have we recorded any rings yet?
  1335.     ORA    A
  1336.     JZ    BUSY        ; If not, handle as a Busy signal
  1337.     JMP    FAILED        ; If yes, handle as a failed call
  1338. ;
  1339. ON$LINE:CALL    J$ILPRT
  1340.     DB    'on line',0
  1341.     JMP    CONMADE
  1342. ;.....
  1343. ;
  1344. ;
  1345. ON$300:    CALL    J$ILPRT
  1346.     DB    'on 300',0
  1347.     CALL    J$300
  1348.     JMP    CONMADE
  1349. ;.....
  1350. ;
  1351. ;
  1352. ON$1200:CALL    J$ILPRT
  1353.     DB    'on 1200',0
  1354.     CALL    J$1200
  1355.     JMP    CONMADE
  1356. ;.....
  1357. ;
  1358. ;
  1359. ON$2400:CALL    J$ILPRT
  1360.     DB    'on 2400',0
  1361.     CALL    J$2400
  1362.     JMP    CONMADE
  1363. ;.....
  1364. ;
  1365. ;
  1366. ON$3X:    LDA    TBUF+1        ; If 2nd char is 0 for 10, then 2400
  1367.     CPI    '0'
  1368.     JZ    ON$2400
  1369.     JMP    ON$300
  1370. ;.....
  1371. ;
  1372. ;
  1373. ; No dial tone can occur when using the alternate dialing option and a
  1374. ; dial tone is not detected after the pause 'K' or within 5 sec after
  1375. ; the start of the modem dialing routine
  1376. ;
  1377. NO$DT:    CALL    J$ILPRT
  1378.     DB    '- no dial tone',0
  1379.     JMP    DIALAGN
  1380. ;.....
  1381. ;
  1382. ;
  1383. RINGING:CALL    J$ILPRT
  1384.     DB    'ring, ',0
  1385.     MVI    A,1        ; Insure 'A' is not zero
  1386.     STA    RINGFL
  1387.     JMP    SMRESULT
  1388. ;.....
  1389. ;
  1390. ;
  1391. ; This is the auto-linking area.  Up to 32 numbers may be linked, each
  1392. ; should have a comma for a separator, such as:
  1393. ;
  1394. ;    B>>COMMAND: CAL A,F,3,A,G,A,H
  1395. ;
  1396. AUTO:    STA    AUTODIR        ; Direct to terminal mode on answer
  1397. ;
  1398. AUTO1:    MVI    A,0FFH        ; Set the flags to -1
  1399.     STA    AUTOFL        ; Set the auto-linking flag
  1400.     STA    CRFLAG        ; Set the continuous redial flag
  1401.     MVI    B,64        ; Maximum number of characters to move
  1402.     LXI    H,CMDBUF+1    ; Start with number in the string
  1403.     LXI    D,CMDBUF+65    ; Move to aft part of buffer
  1404.     JMP    MOVE        ; When finished return to caller
  1405. ;.....
  1406. ;
  1407. ;
  1408. ; Linking routine
  1409. ;
  1410. AUTO2:    LDA    AUTOFL        ; Increment the flag for each new try
  1411.     INR    A
  1412.     INR    A
  1413.     STA    AUTOFL
  1414.     MOV    C,A        ; Hold momentarily
  1415.     MVI    B,0
  1416.     LDA    CMDBUF+65    ; See how many characters typed
  1417.     CMP    C
  1418.     JNC    AUTO3
  1419.     MVI    A,1        ; Reset the flag to start over
  1420.     MOV    C,A
  1421.     STA    AUTOFL
  1422. ;
  1423. AUTO3:    LXI    H,CMDBUF+65
  1424.     DAD    B
  1425.     JMP    DIAL6        ; Go to work
  1426. ;.....
  1427. ;
  1428. ;
  1429. ANSWFL:    DB    0        ; Answer flag abort, no on line report
  1430. AUTODIR:DB    0        ; Direct to terminal mode on answer
  1431. AUTOFL:    DB    0        ; Auto-linking flag
  1432. NUMBER:    DB    0        ; Number of characters in CMDBUF
  1433. RINGFL:    DB    0        ; Only prints one 'ringing' msg
  1434. ;.....
  1435. ;
  1436. ;
  1437.     DS    50        ; Insures some spares will be available
  1438. ;
  1439. ;           (end of Racal-Vadic/Hayes dialing routine)
  1440. ;=======================================================================
  1441. ;
  1442.     ORG    (($+255+50)/256*256)-50    ; Even page for 'NUMLIB'
  1443. ;
  1444. ; Long distance alternate dialing such as MCI, SPRINT, etc.  Must end
  1445. ; with a '$', use as many commas (2 seconds delay, each) as needed to
  1446. ; let the alternate dialing code return with a new dial tone.  Fill in
  1447. ; any character (periods are fine) after the $ to keep number of columns
  1448. ; to 24, i.e.,    '1234567,,,,12345,,$.....'   --   the first group is the
  1449. ; MCI or SPRINT access number, the second group is the user number.  A
  1450. ; small delay is usually required after the billing number also.
  1451. ;
  1452. ALTDL1:    DB    'xxxxxxx,,,,,,xxxxxxxx,,$' ; Accessed by a < character
  1453. ALTDL2:    DB    'xxxxxxx,,,,,,xxxxxxxx,,$' ; Accessed by a > character
  1454. ;
  1455. ;=======================================================================
  1456. ;
  1457. DIALWT:    DB    5        ; tenth-seconds to wait for dial tone
  1458. SAVSIZ:    DB    XFRSIZ*8    ; Can easily change buffer size for file
  1459.                 ;   transfers with DDT for "NUMBLIB-1"
  1460.                 ;   address.  Normally 4k (32 records
  1461.                 ;   or 4k).
  1462. ;
  1463. ;=======================================================================
  1464. ;
  1465. ; Phone number library table for auto-dialing.    Each number must be as
  1466. ; long as"LIBLEN" (EQU at start of program).  Some areas require extra
  1467. ; characters such as:    1-313-846-7127.  Room is left for those.  Use
  1468. ; a (<) for alternate dialing system #1, and a (>) for alternate dialing
  1469. ; System #2.  Either would preceed the actual number, for example:
  1470. ;
  1471. ;    DB    'A=Alan Alda..........<123-456-7890'    ;'A'
  1472. ;
  1473. ; -    -     -     -      -    -     -     -      -    -     -     -
  1474. ;
  1475. ; NOTE: At least one dot (.) MUST precede the actual phone number
  1476. ;
  1477. ;        '----5---10---15---20---25---30--34'
  1478. NUMBLIB:DB    'A=Norman Beeler.....1-408-245-1420' ; 'A'
  1479.     DB    'B=Rich Berg.........1-618-359-4446' ; 'B'
  1480.     DB    'C=Robert Blacher....1-202-254-2008' ; 'C'
  1481.     DB    'D=Brian Callahan....1-718-625-5931' ; 'D'
  1482.     DB    'E=Bob Clyne.........1-313-759-6569' ; 'E'
  1483.     DB    'F=Bill Earnest......1-215-398-3937' ; 'F'
  1484.     DB    'G=Norm Gregory......1-206-325-1325' ; 'G'
  1485.     DB    'H=Irv Hoff................948-2166' ; 'H'
  1486.     DB    'I=Jeff King.........1-408-247-2853' ; 'I'
  1487.     DB    'J=Kim Levitt........1-213-653-6398' ; 'J'
  1488.     DB    'K=Tim Linehan.......1-206-357-7400' ; 'K'
  1489.     DB    'L=Jim Lopushinski...1-403-484-5981' ; 'L'
  1490.     DB    'M=Trevor Marshall...1-805-492-5472' ; 'M'
  1491.     DB    'N=Wayne Masters.....1-408-378-7474' ; 'N'
  1492.     DB    'O=Paul Matlin.......1-301-661-2175' ; 'O'
  1493.     DB    'P=Dave McCord ZCPR3.1-415-489-9005' ; 'P'
  1494.     DB    'Q=Byron McKay.......1-415-965-4097' ; 'Q'
  1495.     DB    'R=Dick Mead.........1-818-799-1632' ; 'R'
  1496.     DB    'S=Chuck Metz........1-408-354-5934' ; 'S'
  1497.     DB    'T=Al Mehr...........1-408-238-9621' ; 'T'
  1498.     DB    'U=Jud Newell........1-416-232-0442' ; 'U'
  1499.     DB    'V=George Peace......1-717-657-8699' ; 'V'
  1500.     DB    'W=John Riehl........1-713-488-5619' ; 'W'
  1501.     DB    'X=Gary Shaffstall...1-303-985-1108' ; 'X'
  1502.     DB    'Y=Murray Simsolo....1-516-825-8465' ; 'Y'
  1503.     DB    'Z=Larry Snyder......1-305-677-8086' ; 'Z'
  1504.     DB    '0=John Sojak........1-312-941-0049' ; '0'
  1505.     DB    '1=Alex Soya.........1-305-727-0331' ; '1'
  1506.     DB    '2=Ken Stritzel......1-312-983-5147' ; '2'
  1507.     DB    '3=Henry Trujilio....1-207-443-4657' ; '3'
  1508.     DB    '4=Bill Wood.........1-619-256-3914' ; '4'
  1509.     DB    '5=Tom Vande-Stouwe..1-516-567-8267' ; '5'
  1510.     DB    '6=Spare.............1-xxx-xxx-xxxx' ; '6'
  1511.     DB    '7=Spare.............1-xxx-xxx-xxxx' ; '7'
  1512.     DB    '8=Spare.............1-xxx-xxx-xxxx' ; '8'
  1513.     DB    '9=Spare.............1-xxx-xxx-xxxx' ; '9'
  1514.     DB    0        ; End
  1515. ;        '----5---10---15---20---25---30--34'
  1516. ;
  1517. ;-----------------------------------------------------------------------
  1518. ;
  1519. ; This is the storage area for the ten function keys.  The I2FUNC.COM
  1520. ; program dynamically allocates the storage for the keys.  Thus, no
  1521. ; function key is limited to so-and-so many characters.  Rather, the
  1522. ; total number of bytes in the function key library (including flags)
  1523. ; is 256.
  1524. ;
  1525. INTCPT:    DB    ESC        ; Intercept character (prefix)
  1526. ;
  1527. FNCTBL:    DB    0,'DIR ',CR,0
  1528.     DB    1,'DIR *.* $U0AD ',CR,0
  1529.     DB    2,'KMD R ',0
  1530.     DB    3,'KMD S ',0
  1531.     DB    4,'XMODEM R ',0
  1532.     DB    5,'XMODEM S ',0
  1533.     DB    6,'BYE ',CR,0
  1534.     DB    7,'RBBS ',CR,0
  1535.     DB    8,'(vacant)',0
  1536.     DB    9,'Nice chatting, see you again soon... ',CR,0
  1537. ;
  1538.     DS    256-($-FNCTBL)
  1539. ;
  1540. ;
  1541. ;
  1542. ;***********************************************************************
  1543. ;
  1544. ;
  1545. ; P - R - O - G - R - A - M    S - T - A - R - T - S      H - E - R - E
  1546. ;
  1547. ;
  1548. ;***********************************************************************
  1549. ;
  1550. ;
  1551. START:    LXI    H,0
  1552.     DAD    SP        ; Add the current stack pointer to 'HL'
  1553.     SHLD    STACK
  1554.     LXI    SP,STACK    ; Start local stack
  1555. ;
  1556. ;
  1557. ; The 'FIXCNT' calculations are done here and the values stored so the
  1558. ; overhead of doing the calculation is not incurred in the RECV routine
  1559. ; where it is desired to pick up a character from the modem data port as
  1560. ; quickly as possible.
  1561. ;
  1562.     LXI    H,480        ; Adjust to get 1 second time intervals
  1563.     CALL    FIXCNT
  1564.     SHLD    TIMVAL
  1565.     LXI    H,48        ; Should be 1/10 of above value
  1566.     CALL    FIXCNT
  1567.     SHLD    QUIKTIM
  1568. ;
  1569. ;
  1570. ; Now display the program name and version number and we are under way
  1571. ;
  1572.     CALL    CRCGN        ; Generate tables for fast 'CRC' check
  1573.     CALL    INITADR        ; Initialize addresses
  1574.     CALL    INTERCEPT    ; Establish the function key intercept
  1575.     CALL    SETSPD        ; Bring up DTR, set modem speed
  1576.     CALL    PROCOPT        ; Process any options
  1577.     LDA    OPTION        ; Any options on the command line?
  1578.     CPI    ' '+1
  1579.     JNC    RSTRT
  1580.     CALL    ILPRT
  1581.     DB    CR,LF,'IMP v',VERSION/100+'0'
  1582.     DB    VERSION    MOD    100/10+'0'
  1583.     DB    VERSION    MOD 10+'0'
  1584.     DB    ' modem pgm (type M for Menu)'
  1585.     DB    CR,LF,'Copyright (c) 1985, 1987 Irvin M. Hoff'
  1586.     DB    CR,LF,0
  1587.     CALL    J$SYSVR        ; Give configuration message
  1588.     CALL    RATE
  1589.     JMP    MENU
  1590. ;
  1591. ;
  1592. ; Comes here from menu once the options have been set
  1593. ;
  1594. RSTRT:    LXI    SP,STACK    ; Make sure we have a clean stack
  1595.     CALL    CKCHAR        ; Catch any garbage characters left
  1596. ;
  1597. RSTRT1:    LDA    OPTION        ; Get the option
  1598.     CPI    'C'        ; Call (dial) function?
  1599.     JZ    J$DIAL        ; Yes, go to it
  1600. ;
  1601. RSTRT2:    CALL    MOVEFCB
  1602.     XRA    A
  1603.     STA    GOTONE        ; Indicated a batch file was transferred
  1604.     STA    KFLG        ; Reset the flag (might have been used)
  1605.     LDA    OPTION        ; Get main option
  1606.     CPI    'D'        ; Disconnect?
  1607.     JZ    DONETD        ; Yes, disconnect then back to the menu
  1608.     CPI    'M'        ; Menu asked for?
  1609.     JZ    MENU2        ; Go display the menu
  1610.     CPI    'R'        ; Want to receive a file?
  1611.     JZ    RCVFL        ; Exit if yes
  1612.     CPI    'S'        ; Want to send a file?
  1613.     JZ    SNDFL        ; Exit if yes
  1614.     CPI    'T'        ; Want terminal mode?
  1615.     JNZ    RSTRT3        ; If not, exit
  1616.     XRA    A
  1617.     STA    ECHOFLG        ; Reset echo flag
  1618.     STA    LOCFLG        ; Reset local flag
  1619.     JMP    DSKSV        ; Exit if yes
  1620. ;
  1621. RSTRT3:    CPI    'E'        ; Want echo mode?
  1622.     JNZ    NOECHO        ; If not, exit
  1623.     STA    ECHOFLG        ; Set the echo flag
  1624.     XRA    A
  1625.     STA    LOCFLG        ; Reset local flag
  1626.     JMP    DSKSV
  1627. ;
  1628. NOECHO:    CPI    'L'        ; Want local echo mode?
  1629.     JNZ    NOLOCAL        ; If not, exit
  1630.     STA    LOCFLG        ; Set the local flag
  1631.     XRA    A
  1632.     STA    ECHOFLG        ; Reset echo flag
  1633.     JMP    DSKSV
  1634. ;
  1635. NOLOCAL:CALL    NTVLDMSG    ; Say not a valid option
  1636.     JMP    MENU        ; Then go back to the command mode
  1637. ;.....
  1638. ;
  1639. ;
  1640. INITADR:LHLD    0000H+1        ; BIOS warm reboot jump vector
  1641.     LXI    D,3
  1642.     DAD    D
  1643.     SHLD    VSTAT+1        ; BIOS console status jump vector
  1644.     DAD    D
  1645.     SHLD    VKEYIN+1    ; BIOS console keyboard jump vector
  1646.     DAD    D
  1647.     SHLD    VTYPE+1        ; BIOS console CRT jump vector
  1648.     LXI    D,33
  1649.     DAD    D
  1650.     SHLD    GOLIST+1    ; BIOS list device status jump vector
  1651.     CALL    GETUSER        ; Get current user number
  1652.     STA    OLDUSER        ; Save to restore upon exit
  1653.     JMP    GTMAX        ; Find maximum ram for printer use, done
  1654. ;.....
  1655. ;
  1656. ;
  1657. ; Get the function key intercept character and put in appropriate places
  1658. ;
  1659. INTERCEPT:
  1660.     LDA    INTCPT        ; Get the function key intercept char.
  1661.     ANI    07FH        ; Strip off any parity
  1662.     STA    GTCMD1+1    ; Store in the menu area
  1663.     CPI    ' '        ; Printing character?
  1664.     JNC    INTER1        ; If yes, exit
  1665. ;
  1666.     CPI    ESC        ; Using the ESC key?
  1667.     JZ    INTER2        ; If yes, special case
  1668.     ADI    40H        ; Change to printing character
  1669.     STA    MENU3+1
  1670.     MVI    A,'^'
  1671.     STA    MENU3        ; Store the "control-" character
  1672.     RET
  1673. ;...
  1674. ;
  1675. ;
  1676. INTER1:    STA    MENU3+1
  1677.     RET
  1678. ;...
  1679. ;
  1680. ;
  1681. INTER2:    MVI    A,'E'        ; Just show 'ESC' then rather than ^[
  1682.     STA    MENU3
  1683.     MVI    A,'S'
  1684.     STA    MENU3+1
  1685.     MVI    A,'C'
  1686.     STA    MENU3+2
  1687.     RET
  1688. ;.....
  1689. ;
  1690. ;
  1691. ; Process any options - put 0 in appropriate place in option table if
  1692. ; option is selected
  1693. ;
  1694. PROCOPT:LXI    D,FCB+1        ; Look at first char. on command line
  1695.     LDAX    D        ; Get the character
  1696.     STA    OPTION        ; Store it for primary option
  1697.     CPI    ' '        ; Exit if no options
  1698.     RZ
  1699. ;
  1700. OPTLP:    INX    D        ; See if an additional option
  1701.     LDAX    D        ; Get the character
  1702.     CPI    ' '        ; Was it a space?
  1703.     JZ    ENDOPT        ; If yes, options are finished
  1704.     LXI    H,OPTBL        ; Start of option table
  1705.     MVI    B,OPTBE-OPTBL    ; Number of entries in option table
  1706. ;
  1707. OPTCK:    CMP    M        ; See if character matches one in table
  1708.     JNZ    OPTNO        ; If not, keep looking
  1709.     MVI    M,0        ; If yes, reset the flag to zero
  1710.     JMP    OPTLP        ; Check on additional options on line
  1711. ;
  1712. OPTNO:    INX    H        ; Next location in option table
  1713.     DCR    B        ; One less to go
  1714.     JNZ    OPTCK        ; If not zero, keep checking the table
  1715.     CALL    NTVLDMSG    ; If none of those was a wrong entry
  1716.     POP    H        ; Preserve stack
  1717.     JMP    MENU        ; Jump out to the menu
  1718. ;
  1719. ENDOPT:    LDA    VSEEFLG        ; See if visual flag is set
  1720.     ORA    A
  1721.     JNZ    CKOPT
  1722.     STA    QFLG        ; Quiet mode for watching data items
  1723. ;
  1724. ;
  1725. ; Checked for supplementary options, now check the primary option
  1726. ;
  1727. CKOPT:    LDA    OPTION        ; Check on the primary option
  1728.     CPI    'C'        ; Going to autodial now?
  1729.     RZ
  1730.     CPI    'D'        ; Going to disconnect?
  1731.     RZ
  1732.     CPI    'E'        ; Return if echo option
  1733.     RZ
  1734.     CPI    'M'        ; Return if help option
  1735.     RZ
  1736.     CPI    'L'        ; Return if local echo option
  1737.     RZ
  1738.     CPI    'T'        ; Return if terminal mode
  1739.     RZ
  1740. ;
  1741.     MOV    B,A        ; Save the character
  1742.     LDA    NFILFLG        ; Saving memory for disk file?
  1743.     ORA    A
  1744.     JZ    CKOPT2        ; If not, continue
  1745.     POP    H        ; Reset the stack from 'CALL PROCOPT'
  1746.     JMP    MENU0        ; Go show the 'FILE OPEN' message
  1747. ;
  1748. CKOPT2:    MOV    A,B        ; Get the option back
  1749.     CPI    'S'
  1750.     JZ    CKFILE
  1751.     CPI    'R'
  1752.     JNZ    BDOPT        ; None of these, bad option
  1753. ;
  1754.     LDA    BATCHFLG    ; See if the batch mode flag is set
  1755.     ORA    A
  1756.     RZ            ; If yes, exit
  1757. ;
  1758. CKFILE:    LDA    FCB+17        ; 'S' and 'R' need a file name
  1759.     CPI    ' '
  1760.     RNZ            ; Exit if a file name is present
  1761.     MOV    A,B        ; Call 'R' without filename batch
  1762.     CPI    'R'
  1763.     JNZ    CKFILE1
  1764.     XRA    A
  1765.     STA    BATCHFLG    ; Show now in batch mode
  1766.     RET
  1767. ;...
  1768. ;
  1769. ;
  1770. CKFILE1:CALL    ILPRT
  1771.     DB    '++ Enter primary option plus file name ++'
  1772.     DB    CR,LF,BELL,0
  1773.     POP    H        ; Reset stack from 'CALL STFCB'
  1774.     JMP    MENU        ; Abort to command line
  1775. ;.....
  1776. ;
  1777. ;
  1778. BDOPT:    CALL    ILPRT
  1779.     DB    CR,LF,'++ Bad option ++',CR,LF,LF,0
  1780. ;.....
  1781. ;
  1782. ;
  1783. ; Check for any garbage characters on line - catch and ignore
  1784. ;
  1785. CKCHAR:    CALL    RCVRDY        ; Any characters ready to receive?
  1786.     RNZ            ; If not, return
  1787.     CALL    I$MDDATP    ; Otherwise get the character and ignore
  1788.     JMP    CKCHAR        ; Check for any additional characters
  1789. ;.....
  1790. ;
  1791. ;
  1792. ; Revised terminal routine allowing memory save.  First checks for bad
  1793. ; options, to prevent wiping out the disk with accidental memory save.
  1794. ;
  1795. DSKSV:    LDA    BATCHFLG    ; Batch flag set?
  1796.     ORA    A
  1797.     JNZ    DSKSV1        ; If not set, everything is normal
  1798.     MVI    A,'B'        ; If set, shouldn't be, so reset it
  1799.     STA    BATCHFLG
  1800.     JMP    NOTVLD        ; If set, error for 'E', 'L' or 'T'
  1801. ;
  1802. DSKSV1:    STA    XFLG        ; Will use the ASCII capture buffer size
  1803.     LDA    NFILFLG        ; Already saving for a file?
  1804.     ORA    A
  1805.     JZ    DSKSV2        ; Exit if not, and open a file
  1806.     CALL    BUFMS        ; Tell if buffer if on or off
  1807.     JMP    TERM
  1808. ;
  1809. DSKSV2:    LDA    FCB+1        ; First character of filename (if any)
  1810.     CPI    ' '        ; File specified?
  1811.     JNZ    GOODNM        ; Yes, good name
  1812.     XRA    A
  1813.     STA    NFILFLG        ; Show no file being saved
  1814.     STA    SAVEFLG        ; Reset the flag to zero
  1815.     JMP    TERM
  1816. ;...
  1817. ;
  1818. ;
  1819. GOODNM:    CALL    ERASF
  1820.     LXI    H,FCB3
  1821.     CALL    INITFCB
  1822.     LXI    H,FCB        ; Move the disk name into FCB3 area
  1823.     LXI    D,FCB3
  1824.     MVI    B,12
  1825.     CALL    MOVE
  1826.     LXI    D,FCB3        ; Now make a file from that name
  1827.     MVI    C,MAKE
  1828.     CALL    BDOS
  1829.     LXI    D,FCB3        ; Now open the file from FCB3
  1830.     MVI    C,OPEN
  1831.     CALL    BDOS
  1832.     LXI    H,BUFFER    ; Reset pointers to start of buffer
  1833.     SHLD    HLSAV
  1834.     MVI    A,1
  1835.     STA    NFILFLG        ; Show now saving to memory for disk file
  1836.     STA    SAVEFLG        ; Active the file at the same time
  1837.     CALL    BUFMS        ; Show buffer is open
  1838. ;
  1839. TERM:    CALL    GOLIST
  1840.     CALL    STAT        ; Keyboard have a character?
  1841.     JZ    TERML        ; If not, see if any incoming
  1842. ;
  1843.     CALL    KEYIN        ; Get character from keyboard
  1844.     MOV    B,A        ; Save for now to protect 'A' reg.
  1845.     CPI    RUB        ; Test for rub
  1846.     JNZ    NOTRUB        ; Exit if not
  1847.     LDA    CONVRUB        ; Convert rub to backspace?
  1848.     ORA    A
  1849.     JZ    NOTRUB        ; Exit if no conversion
  1850.     MVI    B,BKSP        ; Call it a backspace
  1851.     JMP    NTOG        ; Go send a backspace
  1852. ;
  1853. NOTRUB:    LDA    FNKFLG        ; Get function key active flag
  1854.     ORA    A
  1855.     JZ    CKEXAC        ; If not set yet, exit
  1856. ;
  1857.     XRA    A        ; First zero the flag
  1858.     STA    FNKFLG
  1859.     MOV    A,B        ; Get character
  1860.     CPI    '0'
  1861.     JC    CKEXAC        ; If less, not a function key
  1862.     CPI    '9'+1
  1863.     JNC    CKEXAC        ; If more, not a function key
  1864.     XRA    A
  1865.     STA    EXACFLG        ; Just in case both use same character
  1866.     MOV    A,B        ; Get the character back
  1867.     ANI    0FH        ; Make 0..9
  1868.     JMP    SNDFK
  1869. ;
  1870. CKEXAC:    LDA    EXACFLG        ; External flag set yet?
  1871.     ORA    A
  1872.     JZ    NTEXAFLG    ; If not, proceed normally
  1873. ;
  1874.     XRA    A        ; Reset the flag
  1875.     STA    EXACFLG
  1876.     MOV    A,B        ; Get the character back
  1877.     ANI    5FH        ; Make sure it is upper case
  1878.     MOV    B,A        ; Save for comparison
  1879.     CALL    EXITTST1    ; Want to exit to menu?
  1880. ;
  1881.     LDA    CLEARS        ; ESC-Z to clear screen, terminal mode
  1882.     CMP    B
  1883.     JZ    CLRCRT
  1884.     LDA    FILESND        ; Output text file to remote?
  1885.     CMP    B
  1886.     JZ    SNDFILE
  1887.     LDA    LOGCHR        ; Send logon?
  1888.     CMP    B
  1889.     JZ    SNDLOG
  1890.     LDA    LSTCHR        ; Get the printer control-character
  1891.     CMP    B        ; Did we just ask for printer control?
  1892.     JNZ    NOLST        ; If not, exit
  1893.     LDA    LISTFLG        ; Otherwise reset the printer toggle
  1894.     CMA
  1895.     STA    LISTFLG        ; And store
  1896.     CALL    CRLF
  1897.     CALL    CRLF
  1898.     CALL    LSTMS        ; Tell if printer is on or off now
  1899.     CALL    CRLF
  1900.     JMP    TERML        ; Back to the terminal mode again
  1901. ;...
  1902. ;
  1903. ;
  1904. NOLST:    LDA    BRKCHR        ; Want to send a break tone?
  1905.     CMP    B
  1906.     JZ    SBREAK
  1907.     LDA    NOCONCT        ; Want to disconnect from line?
  1908.     CMP    B
  1909.     JZ    DONETD        ; If yes go disconnect
  1910.     LDA    UNSAVCH        ; Close input buffer?
  1911.     CMP    B
  1912.     JZ    NOLST1        ; If yes, disable copy
  1913.     LDA    SAVECHR        ; Open input buffer?
  1914.     CMP    B
  1915.     JNZ    NTOG
  1916.     LDA    NFILFLG        ; Do not allow save if flag is set
  1917.     ORA    A
  1918.     JZ    TERML
  1919.     JMP    NOLST2
  1920. ;
  1921. NOLST1:    XRA    A        ; Stop copy into file
  1922. ;
  1923. NOLST2:    STA    SAVEFLG
  1924.     CALL    BUFMS
  1925.     JMP    TERM        ; Get next character
  1926. ;.....
  1927. ;
  1928. ;
  1929. NTEXAFLG:
  1930.     LDA    EXTCHR        ; Treat next character in special way?
  1931.     CMP    B        ; Check against this control character
  1932.     JNZ    NOF
  1933.     STA    EXACFLG        ; Set the flag
  1934. ;
  1935.     LDA    INTCPT        ; See if INTCPT is same as EXTCHR
  1936.     CMP    B        ; (If it is, is ok - it uses 0-9)
  1937.     JNZ    TERML        ; If not, all set with EXACFLG flag set
  1938.     STA    FNKFLG        ; If yes, set FNKFLG also
  1939.     JMP    TERML        ; Do not send, get next character
  1940. ;.....
  1941. ;
  1942. ;
  1943. NOF:    LDA    INTCPT        ; Check intercept character
  1944.     CMP    B
  1945.     JNZ    NTOG        ; If not send this character to modem
  1946.     STA    FNKFLG        ; Set the function flag
  1947.     JMP    TERML        ; Do not send the intercept character
  1948. ;.....
  1949. ;
  1950. ;
  1951. ; Clears the CRT screen with "ESC-Z"
  1952. ;
  1953. CLRCRT:    CALL    CLRTST
  1954.     JMP    TERML        ; Back to work
  1955. ;.....
  1956. ;
  1957. ;
  1958. ;***********************************************************************
  1959. ;
  1960. ;             SND A CP/M FILE
  1961. ;
  1962. ;***********************************************************************
  1963. ;
  1964. ;
  1965. SNDFL:    CALL    CKCHAR        ; Catch any garbage characters
  1966.     XRA    A        ; Indicate using send batch mode
  1967.     STA    SNDFLG
  1968.     LDA    BATCHFLG    ; Check if multiple file mode is set
  1969.     ORA    A
  1970.     JNZ    SNDFL4        ; If not using batch mode, exit
  1971. ;
  1972.     CALL    ILPRT
  1973.     DB    'Ready to send in batch mode',CR,LF,0
  1974. ;
  1975. SNDFL1:    LDA    FSTFLG        ; First time through?
  1976.     ORA    A
  1977.     JNZ    SNDFL2        ; If not, exit
  1978.     CALL    TNMBUF        ; Get and store batch file names
  1979.     LDA    FILECT        ; Get the number of files to send
  1980.     ORA    A
  1981.     JNZ    SNDFL2        ; Exit if something to send
  1982.     CALL    ILPRTQ
  1983.     DB    CR,LF,'++ Ask again, file not found ++',0
  1984. ;
  1985. SNDFL2:    CALL    SNDFN        ; Sends file name to receive
  1986.     JNC    SNDFL3        ; More files if carry is not set
  1987. ;
  1988.     MVI    A,'B'        ; Stop batch mode
  1989.     STA    BATCHFLG
  1990.     LDA    GOTONE        ; Was a file actually transferred?
  1991.     ORA    A
  1992.     JZ    ABORT        ; If not, don't say it was
  1993.     JMP    DONE
  1994. ;
  1995. SNDFL3:    CALL    CRLF        ; Extra line before file name
  1996.     CALL    SHOWFIL        ; Display the file name
  1997.     CALL    CRLF
  1998. ;
  1999. SNDFL4:    LDA    FCB+1
  2000.     CPI    ' '
  2001.     JZ    BLKFILE
  2002.     CALL    CNREC        ; Get number of records
  2003.     CALL    OPENFIL
  2004.     CALL    RDBLK1        ; Read some of the file into the buffer
  2005.     CALL    CKCHAR        ; Catch any garbage characters
  2006.     LDA    KKMD        ; See if operator typed "SK"
  2007.     ORA    A
  2008.     JNZ    SNDFL5        ; If not, exit
  2009.     INR    A        ; Else set the manual 1k flag
  2010.     STA    KFLG
  2011. ;
  2012. SNDFL5:    MVI    E,60        ; Wait up to 1 minute for a start signal
  2013.     CALL    WAITNAK
  2014.     CALL    SETFLG        ; Switch to 128 size if under 8 records
  2015. ;
  2016. SNDLP:    CALL    GTRATIO        ; Check the ACK ratio if using 1k blocks
  2017.     CALL    RDRECD        ; Read a record
  2018.     JC    SNDEOF        ; If finished, exit
  2019.     CALL    INCRNO        ; Increment the record number
  2020.     MVI    A,1
  2021.     STA    ERRCT        ; Reset the error count to normal
  2022. ;
  2023. SNDRPT:    CALL    CKABORT        ; Want to quit at this time?
  2024.     CALL    SNDHDR        ; Send a header group
  2025.     CALL    SNDREC        ; Send the record number
  2026.     CALL    SNDCHK        ; Send CRC or Checksum
  2027.     CALL    GTACK        ; Wait for an 'ACK' for this record
  2028.     JC    SNDRPT        ; Repeat same record if no 'ACK'
  2029. ;
  2030.     CALL    SETPTR        ; Successful record so increase pointers
  2031.     JMP    SNDLP        ; Send next record
  2032. ;.....
  2033. ;
  2034. ;
  2035. SNDEOF:    MVI    A,EOT        ; Send an End of Transmission character
  2036.     CALL    SEND
  2037.     LDA    CHKEOT        ; Did not get an 'ACK', try again
  2038.     INR    A
  2039.     STA    CHKEOT        ; Limit number of retries to 4
  2040.     CPI    4
  2041.     JNC    DONE        ; If four or more, assume he got one
  2042.     CALL    GTACK        ; Wait for an 'ACK' that it was received
  2043.     JC    SNDEOF        ; Try again, they didn't get it
  2044.     JMP    DONE        ; Else got a good ACK, so finished
  2045. ;.....
  2046. ;
  2047. ;
  2048. ;***********************************************************************
  2049. ;
  2050. ;               RECEIVE A CP/M FILE
  2051. ;
  2052. ;***********************************************************************
  2053. ;
  2054. ;
  2055. RCVFL:    LDA    XMODEM        ; "RX", insures receiving blocks of 128
  2056.     STA    KFLG        ; Set the 1k block flag similar
  2057.     LDA    CRCDFLT        ; Get mode requested by operator
  2058.     STA    CRCFLG        ; Store it, resets 1k blocks if needed
  2059.     ORA    A
  2060.     JNZ    RCVFL1        ; Skip next line if requesting CRC
  2061.     STA    KFLG        ; Can't have 1k blocks with checksum
  2062. ;
  2063. RCVFL1:    LDA    BATCHFLG    ; Check if multiple file mode
  2064.     ORA    A
  2065.     JNZ    RCVFL2        ; If not, exit
  2066.     MVI    A,1        ; Indicate using receive batch mode
  2067.     STA    SNDFLG        ; For next file transfer
  2068.     CALL    GETFN        ; Get the file name
  2069.     JNC    RCVFL3        ; Carry not set means more files yet
  2070. ;
  2071.     MVI    A,'B'        ; Stop batch
  2072.     STA    BATCHFLG    ; Mode option
  2073.     LDA    GOTONE        ; Indicates a batch file was transferred
  2074.     ORA    A
  2075.     JZ    ABORT        ; If not, don't indicate it was
  2076.     JMP    DONE
  2077. ;
  2078. RCVFL2:    LDA    FCB+1        ; Make sure file is named
  2079.     CPI    ' '
  2080.     JZ    BLKFILE
  2081.     JMP    RCVFL5
  2082. ;
  2083. RCVFL3:    LDA    KMDODE        ; Using Yam batch?
  2084.     ORA    A
  2085.     JZ    RCVFL4        ; Yes, skip showfil as already done
  2086.     CALL    SHOWFIL        ; Show the file name
  2087.     MVI    A,' '
  2088.     CALL    TYPE
  2089.     CALL    SNDPRG        ; Get progress and wait for quiet line
  2090. ;
  2091. RCVFL4:    CALL    CKCPM2
  2092.     LDA    KMDODE
  2093.     ORA    A
  2094.     JZ    RCVFL5        ; Skip CRLF if in Yam batch
  2095.     CALL    CRLF
  2096. ;
  2097. RCVFL5:    CALL    ERASF
  2098.     CALL    MAKEFIL
  2099.     CALL    WAITQ1
  2100.     LDA    BATCHFLG    ; Do not print message if in batch mode
  2101.     ORA    A
  2102.     JZ    RCVFL6        ; Exit if in batch mode
  2103.     CALL    FILNAM
  2104.     CALL    ILPRTQ
  2105.     DB    CR,LF,'File open, ready to receive',CR,LF,0
  2106. ;
  2107. RCVFL6:    LDA    CRCFLG
  2108.     ORA    A
  2109.     JZ    RCVFCHK        ; Exit if in checksum mode
  2110.     LDA    BATCHFLG    ; In batch mode?
  2111.     ORA    A
  2112.     JNZ    RCVFLC        ; Exit if not
  2113.     LDA    KMDODE        ; Yam batch?
  2114.     ORA    A
  2115.     JZ    RCVFL7        ; Yes, skip CRC message and KFLG
  2116. ;
  2117. RCVFLC:    CALL    ILPRTQ        ; Then say so
  2118.     DB    'CRC in effect',CR,LF,0
  2119. ;
  2120. RCVFL7:    MVI    A,CRC        ; Else request 128 size with CRC
  2121.     JMP    RCVLF8
  2122. ;
  2123. RCVFCHK:CALL    ILPRTQ        ; Else say 'CHECKSUM' mode
  2124.     DB    'Checksum in effect',CR,LF,0
  2125.     MVI    A,NAK
  2126. ;
  2127. RCVLF8:    PUSH    PSW
  2128.     CALL    ILPRT
  2129.     DB    'Waiting.....',0
  2130.     POP    PSW
  2131.     CALL    SEND
  2132.     LDA    KFLG        ; Requesting 1k blocks?
  2133.     ORA    A
  2134.     JZ    RCVLP
  2135.     MVI    A,KSND        ; 1k block request
  2136.     CALL    SEND
  2137. ;
  2138. ;
  2139. ; This is the acutal receive loop
  2140. ;
  2141. RCVLP:    CALL    RCVRECD
  2142.     JC    RCVEOT
  2143.     CALL    INCRNO
  2144.     CALL    REPORT        ; Show record received if not in quiet
  2145.     CALL    WRRECD
  2146.     CALL    SNDACK
  2147.     JMP    RCVLP        ; Loop for next incoming record
  2148. ;
  2149. ;
  2150. ; Got an EOT, erase an empty file, else write to disk and close the file
  2151. ;
  2152. RCVEOT:    LHLD    RECNO        ; Check for zero length file
  2153.     MOV    A,H        ; If no records, no file
  2154.     ORA    L
  2155.     JZ    ABORT        ; Abort and erase the zero-length file
  2156.     CALL    WRBLOCK
  2157.     CALL    CLOSFIL
  2158.     CALL    SNDACK
  2159.     JMP    DONE
  2160. ;.....
  2161. ;
  2162. ;
  2163. SNDACK:    MVI    A,ACK
  2164.     JMP    SEND
  2165. ;.....
  2166. ;
  2167. ;
  2168. ;===================== SEND FILE IN T-MODE =============================
  2169. ;
  2170. ;
  2171. ; Send file routine - called with (special character F) when in terminal
  2172. ; mode.  Sending may be cancelled by using CTL-X (cancel) key.
  2173. ;
  2174. SNDFILE:LXI    H,FCB4
  2175.     CALL    INITFCB        ; Initializes FCBs
  2176.     LXI    H,FCB+16
  2177.     CALL    INITFCB
  2178. ;
  2179. ;
  2180. ; Get name of file to send in "T" (terminal) mode
  2181. ;
  2182. GET:    CALL    ILPRT
  2183.     DB    CR,LF,'File name to send? (CR to abort): ',0
  2184.     LXI    D,CMDBUF
  2185.     CALL    INBUF
  2186.     LDA    CMDBUF+2    ; Was file entered?
  2187.     CPI    ' '
  2188.     JZ    RETRN        ; If not probably wanted to quit
  2189.     LXI    D,CMDBUF
  2190.     LXI    H,FCB4
  2191.     CALL    CMDLINE
  2192.     LXI    D,FCB4
  2193.     MVI    C,OPEN
  2194.     CALL    BDOS
  2195.     CPI    0FFH        ; Return with 0FFH means 'NO SUCH FILE'
  2196.     JZ    SNDMSG
  2197. ;
  2198. ;
  2199. ; Choice of normal speed or delays between characters / lines
  2200. ;
  2201.     CALL    ILPRT
  2202.     DB    'Want to include time delays? (Y/N): ',0
  2203.     CALL    KBDCHR
  2204.     CPI    'N'        ; If 'N' send normal speed
  2205.     JZ    DLYSAV
  2206.     XRA    A        ; Otherwise use character/line delays
  2207. ;
  2208. DLYSAV:    STA    DLYFLG        ; Store the decision
  2209.     CALL    CRLF
  2210.     LXI    D,CMDBUF+2    ; Make sure CMDBUF has been selected
  2211.     MVI    C,STDMA
  2212.     CALL    BDOS
  2213. ;
  2214. ;
  2215. ; Get 128-byte record
  2216. ;
  2217. READM:    LXI    D,FCB4
  2218.     MVI    C,READ
  2219.     CALL    BDOS
  2220.     ORA    A        ; Check for a good read
  2221.     JZ    READM1
  2222.     DCR    A        ; Check for end of file to send
  2223.     JZ    RETRNS
  2224.     CALL    ERXIT        ; Neither of those, was a read error
  2225.     DB    '++ DISK READ ERROR ++','$'
  2226. ;
  2227. ;
  2228. ; Successful read, so send the record
  2229. ;
  2230. READM1:    CALL    SND80C        ; Send one 128-char record
  2231.     CPI    EOFCHAR        ; End of file - omit if object
  2232.     JZ    RETRNS        ;   code is to be sent.
  2233.     CPI    CANCEL        ; Want to quit?
  2234.     JNZ    READM
  2235. ;
  2236. RETRN:    CALL    ILPRT
  2237.     DB    CR,LF,LF,'(in Terminal-mode now)',CR,LF,LF,0
  2238.     CALL    SNDNOW        ; Insures last character is finished
  2239.     CALL    CKCHAR        ; Catch any echo character on line
  2240.     JMP    TERM        ; Finished, back to Terminal-mode
  2241. ;.....
  2242. ;
  2243. ;
  2244. RETRNS:    CALL    ILPRT
  2245.     DB    CR,LF,'[Transfer completed]',0
  2246.     JMP    RETRN
  2247. ;.....
  2248. ;
  2249. ;
  2250. SNDMSG:    CALL    ILPRT
  2251.     DB    CR,LF,BELL,'++ FILE NAME ERROR ++ ',CR,LF,0
  2252.     JMP    GET
  2253. ;.....
  2254. ;
  2255. ;
  2256. ; Send one 128-byte record
  2257. ;
  2258. SND80C:    MVI    B,128        ; Will send a maximum of 128 character
  2259.     LXI    H,CMDBUF+2    ; They are in the CMDBUF area
  2260. ;
  2261. SNDCH1:    MOV    A,M        ; Get the character to send
  2262.     ANI    7FH        ; Strip off any high bits set
  2263.     CPI    EOFCHAR
  2264.     RZ
  2265.     CALL    MDOUT        ; Send the character to modem
  2266.     CALL    STAT        ; Want to terminate sending?
  2267.     ORA    A
  2268.     JZ    SKIP1
  2269.     CALL    KEYIN
  2270.     CPI    CANCEL
  2271.     RZ
  2272. ;
  2273. SKIP1:    INX    H
  2274.     DCR    B
  2275.     JNZ    SNDCH1
  2276.     RET
  2277. ;.....
  2278. ;
  2279. ;
  2280. ; Send the character to the output
  2281. ;
  2282. MDOUT:    PUSH    PSW        ; Save the character so can use 'A' reg.
  2283.     CPI    LF
  2284.     JNZ    MDOUTL
  2285.     LDA    ADDLFD        ; Going to send the line feed to modem?
  2286.     ORA    A
  2287.     JNZ    MDOUTL        ; If yes, go to normal routine
  2288.     POP    PSW        ; Get the character back (a line feed)
  2289.     CALL    TYPE        ; Show on CRT, do not send to modem
  2290.     RET
  2291. ;...
  2292. ;
  2293. ;
  2294. MDOUTL:    CALL    TXOFF        ; Check for Xoff
  2295.     LDA    DLYFLG        ; Going to include delays?
  2296.     ORA    A
  2297.     JNZ    MDOUTL2        ; If not, check normal flag
  2298. ;
  2299. MDOUTL1:CALL    SNDTXE        ; See if TxE output buffer is empty yet
  2300.     JNZ    MDOUTL1        ; If not, wait
  2301.     CALL    SPDCHR        ; When ready, kick in requested delay
  2302.     JMP    MDOUTL3        ; Go send the character
  2303. ;
  2304. MDOUTL2:CALL    SNDRDY        ; Wait until modem is ready to send
  2305.     JNZ    MDOUTL
  2306. ;
  2307. MDOUTL3:POP    PSW        ; Get the character back
  2308.     CALL    TYPE        ; Send character to CRT
  2309.     CALL    O$MDDATP    ; Send character to modem
  2310.     CPI    CR        ; Was it an end of line?
  2311.     RNZ            ; If yes, see if any delay is needed
  2312. ;
  2313. ;
  2314. ; Delay to allow slow BBS systems (most use BASIC) to enter the line.
  2315. ; Choice of 0-9 for 100 ms. each, maximum of 900 ms.
  2316. ;
  2317.     LDA    DLYFLG        ; Going to send a delay each line?
  2318.     ORA    A
  2319.     JZ    SPDLIN        ; If yes send the delay
  2320.     RET
  2321. ;.....
  2322. ;
  2323. ;
  2324. ; Add from 0 to 9 ms. delay between characters for slow bulletin board
  2325. ; systems (most use 'C' or 'MBASIC').
  2326. ;
  2327. SPDCHR:    LDA    BYTDLY        ; Get delay between characters (0-9)
  2328.     ORA    A
  2329.     RZ            ; Don't bother if set to zero
  2330.     PUSH    B
  2331.     ADD    A        ; Double the value for 1 ms. loops
  2332.     ADD    A        ; Double again for the 1 ms. loops
  2333.     MOV    B,A        ; Main number of loops
  2334.     CALL    SPEED
  2335.     POP    B        ; Restore the BC values
  2336.     RET
  2337. ;.....
  2338. ;
  2339. ;
  2340. ; Sends 0-900 ms between lines
  2341. ;
  2342. SPDLIN:    LDA    CRDLY        ; Get delay between lines (0-90)
  2343.     ORA    A
  2344.     RZ            ; Don't bother if set to zero
  2345.     PUSH    B
  2346.     ADD    A        ; Double the value for 1 ms. loops
  2347.     ADD    A        ; Double again for the 1 ms. loops
  2348.     MOV    C,A        ; Store
  2349.     MVI    D,100        ; 100 loops for 100 ms. each
  2350. ;
  2351. SPDLIN1:MOV    B,C        ; Get the original value again
  2352.     CALL    SPEED
  2353.     DCR    D        ; One less main loop to go
  2354.     JNZ    SPDLIN1        ; If not zero, keep delaying
  2355.     POP    B        ; Restore the BC values
  2356.     RET
  2357. ;...
  2358. ;
  2359. ;
  2360. ; For 1/2 ms delay
  2361. ;
  2362. SPEED:    LDA    CLOCK        ; Secondary number of loops
  2363. ;
  2364. SPEED1:    XCHG            ; Waste some time
  2365.     XCHG            ; Restore HL & DE, a little more time
  2366.     DCR    A        ; Decrement inner loop
  2367.     JNZ    SPEED1        ; If not zero, keep going
  2368.     DCR    B        ; Decrement outer loop
  2369.     JNZ    SPEED        ; If not zero, reset inner loop
  2370.     RET
  2371. ;.....
  2372. ;
  2373. ;
  2374. TXOFF:    CALL    RCVRDY
  2375.     RNZ
  2376.     CALL    I$MDDATP
  2377.     ANI    7FH
  2378.     CPI    XOFF
  2379.     CZ    WAITXON
  2380.     RET
  2381. ;.....
  2382. ;
  2383. ;
  2384. WAITXON:CALL    RCVRDY        ; Have a character? (like X-on)
  2385.     JNZ    WTXON1        ; If no character see if want to abort
  2386.     CALL    I$MDDATP
  2387.     ANI    7FH        ; Strip off any parity
  2388.     CPI    XON        ; See if character was X-on
  2389.     RZ            ; If yes, keep going
  2390. ;
  2391. WTXON1:    CALL    STAT        ; Test to see if requesting cancellation
  2392.     JZ    WAITXON        ; Nothing typed, wait for X-on
  2393.     CALL    KEYIN        ; Can abort if the X-on never comes
  2394.     CPI    CANCEL        ; CTL-X to abort?
  2395.     JNZ    WAITXON        ; If not, keep going
  2396.     RET
  2397. ;.....
  2398. ;
  2399. ;
  2400. ;=================== END OF FILE SEND IN T-MODE ========================
  2401. ;
  2402. ;
  2403. ;***********************************************************************
  2404. ;
  2405. ;               SUBROUTINES
  2406. ;
  2407. ;***********************************************************************
  2408. ;
  2409. ;
  2410. ; Show the file name as stored in the FCB but in CP/M format
  2411. ;
  2412. SHOWFIL:LDA    QFLG        ; Can type it if no 'QFLG'
  2413.     ORA    A
  2414.     RZ
  2415.     LXI    H,FCB+1
  2416.     XRA    A
  2417.     STA    FTYCNT
  2418.     MVI    C,11
  2419. ;
  2420. PRNAM:    CALL    FTYTST
  2421.     INX    H
  2422.     DCR    C
  2423.     JNZ    PRNAM
  2424.     RET
  2425. ;.....
  2426. ;
  2427. ;
  2428. ; Give report of received records as they occur
  2429. ;
  2430. REPORT:    LDA    QFLG
  2431.     ORA    A
  2432.     RZ
  2433.     LHLD    RECNO        ; Get record number
  2434.     CALL    ILPRT
  2435.     DB    CR,'Received # ',0
  2436.     CALL    DECOUT        ; Print record number in decimal
  2437.     CALL    ILPRT
  2438.     DB    ' ',0
  2439.     RET
  2440. ;.....
  2441. ;
  2442. ;
  2443. FTYTST:    LDA    FTYCNT
  2444.     INR    A
  2445.     STA    FTYCNT
  2446.     CPI    9        ; Are we at the file type?
  2447.     JZ    SPCTST        ; Go if so
  2448. ;
  2449. ENDSPT:    MOV    A,M
  2450.     CPI    ' '        ; Test for space
  2451.     CNZ    TYPE        ; Type if not
  2452.     RET
  2453. ;.....
  2454. ;
  2455. ;
  2456. ; See if enough records in file to use 1k protocol if requested
  2457. ;
  2458. SETFLG:    LHLD    RCNT
  2459.     MOV    A,H        ; Anything in the 'H' register?
  2460.     ORA    A
  2461.     RNZ
  2462.     MOV    A,L        ; Get number of records in 'L' register
  2463.     CPI    8        ; At least 8 yet?
  2464.     RNC            ; If 8 or more, keep going
  2465.     XRA    A        ; Reset the 'K' flag
  2466.     STA    KFLG
  2467.     RET
  2468. ;.....
  2469. ;
  2470. ;
  2471. SPCTST:    MOV    A,M
  2472.     CPI    ' '        ; Test for space in 1st file type byte
  2473.     RZ            ; Do not output period if space
  2474.     MVI    A,'.'
  2475.     CALL    TYPE
  2476.     JMP    ENDSPT        ; Output 1st file type byte
  2477. ;.....
  2478. ;
  2479. ;
  2480. ; Get sender's progress report if it is present and wait for line to get
  2481. ; quiet
  2482. ;
  2483. SNDPRG:    MVI    B,1        ; Wait up to 1 second
  2484.     CALL    RECV
  2485.     CALL    TYPE        ; Show the progress report from sender
  2486.     JNC    SNDPRG
  2487.     RET
  2488. ;.....
  2489. ;
  2490. ;
  2491. SNDFN:    LDA    KMDODE        ; Using Yam batch?
  2492.     ORA    A
  2493.     JZ    SNDKMD        ; If so, skip following routine
  2494. ;
  2495.     CALL    ILPRTQ
  2496.     DB    CR,LF,'Awaiting name NAK',0
  2497.     CALL    GTACK
  2498.     CC    SNDACK
  2499.     LXI    H,FILECT
  2500.     DCR    M
  2501.     JM    NOMRN
  2502.     LHLD    NBSAVE        ; Get file name..
  2503.     LXI    D,FCB        ; In FCB
  2504.     MVI    B,12
  2505.     CALL    MOVE
  2506.     SHLD    NBSAVE
  2507.     CALL    SNDNM        ; Send it
  2508.     ORA    A        ; Clear carry
  2509.     RET
  2510. ;.....
  2511. ;
  2512. ;
  2513. NOMRN:    MVI    A,EOT
  2514.     CALL    SEND
  2515.     STC
  2516.     RET
  2517. ;.....
  2518. ;
  2519. ;
  2520. ;-----------------------------------------------------------------------
  2521. ;               KMD send batch mode
  2522. ;
  2523. SNDKMD:    CALL    CATCH        ; Clear the decks for action
  2524.     XRA    A
  2525.     STA    ERRCT        ; Initialize the error counter
  2526.     MVI    A,1
  2527.     STA    CRCFLG        ; Make sure in CRC mode
  2528.     LDA    FILECT        ; Any files to send?
  2529.     ORA    A
  2530.     JZ    CCHECK        ; If not exit and wait for 'C'
  2531. ;
  2532.     LHLD    NBSAVE        ; Get current file name
  2533.     LXI    D,FCB        ; Move it into the FCB
  2534.     MVI    B,12
  2535.     CALL    MOVE
  2536.     SHLD    NBSAVE
  2537.     LHLD    RECPTR        ; Where to load the 0 block
  2538.     XCHG            ; Put into DE
  2539.     LXI    H,FCB+1
  2540.     MVI    B,8
  2541. ;
  2542. SKMD0:    MOV    A,M
  2543.     ANI    7FH        ; Strip any high bit set
  2544.     ORA    A
  2545.     JZ    SKMD5        ; Null pathname
  2546.     CPI    ' '
  2547.     JZ    SKMD2
  2548. ;
  2549. SKMD1:    CALL    LCASE        ; Put file name in lower case for UNIX
  2550.     STAX    D
  2551.     INX    H
  2552.     INX    D
  2553.     DCR    B
  2554.     JNZ    SKMD0
  2555.     JMP    SKMD3
  2556. ;
  2557. SKMD2:    INX    H        ; Skip over spaces is short name
  2558.     DCR    B
  2559.     JNZ    SKMD2
  2560. ;
  2561. SKMD3:    MOV    A,M
  2562.     CPI    ' '
  2563.     JZ    SKMD5        ; Missing file type field
  2564.     MVI    A,'.'        ; Send name-type seperator
  2565.     STAX    D
  2566.     INX    D
  2567.     MVI    B,3
  2568. ;
  2569. SKMD4:    MOV    A,M
  2570.     ANI    7FH        ; Strip any high bit set
  2571.     CPI    ' '
  2572.     JZ    SKMD5
  2573.     CALL    LCASE        ; Put extent in lower case for UNIX
  2574.     STAX    D
  2575.     INX    H
  2576.     INX    D
  2577.     DCR    B
  2578.     JNZ    SKMD4
  2579. ;
  2580. SKMD5:    XCHG            ; Get the address back to HL
  2581. ;
  2582. SKMD6:    MVI    M,0        ; Fill rest of block with zeroes
  2583.     INR    L
  2584.     JNZ    SKMD6
  2585. ;
  2586.     MVI    C,FILSIZ
  2587.     LXI    D,FCB
  2588.     CALL    BDOS
  2589.     LHLD    FCB+33
  2590.     SHLD    BUFSTR        ; Store the file length at end of block
  2591.     XRA    A
  2592.     STA    RCDCNT        ; Special header starts with 0
  2593. ;
  2594. ;
  2595. ; Wait for a 'C' from remote system
  2596. ;
  2597. CCHECK:    MVI    E,60
  2598. ;
  2599. CCHECK1:CALL    CKABORT
  2600.     MVI    B,1
  2601.     CALL    RECV
  2602.     JC    CCHECK2        ; No character, decrement counter
  2603.     CPI    CANCEL
  2604.     CZ    CKCAN        ; Check for cancel
  2605.     CPI    CRC
  2606.     JZ    SKMD7
  2607.     JMP    CCHECK1
  2608. ;
  2609. CCHECK2:DCR    E        ; One less loop to go
  2610.     JNZ    CCHECK
  2611.     JMP    ABORTX
  2612. ;
  2613. ;
  2614. ; Got a 'C' so either send the file or terminate batch, if no more files
  2615. ;
  2616. SKMD7:    LDA    FILECT        ; Any files to send?
  2617.     ORA    A
  2618.     JZ    KMDEND        ; If not, terminate batch send
  2619.     DCR    A        ; Else decrement count for this file
  2620.     STA    FILECT
  2621.     LXI    H,FILECT
  2622. ;
  2623. ;
  2624. ; Now send the 128-byte file name record
  2625. ;
  2626. SKMD8:    XRA    A
  2627.     STA    KFLG
  2628.     MVI    A,SOH        ; Send SOH
  2629.     CALL    SEND
  2630.     CALL    SNDHNM        ; Send header (record number, inverse)
  2631.     CALL    SNDREC        ; Send a 128 byte record
  2632.     CALL    SNDCRC        ; Send a two byte CRC
  2633.     CALL    GTACK        ; Get the ACK
  2634.     CPI    ACK        ; Was it an 'ACK'?
  2635.     JNZ    SKMD8        ; If not, send the header block again
  2636.     LDA    XMODEM        ; User want's 128 byte blocks?
  2637.     ORA    A
  2638.     JZ    SKMD9        ; Yes
  2639.     MVI    A,1
  2640.     STA    KFLG        ; Use 1k blocks in batch
  2641. ;
  2642. SKMD9:    XRA    A        ; Clear the carry flag
  2643.     STA    ERRCT        ; Start fresh for the main file
  2644.     RET
  2645. ;.....
  2646. ;
  2647. ;
  2648. KMDEND:    XRA    A
  2649.     LHLD    RECPTR
  2650.     MOV    M,A
  2651.     STA    RCDCNT
  2652.     STA    KFLG
  2653.     MVI    A,SOH
  2654.     CALL    SEND
  2655.     CALL    SNDHNM
  2656.     CALL    SNDREC
  2657.     CALL    SNDCRC
  2658.     STC
  2659.     RET
  2660. ;.....
  2661. ;
  2662. ;
  2663. ; Wait for line to get quiet and gobble characters
  2664. ;
  2665. WAITQ1:    MVI    B,1
  2666.     CALL    RECV
  2667.     JNC    WAITQ1
  2668.     RET
  2669. ;.....
  2670. ;
  2671. ;
  2672. ; Send the MODEM7 batch file name
  2673. ;
  2674. SNDNM:    PUSH    H
  2675. ;
  2676. SNDNM1:    MVI    D,11        ; Count characters in name
  2677.     MVI    C,0        ; Initialize checksum
  2678.     LXI    H,FCB+1        ; Address name
  2679. ;
  2680. NAMLPS:    MOV    A,M        ; Send name
  2681.     ANI    7FH        ; Strip high order bit so CP/M2
  2682.     CALL    SEND        ;   will not send R/O file designation.
  2683. ;
  2684. ACKLP:    PUSH    B        ; Save checksum
  2685.     MVI    B,5        ; Wait for receiver to acknowledge
  2686.     CALL    RECV        ;   getting the character
  2687.     POP    B
  2688.     JC    SCKSER
  2689.     CPI    ACK
  2690.     JNZ    ACKLP
  2691.     INX    H        ; Next character
  2692.     DCR    D
  2693.     JNZ    NAMLPS
  2694.     MVI    A,EOFCHAR    ; Tell receiver the end of name
  2695.     CALL    SEND
  2696.     MOV    D,C        ; Save checksum
  2697.     MVI    B,5        ; Wait up to 5 seconds
  2698.     CALL    RECV        ; Get checksum
  2699.     CMP    D
  2700.     JNZ    SCKSER        ; Exit if bad name
  2701.     MVI    A,OKNMCH    ; Good name-tell receiver
  2702.     CALL    SEND
  2703.     POP    H
  2704.     RET
  2705. ;.....
  2706. ;
  2707. ;
  2708. SCKSER:    MVI    A,BDNMCH    ; Bad name-tell receiver
  2709.     CALL    SEND
  2710.     CALL    ILPRT
  2711.     DB    CR,LF,'++ ERROR sending name  ++',CR,LF,0
  2712.     MVI    E,60        ; Do handshaking over (2 minutes maximum)
  2713.     CALL    WAITNAK        ; See what protocol the user has
  2714.     CALL    SNDACK
  2715.     JMP    SNDNM1
  2716. ;.....
  2717. ;
  2718. ;
  2719. GETFN:    LXI    H,FCB
  2720.     CALL    INITFCB1    ; Does not initialize drive
  2721.     LDA    KMDODE        ; Yam batch supported?
  2722.     ORA    A
  2723.     JZ    RCVKMD        ; Yes, go to alternate routine
  2724. ;
  2725.     CALL    ILPRTQ
  2726.     DB    CR,LF,'Awaiting file name',CR,LF,0
  2727.     CALL    HSNAK
  2728.     CALL    GETNM        ; Get the name
  2729.     CPI    EOT        ; If EOT, then no more files
  2730.     JZ    GETFN1
  2731.     ORA    A        ; Clear carry
  2732.     RET
  2733. ;
  2734. GETFN1:    STC            ; Set carry to show no more files
  2735.     RET
  2736. ;.....
  2737. ;
  2738. ;
  2739. ;-----------------------------------------------------------------------
  2740. ;             KMD receive batch mode
  2741. ;
  2742. RCVKMD:    XRA    A        ; Initialize the error counter
  2743.     STA    RCVTRY
  2744.     CALL    CATCH        ; Clear the decks for action
  2745. ;
  2746. RKMD1:    CALL    CKABORT        ; Check for user abort
  2747.     MVI    B,3        ; Wait up to 3 sec. for SOH from remote
  2748.     CALL    RECV
  2749.     JC    RKMD2        ; No character, decrement counter
  2750.     CPI    CANCEL        ; Was it a CTL-X for cancel?
  2751.     CZ    CKCAN        ; Abort if yes
  2752.     CPI    SOH        ; SOH is all we are interested in
  2753.     JZ    RKMD4
  2754.     JMP    RKMD1        ; Anything else, ignore
  2755. ;
  2756. RKMD2:    MVI    A,CRC        ; Send a 'C'
  2757.     CALL    SEND
  2758. ;
  2759. RKMD3:    LDA    RCVTRY        ; Increment the "try" counter
  2760.     INR    A
  2761.     STA    RCVTRY
  2762.     CPI    20        ; Tried 1 minute yet?
  2763.     JC    RKMD1
  2764.     JMP    ABORT        ; Quit and try to force him to quit
  2765. ;
  2766. RKMD4:    MVI    B,5        ; 5 seconds to get sector number
  2767.     CALL    RECV
  2768.     JC    KMDTOT        ; No character, exit
  2769.     MOV    D,A        ; Save sector number in D
  2770.     ORA    A
  2771.     JNZ    KMDHDR        ; Must be a 0 if sending batch header
  2772.     MVI    B,5        ; 5 seconds to get reciprocal
  2773.     CALL    RECV
  2774.     JC    KMDTOT        ; No character, exit
  2775.     CMA            ; Invert it and compare to sector #
  2776.     CMP    D
  2777.     JNZ    KMDCRC        ; Bad match
  2778.     LXI    H,0
  2779.     SHLD    CRCVAL        ; Clear CRC counter
  2780.     MVI    E,128
  2781.     LHLD    RECPTR        ; Get buffer address
  2782. ;
  2783. RKMD5:    MVI    B,5        ; 5 seconds to get 128 byte header block
  2784.     CALL    RECV
  2785.     JC    KMDTOT        ; No character, exit
  2786.     MOV    M,A        ; Store the character in the buffer
  2787.     INX    H        ; Next buffer address
  2788.     DCR    E        ; One less to go
  2789.     JNZ    RKMD5        ; If not, room for another character
  2790.     MVI    E,2
  2791. ;
  2792. RKMD6:    MVI    B,5
  2793.     CALL    RECV        ; Get CRC bytes
  2794.     JC    KMDTOT        ; No character, exit
  2795.     DCR    E        ; Done?
  2796.     JNZ    RKMD6        ; No
  2797.     CALL    CRCCHK        ; Compare CRC received against ours
  2798.     ORA    A        ; Ok?
  2799.     JNZ    KMDCRC        ; No
  2800.     CALL    SNDACK        ; Yes, acknowledge to remote
  2801. ;
  2802. ;
  2803. ; Decode pathname into CPM format
  2804. ;
  2805.     LXI    D,FCB+1        ; Where to put it
  2806.     LHLD    RECPTR        ; Where to get it
  2807.     MVI    B,8        ; Filename length
  2808. ;
  2809. RKMD7:    MOV    A,M        ; Get the character from the buffer
  2810.     ORA    A        ; Was it a zero?
  2811.     JZ    RKMD12        ; If yes, all done
  2812.     CPI    '.'        ; Was it a delimiter?
  2813.     JZ    RKMD9
  2814.     CPI    '_'        ; Unix can't handle this properly
  2815.     JNZ    RKMD8
  2816.     MVI    A,'/'        ; Change it to a slash
  2817. ;
  2818. RKMD8:    CALL    UCASE        ; Insure name is in upper case
  2819.     STAX    D        ; Store filename character in FCB
  2820.     INX    D        ; Increment pointers
  2821.     INX    H
  2822.     DCR    B        ; One less to go
  2823.     JNZ    RKMD7        ; If not 8, keep going
  2824. ;
  2825.     MOV    A,M        ; Get the character back
  2826.     ORA    A        ; We had 8, was there an extent?
  2827.     JZ    RKMD11        ; If zero, was all done
  2828.     JMP    RKMD10        ; Else must be a '.'
  2829. ;
  2830. RKMD9:    MVI    A,' '        ; Spaces to make up 8 spaces for name
  2831.     STAX    D        ; Store space character in FCB
  2832.     INX    D        ; Increment pointers
  2833.     DCR    B        ; One less to go
  2834.     JNZ    RKMD9        ; Keep going until in extent area
  2835. ;
  2836. RKMD10:    INX    H        ; Skip the '.' position
  2837.     MVI    B,3        ; Extent length
  2838.  
  2839. RKMD11:    MOV    A,M        ; Get the character from the buffer
  2840.     ORA    A        ; Was it a zero?
  2841.     JZ    RKMD12        ; If yes, all done
  2842.     CALL    UCASE        ; Insure extent is in upper case
  2843.     STAX    D        ; Store extent character
  2844.     INX    D        ; Increment pointers
  2845.     INX    H
  2846.     DCR    B        ; One less to go
  2847.     JNZ    RKMD11        ; Keep going until finished
  2848. ;
  2849. RKMD12:    LDA    FCB+1        ; See if there was any filename at all
  2850.     CPI    ' '
  2851.     STC
  2852.     RZ            ; No - end of batch
  2853. ;
  2854.     LDA    QFLG
  2855.     ORA    A
  2856.     RZ
  2857. ;
  2858.     CALL    ILPRTQ
  2859.     DB    CR,LF,'File name: ',0
  2860.     LHLD    RECPTR        ; Print filename
  2861. ;
  2862. RKMD13:    MOV    A,M
  2863.     ORA    A
  2864.     JZ    RKMD14        ; If zero, end of filename
  2865.     CALL    UCASE
  2866.     CALL    TYPE
  2867.     INX    H
  2868.     JMP    RKMD13
  2869. ;
  2870. RKMD14:    LHLD    BUFSTR        ; Get the file length, if provided
  2871.     MOV    A,H
  2872.     ORA    L
  2873.     JZ    RKMD15        ; If both zero, length not provided
  2874. ;
  2875.     SHLD    RCNT        ; Store the file length
  2876.     CALL    CRLF        ; Start a new line
  2877.     CALL    SNDTM
  2878. ;
  2879.     CALL    ILPRTQ
  2880.     DB    'k)',CR,LF,'Recv time: ',0
  2881.     LXI    H,KECTBL
  2882.     SHLD    RECTBL+1
  2883.     CALL    KTIM
  2884.     CALL    SNDTM1
  2885. ;
  2886. RKMD15:    CALL    CRLF        ; Finish the filename line
  2887.     XRA    A        ; Reset the carry flag
  2888.     STA    RCVTRY        ; Reset the error counter
  2889.     RET
  2890. ;.....
  2891. ;
  2892. ;
  2893. KMDCRC:    CALL    ILPRTQ
  2894.     DB    '++ CRC error ++',CR,LF,0
  2895.     JMP    KMDXFR
  2896. ;.....
  2897. ;
  2898. ;
  2899. KMDHDR:    CALL    ILPRTQ
  2900.     DB    '++ Wrong header type ++',CR,LF,0
  2901.     JMP    KMDXFR
  2902.  
  2903. ;.....
  2904. ;
  2905. ;
  2906. KMDTOT:    CALL    ILPRTQ
  2907.     DB    '++ Time out receiving filename ++',CR,LF,0
  2908. ;...
  2909. ;
  2910. ;
  2911. KMDXFR:    MVI    B,1        ; Make sure sender has stopped
  2912.     CALL    RECV
  2913.     JNC    KMDXFR        ; If not, wait until all sending stops
  2914.     MVI    A,NAK        ; Tell sender it was not successful
  2915.     CALL    SEND
  2916.     LDA    RCVTRY        ; Increment the error counter
  2917.     INR    A
  2918.     STA    RCVTRY
  2919.     CPI    33        ; Same as value in RKMD2
  2920.     JC    RKMD3        ; Send a NAK and tell him to try again
  2921.     JMP    ABORT        ; Else abort
  2922. ;.....
  2923. ;
  2924. ;          end of KMD get batch file name
  2925. ;-----------------------------------------------------------------------
  2926. ;            MODEM7 geta batch file name
  2927. ;
  2928. GETNM:    PUSH    H
  2929. ;
  2930. GETNM1:    MVI    A,0FFH
  2931.     STA    FLTRFLG
  2932.     MVI    C,0        ; Initialize checksum
  2933.     LXI    H,FCB+1
  2934. ;
  2935. NAMELPG:MVI    B,5
  2936.     CALL    RECV        ; Get the character
  2937.     PUSH    B
  2938.     PUSH    PSW
  2939. ;
  2940.     MVI    A,0FFH        ; Set the TIMFLG
  2941.     STA    TIMFLG
  2942. ;
  2943.     MVI    B,1
  2944.     CALL    RECV
  2945. ;
  2946.     XRA    A
  2947.     STA    TIMFLG
  2948. ;
  2949.     POP    PSW
  2950.     POP    B
  2951.     JNC    GETNM3
  2952.     CALL    ILPRTQ
  2953.     DB    'Time out receiving filename',CR,LF,0
  2954.     JMP    GCKSER
  2955. ;
  2956. GETNM3:    CPI    EOT        ; If EOT, then no more files
  2957.     JZ    GNRET
  2958.     CPI    EOFCHAR        ; Got end of name
  2959.     JZ    ENDNAME
  2960.     PUSH    PSW
  2961.     PUSH    B
  2962.     CALL    SNDACK
  2963.     POP    B
  2964.     POP    PSW
  2965.     MOV    M,A        ; Put name in FCB
  2966.     INX    H        ; Get next character
  2967.     MOV    A,L        ; Don not let noise cause overflow..
  2968.     CPI    7FH        ; Into the program area.
  2969.     JZ    GCKSER
  2970.     JMP    NAMELPG
  2971. ;
  2972. ENDNAME:XRA    A
  2973.     STA    FLTRFLG
  2974.     MOV    A,C        ; Send checksum
  2975.     MOV    D,C
  2976.     CALL    SEND
  2977. ;
  2978. NMLP1:    MVI    B,5        ; Wait up to 5 second to see if..
  2979.     CALL    RECV        ; The checksum is good
  2980.     CPI    OKNMCH        ; Yes if 'OKNMCH' sent
  2981.     JZ    GNRET
  2982.     CMP    D
  2983.     JZ    NMLP1        ; In case it is echo of send
  2984.     CPI    CR
  2985.     JZ    NMLP1
  2986.     CPI    LF
  2987.     JZ    NMLP1
  2988. ;
  2989. GCKSER:    LXI    H,FCB        ; Clear FCB (except drive) since it..
  2990.     CALL    INITFCB1    ; Might be damaged.
  2991.     CALL    ILPRTQ
  2992.     DB    CR,LF,'**  Checksum error  **',CR,LF,0
  2993.     XRA    A
  2994.     STA    FLTRFLG
  2995.     CALL    HSNAK        ; Do handshaking over
  2996.     JMP    GETNM1
  2997. ;
  2998. GNRET:    PUSH    PSW
  2999.     XRA    A
  3000.     STA    FLTRFLG
  3001.     POP    PSW
  3002.     POP    H
  3003.     RET
  3004. ;
  3005. HSNAK:    MVI    E,180        ; 3 minute wait for file name
  3006.     XRA    A
  3007.     STA    FLTRFLG
  3008. ;
  3009. HSNAK1:    CALL    CKABORT        ; Want to abort?
  3010.     MVI    A,NAK        ; Send 'NAK' until receiving 'ACK'
  3011.     CALL    SEND
  3012.     MVI    B,1        ; Wait up to 1 second for a character
  3013.     CALL    RECV
  3014.     CPI    ACK        ; 'ACK' is what we were waiting for
  3015.     RZ
  3016.     DCR    E
  3017.     JNZ    HSNAK1
  3018.     JMP    ABORT        ; Back to command line
  3019. ;.....
  3020. ;
  3021. ;
  3022. TNMBUF:    MVI    A,1        ; Call from 'SNDFL' only once.
  3023.     STA    FSTFLG
  3024.     XRA    A
  3025.     STA    FILECT
  3026.     CALL    SCAN
  3027.     LXI    H,NAMEBUF
  3028.     SHLD    NBSAVE        ; Save address of 1st name
  3029. ;
  3030. TNLP1:    CALL    TRTOBUF
  3031.     LXI    H,FCB
  3032.     LXI    D,FCBBUF
  3033.     CALL    CMDLINE        ; Parse name to CP/M format
  3034. ;
  3035. TNLP2:    CALL    MFNAM        ; Search for names (wildcard format)
  3036.     JC    NEXTNM
  3037.     MVI    C,FILSIZ
  3038.     LXI    D,FCB
  3039.     CALL    BDOS
  3040.     LHLD    FCB+33        ; Get number of records
  3041.     MOV    A,H
  3042.     ORA    L
  3043.     JZ    TNLP2        ; If no records, don't copy this file
  3044.     LDA    FCB+10        ; If CP/M 2 $sys file..
  3045.     ANI    80H        ; Do not send
  3046.     JNZ    TNLP2
  3047.     LHLD    NBSAVE        ; Get name
  3048.     LXI    D,FCB        ; Move it to FCB
  3049.     XCHG
  3050.     MVI    B,12
  3051.     CALL    MOVE
  3052.     XCHG
  3053.     SHLD    NBSAVE        ; Addressof next name
  3054.     LXI    H,FILECT    ; Count files found
  3055.     INR    M
  3056.     JMP    TNLP2
  3057. ;.....
  3058. ;
  3059. ;
  3060. NEXTNM:    LXI    H,NAMECT    ; Count names found
  3061.     DCR    M
  3062.     JNZ    TNLP1
  3063.     LXI    H,NAMEBUF    ; Save start of buffer
  3064.     SHLD    NBSAVE
  3065.  
  3066. ;~this limit is an antique.  allow up to FFh (256 files) by deleting
  3067. ; this routine
  3068. ;    LDA    FILECT
  3069. ;    CPI    64+1        ; No more than 64 transfers
  3070. ;    RC
  3071. ;    MVI    A,64        ; Only transfer first 64
  3072. ;    STA    FILECT
  3073.     RET
  3074. ;.....
  3075. ;
  3076. ;
  3077. ; Tells when buffer is opened/closed for memory save to write on disk
  3078. ;
  3079. BUFMS:    CALL    ILPRT
  3080.     DB    CR,LF,'** Memory buffer ',0
  3081.     LDA    SAVEFLG
  3082.     ORA    A
  3083.     JZ    BUFMS1
  3084.     CALL    ILPRT
  3085.     DB    'open **',CR,LF,LF,';',0
  3086.     RET
  3087. ;
  3088. BUFMS1:    CALL    ILPRT
  3089.     DB    'closed **',CR,LF,LF,0
  3090.     RET
  3091. ;
  3092. BUFMS2:    CALL    ILPRT
  3093.     DB    CR,LF,'** Memory buffer available **',CR,LF,0
  3094.     RET
  3095. ;.....
  3096. ;
  3097. ;
  3098. ; Checks to see if the modem has a character ready
  3099. ;
  3100. RCVRDY:    CALL    I$MDCTL1    ; Get the status register
  3101.     CALL    A$MDRCV        ; AND it with the receive ready flag
  3102.     JMP    C$MDRCV        ; Compare to see if it has a character
  3103. ;.....
  3104. ;
  3105. ;
  3106. ; Checks to see if the modem is ready to receive a character
  3107. ;
  3108. SNDRDY:    CALL    I$MDCTL1
  3109.     CALL    A$MDSND        ; Isolate the
  3110.     JMP    C$MDSND
  3111. ;.....
  3112. ;
  3113. ;
  3114. SNDNOW:    CALL    EXITTEST    ; See if want to quit now
  3115.     CALL    SNDRDY        ; Ready to send a character?
  3116.     JNZ    SNDNOW        ; If not ready wait some more
  3117.     RET            ; Exit if ready
  3118. ;.....
  3119. ;
  3120. ;
  3121. ; Checks to see if the modem TxE output buffer is empty
  3122. ;
  3123. SNDTXE:    CALL    I$MDTXE        ; Get the status register with TxE flag
  3124.     CALL    A$MDTXE        ; Isolate the TxE flag
  3125.     JMP    C$MDTXE        ; Compare to see if it is empty
  3126.  
  3127. ;.....
  3128. ;
  3129. ;
  3130. ; Send the log-on message when requested
  3131. ;
  3132. SNDLOG:    LHLD    LOGPTR        ; 'HL' points to start of logon message
  3133.     CALL    LOGLP
  3134.     JMP    TERML
  3135. ;...
  3136. ;
  3137. ;
  3138. LOGLP:    CALL    SNDNOW        ; Wait until modem is ready
  3139.     MOV    A,M        ; Get logon byte
  3140.     ORA    A        ; Last character in string is '0'
  3141.     RZ            ; Return if finished
  3142.     CALL    O$MDDATP    ; Otherwise send the character
  3143.     CALL    LOGLP1        ; Check for echo character and display it
  3144.     INX    H        ; Next location in message
  3145.     JMP    LOGLP        ; Get next character
  3146. ;.....
  3147. ;
  3148. ;
  3149. LOGLP1:    CALL    J$INMDM        ; Get the echo character
  3150.     RC            ; If no character don't try to print
  3151.     ANI    7FH        ; Strip off any parity
  3152.     JMP    TYPE        ; Display the character, then return
  3153. ;.....
  3154. ;
  3155. ;
  3156. ; Check for exit character
  3157. ;
  3158. EXITTEST:
  3159.     CALL    STAT        ; Anything on keyboard?
  3160.     RZ
  3161.     CALL    KEYIN        ; Get it, then
  3162.     MOV    B,A        ; Save to protect the 'A' reg.
  3163. ;
  3164. EXITTST1:
  3165.     LDA    EXITCHR        ; Exit character
  3166.     CMP    B        ; Asking to exit to menu?
  3167.     RNZ            ; If not, back to work
  3168.     POP    H        ; Clear the stack from 'CALL'
  3169.     CALL    CRLF
  3170.     JMP    MENU0
  3171. ;.....
  3172. ;
  3173. ;
  3174. LSTMS:    CALL    ILPRT
  3175.     DB    'Printer buffer is ',0
  3176.     LDA    LISTFLG        ; See if printer should be on or off
  3177.     ORA    A
  3178.     JZ    LSTMS1
  3179.     CALL    ILPRT
  3180.     DB    'ON',CR,LF,0
  3181.     RET
  3182. ;...
  3183. ;
  3184. ;
  3185. LSTMS1:    CALL    ILPRT
  3186.     DB    'OFF',CR,LF,0
  3187.     RET
  3188. ;.....
  3189. ;
  3190. ;
  3191. ; Special function key handler.  This routine is entered with the
  3192. ; function key number (0..9) in A.  The corresponding function key is
  3193. ; then transmitted.
  3194. ;
  3195. SNDFK:    PUSH    H        ; Save register
  3196.     LXI    H,FNCTBL    ; Point to function key codes
  3197.     DCR    A        ; Table is 1-0 rather than 0-9
  3198.     CPI    0FFH
  3199.     JNZ    SFK1
  3200.     MVI    A,9
  3201. ;
  3202. SFK1:    CMP    M        ; This the one?
  3203.     INX    H        ; Point to next byte
  3204.     JNZ    SFK1        ; Loop until found
  3205.     CALL    LOGLP        ; Send the character
  3206.     POP    H
  3207.     XRA    A        ; Reset the function flag
  3208.     STA    FNKFLG
  3209.     JMP    TERML
  3210. ;.....
  3211. ;
  3212. ;
  3213. ; Send keyboard character to modem, also to console if "E" or "L".  If
  3214. ; "E", include a LF after a CR, if either, include a LF if toggle is set.
  3215. ;
  3216. NTOG:    CALL    J$SNDCHR    ; Send char. in 'B' to modem
  3217.     LDA    LOCFLG        ; Using the local mode?
  3218.     ORA    A
  3219.     JNZ    LTYPE        ; If yes, show the character
  3220.     LDA    ECHOFLG        ; In echo mode?
  3221.     ORA    A
  3222.     JZ    TERML        ; If not, see if it was a 'CR'
  3223. ;
  3224. LTYPE:    MOV    A,B        ; Get the character back
  3225.     CALL    TYPE        ; Show on the local CRT
  3226.     CALL    CKSAV        ; To store local if buffer open
  3227.     CALL    CHKPRNT        ; Put on printer if running
  3228. ;
  3229. CHKCR:    MVI    A,CR
  3230.     CMP    B
  3231.     JNZ    TERML        ; If not CR, all done
  3232.     LDA    ECHOFLG        ; In echo mode now?
  3233.     ORA    A
  3234.     JNZ    CHKLF        ; If yes add a line feed
  3235.     LDA    ADDLFD        ; Going to add a line feed in 'L' mode?
  3236.     ORA    A
  3237.     JZ    TERM        ; If not, exit
  3238. ;
  3239. CHKLF:    MVI    B,LF
  3240.     JMP    NTOG        ; Send locally and to remote
  3241. ;.....
  3242. ;
  3243. ;
  3244. TERML:    CALL    RCVRDY        ; Character on the receive-ready line?
  3245.     JNZ    TERM        ; If not, exit
  3246.     CALL    I$MDDATP    ; Get the character
  3247.     ANI    7FH        ; Strip parity
  3248.     JZ    TERM        ; Don't bother with nulls
  3249.     CPI    RUB
  3250.     JZ    TERM        ; Don't bother with rubouts for fill
  3251.     MOV    B,A        ; Store temporarily
  3252.     LDA    IGNRCTL        ; Ignoring all but necessary CTL-chars?
  3253.     ORA    A
  3254.     JZ    GIVLF        ; If zero, display them all
  3255.     MOV    A,B
  3256.     CPI    ' '
  3257.     JNC    GIVLF        ; Display all printing characters
  3258.     CPI    'G'-40H        ; ^g for bell
  3259.     JC    TERM        ; Ignore ctl-characters less than ^g
  3260.     CPI    CR+1
  3261.     JNC    TERM        ; Ignore ctl-characters more than ^m
  3262. ;
  3263. GIVLF:    MOV    A,B        ; Get the character back
  3264.     CALL    TYPE        ; Show it on the CRT
  3265.     CALL    CKSAV        ; Saving for disk file?
  3266.     CALL    CHKPRNT        ; Printer running?
  3267.     LDA    ECHOFLG        ; Going to echo the character?
  3268.     ORA    A
  3269.     JZ    NOECH        ; If not, do not resend
  3270.     CALL    J$SNDCHR    ; Send char. in 'B' to modem
  3271. ;
  3272. NOECH:    MVI    A,CR
  3273.     CMP    B        ; Was it a 'CR' just now?
  3274.     JNZ    TERM        ; If not, all done so exit
  3275.     LDA    ECHOFLG        ; In the echo mode?
  3276.     ORA    A
  3277.     JZ    TERM
  3278.     CALL    SNDNOW        ; Modem ready for a character?
  3279.     MVI    B,LF
  3280.     JMP    GIVLF        ; Send lf
  3281. ;.....
  3282. ;
  3283. ;
  3284. ; See if putting character into memory for a disk file
  3285. ;
  3286. CKSAV:    LDA    SAVEFLG        ; Saving to disk?
  3287.     ORA    A
  3288.     RZ            ; If not, exit
  3289.     LHLD    HLSAV        ; Get last address
  3290.     MOV    M,B        ; Store this character
  3291.     INX    H        ; Increment for next character
  3292.     SHLD    HLSAV        ; Remember that location
  3293.     MVI    A,LF
  3294.     CMP    B        ; This character a line feed?
  3295.     JNZ    CKSAV1        ; Type ";" after each line feed..
  3296.     MVI    A,CR        ; Insure at left column with a lf
  3297.     CALL    TYPE
  3298.     CALL    TYPESCLN    ; Show a ';' on CRT
  3299. ;
  3300. CKSAV1:    MOV    A,H
  3301.     LXI    H,BUFTOP    ; Get the address at top of buffer
  3302.     CMP    H
  3303.     CZ    DCTLS        ; If different, buffer is not full
  3304.     RET
  3305. ;.....
  3306. ;
  3307. ;
  3308. ; Memory buffer is full, send a X-OFF (CTL-S, DC3), save any extra in-
  3309. ; coming characters, then dump to disk, reset buffer to include those
  3310. ; characters.
  3311. ;
  3312. DCTLS:    CALL    SNDNOW        ; Modem ready for a character?
  3313.     MVI    A,XOFF        ; Send a ctl-s to stop remote computer
  3314.     CALL    O$MDDATP
  3315.     CALL    CHKPRNT        ; Insure character gets to the printer
  3316.     LXI    H,BUFFDSK    ; Address of aux. buffer
  3317.     CALL    GTDSK        ; Put any extra chars. into aux. buffer
  3318.     PUSH    D        ; Save the number of aux. chars.
  3319.     MVI    A,1        ; Show we put something in the buffer..
  3320.     STA    WRFLG        ; To protect erasing an empty file
  3321.     LHLD    HLSAV        ; Find current end of buffer
  3322.     CALL    WRDSK1        ; Write the records
  3323.     POP    D        ; Get aux. char. count back
  3324.     LXI    H,BUFFER    ; Start again at bottom of buffer
  3325.     XRA    A        ; Set 'A' to zero
  3326.     CMP    D        ; See if any count in 'D'
  3327.     JZ    DCTLQ        ; If nothing, exit and continue
  3328.     LXI    B,BUFFDSK    ; Address of aux. buffer
  3329. ;
  3330. ;
  3331. ; Move the characters from the auxiliary buffer to the main buffer and
  3332. ; display
  3333. ;
  3334. DCTLS1:    LDAX    B        ; Get the character there
  3335.     MOV    M,A        ; Store in main buffer
  3336.     CALL    TYPE        ; Show on CRT
  3337.     PUSH    H
  3338.     PUSH    D
  3339.     PUSH    B
  3340.     PUSH    PSW
  3341.     MOV    B,A
  3342.     CALL    CHKPRNT
  3343.     POP    PSW        ; Get the character again
  3344.     POP    B
  3345.     POP    D
  3346.     POP    H
  3347.     CPI    LF
  3348.     CZ    TYPESCLN
  3349.     INX    H        ; Next buffer position
  3350.     INX    B        ; Next aux. buffer position
  3351.     DCR    D        ; One less to go
  3352.     JNZ    DCTLS1        ; If not zero, keep going
  3353.     MVI    B,0        ; Falls through to 'CHKPRNT' next
  3354. ;
  3355. DCTLQ:    SHLD    HLSAV        ; Next position to store in buffer
  3356.     CALL    SNDNOW
  3357.     MVI    A,XON        ; Allow remote input to continue
  3358.     JMP    O$MDDATP
  3359. ;.....
  3360. ;
  3361. ;
  3362. ; Gets any incoming characters after sending an XOFF and stores at HL.
  3363. ; Returns with number of characters stored in D-reg.
  3364. ;
  3365. GTDSK:    MVI    D,0        ; Character count in buffer
  3366.     MVI    E,128        ; Maximum for buffer length
  3367. ;
  3368. GTDSK1:    CALL    J$INMDM        ; Get any character
  3369.     RC            ; If none, finished
  3370.     CPI    ' '
  3371.     JNC    GTDSK2        ; If greater, handle normally
  3372.     CPI    CR+1        ; Ignore ctl-chars. > cr
  3373.     JNC    GTDSK1
  3374. ;
  3375. GTDSK2:    MOV    M,A        ; Store
  3376.     INX    H        ; Next buffer location to use
  3377.     INR    D        ; Increment character count
  3378.     DCR    E        ; Room for one less
  3379.     JNZ    GTDSK1        ; If room in buffer, keep going
  3380.     RET            ; If buffer is filled, exit
  3381. ;.....
  3382. ;
  3383. ;
  3384. ; See if printing the character, if yes, put into buffer
  3385. ;
  3386. CHKPRNT:LDA    LISTFLG        ; Printer in use?
  3387.     ORA    A
  3388.     RZ            ; Return if not
  3389.     LHLD    HLSAV1        ; Get input address
  3390.     MOV    M,B        ; Save this character there
  3391.     INX    H        ; Increment the buffer location
  3392.     SHLD    HLSAV1        ; Store for next character
  3393.     LDA    MAXRAM        ; See if at top of buffer yet
  3394.     CMP    H
  3395.     CZ    PCTLS        ; If different, buffer is not full
  3396.     RET
  3397. ;.....
  3398. ;
  3399. ;
  3400. ; Memory buffer is full, send a X-OFF (CTL-S, DC3), save any extra in-
  3401. ; coming characters, then dump to disk, reset buffer to include those
  3402. ; characters.
  3403. ;
  3404. PCTLS:    CALL    SNDNOW        ; Wait until modem is ready
  3405.     MVI    A,XOFF        ; Send a ctl-s to stop remote computer
  3406.     CALL    O$MDDATP
  3407.     LXI    H,BUFFPNT    ; Address of aux. buffer
  3408.     CALL    GTDSK        ; Put any extra chars. into aux. buffer
  3409.     MOV    A,D        ; Get the aux. buffer char. count
  3410.     STA    DSTORE        ; Save for later
  3411.     RET
  3412. ;.....
  3413. ;
  3414. ;
  3415. ; Output has now caught up to the input and both are at top of buffer
  3416. ;
  3417. PCTLS1:    LDA    DSTORE        ; Get the aux. buffer char. count
  3418.     MOV    D,A        ; Put into 'D' reg.
  3419.     XRA    A        ; Set 'A' to zero
  3420.     CMP    D        ; See if any count in 'D'
  3421.     LXI    H,PBUFF        ; Address at start of printer buffer
  3422.     JZ    PCTLQ        ; If nothing, exit and continue
  3423.     LXI    B,BUFFPNT    ; Address of aux. buffer
  3424. ;
  3425. ;
  3426. ; Move the characters from the auxiliary buffer to the main buffer and
  3427. ; display.
  3428. ;
  3429. PCTLS2:    LDAX    B        ; Get the character there
  3430.     MOV    M,A        ; Store in main buffer
  3431.     CALL    TYPE        ; Show on CRT
  3432.     PUSH    H
  3433.     PUSH    D
  3434.     PUSH    B
  3435.     PUSH    PSW
  3436.     MOV    B,A
  3437.     CALL    CKSAV
  3438.     POP    PSW
  3439.     POP    B
  3440.     POP    D
  3441.     POP    H
  3442.     CPI    LF
  3443.     CZ    TYPESCLN
  3444.     INX    H        ; Next buffer position
  3445.     INX    B        ; Next aux. buffer position
  3446.     DCR    D        ; One less to go
  3447.     JNZ    PCTLS2        ; If not zero, keep going
  3448. ;
  3449. PCTLQ:    SHLD    HLSAV1        ; Next position to store in buffer
  3450.     LXI    H,PBUFF        ; Start of buffer location
  3451.     SHLD    HLSAV2        ; Output to start of buffer
  3452.     CALL    SNDNOW        ; Wait until modem is ready
  3453.     MVI    A,XON        ; Send start character..
  3454.     JMP    O$MDDATP    ; To remote computer, back to work
  3455. ;.....
  3456. ;
  3457. ;
  3458. ; List the character on the printer if it is ready, then see if at the
  3459. ; top of the buffer.
  3460. ;
  3461. GOLIST:    CALL    $-$        ; Get the printer status - filled in..
  3462.     ORA    A        ; By 'INITADR' routine
  3463.     RZ            ; Return if printer not ready
  3464. ;
  3465. ;
  3466. ; Compare input and output pointers.  If at same address, nothing to
  3467. ; print.
  3468. ;
  3469.     CALL    CMP$I$O        ; If the same, nothing to print
  3470.     RZ
  3471. ;
  3472. ;
  3473. ; If not the same, print the character
  3474. ;
  3475.     PUSH    H        ; Save current buffer address
  3476.     MOV    E,M        ; Get the character to display
  3477.     MVI    C,LIST        ; List rutine
  3478.     CALL    BDOS
  3479.     POP    H        ; Restore current buffer address
  3480.     INX    H        ; Increment pointer for next position
  3481.     SHLD    HLSAV2        ; Store for next time through here
  3482. ;
  3483. ;
  3484. ; See if the output is at the end of the buffer now.  If yes, go put
  3485. ; the auxiliary characters into the start of the buffer.
  3486. ;
  3487.     LDA    MAXRAM        ; Check for end of buffer area
  3488.     CMP    H
  3489.     JZ    PCTLS1        ; If at end, restore aux. buffer
  3490. ;
  3491. ;
  3492. ; See if the output has caught up with the input - if so, reset the
  3493. ; pointers to the start of the buffer
  3494. ;
  3495.     CALL    CMP$I$O
  3496.     RNZ            ; If not, back to work
  3497.     LXI    H,PBUFF        ; If output caught input, reset both..
  3498.     SHLD    HLSAV1        ; To bottom of buffer to start over
  3499.     SHLD    HLSAV2
  3500.     RET
  3501. ;.....
  3502. ;
  3503. ;
  3504. ; Compare the input and output pointers to see if the same address
  3505. ;
  3506. CMP$I$O:LHLD    HLSAV1        ; Get input pointer address
  3507.     XCHG            ; Put in 'DE'
  3508.     LHLD    HLSAV2        ; Get output pointer address
  3509.     MOV    A,H
  3510.     CMP    D
  3511.     RNZ            ; Return if different
  3512.     MOV    A,L
  3513.     CMP    E
  3514.     RET
  3515. ;.....
  3516. ;
  3517. ;
  3518. GTMAX:    LDA    BDOS+2        ; 'MSP' of 'BDOS' address
  3519.     SBI    8        ; 'CCP' is 2k or 8 pages
  3520.     STA    MAXRAM        ; Save
  3521.     RET
  3522. ;.....
  3523. ;
  3524. ;
  3525. ; This subroutine will loop until the modem receives a character or 100
  3526. ; milliseconds.  It returns with a character in 'A' reg. but if no char-
  3527. ; acter was recieved it returns after a timeout with carry set.
  3528. ;
  3529. INMDM:    PUSH    H
  3530.     LXI    H,63        ; About 100 milliseconds
  3531.     CALL    FIXCNT
  3532.     MOV    B,H        ; Delay is in 'HL'
  3533.     MOV    C,L        ; Transfer to 'BC'
  3534.     POP    H        ; Get original value of 'HL' back
  3535. ;
  3536. INMDM1:    CALL    RCVRDY        ; See if there is a character ready
  3537.     JNZ    INMDM2        ; If no character, exit
  3538.     CALL    I$MDDATP    ; Get the character
  3539.     ANI    7FH        ; Strip off any parity
  3540.     RET            ; Return with character in 'A' reg.
  3541. ;
  3542. INMDM2:    DCX    B        ; Otherwise keep timing
  3543.     MOV    A,B
  3544.     ORA    C
  3545.     JNZ    INMDM1        ; Loop until timeout if needed
  3546.     STC            ; Shows a timeout occured
  3547.     RET
  3548. ;.....
  3549. ;
  3550. ;
  3551. ;=======================================================================
  3552. ;             WRITE BUFFER TO DISK
  3553. ;
  3554. ; Make sure this record is included in the count.
  3555. ;
  3556. WRDSK:    LHLD    HLSAV
  3557.     MVI    M,EOFCHAR    ; Ascii file, store end-of-file char.
  3558.     LXI    D,127
  3559.     DAD    D
  3560. ;
  3561. WRDSK1:    LXI    D,-(BUFFER)    ; Subtract the start of the buffer..
  3562.     DAD    D        ; By adding a minus number to buffer end
  3563.     MOV    A,L        ; Divide hl by 128..
  3564.     ORA    A
  3565.     RAL            ; To get the..
  3566.     MOV    L,H        ; Number of records
  3567.     MVI    H,0
  3568.     PUSH    PSW
  3569.     DAD    H
  3570.     POP    PSW
  3571.     MVI    A,0
  3572.     ADC    L
  3573.     MOV    L,A        ; Number of records in 'HL'
  3574. ;
  3575. ;
  3576. ; See if buffer is empty.  If yes, see if we need to erase an empty
  3577. ; file or have already written something.
  3578. ;
  3579.     LXI    D,BUFFER
  3580.     LDAX    D
  3581.     CPI    EOFCHAR        ; 'EOF' in first address means..
  3582.     JNZ    WRDSK2        ; Nothing in buffer to write
  3583.     LDA    WRFLG        ; First time by this way?
  3584.     ORA    A
  3585.     JZ    NOWRITE        ; If yes, show erasing file
  3586.     RET            ; Otherwise go close file
  3587. ;.....
  3588. ;
  3589. ;
  3590. ; Write to disk.  Start from BUFFER (in 'DE').    Number of records to
  3591. ; write in 'HL'.
  3592. ;
  3593. WRDSK2:    MVI    C,STDMA
  3594.     CALL    BDOSRT
  3595.     PUSH    D
  3596.     MVI    C,WRITE
  3597.     LXI    D,FCB3        ; Location of filename to write to
  3598.     CALL    BDOSRT
  3599.     POP    D
  3600.     ORA    A
  3601.     JNZ    WRERRSP        ; Error if disk is full ** special patch
  3602.     XCHG            ; Put the current address in 'HL'..
  3603.     PUSH    D        ; And number of records left in..
  3604.     LXI    D,128        ; For now
  3605.     DAD    D        ; Add for next record write, now in 'HL'
  3606.     POP    D        ; Restore number of records left
  3607.     XCHG            ; Records to 'HL' again, address to 'DE'
  3608.     DCX    H        ; One less record left
  3609.     MOV    A,H
  3610.     ORA    L        ; Done writing when 'H' and 'H' both zero
  3611.     JNZ    WRDSK2        ; Otherwise do another disk write
  3612.     RET
  3613. ;.....
  3614. ;
  3615. ;
  3616. ; Error while writing a record, show why it is aborting
  3617. ;
  3618. WRERR:    CALL    CLOSFIL        ; Close the current file
  3619.     MVI    C,CANCEL    ; Send cancel char. to sending station
  3620.     CALL    SEND        ; First cancel character
  3621.     CALL    SEND        ; Second cancel character
  3622.     CALL    SEND        ; Third, to help them cancel too
  3623. ;
  3624. WRERR1:    CALL    ERXIT        ; Also will reset stack
  3625.     DB    '++ DISK FULL, SAVING PARTIAL FILE ++','$'
  3626. ;.....
  3627. ;
  3628. ;
  3629. ; Patch to close FCB3 instead of FCB when in disk-capture mode.
  3630. ;
  3631. WRERRSP:CALL    WRFIL2        ; Close FCB3 file
  3632.     JMP    WRERR1        ; Go write 'DISK FULL' message and quit
  3633. ;.....
  3634. ;
  3635. ;
  3636. ; If no data to store on the disk, close the empty file and erase it
  3637. ;
  3638. NOWRITE:CALL    WRFIL2        ; Close the empty file
  3639.     CALL    NOASK        ; Erase the empty file
  3640.     CALL    ILPRT
  3641.     DB    CR,LF,'++ Nothing to save, erasing file ++'
  3642.     DB    CR,LF,BELL,0
  3643.     LDA    DONEFLG        ; Is the exit flag set?
  3644.     ORA    A
  3645.     JNZ    EXIT2        ; If yes, all done now
  3646.     MVI    A,1        ; Set the flag
  3647.     STA    ABORTFLG    ; Insures returning to command mode
  3648.     JMP    DONETA        ; Reset any flags, return to menu
  3649. ;.....
  3650. ;
  3651. ;
  3652. ; Show you are in memory-save for disk write
  3653. ;
  3654. TYPESCLN:
  3655.     MVI    A,';'
  3656.     JMP    TYPE        ; Show on CRT, return
  3657. ;.....
  3658. ;
  3659. ;
  3660. ; Save the registers, call BDOS then restore the registers
  3661. ;
  3662. BDOSRT:    PUSH    B
  3663.     PUSH    D
  3664.     PUSH    H
  3665.     CALL    BDOS
  3666.     POP    H
  3667.     POP    D
  3668.     POP    B
  3669.     RET
  3670. ;.....
  3671. ;
  3672. ;
  3673. INITFCB:MVI    M,0        ; Zeroes the drive to the 'A' drive
  3674. ;
  3675. INITFCB1:            ; Does not alter disk drive
  3676.     INX    H
  3677.     MVI    B,11        ; Spaces out filename area
  3678. ;
  3679. LOOP11:    MVI    M,' '
  3680.     INX    H
  3681.     DCR    B
  3682.     JNZ    LOOP11        ; Nulls out the data area with zeroes
  3683.     MVI    B,21
  3684. ;
  3685. LOOP21:    MVI    M,0
  3686.     INX    H
  3687.     DCR    B
  3688.     JNZ    LOOP21
  3689.     RET
  3690. ;.....
  3691. ;
  3692. ;
  3693. ; Scans CMDBUF counting names and putting delimiter (space) after last
  3694. ; name
  3695. ;
  3696. SCAN:    PUSH    H
  3697.     LXI    H,NAMECT
  3698.     MVI    M,0
  3699.     LXI    H,CMDBUF+1    ; Find end of cmd line..
  3700.     MOV    C,M        ; And put space there.
  3701.     MVI    B,0
  3702.     LXI    H,CMDBUF+2
  3703.     DAD    B
  3704.     MVI    M,' '
  3705.     LXI    H,CMDBUF+1
  3706.     MOV    B,M
  3707.     INR    B
  3708.     INR    B
  3709. ;
  3710. SCANL1:    INX    H
  3711.     DCR    B
  3712.     JZ    DNSCAN
  3713.     MOV    A,M
  3714.     CPI    ' '
  3715.     JNZ    SCANL1
  3716. ;
  3717. SCANL2:    INX    H        ; Eat extra spaces
  3718.     DCR    B
  3719.     JZ    DNSCAN
  3720.     MOV    A,M
  3721.     CPI    ' '
  3722.     JZ    SCANL2
  3723.     SHLD    BGNMS        ; Save start of names in cmdbuf
  3724.     INR    B
  3725.     DCX    H
  3726. ;
  3727. SCANL3:    INX    H
  3728.     DCR    B
  3729.     JZ    DNSCAN
  3730.     MOV    A,M
  3731.     CPI    ' '
  3732.     JNZ    SCANL3
  3733.     LDA    NAMECT        ; Counts names
  3734.     INR    A
  3735.     STA    NAMECT
  3736. ;
  3737. SCANL4:    INX    H        ; Eat spaces
  3738.     DCR    B
  3739.     JZ    DNSCAN
  3740.     MOV    A,M
  3741.     CPI    ' '
  3742.     JZ    SCANL4
  3743.     JMP    SCANL3
  3744. ;.....
  3745. ;
  3746. ;
  3747. DNSCAN:    MVI    M,' '        ; Space after last char
  3748.     POP    H
  3749.     RET
  3750. ;.....
  3751. ;
  3752. ;
  3753. ; Places next name in buffer so 'CMDLINE' may parse it
  3754. ;
  3755. TRTOBUF:LHLD    BGNMS
  3756.     MVI    B,0
  3757.     LXI    D,FCBBUF+2
  3758. ;
  3759. TBLP:    MOV    A,M
  3760.     CPI    ' '
  3761.     JZ    TRBFEND
  3762.     STAX    D
  3763.     INX    H
  3764.     INX    D
  3765.     INR    B        ; Count chars in name
  3766.     JMP    TBLP
  3767. ;.....
  3768. ;
  3769. ;
  3770. TRBFEND:INX    H
  3771.     MOV    A,M        ; Eat extra spaces
  3772.     CPI    ' '
  3773.     JZ    TRBFEND
  3774.     SHLD    BGNMS
  3775.     LXI    H,FCBBUF+1    ; Put # chars before name
  3776.     MOV    M,B
  3777.     RET
  3778. ;.....
  3779. ;
  3780. ;
  3781. CKCPM2:    MVI    C,CPMVER    ; Bdos 12 -- version number -- cp/m 2.2?
  3782.     CALL    BDOS
  3783.     ORA    A
  3784.     RZ
  3785.     MVI    C,STDMA
  3786.     LXI    D,TBUF
  3787.     CALL    BDOS
  3788.     MVI    C,SRCHF
  3789.     LXI    D,FCB
  3790.     CALL    BDOS
  3791.     CPI    0FFH
  3792.     RZ
  3793. ;
  3794.     CALL    GETADD
  3795.     LXI    D,9
  3796.     DAD    D        ; Point to R/O attribute byte
  3797.     MOV    A,M
  3798.     ANI    80H        ; Test most significant byte
  3799.     JNZ    MKCHG        ; If set, make change
  3800.     INX    H        ; Check system attribute byte
  3801.     MOV    A,M
  3802.     ANI    80H
  3803.     RZ            ; Not $SYS or $R/O attribute
  3804.     DCX    H
  3805. ;
  3806. MKCHG:    LXI    D,-8
  3807.     DAD    D        ; Point HL to filename + 1
  3808.     LXI    D,FCB+1        ; Move directory name to FCB..
  3809.     MVI    B,11        ; Without changing drive.
  3810.     CALL    MOVE
  3811.     LXI    H,FCB+9        ; R/O attribute
  3812.     MOV    A,M
  3813.     ANI    7FH        ; Strip R/O attribute
  3814.     MOV    M,A
  3815.     INX    H        ; System attribute
  3816.     MOV    A,M
  3817.     ANI    7FH
  3818.     MOV    M,A
  3819.     LXI    D,FCB
  3820.     MVI    C,30        ; Set new attributes in directory
  3821.     CALL    BDOS
  3822.     LXI    H,FCB        ; Change name to type "BAK"
  3823.     LXI    D,FCB2
  3824.     MVI    B,9        ; Move drive and name (not type)
  3825.     CALL    MOVE
  3826.     LXI    H,75H        ; Start of type in FCB2
  3827.     MVI    M,'B'
  3828.     INX    H
  3829.     MVI    M,'A'
  3830.     INX    H
  3831.     MVI    M,'K'
  3832.     LXI    D,FCB2
  3833.     MVI    C,ERASE        ; Erase any previous backups
  3834.     CALL    BDOS
  3835.     LXI    H,FCB2        ; FCB2 drive field should..
  3836.     MVI    M,0        ; 0 for rename.
  3837.     LXI    D,FCB
  3838.     MVI    C,23        ; Rename
  3839.     JMP    BDOS
  3840. ;.....
  3841. ;
  3842. ;
  3843. ;***********************************************************************
  3844. ;
  3845. ;        RECEIVE A RECORD FROM SENDING STATION
  3846. ;
  3847. ;***********************************************************************
  3848. ;
  3849. ; If CRC is in effect, there is a 10-second timeout to the first SOH.
  3850. ; It then tries six more times to let the sender know the system is
  3851. ; capable of receiving a 'CRC' check.  At the end of that time a NAK is
  3852. ; sent which tells the sender to use CHECKSUM checking instead of CRC.
  3853. ; This allows automatic compatability with systems implementing CRC -
  3854. ; (Cyclic Redundancy Checking).  The search for SOH will cycle through
  3855. ; one record interval and ignore noise or characters sent by the remote
  3856. ; for any purpose (such as progress reporting).  So extraneous characters
  3857. ; that are sometimes sent by remote-end protocol will be gobbled up until
  3858. ; the first SOH.  EOT is tested only as the first returned character af-
  3859. ; ter each sector.
  3860. ;
  3861. SRCHSOH    EQU    160        ; Number of times to loop search for SOH
  3862. ;
  3863. RCVRECD:MVI    A,1
  3864.     STA    ERRCT        ; Initialize the error count
  3865. ;
  3866. RCVSQ:    CALL    CKABORT        ; Want to quit now?
  3867.     MVI    B,10-1        ; 10 seconds allowed to receive 1st char.
  3868.     LXI    D,SRCHSOH    ; Initialize loop for up to 160 secs.
  3869.     CALL    RECV        ; Get the 1st character
  3870.     JC    RCVSTOT        ; Timeout error if not rcvd in 10 seconds
  3871.     MOV    C,A        ; Save the character for now
  3872.     CPI    EOT        ; See if end of transmission
  3873.     STC            ; Set carry
  3874.     RZ            ; Return with carry set
  3875. ;
  3876. SOHLUP:    MVI    A,0FFH
  3877.     STA    CHRFLG
  3878.     STA    TIMFLG
  3879.     MOV    A,E        ; Get search count-down value
  3880.     CPI    SRCHSOH        ; See if it is the 1st returned character
  3881.     MOV    A,C        ; Get the first character now
  3882.     JZ    NORECV        ; Skip RECV routine if 1st character
  3883.     MVI    B,1
  3884.     CALL    RECV
  3885.     MOV    B,A        ; Store the character again, for a bit
  3886.     JNC    TSTSOH
  3887. ;
  3888. NORECV:    MOV    B,A
  3889.     XRA    A        ; Else set the value that forces timeout
  3890.     STA    CHRFLG
  3891. ;
  3892. TSTSOH:    XRA    A
  3893.     STA    TIMFLG
  3894.     MOV    A,B        ; Get the character back
  3895. ;
  3896.     CPI    SOH        ; See if it is SOH
  3897.     JZ    RCVSOH        ; Got SOH, get rcd # and its complement
  3898.     CPI    STX        ; See if it is STX for 1k blocks
  3899.     JZ    RCVSTX        ; Got STR, get rec # and its complement
  3900.     CPI    CANCEL
  3901.     CZ    CKCAN        ; Check to see if 1st or 2nd one
  3902. ;
  3903.     MOV    A,D
  3904.     ORA    E        ; See if counted-down to zero
  3905.     DCX    D
  3906.     JNZ    SOHLUP        ; Go around again if not
  3907. ;
  3908.     LDA    CHRFLG        ; See if timeout needs to be forced
  3909.     ORA    A
  3910.     JZ    RCVSTOT        ; Go do timeout and count them
  3911. ;
  3912.     LDA    QFLG
  3913.     ORA    A
  3914.     JZ    RCVSR
  3915. ;
  3916.     CALL    CRLF
  3917.     MOV    A,B        ; Get the character back
  3918.     CALL    HEXO        ; And display it
  3919.     CALL    ILPRT
  3920.     DB    'H received not SOH - ',0
  3921. ;
  3922. RCVPRN:    CALL    SHOWERR        ; Display error count
  3923. ;
  3924. RCVSR:    CALL    WAITQ1        ; Clear any characters from the input
  3925.     CALL    CKABORT        ; Want to stop receiving now?
  3926.     LDA    FRSTIM        ; Get first time switch
  3927.     ORA    A        ; Has first 'SOH' been received?
  3928.     MVI    A,NAK        ; Put 'NAK' in 'A' reg.
  3929.     JNZ    RCVSR1        ; Yes, then send 'NAK'
  3930. ;
  3931.     LDA    CRCFLG        ; Get 'CRC' flag
  3932.     ORA    A        ; 'CRC' in effect?
  3933.     MVI    A,NAK        ; Put 'NAK' in 'A' reg.
  3934.     JZ    RCVSR1        ; No, send the 'NAK'
  3935. ;
  3936.     MVI    A,CRC        ; Else tell sender 'CRC' is in effect
  3937.     CALL    SEND
  3938.     LDA    KFLG        ; Capable of 1k blocks?
  3939.     ORA    A
  3940.     JZ    RCVSR1        ; If yes, start with 1k request
  3941.     MVI    A,KSND        ; Tell sender we can use 1k blocks
  3942. ;
  3943. RCVSR1:    CALL    SEND        ; The 'NAK' or 'CRC' request
  3944.     LDA    ERRCT        ; Abort if we have reached error limit
  3945.     INR    A
  3946.     STA    ERRCT        ; Store for next time
  3947.     CPI    ERRLIM        ; See if at limit yet
  3948.     JC    RCVSQ        ; If not, keep going
  3949.     JMP    ABORT
  3950. ;.....
  3951. ;
  3952. ;
  3953. ; Aborts with 1 CTL-X if first time flage is not set, two otherwise
  3954. ;
  3955. CKCAN:    LDA    FRSTIM        ; First time through?
  3956.     ORA    A
  3957.     JZ    CKCAN1        ; If first time, abort and close file
  3958.     MVI    B,2        ; Maximum of 2 seconds for extra CTL-X
  3959.     CALL    RECV
  3960.     RC            ; No additional character, ignore CTL-X
  3961.     CPI    CANCEL        ; If a 2nd CTL-X, wait for 3rd
  3962.     RNZ            ; If not CTL-X, ignore
  3963.     MVI    B,2        ; Maximum of 2 seconds for extra CTL-X
  3964.     CALL    RECV
  3965.     RC            ; No additional character, ignore CTL-X
  3966.     CPI    CANCEL        ; If a 3rd CTL-X, abort and close file
  3967.     RNZ            ; If not CTL-X, ignore
  3968. ;
  3969. CKCAN1:    POP    H        ; Reset stack for  CALL  CKCAN
  3970.     JMP    ABORT        ; Go abort
  3971. ;.....
  3972. ;
  3973. ;
  3974. ; Abort and cancel any partially received file
  3975. ;
  3976. RCVSABT:LXI    SP,STACK    ; Reset the stack just in case
  3977.     CALL    CLOSFIL        ; Close the partial file
  3978.     CALL    NOASK        ; Delete partial file
  3979.     CALL    ILPRT
  3980.     DB    CR,LF,LF
  3981.     DB    '++ RECEIVED FILE CANCELLED ++',CR,LF,BELL
  3982.     DB    '++ UNFINISHED FILE DELETED ++',CR,LF,0
  3983.     JMP    DONETA
  3984. ;.....
  3985. ;
  3986. ;
  3987. RCVSTOT:LDA    QFLG        ; Quiet flag in use?
  3988.     ORA    A
  3989.     JZ    RCVSCC        ; If yes, don't show message
  3990.     LDA    FRSTIM        ; If first time, do not show as error
  3991.     ORA    A
  3992.     JZ    RCVSCC
  3993.     CALL    ILPRT
  3994.     DB    '++ Timeout ',0
  3995.     CALL    SHOWERR
  3996. ;
  3997. RCVSCC:    CALL    RCVSCC2
  3998.     JMP    RCVSR
  3999. ;.....
  4000. ;
  4001. ;
  4002. ; Routine will switch from 'CRC' to Checksum if 'ERCNT' reaches 'ERRCRC'
  4003. ; and 'FIRSTIME' is false
  4004. ;
  4005. RCVSCC2:LDA    FRSTIM        ; First time flag set yet?
  4006.     ORA    A
  4007.     RNZ            ; If yes, already underway so exit
  4008. ;
  4009.     LDA    ERRCT
  4010.     CPI    ERRCRC        ; Up to enough errors to go to checksum?
  4011.     RNZ            ; If not, exit
  4012.     LDA    CRCFLG        ; See if checksum already in use
  4013.     ORA    A
  4014.     RZ            ; If yes, exit
  4015.     XRA    A        ; Else set flags for checksum
  4016.     STA    CRCFLG
  4017.     STA    CRCDFLT
  4018.     CALL    ILPRTQ
  4019.     DB    CR,LF,'** Switching to Checksum mode **',CR,BELL,LF,0
  4020.     RET
  4021. ;.....
  4022. ;
  4023. ;
  4024. ; Got STX - set the KFLG for 1k blocks
  4025. ;
  4026. RCVSTX:    STA    KFLG        ; Set flag for 1k blocks
  4027.     JMP    RCVS1
  4028. ;
  4029. ;
  4030. ; Got SOH - get block #, block # complemented
  4031. ;
  4032. RCVSOH:    XRA    A        ; Clear 1k block flag, will be using 128
  4033.     STA    KFLG
  4034. ;
  4035. RCVS1:    MVI    B,5        ; Timeout = 5 seconds
  4036.     MOV    A,B        ; Get something to store
  4037.     STA    FRSTIM        ; Indicate first 'SOH' received
  4038.     CALL    RECV        ; Get record
  4039.     JC    RCVSTOT        ; Got a timeout
  4040.     MOV    D,A        ; Save the record number for now
  4041.     MVI    B,5        ; Timeout = 5 seconds
  4042.     CALL    RECV        ; Get complemented record number
  4043.     JC    RCVSTOT        ; Got a timeout
  4044.     CMA            ; "Uncomplement" to get original value
  4045.     CMP    D        ; Compare with first bytee
  4046.     JZ    RCVDATA        ; If both the same, received ok
  4047. ;
  4048.     LDA    QFLG        ; See if in quiet mode
  4049.     ORA    A
  4050.     JZ    RCVSR        ; If yes just add up the error
  4051.     CALL    ILPRT        ; Else show bad header received
  4052.     DB    CR,LF,'++ Bad record # in header ',0
  4053.     JMP    RCVPRN
  4054. ;...
  4055. ;
  4056. ;
  4057. ; Got a good header, save the record number, inirialize cheksum and CRC
  4058. ;
  4059. RCVDATA:MOV    A,D        ; Get the record number again
  4060.     STA    RCVCNT        ; Save it
  4061.     MVI    A,1        ; Insures only data displayed visually
  4062.     STA    DATAFLG
  4063.     MVI    C,0        ; Clear the checksum value
  4064.     LXI    H,0        ; Clear the CRC value
  4065.     SHLD    CRCVAL
  4066. ;
  4067. ;
  4068. ; Copy either 128 or 1024 characters into the buffer starting at address
  4069. ; pointed to by RCVPTR.
  4070. ;
  4071.     LXI    D,128        ; For 128 character blocks
  4072.     LDA    KFLG        ; Using 1k blocks?
  4073.     ORA    A
  4074.     JZ    $+6        ; If not, skip next line
  4075.     LXI    D,1024        ; If using 1k blocks
  4076.     LHLD    RECPTR        ; Get buffer address
  4077. ;
  4078. RCVCHR:    MVI    B,5        ; Wait up to 5 seconds for a character
  4079.     CALL    RECV
  4080.     JC    RCVSTOT        ; Got a timeout
  4081.     MOV    M,A        ; Store the character in buffer
  4082.     INX    H        ; Next buffer address
  4083.     DCX    D        ; One less to go
  4084.     MOV    A,D        ; See if 'D' and 'E' are both zero
  4085.     ORA    E
  4086.     JNZ    RCVCHR        ; If not, room for another character
  4087.     XRA    A
  4088.     STA    DATAFLG
  4089.     LDA    CRCFLG        ; Sending CRC?
  4090.     ORA    A
  4091.     JNZ    RCVCR        ; If yes get the CRC bytes
  4092. ;
  4093. ;
  4094. ; Verify checksum
  4095. ;
  4096.     MOV    D,C        ; Otherwise put the checksum in 'D'
  4097.     MVI    B,5        ; Wait up to 5 seconds for an answer
  4098.     CALL    RECV        ; Get the checksum value
  4099.     JC    RCVSTOT        ; Exit if nothing
  4100.     CMP    D        ; Compare sender's checksum with ours
  4101.     JNZ    RCVCER        ; Show an error if not ok
  4102. ;
  4103. ;
  4104. ; Got a record, it's a duplicate if equal to the previous number, it's
  4105. ; OK if previous + 1 record
  4106. ;
  4107. CHKSNUM:LDA    RCVCNT        ; Get received record number
  4108.     MOV    B,A        ; Save it
  4109.     LDA    RCDCNT        ; Get previous record number
  4110.     CMP    B        ; Rrevious record repeated?
  4111.     JZ    RCVACK        ; If yes 'ACK' to catch up
  4112.     INR    A        ; Increment by 1 for 120 character block
  4113.     CMP    B        ; Match this one we just got?
  4114.     JNZ    ABORT        ; No match, stop the sender, exit
  4115.     RET            ; Else return with carry not set, was ok
  4116. ;.....
  4117. ;
  4118. ;
  4119. ; Get the CRC bytes
  4120. ;
  4121. RCVCR:    MVI    E,2        ; Number of 'CRC' bytes
  4122. ;
  4123. RCVCR2:    MVI    B,5        ; Wait up to 5 seconds for a character
  4124.     CALL    RECV
  4125.     JC    RCVSTOT
  4126.     DCR    E        ; Started out with 2 characters needed
  4127.     JNZ    RCVCR2        ; If not zero, need 1 more yet
  4128.     CALL    CRCCHK        ; Check incoming two against our two
  4129.     ORA    A
  4130.     JZ    CHKSNUM        ; If ok, exit
  4131. ;
  4132.     LDA    QFLG        ; Else show an error
  4133.     ORA    A
  4134.     JZ    RCVSR
  4135.     CALL    ILPRT
  4136.     DB    '++ CRC error ',0
  4137.     JMP    RCVPRN
  4138. ;.....
  4139. ;
  4140. ;
  4141. RCVCER:    LDA    QFLG
  4142.     ORA    A
  4143.     JZ    RCVSR
  4144.     CALL    ILPRT
  4145.     DB    '++ checksum error ',0
  4146.     JMP    RCVPRN
  4147. ;.....
  4148. ;
  4149. ;
  4150. RCVACK:    CALL    SNDACK
  4151.     JMP    RCVRECD
  4152. ;.....
  4153. ;
  4154. ;
  4155. ; Get the error count and display on CRT
  4156. ;
  4157. SHOWERR:PUSH    H
  4158.     LHLD    ERRCT
  4159.     MVI    H,0
  4160.     CALL    DECOUT
  4161.     POP    H
  4162.     CALL    ILPRT
  4163.     DB    ' ++',CR,LF,0
  4164.     LDA    ERRCT
  4165.     CPI    ERRLIM
  4166.     JNC    ABORT
  4167.     RET
  4168. ;.....
  4169. ;
  4170. ;
  4171. ; Send SOH (or STX), record number and complemented record number.  Put
  4172. ; the display after the first character to add any delay at that point.
  4173. ;
  4174. SNDHDR:    LDA    KFLG        ; Sending 1k blocks?
  4175.     ORA    A
  4176.     MVI    A,STX        ; If yes, send a 'STX' rather than 'SOH'
  4177.     JNZ    $+5
  4178.     MVI    A,SOH        ; Send 'SOH' character to the output
  4179.     CALL    SEND
  4180.     LDA    QFLG
  4181.     ORA    A
  4182.     JZ    SNDHNM
  4183.     CALL    ILPRT
  4184.     DB    CR,'Sending: # ',0
  4185.     PUSH    H        ; Store current address
  4186.     LHLD    RECNO        ; Get record number
  4187.     CALL    DECOUT        ; Print it in decimal
  4188.     CALL    ILPRT
  4189.     DB    ' ',0        ; Just spaces the cursor one extra
  4190.     POP    H        ; Restore current address
  4191. ;
  4192. SNDHNM:    LDA    RCDCNT        ; Send the current transmission number
  4193.     CALL    SEND
  4194.     LDA    RCDCNT
  4195.     CMA            ; Complement the transmission number
  4196.     JMP    SEND        ; Send this value to the output
  4197. ;.....
  4198. ;
  4199. ;
  4200. SNDREC:    MVI    A,1        ; Used for video display while sending
  4201.     STA    DATAFLG
  4202.     MVI    C,0
  4203.     LXI    H,0        ; New record, clear 'CHECKSUM' value
  4204.     SHLD    CRCVAL        ; New record, clear 'CRC' value
  4205.     LDA    KFLG        ; Sending 1k blocks?
  4206.     ORA    A
  4207.     LXI    D,1024        ; For 1k blocks
  4208.     JNZ    $+6        ; If yes, skip next line
  4209.     LXI    D,128        ; For 128 character blocks
  4210.     LHLD    RECPTR        ; Find buffer location for storage
  4211. ;
  4212. SENDC:    MOV    A,M        ; Get character from buffer
  4213.     CALL    SEND        ; Send to modem
  4214.     INX    H        ; Next character locatiuon
  4215.     DCX    D        ; One less to go
  4216.     MOV    A,E        ; Compare 'E' with 'D'
  4217.     ORA    D        ; Are both zero yet?
  4218.     JNZ    SENDC        ; If not, go do another
  4219.     XRA    A        ; Else finished
  4220.     STA    DATAFLG        ; Used for video display while sending
  4221.     RET
  4222. ;.....
  4223. ;
  4224. ;
  4225. ; Send the checksum or CRC bytes
  4226. ;
  4227. SNDCHK:    LDA    CRCFLG        ; Check if using CRC or checksum
  4228.     ORA    A
  4229.     JNZ    SNDCRC        ; Exit and send CRC bytes
  4230. ;...
  4231. ;
  4232. ;
  4233. ; Send the checksum
  4234. ;
  4235. SNDCKS:    MOV    A,C        ; Get the checksum value
  4236.     JMP    SEND        ; Send to modem
  4237. ;.....
  4238. ;
  4239. ;
  4240. ; Send the two CRC (Cyclic Redundancy Check) characters
  4241. ;
  4242. SNDCRC:    PUSH    H
  4243.     LHLD    CRCVAL        ; Get the two CRC bytes
  4244.     MOV    A,H
  4245.     CALL    SEND        ; Send the first
  4246.     MOV    A,L
  4247.     CALL    SEND        ; Send the second
  4248.     POP    H
  4249.     XRA    A        ; Reset the carry bit
  4250.     RET
  4251. ;.....
  4252. ;
  4253. ;
  4254. ; After a record has been sent, and accepted, move the pointers forward
  4255. ; 128 or 1024 characters for the next record.
  4256. ;
  4257. SETPTR:    LXI    D,128        ; For 128 character blocks
  4258.     LDA    KFLG        ; See if using 1k blocks
  4259.     ORA    A
  4260.     JZ    $+6        ; If not, skip next line
  4261.     LXI    D,1024        ; Else set for 1024 character blocks
  4262.     LHLD    RECPTR        ; Get the buffer pointer
  4263.     DAD    D        ; Increment for the record just sent
  4264.     SHLD    RECPTR        ; New buffer address for next block
  4265.     RET
  4266. ;.....
  4267. ;
  4268. ;
  4269. ; After a record is sent, a character is returned telling if it was re-
  4270. ; ceived properly or not.  An ACK allows the next record to be sent.  A
  4271. ; NAK causes the current record to be resent.  If no character (or any
  4272. ; character other than ACK or NAK) is received after a short wait (10
  4273. ; to 12 seconds), a timeout error message is shown and the record will
  4274. ; be resent.  The GTACK routine can gobble up a string of up to 191
  4275. ; characters while searching for an 'ACK' or a 'NAK'.
  4276. ;
  4277. GTACK:    MVI    E,192        ; Number of characters to gobble
  4278. ;
  4279. ACKLUP:    MVI    A,0FFH
  4280.     STA    CHRFLG        ; Set the character flag
  4281.     STA    TIMFLG        ; Set the time flag
  4282.     MVI    B,1
  4283.     CALL    RECV
  4284.     MOV    B,A        ; Save the character
  4285.     JNC    ACKTST
  4286.     XRA    A
  4287.     STA    CHRFLG        ; Reset the character flag, was none
  4288. ;
  4289. ACKTST:    XRA    A
  4290.     STA    TIMFLG        ; Reset the time flag
  4291.     MOV    A,B        ; Get the character back
  4292.     CPI    ACK
  4293.     RZ
  4294.     CPI    NAK
  4295.     JZ    GTACK1
  4296.     CPI    CANCEL        ; Was this a CTL-X to cancel?
  4297.     CZ    CKCAN        ; Check for abort
  4298.     DCR    E        ; One less to go
  4299.     JNZ    ACKLUP        ; Loop around again if not zero
  4300.     LDA    CHRFLG
  4301.     ORA    A
  4302.     JZ    GETATOT
  4303. ;
  4304. GTACK1:    LDA    QFLG
  4305.     ORA    A
  4306.     JZ    ACKER
  4307.     LDA    CHKEOT        ; Waiting for ACK after EOT?
  4308.     ORA    A
  4309.     JNZ    ACKER        ; If yes, ignore message
  4310.     CALL    ILPRT
  4311.     DB    '++ ',0
  4312.     MOV    A,B
  4313.     CPI    NAK
  4314.     JZ    GTACK3
  4315.     CALL    HEXO
  4316.     CALL    ILPRT
  4317.     DB    'H',0
  4318.     JMP    GTACK4
  4319. ;
  4320. GTACK3:    CALL    ILPRT
  4321.     DB    'NAK',0
  4322. ;
  4323. GTACK4:    CALL    ILPRT
  4324.     DB    ' received not ACK - ',0
  4325.     CALL    SHOWERR
  4326. ;
  4327. ACKER:    LDA    ERRCT
  4328.     INR    A
  4329.     STA    ERRCT
  4330.     CPI    ERRLIM+1    ; At error limit yet?
  4331.     RC            ; If not, return
  4332. ;
  4333. ACKMSG:    CALL    ERXIT
  4334.     DB    CR,LF,LF,'++ FILE TRANSFER ABORTED ++','$'
  4335. ;.....
  4336. ;
  4337. ;
  4338. ; Reached error limit
  4339. ;
  4340. GETATOT:CALL    ILPRT
  4341.     DB    CR,'++ TIMEOUT - no ACK - ',0
  4342.     CALL    SHOWERR        ; Display error count
  4343.     JMP    ACKER
  4344. ;.....
  4345. ;
  4346. ;
  4347. ; Check the total error count vs. records sent, switch from 1k to 128
  4348. ; character transmissions if higher than operator selected value.
  4349. ;
  4350. GTRATIO:LDA    KFLG        ; Using 1k blocks?
  4351.     ORA    A
  4352.     RZ            ; If not, skip this routine
  4353. ;
  4354.     LDA    ERRCT        ; See if we got any errors last record
  4355.     CPI    4+1        ; If under 4 consecutive errors, exit
  4356.     JNC    GTRATIO1    ; (ERRCT is set to 1 initially, below)
  4357.     LDA    ACCERR        ; See if up to minimum errors yet
  4358.     CPI    3        ; Had as many as three errors yet?
  4359.     RC            ; If not, don't get excited too quickly
  4360. ;
  4361.     LHLD    RECNO        ; Get current record number increment
  4362.     LXI    D,-8        ; Have not successfully sent this 1k yet
  4363.     DAD    D        ; Subtract the current increment, then
  4364.     XCHG            ; Put in DE for now
  4365.     LHLD    ACCERR        ; Number of non-'ACK' errors in HL
  4366.     XCHG            ; Back to normal
  4367.     CALL    DVHLDE        ; Get ratio in BC of records/hit
  4368.     LDA    MSPEED        ; Get current speed
  4369.     CPI    5        ; 1200 baud?
  4370.     MVI    A,71-1        ; For 1200 bps    (78 ms delay)
  4371.     JZ    $+5        ; If 1200, skip next line
  4372.     MVI    A,43-1        ; For 2400 bps    (78 ms delay)
  4373.     CMP    C        ; Compare with actual ratio
  4374.     RC            ; Return if less hits than allowed
  4375. ;
  4376. GTRATIO1:
  4377.     XRA    A        ; Else reset the system to 128
  4378.     STA    KFLG
  4379.     CALL    ILPRTQ
  4380.     DB    CR,LF,'Aborting 1k blocks, too many ACK errors',CR,LF,0
  4381.     RET
  4382. ;.....
  4383. ;
  4384. ;
  4385. CKABORT:LDA    QFLG
  4386.     ORA    A
  4387.     RZ
  4388.     CALL    STAT
  4389.     ORA    A
  4390.     RZ
  4391.     CALL    KEYIN
  4392.     CPI    CANCEL
  4393.     RNZ
  4394. ;
  4395. ;
  4396. ; Aborts send or receive routines and returns to command line
  4397. ;
  4398. ABORT:    LXI    SP,STACK
  4399. ;
  4400. ABORTL:    MVI    B,1        ; 1-second delay to clear input
  4401.     CALL    RECV
  4402.     JNC    ABORTL
  4403.     MVI    A,CANCEL    ; Show you are cancelling
  4404.     CALL    SEND        ; They may quit also with enough CTL-X
  4405.     CALL    SEND
  4406.     CALL    SEND
  4407. ;
  4408. ABORTW:    MVI    B,1        ; 1-second delay to clear input
  4409.     CALL    RECV
  4410.     JNC    ABORTW
  4411.     MVI    A,BKSP        ; Remove the three CTL-X's if needed
  4412.     CALL    SEND
  4413.     CALL    SEND
  4414.     CALL    SEND
  4415.     MVI    A,'B'        ; Clear the batch mode flag
  4416.     STA    BATCHFLG
  4417.     STA    ABORTFLG    ; Shows an abort was made
  4418.     XRA    A
  4419.     STA    NFILFLG        ; Stop copy into memory for disk file
  4420. ;
  4421. ABORTX:    LDA    OPTION        ; Receiving a file now?
  4422.     CPI    'R'
  4423.     JZ    RCVSABT        ; If yes, delete the unfinished file
  4424. ;
  4425.     CALL    ILPRT
  4426.     DB    CR,LF,LF,'++ FILE CANCELLED ++',CR,LF,BELL,0
  4427.     JMP    DONETA
  4428. ;.....
  4429. ;
  4430. ;
  4431. ; Increment the record count
  4432. ;
  4433. INCRNO:    PUSH    H
  4434.     PUSH    D
  4435.     LHLD    RCDCNT        ; Increment the transmission count
  4436.     INX    H
  4437.     SHLD    RCDCNT
  4438.     LXI    D,1        ; Increment by 1 for 128 char. blocks
  4439.     LDA    KFLG        ; Sending 1k blocks?
  4440.     ORA    A
  4441.     JZ    $+6        ; If not, skip next line
  4442.     LXI    D,8        ; If yes, increment count by 8
  4443.     LHLD    RECNO        ; Get record number
  4444.     DAD    D
  4445.     SHLD    RECNO        ; Store it
  4446.     POP    D
  4447.     POP    H
  4448.     RET
  4449. ;.....
  4450. ;
  4451. ;
  4452. ; First check for any wild cards and disallow, just to be safe.  Do not
  4453. ; want a group of files being accidently erased.
  4454. ;
  4455. ERASF:    LXI    H,FCB        ; File name is stored here
  4456.     MVI    B,11        ; Maximum of 11 chars for filename, ext.
  4457. ;
  4458. ERASF1:    INX    H        ; Next location in file name
  4459.     MOV    A,M        ; Get the character
  4460.     CPI    '?'        ; Check for any wild card characters
  4461.     JZ    ERRORW        ; Error if one is found
  4462.     DCR    B        ; Number of tries left
  4463.     JNZ    ERASF1        ; If not zero, keep checking
  4464. ;
  4465.     LDA    BATCHFLG    ; Batch mode?
  4466.     ORA    A
  4467.     JZ    NOASK        ; Exit if set (will be zero)
  4468. ;
  4469.     LXI    D,FCB
  4470.     MVI    C,SRCHF
  4471.     CALL    BDOS
  4472.     INR    A
  4473.     RZ            ; File erased ok, return
  4474.     CALL    ILPRT        ; Otherwise make sure it'S OK
  4475.     DB    'File exists - erase?  (Y/N): ',BELL,0
  4476.     CALL    KBDCHR
  4477.     PUSH    PSW        ; Save the answer for a moment
  4478.     CALL    CRLF        ; Turn up a line
  4479.     POP    PSW        ; Get the character back now
  4480.     CPI    'Y'
  4481.     JNZ    MENU        ; If not a 'Y' do not erase
  4482. ;
  4483. NOASK:    LXI    D,FCB        ; Else erase the file
  4484.     MVI    C,ERASE
  4485.     JMP    BDOS        ; Return from ERASF
  4486. ;.....
  4487. ;
  4488. ;
  4489. ERRORW:    POP    H        ; Restore stack from "call ERASF"
  4490.     CALL    ILPRT
  4491.     DB    '++ NO WILDCARDS ALLOWED FOR TEXT FILES ++'
  4492.     DB    CR,LF,BELL,0
  4493.     JMP    MENU
  4494. ;.....
  4495. ;
  4496. ;
  4497. BLKFILE:CALL    ILPRT        ; No file named for send or receive
  4498.     DB    '++ NO FILE SPECIFIED ++',CR,LF,BELL,0
  4499.     JMP    MENU
  4500. ;.....
  4501. ;
  4502. ;
  4503. MAKEFIL:LXI    D,FCB
  4504.     MVI    C,MAKE
  4505.     CALL    BDOS
  4506.     INR    A
  4507.     RNZ
  4508.     CALL    ERXIT
  4509.     DB    '++ ERROR -- Can''t open file ++',CR,LF
  4510.     DB    '++ Directory is perhaps full ++','$'
  4511. ;
  4512. CNREC:    MVI    C,FILSIZ    ; Compute file size function in cp/m 2.x
  4513.     LXI    D,FCB        ; Point to file control block
  4514.     CALL    BDOS
  4515.     LHLD    FCB+33        ; Get record count
  4516.     SHLD    RCNT        ; Store it
  4517.     LXI    H,0        ; Zero 'HL'
  4518.     SHLD    FCB+33        ; Reset random record in FCB
  4519.     RET
  4520. ;.....
  4521. ;
  4522. ;
  4523. OPENFIL:XRA    A
  4524.     STA    FCBEXT
  4525.     LXI    D,FCB
  4526.     MVI    C,OPEN
  4527.     CALL    BDOS
  4528.     INR    A
  4529.     JZ    OPENF1        ; Exit if no file
  4530.     LHLD    RCNT        ; See if anything in the file first
  4531.     MOV    A,H
  4532.     ORA    L
  4533.     JNZ    SNDTM        ; If yes send transfer time, etc.
  4534.     CALL    ERXIT
  4535.     DB    '++ File is zero-length ++','$'
  4536. ;
  4537. OPENF1:    CALL    ERXIT        ; File did not open
  4538.     DB    '++ FILE NOT FOUND ++','$'
  4539. ;.....
  4540. ;
  4541. ;
  4542. CLOSFIL:LXI    D,FCB        ; Get the file name
  4543.     MVI    C,CLOSE
  4544.     CALL    BDOS        ; Close the file
  4545.     INR    A
  4546.     RNZ
  4547.     JMP    ERXIT1        ; No file to close, exit
  4548. ;.....
  4549. ;
  4550. ;
  4551. ;-----------------------------------------------------------------------
  4552. ;        read a record, refill buffer if empty
  4553. ;
  4554. ; Update record read
  4555. ;
  4556. RDRECD:    LDA    RECNBF        ; Get number of records in buffer
  4557.     ORA    A
  4558.     JZ    RDBLOCK        ; If none, go get some
  4559.     LDA    KFLG        ; Using 1k blocks?
  4560.     ORA    A
  4561.     JZ    RDREC1        ; If not, exit
  4562. ;
  4563. ;
  4564. ; Using 1k blocks, switch to 128 if less than 8 records left
  4565. ;
  4566.     LDA    RECNBF        ; See how many records in buffer
  4567.     CPI    8
  4568.     JNC    RDREC2        ; If 8 or more stay in 1k blocks
  4569.     XRA    A        ; Else there are 1-7 records left
  4570.     STA    KFLG        ; Reset the 1k flag for 128
  4571. ;
  4572. RDREC1:    LDA    RECNBF        ; Decrement 'RECORDS IN BUFFER' count
  4573.     DCR    A
  4574.     STA    RECNBF
  4575.     RET
  4576. ;...
  4577. ;
  4578. ;
  4579. ; Using 1k blocks, get set to send another one
  4580. ;
  4581. RDREC2:    SUI    8        ; Subtract 1k worth
  4582.     STA    RECNBF
  4583.     RET
  4584. ;.....
  4585. ;
  4586. ;
  4587. ; Buffer empty so read in another block from the disk
  4588. ;
  4589. RDBLOCK:LDA    EOFLG
  4590.     CPI    1
  4591.     STC
  4592.     RZ
  4593. ;
  4594.     CALL    RDBLK1
  4595.     JMP    RDRECD
  4596. ;.....
  4597. ;
  4598. ;
  4599. ; Read up to 16k of the file from disk to buffer, ready to send
  4600. ;
  4601. RDBLK1:    MVI    C,0
  4602.     LXI    D,BUFFER
  4603. ;
  4604. RDRECLP:PUSH    B
  4605.     PUSH    D
  4606.     MVI    C,STDMA        ; Use the 'DE' address to store file
  4607.     CALL    BDOS
  4608. ;
  4609.     LXI    D,FCB
  4610.     MVI    C,READ        ; Read a record from the file and store
  4611.     CALL    BDOS
  4612. ;
  4613.     POP    D
  4614.     POP    B
  4615.     ORA    A        ; Read ok?
  4616.     JNZ    REOF        ; If not, error or end of file
  4617. ;
  4618.     LXI    H,128        ; Add length of one record
  4619.     DAD    D        ; To next buffer address
  4620.     XCHG            ; Buffer address for next record to DE
  4621.     INR    C        ; Increment records in buffer count
  4622.     CALL    DSKSIZ        ; See if buffer is full yet
  4623.     JNZ    RDRECLP        ; If not full, do another
  4624. ;...
  4625. ;
  4626. ;
  4627. ; Buffer full or received "End Of File (EOF)"
  4628. ;
  4629. RDBFULL:STA    RECNBF        ; Store the number records in buffer
  4630.     LXI    H,BUFFER    ; Start at beginning of buffer
  4631.     SHLD    RECPTR        ; Initialize buffer poninters
  4632.     MVI    C,STDMA        ; Reset file storage to default area
  4633.     LXI    D,TBUF
  4634.     JMP    BDOS        ; Have something to read, now
  4635. ;.....
  4636. ;
  4637. ;
  4638. REOF:    DCR    A        ; 'EOF' yet?
  4639.     JNZ    RDERR        ; If not, was an error
  4640.     MVI    A,1
  4641.     STA    EOFLG        ; Set EOF flag
  4642.     MOV    A,C
  4643.     JMP    RDBFULL
  4644. ;.....
  4645. ;
  4646. ;
  4647. RDERR:    CALL    ERXIT
  4648.     DB    '++ FILE READ ERROR ++','$'
  4649. ;
  4650. ;
  4651. ;
  4652. ;
  4653. ; If the 128 or 1024 byte record was received ok by RCVDATA and passed
  4654. ; the CRC (or checksum) test, then we aleady have the infomration in the
  4655. ; buffer and just move the RECPTR pointers 128 or 1024 bytes for the
  4656. ; next record's location.  If this puts us up to the limit of records,
  4657. ; we dump to disk and reset everything.
  4658. ;
  4659. WRRECD:    LHLD    RECPTR        ; Get buffer address
  4660.     LXI    D,128        ; 128 characters/record
  4661.     LDA    KFLG        ; Using 1k blocks?
  4662.     ORA    A
  4663.     JZ    $+6        ; If not skip next line
  4664.     LXI    D,1024        ; 1k characters/record
  4665.     DAD    D        ; To next buffer
  4666.     SHLD    RECPTR        ; Save buffer address
  4667.     LDA    KFLG        ; Using 1k blocks?
  4668.     ORA    A
  4669.     JZ    WRREC1        ; If not, exit
  4670.     LDA    RECNBF        ; Get number of records in buffer
  4671.     ADI    8        ; Increment it 8 records for 1k block
  4672.     JMP    WRREC2
  4673. ;
  4674. WRREC1:    LDA    RECNBF        ; Get number of records in buffer
  4675.     INR    A        ; Increment it for one 128 char. record
  4676. ;
  4677. WRREC2:    STA    RECNBF        ; Store the new value
  4678.     MOV    C,A        ; Store the record count for now
  4679.     CALL    DSKSIZ        ; Establish buffer size
  4680.     RNZ            ; Buffer not full, return
  4681. ;
  4682. ;
  4683. ; Write a block to disk
  4684. ;
  4685. WRBLOCK:LDA    RECNBF        ; Get the number of records in the buffer
  4686.     ORA    A
  4687.     RZ            ; If zero, don't try to move to disk
  4688.     MOV    C,A        ; Otherwise store in 'C' reg.
  4689.     LXI    D,BUFFER    ; Start of buffer to move to disk
  4690. ;
  4691. DSKWRT:    PUSH    B
  4692.     PUSH    D
  4693.     PUSH    H
  4694. ;
  4695.     MVI    C,STDMA
  4696.     CALL    BDOS
  4697. ;
  4698.     MVI    C,WRITE
  4699.     LXI    D,FCB
  4700.     CALL    BDOS
  4701. ;
  4702.     POP    H
  4703.     POP    D
  4704.     POP    B
  4705.     ORA    A
  4706.     JNZ    WRERR        ; Error if disk is full
  4707.     LXI    H,128        ; Add in another record
  4708.     DAD    D        ; Increment the current buffer address
  4709.     XCHG            ; Put in DE for new buffer address
  4710.     DCR    C        ; One less record left to move to disk
  4711.     JNZ    DSKWRT        ; If not finished, write another record
  4712.     XRA    A        ; Else all done, zero the pointers
  4713.     STA    RECNBF        ; Zero the 'RECORDS IN BUFFER' count
  4714.     LXI    H,BUFFER    ; Reset location to next buffer start
  4715.     SHLD    RECPTR        ; Now at start of buffer again
  4716.     RET
  4717. ;.....
  4718. ;
  4719. ;
  4720. ; Determine if the buffer size is for file transfer or for ASCII capture
  4721. ; to disk then compare with current record length
  4722. ;
  4723. DSKSIZ:    LDA    XFLG        ; See if transferring files now
  4724.     ORA    A
  4725.     MOV    A,C        ; Get the current record count
  4726.     JZ    DSKSIZ1        ; If yes, exit
  4727.     MOV    A,C
  4728.     CPI    BUFSIZ*8    ; Buffer size for ASCII capture to disk
  4729.     RET            ; Return with flag set for the compare
  4730. ;...
  4731. ;
  4732. ;
  4733. DSKSIZ1:LDA    SAVSIZ        ; Get the file transfer buffer size..
  4734.     CMP    C        ; From special storage area and compare
  4735.     RET            ; Return with flag set for the compare
  4736. ;.....
  4737. ;
  4738. ;
  4739. ; Timeout time is in B, in seconds.  Entry via 'RECVDG' deletes garbage
  4740. ; characters on the line.  For example, having just sent a record, cal-
  4741. ; ling RECVDG will delete any line noise induced characters LONG before
  4742. ; the ACK/NAK would be received.
  4743. ;
  4744. RECVDG:    CALL    CKCHAR        ; Catch any garbage characters
  4745. ;
  4746. RECV:    PUSH    D
  4747. ;
  4748. ;
  4749. ; Get back quickly to gobble 2nd character if TIMFLG is set by the GETNM
  4750. ; routine - or just step through quickly after the first wait for 'SOH'
  4751. ; in the 'SOHLUP' routine.
  4752. ;
  4753. MSEC:    PUSH    H
  4754.     LXI    H,TIMFLG
  4755.     MOV    E,M
  4756.     INR    E
  4757.     LHLD    QUIKTIM
  4758.     JZ    DOQUIK
  4759.     LHLD    TIMVAL
  4760. ;
  4761. DOQUIK:    XCHG
  4762.     POP    H
  4763. ;
  4764. MWTI:    CALL    RCVRDY
  4765.     JZ    MCHAR
  4766.     MOV    A,D
  4767.     ORA    E
  4768.     DCX    D
  4769.     JNZ    MWTI
  4770.     DCR    B
  4771.     JNZ    MSEC
  4772.     POP    D
  4773.     CALL    CKABORT
  4774.     STC
  4775.     RET
  4776. ;.....
  4777. ;
  4778. ;
  4779. ; Get the character from the modem, but filter out 'ACK' and '.' chars.
  4780. ; if recieving a file name.  ('FILTRFLG' is set by the 'GETNM' routine.)
  4781. ;
  4782. MCHAR:    CALL    I$MDDATP    ; Get the character that is waiting
  4783.     POP    D
  4784.     PUSH    PSW        ; Save the character for later use also
  4785.     CPI    ACK        ; See if it is 'ACK'
  4786.     JZ    ISACK
  4787.     CPI    '.'        ; See if it is a period
  4788.     JNZ    DOUPD        ; Neither, so update 'CRC'
  4789. ;
  4790. ISACK:    PUSH    H
  4791.     PUSH    D
  4792.     LXI    H,FLTRFLG    ; See if need to each 'ACK' or period
  4793.     MOV    E,M
  4794.     INR    E
  4795.     POP    D
  4796.     POP    H
  4797.     JZ    MWTI        ; Yes, so do it
  4798. ;
  4799. DOUPD:    CALL    CRCUPD        ; Calculate 'CRC'
  4800.     ADD    C
  4801.     MOV    C,A
  4802.     LDA    RSEEFLG
  4803.     ORA    A
  4804.     JZ    MONIN
  4805.     LDA    VSEEFLG
  4806.     ORA    A
  4807.     JNZ    NOMONIN
  4808.     LDA    DATAFLG
  4809.     ORA    A
  4810.     JZ    NOMONIN
  4811. ;
  4812. MONIN:    POP    PSW        ; Get the character again
  4813.     PUSH    PSW        ; Resave it for later use also
  4814.     CALL    SHOW        ; Show the character on the CRT
  4815. ;
  4816. NOMONIN:CALL    CKABORT
  4817.     POP    PSW        ; Get the character back once more
  4818.     ORA    A        ; Reset the carry flag
  4819.     RET            ; Return with the character and flag set
  4820. ;.....
  4821. ;
  4822. ;
  4823. ; Send a character to the modem
  4824. ;
  4825. SEND:    PUSH    PSW
  4826.     LDA    SSEEFLG
  4827.     ORA    A
  4828.     JZ    MONOUT
  4829.     LDA    VSEEFLG
  4830.     ORA    A
  4831.     JNZ    NOMONOT
  4832.     LDA    DATAFLG
  4833.     ORA    A
  4834.     JZ    NOMONOT
  4835. ;
  4836. MONOUT:    POP    PSW
  4837.     PUSH    PSW
  4838.     CALL    SHOW
  4839. ;
  4840. NOMONOT:POP    PSW
  4841.     PUSH    PSW
  4842.     CALL    CRCUPD        ; Update the 'CRC' calcuation
  4843.     ADD    C
  4844.     MOV    C,A
  4845. ;
  4846. SENDW:    CALL    SNDRDY        ; See if modem is ready for new char.
  4847.     JNZ    SENDW        ; If not, wait until modem is ready
  4848.     POP    PSW        ; Get the character back
  4849.     JMP    O$MDDATP    ; Send character to modem, done
  4850. ;.....
  4851. ;
  4852. ;
  4853. ; Waits for the first character received while waiting to send a file.
  4854. ; If a character is not received in one second, it loops again until a
  4855. ; char. is received or it times out.  The count is set for two minutes
  4856. ; before timeout.  This gives the receiving station ample time to name
  4857. ; a file, etc.
  4858. ;
  4859. WAITNAK:CALL    CKABORT
  4860.     MVI    B,1        ; Wait up to 1 second for a character
  4861.     CALL    RECV        ; Clear the buffer first then get char.
  4862.     JC    WAITN2        ; No character this time
  4863.     CPI    CANCEL        ; Want to quit?
  4864.     CZ    CKCAN        ; If yes, check for a trailing CTL-X
  4865. ;
  4866. WAITN1:    CPI    CRC        ; 'CRC' request?
  4867.     JZ    WAITK        ; Yes, see if there will be a trailing K
  4868.     CPI    KSND        ; Request for 1k blocks?
  4869.     JZ    WAIKST        ; Yes, go set the 1k flag
  4870.     CPI    NAK
  4871.     JZ    WAICKSM
  4872.     mov    b,a        ; Save the character for now
  4873.     lda    batchflg    ; In batch mode now?
  4874.     ora    a
  4875.     jnz    waitn2        ; if not, exit
  4876.     mov    a,b        ; Get the character back
  4877.     cpi    EOT        ; See if file exists on host
  4878.     jz    exists        ; Exit if batch file already exists
  4879. ;
  4880. WAITN2:    DCR    E
  4881.     JNZ    WAITNAK
  4882.     JMP    ABORT
  4883. ;...
  4884. ;
  4885. ;
  4886. WAITK:    MVI    B,1        ; Got a 'C', wait up to 1 second for 'K'
  4887.     CALL    RECV
  4888.     JC    WAITCRC        ; Didn't get anything, so not using 1k
  4889.     ANI    7FH
  4890.     CPI    '{'
  4891.     JZ    WAITK        ; Disregard noisy lines
  4892.     CPI    KSND        ; Requesting 1k?
  4893.     JZ    WAIKST        ; Exit if yes, otherwise set CRC
  4894.     JMP    WAITCRC
  4895. ;.....
  4896. ;
  4897. ;
  4898. WAICKSM:LDA    BATCHFLG    ; In batch mode?
  4899.     ORA    A
  4900.     JZ    WAICKSN        ; If yes, exit
  4901.     XRA    A
  4902.     STA    CRCFLG        ; Make sure in checksum mode
  4903.     STA    KFLG        ; Cancel any 1k block request
  4904.     CALL    ILPRTQ
  4905.     DB    'Got checksum request',CR,LF,0
  4906.     RET
  4907. ;...
  4908. ;
  4909. ;
  4910. WAICKSN:CALL    ILPRTQ
  4911.     DB    'Checksum not used for batch mode',CR,LF,0
  4912.     JMP    WAITNAK        ; Keep waiting for CRC value
  4913. ;.....
  4914. ;
  4915. ;
  4916. WAITCRC:LDA    KFLG
  4917.     ORA    A
  4918.     JNZ    WAIKST1
  4919.     CALL    ILPRTQ
  4920.     DB    'CRC request received',CR,LF,0
  4921.     MVI    A,1
  4922.     STA    CRCFLG        ; Make sure in 'CRC' mode then
  4923.     XRA    A
  4924.     STA    KFLG        ; Cancel any 1k blocks request
  4925.     RET
  4926. ;.....
  4927. ;
  4928. ;
  4929. ; If a 'K' was received set for 1k blocks, unless we typed a 'SX' to
  4930. ; force XMODEM protocol with 128 character blocks, intentionall.
  4931. ;
  4932. WAIKST:    LDA    XMODEM        ; Get the value of XMODEM flag
  4933.     ORA    A
  4934.     JZ    WAITCRC
  4935. ;
  4936. WAIKST1:STA    CRCFLG        ; Set the CRC flag
  4937.     STA    KFLG        ; Set the flag for 1k blocks
  4938.     CALL    ILPRTQ
  4939.     DB    '1k request received',CR,LF,0
  4940.     RET
  4941. ;.....
  4942. ;
  4943. ;
  4944. ; File exists we were trying to send via batch mode, so abort
  4945. ;
  4946. exists:    call    erxit
  4947.     db    CR,LF,'++ File exists on host, aborting transfer ++','$'
  4948. ;.....
  4949. ;
  4950. ;
  4951. ; Finished with the file transfer
  4952. ;
  4953. DONE:    LDA    BATCHFLG    ; In batch mode?
  4954.     ORA    A
  4955.     JNZ    DONET        ; Exit if not
  4956. ;
  4957.     LDA    QFLG
  4958.     ORA    A
  4959.     JZ    NMSTRNS
  4960.     MVI    B,12        ; Zero out FTRNM
  4961.     LXI    H,FTRNM
  4962.     MVI    A,0
  4963. ;
  4964. ZEROLP:    MOV    M,A
  4965.     INX    H
  4966.     DCR    B
  4967.     JNZ    ZEROLP
  4968.     MVI    B,12        ; Put file name in FTRNM
  4969.     LXI    H,FCB+1
  4970.     LXI    D,FTRNM
  4971. ;
  4972. LOADMSG:MVI    A,4        ; Start of file type?
  4973.     CMP    B
  4974.     JZ    PERIOD        ; Put in period if so
  4975.     MOV    A,M
  4976.     CPI    ' '        ; Don't put in space
  4977.     JZ    SKPSP
  4978.     STAX    D        ; Store in FTRNM
  4979.     INX    D
  4980. ;
  4981. SKPSP:    INX    H
  4982.     DCR    B
  4983.     MOV    A,B
  4984.     ORA    A        ; End of file name?
  4985.     JZ    FTRNM0        ; Display file name
  4986.     JMP    LOADMSG        ; Loop for another character
  4987. ;.....
  4988. ;
  4989. ;
  4990. PERIOD:    MOV    A,M
  4991.     CPI    ' '        ; Is file type empty?
  4992.     JZ    FTRNM0        ; Go if so
  4993.     MVI    A,'.'        ; Else put period in message
  4994.     STAX    D
  4995.     INX    D
  4996.     DCR    B
  4997.     JMP    LOADMSG
  4998. ;.....
  4999. ;
  5000. ;
  5001. FTRNM0:    CALL    ILPRT
  5002.     DB    CR,LF
  5003. ;
  5004. FTRNM:    DB    0,0,0,0,0,0,0
  5005.     DB    0,0,0,0,0,0
  5006.     CALL    ILPRT
  5007.     DB    ' Transferred',CR,LF,0
  5008. ;
  5009. NMSTRNS:LXI    H,FCB        ; Blank out file control blocks
  5010.     CALL    INITFCB1
  5011.     LXI    H,RESTSN    ; Restore record numbers
  5012.     LXI    D,RECNOB    ; For new file transfer
  5013.     MVI    B,RECNOE-RECNOB    ; Routine also done in menu
  5014.     CALL    MOVE
  5015.     CALL    SNDNOW        ; Insures last character is finished
  5016.     CALL    CKCHAR        ; Catch any echo characters on line
  5017.     MVI    A,1
  5018.     STA    GOTONE        ; Indicates a batch file was handled
  5019.     LDA    SNDFLG        ; Check batch flag
  5020.     ORA    A
  5021.     JNZ    RCVFL        ; Receiving batch, if set
  5022.     JMP    SNDFL1        ; Sending batch if not set
  5023. ;.....
  5024. ;
  5025. ;
  5026. DONET:    CALL    CKABORT        ; Slight delay for next message
  5027.     CALL    ILPRT
  5028.     DB    CR,LF,'[Transfer completed]',CR,LF,BELL,0
  5029. ;
  5030. DONETA:    LDA    XITFLG        ; Special 'Z' flag set?
  5031.     ORA    A
  5032.     JZ    BYEBYE        ; If yes, disconnect and reboot
  5033.     LDA    DISCFLG        ; Normal 'D' flag set?
  5034.     ORA    A
  5035.     JZ    DONETD        ; If yes, disconnect, get next command
  5036. ;
  5037. DONETB:    XRA    A
  5038.     STA    CRCFLG        ; Reset back to checksum
  5039.     STA    FRSTIM        ; Reset first-time 'SOH' flag
  5040.     STA    FSTFLG        ; Reset multi-file transmission
  5041.     STA    NFILFLG        ; Turn off the memory save for disk file
  5042.     STA    SAVEFLG        ; Stop memory save in term routine.
  5043.     LDA    VSEEFLG        ; View flag set?
  5044.     ORA    A
  5045.     JNZ    DONETC        ; If not, exit
  5046.     CMA
  5047.     STA    QFLG        ; VSEEFLG also sets the QFLG
  5048.     STA    VSEEFLG        ; Reset the flag
  5049. ;
  5050. DONETC:    LXI    H,QFLG        ; In quiet mode?
  5051.     MOV    A,M
  5052.     ORA    A
  5053.     MVI    M,'Q'        ; Reset the flag to normal
  5054.     JZ    MENU        ; If yes, go back to command line
  5055.     LDA    ABORTFLG    ; Come here from a timeout?
  5056.     ORA    A
  5057.     JNZ    MENU        ; If yes, go to command mode
  5058.     JMP    TERM        ; Otherwise return to terminal mode
  5059. ;.....
  5060. ;
  5061. ;
  5062. DONETD:    CALL    ILPRT
  5063.     DB    CR,LF,'  wait... ',0
  5064.     CALL    STPCHR        ; Try to stop any incoming characters
  5065.     LDA    NODTR        ; Able to disconnect by dropping DTR?
  5066.     ORA    A
  5067.     JNZ    DONETE        ; If not, exit
  5068.     CALL    J$GOODBYE    ; Disconect with ATH0 string
  5069.     JMP    DONETF
  5070. ;
  5071. DONETE:    CALL    J$DSCONT    ; Disconnect with ATH0 string    
  5072. ;
  5073. DONETF:    CALL    ILPRT
  5074.     DB    CR,'<< Disconnected >>',BELL,CR,LF,0
  5075.     JMP    MENU0        ; Back to command line
  5076. ;.....
  5077. ;
  5078. ;
  5079. ; Sends a break tone for 300 ms
  5080. ;
  5081. SBREAK:    LDA    J$BREAK
  5082.     CPI    0C3H        ; See if overlay has "J$BREAK" installed
  5083.     JNZ    TERM        ; If not, get next character/command
  5084.     CALL    STPCHR        ; Stop any incoming characters
  5085.     CALL    J$BREAK        ; Send the break tone
  5086. ;
  5087.     JMP    TERM        ; Get next character/command
  5088. ;.....
  5089. ;
  5090. ;
  5091. ; This routine stops any incoming characters if possible
  5092. ;
  5093. STPCHR:    CALL    J$INMDM        ; See if any incoming characters
  5094.     JC    STPCHR1        ; If no incoming, exit
  5095.     MVI    B,'S'-40H    ; X-off to stop host if possible
  5096.     CALL    J$SNDCHR    ; Send to host        
  5097.     MVI    B,1        ; Delay 100 ms to take effect
  5098.     CALL    J$TIMER
  5099.     JMP    STPCHR        ; See if characters have stopped now
  5100. ;
  5101. STPCHR1:RET            ; Done
  5102. ;.....
  5103. ;
  5104. ;
  5105. SHOW:    CPI    LF
  5106.     JZ    CTYPE
  5107.     CPI    CR
  5108.     JZ    CTYPE
  5109.     CPI    9
  5110.     JZ    CTYPE
  5111.     CPI    ' '
  5112.     JC    SEEHEX
  5113.     CPI    7FH
  5114.     JC    CTYPE
  5115. ;
  5116. SEEHEX:    PUSH    PSW
  5117.     MVI    A,'('
  5118.     CALL    CTYPE
  5119.     POP    PSW
  5120.     CALL    HEXO
  5121.     MVI    A,')'
  5122.     JMP    CTYPE
  5123. ;.....
  5124. ;
  5125. ;
  5126. CTYPE:    PUSH    B
  5127.     PUSH    D
  5128.     PUSH    H
  5129.     MOV    E,A
  5130.     MVI    C,WRCON
  5131.     CALL    BDOS
  5132.     POP    H
  5133.     POP    D
  5134.     POP    B
  5135.     RET
  5136. ;.....
  5137. ;
  5138. ;
  5139. CRLF:    PUSH    PSW
  5140.     MVI    A,CR
  5141.     CALL    TYPE
  5142.     MVI    A,LF
  5143.     CALL    TYPE
  5144.     POP    PSW
  5145.     RET
  5146. ;.....
  5147. ;
  5148. ;
  5149. STAT:    PUSH    B
  5150.     PUSH    D
  5151.     PUSH    H
  5152. ;
  5153. VSTAT:    CALL    $-$        ; BIOS constat address, filled in..
  5154.     POP    H        ; By 'INITADR' routine
  5155.     POP    D
  5156.     POP    B
  5157.     ORA    A
  5158.     RET
  5159. ;.....
  5160. ;
  5161. ;
  5162. KEYIN:    PUSH    B
  5163.     PUSH    D
  5164.     PUSH    H
  5165. ;
  5166. VKEYIN:    CALL    $-$        ; BIOS 'CONIN' address, filled in..
  5167.     POP    H        ; By 'INITADR' routine
  5168.     POP    D
  5169.     POP    B
  5170.     RET
  5171. ;.....
  5172. ;
  5173. ;
  5174. TYPE:    PUSH    PSW
  5175.     PUSH    B
  5176.     PUSH    D
  5177.     PUSH    H
  5178.     MOV    C,A
  5179. ;
  5180. VTYPE:    CALL    $-$        ; BIOS 'CONOUT' address, filled in..
  5181.     POP    H        ; By 'INITADR' routine
  5182.     POP    D
  5183.     POP    B
  5184.     POP    PSW
  5185.     RET
  5186. ;.....
  5187. ;
  5188. ;
  5189. ; Catch any extra keyboard characters coming through BDOS
  5190. ;
  5191. CKCON:    MVI    C,CONST        ; See if any characters waiting
  5192.     CALL    BDOS
  5193.     ORA    A
  5194.     RZ            ; If not, exit
  5195.     MVI    C,RDCON        ; Otherwise get the character
  5196.     CALL    BDOS
  5197.     XRA    A        ; Discard the character
  5198.     JMP    CKCON        ; See if any others
  5199. ;.....
  5200. ;
  5201. ;
  5202. ; Used in overlay area to permit saying "SET 2400", etc.
  5203. ;
  5204. CMDSPL:    LXI    D,CMDBUF+6
  5205.     LDAX    D
  5206.     CPI    '0'
  5207.     RET
  5208. ;.....
  5209. ;
  5210. ;
  5211. DECOUT:    PUSH    PSW
  5212.     PUSH    B
  5213.     PUSH    D
  5214.     PUSH    H
  5215.     LXI    B,-10
  5216.     LXI    D,-1
  5217. ;
  5218. DECOU1:    DAD    B
  5219.     INX    D
  5220.     JC    DECOU1
  5221.     LXI    B,10
  5222.     DAD    B
  5223.     XCHG
  5224.     MOV    A,H
  5225.     ORA    L
  5226.     CNZ    DECOUT
  5227.     MOV    A,E
  5228.     ADI    '0'
  5229.     CALL    CTYPE
  5230.     POP    H
  5231.     POP    D
  5232.     POP    B
  5233.     POP    PSW
  5234.     RET
  5235. ;.....
  5236. ;
  5237. ;
  5238. ; Displays error statement then resturns to command mode
  5239. ;
  5240. ERXIT:    POP    D
  5241.     CALL    PRTMSG
  5242.     MVI    A,BELL
  5243.     CALL    TYPE
  5244.     CALL    CRLF
  5245. ;
  5246. ERXIT1:    MVI    A,1
  5247.     STA    ABORTFLG    ; Shows an unintentional abort
  5248.     LDA    BATCHFLG    ; In batch mode?
  5249.     ORA    A
  5250.     JNZ    DONETB        ; If not, exit
  5251.     JMP    ABORT        ; Abort other computer
  5252. ;.....
  5253. ;
  5254. ;
  5255. ; Exits directly to CP/M, with no reboot unless you have selected pos-
  5256. ; sible overwriting of 'CCP'
  5257. ;
  5258. EXIT:    LDA    OLDUSER        ; Get original user number back
  5259.     MOV    E,A
  5260.     CALL    STUSER
  5261.     MVI    C,STDMA
  5262.     LXI    D,TBUF        ; Restore original buffer area
  5263.     CALL    BDOS
  5264.     LXI    B,1A00H        ; A little delay timer
  5265. ;
  5266. EXIT1:    DCX    B        ; One less loop to make
  5267.     MOV    A,B
  5268.     ORA    C
  5269.     JNZ    EXIT1        ; Loop again till both are zero
  5270.     CALL    CKCON        ; Catch any extra keyboard characters
  5271.     LDA    NFILFLG        ; Saving for a disk file?
  5272.     ORA    A
  5273.     STA    DONEFLG        ; Set the flag
  5274.     CNZ    WRFIL1        ; If yes, close the file
  5275.     LDA    MSPEED        ; Get the current modem speed
  5276.     STA    STRSPD        ; Store in case we come right back
  5277. ;
  5278. EXIT2:    CALL    J$EXITVEC    ; See if overlay needs to do anything
  5279.     XRA    A        ; Clear the 'A' reg. and all flags
  5280.     LHLD    STACK        ; Get the original stack pointer back
  5281.     SPHL            ; Set the stack pointer to that address
  5282.     RET
  5283. ;.....
  5284. ;
  5285. ;
  5286. ; Include the filename when transferring a file.  Check to see if from
  5287. ; an .ARC, .ARK or .LBR group first.
  5288. ;
  5289. FILNAM:    CALL    ILPRTQ
  5290.     DB    'File name: ',0
  5291.     LXI    H,93
  5292.     MVI    B,8        ; Maximum size of file name
  5293.     CALL    FILN1
  5294.     MOV    A,M        ; Get the next character
  5295.     CPI    32        ; Any file extent?
  5296.     RZ            ; If not, finished
  5297. ;
  5298.     MVI    A,46
  5299.     CALL    TYPE
  5300.     MVI    B,3        ; Maximum size of file extent
  5301. ;
  5302. FILN1:    MOV    A,M        ; Get FCB FILENAME/EXT character
  5303.     CPI    32        ; Skip any blanks
  5304.     CNZ    TYPE
  5305.     INX    H        ; Next FCB position
  5306.     DCR    B        ; One less to go
  5307.     JNZ    FILN1        ; If not done, get next one
  5308.     RET
  5309. ;.....
  5310. ;
  5311. ;
  5312. ; Adjusts loop counter for the selected clock speed.  Returns with delay
  5313. ; in 'HL'.
  5314. ;
  5315. FIXCNT:    LDA    CLOCK        ; Get the user's clock speed
  5316.     PUSH    D        ; Save the current 'DE' value
  5317.     PUSH    H
  5318.     POP    D        ; Get same value into 'DE' as in 'HL'
  5319. ;
  5320. CNTMUL:    DAD    D        ; Add 'DE' to 'HL'
  5321.     DCR    A        ; One less to go
  5322.     JNZ    CNTMUL
  5323.     POP    D        ; Restore current 'DE', delay in 'HL'
  5324.     RET
  5325. ;.....
  5326. ;
  5327. ;
  5328. ; Special routine to let overlays substitute their own printer routines.
  5329. ; Returns with GOLIST+1 and GOLIST+15 addresses.
  5330. ;
  5331. GOLST:    LXI    H,GOLIST+1
  5332.     LXI    D,GOLIST+15
  5333.     RET
  5334. ;.....
  5335. ;
  5336. ;
  5337. ; Prints a hex value in 'A' on the CRT
  5338. ;
  5339. HEXO:    PUSH    PSW
  5340.     RAR
  5341.     RAR
  5342.     RAR
  5343.     RAR
  5344.     CALL    NIBBL
  5345.     POP    PSW
  5346. ;
  5347. NIBBL:    ANI    0FH
  5348.     CPI    10
  5349.     JC    ISNUM
  5350.     ADI    7
  5351. ;
  5352. ISNUM:    ADI    '0'        ; Add in ASCII bias
  5353.     JMP    CTYPE
  5354. ;.....
  5355. ;
  5356. ;
  5357. ; Write a string of characters to the CRT
  5358. ;
  5359. ILPRT:    XTHL
  5360. ;
  5361. ILPRT1:    MOV    A,M        ; Get the character
  5362.     ORA    A        ; See if a "0" for end of string
  5363.     JZ    ILPRT2        ; If yes, all done
  5364.     CALL    CTYPE        ; Show on CRT
  5365.     INX    H        ; Get the next location in the string
  5366.     JMP    ILPRT1
  5367. ;
  5368. ILPRT2:    XTHL            ; Restore the address
  5369.     RET
  5370. ;.....
  5371. ;
  5372. ;
  5373. ; Write a string of characters unless in the Quiet mode
  5374. ;
  5375. ILPRTQ:    XTHL
  5376. ;
  5377. ILPRTQ1:MOV    A,M        ; Get the character
  5378.     ORA    A        ; See if a "0" for end of string
  5379.     JZ    ILPRTQ2        ; If yes, all done
  5380.     LDA    QFLG
  5381.     ORA    A
  5382.     MOV    A,M
  5383.     CNZ    CTYPE        ; Show on CRT if not in quiet mode
  5384.     INX    H        ; Get the next location in the string
  5385.     JMP    ILPRTQ1
  5386. ;
  5387. ILPRTQ2:XTHL            ; Restore the address
  5388.     RET
  5389. ;.....
  5390. ;
  5391. ;
  5392. MOVE128:MVI    B,128
  5393. ;
  5394. MOVE:    MOV    A,M
  5395.     STAX    D
  5396.     INX    H
  5397.     INX    D
  5398.     DCR    B
  5399.     JNZ    MOVE
  5400.     RET
  5401. ;.....
  5402. ;
  5403. ;
  5404. MOVEFCB:LXI    H,FCB+16
  5405.     LXI    D,FCB
  5406.     MVI    B,16
  5407.     CALL    MOVNAM
  5408.     XRA    A
  5409.     STA    FCBSNO
  5410.     STA    FCBEXT
  5411.     RET
  5412. ;.....
  5413. ;
  5414. ;
  5415. ; Prevents accidently including an "ESC" character in a file name
  5416. ;
  5417. MOVNAM:    MOV    A,M
  5418.     CPI    '['-40H        ; ESC character?
  5419.     JNZ    $+5        ; If yes, store normally
  5420.     MVI    A,' '
  5421.     STAX    D
  5422.     INX    D
  5423.     INX    H
  5424.     DCR    B
  5425.     JNZ    MOVNAM
  5426.     RET
  5427. ;.....
  5428. ;
  5429. ;
  5430. ; Initializes speed to that last used, if any, from 03CH MSPEED storage
  5431. ; and restores DTR.
  5432. ;
  5433. SETSPD:    LDA    STRSPD        ; Location of MSPEED from memory
  5434.     ORA    A        ; See if it has been used
  5435.     JZ    SETSP1        ; If not, use normal speed
  5436.     CPI    9+1        ; Takes us up to MSPEED = 19200 bps
  5437.     JNC    SETSP1        ; If more, was not a valid baudrate
  5438.     STA    MSPEED        ; Set former speed, then
  5439. ;
  5440. SETSP1:    JMP    J$INITMOD    ; Go set the speed, done
  5441. ;.....
  5442. ;
  5443. ;
  5444. ; Get a character from the keyboard, convert to upper-case if needed,
  5445. ; and show on CRT
  5446. ;
  5447. KBDCHR:    CALL    KEYIN        ; Get a keyboard character
  5448.     CALL    UCASE        ; Convert to upper case if needed
  5449.     CALL    TYPE        ; Show on CRT
  5450.     RET
  5451. ;.....
  5452. ;
  5453. ;
  5454. LCASE:    CPI    41H        ; Ignore if less than upper case 'A'
  5455.     RC
  5456.     CPI    5AH+1        ; Ignore if more than upper case 'Z'
  5457.     RNC
  5458.     ORI    20H        ; Change to lower case
  5459.     RET
  5460. ;.....
  5461. ;
  5462. ;
  5463. UCASE:    CPI    61H        ; Ignore if less than lower case 'a'
  5464.     RC
  5465.     CPI    7AH+1        ; Ignore if more than lower case 'z'
  5466.     RNC
  5467.     ANI    5FH        ; Else change lower ASCII to upper case
  5468.     RET
  5469. ;.....
  5470. ;
  5471. ;
  5472. ; Displays a string of chracters on the screen
  5473. ;
  5474. PRTMSG:    MVI    C,PRINT        ; Print the string
  5475.     JMP    BDOS
  5476. ;.....
  5477. ;
  5478. ;
  5479. ; Allows the TeleVideo 803 to use the RCVRDY routine for its special
  5480. ; receive-only status register.
  5481. ;
  5482. RCVRSP:    LXI    H,RCVRDY+1
  5483.     RET
  5484. ;.....
  5485. ;
  5486. ;
  5487. ; Displays the control-characters shown in the menu
  5488. ;
  5489. SHFTYPE:PUSH    PSW
  5490.     CALL    ILPRT
  5491.     DB    'ESC-',0
  5492.     POP    PSW
  5493.     CALL    TYPE        ; Show on the CRT
  5494.     JMP    ILPRT
  5495. ;.....
  5496. ;
  5497. ;
  5498. ; Sends the character in 'A' to the modem
  5499. ;
  5500. SNDCHR:    CALL    SNDNOW        ; Wait until modem is ready for char.
  5501.     MOV    A,B        ; Get the original character back
  5502.     JMP    O$MDDATP    ; Send the character to modem, return
  5503. ;.....
  5504. ;
  5505. ;
  5506. ; Initializes CP/M file control blocks AT 5CH and 6CH
  5507. ;
  5508. STFCB:    LXI    D,CMDBUF
  5509.     LXI    H,FCB
  5510.     JMP    CMDLINE
  5511. ;.....
  5512. ;
  5513. ;
  5514. ; Timer routine.  Waits 0.1 seconds for each unit in 'B' reg.
  5515. ;
  5516. TIMER:    PUSH    H
  5517. ;
  5518. TIMER1:    PUSH    B
  5519. ;
  5520. TIMER2:    CALL    J$INMDM        ; 100 ms. delay per loop
  5521.     JNC    TIMER2
  5522.     POP    B
  5523.     DCR    B
  5524.     JNZ    TIMER1
  5525.     POP    H
  5526.     RET
  5527. ;.....
  5528. ;
  5529. ;
  5530. ;=======================================================================
  5531. ;
  5532. ; Loads a command line addressed by 'DE' registers (max # characters in
  5533. ; line in 'DE', number of characters in line in DE+1, line starts in
  5534. ; DE+2) into FCB addressed by 'HL' registers.  The FCB should be at
  5535. ; least 33 bytes in length.  The command line buffer must have a maxi-
  5536. ; mum length at least one more than the greatest number of characters
  5537. ; that will be needed.
  5538.  
  5539. CMDLINE:PUSH    PSW
  5540.     PUSH    B
  5541.     PUSH    D
  5542.     PUSH    H
  5543.     CALL    INITIAL        ; Fills FCBs with blanks and nulls
  5544.     XCHG            ; Get start of command line in HL
  5545.     INX    H        ; Address # bytes in command line
  5546.     MOV    E,M        ; Load DE pair with # bytes
  5547.     MVI    D,0
  5548.     INX    H
  5549.     DAD    D        ; Point to byte after last character
  5550.     MVI    M,CR        ; In command line and store delimiter
  5551.     POP    H        ; Restore HL and DE
  5552.     POP    D
  5553.     PUSH    D
  5554.     PUSH    H
  5555.     INX    D        ; Address start of command
  5556.     INX    D
  5557.     CALL    DRIVE
  5558. ;
  5559.     MVI    C,8        ; Transfer first filename to FCB
  5560.     CALL    TRANS
  5561.     CPI    CR
  5562.     JZ    DONEL
  5563.     CPI    ' '        ; If space, then start of 2nd filename
  5564.     JZ    NAME1
  5565.     POP    H        ; Filetype starts after 8th byte
  5566.     PUSH    H
  5567.     LXI    B,9
  5568.     DAD    B
  5569.     MVI    C,3        ; Transfer type of first file
  5570.     CALL    TRANS
  5571.     CPI    CR
  5572.     JZ    DONEL
  5573. ;
  5574. NAME1:    LDAX    D        ; Eat multiple spaces between names
  5575.     CPI    ' '
  5576.     JNZ    NAME2
  5577.     INX    D
  5578.     JMP    NAME1
  5579. ;
  5580. NAME2:    POP    H        ; Second name starts in 16th byte
  5581.     PUSH    H        ; Point HL to this byte
  5582.     LXI    B,16
  5583.     DAD    B
  5584.     CALL    DRIVE
  5585.     MVI    C,8
  5586.     CALL    TRANS
  5587.     CPI    CR
  5588.     JZ    DONEL
  5589.     POP    H        ; Second file type starts in 25th byte
  5590.     PUSH    H
  5591.     LXI    B,25
  5592.     DAD    B
  5593.     MVI    C,3
  5594.     CALL    TRANS
  5595. ;
  5596. DONEL:    POP    H
  5597.     PUSH    H
  5598.     INX    H        ; Point to 1st char of 1st name in FCB
  5599.     CALL    SCANL        ; Check for * (ambiguous names)
  5600.     POP    H
  5601.     PUSH    H
  5602.     LXI    B,17        ; To 1st character of second name in FCB
  5603.     DAD    B
  5604.     CALL    SCANL
  5605.     POP    H
  5606.     POP    D
  5607.     POP    B
  5608.     POP    PSW
  5609.     RET
  5610. ;.....
  5611. ;
  5612. ;
  5613. ; Subroutines for CMDLINE section
  5614. ;
  5615. INITIAL:PUSH    H        ; Initializes FCB with 1 null for first
  5616.     PUSH    B        ; Drive with 11 blanks, 4 nulls, 1
  5617.     MVI    M,0        ; Null for second drive with 11 blanks
  5618.     INX    H        ; And 4 nulls
  5619.     MVI    B,11
  5620.     MVI    A,' '
  5621.     CALL    INITFILL
  5622.     MVI    B,5
  5623.     XRA    A
  5624.     CALL    INITFILL
  5625.     MVI    B,11
  5626.     MVI    A,' '
  5627.     CALL    INITFILL
  5628.     MVI    B,4
  5629.     XRA    A
  5630.     CALL    INITFILL
  5631.     POP    B
  5632.     POP    H
  5633.     RET
  5634. ;.....
  5635. ;
  5636. ;
  5637. INITFILL:
  5638.     MOV    M,A
  5639.     INX    H
  5640.     DCR    B
  5641.     JNZ    INITFILL
  5642.     RET
  5643. ;.....
  5644. ;
  5645. ;
  5646. DRIVE:    INX    D        ; Check 2nd byte of filename.  if it..
  5647.     LDAX    D        ; Is a ":", then drive was specified..
  5648.     DCX    D
  5649.     CPI    ':'
  5650.     JNZ    DEFDR        ; Else zero for default drive
  5651.     LDAX    D        ; ('INIT' put zero)
  5652.     ANI    5FH
  5653.     SUI    40H        ; Calculate drive (A=1, B=2,...)
  5654.     MOV    M,A        ; Place it in FCB
  5655.     INX    D        ; Address first byte in command line
  5656.     INX    D
  5657. ;
  5658. DEFDR:    INX    H        ; And name field in FCB
  5659.     RET
  5660. ;.....
  5661. ;
  5662. ;
  5663. TRANS:    LDAX    D        ; Transfer from command line to FCB
  5664.     INX    D        ; Up to number of chars specified
  5665.     CPI    CR        ; By 'C' reg.    Keep scanning field
  5666.     RZ            ; Without transfer until a delimiting
  5667.     CPI    '.'        ; Field char such as '.', blank, or
  5668.     RZ            ; CR (for end of commmand line).
  5669.     CPI    ' '
  5670.     RZ
  5671.     DCR    C
  5672.     JM    TRANS        ; Once C-reg is less than zero, keep
  5673.     MOV    M,A        ; Reading command line but do not
  5674.     INX    H        ; Transfer to FCB.
  5675.     JMP    TRANS
  5676. ;...
  5677. ;
  5678. ;
  5679. SCANL:    MVI    B,8        ; Scan file name addressed by HL
  5680. ;
  5681. TSTNAM:    MOV    A,M
  5682.     CPI    '*'        ; If '*' found, fill in rest of field
  5683.     JZ    FILL1        ; With '?' for ambiguous name.
  5684.     INX    H
  5685.     DCR    B
  5686.     JNZ    TSTNAM
  5687.     JMP    TSTTYP
  5688. ;...
  5689. ;
  5690. ;
  5691. FILL1:    CALL    FILL
  5692. ;
  5693. TSTTYP:    MVI    B,3        ; Scan and fill type field for name
  5694. ;
  5695. TSTTYPL:MOV    A,M
  5696.     CPI    '*'
  5697.     JZ    FILL2
  5698.     INX    H
  5699.     DCR    B
  5700.     JNZ    TSTTYPL
  5701.     RET
  5702. ;.....
  5703. ;
  5704. ;
  5705. FILL2:    CALL    FILL
  5706.     RET
  5707. ;.....
  5708. ;
  5709. ;
  5710. FILL:    MVI    M,'?'        ; Routine transfers '?'
  5711.     INX    H
  5712.     DCR    B
  5713.     JNZ    FILL
  5714.     RET
  5715.  
  5716. ;=======================================================================
  5717. ;
  5718. ; LISTS DIRECTORY AND GIVES FREE SPACE REMAINING ON THE REQUESTED DRIVE.
  5719. ;
  5720. ;
  5721. ; Disk system reset - currently bypassed, if you wish this feature, put
  5722. ;    JMP DRLST2 instead of JMP DRLST3 in the eighth line.  The
  5723. ;    current disk (plus the A: drive) will then reset each DIR re-
  5724. ;    quest.    You can also reset the disk with the LOG command when
  5725. ;    when inserting a different one.  This saves a reset each time
  5726. ;    DIR might be requested.
  5727. ;
  5728. DRLST:    CALL    GETDISK
  5729.     ADI    'A'        ; Change to ASCII
  5730.     STA    DRNAME        ; Show for drive name
  5731.     STA    ACTDRV        ; Show for space remaining on drive
  5732.     JMP    DRLST1
  5733.     MVI    C,RESET        ; 13 reset disk system (resetdk)
  5734.     CALL    BDOS
  5735. ;
  5736. ;
  5737. ; Directory list routine
  5738. ;
  5739. DRLST1:    LXI    D,CMDBUF    ; Put command line in FCB
  5740.     LXI    H,FCB
  5741.     CALL    CMDLINE
  5742.     LXI    H,FCB4
  5743.     CALL    INITFCB
  5744.     LDA    FCB2        ; Get drive number
  5745.     STA    FCB4
  5746.     LDA    FCB2+1
  5747.     CPI    ' '        ; If a space (blank) get all names
  5748.     PUSH    PSW
  5749.     CZ    QSTMARK
  5750.     POP    PSW
  5751.     CNZ    MOVNAME        ; Else move name into FCB
  5752.     CALL    DRIVEL
  5753.     MVI    C,STDMA
  5754.     LXI    D,TBUF
  5755.     CALL    BDOS
  5756.     LDA    NOFCOL        ; Number of columns into 'A' register
  5757.     STA    NAMECT        ; CRLF after 'NOFCOL' number of columns
  5758.     LXI    D,FCB4
  5759.     MVI    C,SRCHF        ; Do first search
  5760.     CALL    BDOS
  5761.     INR    A        ; 0FFH --> 0 if no file(s) found
  5762.     JNZ    DIRLOOP
  5763.     CALL    ILPRT
  5764.     DB    '++ FILE NOT FOUND ++',0
  5765.     JMP    STORAGE        ; Still show storage on default drive
  5766. ;
  5767. DIRLOOP:CALL    GETADD
  5768.     INX    H        ; Point to first letter of filename
  5769.     LXI    D,PRTNAME
  5770.     LXI    B,8
  5771.     CALL    MOVER
  5772.     INX    D
  5773.     LXI    B,3
  5774.     CALL    MOVER
  5775.     CALL    ILPRT
  5776. ;
  5777. PRTNAME:DB    '        ','.','   ',0 ; 8 spaces, period, 3 spaces
  5778. ;
  5779. NEXTSR:    LXI    D,FCB4
  5780.     MVI    C,SRCHN        ; Do next search
  5781.     CALL    BDOS
  5782.     INR    A        ; If 0FFH --> 0 directory read is done
  5783.     JZ    STORAGE
  5784.     PUSH    PSW
  5785.     PUSH    D
  5786.     PUSH    H
  5787.     LDA    NAMECT
  5788.     DCR    A
  5789.     STA    NAMECT        ; Name count updated
  5790.     ORA    A
  5791.     CZ    CRLF        ; Terminate line of file names
  5792.     JNZ    FENCE
  5793.     LDA    NOFCOL        ; Restart columns-per-line count
  5794.     STA    NAMECT
  5795.     JMP    NOFENCE        ; Fence not needed
  5796. ;
  5797. FENCE:    CALL    ILPRT
  5798.     DB    ' : ',0        ; Fence if not at end of line or
  5799. ;                ;   last filename
  5800. NOFENCE:POP    H
  5801.     POP    D
  5802.     POP    PSW
  5803.     JMP    DIRLOOP
  5804. ;.....
  5805. ;
  5806. ;
  5807. ; Determine storage remaining on default drive
  5808. ;
  5809. STORAGE:CALL    CKCPM3
  5810.     MVI    C,DSKPAR    ; Current disk parameter block
  5811.     CALL    BDOS
  5812.     INX    H
  5813.     INX    H
  5814.     MOV    A,M        ; Get block shift factor
  5815.     STA    BSHIFTF
  5816.     INX    H        ; Bump to block mask
  5817.     MOV    A,M        ; Get it
  5818.     STA    BMASK
  5819.     INX    H
  5820.     INX    H
  5821.     MOV    E,M        ; Get maximum block number
  5822.     INX    H
  5823.     MOV    D,M
  5824.     XCHG
  5825.     SHLD    BMAX        ; Put it away
  5826.     MVI    C,DSKALL    ; Address of CP/M allocation vector
  5827.     CALL    BDOS
  5828.     XCHG            ; Get its length
  5829.     LHLD    BMAX
  5830.     INX    H
  5831.     LXI    B,0        ; Initialize block count to zero
  5832. ;
  5833. GSPBYT:    PUSH    D        ; Save allocation address
  5834.     LDAX    D
  5835.     MVI    E,8        ; Set to process 8 blocks
  5836. ;
  5837. GSPLUP:    RAL            ; Test bit
  5838.     JC    NOTFRE
  5839.     INX    B
  5840. ;
  5841. NOTFRE:    MOV    D,A        ; Save bits
  5842.     DCX    H
  5843.     MOV    A,L
  5844.     ORA    H
  5845.     JZ    ENDALC        ; Quit if out of blocks
  5846.     MOV    A,D        ; Restore bits
  5847.     DCR    E        ; Count down 8 bits
  5848.     JNZ    GSPLUP        ; Do another bit
  5849.     POP    D        ; Next count of allocation vector
  5850.     INX    D
  5851.     JMP    GSPBYT        ; Process it
  5852. ;
  5853. ENDALC:    POP    D        ; Clear alloc vector pointer from stack
  5854.     MOV    L,C        ; Copy block to HL
  5855.     MOV    H,B
  5856.     LDA    BSHIFTF        ; Get block shift factor
  5857.     SUI    3        ; Convert from records to thousands (k)
  5858.     JZ    PRTFREE        ; Skip shifts if 1k blocks
  5859. ;
  5860. FREKLP:    DAD    H        ; Multiply blocks by 'k' per block
  5861.     DCR    A
  5862.     JNZ    FREKLP
  5863. ;
  5864. PRTFREE:CALL    DECOUT        ; (number of free 'k' bytes now in 'HL')
  5865.     LXI    D,FREEMSG
  5866.     JMP    PRTMSG
  5867. ;.....
  5868. ;
  5869. ;
  5870. ; Subroutines for 'DRLST' section
  5871. ;
  5872. QSTMARK:MVI    A,'?'        ; If blank in FCB, put in 11 ?'S
  5873.     MVI    B,11
  5874.     LXI    H,FCB4+1
  5875. ;
  5876. QSTLP:    MOV    M,A
  5877.     INX    H
  5878.     DCR    B
  5879.     JNZ    QSTLP
  5880.     RET
  5881. ;.....
  5882. ;
  5883. ;
  5884. MOVNAME:LXI    H,FCB2+1
  5885.     LXI    D,FCB4+1
  5886.     LXI    B,11
  5887.     CALL    MOVER
  5888.     RET
  5889. ;.....
  5890. ;
  5891. ;
  5892. GETADD:    DCR    A        ; Undo the INR above
  5893.     ADD    A        ; Times 32
  5894.     ADD    A
  5895.     ADD    A
  5896.     ADD    A
  5897.     ADD    A
  5898.     ADI    TBUF        ; Add buffer offset
  5899.     MOV    L,A
  5900.     MVI    H,0
  5901.     RET
  5902. ;.....
  5903. ;
  5904. ;
  5905. DRIVEL:    LDA    FCB4        ; Use default drive in DRNAME
  5906.     ORA    A
  5907.     JZ    PRNTHD
  5908.     PUSH    PSW
  5909.     DCR    A
  5910.     MOV    E,A
  5911.     MVI    C,SELDSK
  5912.     CALL    BDOS
  5913.     POP    PSW
  5914.     ADI    40H        ; Make 1=A, 2=B, etc.
  5915.     STA    DRNAME        ; Overwrite default stored below
  5916.     STA    ACTDRV
  5917. ;
  5918. PRNTHD:    CALL    ILPRT
  5919.     DB    'Drive '
  5920. ;
  5921. DRNAME:    DB    ' :',CR,LF,0
  5922.     RET
  5923. ;.....
  5924. ;
  5925. ;
  5926. ; Initialized storage
  5927. ;
  5928. FREEMSG:DB    'k bytes free on drive '
  5929. ACTDRV:    DB    ' :',CR,LF,'$'
  5930. ;
  5931. ;
  5932. ; Uninitialized storage
  5933. ;
  5934. BMAX:    DB    0,0        ; Highest block number on drive
  5935. BMASK:    DB    0        ; Rec/blk - 1
  5936. BSHIFTF:DB    0        ; # of shifts to multiply by rec/blk
  5937. ;.....
  5938. ;
  5939. ;
  5940. ; CALCULATES DISK SPACE REMAINING IF CP/M+
  5941. ;
  5942. CKCPM3:    CALL    CRLF
  5943.     MVI    C,CPMVER    ; Check version #
  5944.     CALL    BDOS
  5945.     MOV    A,L
  5946.     CPI    30H        ; Version 3.0?
  5947.     RC            ; Use normal method if not CP/M+
  5948.     POP    H        ; Remove "call CKCPM3" from stack
  5949.     MVI    C,CURDSK
  5950.     CALL    BDOS
  5951.     MOV    E,A
  5952.     MVI    C,46        ; CP/M+ compute free space call
  5953.     CALL    BDOS
  5954.     MVI    C,3        ; Answer is 3 bytes long (24 bits)
  5955. ;
  5956. FREE30:    LXI    H,TBUF+2    ; Answer is located here
  5957.     MVI    B,3        ; Convert to 'k' length
  5958.     ORA    A
  5959. ;
  5960. FREE31:    MOV    A,M
  5961.     RAR
  5962.     MOV    M,A
  5963.     DCX    H
  5964.     DCR    B
  5965.     JNZ    FREE31        ; Loop for 3 bytes
  5966.     DCR    C
  5967.     JNZ    FREE30        ; Shift 3 times
  5968.     LHLD    TBUF        ; Get result in 'k'
  5969.     JMP    PRTFREE        ; Display result
  5970. ;.....
  5971. ;
  5972. ;            end of directory routine
  5973. ;=======================================================================
  5974. ;
  5975. ; Duplicates 'READ BUFFER' routine same as CP/M function 10, but does
  5976. ; not use CTL-C (reason for the routine).  Does allow controls U, R and
  5977. ; H (BACKSPACE).  Outputs bell if the input is greater than the buffer.
  5978. ;
  5979. INBUF:    PUSH    PSW
  5980.     PUSH    H
  5981.     PUSH    B
  5982.     PUSH    D        ; 'DE' registers must be pushed last
  5983. ;
  5984. INBUFA:    CALL    CLEARBUF    ; Clear the buffer area
  5985.     POP    D        ; Get address of buffer on retries
  5986.     PUSH    D        ; Restore stack
  5987.     XRA    A
  5988.     INX    D        ; Address count field
  5989.     STAX    D        ; Initialize with a zero in count byte
  5990.     INX    D
  5991.     XCHG            ; Address first buffer byte with 'HL'
  5992. ;
  5993. INBUFB:    CALL    KEYIN        ; Waits for a charcter
  5994.     CALL    UCASE        ; Convert to upper case if needed
  5995.     CPI    CR        ; Is it <return> (enter command)?
  5996.     JZ    INBUFR        ; If so, then return
  5997.     CPI    'H'-40H        ; CTL-H backspaces over deleted char.
  5998.     JZ    DELETE
  5999.     CPI    7FH        ; Is it a delete?
  6000.     JZ    DELETE
  6001.     CPI    'U'-40H        ; Is it a CTL-U?
  6002.     JZ    INBUFO        ; Output #, CR, LF, and start over
  6003.     CPI    'R'-40H        ; CTL-R retypes line
  6004.     JZ    RETYPE
  6005.     CPI    CLEARSC        ; Want to clear CRT?
  6006.     JZ    CLRS        ; If yes, go clear screen
  6007. ;
  6008.     MOV    B,A        ; Save inputted character
  6009.     XCHG            ; Save 'HL' in 'DE'
  6010.     POP    H        ; Get address of buffer in 'HL'
  6011.     PUSH    H        ; Restore stack
  6012.     INX    H        ; Address count byte
  6013.     INR    M        ; Increase count byte
  6014.     DCX    H        ; Address maximum
  6015.     MOV    A,M        ; Put maximum in 'A'
  6016.     INX    H        ; Address count
  6017.     CMP    M        ; Compare count to maximum
  6018.     JC    ALERTL        ; If maximum, ring bell and wait for CR
  6019.     XCHG            ; Restore buffer pointer to 'HL'
  6020.     MOV    M,B        ; Put inputted character in buffer
  6021.     MOV    A,B        ; Output it
  6022.     CPI    20H        ; Printing character?
  6023.     CNC    TYPE        ; If yes, print it
  6024.     INX    H        ; Bump pointer
  6025.     JMP    INBUFB        ; Get next character
  6026. ;...
  6027. ;
  6028. ;
  6029. DELETE:    XCHG            ; Save buffer pointer in 'DE'
  6030.     POP    H        ; Address beginning of buffer
  6031.     PUSH    H        ; Restore stack
  6032.     INX    H        ; Address count field
  6033.     MOV    A,M
  6034.     SUI    1        ; Decrease count
  6035.     MOV    M,A
  6036.     JC    NODEL        ; Don't delete past beginning of buffer
  6037.     XCHG            ; Restore buffer pointer to 'HL'
  6038.     DCX    H        ; Point to last byte inputted
  6039.     MOV    A,M        ; Get the character being deleted
  6040.     MVI    M,' '        ; Restore blank
  6041.     CPI    ' '        ; See if a non-printing character
  6042.     JC    INBUFB        ; If yes, skip the CRT backup
  6043.     MVI    A,BKSP
  6044.     CALL    TYPE        ; True erase if 08H
  6045.     MVI    A,' '
  6046.     CALL    TYPE
  6047.     MVI    A,BKSP
  6048.     CALL    TYPE
  6049.     JMP    INBUFB
  6050. ;.....
  6051. ;
  6052. ;
  6053. NODEL:    INR    M        ; Don't leave count negative
  6054.     XCHG            ; Restore pointer to 'HL'
  6055.     MVI    A,BELL        ; Says can go no further
  6056.     CALL    TYPE
  6057.     JMP    INBUFB
  6058. ;.....
  6059. ;
  6060. ;
  6061. INBUFO:    MVI    A,'#'        ; Announces the line has been removed
  6062.     CALL    TYPE
  6063.     CALL    CRLF
  6064.     JMP    INBUFA
  6065. ;.....
  6066. ;
  6067. ;
  6068. RETYPE:    POP    D
  6069.     PUSH    D
  6070.     INX    D        ; Point to current number of characters
  6071.     LDAX    D
  6072.     MOV    B,A
  6073.     MVI    A,'#'
  6074.     CALL    TYPE
  6075.     CALL    CRLF
  6076.     MOV    A,B        ; Test if zero input
  6077.     ORA    A
  6078.     JZ    INBUFB
  6079. ;...
  6080. ;
  6081. ;
  6082. CTLRLP:    INX    D
  6083.     LDAX    D
  6084.     CALL    TYPE
  6085.     DCR    B
  6086.     JNZ    CTLRLP
  6087.     JMP    INBUFB
  6088. ;.....
  6089. ;
  6090. ;
  6091. ALERTL:    MVI    A,BELL        ; Alarm for full buffer
  6092.     CALL    TYPE
  6093.     DCR    M
  6094.     XCHG
  6095.     JMP    INBUFB
  6096. ;.....
  6097. ;
  6098. ;
  6099. INBUFR:    CALL    CRLF        ; 1st new line after a command character
  6100.     POP    D
  6101.     POP    B
  6102.     POP    H
  6103.     POP    PSW
  6104.     RET
  6105. ;.....
  6106. ;
  6107. ;
  6108. CLEARBUF:
  6109.     POP    D        ; Accounts for call
  6110.     POP    H        ; Address buffer in 'HL'
  6111.     PUSH    H        ; Restore stack
  6112.     PUSH    D
  6113.     MOV    B,M        ; Save maximum in 'B'
  6114.     INX    H        ; Point to first buffer byte
  6115.     INX    H
  6116.     MVI    A,' '
  6117. ;
  6118. CLEARL:    MOV    M,A
  6119.     INX    H
  6120.     DCR    B
  6121.     JNZ    CLEARL
  6122.     RET
  6123. ;.....
  6124. ;
  6125. ;
  6126. ;=======================================================================
  6127. ;
  6128. ; In-line compare.  Compares string addressed by 'DE' to string after
  6129. ; call (ends with zero).  Return with carry set means strings not the
  6130. ; same.  All registers except 'A'-reg are unaffected.
  6131. ;
  6132. INLNCP:    XTHL            ; Point 'HL' to 1st character
  6133.     PUSH    D
  6134. ;
  6135. ILCOMPL:MOV    A,M        ; 'HL' points to in-line string
  6136.     ORA    A        ; End of string if zero
  6137.     JZ    SAME
  6138.     LDAX    D
  6139.     CMP    M
  6140.     JNZ    NOTSAME
  6141.     INX    H
  6142.     INX    D
  6143.     JMP    ILCOMPL
  6144. ;...
  6145. ;
  6146. ;
  6147. NOTSAME:XRA    A
  6148. ;
  6149. NSLP:    INX    H
  6150.     CMP    M
  6151.     JNZ    NSLP
  6152.     STC
  6153. ;
  6154. SAME:    POP    D
  6155.     INX    H        ; Avoids a NOP instruction when done
  6156.     XTHL
  6157.     RET
  6158. ;.....
  6159. ;
  6160. ;
  6161. ;=======================================================================
  6162. ;          MULTI-FILE ACCESS ROUTINE
  6163. ;
  6164. ; Multi-file access subroutine.  Allows processing of multiple files
  6165. ; (i.e., *.ASM) from disk.  Builds the correct name in the FCB each time
  6166. ; it is called.  The command is used in programs to process single or
  6167. ; multiple files.  The FCB is set up with the next name, ready to do
  6168. ; normal processing (open, read, etc.) when routine is called.    Carry is
  6169. ; set if no more names are found.
  6170.  
  6171. MFNAM:    PUSH    B
  6172.     PUSH    D
  6173.     PUSH    H
  6174.     MVI    C,STDMA
  6175.     LXI    D,TBUF
  6176.     CALL    BDOS
  6177.     POP    H
  6178.     POP    D
  6179.     POP    B
  6180.     XRA    A
  6181.     STA    FCBEXT
  6182.     LDA    MFFLG1
  6183.     ORA    A
  6184.     JNZ    MFNAM1
  6185.     MVI    A,1
  6186.     STA    MFFLG1
  6187.     LXI    H,FCB
  6188.     LXI    D,MFNAM5
  6189.     LXI    B,12
  6190.     CALL    MOVER
  6191.     LDA    FCB
  6192.     STA    MFNAM6        ; Save disk in current FCB
  6193.     LXI    H,MFNAM5
  6194.     LXI    D,FCB
  6195.     LXI    B,12
  6196.     CALL    MOVER
  6197.     PUSH    B
  6198.     PUSH    D
  6199.     PUSH    H
  6200.     MVI    C,SRCHF
  6201.     LXI    D,FCB
  6202.     CALL    BDOS
  6203.     POP    H
  6204.     POP    D
  6205.     POP    B
  6206.     JMP    MFNAM2
  6207. ;...
  6208. ;
  6209. ;
  6210. MFNAM1:    LXI    H,MFNAM6
  6211.     LXI    D,FCB
  6212.     LXI    B,12
  6213.     CALL    MOVER
  6214.     PUSH    B
  6215.     PUSH    D
  6216.     PUSH    H
  6217.     MVI    C,SRCHF
  6218.     LXI    D,FCB
  6219.     CALL    BDOS
  6220.     POP    H
  6221.     POP    D
  6222.     POP    B
  6223.     LXI    H,MFNAM5
  6224.     LXI    D,FCB
  6225.     LXI    B,12
  6226.     CALL    MOVER
  6227.     PUSH    B
  6228.     PUSH    D
  6229.     PUSH    H
  6230.     MVI    C,SRCHN
  6231.     LXI    D,FCB
  6232.     CALL    BDOS
  6233.     POP    H
  6234.     POP    D
  6235.     POP    B
  6236. ;
  6237. MFNAM2:    INR    A
  6238.     STC
  6239.     JNZ    MFNAM3
  6240.     STA    MFFLG1
  6241.     RET
  6242. ;.....
  6243. ;
  6244. ;
  6245. MFNAM3:    DCR    A
  6246.     ANI    3
  6247.     ADD    A
  6248.     ADD    A
  6249.     ADD    A
  6250.     ADD    A
  6251.     ADD    A
  6252.     ADI    81H
  6253.     MOV    L,A
  6254.     MVI    H,0
  6255.     PUSH    H        ; Save name pointer
  6256.     LXI    D,MFNAM6+1
  6257.     LXI    B,11
  6258.     CALL    MOVER
  6259.     POP    H
  6260.     LXI    D,FCB+1
  6261.     LXI    B,11
  6262.     CALL    MOVER
  6263.     XRA    A
  6264.     STA    FCBEXT
  6265.     STA    FCBRNO
  6266.     RET
  6267. ;.....
  6268. ;
  6269. ;
  6270. MOVER:    MVI    A,2
  6271.     INR    A
  6272.     JPE    MFNAM4
  6273.     DB    0EDH,0B0H    ; Z-80 'LDIR' instruction
  6274.     RET
  6275. ;.....
  6276. ;
  6277. ;
  6278. MFNAM4:    MOV    A,M        ; Used if an 8080 CPU is active
  6279.     STAX    D
  6280.     INX    H
  6281.     INX    D
  6282.     DCX    B
  6283.     MOV    A,B
  6284.     ORA    C
  6285.     JNZ    MFNAM4
  6286.     RET
  6287. ;.....
  6288. ;
  6289. ;        (END OF MULTI-FILE ACCESS ROUTINE)
  6290. ;=======================================================================
  6291. ;         CALCULATE FILE TRANSFER TIME
  6292. ;
  6293. ;
  6294. ; Shows the time to transfer a file at various baud rates.  (110-19200)
  6295. ;
  6296. SNDTM:    CALL    ILPRT
  6297.     DB    'File open: ',0
  6298.     LHLD    RCNT        ; Get record count
  6299.     CALL    DECOUT        ; Print decimal number of records
  6300.     PUSH    H
  6301.     CALL    ILPRT
  6302.     DB    ' records (',0
  6303.     POP    H        ; Get # of 128 byte records
  6304.     LXI    D,8        ; Divide by 8
  6305.     CALL    DVHLDE        ; To get # of 1024 byte blocks
  6306.     MOV    A,H
  6307.     ORA    L        ; Check if remainder
  6308.     MOV    H,B        ; Get quotient
  6309.     MOV    L,C
  6310.     JZ    $+4        ; If 0 remainder, exact kilobytes
  6311.     INX    H        ; Else, increment to next 'k'
  6312.     CALL    DECOUT        ; Show # of kilobytes
  6313.     LDA    SNDFLG        ; Receiving batch mode now?
  6314.     ORA    A
  6315.     RNZ            ; If yes, all done
  6316. ;
  6317. ;
  6318. ; Show transfer time, first for 1k blocks, then for 128 (skip the 1k
  6319. ; times for slower than 1200 bps.)for 1200 bps
  6320. ;
  6321.     CALL    ILPRT
  6322.     DB    'k)',CR,LF,'Send time: ',0
  6323. ;
  6324.     LDA    MSPEED
  6325.     CPI    5        ; 1200 bps
  6326.     JC    XMDSPD        ; Skip KMD speed if less than 1200 bps
  6327. ;
  6328. KMDSPD:    LXI    H,KECTBL
  6329.     SHLD    RECTBL+1
  6330.     CALL    KTIM        ; Get file transfer time in BC (minutes)
  6331.     CALL    SNDTM1
  6332.     CALL    ILPRT
  6333.     DB    ' - 1k size',CR,LF,'Send time: ',0
  6334. ;
  6335. XMDSPD:    LXI    H,XECTBL
  6336.     SHLD    RECTBL+1
  6337.     CALL    XTIM        ; Get file transfer time in BC (minutes)
  6338.     CALL    SNDTM1
  6339.     CALL    ILPRT
  6340.     DB    ' - 128 size',CR,LF,CR,LF,0
  6341.     CALL    FILNAM
  6342.     CALL    ILPRT
  6343.     DB    CR,LF,'File open, ready to send',CR,LF,0
  6344.     RET
  6345. ;.....
  6346. ;
  6347. ;
  6348. SNDTM1:    PUSH    H        ; Save seconds in 'L'
  6349.     MOV    L,C
  6350.     MOV    H,B
  6351.     CALL    DECOUT        ; Print decimal number of minutes
  6352.     CALL    ILPRT
  6353.     DB    ':',0
  6354.     POP    H        ; Get seconds
  6355. ;
  6356.     CALL    ZERO        ; See if 10 or more seconds
  6357.     CALL    DECOUT        ; Print the seconds portion
  6358.     CALL    ILPRT
  6359.     DB    ' at ',0
  6360.     CALL    PRTBAUD
  6361.     RET
  6362. ;.....
  6363. ;
  6364. ;
  6365. PRTBAUD:LXI    H,SPTBL        ; Start of baud rate speeds
  6366.     MVI    D,0        ; Zero the 'D' register
  6367.     LDA    MSPEED        ; Get speed indicator
  6368.     ADD    A        ; Index into the baud rate table
  6369.     ADD    A
  6370.     MOV    E,A        ; Now have the index factor in 'DE'
  6371.     DAD    D        ; Add to 'HL'
  6372.     XCHG            ; Put address in 'DE' regs.
  6373.     MVI    C,PRINT        ; Show the baud
  6374.     CALL    BDOS
  6375.     LDA    MSPEED
  6376.     CPI    5
  6377.     JC    PRTBD1        ; Adds a zero for 2400, 4800, 9600 bps
  6378.     CALL    ILPRT
  6379.     DB    '0',0
  6380. ;
  6381. PRTBD1:    CALL    ILPRT
  6382.     DB    ' bps',0
  6383.     RET
  6384. ;.....
  6385. ;
  6386. ;
  6387. KTABLE:     IF    NOT STOPBIT    ; One stop bit
  6388.     DW    5,14,21,27,32,54,101,190,330,525,0
  6389.      ENDIF            ; NOT STOPBIT
  6390. ;
  6391.      IF    STOPBIT        ; Two stop bits
  6392.     DW    5,13,19,25,29,49,92,173,300,477,0
  6393.      ENDIF            ; STOPBIT
  6394.  
  6395. KECTBL:     IF    NOT STOPBIT    ; One stop bit
  6396.     DB    192,69,46,36,30,18,9,5,3,2,0
  6397.      ENDIF            ; NOT STOPBIT
  6398. ;
  6399.      IF    STOPBIT        ; Two stop bits
  6400.     DB    192,74,51,38,33,20,10,6,3,2,0
  6401.      ENDIF            ; STOPBIT
  6402. ;
  6403. ;
  6404. XTABLE:     IF    NOT STOPBIT    ; One stop bit
  6405.     DW    5,13,19,25,30,48,86,141,210,280,0
  6406.      ENDIF            ; NOT STOPBIT
  6407. ;
  6408.      IF    STOPBIT        ; Two stop bits
  6409.     DW    5,12,18,23,27,44,79,128,191,255,0
  6410.      ENDIF            ; STOPBIT
  6411.  
  6412. XECTBL:     IF    NOT STOPBIT    ; One stop bit
  6413.     DB    192,74,51,38,32,20,11,8,5,3,0
  6414.      ENDIF            ; NOT STOPBIT
  6415. ;
  6416.      IF    STOPBIT        ; Two stop bits
  6417.     DB    192,80,53,42,36,22,12,7,5,4,0
  6418.      ENDIF            ; STOPBIT
  6419. ;
  6420. SPTBL:    DB    '110$','300$','450$','600$','710$','120$','240$'
  6421.     DB    '480$','960$','1920$'
  6422. ;.....
  6423. ;
  6424. ;
  6425. ; Pass record count in RCNT: returns file's approximate download/upload
  6426. ; time in minutes in BC, seconds in 'L', also stuffs the # of mins/secs
  6427. ; values in PGSIZE if LOGCAL is YES.
  6428. ;
  6429. KTIM:    LXI    H,KTABLE
  6430.     JMP    FILTIM
  6431. ;
  6432. XTIM:    LXI    H,XTABLE    ; Point to baud factor table
  6433. ;
  6434. FILTIM:    LDA    MSPEED        ; Get speed indicator
  6435.     MVI    D,0
  6436.     MOV    E,A        ; Set up for table access
  6437.     DAD    D        ; Index to proper factor
  6438.     DAD    D
  6439.     MOV    E,M
  6440.     INX    H
  6441.     MOV    D,M
  6442.     LHLD    RCNT        ; Get number of records
  6443.     CALL    DVHLDE        ; Divide HL by value in DE (records/min)
  6444.     PUSH    H        ; Save remainder
  6445. ;
  6446. RECTBL:    LXI    H,KECTBL    ; Point to divisors for seconds calc.
  6447.     MVI    D,0
  6448.     LDA    MSPEED        ; Get speed indicator
  6449.     MOV    E,A
  6450.     DAD    D        ; Index into table
  6451.     MOV    A,M        ; Get multiplier
  6452.     POP    H        ; Get remainder
  6453.     CALL    MULHLA        ; Multiply 'H' by 'A'
  6454.     CALL    SHFTHL
  6455.     CALL    SHFTHL
  6456.     CALL    SHFTHL
  6457.     CALL    SHFTHL
  6458.     MVI    H,0        ; HL now = seconds (L=secs,H=0)
  6459.     MOV    A,L        ; See if 59 or less seconds
  6460.     CPI    60
  6461.     RC            ; If yes, all done
  6462.     SUI    60        ; Otherwise subtract 60 seconds
  6463.     MOV    L,A        ; Store what is left
  6464.     INR    C        ; Increments the minutes count
  6465.     RET            ; End of SNDTM routine
  6466. ;.....
  6467. ;
  6468. ;
  6469. ZERO:    MOV    A,L        ; Get the number of seconds
  6470.     CPI    9+1        ; 10 seconds or more?
  6471.     RNC            ; If yes, disregard
  6472.     CALL    ILPRT
  6473.     DB    '0',0
  6474.     RET
  6475. ;.....
  6476. ;
  6477. ;
  6478. ;---->    DVHLDE: Divides 'HL' by value in 'DE',
  6479. ;    Upon exit: 'BC'=quotient,'L'=remainder
  6480. ;
  6481. DVHLDE:    PUSH    D        ; Save divisor
  6482.     MOV    A,E
  6483.     CMA            ; Negate divisor
  6484.     MOV    E,A
  6485.     MOV    A,D
  6486.     CMA
  6487.     MOV    D,A
  6488.     INX    D        ; 'DE' is now two's complemented
  6489.     LXI    B,0        ; Init quotient
  6490. ;
  6491. DIVL1:    DAD    D        ; Subtract divisor from dividend
  6492.     INX    B        ; Bump quotient
  6493.     JC    DIVL1        ; Loop till sign changes
  6494.     DCX    B        ; Adjust quotient
  6495.     POP    D        ; Retrieve divisor
  6496.     DAD    D        ; Adjust remainder
  6497.     RET
  6498. ;.....
  6499. ;
  6500. ;
  6501. ;---->    MULHLA:  Multiply the value in 'HL' by the value in 'A'
  6502. ;         Return with answer in 'HL'
  6503. ;
  6504. MULHLA:    XCHG            ; Multiplicand to 'DE'
  6505.     LXI    H,0        ; Init product
  6506.     INR    A        ; Adjust multiplier for zero test
  6507. ;
  6508. MULLP:    DCR    A
  6509.     RZ
  6510.     DAD    D
  6511.     JMP    MULLP
  6512. ;.....
  6513. ;
  6514. ;
  6515. ; Shift 'HL' register pair one bit to the right
  6516. ;
  6517. SHFTHL:    MOV    A,L
  6518.     RAR
  6519.     MOV    L,A
  6520.     ORA    A        ; Clear the carry
  6521.     MOV    A,H
  6522.     RAR
  6523.     MOV    H,A
  6524.     RNC
  6525.     MVI    A,128
  6526.     ORA    L
  6527.     MOV    L,A
  6528.     RET
  6529. ;.....
  6530. ;
  6531. ;        (END OF FILE TRANSFER TIME ROUTINE)
  6532. ;=======================================================================
  6533. ;             CRC SUBROUTINES
  6534. ;
  6535. ;
  6536. ; Check 'CRC' bytes of record just received
  6537. ;
  6538. CRCCHK:    PUSH    H
  6539.     LHLD    CRCVAL
  6540.     MOV    A,H
  6541.     ORA    L
  6542.     POP    H
  6543.     RZ
  6544.     MVI    A,0FFH
  6545.     RET
  6546. ;.....
  6547. ;
  6548. ;
  6549. ; Generate the CRC tables for fast calculations
  6550. ;
  6551. CRCGN:    LXI    H,CRCTBL    ; Address at start of 'CRC' lookup table
  6552.     MVI    C,0
  6553. ;
  6554. CRCGN1:    XCHG            ; Store table location into 'DE'
  6555.     LXI    H,0        ; Clear 'HL' pair
  6556.     MOV    A,C
  6557.     PUSH    B
  6558.     MVI    B,8
  6559.     XRA    H
  6560.     MOV    H,A
  6561. ;
  6562. CRCGN2:    DAD    H        ; Index into the table
  6563.     JNC    CRCGN3
  6564.     MVI    A,16        ; Using x^ 16 + x^12 + x^5 + 1 algorithm
  6565.     XRA    H
  6566.     MOV    H,A
  6567.     MVI    A,32+1
  6568.     XRA    L
  6569.     MOV    L,A
  6570. ;
  6571. CRCGN3:    DCR    B
  6572.     JNZ    CRCGN2        ; Make 8 loops, one for each bit
  6573. ;
  6574. ;
  6575. ; Value now in 'HL', table address still stored in 'DE'.  Exchange, and
  6576. ; store the 'CRC' value in the two tables after splitting.
  6577. ;
  6578.     POP    B        ; Finished borrowing the 'B' reg.
  6579.     XCHG            ; Address back in 'HL', 'CRC' in 'DE'
  6580.     MOV    M,D        ; Store 1st part of 'CRC' value
  6581.     INR    H        ; Move up 256 bytes
  6582.     MOV    M,E        ; Store 2nd part of 'CRC' value
  6583.     DCR    H        ; Move back 256 bytes
  6584.     INX    H        ; Increment to next location
  6585.     INR    C        ; Done when 'C' reg. turns zero again
  6586.     JNZ    CRCGN1        ; Now go do the next location
  6587.     RET
  6588. ;.....
  6589. ;
  6590. ;
  6591. ; Update the CRC value from a character in the 'A' register
  6592. ;
  6593. CRCUPD:    PUSH    PSW        ; Save all registers just in case
  6594.     PUSH    B
  6595.     PUSH    D
  6596.     PUSH    H
  6597.     LHLD    CRCVAL        ; Get current value
  6598.     XCHG            ; Put in 'DE' for now
  6599.     MVI    B,0
  6600.     XRA    D
  6601.     MOV    C,A        ; Now have the character in 'BC' pair
  6602.     LXI    H,CRCTBL    ; Start of 'CRC' lookup-table
  6603.     DAD    B        ; Index into the 'CRC' table
  6604.     MOV    A,M        ; Get the value from the table
  6605.     XRA    E
  6606.     MOV    D,A
  6607.     INR    H        ; Move 256 bytes for 2nd table location
  6608.     MOV    E,M        ; Put value there into 'E' register
  6609.     XCHG            ; Put 'DE' into 'HL'
  6610.     SHLD    CRCVAL        ; Updated 'CRC' value with this character
  6611.     POP    H        ; Restore all registers
  6612.     POP    D
  6613.     POP    B
  6614.     POP    PSW
  6615.     RET
  6616. ;.....
  6617. ;
  6618. ;
  6619. ;==================== END OF CRC SUBROUTINE ============================
  6620. ;
  6621. ;
  6622. ;=========================START OF MENU ================================
  6623. ;
  6624. ;
  6625. MENU0:    LDA    NFILFLG
  6626.     ORA    A
  6627.     JZ    MENU        ; Exit if not saving memory for disk file
  6628.     CALL    ILPRT        ; Else print message
  6629.     DB    CR,LF,'** File still open, use DEL, DIR, WRT, E, L '
  6630.     DB    'or T ** ',CR,LF,BELL,0
  6631.     JMP    MENU1
  6632. ;
  6633. MENU:    XRA    A
  6634.     STA    ABORTFLG    ; Null the flag
  6635. ;
  6636. MENU1:    LXI    H,RESTSN    ; Restore record numbers..
  6637.     LXI    D,RECNOB    ; For new file transfer.
  6638.     MVI    B,RECNOE-RECNOB
  6639.     CALL    MOVE
  6640.     LXI    H,RESTROPT    ; Restore option table
  6641.     LXI    D,OPTBL
  6642.     MVI    B,OPTBE-OPTBL
  6643.     CALL    MOVE
  6644.     XRA    A
  6645.     STA    FLTRFLG        ; Reset multi-file trans
  6646.     STA    FSTFLG
  6647.     STA    MFFLG1        ; Reset MFACCESS routine
  6648.     STA    TIMFLG
  6649.     JMP    XPRT
  6650. ;.....
  6651. ;
  6652. ;
  6653. ; * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
  6654. ;
  6655. ;               MENU OF COMMANDS
  6656. ;
  6657. ; * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
  6658. ;
  6659. MENU2:    CALL    CLRTST
  6660.     CALL    ILPRT
  6661.     DB    '                  Single Letter Commands',CR,LF,LF
  6662.     DB    ' ?  - Display current settings',CR,LF
  6663. MENU3:    DB    ' ^  - Function key intercept character, '
  6664.     DB    'then (0-9)',CR,LF
  6665.     DB    ' M  - Display the menu',CR,LF
  6666.     DB    ' E  - Terminal mode with echo',CR,LF
  6667.     DB    ' L  - Terminal mode with local echo',CR,LF
  6668.     DB    ' T  - Terminal mode',CR,LF
  6669.     DB    '^Z  - Clears screen (command mode only)',CR,LF
  6670.     DB    ' R  - Receive an 8-bit binary CP/M file',CR,LF
  6671.     DB    ' S  - Send an 8-bit binary CP/M file',CR,LF,CR,LF
  6672.     DB    '         COMMAND: R (or S) FILENAME.TYP',CR,LF
  6673.     DB    '         R and S can use the following subcommands:'
  6674.     DB    CR,LF
  6675.     DB    '            B  - Batch transfer, can use wildcards '
  6676.     DB    '(e.g., *.*)',CR,LF
  6677.     DB    '            D  - Disconnect when done'
  6678.     DB    CR,LF
  6679.     DB    '            K  - Manual request for 1k transmissions'
  6680.     DB    CR,LF
  6681.     DB    '            Q  - Quiet mode (no messages to console)'
  6682.     DB    CR,LF
  6683.     DB    '            V  - View ASCII files on CRT during a '
  6684.     DB    'file transfer',CR,LF
  6685.     DB    '            X  - Inhibits auto 1k request to sender'
  6686.     DB    CR,LF
  6687.     DB    '            Z  - When done, disconnect, go to CP/M'
  6688.     DB    CR,LF,CR,LF
  6689.     DB    '         For copying text to disk use T (E or L) '
  6690.     DB    'FILENAME.TYP',CR,LF,0
  6691. ;
  6692.     CALL    NXTSCR        ; Wait at end of 1nd page
  6693. ;
  6694. ;
  6695. ; Start of 2nd menu page
  6696. ;
  6697.     CALL    ILPRT
  6698.     DB    '                Three Letter Commands',CR,LF,LF
  6699.     DB    'BYE - Disconnect, then return to CP/M',CR,LF
  6700.     DB    'CAL - Dial number',CR,LF
  6701.     DB    'CPM - Exit from this program to CP/M',CR,LF
  6702.     DB    'DIR - List directory and space free (may specify '
  6703.     DB    'drive)',CR,LF
  6704.     DB    'DSC - Disconnect from the phone line',CR,LF
  6705.     DB    'ERA - Erase file (may specify drive)',CR,LF
  6706.     DB    'LOG - Change default drive/user no. (specify '
  6707.     DB    'drive/user)',CR,LF
  6708.     DB    '         and reset disks i.e., LOG A0: or LOG B:  '
  6709.     DB    '(user # unchanged)',CR,LF
  6710.     DB    'SET - Set modem baud rate',CR,LF
  6711.     DB    'SPD - Set file output speed in terminal mode',CR,LF
  6712.     DB    'TBM - Toggle MODEM7/KMD batch mode selection',CR,LF
  6713.     DB    'TCC - Toggle CRC/Checksum mode on receive',CR,LF
  6714.     DB    'TIG - Toggle ''ignore CTL characters'' on/off',CR,LF
  6715.     DB    'TLF - Toggle LF after CR in "L" or "T" mode for '
  6716.     DB    'a disk file',CR,LF
  6717.     DB    'TRB - Toggle rubout to backspace conversion',CR,LF,LF
  6718.     DB    '      The following are terminal text buffer '
  6719.     DB    'commands:',CR,LF,LF
  6720.     DB    'DEL - Delete memory buffer and file',CR,LF
  6721.     DB    'WRT - Write memory buffer to disk file'
  6722.     DB    CR,LF,LF,0
  6723. ;
  6724.     CALL    NXTSCR        ; Wait at end of 2nd page
  6725. ;
  6726. ;
  6727. ; Write 3rd (and last) menu screen
  6728. ;
  6729.     CALL    ILPRT
  6730.     DB    '        Local Commands while in Terminal Mode'
  6731.     DB    CR,LF,LF,0
  6732.     LDA    EXITCHR
  6733.     CALL    SHFTYPE
  6734.     DB    '  - Exit to command mode',CR,LF,0
  6735.     LDA    FILESND
  6736.     CALL    SHFTYPE
  6737.     DB    '  - Send file to remote system',CR,LF,0
  6738.     LDA    LOGCHR
  6739.     CALL    SHFTYPE
  6740.     DB    '  - Send log-on message',CR,LF,0
  6741.     LDA    NOCONCT
  6742.     CALL    SHFTYPE
  6743.     DB    '  - Disconnect from the phone line',CR,LF,0
  6744.     LDA    LSTCHR
  6745.     CALL    SHFTYPE
  6746.     DB    '  - Turn printer on (or off)',CR,LF,0
  6747.     LDA    BRKCHR
  6748.     CALL    SHFTYPE
  6749.     DB    '  - Send break tone',CR,LF,0
  6750.     LDA    CLEARS
  6751.     CALL    SHFTYPE
  6752.     DB    '  - Clears screen, terminal mode',CR,LF,LF,0
  6753.     LDA    UNSAVCH
  6754.     CALL    SHFTYPE
  6755.     DB    '  - Stop copy into buffer',CR,LF,0
  6756.     LDA    SAVECHR
  6757.     CALL    SHFTYPE
  6758.     DB    '  - Start copy into buffer',CR,LF,LF
  6759.     DB    '             Start and stop may be toggled as often '
  6760.     DB    'as desired.',CR,LF
  6761.     DB    '             A ";" at start of line indicates buffer '
  6762.     DB    'is copying.',CR,LF
  6763.     DB    '             X-off automatically used to stop input '
  6764.     DB    'when writing',CR,LF
  6765.     DB    '                   full buffer to disk, X-on sent to '
  6766.     DB    'resume.'
  6767.     DB    CR,LF,LF,LF,LF,LF,LF,0 ; Falls on through to "XPRT"
  6768. ;
  6769. ;             (END OF COMMAND MENU)
  6770. ;=======================================================================
  6771. ;            START OF COMMAND LINE HANDLING
  6772. ;
  6773. ;
  6774. ; Check first to see if a file was opened for copying incoming to disk
  6775. ;
  6776. XPRT:    CALL    CRLF        ; Turn up a blank line to look nice
  6777.     LDA    NFILFLG        ; Have a file open for text mode copy?
  6778.     ORA    A
  6779.     JZ    XPRT1        ; If not, exit
  6780. ;
  6781.     CALL    GETSPC        ; Otherwise show remaining space
  6782.     CALL    ILPRT
  6783.     DB    ' Bytes of buffer free',CR,LF,LF,0
  6784. ;
  6785. ;
  6786. ; Show disk drive and user number, then command line
  6787. ;
  6788. XPRT1:    MVI    C,CURDSK    ; Current disk function
  6789.     CALL    BDOS
  6790.     ADI    'A'        ; Make ASCII
  6791.     CALL    TYPE
  6792.     CALL    GETUSER        ; Get current user number
  6793.     ORA    A
  6794.     JZ    XPRT2        ; Skip if user 0
  6795.     MVI    H,0
  6796.     MOV    L,A
  6797.     CALL    DECOUT        ; Show current user area
  6798. ;
  6799. XPRT2:    CALL    ILPRT
  6800.     DB    '>>COMMAND: ',0
  6801.     XRA    A
  6802.     STA    XFLG        ; Null the buffer-length flag
  6803. ;
  6804. ;
  6805. ; Get the command line parameters
  6806. ;
  6807. GTCMD:    LXI    D,CMDBUF    ; Enter command
  6808.     CALL    INBUF        ; Get keyboard-entered command
  6809.     LDA    CMDBUF+2    ; Check first command character
  6810. ;
  6811. GTCMD1:    CPI    '^'        ; Function key intercept character
  6812.     JZ    FUNCT        ; (supplied from 'INTCPT' table)
  6813.     CPI    '?'        ; Want to see current parameters?
  6814.     JZ    CURPAR
  6815.     CPI    ' '        ; If a space, ask again
  6816.     JZ    XPRT+3        ; Skip the extra line feed
  6817.     CALL    STDRV        ; See if request for new drive/user
  6818.     LXI    D,CMDBUF+2    ; Point to command
  6819.     CALL    INLNCP        ; Compare request with available commands
  6820.     DB    'BYE',0
  6821.     JNC    BYEBYE
  6822.     CALL    INLNCP
  6823.     DB    'CPM',0
  6824.     JNC    EXIT
  6825.     CALL    INLNCP
  6826.     DB    'LOG',0
  6827.     JNC    LOGNW
  6828.     CALL    INLNCP
  6829.     DB    'WRT',0
  6830.     JNC    WRFIL
  6831.     CALL    CRLF        ; (1st CR/LF at 'INBUFR')
  6832.     CALL    INLNCP
  6833.     DB    'DIR',0
  6834.     JNC    DIR
  6835.     CALL    INLNCP
  6836.     DB    'ERA',0
  6837.     JNC    ERASEF
  6838.     CALL    INLNCP
  6839.     DB    'SPD',0
  6840.     JNC    STSPD
  6841.     CALL    INLNCP
  6842.     DB    'TBM',0
  6843.     JNC    TGBAT
  6844.     CALL    INLNCP
  6845.     DB    'TCC',0
  6846.     JNC    TGCRC
  6847.     CALL    INLNCP
  6848.     DB    'TIG',0
  6849.     JNC    TIGNR
  6850.     CALL    INLNCP
  6851.     DB    'TRB',0
  6852.     JNC    TGRUB
  6853.     CALL    INLNCP
  6854.     DB    'TLF',0
  6855.     JNC    TGLF
  6856.     CALL    INLNCP
  6857.     DB    'SET',0
  6858.     JNC    STUPENT
  6859.     CALL    INLNCP
  6860.     DB    'DEL',0
  6861.     JNC    NEWFILE
  6862.     CALL    INLNCP
  6863.     DB    'DSC',0
  6864.     JNC    DONETD
  6865.     CALL    INLNCP        ; 'DE' set from 1st 'INLNCP' call
  6866.     DB    'CALL',0
  6867.     JNC    NOTVLD
  6868.     CALL    INLNCP
  6869.     DB    'CAL',0
  6870.     JNC    J$DIAL
  6871. ;
  6872. ;
  6873. ; If none of these, compare single characters with the table
  6874. ;
  6875.     LDA    CMDBUF+2
  6876.     LXI    H,COMPLIST
  6877.     CALL    COMPARE        ; Compares list pointed to by HL..
  6878.     JC    NOTVLD        ; Carry set = no match
  6879.     CALL    STFCB        ; Loads command buffer into FCB
  6880.     CALL    PROCOPT        ; Check out the options
  6881.     JMP    RSTRT        ; Go to work
  6882. ;.....
  6883. ;
  6884. ;
  6885. NOTVLD:    CALL    NTVLDMSG
  6886.     JMP    XPRT
  6887. ;.....
  6888. ;
  6889. ;
  6890. NTVLDMSG:
  6891.     CALL    ILPRT
  6892.     DB    '++ Invalid command ++',CR,LF,BELL,0
  6893.     RET
  6894. ;.....
  6895. ;
  6896. ;
  6897. ; Clears the screen with a "Z" as first character of the command line
  6898. ;
  6899. CLRS:    CALL    CLRTST        ; Clear the CRT
  6900.     LXI    SP,STACK    ; Cancel all the INBUF PUSHes
  6901.     JMP    XPRT1        ; Show the command line again
  6902. ;.....
  6903. ;
  6904. ;
  6905. ; Displays the function key table
  6906. ;
  6907. FUNCT:    LDA    INTCPT        ; Get the function key intercept char.
  6908.     ANI    07FH        ; Strip off any parity
  6909.     PUSH    PSW        ; Save the character for now
  6910.     CALL    CLRTST
  6911.     CALL    ILPRT
  6912.     DB    '         SPECIAL FUNCTION KEY TABLE'
  6913.     DB    CR,LF,LF,0
  6914.     POP    PSW        ; Get the character back
  6915.     CPI    ' '        ; See if a printing character
  6916.     JNC    FUNCT2        ; If a printing character, show it
  6917.     CPI    ESC
  6918.     JNZ    FUNCT1
  6919.     MVI    A,'E'
  6920.     CALL    TYPE
  6921.     MVI    A,'S'
  6922.     CALL    TYPE
  6923.     MVI    A,'C'
  6924.     JMP    FUNCT2
  6925. ;
  6926. FUNCT1:    PUSH    PSW
  6927.     CALL    ILPRT
  6928.     DB    'CTL-',0
  6929.     POP    PSW
  6930.     ADI    40H        ; Convert binary to ASCII character
  6931. ;
  6932. FUNCT2:    CALL    TYPE        ; Show on the CRT
  6933.     CALL    ILPRT
  6934.     DB    ' current function key intercept character',CR,LF,LF,0
  6935. ;
  6936. ;
  6937. ; Shows the functions of the (0-9) keys
  6938. ;
  6939.     LXI    H,FNCTBL-1    ; Index into the function key table
  6940.     MVI    B,10        ; Has ten entries
  6941. ;
  6942. FUNCT3:    INX    H        ; Next table location
  6943.     MOV    A,M        ; Get the binary function number
  6944.     ADI    '1'        ; Convert binary to ASCII digits
  6945.     CPI    '9'+1
  6946.     JNZ    FUNCT4
  6947.     MVI    A,'0'
  6948. ;
  6949. FUNCT4:    CALL    TYPE
  6950.     MVI    A,' '
  6951.     CALL    TYPE
  6952. ;
  6953. FUNCT5:    INX    H        ; Next table location
  6954.     MOV    A,M
  6955.     ORA    A        ; See if a binary zero
  6956.     JZ    FUNCT7
  6957.     CPI    CR
  6958.     JNZ    FUNCT6
  6959.     CALL    ILPRT
  6960.     DB    '<CR>',0
  6961.     JMP    FUNCT5
  6962. ;
  6963. FUNCT6:    CALL    TYPE
  6964.     JMP    FUNCT5
  6965. ;
  6966. FUNCT7:    CALL    CRLF
  6967.     DCR    B
  6968.     JNZ    FUNCT3
  6969.     CALL    J$ILPRT
  6970.     DB    CR,LF,LF,LF,LF,LF,LF,0
  6971.     JMP    XPRT
  6972. ;.....
  6973. ;
  6974. ;
  6975. BYEBYE:    CALL    ILPRT
  6976.     DB    CR,LF,'  wait... ',0
  6977.     CALL    STPCHR        ; Stop any incoming if possible
  6978.     LDA    NODTR        ; Support DTR?
  6979.     ORA    A
  6980.     JNZ    $+9        ; If not, call J$DSCONT
  6981.     CALL    J$GOODBYE    ; Else disconnect normally with DTR
  6982.     JMP    $+6
  6983.     CALL    J$DSCONT
  6984.     CALL    ILPRT
  6985.     DB    CR,'<< Disconnected, exit to CP/M >>',CR,LF,0
  6986.     JMP    EXIT        ; Return to CP/M
  6987. ;.....
  6988. ;
  6989. ;
  6990. DIR:    MVI    C,CURDSK
  6991.     CALL    BDOS
  6992.     STA    DISKSAV
  6993.     CALL    DRLST
  6994.     LDA    DISKSAV
  6995.     MOV    E,A
  6996.     MVI    C,SELDSK
  6997.     CALL    BDOS
  6998.     JMP    XPRT
  6999. ;.....
  7000. ;
  7001. ;
  7002. ERASEF:    LXI    D,CMDBUF    ; Put command line into FCB at 'HL'
  7003.     LXI    H,FCB
  7004.     CALL    CMDLINE
  7005.     CALL    MOVEFCB        ; Move FCB+16 to FCB
  7006.     LDA    FCB+1
  7007.     CPI    ' '
  7008.     JZ    NOTVLD        ; Go if no file specified
  7009.     LXI    D,FCB
  7010.     MVI    C,SRCHF
  7011.     CALL    BDOS
  7012.     INR    A        ; 0 if file not found
  7013.     JNZ    ERAFILE        ; Ok, go erase
  7014.     CALL    ILPRT
  7015.     DB    '++ File not found ++',CR,LF,BELL,0
  7016.     JMP    XPRT
  7017. ;.....
  7018. ;
  7019. ;
  7020. ERAFILE:LXI    D,FCB
  7021.     MVI    C,ERASE
  7022.     CALL    BDOS
  7023.     CALL    ILPRT
  7024.     DB    'File erased',CR,LF,0
  7025.     JMP    XPRT
  7026. ;.....
  7027. ;
  7028. ;
  7029. LOGNW:    LDA    NFILFLG        ; File open for memory save to disk?
  7030.     ORA    A
  7031.     JNZ    NORESET        ; If yes, do not reset disk drive now
  7032.     LDA    CMDBUF+6    ; Any disk drive specified?
  7033.     CPI    ' '
  7034.     JNZ    LOGNW1        ; If not a blank, exit
  7035.     CALL    GETDISK        ; If not, use current drive
  7036.     ADI    'A'        ; To compensate for next line
  7037. ;
  7038. LOGNW1:    SUI    'A'
  7039.     CPI    15+1        ; For drives 0-15
  7040.     JNC    NOTVLD        ; If more than 15, display error message
  7041.     STA    DISKSAV        ; Store requested drive
  7042.     CALL    GETUSER        ; Pick up current user number
  7043.     MOV    B,A        ; Save it
  7044.     LDA    CMDBUF+7    ; Get new user number
  7045.     CALL    CHRCK        ; Check the character
  7046.     CALL    FINDUSER
  7047.     LDA    CMDBUF+8    ; Get 2nd digit
  7048.     CALL    CHRCK        ; Check the character
  7049.     CALL    FINDUSER+2
  7050. ;
  7051. LOGNW2:    CALL    SAVEUSER
  7052.     MVI    C,RESET
  7053.     CALL    BDOS
  7054.     LDA    DISKSAV
  7055.     MOV    E,A
  7056.     MVI    C,SELDSK
  7057.     CALL    BDOS
  7058.     LDA    SAVUSR
  7059.     MOV    E,A
  7060.     CALL    STUSER
  7061.     JMP    XPRT
  7062. ;.....
  7063. ;
  7064. ;
  7065. CHRCK:    CPI    ' '
  7066.     JZ    CHRCK1
  7067.     CPI    ':'        ; In case of A: or A1: or A11:    (etc.)
  7068.     RNZ
  7069. ;
  7070. CHRCK1:    POP    PSW        ; Reset the 'CALL' on the stack
  7071.     JMP    LOGNW2
  7072. ;.....
  7073. ;
  7074. ;
  7075. FINDUSER:
  7076.     MVI    B,0        ; Zero the 'B' reg. for 1st time through
  7077.     CALL    NUMCHK        ; If neither, see if a valid number
  7078.     MOV    C,A        ; Save
  7079.     MOV    A,B        ; Get save first digit
  7080.     ADD    A        ; X2
  7081.     ADD    A        ; X4
  7082.     ADD    A        ; X8
  7083.     ADD    B        ; X9
  7084.     ADD    B        ; X10
  7085.     ADD    C
  7086.     MOV    B,A        ; Save
  7087.     RET
  7088. ;.....
  7089. ;
  7090. ;
  7091. SAVEUSER:
  7092.     MOV    A,B
  7093.     CPI    15+1        ; User numbers are 0-15
  7094.     JNC    NOTVLD
  7095.     STA    SAVUSR
  7096.     RET
  7097. ;.....
  7098. ;
  7099. ;
  7100. NUMGET:    LXI    D,CMDBUF
  7101.     CALL    INBUF
  7102.     LDA    CMDBUF+2    ; Get number
  7103.     CPI    ' '
  7104.     RZ
  7105. ;
  7106. NUMCHK:    SUI    '0'        ; Remove ASCII bias
  7107.     CPI    9+1
  7108.     RC            ; Ok if 9 or less
  7109.     POP    H        ; Remove 1st call from the stack
  7110.     POP    H        ; Remove 2nd call from the stack
  7111.     JMP    NOTVLD
  7112. ;
  7113. GETUSER:MVI    E,0FFH        ; Get current user
  7114. ;
  7115. STUSER:    MVI    C,USER        ; Set up BDOS call
  7116.     JMP    BDOS
  7117. ;.....
  7118. ;
  7119. ;
  7120. GETDISK:MVI    C,CURDSK    ; Get current drive
  7121.     JMP    BDOS
  7122. ;.....
  7123. ;
  7124. ;
  7125. NORESET:CALL    ILPRT
  7126.     DB    '++      Terminal mode file open      ++',CR,LF
  7127.     DB    '++ Use WRT or DEL before LOG command ++',CR,LF
  7128.     DB    CR,LF,BELL,0
  7129.     XRA    A
  7130.     JMP    XPRT
  7131. ;.....
  7132. ;
  7133. ;
  7134. STSPD:    CALL    ILPRT
  7135.     DB    'Delay between chars. (0-9): ',0
  7136. ;
  7137. STSPD1:    CALL    STAT
  7138.     JZ    STSPD1
  7139.     CALL    KEYIN
  7140.     CALL    TYPE
  7141.     CALL    SAVEA
  7142.     CPI    CR
  7143.     JZ    STSPD2
  7144.     SUI    '0'
  7145.     CPI    9+1
  7146.     JNC    NOTVLD
  7147.     ADD    A
  7148.     ADD    A
  7149.     STA    BYTDLY
  7150. ;
  7151. STSPD2:    CALL    ILPRT
  7152.     DB    'Delay at end of line (0-9): ',0
  7153. ;
  7154. STSPD3:    CALL    STAT
  7155.     JZ    STSPD3
  7156.     CALL    KEYIN
  7157.     CALL    TYPE
  7158.     CALL    SAVEA
  7159.     CPI    CR
  7160.     JZ    STSPD4
  7161.     SUI    '0'
  7162.     CPI    9+1
  7163.     JNC    NOTVLD
  7164.     STA    CRDLY
  7165. ;
  7166. STSPD4:    CALL    SPDMSG
  7167.     JMP    XPRT
  7168. ;.....
  7169. ;
  7170. ;
  7171. SPDMSG:    CALL    ILPRT
  7172.     DB    CR,LF,'Char. delay (terminal file mode) is:  ',0
  7173.     LDA    BYTDLY
  7174.     CPI    10
  7175.     JNC    SPDMSG1
  7176.     PUSH    PSW
  7177.     CALL    ILPRT
  7178.     DB    ' ',0
  7179.     POP    PSW
  7180. ;
  7181. SPDMSG1:PUSH    H
  7182.     MOV    L,A
  7183.     MVI    H,0
  7184.     CALL    DECOUT
  7185.     POP    H
  7186.     CALL    ILPRT
  7187.     DB    ' ms. per character',CR,LF
  7188.     DB    'Line  delay (terminal file mode) is: ',0
  7189.     LDA    CRDLY
  7190.     PUSH    H
  7191.     MOV    L,A
  7192.     MVI    H,0
  7193.     CALL    DECOUT
  7194.     POP    H
  7195.     CALL    ILPRT
  7196.     DB    '00 ms. per CR character',CR,LF,0
  7197.     RET
  7198. ;......
  7199. ;
  7200. ;
  7201. SAVEA:    PUSH    PSW
  7202.     CALL    ILPRT
  7203.     DB    CR,LF,0
  7204.     POP    PSW
  7205.     RET
  7206. ;.....
  7207. ;
  7208. ;
  7209. ; Set the drive/user area if any requested
  7210. ;
  7211. STDRV:    LDA    CMDBUF+3    ; Allow for B: or B2: or B15:, etc.
  7212.     CPI    ':'
  7213.     JZ    STDRV1
  7214.     LDA    CMDBUF+4
  7215.     CPI    ':'
  7216.     JZ    STDRV1
  7217.     LDA    CMDBUF+5
  7218.     CPI    ':'
  7219.     RNZ            ; If no drive/user requested, return
  7220.     LDA    CMDBUF+2
  7221.     CPI    'S'        ; Allows S B:FILENAME.EXT
  7222.     RZ
  7223.     CPI    'R'        ; Allows R B:FILENAME.EXT
  7224.     RZ
  7225. ;
  7226. ;
  7227. ; First check for the drive
  7228. ;
  7229. STDRV1:    POP    H        ; Remove "CALL STDRV" from stack
  7230.     LDA    CMDBUF+2    ; Get the disk drive
  7231.     SUI    'A'        ; Convert to binary value
  7232.     CPI    15+1        ; For drives 0-15
  7233.     JNC    NOTVLD        ; Answers over 15 not valid this program
  7234. ;
  7235.     MOV    E,A
  7236.     MVI    C,SELDSK    ; Select requested drive
  7237.     CALL    BDOS
  7238. ;
  7239. ;
  7240. ; See if any user area requested
  7241. ;
  7242.     LDA    CMDBUF+3    ; See if just plain B: and no user area
  7243.     CPI    ':'
  7244.     JZ    XPRT        ; If yes, finished
  7245. ;
  7246. ;
  7247. ; Since there was, enter the request
  7248. ;
  7249.     SUI    '0'        ; Convert to binary value
  7250.     CPI    1        ; If a '1', could be units or tens
  7251.     JNZ    STDRV3        ; If not, numbers stop at 15 so exit
  7252.     LDA    CMDBUF+4    ; Check for a 2nd digit
  7253.     CPI    ':'        ; Accecpt '1' for  B1:    etc.
  7254.     JNZ    STDRV2
  7255.     MVI    A,1
  7256.     JMP    STDRV4
  7257. ;
  7258. STDRV2:    CPI    '0'
  7259.     JC    STDRV5        ; If less, not a valid number, ignore
  7260.     SUI    '0'-10        ; Leave the '10' in as two digits used
  7261. ;
  7262. STDRV3:    CPI    15+1        ; User areas are 0-15 for this program
  7263.     JNC    NOTVLD
  7264. ;
  7265. STDRV4:    MOV    E,A
  7266.     CALL    STUSER
  7267.     JMP    XPRT        ; Back to work
  7268. ;
  7269. STDRV5:    MVI    A,1
  7270.     JMP    STDRV2
  7271. ;.....
  7272. ;
  7273. ;
  7274. ; Set MODEM7/KMD batch selection
  7275. ;
  7276. TGBAT:    LDA    KMDODE        ; Get current selection and switch it
  7277.     CMA
  7278.     STA    KMDODE
  7279.     CALL    TGBAT1        ; Show on CRT it has been changed
  7280.     JMP    XPRT
  7281. ;.....
  7282. ;
  7283. ;
  7284. ; Set CRC/checksum toggle
  7285. ;
  7286. TGCRC:    LDA    CRCDFLT        ; Get present value and switch it
  7287.     CMA
  7288.     STA    CRCDFLT
  7289.     CALL    TGCRC1        ; Show on CRT it has been changed
  7290.     JMP    XPRT
  7291. ;.....
  7292. ;
  7293. ;
  7294. TGBAT1:    LDA    KMDODE
  7295.     ORA    A
  7296.     JZ    TGBAT2
  7297.     CALL    ILPRT
  7298.     DB    'MODEM7 batch mode',CR,LF,0
  7299.     RET
  7300. ;
  7301. TGBAT2:    CALL    ILPRT
  7302.     DB    'KMD batch mode',CR,LF,0
  7303.     RET
  7304. ;.....
  7305. ;
  7306. ;
  7307. TGCRC1:    CALL    ILPRT
  7308.     DB    'Mode: ',0
  7309.     LDA    CRCDFLT        ; See if set for 'CRC' or 'checksum'
  7310.     ORA    A
  7311.     JZ    CHEKMSG
  7312.     CALL    ILPRT
  7313.     DB    'CRC',CR,LF,0
  7314.     RET
  7315. ;
  7316. CHEKMSG:CALL    ILPRT
  7317.     DB    'checksum',CR,LF,0
  7318.     RET
  7319. ;.....
  7320. ;
  7321. ;
  7322. TIGNR:    LDA    IGNRCTL
  7323.     CMA
  7324.     STA    IGNRCTL
  7325.     CALL    TIGNR1
  7326.     JMP    XPRT
  7327. ;.....
  7328. ;
  7329. ;
  7330. TIGNR1:    CALL    ILPRT
  7331.     DB    'Incoming control characters ',0
  7332.     LDA    IGNRCTL
  7333.     ORA    A
  7334.     JZ    NOIGNR
  7335.     CALL    ILPRT
  7336.     DB    'ignored',CR,LF,0
  7337.     RET
  7338. ;.....
  7339. ;
  7340. ;
  7341. NOIGNR:
  7342.     CALL    ILPRT
  7343.     DB    'received',CR,LF,0
  7344.     RET
  7345. ;.....
  7346. ;
  7347. ;
  7348. TGRUB:    LDA    CONVRUB
  7349.     CMA
  7350.     STA    CONVRUB
  7351.     CALL    TGRUB1
  7352.     JMP    XPRT
  7353. ;.....
  7354. ;
  7355. ;
  7356. TGRUB1:    LDA    CONVRUB
  7357.     ORA    A
  7358.     JZ    NORUBMSG
  7359.     CALL    ILPRT
  7360.     DB    'Rub is backspace',CR,LF,0
  7361.     RET
  7362. ;.....
  7363. ;
  7364. ;
  7365. NORUBMSG:
  7366.     CALL    ILPRT
  7367.     DB    'Rub is rub',CR,LF,0
  7368.     RET
  7369. ;.....
  7370. ;
  7371. ;
  7372. TGLOC1:    CALL    ILPRT
  7373.     DB    'Use ESC before local command in terminal mode',CR,LF,0
  7374.     RET
  7375. ;.....
  7376. ;
  7377. ;
  7378. TGLF:    LDA    ADDLFD
  7379.     CMA
  7380.     STA    ADDLFD
  7381.     CALL    TGLF1
  7382.     JMP    XPRT
  7383. ;.....
  7384. ;
  7385. ;
  7386. TGLF1:    CALL    ILPRT
  7387.     DB    'LF ',0
  7388.     LDA    ADDLFD        ; Adding LF after CR?
  7389.     ORA    A
  7390.     JNZ    LFMSG        ; If yes, exit
  7391.     CALL    ILPRT
  7392.     DB    'NOT ',0
  7393. ;
  7394. LFMSG:    CALL    ILPRT
  7395.     DB    'sent after CR in "L" or "T" for a disk file',CR,LF,0
  7396.     RET
  7397. ;.....
  7398. ;
  7399. ;
  7400. RATE:    CALL    ILPRT
  7401.     DB    'Modem speed is: ',0
  7402.     CALL    PRTBAUD        ; Display the speed
  7403.     CALL    ILPRT
  7404.     DB    CR,LF,0
  7405.     RET
  7406. ;.....
  7407. ;
  7408. ;
  7409. XOFFMSG:CALL    ILPRT
  7410.     DB    'XOFF testing used in terminal mode file output'
  7411.     DB    CR,LF,0
  7412.     RET
  7413. ;.....
  7414. ;
  7415. ;
  7416. GETANS:    LXI    D,CMDBUF
  7417.     CALL    INBUF
  7418.     LDA    CMDBUF+2    ; Get answer
  7419.     CPI    ' '
  7420.     CMC            ; Set the carry flag
  7421.     RZ
  7422.     MOV    B,A
  7423.     CPI    'N'
  7424.     MVI    A,0
  7425.     RZ
  7426.     MOV    A,B
  7427.     CPI    'Y'
  7428.     MVI    A,1
  7429.     RZ
  7430.     POP    PSW        ; Preserve stack
  7431.     JMP    NOTVLD
  7432. ;.....
  7433. ;
  7434. ;
  7435. STUPENT:MVI    A,1
  7436.     STA    MANUAL        ; Speed is being manually selected
  7437.     LXI    D,CMDBUF+1
  7438.     CALL    J$STUPR        ; Go set the speed
  7439.     CALL    RATE
  7440.     JMP    XPRT
  7441. ;.....
  7442. ;
  7443. ;
  7444. NEWFILE:LDA    NFILFLG        ; File open for disk save?
  7445.     ORA    A
  7446.     JZ    NOFILOPN    ; If not, show "no file open" message
  7447.     LDA    FCB3+1        ; Check that file was requested
  7448.     CPI    ' '
  7449.     JZ    NOFILOPN    ; If no file, do not erase
  7450.     LXI    D,FCB3        ; Otherwise erase the old file
  7451.     MVI    C,ERASE
  7452.     CALL    BDOS
  7453.     XRA    A
  7454.     STA    NFILFLG        ; No file mentioned, reset flags
  7455.     STA    SAVEFLG
  7456.     LXI    H,FCB3
  7457.     CALL    INITFCB
  7458.     LXI    H,BUFFER    ; Reset flags to bottom of ram just to
  7459.     SHLD    HLSAV        ; Insure they are there
  7460.     JMP    XPRT
  7461. ;.....
  7462. ;
  7463. ;
  7464. WRFIL:    LDA    NFILFLG        ; Saving memory for a disk file?
  7465.     ORA    A
  7466.     JZ    NOFILOPN    ; If not, nothing to write to disk
  7467.     CALL    WRFIL1        ; Close the file
  7468.     STA    SAVEFLG
  7469.     STA    WRFLG
  7470.     LXI    H,FCB3
  7471.     CALL    INITFCB        ; Blank out 'FCB' to written file
  7472.     LXI    H,BUFFER    ; Can't be erased
  7473.     SHLD    HLSAV        ; Reset to buffer start for next time
  7474.     JMP    XPRT
  7475. ;...
  7476. ;
  7477. ;
  7478. WRFIL1:    LDA    FCB3+1        ; Check that file was requested
  7479.     CPI    ' '
  7480.     RZ
  7481.     CALL    WRDSK        ; Write buffer to disk if not empty
  7482. ;
  7483. WRFIL2:    LXI    D,FCB3        ; Close the file
  7484.     MVI    C,CLOSE
  7485.     CALL    BDOS
  7486. ;
  7487. ;
  7488. ; Show name of file that is being closed
  7489. ;
  7490.     MVI    A,CR
  7491.     CALL    TYPE
  7492.     MVI    A,LF
  7493.     CALL    TYPE
  7494.     MVI    B,8
  7495.     LXI    H,FCB3+1
  7496.     CALL    WRFIL4
  7497.     MOV    A,M
  7498.     CPI    ' '+1
  7499.     JC    WRFIL3
  7500.     MVI    A,'.'
  7501.     CALL    TYPE
  7502. ;
  7503. WRFIL3:    MVI    B,3
  7504.     CALL    WRFIL4
  7505.     CALL    ILPRT
  7506.     DB    ' closed',CR,LF,0
  7507.     XRA    A
  7508.     STA    NFILFLG        ; File written, reset flags
  7509.     RET
  7510. ;...
  7511. ;
  7512. ;
  7513. WRFIL4:    MOV    A,M
  7514.     CPI    ' '
  7515.     JZ    WRFIL5
  7516.     CALL    TYPE
  7517. ;
  7518. WRFIL5:    INX    H
  7519.     DCR    B
  7520.     JNZ    WRFIL4
  7521.     RET
  7522. ;.....
  7523. ;
  7524. ;
  7525. NOFILOPN:
  7526.     CALL    ILPRT
  7527.     DB    CR,LF,'++ No file open ++',CR,LF,BELL,0
  7528.     JMP    XPRT
  7529. ;.....
  7530. ;
  7531. ;
  7532. NEWLINE:MVI    A,CR        ; Puts CRLF at memory pointed by 'DE'
  7533.     STAX    D        ; Store it
  7534.     MVI    A,LF        ; Line feed
  7535.     INX    D        ; Bump pointer
  7536.     STAX    D        ; Store lf
  7537.     INX    D        ; Bump pointer
  7538.     RET
  7539. ;.....
  7540. ;
  7541. ;
  7542. SPACES:    MVI    A,' '        ; Space
  7543.     STAX    D
  7544.     INX    D        ; 1
  7545.     STAX    D
  7546.     INX    D        ; 2
  7547.     STAX    D
  7548.     INX    D        ; 3
  7549.     RET
  7550. ;.....
  7551. ;
  7552. ;
  7553. COMPARE:MOV    B,M        ; Compares 'A' reg. with list
  7554. ;
  7555. COMPLP:    INX    H
  7556.     CMP    M
  7557.     JZ    VALID
  7558.     DCR    B
  7559.     JNZ    COMPLP
  7560.     STC
  7561. ;
  7562. VALID:    RET
  7563. ;.....
  7564. ;
  7565. ;
  7566. NXTSCR:    CALL    ILPRT
  7567.     DB    '[more] ',0
  7568. ;
  7569. NOKEY1:    CALL    STAT        ; Get keyboard status
  7570.     JZ    NOKEY1        ; Keep looping until keypress
  7571.     CALL    KEYIN        ; Gobble up keypress
  7572.     MVI    B,CLEARSC    ; CTL-Z to clear screen?
  7573.     CMP    B
  7574.     JNZ    NOKEY2        ; If not, exit
  7575.     JMP    CLRS        ; Erase screen, back to command
  7576. ;
  7577. NOKEY2:    CPI    'C'-40H        ; CTL-C to abort?
  7578.     JNZ    CLRTST
  7579.     POP    H        ; Clear stack of return address
  7580.     CALL    CRLF        ; Turn up a blank line
  7581.     JMP    XPRT
  7582. ;.....
  7583. ;
  7584. ;
  7585. CLRTST:    LDA    CLEAR        ; "Clear screen" character used?
  7586.     ORA    A
  7587.     JZ    CLRT2        ; If not, exit
  7588. ;
  7589.     CPI    ' '        ; See if a control character
  7590.     JC    CLRT1
  7591.     PUSH    PSW        ; Save the "Clear screen" character
  7592.     MVI    A,ESC        ; Send an 'Escape' character first
  7593.     CALL    TYPE
  7594.     POP    PSW        ; Get the "Clear screen" character back
  7595. ;
  7596. CLRT1:    JMP    TYPE        ; Send it, done
  7597. ;
  7598. CLRT2:    MVI    A,CR        ; Else use a bunch of line feeds
  7599.     CALL    TYPE
  7600.     MVI    B,24
  7601.     MVI    A,LF
  7602. ;
  7603. LFLOOP:    CALL    TYPE
  7604.     DCR    B
  7605.     JNZ    LFLOOP
  7606.     RET
  7607. ;.....
  7608. ;
  7609. ;
  7610. CURPAR:    CALL    CLRTST
  7611.     CALL    ILPRT
  7612.     DB    '                Current Settings',CR,LF,LF,0
  7613.     CALL    TGCRC1        ; CRC/checksum mode
  7614.     CALL    TGBAT1        ; MODEM7/KMD batch mode
  7615.     CALL    TGRUB1        ; Toggle rub to backspace
  7616.     CALL    LSTMS
  7617.     CALL    RATE
  7618.     CALL    TIGNR1        ; Toggle incoming CTL-characters
  7619.     CALL    ILPRT
  7620.     DB    'Terminal mode file buffer is ',0
  7621.     LDA    NFILFLG        ; Saving memory for a disk file?
  7622.     ORA    A
  7623.     JNZ    ACTIVE        ; If yes, go say "active"
  7624.     CALL    ILPRT
  7625.     DB    'in',0        ; If not, say "inactive"
  7626. ;
  7627. ACTIVE:    CALL    ILPRT
  7628.     DB    'active',CR,LF,'Unused portion of buffer is ',0
  7629.     CALL    GETSPC
  7630.     CALL    ILPRT
  7631.     DB    ' bytes',CR,LF,0
  7632.     CALL    TGLOC1
  7633.     CALL    XOFFMSG
  7634.     CALL    TGLF1
  7635.     CALL    SPDMSG
  7636.     CALL    ILPRT
  7637.     DB    CR,LF,LF,LF,LF,LF,LF,0
  7638.     JMP    XPRT
  7639. ;.....
  7640. ;
  7641. ;
  7642. GETSPC:    LXI    D,BUFTOP    ; Top of memory buffer
  7643.     LHLD    HLSAV        ; Current buffer location
  7644.     XCHG
  7645.     XRA    A        ; Clear the carry bit, if set
  7646.     SUB    E
  7647.     MOV    L,A
  7648.     MOV    A,H
  7649.     SBB    D
  7650.     MOV    H,A
  7651.     CALL    DECOUT        ; Print the space remaining
  7652.     RET
  7653. ;.....
  7654. ;
  7655. ;
  7656. ;***********************************************************************
  7657. ;
  7658. ;    D - A - T - A     A - R - E - A
  7659. ;
  7660. ;***********************************************************************
  7661. ;
  7662. ;
  7663. COMPLIST: DB    6, 'S',    'R', 'T', 'E', 'L', 'M'
  7664. ;.....
  7665. ;
  7666. ;
  7667. ; OPTION TABLE
  7668. ;
  7669. OPTBL    EQU    $
  7670. BATCHFLG: DB    'B'
  7671. DISCFLG:DB    'D'
  7672. KKMD:    DB    'K'
  7673. QFLG:    DB    'Q'
  7674. RSEEFLG:DB    'R'
  7675. SSEEFLG:DB    'S'
  7676. VSEEFLG:DB    'V'
  7677. XMODEM:    DB    'X'
  7678. XITFLG:    DB    'Z'
  7679. OPTBE    EQU    $        ; Transfer when program initially called
  7680. ;
  7681. ;
  7682. ; The following must be in the same order as the table above:
  7683. ;
  7684. RESTROPT: DB    'B','D','K','Q','R','S','V','X','Z'
  7685. ;
  7686. ;
  7687. ; The next 16 bytes equal the number of bytes between RECNOB and
  7688. ; RECNOE.
  7689. ;
  7690. RESTSN:    DB    0,0,0,0,0
  7691.     DB    0,0,0,0,0
  7692.     DB    0,0,0,0
  7693.     DW    BUFFER
  7694. ;
  7695. RECNOB    EQU    $        ; Start of table marker
  7696. ACCERR:    DB    0,0        ; \ No 'ACK' error count for 1k ratio
  7697. CHKEOT:    DB    0        ; \
  7698. DATAFLG:DB    0        ; \
  7699. EOFLG:    DB    0        ; \
  7700. ERRCT:    DB    0        ; \  16 bytes between table markers
  7701. FRSTIM:    DB    0        ; /
  7702. RCDCNT:    DB    0,0        ; /  (These get reset each batch mode
  7703. RCNT:    DB    0,0        ; /  file that is sent)
  7704. RECNBF:    DB    0        ; /
  7705. RECNO:    DB    0,0        ; /
  7706. RECPTR:    DW    BUFFER        ; /
  7707. RECNOE    EQU    $        ; End of table marker
  7708. ;
  7709. ;
  7710. ; Additional 16-bit initialized storage
  7711. ;
  7712. CRCVAL:    DW    0
  7713. DIALCT:    DW    0
  7714. HLSAV:    DW    BUFFER
  7715. HLSAV1:    DW    PBUFF
  7716. HLSAV2:    DW    PBUFF
  7717. ;
  7718. ;
  7719. ; Additional general purpose initialized storage
  7720. ;
  7721. ABORTFLG: DB    0
  7722. CRCFLG:    DB    0
  7723. CRFLAG:    DB    0
  7724. DLYFLG:    DB    0
  7725. ECHOFLG:DB    0
  7726. EXACFLG:DB    0
  7727. DONEFLG:DB    0
  7728. FNKFLG:    DB    0        ; Function key activity flag
  7729. FSTFLG:    DB    0
  7730. GOTONE:    DB    0
  7731. KFLG:    DB    0        ; Flag for 1k blocks
  7732. LISTFLG:DB    0
  7733. LOCFLG:    DB    0
  7734. MFFLG1:    DB    0
  7735. NFILFLG:DB    0
  7736. OPTION:    DB    0
  7737. RCVCNT:    DB    0        ; Record number received
  7738. RCVTRY:    DB    0        ; Limits tries for batch mode header
  7739. SAVEFLG:DB    0
  7740.     DB    0
  7741. KMDODE:    DB    0        ; Selects MODEM7/KMD batch
  7742. WRFLG:    DB    0
  7743. XFLG:    DB    0
  7744. CMDBUF:    DB    80H,0        ; Command buffer control area
  7745. ;
  7746. ;
  7747. ; General purpose unitialized storage area
  7748. ;
  7749.     DS    128        ; Storage area for 'CMDBUF'
  7750. BGNMS:    DS    2
  7751. TIMFLG:    DS    1
  7752. FLTRFLG:DS    1
  7753. CHRFLG:    DS    1
  7754. TIMVAL:    DS    2
  7755. QUIKTIM:DS    2
  7756. DISKNO:    DS    1
  7757. DISKSAV:DS    1
  7758. DSTORE:    DS    1
  7759. FILECT:    DS    1
  7760. FTYCNT:    DS    1
  7761. MAXRAM:    DS    1
  7762. NAMECT:    DS    1
  7763. NBSAVE:    DS    2
  7764. OLDUSER:DS    1
  7765. SAVUSR:    DS    1
  7766. SNDFLG:    DS    1
  7767. ;
  7768. FCB3:    DS    33
  7769. FCB4:    DS    33
  7770. FCBBUF:    DS    15
  7771. MFNAM5:    DS    12        ; Requested name
  7772. MFNAM6:    DS    12        ; Current name
  7773.     DS    100        ; Stack depth
  7774. ;
  7775. ;
  7776. EVNPAGE    EQU    ($+255)/256*256    ; Sets buffers on even page
  7777. ;
  7778. ;
  7779.     ORG    EVNPAGE
  7780. ;
  7781. ;
  7782. STACK    EQU    EVNPAGE-2    ; Store original stack pointer
  7783. CRCTBL:    DS    512        ; Two tables of 128 bytes each
  7784. BUFFDSK:DS    128        ; Buffer for disk save
  7785. BUFFPNT:DS    128        ; Buffer for printer
  7786. BUFFER:    DS    1024*BUFSIZ    ; Send/receive file buffer
  7787. BUFSTR    EQU    BUFFER+126    ; For storing batch mode file length
  7788. BUFTOP:    DS    0        ; Filled in when length is found
  7789. PBUFF    EQU    $        ; Printer buffer starts here
  7790. NAMEBUF    EQU    $        ; Batch-mode filenames buffer
  7791. ;.....
  7792. ;
  7793. ;
  7794. ; BDOS EQUATES
  7795. ;
  7796. RDCON    EQU    1
  7797. WRCON    EQU    2
  7798. LIST    EQU    5
  7799. PRINT    EQU    9
  7800. CONST    EQU    11
  7801. CPMVER    EQU    12
  7802. RESET    EQU    13
  7803. SELDSK    EQU    14
  7804. OPEN    EQU    15
  7805. CLOSE    EQU    16
  7806. SRCHF    EQU    17
  7807. SRCHN    EQU    18
  7808. ERASE    EQU    19
  7809. READ    EQU    20
  7810. WRITE    EQU    21
  7811. MAKE    EQU    22
  7812. CURDSK    EQU    25
  7813. STDMA    EQU    26
  7814. DSKALL    EQU    27
  7815. DSKPAR    EQU    31
  7816. USER    EQU    32
  7817. FILSIZ    EQU    35
  7818. BDOS    EQU    0005H
  7819. FCB    EQU    5CH
  7820. FCBEXT    EQU    FCB+12
  7821. FCBSNO    EQU    FCB+32
  7822. FCBRNO    EQU    FCB+32
  7823. FCB2    EQU    6CH
  7824. TBUF    EQU    80H
  7825. ;.....
  7826. ;
  7827. ;
  7828.     END
  7829.