home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / ZCPR33 / A-R / PTCAP12.LBR / PTCAP12.1Z0 / PTCAP12.180
Text File  |  2000-06-30  |  22KB  |  689 lines
  1. title PTCAP TCAP Modifier for PBBS
  2. ;=========================================================================
  3. ; PTCAP  
  4. ;
  5. ; Written by:     Terry Pinto
  6. ;        Access Programming RAS
  7. ;        14385 SW Walker Rd. B3
  8. ;        Beaverton, OR  97006
  9. ;        
  10. ;        (503) 646-4937  (300/1200  24 hours/day)
  11. ;        (503) 644-0900  Voice ==> 6:00pm to 10:00pm ONLY
  12. ;
  13. ; This program was designed to make the updateing of the TCAP entry
  14. ; file easier. At present, each time a new TCAP file is released, 
  15. ; all of the user entries must be updated by hand, or each caller 
  16. ; must go in and reselect his/her terminal identifier. This can be
  17. ; a large undertaking in the case of better known boards that have 
  18. ; a large user base. This makes the changeover to new TCAP's sluggish.
  19. ; Many sysop's are not installing the new versions of TCAP because of 
  20. ; this drawback. Gentlemen, we have computers to do the jobs we don't
  21. ; want to or don't have time to do. Lets get the show on the road!
  22. ;
  23. ; PTCAP reads the index list of both the current and new TCAP's into
  24. ; memory. Then the PBBS user base (USERS.PBS) is opened and each user 
  25. ; record is examined. The terminal code is taken from the user record   
  26. ; and is used to get the current terminal id string. This string is
  27. ; compared against the new TCAP file. When a match is found, a new  
  28. ; index number is calculated and stored in the user record. If no      
  29. ; match is found, it is assumed that support for the previous entry 
  30. ; has been dropped. The user record is then updated to reflect the 
  31. ; (None requested) selection. This entry will force the user through
  32. ; selection process on his/her next call. 
  33. ;
  34. ; PTCAP was written to assemble with SLR180p, however it will also
  35. ; work with M80. In either case it must be linked with SYSLIB36.REL 
  36. ; and Z3LIB13.REL
  37. ;
  38. ; If you have any problems, fixes or suggestions, please report them to
  39. ; me on either Russ Pencin's board, "Dallas Connection" (415) 964-4356,   
  40. ; Ben Grey's board, "Cedar Mill Z-Node 24" (503) 644-4621, or my board,
  41. ; "Access Programming RAS" (503) 644-0900.
  42. ;
  43. ; Writting this program would not have been possible if it were not 
  44. ; for the help and patience of Ben Grey, sysop of Cedar Mill Z-Node 24 
  45. ; and co-sysop of Access Progrmaming RAS. Thank you Ben.
  46. ;
  47. ; HISTORY - 
  48. ;
  49. ;    Version 1.2    05/16/87    Re-work display routines to
  50. ;                    enhance program speed.    [tlp]
  51. ;
  52. ;    Version 1.1    05/01/87    Fix problem with the update of
  53. ;                    users with terminals no longer
  54. ;                    supported.        [tlp]
  55. ;
  56. ;    Version 1.0    04/02/87    Original release    [tlp]
  57. ;
  58. ;=========================================================================
  59. ;
  60. ;
  61.     yes    equ    1
  62.     no    equ    not yes
  63. ;
  64. ; Version and revision number. The only official releases are those that
  65. ; have been approved by the Access Programming RAS. Any other versions è; or revisions are not official and will not be supported by me. Please
  66. ; send any updates or revisions to me at the above address or by modem   
  67. ; to my system.  
  68. ;
  69.     ver    equ    1    ; version number
  70.     vers    equ    2    ; revision number
  71. ;
  72.     tab    equ    09h    ; tab character
  73.     cr    equ    0dh    ; carriage return
  74.     lf    equ    0ah    ; line feed
  75.     bell    equ    07h    ; bell character
  76.     tbuf    equ    80h    ; default DMA
  77. ;
  78. ; If you do not use a ZCPR3x operating system, set the Z3ENV to 0.
  79. ;
  80.     z3env    equ    0d000h    ; z3 environment descriptor
  81.     dfcb1    equ    05ch    ; default fcb1
  82.     dfcb2    equ    06ch    ; default fcb2
  83. ;
  84. ; The clear screen defined below will use your TCAP's code
  85. ; if you have a Z3ENV defined above. If you do not operate
  86. ; within a Z3 environment, you have been provided with six
  87. ; bytes to define a clear screen and home cursor sequence.
  88. ; The seventh byte is a terminator, DO NOT CHANGE!
  89. ;
  90.      if    z3env ne 0
  91.     cls    equ    z3env+97h ; clear screen code
  92.      else
  93.     cls    db    0,0,0,0,0,0  
  94.         db    0      ; terminator - DO NOT CHANGE
  95.      endif
  96. ;
  97. ; The following equates should be set the same as they are in the PBBS
  98. ; header file. THIS IS IMPORTANT.
  99. ;
  100.     totusr    equ    400    ; maximum users set in PBBSHDR
  101. ;
  102. ; The system drive and user areas reflect the DU where your 
  103. ; USERS.PBS and the 'old' and 'new' Z3TCAPxx.TCP files are
  104. ; located. Usually A14:. 
  105. ;
  106.     sysdrv    equ    0    ; system drive A=0 B=1...  
  107.     sysusr    equ    14    ; system user area
  108.     version    equ    yes     ; show version number 1=yes 0=no
  109.     credits    equ    yes    ; show author name    1=yes 0=no
  110. ;
  111. ; The following declares any external subroutines necessary
  112. ; for assembly. These routines are all defined in SYSLIB36.REL.
  113. ;
  114.     ext    f$open, f$close, f$read, r$write, f$exist, r$read
  115.     ext    setdma, compbc, initfcb, scanner, divhd, instr
  116.     ext    epstr, pfn1, putud, getud, logud, crlf, padc
  117.     ext    z3init, phl4hc, phlfdc, phldc, mulhd, cout             
  118.     ext    fi0$open, fo0$open, fi0$close, fo0$close, f0$get, f0$put
  119. ;
  120.     org    100h
  121. ;
  122. ; Standard Z3 Header for all Z system programs.
  123. ;
  124.      if    z3env ne 0
  125. ; 
  126. ; External ZCPR3 Environment Descriptor
  127. ;
  128.     jp    start 
  129.     db    'Z3ENV'
  130.     db    1
  131. z3eadr:    dw    z3env
  132. start:    ld    hl,(z3eadr)
  133.      else
  134. ;
  135. ; Internal ZCPR3 Environment Descriptor
  136. ;
  137.     MACLIB     Z3BASE        ; get ZCPR3 system equates
  138.     MACLIB    SYSENV
  139. ;
  140. z3eadr:    jp    start 
  141.     SYSENV
  142. start:    ld    hl,z3eadr
  143.      endif
  144. ;
  145. ; Standard initialization for PBBS programs. Save the system stack for
  146. ; re-entry to operating system. Load the drive/user areas defined in
  147. ; the header file as the system drive/user area. This is where we will
  148. ; find the files we will want to look at.
  149. ;
  150.     ld    (system),sp    ; save stack
  151.     ld    sp,system    ; point to stack
  152. ;
  153. ; Environment Definition
  154. ;
  155.     call    z3init        ; initialize z3 environment
  156.      call    putud         ; save current drive/user area
  157.      ld    b,sysdrv    ; defined system drive
  158.      ld    c,sysusr    ; defined system user area
  159.      call    logud         ; log into defined drive/user area
  160. ;
  161. ; Initialize all FCB's
  162. ;
  163.     ld    de,fcb1        ; point to fcb1
  164.     call    initfcb        ; initialize
  165.     ld    de,fcb2        ; point to fcb2
  166.     call    initfcb        ; initialize
  167.     ld    de,fcb3        ; point to fcb3
  168.     call    initfcb        ; initialize
  169.     ld    de,fcb4        ; point to fcb4
  170.     call    initfcb        ; initialize
  171. ;
  172. ; Sign-on message
  173. ;
  174.     ld    hl,cls        ; point to clear screen message
  175.     call    epstr        ; clear screen
  176.     ld    hl,signon    ; point to signon message
  177.       call    epstr        ; print signon message
  178. cmdln:    
  179.     ld    hl,tbuf      ; point to command line     
  180.           ld    a,(hl)        ; put first character of command line in A
  181.     cp    0        ; 0 = no command tail
  182.     jp    z,help0     ; if yes, give syntax error and help
  183.     ld    hl,dfcb1+1    ; point to first filename
  184.     ld    de,fcbn1    ; point to internal fcb1
  185.     ld    bc,8        ; number of bytes to transferè    ldir            ; move to internal FCB1
  186.     ld    hl,dfcb2+1    ; point to second filename
  187.            ld    a,(hl)        ; put first character in A
  188.            cp     ' '          ; 0 means no filename specified
  189.     jp    z,option      ; if so - use internally defined filename
  190.     ld    de,fcbn2    ; point to internal fcb2
  191.     ld    bc,8        ; number of bytes to transfer
  192.     ldir            ; move to internal FCB2
  193. option:    
  194.     ld    hl,fcbn1    ; point to first character in fcb1
  195.     ld    a,(hl)        ; place character in A
  196.     cp    '?'        ; is it a '?'
  197.     jp    z,help         ; yes - give help
  198.     cp    '/'         ; is it z3 system help - '/'
  199.     jp    z,help         ; yes - give help
  200. ;
  201. ; initialize buffers for opening of files
  202. ;
  203.     ld    de,fcb1        ; open new TCAP file   
  204.     call    fopen                      
  205.     ld    de,fcb2        ; open old TCAP file  
  206.     call    fopen                        
  207.     ld    de,fcb3        ; open PBBS user file
  208.     call    uopen                     
  209.     ld    de,fcb4        ; open new PBBS user file
  210.     call    nopen
  211. ;
  212. ; Read TCAP index files into memory - the terminal id string is 16 bytes long
  213. ; and each terminal is listed in the beginning of the TCAP file in an index.
  214. ; The last entry in the index is a space followed by the version number of
  215. ; the TCAP listing.
  216. ; 
  217. ; Read new TCAP into memory
  218. ;
  219.     ld    de,fcb1        ; point to current FCB
  220.     ld    (fcb),de    ; save it
  221.     ld    de,buf1        ; point to current buffer
  222.     ld    (buffer),de    ; save it
  223.     call    tid           ; read TCAP into memory
  224. ;
  225. ; Read old TCAP into memory
  226. ;
  227.     ld    de,fcb2        ; point to current FCB
  228.     ld    (fcb),de    ; save it
  229.     ld    de,buf2        ; point to current buffer
  230.     ld    (buffer),de    ; save it
  231.     call    initrd        ; read TCAP into memory
  232.     call    crlf        ; new line
  233.     call    crlf        ; another new line
  234. next:
  235.     call    user        ; read user record into memory
  236. ;
  237. ; Process user record
  238. ;
  239.     ld    hl,pcmsg    ; point to processing message
  240.     call    epstr        ; print message
  241.     ld    hl,(nlrec)    ; get record number
  242.     ld    de,totusr    ; get maximum number of users
  243.     sbc    hl,de        ; have we reached the end?
  244.     jp    nc,norec    ; skip processing, just write record
  245.     ld    hl,(nlrec)    ; get record number again
  246.     call    phldc        ; print record number
  247.     ld    hl,unamef    ; point to user name
  248.     ld    a,(hl)        ; is there a name here?
  249.     cp    ' '        ; a space means no name
  250.     jp      z,norec        ; get next user record
  251.     cp    0        ; is the record used     
  252.     jp      z,norec        ; no - get next record
  253.     ld    de,name        ; point to internal buffer
  254.     ld    bc,30        ; length of user name field
  255.     ldir            ; transfer name to internal buffer
  256.     ld    a,(tcodef)    ; get terminal code into A 
  257.     ld    (tcode2),a     ; put into internal buffer
  258.     dec    a        ; decrement pointer
  259.     ld    l,a        ; put A in L
  260.     ld    h,0        ; zero H
  261.     ld     de,16        ; number of bytes per entry
  262.     call    mulhd        ; multiply HL by DE
  263.     ld    de,buf2        ; start address of old TCAP file
  264.     add    hl,de        ; add in offsetè    ld    de,term2     ; point to internal buffer
  265.     ld    bc,16        ; length of id string
  266.     ldir            ; transfer to internal buffer
  267.     ld    hl,buf1        ; string to scan 
  268.     ld    de,term2     ; string to scan for
  269.     call    instr        ; scan for termid in new buffer
  270.     jp        nz,sc$err    ; indicate scan error
  271.     ld    (buf),hl    ; save string start address
  272.     ld     de,buf1        ; get start address of new TCAP file
  273.     sbc    hl,de        ; offset into buffer
  274.     ld    de,16        ; number of bytes per entry
  275.     call    divhd        ; calculate new terminal code number 
  276.     ld    a,l        ; put terminal code in A
  277.     ld    (tcode1),a     ; save terminal code
  278.     inc    a        ; bump pointer
  279.     ld    a,(tcode1)    ; get new terminal code
  280.     ld    l,a        ; put in L
  281.     ld    h,0        ; zero H
  282.     ld    de,16        ; number of bytes per entry
  283.     call    mulhd        ; multiply HL by DE
  284.     ld    de,buf1        ; get start address of new TCAP buffer
  285.     add    hl,de        ; add in offset
  286.     ld    de,term1    ; point to internal buffer
  287.     ld    bc,16        ; length of terminal string
  288.     ldir            ; transfer to internal buffer
  289. errtn:
  290.     call    pwrt        ; write record to USER file
  291.     jp    next        ; get next user record
  292. ;
  293. ; Copy blank record to user file so as not to contaminate USER index.
  294. ;
  295. norec:
  296.     call    nowrt        ; write blank record to USER file
  297.     jp    next        ; get next record
  298. ;
  299. ; Read USER record into memory
  300. ;
  301. user:                 
  302.     ld    b,100        ; number of bytes in user record
  303.     ld    c,0        ; zero C
  304.     ld    hl,(nlrec)    ; get record counter
  305.     inc    hl        ; bump counter
  306.     ld    (nlrec),hl    ; save logical record number in buffer
  307.     ld    de,totusr+4    ; number of records to load in buffer
  308.     sbc    hl,de        ; check for end of file
  309.     jp    z,exit        ; if EOF, then exit
  310.     ld    hl,tbuf        
  311. get:
  312.     call    f0$get        ; read block into memory
  313.     call    nz,fop$err    ; file read error routines
  314.     ld    (hl),a        ; put character in buffer
  315.     inc    hl        ; increment pointer
  316.     djnz    get        ; get next character
  317.     ret
  318. ;
  319. ; Subroutine to write record to USER file
  320. ;
  321. pwrt:
  322.      ld    a,(tcode1)    ; get new terminal code
  323.     inc    a        ; increment value of terminal code
  324.      ld    (tcodef),a    ; put in USER record
  325. nowrt:
  326.     ld    b,100        ; number of bytes in user record
  327.     ld    c,0        ; zero C
  328.     ld    hl,tbuf        ; point to buffer
  329. put:
  330.     ld    a,(hl)        ; put character from buffer into A
  331.     call    f0$put        ; write character to file
  332.     call    nz,fop$err    ; file write error routines
  333.     inc    hl        ; increment pointer
  334.     djnz    put        ; get next character
  335.     ret
  336. ;
  337. ; Subroutine to read TCAP into memory
  338. ;
  339. tid:
  340.     ld    hl,tcapid    ; point to status message
  341.     call    epstr        ; print message
  342. initrd:
  343.     ld    hl,(buffer)      ; point to internal buffer
  344.     ld    (buf),hl    ; save internal buffer address
  345. rtcap: 
  346.     ld    hl,tbuf        ; point to default DMA
  347.     call    setdma        ; set DMA address
  348.     ld    de,(fcb)    ; get FCB address
  349.      call    f$read        ; read record into TBUF
  350.      jp    nz,rf$err    ; read error routines
  351.     ld    hl,tbuf        ; point to tbuf
  352.     ld    de,(buf)    ; point to buf
  353.     ld      bc,128        ; number of bytes to transfer
  354.     ldir            ; transfer to internal buffer
  355.     ld    (buf),de    ; save new buffer address
  356.     ld    hl,tbuf      ; point to default buffer
  357.     ld    de,term        ; point to terminator descriptor
  358.     ld    b,128        ; number of bytes in buffer
  359.     ld    c,1        ; number of bytes to look for
  360.     call    scanner        ; search for DE in HL
  361.     or    a        ; set flags
  362.     jr    nz,rtcap     ; get next record
  363.     ld    hl,(buf)    ; point to current buffer
  364.     ld    bc,16        ; size of terminal id string
  365. rep:     
  366.     sbc    hl,bc        ; subtract 16 from buffer pointer
  367.     ld    a,(hl)        ; put first character of buffer in A
  368.     cp    ' '        ; is it a space?
  369.     inc    hl        ; advance buffer pointer
  370.     jr    nz,rep         ; if no, repeat until find
  371.     dec    hl        ; retard pointer againè    ld    (buf),hl    ; save temporary buffer
  372.     ld    de,(buffer)    ; get start address of buffer
  373.     sbc    hl,de        ; subtract end address to get length of buffer
  374.     ld    de,16        ; set divisor
  375.     call    divhd        ; divide HL by DE
  376.     ld    (cnt),hl    ; store in buffer
  377.     ld    hl,(buf)    ; restore temporary buffer
  378.     ld    de,versn    ; point to destination for version number
  379.     ld    bc,4        ; number of bytes to transfer
  380.     ldir            ; transfer version number to internal buffer
  381.     ld    hl,tcver    ; point to VERSION
  382.     call    epstr        ; print message
  383.     ld    hl,versn+1    ; get version number of TCAP   
  384.     call    epstr        ; print version number
  385.     ld    hl,(cnt)    ; get number of terminals in TCAP
  386.     call    phldc        ; display number of terminals
  387.     ld    hl,entry    ; point to TERMINALS message
  388.     call    epstr        ; print message
  389.     ret
  390. ;       
  391. ; open files
  392. ;
  393. fopen:
  394.     call    f$exist        ; does file exist?
  395.     jp      z,fnf$err    ; file not found error routine
  396.     call    f$open        ; open file
  397.     or    a        ; set flags
  398.     call    nz,op$err    ; open error routines
  399.     ret
  400. uopen:    
  401.     call    f$exist        ; does file exist?
  402.     jp    z,fnf$err    ; file not found error routines
  403.     call    fi0$open    ; open file
  404.     or    a        ; set flags
  405.     call    nz,fop$err    ; open error routines
  406.     ret
  407. nopen:
  408.     call    fo0$open    ; create and open file
  409.     or     a        ; set flags
  410.     call    nz,fop$err    ; open error routines
  411.     ret
  412. exit:
  413.     call    crlf        ; new line
  414.     ld    hl,dpmsg    ; point to terminals dropped message
  415.     call    epstr        ; print message
  416.     ld    a,(drop)    ; get number of users without support
  417.     call    padc         ; print number
  418.       call    crlf        ; new line
  419.     ld    hl,comp         ; point to operation completed message
  420.     call    epstr        ; print message
  421.     ld    de,fcb1        ; point to old TCAP file
  422.     call    f$close        ; close file
  423.     call    nz,cl$err    ; close file error routines
  424.     ld    de,fcb2        ; point to new TCAP file
  425.     call    f$close        ; close file
  426.     call    nz,cl$err    ; close file error routines
  427.     ld    de,fcb3        ; point to PBBS user file
  428.     call    fi0$close    ; close file
  429.     call    nz,fop$err    ; close error routines
  430.     ld    de,fcb4        ; point to new USER file
  431.     call    fo0$close    ; close file
  432.     call    nz,fop$err    ; close error routines
  433. ext2:
  434.     call    getud        ; restore original drive/user area
  435.     ld    sp,(system)    ; restore old stack pointer
  436.     ret
  437. ;
  438. ; Error routines
  439. ;
  440. fop$err:
  441.     push    hl        ; save HL on stack
  442.     push    de        ; save DE on stack
  443.     ld    hl,err        ; point to ERROR
  444.     call    epstr        ; print ERROR
  445.     cp    1
  446.     jp    nz,ferr2
  447.     ld    hl,foerr1
  448.     jp    prerr
  449. ferr2:    cp    2
  450.     jp    nz,ferr3
  451.     ld    hl,foerr2
  452.     jp    prerr
  453. ferr3:    cp    3
  454.     jp    nz,ferr4
  455.     ld    hl,foerr3
  456.     jp    prerr
  457. ferr4:    cp    4
  458.     jp    nz,ferr5
  459.     ld    hl,foerr4
  460.     jp     prerr
  461. ferr5:    cp    5
  462.     jp    nz,ferr6
  463.     ld    hl,foerr5
  464.     jp    prerr
  465. ferr6:    cp    6
  466.     jp    nz,ferr7
  467.     ld    hl,foerr6
  468.     jp    prerr
  469. ferr7:    cp    7
  470.     jp    nz,rerr9
  471.     ld    hl,foerr7
  472.     jp    prerr
  473. rf$err:    è    push    hl        ; save HL on stack
  474.     push    de        ; save DE on stack
  475.     ld    hl,err        ; point to ERROR
  476.     call    epstr        ; print ERROR
  477.     cp    1        ; was it read error 1
  478.     jp    nz,rerr2    ; if yes, show error
  479.     ld    hl,rderr1
  480.     jr    prerr    
  481. rerr2:    cp    2        ; was it read error 3
  482.     jp    nz,rerr9    ; if yes, show error
  483.     ld    hl,rderr2
  484.     jr    prerr
  485. rerr9:    ld    hl,rderr9
  486. prerr:    call    epstr        ; print error message
  487.     call    crlf        ; print cr lf
  488.     pop    de        ; restore stack
  489.     pop    hl        ; restore stack
  490.     jp     exit
  491. eof$err:
  492.     ld    hl,err        ; point to ERROR 
  493.     call    epstr        ; print ERROR
  494.     ld    hl,eoferr    ; point to error message
  495.     call    epstr        ; print error message
  496.     call    crlf        ; print CRLF
  497.     jp    exit
  498. op$err:
  499.     ld    hl,err        ; point to ERROR
  500.     call    epstr        ; print ERROR
  501.     ld    hl,operr    ; point to error message
  502.     call    epstr        ; print error message
  503.     inc    de        ; point to FCB+1
  504.     call    pfn1        ; print filename
  505.     call    crlf        ; print CRLF
  506.     dec    de        ; restore DE
  507.     ret    
  508. cl$err:
  509.     ld    a,(fnf)        ; get file not found flag
  510.     cp    0        ; was the file found?
  511.     ret    z         ; if not - skip error messages
  512.     ld    hl,err        ; point to ERROR
  513.     call    epstr        ; print ERROR
  514.     ld    hl,clerr    ; point to error message
  515.     call    epstr        ; print error message
  516.     inc    de        ; point to FCB+1
  517.     call    pfn1        ; print filename
  518.     call    crlf        ; print CRLF
  519.     dec     de        ; restore DE
  520.     ret    
  521. fr$err:    
  522.     ld    hl,err        ; point to ERROR
  523.     call    epstr        ; print ERROR
  524.     ld    hl,frerr    ; point to error message
  525.     call    epstr        ; print error message
  526.     call    crlf        ; print CRLF
  527.     jp    exitèfnf$err:
  528.     ld    hl,0        ; flag for file not found
  529.     ld    (fnf),hl    ; set flag
  530.     ld    hl,err        ; point to ERROR
  531.     call    epstr        ; print ERROR
  532.     ld    hl,fnferr    ; point to error message
  533.     call    epstr        ; print error message
  534.     inc    de        ; point FCB+1
  535.     call    pfn1        ; print filename
  536.     call    crlf        ; print CRLF
  537.     dec     de        ; restore DE
  538.     jp         ext2    
  539. sc$err:
  540.     ld    a,(drop)    ; get number of terminals dropped
  541.     inc    a         ; increment number
  542.     ld    (drop),a    ; save in buffer
  543.     ld    a,0           ; put terminal 0 in A
  544.     ld    (tcode1),a    ; save in internal buffer
  545.     jp     errtn        ; get next name
  546. help0:
  547.     ld    hl,err        ; point to ERROR
  548.     call    epstr        ; print ERROR
  549.     ld    hl,hperr    ; point to error message
  550.     call    epstr        ; print error message
  551.     call    crlf        ; print CRLF
  552.     call    crlf        ; print CRLF 
  553.     jp     ext2        ; exit
  554. help:
  555.     ld    hl,hlpmsg
  556.     call    epstr        ; print follwoing message
  557.      jp    ext2        ; exit
  558. hlpmsg:
  559.     db    'PTCAP',ver+'0',vers+'0',' - Help File',cr,lf,lf
  560.     db    'Syntax:  PTCAP newfile [oldfile] [? or /]',cr,lf,lf
  561.     db    '         Where newfile = name of new TCAP file.',cr,lf
  562.     db    '               oldfile = name of old TCAP file. ',cr,lf,lf
  563.     db    '               If no filename is specified for the',cr,lf
  564.     db    '               OLD TCAP file, Z3TCAP is used.  The',cr,lf
  565.     db    '               default filetype for the TCAP files',cr,lf
  566.     db    '               is .TCP and is not specified on the',cr,lf
  567.     db    '               command line.',cr,lf,lf
  568.     db    '         PTCAP ? or / Prints this help file.',cr,lf
  569.     db    0
  570. signon:    
  571.     db    'PTCAP - PBBS TCAP Entry Modifier',cr,lf
  572.      if    version
  573.     db    'Version ',ver+'0','.',vers+'0'
  574.     db    ' - 05/16/87',cr,lf
  575.      endif
  576.      if    credits
  577.     db    'Written by Terry Pinto ',cr,lf
  578.       endif
  579.     db    cr,lf,0ètcapid:    db    'Loading Z3TCAP  ',0          
  580. tcver:  db    'Version ',0
  581. entry:    db    ' Terminals',cr,lf,tab,tab,0  
  582. pcmsg:    db    cr,'Processing Record #',0
  583. dpmsg:    db    'Terminals no longer supported: ',0      
  584. comp:    db    cr,lf,'Installation Complete... ',0
  585. ;
  586. ; Error messages
  587. ;
  588. foerr1:    db    'GET or PUT Attempt On Unopened File',0
  589. foerr2:    db    'Disk Full',0
  590. foerr3:    db    'Input File Not Found',0
  591. foerr4:    db    'Attempt to Read Past EOF',0
  592. foerr5:    db    'Directory Full',0
  593. foerr6:    db    'Error In Closing File',0
  594. foerr7:    db    'Attempt to Open File Already Opened',0
  595. rderr1:    db    'Read Past End Of File',0
  596. rderr2:    db    'Reading Unwritten Data',0
  597. rderr9:    db    'Unknown Error Occurred - ABORT!',0
  598. eoferr:    db    'Read Past End Of File',0
  599. frerr:    db    'Reading Unwritten Data',0
  600. operr:    db    'Unable to Open File -> ',0
  601. clerr:    db    'Unable to Close File -> ',0
  602. err:    db    cr,lf,bell,'ERROR - ',0
  603. fnferr:    db    'File Not Found -> ',0
  604. hperr:    db    'New TCAP File Not Specified',0
  605. ;
  606. ; Buffer space
  607. ;
  608. ; File control block for NEW TCAP file
  609. ;
  610. fcb1:    db    0        ; disk drive 0=default drive
  611. fcbn1:    db    '        '    ; filename filled by parse from input
  612. fcbt1:    db    'TCP'        ; default filetype
  613.     ds    24        ; balance of FCB filled by INITFCB
  614. ;
  615. ; File control block for OLD TCAP file. If you current TCAP
  616. ; has a different name, you should specify it on the command
  617. ; line. The specified name will be parsed into this FCB.
  618. ;
  619. fcb2:    db    0        ; disk drive 0=default drive
  620. fcbn2:    db    'Z3TCAP  '    ; default filename if none specified in input
  621. fcbt2:    db    'TCP'        ; default filetype
  622.     ds    24        ; balance of FCB filled by INITFCB
  623. ;
  624. ; File control block for PBBS User file
  625. ;
  626. fcb3:    db    0        ; disk drive 0=default drive
  627. fcbn3:    db    'USERS   '    ; filename
  628. fcbt3:    db    'PBS'        ; filetype
  629.     ds    24
  630. ;
  631. ; File control block for new PBBS User file
  632. ;
  633. fcb4:    db    0        ; disk drive 0=default drive
  634. fcbn4:    db    'USERS   '    ; filename
  635. fcbt4:    db    'NEW'        ; filetype
  636.     ds    24
  637. ;
  638. term1:    db    '                '
  639.     db    0
  640. term2:     db    '                '
  641.     db    0
  642. name:    db    '                              '
  643.     db    0èversn:    db    '    ',0           ; TCAP version number (terminated with 0)
  644. drop:    ds    1        ; number of terminals not supported
  645. rec:    db    0        ; record storage
  646. buf:    ds    2        ; buffer address
  647. fcb:    ds    2         ; selected fcb
  648. buffer:    ds    2        ; starting address for selected TCAP
  649. nlrec:    db    0        ; new logical record
  650. term:    db     0        ; terminator descriptor
  651. tcode1:    db    0             ; new terminal code
  652. tcode2:    db    0             ; old terminal code
  653. cnt:    ds    2        ; total entries in TCAP file
  654. fnf:    db    0        ; file not found flag  0=not found
  655. ;
  656. ; User file buffer
  657. ;
  658. usrec    equ    tbuf
  659. availf    equ        usrec        ; record availability  00=free record
  660. unamef    equ    availf+1    ; user name field
  661. citstf    equ    unamef+30    ; city and state
  662. pswrdf    equ    citstf+20    ; password
  663. phonef    equ    pswrdf+10    ; telephone
  664. tmsonf    equ    phonef+12    ; number of times on system
  665. lstonf    equ    tmsonf+2    ; date last on system
  666. acessf    equ    lstonf+3    ; access level
  667. mailf    equ    acessf+1    ; mail waiting flag
  668. intarf    equ    mailf+1         ; area to bump user to after signon
  669. nnullf    equ    intarf+1    ; number of nulls needed
  670. bdcdef    equ    nnullf+1    ; baudrate code (last signon)
  671. upldsf    equ    bdcdef+1    ; upload count
  672. dnldsf    equ    upldsf+2    ; download count
  673. usrmpf    equ    dnldsf+2    ; userarea map
  674. drvmpf    equ     usrmpf+2    ; drive map
  675. tcodef    equ    drvmpf+2    ; terminal identifier code  
  676. totmef    equ    tcodef+1    ; total time on-line on day basis
  677. himsgf    equ    totmef+1    ; highest message read folder-1
  678. ufaccf    equ    himsgf+2    ; mail folder access byte
  679. lengf    equ    ufaccf+2    ; terminal line length
  680. ;
  681. buf1    equ    ($/128)*128+128   
  682.     ds    2048
  683. buf2    equ    buf1+2048
  684.     ds    2048
  685. ;
  686.     ds    64
  687. system    dw    0
  688.     end
  689.