home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / ZCPR33 / S-Z / W22.LBR / W22.ZZ0 / W22.Z80
Text File  |  2000-06-30  |  32KB  |  1,121 lines
  1. ;  Program:  W -  Wildcard Processing Shell
  2. ;  Author:  Steve Cohen
  3. ;
  4. ;  VERSION 2.2
  5. ;  DATE November 9, 1987 by Rob Wood
  6. ;
  7. ;  Add code for W to use the external FCB to find the name it was invoked with
  8. ;  and build the shell/reinvokation command using this name.
  9. ;  Added Z33 option in program configuration bytes.  This option is set to TRUE
  10. ;  if running in ZCPR 3.3 and the DU: from the external FCB is to be included in
  11. ;  the shell/reinvokation command line.  If running on ZCPR 3.0 or the DU: is
  12. ;  not wanted then set Z33 to FALSE.
  13. ;
  14. ;  Added INSERT option in program configuration bytes.  If this option is TRUE
  15. ;  then W will insert it's reinvokation command, which is stored in the first
  16. ;  shell stack entry, into the multiple command line buffer after the command
  17. ;  line W builds using the AFN.  Any commands pending in the multiple command
  18. ;  line buffer are then appended to the end of the reinvokation command.  This
  19. ;  causes W to be reinvoked from the command line and not as a shell.  The two
  20. ;  shell stack entries are still used.
  21. ;  If the INSERT option is FALSE, then W functions as a shell and will be
  22. ;  reinvoked after all commands have been processed from the multiple command
  23. ;  line buffer.  
  24. ;
  25. ;  Corrected problem in next filename selection.  The compare routine compares
  26. ;  all eight bits of each byte of the filename.  If any of the file attributes,
  27. ;  the msb's of the filename, are set then files were being skipped.
  28. ;  Added code that clears the msb of the directory filenames while searching
  29. ;  for the next filename.
  30. ;
  31. ;  Added internal QUIET flag support.  If the IQUIET flag is TRUE then only
  32. ;  install, finish, and  abort messages will be displayed.  Added IQUIET in
  33. ;  configuration bytes.
  34. ;
  35. ;  The AND of the SYS and NONSYS flags is now kept in word 31 of the second
  36. ;  shell stack entry for easy use when W is reinvoked.  WTOKEN is also moved to
  37. ;  word 30 of the second shell stack entry.
  38. ;
  39. ;  M80 and L80 were used for this revision.  The []'s were changed to ()'s.
  40. ;
  41. ;  VERSION 2.1 (Jay Sage personal version)
  42. ;  DATE: December 27, 1986
  43. ;  1) Added an extra message and check for abort at each shell invokation to
  44. ;     keep up user's patience.
  45. ;  2) Fixed a bug in the code that set up the initial value for the previously
  46. ;     matched file.  Since it only replaced '?' with ' ' before, the program
  47. ;     would not work when the ambiguous file spec happened to be unambiguous, a
  48. ;     overlook a file named "JUNK." with no type.  The new code just
  49. ;     initializes the previously matched file to all ' '.
  50. ;  3) Fixed errors in the code for delay. Value is now put in directly in
  51. ;     millisecs.
  52. ;  4) Put SYS, NONSYS, and QSEC (now MSEC) parameters into configuration
  53. ;     and patch bytes at start of program.
  54. ;
  55. ;  Changed code is marked with <JPS>.
  56. ;
  57. ;  VERSION 2.0
  58. ;  DATE    FEB. 10, 1986
  59. ;  Passage of DU: now works as follows:
  60. ;  If Logged user <> file user then
  61. ;    Pass du:filename.typ
  62. ;  Else
  63. ;    If    Logged Drive <>    file drive then
  64. ;      Pass d:filename.typ
  65. ;    Else
  66. ;      Pass filename.typ
  67. ;
  68. ;  Added reset of command status byte so that flow control can work
  69. ;  Corrected results when no files matched wildcard,
  70. ;  Now no trailing spaces follow commands.
  71. ;  Made    delay user settable.
  72. ;  Indication now given if no files match wildcard
  73. ;
  74. ;  VERSION 1.1
  75. ;  date: Jan 29, 1986
  76. ;  improved command line control of user areas:
  77. ;    user area only passed if different from    current.
  78. ;    This way only progs that can use user area info    get it.
  79. ;  removed conditional assembly    HELP equate
  80. ;
  81. ;  previous version:  1.0
  82. ;  date:  Jan 26, 1986
  83. ;
  84. ;    .z80            ; for m80 compatiblity
  85. ;    aseg            ; also for M80/L80 compatiblity
  86. VERS    EQU    22
  87. Z3ENV    ASET    0FE00H
  88. ;
  89. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  90. ;
  91. ;  W.COM may be    used freely by the ZCPR3 community
  92. ;  and is released to the ZCPR3 community through the
  93. ;  new NAOG/ZSIG user's group.
  94. ;
  95. ; W.COM    is a ZCPR3 shell which stores an afn and a ufn on the
  96. ; shell    stack.    It merely finds    the next instance matching the afn
  97. ; which    is larger than the ufn,    stores the find    as a new ufn and inserts
  98. ; it into whatever command line    it is storing, allowing    wildcard capability
  99. ; to programs that do not accept afn parameters.  W.COM    then passes the    rest
  100. ; of the command line to the command processor for action.
  101. ; If no    suitable match is found, W.COM removes itself from the shell
  102. ; stack    and control reverts to the OS.
  103. ;
  104. ;   W.COM is installed by Z3INS.
  105. ;
  106. ;   W.COM works    with all z80 ZCPR3 systems with    at least a
  107. ;   2-entry shell stack    whose entries are at least 32 bytes
  108. ;   The    ZCPR3 "standard" shell stack is    4 32-byte entries.
  109. ;
  110. ;   Z80ASM is required for assembly of this file.
  111. ;   It should also be adaptible    to M80 without much difficulty.
  112. ;
  113. ;   Usage: W COMMAND AFN [parm,parm,...,parm]
  114. ;      or  W ZEX COMMAND AFN [Parm,parm...,parm]
  115. ;
  116. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  117. ;                        ;
  118. ;   routines here need vlib, z3lib and syslib    ;
  119. ;                        ;
  120. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  121. ;
  122.     EXT    GETEFCB                ; z3lib
  123.     EXT    Z3INIT,ZPRSFN,GETSH1,GETSH2    ; z3lib
  124.     EXT    SHPOP,PUTCL,Z3LOG        ; z3lib
  125.     EXT    WAIT1MS,PUTZEX,GETCL1,PUTCST    ; z3lib
  126.     EXT    GETZRUN,GETSHM,PUTSHM,GETMSG    ; z3lib
  127.     EXT    MAFDC,ARGV,CODEND,COMPB,DIRF    ; syslib
  128.     EXT    FILLB,INITFCB,MFN2,SKNSP,SKSP    ; syslib
  129.     EXT    RETUD,PSTR            ; syslib
  130.     EXT    GETUD,PUTUD,CONDIN        ; syslib
  131. ;
  132. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  133. ;                        ;
  134. ; basic    definitions                ;
  135. ;                        ;
  136. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  137. ;
  138. CR    EQU    0DH
  139. LF    EQU    0AH
  140. ESC    EQU    1BH
  141. BDOS    EQU    5
  142. RDBUF    EQU    10
  143. TAILB    EQU    80H
  144. ;
  145. FALSE    EQU    0
  146. TRUE    EQU    NOT FALSE
  147. ;
  148. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  149. ;                        ;
  150. ; user selectable equates            ;
  151. ;                        ;
  152. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  153. ;
  154. Z33    EQU    FALSE    ; true if running on a ZCPR3.3 system and include DU:
  155. SYS    EQU    TRUE    ; <JPS> true to see system type files
  156. NONSYS    EQU    TRUE    ; <JPS> true to see non-system type files
  157. SECHO    EQU    TRUE    ; true for command line echo
  158. IQUIET    EQU    FALSE    ; true for only install, finish, and abort messages
  159. INSERT    EQU    TRUE    ; true for W reinvokation command to be inserted in
  160.             ;   the mult cmd line buf, false to execute as a shell
  161. MSEC    EQU    0000    ; <JPS> delay in milliseconds
  162. ;
  163. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  164. ;                        ;
  165. ;  MAIN    PROGRAM    BODY                ;
  166. ;                        ;
  167. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  168. ;
  169. ;    ORG    100H
  170. ;
  171. ; environment definition
  172. ;
  173.     IF    Z3ENV NE 0
  174. ;
  175. ; external ZCPR3 environment descriptor
  176. ;
  177.     JP    START
  178.     DB    'Z3ENV'        ; this is a ZCPR3 utility
  179.     DB    1        ; external environment descriptor
  180. Z3EADR:
  181.     DW    Z3ENV
  182. ;
  183.     ELSE
  184. ;
  185. ; internal ZCPR3 environment descriptor
  186. ;
  187.     MACLIB    Z3BASE.LIB
  188.     MACLIB    SYSENV.LIB
  189. Z3EADR:
  190.     JP    START
  191.     SYSENV
  192. ;
  193.     ENDIF
  194. ;
  195. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  196. ;                        ;
  197. ; configurataion and patch area <JPS>        ;
  198. ;                        ;
  199. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  200. ;
  201.     DB    'Z33='        ; marker in code
  202. AZ33:
  203.     DB    Z33        ; FFH if ZCPR3.3, else 00H for ZCPR3.0
  204. ;
  205.     DB    'SYS='        ; marker in code
  206. ASYS:
  207.     DB    SYS        ; FFH to allow SYS type files, else 00H
  208. ;
  209.     DB    'NONSYS='    ; marker in code
  210. ANONSYS:
  211.     DB    NONSYS        ; FFH to allow non-SYS type files, else 00H
  212. ;
  213.     DB    'SECHO='    ; marker in code
  214. ASECHO:
  215.     DB    SECHO        ; FFH to have command line echoed
  216. ;
  217.     DB    'IQUIET='    ; marker in code
  218. AIQUIET:
  219.     DB    IQUIET        ; FFH for only install, finish and abort msgs
  220. ;
  221.     DB    'INSERT='    ; marker in code for easy patching
  222. AINSERT:
  223.     DB    INSERT        ; FF to insert W reinvoke cmd in cmd line,
  224.                 ;   else 00H to execute as a shell
  225.     DB    'MSEC='        ; marker in code
  226. DELAY:
  227.     DW    MSEC        ; number of milliseconds to wait between files
  228. ;
  229. ; start of program
  230. ;
  231. START:
  232.     IF    Z3ENV NE 0
  233.     LD    HL,(Z3EADR)    ; pt to    ZCPR3 environment if external env desc
  234.     ELSE
  235.     LD    HL,Z3EADR    ; pt to    ZCPR3 environment if internal env desc
  236.     ENDIF
  237. ;
  238. ; initialize ZCPR3 environment
  239. ;
  240.     CALL    Z3INIT
  241. ;
  242. ; get shell data
  243. ;
  244.     CALL    GETSH2        ; is there a shell stack?
  245.     JR    NZ,SHFINE    ; yes
  246. SHBAD:    LD    HL,SHERR    ; no, so error and abort
  247.     JP    PSTR
  248. ;
  249. SHFINE:
  250.     LD    (SHLSTK),HL    ; save this pointer
  251.     LD    (SHSIZE),DE    ; save shell size
  252.     ADD    HL,DE        ; hl points to 2nd entry on shell stack
  253.     LD    (SHLSTK2),HL    ; save 2nd entry on shell stack
  254. ;
  255. ; determine what name invoked with from the external FCB, if it doesn't exist
  256. ; then use the compiled defaults.
  257. ; if using ZCPR 3.3 and the Z33 flag is true (FFH) then the drive and user (DU)
  258. ; where the com file is located can also be found from the external FCB.
  259. ; 
  260.     CALL    GETEFCB        ; get EXT FCB address
  261.     JP    Z,NOFCB        ; if no EXT FCB, use default SHNAME
  262.     PUSH    HL        ; save EXT FCB address
  263.     LD    DE,SHNAME    ; point to SHNAME
  264.     LD    A,(AZ33)    ; get Z33 flag
  265.     OR    A
  266.     JP    Z,NODU        ; if 0 then not Z33, thus can't determine DU:
  267.     POP    IX        ; get EXT FCB address
  268.     PUSH    IX        ; save it again for later use
  269.     LD    A,(IX+14)    ; get Drive from EXT FCB byte 14
  270.     CALL    DPASS        ; decode and put in SHNAME
  271.     LD    A,(IX+13)    ; get User from EXT FCB byte 13
  272.     CALL    MAFDC        ; decode and put in SHNAME
  273.     LD    A,':'        ; append ':' to DU in SHNAME
  274.     LD    (DE),A
  275.     INC    DE        ; point to next byte in SHNAME
  276.  
  277. NODU:    POP    HL        ; get EXT FCB address
  278.     INC    HL        ; point to filename
  279.     LD    BC,8        ; move first 8 bytes of the filename to SHNAME
  280.     LDIR
  281.     LD    A,' '        ;
  282.     LD    (DE),A        ; insure filename is terminated with a space
  283.     LD    HL,SHNAME    ; point to start of SHNAME
  284.     CALL    SKNSP        ; move pointer to first space in SHNAME
  285.     INC    HL        ; point to next byte
  286.  
  287.     LD    DE,SHNAME    ; calculate length of reinvokation name
  288.     OR    A        ; clear carry
  289.     SBC    HL,DE        ; subtract start from end
  290.     LD    (SHNLEN),HL    ; save length
  291. ;
  292. NOFCB:
  293. ;
  294. ; determine whether to install or just run
  295. ;
  296.     LD    HL,(SHNLEN)
  297.     LD    B,L
  298.     LD    HL,(SHLSTK)    ; compare first entry in the shell stack with
  299.     LD    DE,SHNAME    ;   shell name to see if we are installed
  300.     CALL    COMPB        ; compare
  301.     JP    Z,RUNSH        ; if the same don't install, just run
  302. ;
  303. ; install by putting information in shell stack 
  304. ;
  305.     LD    BC,(SHSIZE)    ; get shell stack size
  306.     LD    A,C
  307.     CP    32
  308.     JR    NC,STD        ; shell    stack size must    be at least 32
  309.     LD    HL,SHERR    ; give message that won't work and abort
  310.     JP    PSTR
  311. ;
  312. STD:    XOR    A        ; don't    mess with command line
  313.     LD    DE,TKNTBL
  314.     LD    HL,TAILB+1
  315.     CALL    ARGV        ; split    command    line into tokens
  316. ;
  317.     LD    A,(NFND)    ; no of    tokens in command line
  318.     CP    2        ; must be at least 2
  319.     JR    NC,CHEKZEX    ; it is, go on
  320. NENUF:    LD    HL,HLPMSG    ; it isn't so print help msg and
  321.     JP    PSTR        ; abort
  322. ;
  323. CHEKZEX:
  324.     LD    HL,(TKN1)    ; compare first    cmd line token
  325.     LD    DE,ZEXNAME    ; with "ZEX "
  326.     LD    B,4
  327.     CALL    COMPB
  328.     JR    NZ,ENUFTOK
  329.     LD    HL,WTOKEN    ; this flag holds either 2 (default) or    3 (ZEX)
  330.                 ; indicating wildcard location
  331.     LD    (HL),3
  332. ENUFTOK:
  333.     LD    BC,(WTOKEN)
  334.     LD    A,(NFND)
  335.     CP    C
  336.     JR    C,NENUF        ; if ZEX now need 3 tokens
  337.     JR    NZ,GT2        ; if exactly 2 tokens must find    end of tail
  338.     CALL    HLTOKEN
  339.     PUSH    HL
  340.     POP    DE        ; copy token address to    de
  341.     DEC    HL
  342. CNTR:    INC    HL        ; look at each character in 2nd    token
  343.     LD    A,(HL)
  344.     OR    A        ; is it    0?
  345.     JR    NZ,CNTR        ; no, get next
  346.     JR    TSTLNG
  347. GT2:    LD    BC,(WTOKEN)
  348.     CALL    HLTOKEN
  349.     EX    DE,HL        ; de has addr of wildcard token
  350.     INC    BC
  351.     CALL    HLTOKEN        ; hl has addr of following token
  352. TSTLNG:    SBC    HL,DE        ; derive length    of wildcard token
  353.     LD    A,(TAILB)    ; length of the    command    tail
  354.     SBC    A,L        ; subtract length of wildcard token
  355.     LD    HL,(SHNLEN)    ; get length of reinvokation name
  356.     ADD    A,L        ; add it to the reinvokation command tail
  357.     CP    32        ; too long for the shell stack?
  358.     JR    C,SMLENUF    ; no, small enough
  359.     JR    Z,SMLENUF    ;
  360.     LD    HL,TOOLRG    ; yes, error and abort
  361.     JP    PSTR
  362. ;
  363. SMLENUF:
  364.     LD    DE,(TKN1)    ; beginning of command in de
  365.     LD    BC,(WTOKEN)
  366.     CALL    HLTOKEN        ; beginning of wildcard    token in hl
  367.     SBC    HL,DE        ; length of tokens before wildcard in hl
  368.     PUSH    HL
  369.     POP    BC        ; move to bc
  370.     LD    HL,SHNAME    ; get start address of SHNAME buffer
  371.     LD    DE,(SHNLEN)    ; get length of shell name
  372.     ADD    HL,DE        ; calc where to append rest of cmd line
  373.     LD    DE,(TKN1)    ; get address for start of cmd line
  374.     EX    DE,HL
  375.     LDIR            ; copy
  376.     PUSH    DE        ; save next load address in ntail buffer
  377.  
  378.     LD    BC,(WTOKEN)
  379.     LD    A,(NFND)
  380.     INC    C        ; bump it
  381.     CP    C        ; and compare with no of tokens    found
  382.  
  383.     JR    NC,DOMOVE    ; c <= # of tokens, so more to move
  384.     POP    HL        ; c > #    of tokens so
  385.     LD    (HL),0        ; put a    zero at    end of ntail
  386.     JR    STARTCONT
  387.  
  388. DOMOVE:    LD    BC,(WTOKEN)
  389.     INC    C        ; we want the token after the wild card
  390.     CALL    HLTOKEN
  391.     POP    DE        ; de has dest addr in ntail buffer
  392.     XOR    A        ; we're    looking    for a zero
  393.     CALL    CPUNTL        ; copy bytes until we find one
  394. ;
  395. STARTCONT:
  396.     LD    BC,(WTOKEN)
  397.     CALL    HLTOKEN        ; convert second token
  398.     LD    DE,AMBIGFCB    ; to a proper z3 fcb
  399.     CALL    INITFCB
  400.     XOR    A        ; a=0 scan dir: first
  401. ;    INC    A        ; a=1 scan du: first <JPS - commented out>
  402.     CALL    ZPRSFN
  403.     LD    A,(DE)
  404.     OR    A        ; was a    drive specified?
  405.     JR    NZ,COPYFCB    ; yes, don't bother changing it
  406.     CALL    RETUD        ; get current du:
  407.     INC    B        ; b is drive code -1
  408.     LD    A,B
  409.     LD    (DE),A        ; store    it in fcb
  410. ;
  411. COPYFCB:    ; <JPS> following code modified to initialize to blanks
  412.     LD    HL,AMBIGFCB+16
  413.     LD    (HL),' '    ; fill starting filename with blanks
  414.     LD    DE,AMBIGFCB+17
  415.     LD    BC,11
  416.     LDIR
  417. ;
  418. FORMSHL:
  419.     LD    HL,AMBIGFCB
  420.     LD    A,1        ; no null termination in SHPUSH2
  421.     CALL    SHPUSH2
  422.     JP    NZ,SHBAD
  423.  
  424.     LD    HL,SHNAME
  425.     XOR    A        ; null termination okay    here
  426.     CALL    SHPUSH2        ; store    the shell name
  427.     JR    Z,RUNSH0    ; push okay, then skip next
  428.     CALL    SHPOP        ; get rid of the fcb's just placed on stack
  429.     JP    SHBAD        ; and abort
  430. RUNSH0:
  431.     LD    HL,HELLO    ; tell user that W has been installed
  432.     CALL    PSTR        ;
  433. ;
  434.     LD    IX,(SHLSTK2)    ; get address of second shell stack
  435. ;
  436. ; Store the value at WTOKEN in the second shell stack entry word 30 so
  437. ; on reinvokation we can easily tell if we are processing a ZEX command
  438. ;
  439.     LD    A,(WTOKEN)    ; get value at WTOKEN, 2=normal, 3=ZEX
  440.     LD    (IX+29),A    ; store in second shell stack word 30
  441. ;
  442. ; Store the system and non-system file use flags in the second shell stack
  443. ; entry word 31
  444. ;
  445.     LD    A,(ASYS)    ; get use system file flag
  446.     AND    01000000B    ; mask to get flag
  447.     LD    B,A        ; save value
  448.     LD    A,(ANONSYS)    ; get use non-system file flag
  449.     AND    10000000B    ; mask to get flag
  450.     OR    B        ; combine flags
  451.     LD    (IX+30),A    ; store in second shell stack word 31
  452. ;
  453. ; Store the current shell control byte in the second shell stack
  454. ; entry word 32 and set this byte for echo of command line
  455. ;
  456.     LD    B,0        ; byte is at Z3MSG+13
  457.     CALL    GETSHM
  458.     LD    (IX+31),A    ; store    it at word 32 of 2nd shell stack
  459.     LD    A,(ASECHO)    ; get shell echo command flag
  460.     AND    00000010B    ; value    to echo    command    lines built
  461.     CALL    PUTSHM        ; put it
  462. ;
  463. ; here is where    the normal processing after initial installation begins
  464. ;
  465. RUNSH:
  466. ;
  467. ; the need to check for ZEX running is only when using ZCPR30, ZEX processes
  468. ; all pending command lines in ZCPR33 before returning to the shell
  469. ;
  470.     CALL    GETZRUN        ; check    ZEX message byte
  471.     JP    NZ,ZEXRUN    ; process ZEX command line if ZEX running
  472.  
  473.     LD    HL,WAITMSG    ; <JPS> remind user that W is running
  474.     CALL    LQPSTR        ; if quiet flag is not set
  475.  
  476.     LD    BC,(DELAY)    ; Delay    value in milliseconds
  477. DLOOP:    LD    A,B
  478.     OR    C
  479.     JR    Z,XLOOP        ; BC = 0 delay finished
  480.     CALL    WAIT1MS        ; delay    to give    chance for abort
  481.     DEC    BC
  482.     JR    DLOOP        ; loop
  483. XLOOP:    CALL    CONDIN
  484.     JR    Z,RUNSH1    ; no key hit, go ahead
  485.     CP    ESC        ; is it    <escape>?
  486.     JR    NZ,RUNSH1    ; no so    go ahead
  487.     LD    HL,ABORTMSG    ; yes
  488.     CALL    PSTR        ; print    msg and
  489.     JP    QUIT1        ; quit
  490. ;
  491. RUNSH1:
  492.     LD    IX,(SHLSTK2)    ; point to second shell stack entry
  493.     LD    A,(IX+29)    ; get WTOKEN value from word 30
  494.     LD    (WTOKEN),A    ; store value in local WTOKEN
  495.  
  496.     CALL    PUTUD        ; save current du:
  497.     LD    A,(IX+13)    ; store    user num from second shell entry in a
  498.     OR    (IX+30)        ; system and non-system file usage flags
  499.     LD    B,A        ; user area to search
  500.     CALL    CODEND        ; hl points to beginning of dir    buffer
  501.     LD    DE,(SHLSTK2)    ; de points to ambiguous fcb in    shell stack
  502.     CALL    Z3LOG
  503.     CALL    DIRF        ; load directory entries
  504.     CALL    GETUD        ; restore du:
  505.     JP    Z,TPAOVFL    ; just in case
  506.     LD    A,B        ; bc holds number of matching entries
  507.     OR    C
  508.     JP    Z,ZQUIT        ; end operation    if no matching entries
  509.  
  510.     PUSH    BC        ; # of dir entries matching ambigfcb
  511.     LD    DE,15        ; so, when 16 is added in the loop, hl
  512.     SBC    HL,DE        ; will point to    the directory buffer + 1
  513.     PUSH    HL
  514. ;
  515. ; loop compares    sorted directory with last filename processed in
  516. ; previous runs
  517. ;
  518. CMPLOOP:
  519.     LD    DE,(SHLSTK2)
  520.     LD    HL,17
  521.     ADD    HL,DE        ; hl holds 1st byte of last file name
  522.                 ; in shell stack fcb
  523.     POP    DE        ; de holds current directory file name
  524.     PUSH    HL
  525.     LD    HL,16
  526.     ADD    HL,DE        ; hl holds next    entry in dir buffer
  527.     POP    DE        ; de holds 1st byte of last file selected
  528. ;
  529. ; reset file attributes so that the ascii compare works properly
  530. ;
  531.     PUSH    HL        ; save pointer to next entry in dir buffer
  532.     LD    B,11        ; reset MSB on the 11 bytes of file name
  533. RLOOP:    RES    7,(HL)        ; reset MSB (file flag) in dir file name
  534.     INC    HL        ; next byte
  535.     DEC    B        ; 
  536.     JR    NZ,RLOOP    ; do for 11 bytes
  537.     POP    HL        ; hl holds next entry in dir buffer
  538.  
  539.     LD    B,11        ; compare 11 bytes
  540.     CALL    COMPB
  541.     JR    C,BUMPB        ; if dir < last    one, not one we    want
  542.     JR    Z,BUMPB        ; if dir = last    one, not one we    want
  543.     JP    DOIT        ; dir >    last one, we want that one
  544. BUMPB:    POP    BC
  545.     DEC    BC
  546.     LD    A,C
  547.     OR    B
  548.     JP    Z,QUIT        ; none found, time to exit shell
  549.     PUSH    BC
  550.     PUSH    HL
  551.     JR    CMPLOOP        ; try again
  552. ;
  553. ; the 'next' file name is entered into the command line
  554. ;
  555. DOIT:                ; <JPS> check again for abort
  556.     CALL    CONDIN
  557.     POP    BC        ; restore BC regs pushed above
  558.     JR    Z,DOIT0        ; no key hit - continue
  559.     CP    ESC        ; is it <escape>?
  560.     JR    NZ,DOIT0    ; no - continue
  561.     LD    HL,ABORTMSG    ; yes - point to abort message
  562.     CALL    PSTR        ; display it
  563.     JP    QUIT1        ; quit
  564. ;
  565. DOIT0:
  566.     PUSH    HL        ; saving addrss    in dir buffer for mfn2
  567.     LD    HL,(SHLSTK2)
  568.     LD    DE,17
  569.     ADD    HL,DE
  570.     EX    DE,HL        ; de points to filename    field of fcb on
  571.                 ; level    2 of shell stack
  572.     POP    HL        ; hl points to chosen filename in dir
  573.     PUSH    HL        ; we're    still gonna need it
  574.     LD    BC,11
  575.     LDIR            ; shell    stack now updated for next runthrough
  576. ;
  577. ; parse    the pseudo - command line in the shell stack
  578. ;
  579. ;    1: eliminate the first argument    as it is W and pass the    second to
  580. ;       the temporary buffer
  581. ;
  582. DOIT1:    LD    HL,(SHLSTK)    ; point to command line in shell stack
  583.     CALL    SKNSP        ; move pointer to first space
  584.     INC    HL        ; now point to second token in command line
  585.     LD    A,(WTOKEN)    ; get value from local WTOKEN
  586.     CP    3        ; if =3 then ZEX command
  587.     LD    A,' '        ; stop on a space
  588.     LD    DE,TEMPBUF
  589.     JR    NZ,ONCE        ; not ZEX, copy    only one token
  590.     CALL    CPUNTL        ; copy token to    temporary buffer
  591. ONCE:    CALL    CPUNTL        ; copy token to    temporary buffer
  592. ;
  593. ;    2: process the fcb that    cmploop    stopped    on, converting it
  594. ;       to a    string with d: and u: if different from    current
  595. ;       add it to the temporary buffer
  596. ;       Note: DE still has address in temporary file    name buffer
  597. ;
  598. DOIT2:    POP    BC        ; address in directory buffer
  599.     PUSH    HL        ; hl = address in shell    stack buffer to    move
  600.     PUSH    BC
  601.     LD    B,17
  602.     LD    A,' '
  603.     EX    DE,HL
  604.     CALL    FILLB        ; fill next 17 bytes of    tempbuf    with ' '
  605.                 ; drive:    1
  606.                 ; user:        2
  607.                 ; colon:    1
  608.                 ; filename:    8
  609.                 ; period:    1
  610.                 ; file type:    3
  611.                 ; trail. space    1
  612.                 ; total           17
  613.     EX    DE,HL
  614.     LD    IX,(SHLSTK2)
  615.     CALL    RETUD        ; Current DU in    BC
  616.     LD    A,(IX+13)    ; File U in A
  617.     CP    C        ; Same?
  618.     JR    Z,USRSAME    ; Yes
  619.     LD    A,(IX)        ; No so    must pass DU:
  620.     CALL    DPASS        ; Pass Drive
  621.     LD    A,(IX+13)
  622.     CALL    MAFDC        ; Pass User
  623.     JR    COLON        ; add the ':'
  624. USRSAME:
  625.     LD    A,(IX)        ; A has    drive code of afn in shell stack
  626.     INC    B        ; B has    Current    D from RETUD, must add 1
  627.     CP    B        ; Current Drive    = File Drive?
  628.     JR    Z,FILENM    ; Yes, pass no DU: at all
  629.     CALL    DPASS        ; Pass Drive
  630. COLON:    LD    A,':'
  631.     LD    (DE),A        ; add the colon
  632.     INC    DE        ; de points to next byte of temp buffer
  633. FILENM:    POP    HL        ; hl = address in directory buffer to process
  634.     EX    DE,HL        ; switch em
  635.     CALL    MFN2        ; adds it to the temp buffer
  636.     CALL    SKNSP        ; hl points to first space
  637. ;
  638. ;    3: move    the rest of the    pseudo command line in the shell stack
  639. ;       buffer into the temporary buffer.  this buffer now contains the
  640. ;       command line    we will    pass to    the ccp.
  641. ;
  642. DOIT3:
  643.     POP    DE        ; de = address in shell    stack buffer to    move
  644.     EX    DE,HL        ; switch 'em
  645.     LD    A,(HL)        ; next byte to write
  646.     OR    A        ; is it    a zero?    (EOL)
  647.     JR    NZ,DOIT3A    ; No.
  648.     LD    (DE),A        ; Yes, Zero last byte of command line
  649.     JR    DOIT3B
  650. DOIT3A:    INC    DE        ; leave    space alone and    add rest of CL
  651.     XOR    A        ; lookin for a zero
  652.     CALL    CPUNTL        ; copy rest of command line to buffer
  653. DOIT3B:    LD    B,0        ; look at shell    msg 0
  654.     CALL    GETSHM
  655.     AND    00000010B    ; echo byte on?
  656.     OR    A        ;
  657.     JR    Z,DOIT5        ; no so    don't print cmdline
  658.     LD    HL,INFORM1
  659.     CALL    LQPSTR        ; print abbreviated <w> message if quiet
  660.                 ; flag is not set
  661.     LD    HL,TEMPBUF
  662.     CALL    LQPSTR        ; print if quiet flag is not set
  663. ;
  664. ; turn off command status byte so IF's will work right
  665. ;
  666. DOIT5:    CALL    GETMSG
  667.     INC    HL
  668.     INC    HL
  669.     INC    HL        ; HL points to command status byte
  670.     LD    (HL),0
  671. ;
  672. ; put our generated command and reinvokation command in the mult cmd buf
  673. ;
  674. ; Note:  the command lines are moved to a scratch buffer in unused memory and
  675. ;      then moved to the mult cmd line buf  because the PUTCL routine
  676. ;      will append any pending commands in the mult cmd buf to the command
  677. ;      line being added, then copy the new command line back to the start
  678. ;      of the mult cmd line buf
  679. ;
  680. DOIT6:    CALL    CODEND        ; hl = start of scratch buffer/memory
  681.     PUSH    HL        ; save start address for later use
  682.     LD    DE,TEMPBUF    ; address of generated command
  683.     EX    DE,HL        ; swap so hl = command, de = buffer
  684.     XOR    A        ; set end of copy character to null word
  685.     CALL    CPUNTL        ; copy command to scratch buffer
  686.  
  687.     LD    A,(AINSERT)    ; get INSERT W reinvokation flag
  688.     OR    A
  689.     JP    Z,DOIT7        ; if FALSE, go add just generated cmd to cmd buf
  690.  
  691.     LD    A,(WTOKEN)    ; get local WTOKEN value
  692.     CP    3        ; if = 3 then processing a ZEX command
  693.     JP    Z,DOIT7        ; if ZEX, go add just generated cmd to cmd buf
  694.  
  695.     EX    DE,HL        ;
  696.     DEC    HL        ; point to null word
  697.     LD    (HL),';'    ; add multiple command seperator in buffer
  698.     INC    HL        ;
  699.     LD    DE,(SHLSTK)    ; get address of reinvokation command
  700.     EX    DE,HL        ; swap so hl = command, de = buffer
  701.     LD    A,' '        ; copy only W, rest of tail not needed
  702.     CALL    CPUNTL        ; copy command to scratch buffer
  703.     EX    DE,HL        ; swap so hl = buffer, de = command
  704.     DEC    HL        ; point to space copied to buffer
  705.     LD    (HL),0        ; mark end of command with null
  706.  
  707. DOIT7:    POP    HL        ; get start address of scratch buffer back
  708.     CALL    PUTCL        ; put commands in mult cmd buf
  709.     JP    Z,MCLOVFL    ; jump if mult cmd buf overflow
  710.     RET            ; to ccp
  711. ;
  712. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  713. ;                        ;
  714. ; EXIT ROUTINES                    ;
  715. ;                        ;
  716. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  717. ;
  718. ; dump the shell and exit
  719. ;
  720. ZQUIT:    LD    HL,STRIKEOUT    ; no matching files message
  721.     CALL    LQPSTR        ; print if quiet flag not set
  722. QUIT:
  723.     LD    HL,GOODBYE
  724.     CALL    PSTR
  725. QUIT1:                ; land here on aborts
  726.     LD    B,0
  727.     LD    IX,(SHLSTK2)
  728.     LD    A,(IX+31)    ; get old shell    message    byte
  729.     CALL    PUTSHM        ; restore it
  730.     CALL    SHPOP        ; take our name    off
  731.     CALL    SHPOP        ; get rid of fcb's on shell stack
  732.     RET            ; to ccp
  733. ;
  734. ; not enuf memory for directory    (just in case)
  735. ;
  736. TPAOVFL:
  737.     CALL    SHPOP        ; reset    shell stack to prior condition
  738.     LD    HL,TPAMSG
  739.     JP    PSTR
  740. ;
  741. ; not enuf room in multiple command line buffer
  742. ;
  743. MCLOVFL:
  744.     LD    HL,MCLMSG
  745.     CALL    PSTR
  746.     JP    QUIT1
  747. ;
  748. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  749. ;                        ;
  750. ; UTILITY ROUTINES                ;
  751. ;                        ;
  752. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  753. ;
  754. ; Convert drive    code in    A to a letter, move it to location
  755. ; in DE    pointer    and bump the pointer
  756. ;
  757. DPASS:
  758.     ADD    A,'@'        ; convert drive    code to    a letter
  759.     LD    (DE),A
  760.     INC    DE        ; bump pointer to temp buffer
  761.     RET
  762. ;
  763. ; this routine takes a value in    c and returns in hl an address to the
  764. ; c'th token in    a string which has been    parsed by argv.
  765. ;
  766. HLTOKEN:
  767.     PUSH    DE
  768.     LD    A,C
  769.     ADD    A,C        ; double this value to get offset
  770.     LD    D,0        ; transfer to de
  771.     LD    E,A
  772.     LD    HL,TKNTBL    ; add to beginning of table
  773.     ADD    HL,DE        ; hl now has pointer to    beginning addr of token
  774.     LD    E,(HL)
  775.     INC    HL
  776.     LD    D,(HL)
  777.     EX    DE,HL        ; hl now points    to beginning of    token
  778.     POP    DE
  779.     RET
  780. ;
  781. ; copy bytes upto and including a given byte
  782. ;   inputs:
  783. ;    a  : byte to stop on
  784. ;    hl : source
  785. ;    de : dest
  786. ;   outputs :
  787. ;    hl and de point    to byte    following the last byte copied
  788. ;
  789. CPUNTL:    
  790.     CP    (HL)
  791.     LDI            ; copy byte from hl to de
  792.     JR    NZ,CPUNTL
  793.     RET
  794. ;
  795. ; local quiet print string - uses AIQUIET flag
  796. ;   inputs:
  797. ;    hl : point to null terminated string to print
  798. ;    (AIQUIET) : internal quiet flag; 00h=print, FFh=don't print
  799. ;   outputs:
  800. ;    none
  801. ;
  802. LQPSTR:
  803.     PUSH    PSW        ; save reg a
  804.     LD    A,(AIQUIET)    ; get W internal quiet flag
  805.     OR    A
  806.     CALL    Z,PSTR        ; if FALSE, print string
  807.     POP    PSW        ; restore reg a
  808.     RET
  809. ;
  810. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  811. ;                        ;
  812. ; module SHPUSH2                ;
  813. ;                        ;
  814. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  815. ;
  816. ; The following    code is    derived    from and is in fact, almost identical
  817. ; to R.    Conn's Z3SHPUSH.MAC, the only differences being
  818. ; 1> z80 code and
  819. ; 2> the fact that Conn's code
  820. ; quite    sensibly stops copying the new entry onto the stack once a
  821. ; zero byte is encountered.  This program introduces a non-
  822. ; standard use of a shell stack    entry to hold an FCB, so needs
  823. ; to copy the full number of bytes regardless of content.  Therefore
  824. ; we introduce an input    flag in    the a register.     When zero the
  825. ; normal SHPUSH    null terminated    copy is    performed.  When non-zero,
  826. ; the full number of bytes is copied.  Obviously, be very careful
  827. ; with this sort of thing.
  828. ;
  829. ; macros
  830. ;
  831. PUTRG    MACRO
  832.     PUSH    HL
  833.     PUSH    DE
  834.     PUSH    BC
  835.     ENDM
  836. GETRG    MACRO
  837.     POP    BC
  838.     POP    DE
  839.     POP    HL
  840.     ENDM
  841. ;
  842. ;    SHPUSH pushes the string (incl ending 0) pted to by hl onto
  843. ; the shell stack if possible.    SHPUSH returns with a=0    and zero flag
  844. ; set (z) if push is successful, else SHPUSH returns with a<>0 and
  845. ; zero flag clear (nz) if an error occurred.  the following error
  846. ; codes    are returned:
  847. ;        1 - no shell stack available
  848. ;        2 - shell stack    is full
  849. ;        3 - string is too long for shell stack entry
  850. ;
  851. SHPUSH2:
  852.     PUTRG            ;save registers
  853. ;
  854. ; get shell data for later use
  855. ;
  856.     LD    (NULTRM),A    ;store a into null termination flag
  857.     PUSH    HL        ;save ptr to string
  858.     CALL    GETSH2        ;get ptr to shell stack
  859. ;
  860.     POP    HL        ;get ptr to string
  861.     JP    Z,NOSHELL    ;error if no shell stack
  862. ;
  863. ; see if string    is too long (only if null-termination in effect);
  864. ;
  865.     PUSH    HL        ;save ptr to string
  866.     LD    A,(NULTRM)    ;following check unnecessary in    event
  867.     OR    A        ;null termination disabled
  868.     JR    NZ,CKS1        ;
  869. CKSIZE:
  870.     LD    A,(HL)        ;get elt
  871.     INC    HL        ;pt to next
  872.     OR    A        ;end of    string?
  873.     JR    Z,CKS1
  874.     DEC    E        ;count down
  875.     JR    NZ,CKSIZE
  876.     JP    TOOBIG        ;string    is too long
  877. CKS1:
  878. ;
  879. ; check    to see if shell    stack is full
  880. ;
  881.     CALL    GETSH2        ;get values for    copy
  882. FCHK:
  883.     LD    A,(HL)        ;get next element
  884.     OR    A        ;last element on stack?
  885.     JR    Z,FCHK1        ;stack ok
  886.     ADD    HL,DE        ;pt to next element
  887.     DEC    B        ;count down
  888.     JR    NZ,FCHK
  889.     JP    NOROOM        ;shell is full
  890. FCHK1:
  891. ;
  892. ; copy current shell stack up
  893. ;
  894.     CALL    GETSH2        ;get shell stack values
  895. ;
  896. ; point    to end of new top element
  897. ;
  898.     PUSH    BC
  899. MOVE0:
  900.     LD    A,B        ;check for done
  901.     CP    1
  902.     JR    Z,MOVE1
  903.     ADD    HL,DE        ;pt to next
  904.     DEC    B        ;count down
  905.     JR    MOVE0
  906. MOVE1:
  907.     POP    BC
  908.     LD    C,E        ;get count of elements in c
  909.     DEC    HL        ;pt to first byte to copy
  910.     EX    DE,HL        ;de pts    to source
  911.     ADD    HL,DE        ;hl pts    to destination
  912. ;
  913. ; copy stack up    one entry size
  914. ;
  915. MOVE2:
  916.     LD    A,B        ;check for copy    done
  917.     CP    1        ;one less element
  918.     JP    Z,MOVE4
  919.     DEC    B        ;count down
  920.     PUSH    BC        ;b=number of elements left to copy, c=size of each
  921. MOVE3:
  922.     LD    A,(DE)        ;get
  923.     LD    (HL),A        ;put
  924.     DEC    HL        ;back up
  925.     DEC    DE
  926.     DEC    C        ;count down
  927.     JR    NZ,MOVE3
  928.     POP    BC        ;get values
  929.     JR    MOVE2
  930. MOVE4:
  931.     LD    A,(NULTRM)    ;the null termination flag is evaluated
  932.     OR    A
  933.     JR    NZ,FULLCOPY
  934.     CALL    GETSH2        ;get ptr to shell stack
  935.     POP    DE        ;get ptr to string
  936. ;
  937. ; copy new shell entry from de to hl
  938. ;
  939. COPY:
  940.     LD    A,(DE)        ;get byte
  941.     LD    (HL),A        ;put byte
  942.     INC    HL        ;pt to next
  943.     INC    DE
  944.     OR    A        ;done?
  945.     JR    NZ,COPY
  946.     JR    WELLDONE
  947. FULLCOPY:
  948.     CALL    GETSH1        ;get ptr to shell stack, and # of bytes    in b
  949.     LD    C,B
  950.     LD    B,0
  951.     POP    DE        ;get ptr to string
  952.     EX    DE,HL        ;reverse em for    ldir
  953.     LDIR
  954. WELLDONE:
  955.     GETRG            ;restore registers
  956.     XOR    A        ;ok return
  957.     RET
  958. NULTRM:    DS    1        ; null termination flag
  959. ;
  960. ; no shell stack available
  961. ;
  962. NOSHELL:
  963.     POP    HL        ;restore hl
  964.     GETRG            ;restore registers
  965.     LD    A,1        ;error code
  966.     OR    A
  967.     RET
  968. ;
  969. ; no room on shell stack
  970. ;
  971. NOROOM:
  972.     POP    HL        ;restore hl
  973.     GETRG            ;restore registers
  974.     LD    A,2        ;error code
  975.     OR    A
  976.     RET
  977. ;
  978. ; string is too    large
  979. ;
  980. TOOBIG:
  981.     POP    HL        ;restore hl
  982.     GETRG            ;restore registers
  983.     LD    A,3        ;error code
  984.     OR    A
  985.     RET
  986. ;
  987. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  988. ;                        ;
  989. ;  Run ZEX on top of W                ;
  990. ;                        ;
  991. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  992. ;
  993. ;  Command line    is currently empty and ZEX is active.
  994. ;  Accept new command line from    ZEX and    pass it    to ZCPR3.
  995. ;  This    code unasheamedly cribbed from Al Dunsmuir's VFILER.
  996. ;
  997. ZEXRUN:    LD    HL,WSTR
  998.     CALL    LQPSTR        ; print if quiet flag not set
  999.     JR    ZEXR1
  1000. WSTR:    DEFB    CR,LF,'W> ',0
  1001. ZEXR1:    LD    A,1        ;tell ZEX that it is prompted
  1002.     CALL    PUTZEX
  1003.     CALL    GETCL1        ;pt to command line buffer
  1004.     LD    D,H        ;copy pointer
  1005.     LD    E,L
  1006.     INC    DE        ;pt to 1st char
  1007.     INC    DE
  1008.     INC    DE
  1009.     INC    DE
  1010.     LD    (HL),E        ;set ptr to first character.
  1011.     INC    HL
  1012.     LD    (HL),D
  1013.     INC    HL        ;pt to char count
  1014.     EX    DE,HL        ;... in    de
  1015.     PUSH    DE        ;save ptr
  1016.     LD    C,RDBUF        ;input line via    bdos
  1017.     CALL    BDOS
  1018.     POP    HL        ;pt to char count
  1019.     INC    HL
  1020.     LD    E,(HL)        ;get char count
  1021.     INC    HL        ;pt to first char
  1022.     PUSH    HL        ;save ptr
  1023.     LD    D,0        ;de=char count
  1024.     ADD    HL,DE
  1025.     LD    (HL),0        ;store ending 0
  1026.     POP    HL        ;pt to first char
  1027.     CALL    SKSP        ;skip over leading spaces
  1028.     LD    A,(HL)        ;check for comment
  1029.     CP    ';'        ;if comment,
  1030.     JR    Z,ZEXRUN    ;loop until real command is found
  1031.     XOR    A        ;a=0
  1032.     CALL    PUTZEX        ;resume    ZEX (a=0)
  1033.     JP    PUTCST        ;set command status to normal (a=0),
  1034.     ;... then return to opsys
  1035. ;
  1036. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1037. ;                        ;
  1038. ; Miscellaneous    Buffers                ;
  1039. ;                        ;
  1040. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1041. ;
  1042. WTOKEN:    DW    2        ; default is that 2nd token is wildcard
  1043. ZEXNAME:
  1044.     DB    'ZEX '        ; check    to see if a ZEX    command
  1045. AMBIGFCB:
  1046.     DS    36
  1047. TEMPBUF:
  1048.     DS    64
  1049. SHLSTK:
  1050.     DS    2
  1051. SHLSTK2:
  1052.     DS    2
  1053. SHSIZE:
  1054.     DW    32
  1055. SHNLEN:
  1056.     DW    NTAIL-SHNAME
  1057. SHNAME:
  1058.     DB    'W '
  1059. NTAIL:    DS    32-($-SHNAME)    ; 32 spaces in shell stack entry
  1060. ;
  1061. ; table    of pointers to command line tokens created by argv
  1062. ;
  1063. TKNTBL:    DB    6
  1064. NFND:    DS    1
  1065. TKN1:    DS    2
  1066. TKN2:    DS    2
  1067. TKN3:    DS    2
  1068. TKN4:    DS    2
  1069. TKN5:    DS    2
  1070. TKN6:    DS    2
  1071. ;
  1072. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1073. ;                        ;
  1074. ; Miscellaneous    Messages            ;
  1075. ;                        ;
  1076. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1077. ;
  1078. SHERR:    DB    'Shell Stack Error.',0
  1079. TOOLRG:    DB    'W Command Line Overflow.',0
  1080. TPAMSG:    DB    CR,LF,'Not Enough Memory. Aborting.',0
  1081. MCLMSG:    DB    CR,LF,'Multiple Command Line Buffer Overflow. Aborting.',0
  1082. HELLO:    DB    '<W Vers. '
  1083.     DB    (VERS/10)+30h,'.'
  1084.     DB    (VERS mod 10)+30h
  1085.     DB    ' Installed>',CR,LF,0
  1086. INFORM1:
  1087.     DB    CR,LF,'<W> ',0
  1088. WAITMSG:
  1089.     DB    CR,LF
  1090.     DB    '   W Scanning for Next Matching File',CR,LF
  1091.     DB    '   Please wait or ESC to abort ... '
  1092.     DB    CR,LF,0
  1093. STRIKEOUT:
  1094.     DB    CR,LF,'   No files match wildcard. ',0
  1095. GOODBYE:
  1096.     DB    CR,LF,'<W Finished>',0
  1097. ABORTMSG:
  1098.     DB    CR,LF,'<W Aborted> ',0
  1099. HLPMSG:
  1100.     DB    CR,LF,'<W Vers. '
  1101.     DB    (VERS/10)+30h,'.'
  1102.     DB    (VERS mod 10)+30h
  1103.     DB    '> -- THE WILDCARD PROCESSOR'
  1104.     DB    CR,LF
  1105.     DB    CR,LF,'SYNTAX:'
  1106.     DB    CR,LF,'      W COMMAND AFN [parm,parm...parm]'
  1107.     DB    CR,LF,'         where COMMAND is any executable ZCPR3 command'
  1108.     DB    CR,LF,'         and AFN is an ambiguous filename upon which'
  1109.     DB    CR,LF,'         COMMAND is to act, with optional parameters'
  1110.     DB    CR,LF,' OR --'
  1111.     DB    CR,LF,'      W ZEX COMMAND AFN [parm,parm...parm]'
  1112.     DB    CR,LF,'         where COMMAND is a ZEX command script file'
  1113.     DB    CR,LF
  1114.     DB    CR,LF,'W is used to add wildcard capability for commands that'
  1115.     DB    CR,LF,'do not normally accept wildcards.'
  1116.     DB    CR,LF
  1117.     DB    CR,LF,'To abort W type <ESCAPE> several times.'
  1118.     DB    CR,LF,0
  1119. ;
  1120.     END
  1121.