home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / ZCPR33 / A-R / RCPPEEP.LBR / RPEEP.LZB / RPEEP.LIB
Text File  |  2000-06-30  |  19KB  |  934 lines
  1. ;=============================================================================
  2. ;
  3. ;        P E E P    C O M M A N D
  4. ;
  5. ;============================================================================
  6.  
  7. ; +++++++    NOT an official RCP segment for Z33RCP.Z80
  8. ;        This is a hacker's module intended to work with Z33RCP.
  9.  
  10. ; Command:    PEEP
  11. ; Function:    Text File Browser and Lister
  12. ; Comments:    The CRT protocol has to be hard coded into this module.
  13. ;        If the TCAP were used, PEEP would not be practical.
  14. ;        PEEPSECURE equate determines where the file is loaded.
  15. ; Author:     Rob Friefeld, 4607 Colorado St., Long Beach, CA 213-434-7338
  16. ; Date:        23 Aug 1987 Version 1.0
  17.  
  18. ;----------------------------------------------------------------------------
  19. ; Usage:    Hands rest on the home row of keys.  Left hand moves ahead,
  20. ;        right hand moves back through file. 
  21. ;                                                            ---
  22. ;                                              Go To Marker | 0 |
  23. ;                                                            ---
  24. ;                      Read More                     Init    Set    Print
  25. ;                  (if memory full)                 Printer Marker (from mark)
  26. ;                         ---                         ---    ---    ---
  27. ;                        | R |                       | I |  | O |  | P |
  28. ;                         ---                         ---    ---    ---
  29. ;    ---    ---    ---    ---    ---    ---    ---    ---    ---    ---
  30. ;   | A |  | S |  | D |  | F |  | G |  | H |  | J |  | K |  | L |  | ; |
  31. ;    ---    ---    ---    ---    ---    ---    ---    ---    ---    ---
  32. ;    End   Scan   Next   Next    Find   Rpt    Prev   Prev  R/Scan  Top
  33. ;  Screen         Line  Screen         Find   Screen  Line         Screen
  34. ;
  35. ;
  36. ;  X - Exit   <sp> - Hop 10 lines   <cr> - Next Screen (F)  </,?> - File Name
  37. ;----------------------------------------------------------------------------
  38.  
  39. ;
  40. ; PEEP EQUATES
  41. ;
  42.  
  43. bell    equ    07h
  44.  
  45. PEEPGO    EQU    NO        ; Permit re-entering with a GO
  46.  
  47.      IF    PEEPGO
  48.     TEXTLOC    EQU    TPA+3    ; There will be a jump instruction at TPA
  49.      ELSE
  50.     TEXTLOC    EQU    TPA    ; File will be read in to TPA
  51.      ENDIF
  52.  
  53. crtrows    equ    24        ; 24 line screen
  54. crtcols    equ    80        ; 80 col screen
  55.  
  56. tabsize    equ    8        ; Tab expansion size
  57. scanspd    equ    2000h        ; Scroll rate - smaller number goes faster
  58.  
  59. scrlns    equ    crtrows-1    ; Don't change these
  60. width    equ    crtcols-1
  61.  
  62. findsz    equ    12        ; Maximum size of "find" string
  63.  
  64. ;
  65. ; PRINITER INITIALIZATION STRING
  66. ; If you wish to send an initialization string with the I command, install
  67. ; it here.  The last byte must have the MSB set.
  68.  
  69. init$str:
  70.     db    cr+80h
  71.  
  72. ;
  73. ; CRT PROTOCOL INSTALLATION SECTION
  74. ;
  75. ; The defaults are standard for Televideo, Wyse, et al.
  76. ; 
  77.  
  78.  
  79. ; CODE TO CLEAR SCREEN, HOME CURSOR
  80. clr_scr        macro
  81.     db    1ah+80h        ; Not used if CLSON is true.
  82.         endm
  83.  
  84. ; CODE FOR CLEAR TO END OF LINE
  85. cl_to_eol    macro
  86.     db    esc,'T'+80h
  87.         endm
  88.  
  89. ; CODE FOR HOME CURSOR, DO NOT CLEAR SCREEN.
  90. hom_crs        macro
  91.     db    1eh+80h
  92.         endm
  93.  
  94. ; CODE FOR INSERT LINE
  95. ins_line    macro
  96.     db    esc,'E'+80h
  97.         endm
  98.  
  99. ; CODE FOR RETURNING CURSOR TO START OF BOTTOM LINE OF CRT
  100. ret_crs        macro
  101.     db    esc,'=',scrlns+32,0+32+80h
  102.         endm
  103.  
  104. ; CODE FOR STANDOUT MODE.  MUST NOT TAKE SCREEN SPACE.  USE 0 IF NOT AVAILABLE.
  105. dim_on        macro
  106.     db    esc,')'+80h
  107.         endm
  108.  
  109. ; CODE FOR STANDEND.
  110. dim_off        macro
  111.     db    esc,'('+80h
  112.         endm
  113.  
  114. ;
  115. ;  END OF CRT PROTOCOL INSTALLATION SECTION
  116. ;
  117.  
  118.  
  119. ;
  120. ; CRT ROUTINES USING ABOVE MACROS
  121. ;
  122.  
  123. ; PRINT CR AND CLREOL
  124. cr$clr:    ld    a,cr
  125.     call    conout
  126. clreol:    call    print
  127.     cl_to_eol
  128.     ret
  129.  
  130. ; HOME CURSOR
  131. homcrs:    call    print
  132.     hom_crs
  133.     ret
  134.  
  135. ; INSERT BLANK LINE AT TOP OF SCREEN
  136. inslin:    call    homcrs
  137.     call    print
  138.     ins_line
  139.     jr    clreol
  140.  
  141. ; RETURN CURSOR TO LAST LINE OF SCREEN
  142. retcrs:    call    print
  143.     ret_crs
  144.     ret
  145.  
  146. ; CLEAR SCREEN
  147.      if    [ not CLSON ]
  148. cls:    call    print
  149.     clr_scr
  150.     ret
  151.      endif
  152.  
  153. ;
  154. ; DISPLAY CONTROL CHARACTERS AS ^n
  155. ;
  156.  
  157. outchr:
  158.     cp    20h
  159.     jp    nc,conout    ; Not a control
  160.  
  161. ; WE HAVE A CONTROL
  162.  
  163.     push    af    ;save it
  164.     ld    a,'^'
  165.     call    conout
  166.     pop    af    ;restore it
  167.     add    40h    ;make it printable
  168.     inc    c    ;bump tab expansion counter of "^" char
  169.     jp    conout
  170.  
  171. ; SWITCHING CONOUT
  172.  
  173. plcon:    ld    a,5        ; Switch to list output
  174. plcon1:    ld    (conout+8),a    ; Poke list byte at  ld  c,bdosf
  175.     ret
  176.  
  177. plcoff:    ld    a,2        ; Switch to con output
  178.     jr    plcon1
  179.  
  180. ; START STANDOUT MODE
  181. stndout:
  182.     call    print
  183.     dim_on
  184.     ret
  185.  
  186. ; END STANDOUT MODE
  187. stndend:
  188.     call    print
  189.     dim_off
  190.     ret
  191.  
  192. ;
  193. ; SLOW DOWN SCAN FUNCTIONS
  194. ;
  195.  
  196. wait:    ld    hl,scanspd
  197. wait0:    dec    hl        ; Down count to 0
  198.     ld    a,h
  199.     or    l
  200.     ret    z
  201.     jr    wait0
  202.  
  203. ;
  204. ; WAIT FOR A CHAR THEN ERASE LINE
  205. ;
  206. getchr:
  207.     call    conin
  208.     push    af
  209.     call    cr$clr        ; Erase it
  210.     pop    af
  211.     ret
  212.  
  213. ;
  214. ;  UPCASE CHAR IN A
  215. ;
  216.  
  217. mkupper:
  218.     cp    'a'
  219.     ret    c
  220.     cp    'z'+1
  221.     ret    nc
  222.     and    5fh
  223.     ret
  224.  
  225. ;
  226. ; MAIN PROGRAM
  227. ;
  228.  
  229. peep:    call    retsave        ; Save zcpr return
  230.  
  231. ; A jump instruction to peep is loaded at 100h.  This permits using peep again
  232. ; with a GO, and prevents an object file read in at TPA from starting with a GO
  233.  
  234.      if    peepgo
  235.     ld    a,0c3h        ; Jump code
  236.     ld    (tpa),a
  237.     ld    hl,peep
  238.     ld    (tpa+1),hl
  239.      endif
  240.  
  241.     call    getfil        ; Read the file into memory
  242.     call    cls        ; Clear the screen
  243.  
  244. ; RESTART ENTRY FOR READING IN MORE TEXT ON "MEMORY FULL" MESSAGE
  245.  
  246. resrt:    ld    hl,textloc    ; Set Start Pointer to beginning of file
  247.     ld    (srtptr),hl
  248.     ld    (mrkptr),hl    ; Set place marker to start of text
  249.  
  250.     ld    hl,(eofptr)    ; Set End of Screen Pointer to beginning
  251.     ld    b,scrlns    ;   of last screen
  252.     call    pvline        ; Back up one screen from end
  253.     djnz    $-3
  254.     ld    (eosptr),hl    ; Now set pointer
  255.  
  256. ;
  257. ; PRINT ONE SCREEN OF TEXT
  258. ;
  259.  
  260. prnscr:    call    homcrs
  261.     ld    hl,(srtptr)
  262.     push    hl        ; If near end then print entire last screen
  263.     ld    de,(eosptr)    ; Compute position relative to last screen
  264.     xor    a        ; Reset carry flag
  265.     sbc    hl,de
  266.     pop    hl
  267.     jr    z,prn1        ; We are at or before last screen so go ahead
  268.     jp    nc,last        ; We are past last screen so back up
  269.  
  270. prn1:    ld    b,scrlns    ; Line count in B
  271. prnlp1:    call    clreol
  272.     call    prnline
  273.     djnz    prnlp1        ; Print SCRLNS lines
  274.     ld    (nxtptr),hl    ; And set Next Pointer
  275.     call    retcrs        ; Cursor to prompt line
  276.  
  277. ;
  278. ; COMMAND INPUT ROUTINE
  279. ;
  280.  
  281. command:
  282.     call    getchr        ; Get command
  283.     call    case        ; Scan list of commands
  284.  
  285. ;
  286. ; COMMAND LIST: CHAR TO MATCH FOLLOWED BY ADDRESS
  287. ;
  288.  
  289.     db    'A'        ; Last screen of file
  290.     dw    last
  291.     db    'D'        ; Forward a line
  292.     dw    down
  293.     db    'F'        ; Next screen
  294.     dw    next
  295.     db    'G'        ; Find string
  296.     dw    find
  297.     db    'H'        ; Find string again
  298.     dw    find0
  299.     db    'I'        ; Init printer
  300.     dw    init$prt
  301.     db    'J'        ; Previous screen
  302.     dw    prev
  303.     db    'K'        ; Back a line
  304.     dw    up
  305.     db    'L'        ; Scan backward
  306.     dw    back
  307.     db    'O'        ; Set place marker
  308.     dw    mark
  309.     db    'P'        ; Print from marker
  310.     dw    list
  311.     db    'R'        ; Read in more text
  312.     dw    read
  313.     db    'S'        ; Scan forward
  314.     dw    scan
  315.     db    'X'        ; Exit to CPR
  316.     dw    exit
  317.     db    ';'        ; Top of file
  318.     dw    top
  319.     db    '0'        ; Go to marker
  320.     dw    gomark0
  321.     db    20h        ; <sp> jump ahead 10 lines
  322.     dw    hop
  323.     db    cr        ; <cr> next screen
  324.     dw    next
  325.     db    '/'
  326.     dw    what        ; Show filename
  327.     db    '?'
  328.     dw    what
  329.     db    0        ; table delimiter
  330.  
  331.     jr    command        ; Loop back on invalid input
  332.  
  333. ;
  334. ; CASE - JUMP TABLE SCANNER
  335. ; FORMAT:  CALL CASE    ;CALL WITH VALUE TO MATCH IN A
  336. ;       DB    VAL1    ;FIRST VAL TO MATCH
  337. ;       DW    ADDR1    ;JUMP ADDRESS
  338. ;       ...
  339. ;       DB    0    ;END TABLE
  340. ;       ELSE NEXT INSTUCTION EXECUTES IF NO MATCH
  341.  
  342. case:
  343.     ex    (sp),hl        ;hl -> next addr after call
  344.     ex    af,af'        ;save char
  345.     xor    a
  346. case1:
  347.     ex    af,af'        ;restore char
  348.     cp    (hl)        ;match?
  349.     inc    hl        ;set pointer to val's jump addr
  350.     jr    z,case0        ;if match, jump
  351.     inc    hl        ;point to next val
  352.     inc    hl
  353.     ex    af,af'        ;check for list terminator
  354.     cp    (hl)
  355.     jr    nz,case1    ;keep looking
  356.  
  357.     inc    hl        ;no match, execute next instruction
  358. casex:    ex    (sp),hl
  359.     ret
  360.  
  361. case0:    ld    e,(hl)        ;load address
  362.     inc    hl
  363.     ld    d,(hl)
  364.     ex    de,hl
  365.     jr    casex        ;go
  366.  
  367. ;
  368. ;  PRINT ONE LINE OF TEXT
  369. ;  HL -> first char on entry, next char on exit
  370. ;
  371.  
  372. prnline:
  373.     push    bc        ; Preserve possible loop counter on entry
  374.     xor    a
  375.     ld    c,a        ; Char counter for CRT width and tabs
  376. prnl1:
  377.     ld    a,(hl)        ; Get char
  378.     cp    eof        ; At end?
  379.     jr    z,prnl2        ; Can occur on text smaller than one screen
  380.     call    prnl3        ; Print the character
  381.     cp    lf        ; Are we at end of line?
  382.     inc    hl        ; Bump pointer
  383.     jr    nz,prnl1    ; No
  384. prnl2:    pop    bc
  385.     ret            ; Exit routine
  386.  
  387. ; PRINT THE CHAR IF THE LINE IS NOT FULL
  388.  
  389. prnl3:    cp    cr        ; Always print cr
  390.     jp    z,conout
  391.     cp    lf        ; Always print lf
  392.     jp    z,conout
  393.     cp    tab
  394.     jr    z,prnl5        ; Expand tab
  395.  
  396. prnl4:    ld    e,a        ; Save char
  397.     inc    c        ; Bump char counter
  398.     ld    a,width        ; Exceeded line width?
  399.     cp    c
  400.     ret    c        ; Yes, quit
  401.     ld    a,e        ; Restore char
  402.     jp    outchr        ; Send it out
  403.  
  404. ; TAB EXPANSION
  405.  
  406. prnl5:    ld    a,c        ; Compute char count MOD tabsize
  407.     sub    tabsize
  408.     jr    nc,$-2
  409.     neg            ; Spaces to next tab in A
  410.     ld    b,a        ; Use as loop counter
  411.     ld    a,' '        ; Print space
  412. prnl51:    call    prnl4        ; Send it out if room and update char count
  413.     ret    c        ; Line overflow, quit
  414.     djnz    prnl51
  415.     ret
  416.  
  417. ;
  418. ; PRINT NEXT SCREEN
  419. ;
  420.  
  421. next:    ld    hl,(nxtptr)
  422.     ld    a,eof        ; Is there a next screen?
  423.     cp    (hl)
  424.     jr    z,hop0        ; No
  425.     ld    (srtptr),hl    ; Next screen is new start pointer
  426.     jr    top0        ; Print the screen
  427.  
  428. ;
  429. ; PRINT FIRST SCREEN
  430. ;
  431.  
  432. top:    ld    hl,textloc    ; Start of text
  433.     ld    (srtptr),hl    ; To start pointer
  434. top0:    jp    prnscr
  435.  
  436. ;
  437. ; PRINT LAST SCREEN
  438. ;
  439.  
  440. last:    ld    hl,(eosptr)    ; Top of last screen
  441.     ld    (srtptr),hl    ; Start there
  442.     jr    top0        ; Print the screen
  443.  
  444. ;
  445. ; PRINT NEXT LINE
  446. ;
  447.  
  448. down:    ld    b,1        ; Loop counter = 1 line
  449.     jr    hop1        ; Print the line
  450.  
  451. ;
  452. ; HOP FORWARD 10 LINES
  453. ;
  454.  
  455. hop:    ld    b,10        ; Loop counter = 10 lines
  456. hop1:    push    bc        ; Save it
  457.     call    dnline        ; Print next line
  458.     pop    bc
  459.     djnz    hop1
  460. hop0:    jp    command
  461.  
  462. ;
  463. ; SCROLL CONTINUOUSLY AHEAD UNTIL A KEY PRESSED
  464. ;
  465.  
  466. scan:    call    dnline        ; Print next line
  467.     jr    z,hop0        ; Routine returns 0 on EOF
  468.     call    scstop        ; Check for key press
  469.     call    wait        ; Pause a few msec
  470.     jr    scan
  471.  
  472. ;
  473. ;  CHECK FOR BREAK
  474. ;
  475.  
  476. scstop:    ld    c,CONSTF
  477.     call    bdos
  478.     or    a
  479.     ret    z        ; No character, continue
  480.     pop    af        ; Dispose of return address
  481.     call    getchr        ; Erase screen echo and dispose of char
  482.     jr    hop0        ; Back to command list
  483.  
  484. ;
  485. ; PRINT NEXT LINE
  486. ;
  487.  
  488. dnline:    ld    hl,(nxtptr)    ; Look at start of next line
  489.     ld    a,eof        ; Is it EOF?
  490.     cp    (hl)
  491.     ret    z        ; There is no next line
  492.     call    prnline        ; Print the line
  493.     ld    (nxtptr),hl    ; Advance Next Pointer
  494.     ld    hl,(srtptr)    ; Advance Start Pointer
  495.     call    nxline        ; Find start of next line
  496.     ld    (srtptr),hl    
  497.     xor    a        ; A NZ flag on successful return
  498.     dec    a
  499.     ret
  500.  
  501. ;
  502. ;  SEARCH FOR NEXT LINE OF TEXT
  503. ;  HL -> starting point
  504. ;
  505.  
  506. nxline:    ld    a,(hl)        ; Look at char
  507.     cp    eof
  508.     ret    z        ; No more text
  509.     inc    hl        ; Bump pointer
  510.     cp    lf
  511.     jr    nz,nxline
  512.     ret            ; Returns HL at character after LF
  513.  
  514. ;
  515. ; PRINT PREVIOUS SCREEN
  516. ;
  517.  
  518. prev:    ld    hl,(srtptr)    ; HL-> char at top of screen
  519.     ld    b,scrlns    ; Loop counter SCRLNS lines
  520. prev0:    call    pvline        ; Find start of previous line
  521.     djnz    prev0
  522.     ld    (srtptr),hl    ; Set Start Pointer
  523.     jp    prnscr        ; Print the screen
  524.  
  525. ;
  526. ;  SEARCH FOR START OF PREVIOUS LINE OF TEXT
  527. ;
  528.  
  529. pvline:    push    bc        ; Save possible loop counter on entry
  530.     ld    b,2        ; We need the LF BEFORE the last one
  531. prvlp:    xor    a        ; Reset carry flag
  532.     ld    de,textloc    ; Are we already at beginning of file?
  533.     push    hl
  534.     sbc    hl,de
  535.     pop    hl
  536.     jr    c,prv0        ; Yes, so we are done
  537.     ld    a,(hl)        ; Look for last LF
  538.     cp    lf
  539.     dec    hl        ; Decrement char pointer
  540.     jr    nz,prvlp    ; Haven't found LF yet
  541.     djnz    prvlp        ; Do it once more
  542.     inc    hl        ; Move HL pointer to character after LF
  543. prv0:    inc    hl
  544.     pop    bc
  545.     ret
  546.  
  547. ;
  548. ;  PRINT PREVIOUS LINE
  549. ;
  550.  
  551. up:    call    upline
  552. up0:    jp    command
  553.  
  554. ;
  555. ; SCAN BACKWARDS UNTIL KEY PRESS
  556. ;
  557.  
  558. back:    call    upline        ; Move up a line
  559.     jr    z,up0        ; Returns Z if no more lines
  560.     call    scstop        ; Check for break
  561.     call    wait        ; Give screen time to catch up
  562.     jr    back
  563.  
  564. ;
  565. ; MOVE DISPLAY UP A LINE
  566. ;
  567.  
  568. upline:    ld    de,textloc    ; Are we already at start of text?
  569.     ld    hl,(srtptr)
  570.     xor    a
  571.     sbc    hl,de
  572.     ret    z        ; Yes, quit and return Z
  573.  
  574.     call    inslin        ; Home cursor and insert a blank line
  575.     ld    hl,(srtptr)    ; Back up a line
  576.     call    pvline
  577.     ld    (srtptr),hl    ; Set pointer
  578.     call    prnline        ; Print the line
  579.     ld    hl,(nxtptr)    ; Set Next Pointer
  580.     call    pvline
  581.     ld    (nxtptr),hl
  582.     call    retcrs        ; Return cursor to bottom of screen
  583.     call    cr$clr        ; Erase dead line
  584.     xor    a        ; Return NZ
  585.     dec    a
  586.     ret
  587.  
  588. ;
  589. ; FIND A STRING
  590. ;
  591.  
  592. find:
  593.     call    STNDOUT
  594.     call    print        ; Find string in following pages
  595.     db    'Find ->',' '+80h
  596.     ld    de,finbuf    ; Read string to find
  597.     ld    c,RDBUFF
  598.     call    bdos
  599.     call    STNDEND
  600.     call    cr$clr        ; Erase it from screen
  601.  
  602. find0:    ld    ix,finbuf+1    ; IX points to string length
  603.     ld    a,(ix)        ; Move it to A
  604.     or    a
  605.     jp    z,command    ; 0 length string ... abort
  606.  
  607. ;  UPCASE THE STRING FOR CASE INSENSITIVE SEARCH
  608.  
  609.     ld    b,a        ; Length is loop counter
  610.     ld    hl,findat    ; First char of string
  611. find01:    ld    a,(hl)
  612.     call    mkupper
  613.     ld    (hl),a
  614.     inc    hl
  615.     djnz    find01
  616.  
  617. ; START SEARCH AT NEXT LINE
  618.     ld    hl,(srtptr)
  619.     call    nxline        ; HL now -> next line
  620. finlp0:    ld    iy,findat    ; IY will be string pointer
  621. finlp1:    ld    a,(hl)        ; Get char from text
  622.     call    mkupper        ; Upcase it
  623.     cp    eof
  624.     jr    z,finot        ; Hit end of file before match
  625.     cp    (iy)        ; First char to match
  626.     inc    hl        ; Bump text pointer
  627.     jr    nz,finlp1    ; No match, keep moving through text
  628.  
  629. ; AT THIS POINT, FIRST CHAR IS MATCHED
  630.     ld    b,(ix)        ; IX still has string length
  631.     dec    b        ; We have already found 1
  632.     jr    z,findex    ; Done if only 1 char to match
  633. finlp2:    inc    iy        ; Compare the next chars
  634.     ld    a,(hl)
  635.     call    mkupper
  636.     cp    (iy)
  637.     jr    nz,finlp0    ; No match ... start looking again
  638.     inc    hl        ; So far, so good
  639.     djnz    finlp2        ; Match next chars
  640.  
  641. ; THE STRING IS IN THE CURRENT LINE, MOVE IT TO TOP OF SCREEN
  642.  
  643. findex:    call    pvline        ; Find previous line
  644.     call    nxline        ; Go to beginning of this line
  645.     ld    (srtptr),hl
  646.     jp    prnscr        ; Show the screen
  647.  
  648. ; NO LUCK ON FIND
  649.  
  650. finot:    call    cr$clr        ; String not found - print message
  651.     call    stndout
  652.     call    print
  653.     db    'Not found',' '+80h
  654. finot0:    call    stndend
  655.     jp    command
  656.  
  657.  
  658. ;  BUFFERS FOR FIND
  659.  
  660. finbuf:    db    FINDSZ        ; String to match size
  661.     ds    1        ; Returned char count
  662. findat:    ds    FINDSZ        ; Buffer
  663.  
  664. ;
  665. ;  SHOW FILE NAME COMMAND
  666. ;
  667.  
  668. what:    call    stndout
  669.     ld    hl,fcb1+1
  670.     call    prfn        ; ROUTINE ELSEWHERE IN RCP
  671.     jr    finot0        ; Finish up display
  672.  
  673. ;
  674. ; SET PLACE MARKER
  675. ;
  676.  
  677. mark:
  678.     ld    hl,(srtptr)    ; Top of screen pointer is marker pointer
  679.     ld    (mrkptr),hl
  680.     call    stndout
  681.     call    print
  682.     db    'Marke','d'+80h
  683.     jr    finot0        ; Finish up display
  684.  
  685.  
  686. ;
  687. ; GO TO MARKER
  688. ;
  689.  
  690. gomark0:
  691.     ld    hl,(mrkptr)
  692.     ld    (srtptr),hl
  693.     jp    prnscr
  694.  
  695.  
  696. ;
  697. ;  LIST MARKED PORTION OF FILE
  698. ;
  699.  
  700. list:
  701.     ld    hl,lstmsg
  702.     call    qprompt        ; Are we serious?  (And is printer on?)
  703.     jr    z,list4        ; Abort
  704.  
  705. ; Compute print block size
  706.  
  707.     ld    de,(mrkptr)    ; Beginning of block
  708.     ld    hl,(nxtptr)    ; End of block
  709.     xor    a
  710.     sbc    hl,de        ; Block size now in HL
  711.     jr    c,lsterr    ; If beginning at or after end then no go
  712.     jr    z,lsterr
  713.  
  714. ; Set up pointers
  715.  
  716.     ex    de,hl        ; Block size in DE, start in HL
  717.     push    de
  718.     pop    bc        ; Block size in HL
  719.     ld    de,0        ; Count # lines in DE
  720.     ld    a,lf
  721. list1:    cpir            ; Count line feeds
  722.     jp    po,list11    ; Loop expired
  723.     inc    de
  724.     jr    list1
  725.  
  726. list11:
  727.     call    plcon        ; Switch output to list
  728.     push    de
  729.     pop    bc        ; Count to BC
  730.     inc    bc        ; Actually need 1 more
  731.     ld    hl,(mrkptr)    ; Print BC lines
  732. list3:    call    prnline        ; Output switched to list:
  733.     dec    bc
  734.     ld    a,b
  735.     or    c
  736.     jr    nz,list3
  737.  
  738.     call    plcoff        ; Switch output to con:
  739.  
  740. lsterr:    ld    a,bell        ; Beep on marker error or finish print
  741.     call    conout
  742. list4:    call    cr$clr
  743. listx:    jp    command
  744.  
  745.  
  746.  
  747. lstmsg:    db    'Print from MAR','K'+80h
  748.  
  749. ;
  750. ;  SEND INIT STRING TO PRINTER
  751. ;
  752.  
  753. init$prt:
  754.     ld    hl,initmsg
  755.     call    qprompt
  756.     jr    z,list4
  757.     call    plcon        ; Switch conout to list
  758.     ld    hl,init$str    ; Send string
  759.     call    printhl
  760.     call    plcoff        ; Switch conout to con
  761.     jr    list4
  762.  
  763. initmsg:
  764.     db    'Init LST',':'+80h 
  765.  
  766. ;
  767. ;  READ FILE INTO TPA UNTIL FULL OR EOF
  768. ;
  769.  
  770. getfil:
  771.  
  772. ; SET UP TOP OF MEMORY POINTER
  773.  
  774.     ld    hl,(bdos+1)    ; BDOS location
  775.     ld    de,-905h    ; CCP size + TPA  +  cr,lf,eof at end
  776.     add    hl,de
  777.     ld    (topmem),hl    ; Store as top of memory
  778.  
  779. ; REJECT BLANK FILE SPEC
  780.  
  781. getfil1:
  782.     call    filcheck
  783.  
  784.     CALL    LOGUSR        ; ROUTINE IS IN RCPSUBS.LIB
  785.  
  786. ; OPEN THE FILE
  787.     call    opensource
  788.  
  789. ; RESET EOF FLAG (EOF NOT ENCOUNTERED)
  790.     xor    a
  791.     ld    (eoflag),a
  792.  
  793. ; FILE READ LOOP
  794.  
  795.     ld    hl,textloc    ; Start of text pointer
  796. getlp1:    ld    (srtptr),hl    ; Entry with hl -> input location
  797.     ex    de,hl
  798.  
  799.     ld    hl,(topmem)    ; Check memory full
  800.     xor    a
  801.     sbc    hl,de
  802.     jr    c,toobig    ; Yes
  803.  
  804.     ld    c,SETDMAF    ; File read into current position
  805.     call    bdos
  806.     ld    de,fcb1
  807.     ld    c,readf
  808.     call    bdos
  809.     or    a        ; Check for end of file encountered
  810.     jr    nz,geteof    ; Yes
  811.     ld    hl,(srtptr)    ; Move pointer along one record worth
  812.     ld    de,128
  813.     add    hl,de
  814.     jr    getlp1        ; Keep reading
  815.  
  816. geteof:    ld    (eoflag),a    ; Set EOF flag
  817.     ld    hl,(srtptr)    ; Eof not returned until read after eof!
  818.     ld    de,-128
  819.     add    hl,de        ; Back up a record
  820.     ld    a,eof
  821.     ld    bc,128
  822.     cpir            ; Find the first eof
  823.  
  824. ; SET UP EOF POINTER
  825.  
  826. getmrk:
  827.     dec    hl
  828. getmrk1:
  829.     ld    (hl),cr        ; Works better with CRLF at end of file
  830.     inc    hl
  831.     ld    (hl),lf
  832.     inc    hl
  833.     ld    (hl),eof
  834.     ld    (eofptr),hl    ; Store it for later
  835.     ret
  836.  
  837. ; FILE HAS FILLED AVAILABLE MEMORY, PRINT WARNING
  838.  
  839. toobig:    push    de
  840.     call    print
  841.     db    bell,'Mem full',' '+80h
  842.     call    getchr        ; Wait for key press
  843.     pop    hl
  844.     jr    getmrk1
  845.  
  846.  
  847. ;
  848. ; READ MORE TEXT COMMAND
  849. ;
  850.  
  851. read:    ld    a,(eoflag)    ; Has EOF been encountered?
  852.     or    a
  853.     jr    nz,rdprompt    ; If so, send message
  854.     ld    de,textloc    ; Else, preserve some text and read more
  855.     ld    hl,(eosptr)
  856.     ld    a,eof
  857. rdlp1:    ldi            ; Move last page to beginning of buffer
  858.     cp    (hl)        ; Check for end of file marker
  859.     jr    nz,rdlp1    ; Loop until it is reached
  860.     dec    de        ; Back up over last CR,LF
  861.     dec    de
  862.     ex    de,hl        ; HL now points to read data location
  863.     call    getlp1        ; Fill memory with more of file
  864.     jr    readx        ; Re-initialize pointers and start
  865.  
  866.  
  867. ; PROMPT IF NO MORE TO READ
  868.  
  869. rdmsg:    db    'Start ove','r'+80h
  870. rdprompt:
  871.     ld    hl,rdmsg
  872.     call    qprompt
  873.     push    af        ; Save answer
  874.     call    cr$clr
  875.     pop    af
  876.     jp    z,command    ; No
  877.  
  878.  
  879. ; STARTING OVER, ZERO FCB POSITION POINTERS
  880.  
  881. read1:
  882.     CALL    INITFCB1    ; IN RCPSUBS.LIB
  883.     call    getfil1        ; Read the file
  884. readx:    jp    resrt        ; Restart PEEP
  885.  
  886.  
  887. ; EXAMINE COMMAND LINE FOR FILE SPEC
  888.  
  889. filcheck:
  890.     ld    hl,fcb1+1
  891.     ld    a,' '
  892.     cp    (hl)
  893. filcx:    ret    nz
  894.     call    prfnf        ; ROUNTINE IS ELSEWHERE IN RCP
  895.     jp    exit        ; NO FILE SPEC
  896.  
  897. ; OPEN SOURCE FILE
  898.  
  899. opensource:
  900.     ld    de,fcb1
  901.     ld    c,openf
  902.     call    bdos
  903.     inc    a
  904.     jr    filcx
  905.  
  906.  
  907. ; Enter with HL -> message.  Return Z if answer = N.
  908. qprompt:
  909.     call    stndout
  910.     call    printhl
  911.     call    print
  912.     db    ' ? (Y/n)',' '+80h
  913.     call    stndend
  914.     call    conin
  915.     cp    'N'
  916.     ret
  917.  
  918.  
  919. ;
  920. ; STORAGE
  921. ;
  922.  
  923. eoflag    ds    1        ; EOF encountered flag
  924. srtptr    ds    2        ; Start Pointer -> top of screen
  925. nxtptr    ds    2        ; Next Pointer -> next screen
  926. eosptr    ds    2        ; End of Screen Pointer -> last screen
  927. eofptr    ds    2        ; End of File Pointer -> end of text
  928. topmem    ds    2        ; Top of memory pointer
  929. mrkptr:    dw    textloc        ; Place marker
  930.  
  931. ; End RCP-PEEP.Z80
  932.  
  933. File Pointer -> end of text
  934. topmem    ds    2        ; Top of memory poin