home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / ZCPR33 / Z3-33 / Z33RCP02.LBR / RCPWHL.LZB / RCPWHL.LIB
Text File  |  2000-06-30  |  1KB  |  72 lines
  1.     page
  2. ;
  3. ;Section 5K
  4. ;Command: WHL/WHLQ
  5. ;Function:  Set the Wheel Byte on or off
  6. ;
  7. ;If WHLQUIET equate is true, then RCP does not report wheel status with WHL
  8. ;command.
  9. ;
  10. ;Form:
  11. ;    WHL        -- turn Wheel Byte OFF
  12. ;    WHL password    -- turn Wheel Byte ON if password is correct
  13. ;               no change if password is wrong
  14. ;    WHLQ        -- find out status of Wheel Byte
  15.  
  16. whl:
  17.     ld    hl,fcb1+1    ; Pt to first char
  18.     ld    a,(hl)        ; Get it
  19.     cp    ' '        ; Turn byte off if no password
  20.     jr    z,whloff
  21.     ld    de,whlpass
  22.     ld    b,8        ; Check 8 chars
  23.     call    comp        ; Compare
  24.     jr    nz,whlmsg1
  25.  
  26. ; TURN ON WHEEL BYTE
  27.  
  28.     ld    a,0ffh        ; Turn on wheel byte
  29.     jr    whlset
  30.  
  31. ; TURN OFF WHEEL BYTE
  32.  
  33. whloff:
  34.     xor    a        ; Turn off wheel byte
  35. whlset:
  36.     ld    (z3whl),a    ; Set wheel byte and print message
  37.  
  38. whlmsg1:
  39.      if    whlquiet
  40.     ret
  41.      endif
  42.  
  43. ; PRINT WHEEL BYTE MESSAGE
  44.  
  45.      if    [not whlquiet] or whlqon
  46.  
  47. whlmsg:
  48.     call    print
  49.     db    ' Wheel Byte',' '+80h
  50.     ld    a,(z3whl)    ; Get wheel byte
  51.     or    a        ; Zero is off
  52.     jr    z,offm
  53.     call    print
  54.     db    'O','N'+80h
  55.     ret
  56. offm:
  57.     call    print
  58.     db    'OF','F'+80h
  59.     ret
  60.  
  61.      endif    ;[not whlquiet] or whlqon
  62.  
  63.  
  64. ; WHEEL PASSWORD DEFINED FROM SYSRCP.LIB FILE
  65.  
  66.     db    'Z'-'@'        ; Leading ^z to block attempt to type rcp file
  67. whlpass:
  68.     wpass            ; Use macro
  69. ;
  70. ; End RCP-WHL.Z80
  71.  
  72.