home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / ZCPR33 / A-R / LONGSUB.ZZ0 / LONGSUB.Z80
Text File  |  2000-06-30  |  33KB  |  1,259 lines
  1. ; LONGSUB: SUBmit utility for ZCPR33 for long submit files.
  2. ;    by Thomas E. Croley II, 30 June 1987
  3. ;        * Requires modification of your ZCPR33 CCP !!!! (see below)
  4. ;        * Corrects ZCPR33 error in submit processing for $$$.SUB files
  5. ;            longer than can be accessed with a single directory
  6. ;            entry.
  7. ;        * Derived from SUB34.
  8. ;
  9. ; Submit file processing is (and has always been?) limited to short *.SUB file
  10. ; lengths (fewer than 128 lines for disk allocation blocks of 2k, 256 lines
  11. ; for disk allocation blocks of 4k, ...).  This is because ZCPR33 finds the
  12. ; last record in the $$$.SUB file for processing and attempts to close the file
  13. ; one record shorter to remove that record (command) from further processing;
  14. ; to do this, ZCPR33 decrements the record count in the FCB for the file before
  15. ; the close.  This works if there is only one directory entry in the directory
  16. ; for the $$$.SUB file but it does not work if there are more.  Subsequently,
  17. ; for longer $$$.SUB files, ZCPR33 neither finds the end of file correctly, nor
  18. ; is it able to reduce the file length past the point allocated to an earlier
  19. ; directory entry.  The proper way around this is to implement direct access
  20. ; ("random access" in old CP/M terminology) file manipulations to find the end
  21. ; of the file and to keep track of the last record processed.  The SUB utility
  22. ; must be modified also to use this method so that the last record (first
  23. ; command) to be accessed by the CCP is pointed to in the file (the last record
  24. ; of the file is used for this purpose here).  Also, file append (for nesting
  25. ; of SUB commands), must properly maintain this pointer.
  26. ;
  27. ; If you use this SUB command, you must modify your ZCPR33 CCP by adding the
  28. ; following code as instructed below.  The PENALTY is that it will slow submit
  29. ; file processing (hardly noticeable on a RAM disk but may be significant on a
  30. ; floppy) since additional disk reads and writes are required to find and
  31. ; maintain the next-command pointer.  These reads and writes are not to
  32. ; sequential records on the disk since the pointer is maintained in the last
  33. ; record of the file while commands are taken successively toward the
  34. ; beginning.  The ADVANTAGE is that it will allow arbitrary length submit files
  35. ; for processing.
  36. ;
  37. ; If you do not use this SUB command and do not modify your ZCPR33 CCP as
  38. ; follows, then BEWARE that submit files with line lengths exceeding the above
  39. ; limits will not be possible and there is no error message nor error checking
  40. ; for this condition within the CCP.
  41. ;
  42. ; MODIFICATIONS TO ZCPR33.Z80 (may require reconfiguration in Z33HDR.LIB to
  43. ;            make room for the additional code on your machine)
  44. ;
  45. ; Find the label "subfcr:" in ZCPR33.Z80 and add the code denoted by ";TEC" as
  46. ; follows:
  47. ;
  48. ;    subfcr:
  49. ;        defs    1        ; Current record number
  50. ;    subfr:                ;TEC
  51. ;        defs    3        ;TEC Random record no. (16 bits) + ovrflw byte
  52. ;
  53. ; Find the label "readbuf:" in ZCPR33.Z80 and modify or add the code as denoted
  54. ; by ";TEC" as follows:
  55. ;
  56. ;    readbuf:
  57. ;
  58. ;        ld    a,(zexrunfl)    ; Get ZEX-running flag
  59. ;        or    a
  60. ;        jp    nz,userinput    ; If ZEX running, go directly to user input
  61. ;
  62. ;         if    subon        ; If submit facility is enabled, check for it
  63. ;
  64. ;        ld    a,(subflag)    ; Test for submit file running
  65. ;        or    a
  66. ;        jr    z,shellinput    ; If not, go on to possible shell input
  67. ;
  68. ;        xor    a        ; Log into user 0
  69. ;        call    setuser
  70. ;        call    defltdma    ; Initialize DMA pointer
  71. ;        ld    de,subfcb    ; Point to submit file FCB
  72. ;        call    open        ; Try to open file
  73. ;        jr    z,readbuf1    ; Branch if open failed
  74. ;
  75. ;    ;TEC    ld    hl,subfrc    ; Point to record count in submit FCB
  76. ;    ;TEC    ld    a,(hl)        ; Get the number of records in file
  77. ;    ;TEC    dec    a        ; Reduce to number of last record
  78. ;    ;TEC    ld    (subfcr),a    ; ..and put into current record field
  79. ;        ld    c,23h        ;TEC "Compute file size" bdos call no.
  80. ;        call    bdossave    ;TEC DE still => subfcb; get file size in subfr
  81. ;        ld    hl,(subfr)    ;TEC Get file size
  82. ;        dec    hl        ;TEC Decrement to get last record no.
  83. ;        ld    (subfr),hl    ;TEC Replace in random record field
  84. ;        ld    c,21h        ;TEC "Read random" bdos call no.
  85. ;        call    bdossave    ;TEC DE still => subfcb; randm read last record
  86. ;        ld    hl,(tbuff)    ;TEC Get current "last record" from last record
  87. ;        dec    hl        ;TEC Point to next earlier record to read
  88. ;        ld    (tbuff),hl    ;TEC Save pointer in actual last record
  89. ;        inc    c        ;TEC ... and write back to file (c=22h)
  90. ;        call    bdossave    ;TEC DE still => subfcb; randm write last recrd
  91. ;        ld    (subfr),hl    ;TEC Now prepare to read new "last record"
  92. ;        dec    c        ;TEC (c=21h)
  93. ;        call    bdossave    ;TEC Random read record; DE still => subfcb
  94. ;    ;TEC    call    read        ; Attempt to read submit file
  95. ;    ;TEC    jr    nz,readbuf1    ; Branch if read failed
  96. ;
  97. ;    ;TEC    dec    (hl)        ; Reduce file record cound
  98. ;    ;TEC    dec    hl        ; Point to S2 byte of FCB (yes, this is req'd!)
  99. ;    ;TEC    ld    (hl),a        ; Stuff a zero in there (A=0 from call to READ)
  100. ;        ld    (subfrc-1),a    ;TEC Zero FCB S2 byte (A=0 from previous read)
  101. ;        call    close        ; Close the submit file one record smaller
  102. ;        jr    z,readbuf1    ; Branch if close failed
  103. ;
  104. ; END of ZCPR33.Z80 changes...
  105. ;
  106. ;
  107. ; The following program is SUB34.Z80 with ALL modifications denoted by ";TEC".
  108. ;
  109. ; PROGRAM NAME:  SUB
  110. ; AUTHOR:  RICHARD CONN (From SuperSUB Ver 1.1 by Ron Fowler)
  111. ; VERSION:  3.4  (Royce Shofner)
  112. ; DATE:  8 June 1987
  113. ;
  114. ; PREVIOUS VERSION:   3.3 (4 MAY 1987) HOWARD GOLDSTEIN
  115. ; PREVIOUS VERSION:  3.2 (27 APRIL 1987) JAY SAGE
  116. ; PREVIOUS VERSIONS:  3.1 (19 JAN 1985) JOE WRIGHT
  117. ; PREVIOUS VERSIONS:  3.0 (18 MAY 84) RELEASE VERSION
  118. ; PREVIOUS VERSIONS:  2.3 (6 Jan 83) - Called SUB2.ASM
  119. ; PREVIOUS VERSIONS:  2.2 (7 DEC 82), 2.1 (14 NOV 82), 2.0 (11 OCT 82)
  120. ; PREVIOUS VERSIONS:  1.4 (10 OCT 81), 1.3 (7 OCT 81)
  121. ; PREVIOUS VERSIONS:  1.2 (5 OCT 81), 1.1 (3 OCT 81), 1.0 (1 OCT 81)
  122. ; NOTE:  FOR USE WITH ZCPR3
  123. ;
  124. vers    equ    34        ; Modified for ZCPR33 compatibility
  125. ;
  126. z3env    defl    0f900h
  127. ;
  128. ;    SUB is derived from Ron's SuperSUB program; it provides a different
  129. ; format for the command line, a command-search hierarchy like ZCPR3, a
  130. ; resetting of the DMA address, several additional functions, and there are
  131. ; several other additions/changes.  Additionally, ZCPR3-specific enhancements,
  132. ; such as appending the rest of the multiple command line to the command file
  133. ; and allowing multiple commands on a single line, are permitted.
  134. ;
  135. ;    SuperSUB, VERSION 1.1 (09/13/81)        by Ron Fowler
  136. ;    2/18/81 (first written)             WESTLAND, MICH.
  137. ;
  138. ;
  139. ; Version 3.2    Modified to write $$$.SUB file to user 0 instead of current
  140. ; user.
  141.  
  142. ; Version 3.3        Deletes $$$.SUB file from user 0.  ALLOWS
  143. ; use of "^^" to represent "^".  Permits only 126 characters per line 
  144. ; so that there will always be a trailling null.  No longer CP/M
  145. ; compatible.  Requires ZCPR3 with multiple command line at least 127
  146. ; characters long.  Recognizes explicit directory spec for input file
  147. ; and does not search along path if so.
  148.  
  149. ; Version 3.4    Modified to take advantage of ZCPR33'S external running
  150. ; submit flag. SUB34 will set the flag after writing the submit file. If
  151. ; ZCPR33 is resident, SUB will just return to system; else, it will do
  152. ; the traditional warm boot.
  153.  
  154. ; 
  155. ; This program is intended as a replacement for the
  156. ; SUBMIT program provided with CP/M.  It provides sev-
  157. ; eral new facilities:
  158. ;    1) Nestable SUBMIT runs
  159. ;    2) Interactive entry of SUBMIT job (no need
  160. ;       to use an editor for simple SUBMIT runs)
  161. ;    3) Command line entry of small SUBMIT jobs
  162. ;    4) Ability to enter blank lines in an edited
  163. ;       SUBMIT file
  164. ;    5) User customization of number of parameters
  165. ;       and drive to send $$$.SUB to
  166. ;
  167.  
  168. ;
  169. ; DEFINE BOOLEANS
  170. ;
  171. false    equ    0
  172. true    equ    not false
  173.  
  174. ;
  175. ;        --  User customizable options --
  176. ;
  177.  
  178. force$sub equ    false        ; True if submitted file must be of type .sub
  179. time$const equ    0c000h        ; Delay for ringing bell
  180. npar    equ    10        ; Number of allowable parameters
  181. cpbase    equ    0        ; Set to 4200h for heath cp/m
  182. opt    equ    '/'        ; Option delimiter char
  183. pdelim    equ    '$'        ; Parameter delimiter
  184.  
  185. ;
  186. ; SYSLIB AND Z3LIB ROUTINES
  187. ;
  188.     ext    z3init,pfind,getcl1,getmsg
  189.     ext    logud
  190.     ext    initfcb
  191.     ext    pstr,print,qprint,cout,crlf,caps,phldc
  192.     ext    codend
  193.  
  194. ;
  195. ; Z33LIB ROUTINES
  196. ;
  197.     ext    getsrun,subon
  198.  
  199. ;
  200. ; CP/M DEFINITIONS
  201. ;
  202. fgchar    equ    1        ; Get char function
  203. diriof    equ    6        ; Direct console i/o
  204. rdbuf    equ    10        ; Read console buffer
  205. login    equ    14        ; Log in disk
  206. openf    equ    15        ; Open file function
  207. closef    equ    16        ; Close file function
  208. deletf    equ    19        ; Delete file function
  209. readf    equ    20        ; Read record function
  210. writef    equ    21        ; Write record function
  211. makef    equ    22        ; Make (create) file function
  212. getdsk    equ    25        ; Return current disk
  213. setdma    equ    26        ; Set dma address
  214. ucode    equ    32        ; Get/set user code
  215. ;
  216. udflag    equ    cpbase+4
  217. bdos    equ    cpbase+5
  218. ;
  219. curind    equ    '$'        ; Current user/disk indicator
  220. fcb    equ    5ch        ; Default file control block
  221. fcbex    equ    12        ; Fcb offset to extent field
  222. fcbrc    equ    15        ; Fcb offset to record count
  223. fcbnr    equ    32        ; Fcb offset to next record
  224. fn    equ    1        ; Fcb offset to file name
  225. ft    equ    9        ; Fcb offset to file type
  226. tbuf    equ    cpbase+80h    ; Default buffer
  227. tpa    equ    cpbase+100h    ; Transient program area
  228. ;
  229. putcnt    equ    tbuf        ; Counter for output chars
  230. ;
  231. ; DEFINE SOME TEXT CHARACTERS
  232. ;
  233. ctrlc    equ    'C'-'@'
  234. ctrlz    equ    'Z'-'@'
  235. bel    equ    7        ; Ring bell
  236. cr    equ    13        ; Carriage return
  237. lf    equ    10        ; Line feed
  238. tab    equ    9
  239.  
  240. ;
  241. ; Environment Definition
  242. ;
  243.      if    z3env ne 0
  244. ;
  245. ; External ZCPR3 Environment Descriptor
  246. ;
  247.     jp    start
  248.     db    'Z3ENV'        ; This is a zcpr3 utility
  249.     db    1        ; External environment descriptor
  250. z3eadr:
  251.     dw    z3env
  252. start:
  253.     ld    hl,(z3eadr)    ; Pt to zcpr3 environment
  254. ;
  255.      else
  256. ;
  257. ; Internal ZCPR3 Environment Descriptor
  258. ;
  259.     maclib    z3base.lib
  260.     maclib    sysenv.lib
  261. z3eadr:
  262.     jp    start
  263.     sysenv
  264. start:
  265.     ld    hl,z3eadr    ; Pt to zcpr3 environment
  266.      endif
  267.  
  268. ;
  269. ; Start of Program -- Initialize ZCPR3 Environment
  270. ;
  271.     call    z3init        ; Initialize the zcpr3 env and the vlib env
  272.     ld    hl,0        ; Save stack in case
  273.     add    hl,sp        ; Only help requested
  274.     ld    (spsave),hl    ; (not otherwise used)
  275.     call    qprint
  276.     db    'SUB  Version ',vers/10+'0','.',(vers mod 10)+'0',0
  277.  
  278.     call    codend        ; Set up external buffers
  279.     ld    (clbuf),hl    ; Set ptr
  280.     ld    (hl),128    ; Allow 128 chars
  281.     ld    de,100h        ; Free space
  282.     add    hl,de        ; Pt to free area
  283.     ld    (fremem),hl    ; Set ptr to free memory area
  284.     ld    sp,hl        ; Set stack ptr
  285.  
  286.     ld    a,(fcb+1)    ; Anything on cmd line?
  287.     cp    ' '
  288.     jp    z,help        ; No, go print help
  289.     call    initvar        ; Initialize the variable area
  290.     call    getpar        ; Get command line parameters and extract option
  291.     call    abort        ; Perform abort if flag set
  292.     call    setup        ; Set up read of submit file
  293.     call    rdfile        ; Read the submit file
  294.     call    wrset        ; Set up write of "$$$.SUB"
  295.     call    wrsub        ; Write "$$$.SUB"
  296.  
  297.     call    getsrun        ; Is a submit file already active ?
  298.     jr    nz,subxit    ; If so, just return to zcpr33
  299.  
  300.     call    getmsg        ; else, set the submit running flag
  301.     ld    de,2dh
  302.     add    hl,de
  303.     ld    (hl),0ffh
  304. subxit:
  305.     call    subon        ; zcpr33 & submit enabled ?
  306.     jp    nz,gozcpr    ; Return to zcpr33 if posible
  307.     jp    cpbase        ; else, try a warm boot
  308. ;
  309. ;    SETUP SETS UP THE FILE CONTROL BLOCK
  310. ;    FOR READING IN THE .SUB TEXT FILE
  311. ;
  312. setup:
  313.     ld    hl,fcb+ft    ; Look at first char of
  314.     ld    a,(hl)        ; File type.  if it is
  315.     cp    ' '        ; Blank, then go move
  316.     jp    z,putsub    ; "sub" INTO FT FIELD
  317.  
  318.      if    force$sub    ; File type must be of .sub
  319.     ld    de,subtyp    ; File type must be .sub
  320.     ld    b,3        ; 3 bytes
  321.     call    compar
  322.     jp    nz,notfnd    ; File not found if no type match
  323.      endif
  324.  
  325.     ret            ; If not blank, then accept any file type
  326. ;
  327. ;    MOVE "SUB" INTO THE FILE TYPE
  328. ;
  329. putsub:
  330.     ex    de,hl        ; By convention, move from
  331.     ld    hl,subtyp    ; @hl to @de
  332.     ld    b,3
  333.     call    move
  334.     ret
  335. ;
  336. ; MOVE # BYTES IN B REGISTER FROM @HL TO @DE
  337. ;
  338. move:
  339.     ld    a,(hl)        ; Pick up
  340.     ld    (de),a        ; Put down
  341.     inc    hl        ; I'm sure
  342.     inc    de        ; You've seen this
  343.     dec    b        ; Before...
  344.     jp    nz,move        ; 100 times at least
  345.     ret            ; I know i have
  346.  
  347. ;
  348. ; GETPAR MOVES THE SUBSTITUTION PARAMETERS SPECIFIED
  349. ; IN THE COMMAND LINE INTO MEMORY, AND STORES THEIR
  350. ; ADDRESSES IN THE PARAMETER TABLE.  THIS ALLOWS
  351. ; SUBSTITUTION OF $1, $2, ETC., IN THE SUBMIT COMMANDS
  352. ; WITH THEIR ACTUAL VALUES SPECIFED IN THE COMMAND
  353. ; LINE.
  354. ;
  355. getpar:
  356.     xor    a        ; A=0
  357.     ld    (aflag),a    ; Turn off abort command
  358.     ld    hl,tbuf+1    ; Where we find the command tail
  359.     call    scanto        ; Skip submit file name
  360.     ld    (option),a    ; First char of cmd line is option
  361.     ret    c        ; Line ended?
  362.     cp    opt        ; No, check option
  363.     jp    nz,glp0        ; Not keyboard inp, read file
  364.     inc    hl        ; Point past '/'
  365.     ld    a,(hl)        ; Get option char
  366.     cp    'A'        ; Abort command
  367.     jp    z,gparabt
  368.     cp    'I'        ; Interactive mode
  369.     ret    z        ; Return if so
  370.     jp    help        ; Help otherwise
  371. gparabt:
  372.     ld    a,0ffh        ; Turn on abort flag
  373.     ld    (aflag),a
  374.     inc    hl        ; Get possible bell option
  375.     ld    a,(hl)
  376.     cp    'B'        ; Bell option
  377.     ret    nz
  378.     ld    a,0ffh        ; Set bell flag
  379.     ld    (bell$flag),a
  380.     ret
  381. glp0:
  382.     ld    a,(hl)        ; Input is from a .sub file..this
  383.     inc    hl        ; Code skips over the name of
  384.     or    a        ; The sub file to get to the
  385.     ret    z        ; Command line parameters
  386.     cp    ' '
  387.     jp    z,glp
  388.     cp    tab
  389.     jp    nz,glp0
  390. glp:
  391.     call    scanto        ; Pass up the blanks
  392.     ret    c        ; Cy returned if end of cmd line
  393.     call    putpar        ; Now put the parameter into mem
  394.     ret    c        ; Cy returned if end of cmd line
  395.     jp    glp        ; Get them all
  396. ;
  397. ; SCANTO SCANS PAST BLANKS TO THE FIRST NON-BLANK. IF
  398. ; END OF COMMAND LINE FOUND, RETURNS CARRY SET.
  399. ;
  400. scanto:
  401.     ld    a,(hl)
  402.     inc    hl
  403.     or    a        ; Set flags on zero
  404.     scf            ; In case zero found (end of cmd lin)
  405.     ret    z
  406.     cp    ' '
  407.     jp    z,scanto    ; Scan past blanks
  408.     cp    tab        ; Do tabs too, just for
  409.     jp    z,scanto    ; Good measure
  410.     dec    hl        ; Found char, point back to it
  411.     or    a        ; Insure carry clear
  412.     ret
  413. ;
  414. ; PUTPAR PUTS THE PARAMETER POINTED TO BY HL INTO
  415. ; MEMORY POINTED TO BY "TXTPTR".  ALSO STORES THE
  416. ; ADDRESS OF THE PARAMETER INTO THE PARAMETER TABLE
  417. ; FOR EASY ACCESS LATER, WHEN WE WRITE $$$.SUB
  418. ;
  419. putpar:
  420.     push    hl        ; Save pointer to parm
  421.     ld    hl,(txtptr)    ; Next free memory
  422.     ex    de,hl        ; Into de
  423.     ld    hl,(tblptr)    ; Next free area of table
  424.     ld    a,(hl)        ; Non-zero in table
  425.     or    a        ; Indicates table
  426.     jp    nz,parovf    ; Table overflow (too many parms)
  427.     ld    (hl),e        ; Store the parm adrs
  428.     inc    hl
  429.     ld    (hl),d
  430.     inc    hl
  431.     ld    (tblptr),hl    ; Save table pntr for next time
  432.     pop    hl        ; Get back parm pointer
  433.     push    de        ; Save free mem pointer because
  434.                 ; We will have to have it back
  435.                 ; Later to store the length
  436.     inc    de        ; Point past length storage
  437.     ld    b,0        ; Initialize length of parm
  438. pplp:
  439.     ld    a,(hl)        ; Get next byte of parm
  440.     inc    hl
  441.     or    a        ; Test for end of cmd line
  442.     jp    z,pp2        ; Jump if end
  443.     cp    ' '        ; Test for end of command
  444.     jp    z,pp2
  445.     cp    tab        ; Tab also ends command
  446.     jp    z,pp2
  447.     ld    (de),a        ; Put parameter byte-by-byte
  448.     inc    de        ; Into free memory
  449.     inc    b        ; Bump length
  450.     jp    pplp
  451. pp2:
  452.     ex    de,hl
  453.     ld    (txtptr),hl    ; New free memory pointer
  454.     pop    hl        ; Remember our length pointer?
  455.     ld    (hl),b        ; Store the length
  456.     ex    de,hl        ; Have to retn hl > cmd line
  457.     or    a        ; Now return end of line flag
  458.     scf
  459.     ret    z        ; Return cy if zero (eol mark)
  460.     ccf
  461.     ret
  462. ;
  463. ;
  464. ;    ABORT CHECKS TO SEE IF THE ABORT FLAG IS SET AND
  465. ;    EXECUTES THE ABORT FUNCTION IF SO
  466. ;
  467. ;
  468. abort:
  469.     ld    a,(aflag)    ; Get the flag
  470.     or    a        ; 0=no
  471.     ret    z
  472.     call    print
  473.     db    cr,lf,' Strike ^C to Abort Command File - ',0
  474.     call    charinb        ; Get response
  475.     cp    ctrlc        ; Abort?
  476.     jp    nz,abort1    ; Return to opsys
  477. abort0:
  478.     ld    e,0        ; Set user 0
  479.     ld    c,20h
  480.     call    bdos
  481.  
  482.     ld    de,subfcb    ; Delete submit file
  483.     ld    c,deletf
  484.     call    bdos
  485.     call    print
  486.     db    ' ... Aborted',0
  487.     jp    cpbase        ; Return to cp/m
  488. abort1:
  489.     call    print
  490.     db    ' ... Continuing',0
  491.     jp    cpbase        ; Return to cp/m
  492. ;
  493. ;    INPUT CHAR FROM CON:; RING BELL EVERY SO OFTEN IF FLAG SET
  494. ;
  495. charinb:
  496.     ld    a,(bell$flag)    ; Get flag
  497.     or    a        ; 0=no
  498.     jp    z,charin
  499.     push    hl        ; Save hl
  500. charinb$loop:
  501.     ld    hl,time$const    ; Get time constant
  502. charinb$loop1:
  503.     ex    (sp),hl        ; Long delay
  504.     ex    (sp),hl
  505.     dec    hl        ; Count down
  506.     ld    a,h
  507.     or    l
  508.     jp    nz,charinb$loop1
  509.     ld    e,0ffh        ; Request status
  510.     ld    c,diriof    ; Direct i/o
  511.     call    bdos
  512.     or    a        ; Any input?
  513.     jp    nz,charinb$done
  514.     ld    e,bel        ; Ring bell
  515.     ld    c,diriof
  516.     call    bdos
  517.     jp    charinb$loop
  518. charinb$done:
  519.     pop    hl        ; Restore hl
  520.     jp    caps        ; Capitalize char
  521.  
  522. ;
  523. ;    INPUT CHAR FROM CON:; CAPITALIZE IT AND ECHO <CRLF>
  524. ;
  525. charin:
  526.     ld    c,fgchar    ; Get char
  527.     call    bdos
  528.     jp    caps        ; Capitalize
  529. ;
  530. ;    RDFILE READS THE .SUB FILE SPECIFIED
  531. ;    IN THE SUBMIT COMMAND INTO MEMORY
  532. ;
  533. rdfile:
  534.     ld    hl,0        ; Init line number
  535.     ld    (linnum),hl
  536.     ld    a,(option)    ; Using a file?
  537.     cp    opt        ; Opt option tells
  538.     jp    nz,rdfile1    ; Jump if not
  539.     call    print
  540.     db    cr,lf,' Input Command Lines',0
  541.     call    clfill        ; Get first line
  542.     jp    line
  543. rdfile1:
  544.     call    print
  545.     db    cr,lf,' Processing SUB File',0
  546.  
  547. ;  CHECK FOR .SUB FILE IN SPECIFIED DIRECTORY OR ALONG PATH
  548.     ld    de,fcb        ; Pt to FCB
  549.     ld    a,(de)        ; Get drive byte
  550.     or    a        ; If zero, no dir specified (Z33 feature)
  551.     jr    z,rdfile2
  552.     dec    a        ; Gt drive in range 0..15
  553.     ld    b,a        ; Store drive in B
  554.     ld    a,(fcb+13)    ; Get user number
  555.     ld    c,a        ; ..into C
  556.     call    logud        ; Log in
  557.     call    initfcb        ; Initialize FCB
  558.     jr    rdfile3        ; ..and attempt to open file
  559.  
  560. rdfile2:
  561.     call    initfcb        ; Init fcb
  562.     ld    a,0ffh        ; Search current also
  563.     call    pfind        ; Look for file
  564.     jp    z,notfnd    ; File not found
  565.     call    logud        ; Log into directory
  566.     ld    de,fcb        ; Pt to fcb
  567.  
  568. rdfile3:
  569.     ld    c,openf        ; Open file
  570.     call    bdos
  571.     inc    a        ; Set zero flag if open failed
  572.     jp    z,notfnd
  573.     call    fill        ; Read first block
  574.     jp    nz,notext    ; Empty file
  575. line:
  576.     ld    hl,(linnum)    ; Bump line number
  577.     inc    hl
  578.     ld    (linnum),hl
  579.     ld    hl,(prev)    ; Get prev previous line pointer
  580.     ex    de,hl
  581.     ld    hl,(txtptr)    ; Get current free mem pointer
  582.     ld    (prev),hl    ; Make it the prev line (for nxt pass)
  583.     ld    (hl),e        ; Store at begin of current line,
  584.     inc    hl        ; A pointer to the previous
  585.     ld    (hl),d
  586.     inc    hl
  587.     push    hl        ; Later we will put length here
  588.     inc    hl        ; Skip past length
  589.     ld    c,1        ; Initialize length to one
  590. llp:
  591.     call    gnb        ; Get next byte from input source
  592.     cp    ctrlz        ; End of file?
  593.     jp    z,eof        ; Cy set if end of file found
  594.     and    7fh        ; Mask out msb
  595.     call    caps        ; Convert to upper case
  596.     cp    lf        ; Ignore linefeeds
  597.     jp    z,llp
  598.     cp    cr        ; If it's a carriage return,
  599.     jp    z,eol        ; Then do end of line
  600.     ld    (hl),a        ; Store all others into memory
  601.     inc    hl
  602.     call    size        ; Make sure no memory overflow
  603.     inc    c        ; Bump char count
  604.     jp    m,lenerr    ; Max of 126 chars per line
  605.     jp    llp        ; Go do next char
  606. ;
  607. ;    DO END OF LINE SEQUENCE
  608. ;
  609. eol:
  610.     ld    (txtptr),hl    ; Save free memory pointer
  611.     pop    hl        ; Current line's length pointer
  612.     dec    c        ; Adjust length
  613.     ld    (hl),c        ; Store length away
  614.     jp    line        ; Go do next line
  615. ;
  616. ;    END OF TEXT FILE
  617. ;
  618. eof:
  619.     ld    (txtptr),hl    ; Save free memory pointer
  620.     dec    c        ; Adjust line length
  621.     push    bc        ; Save line length
  622.     call    zmcl        ; Load rest of command line
  623.     pop    bc        ; Restore line length
  624.     pop    hl        ; Current line's length pointer
  625.     ld    (hl),c        ; Store length away
  626.     ret            ; All done reading sub file
  627. ;
  628. ;  COPY COMMAND LINE INTO MEMORY BUFFER
  629. ;
  630. zmcl:
  631.  
  632.     ld    hl,(linnum)    ; Bump line number
  633.     inc    hl
  634.     ld    (linnum),hl
  635.     ld    hl,(prev)    ; Get prev previous line pointer
  636.     ex    de,hl
  637.     ld    hl,(txtptr)    ; Get current free mem pointer
  638.     ld    (prev),hl    ; Make it the prev line (for nxt pass)
  639.     ld    (hl),e        ; Store at begin of current line,
  640.     inc    hl        ; A pointer to the previous
  641.     ld    (hl),d
  642.     inc    hl
  643.     push    hl        ; Later we will put length here
  644.     inc    hl        ; Skip past length
  645.     ld    c,1        ; Initialize length to one
  646.     ex    de,hl        ; De pts to next place to store a byte
  647.     call    getcl1        ; Get address of command line buffer
  648.     ld    a,(hl)        ; Get low
  649.     inc    hl
  650.     ld    h,(hl)        ; Get high
  651.     ld    l,a        ; Hl pts to first byte of multiple command line
  652.     ld    b,(hl)        ; Get first char in line
  653.     ld    (hl),0        ; Clear line
  654.     ld    a,b        ; Check to see if first char is a semicolon (cmd sep)
  655.     cp    ';'
  656.     jp    nz,zmcl0
  657.     inc    hl        ; Pt to 2nd char
  658.     ld    a,(hl)        ; First was a semicolon, so get second
  659. zmcl0:
  660.     ex    de,hl        ; Hl pts to next buffer space, de pts to mc line
  661.     jp    zmcl1a        ; A=first char in mc line
  662. ;
  663. ;  MAJOR LOOP TO STORE MULTIPLE COMMAND LINE
  664. ;
  665. zmcl1:
  666.     ld    a,(de)        ; Get next byte from multiple command line
  667. zmcl1a:
  668.     or    a        ; 0=eol
  669.     jp    z,zmcl2
  670.     and    7fh        ; Mask out msb
  671.     call    caps        ; Convert to upper case
  672.     ld    (hl),a        ; Store char into memory
  673.     inc    hl        ; Pt to next char
  674.     inc    de
  675.     call    size        ; Make sure no memory ovfl
  676.     inc    c        ; Incr char count
  677.     jp    m,lenerr    ; Max of 128 chars in line
  678.     jp    zmcl1
  679. ;
  680. ;  DONE WITH INPUT OF MULTIPLE COMMAND LINE -- SAVE CHAR CNT AND SET PTR
  681. ;
  682. zmcl2:
  683.     ld    (txtptr),hl    ; Save ptr
  684.     pop    hl        ; Pt to char count position
  685.     dec    c        ; Adjust char count
  686.     ld    (hl),c        ; Store char count
  687.     ret
  688.  
  689. ;
  690. ;    GET NEXT BYTE FROM INPUT FILE OR USER
  691. ;
  692. gnb:
  693.     push    hl        ; Don't alter anybody
  694.     push    de
  695.     push    bc
  696.     ld    a,(option)    ; Input from .sub file?
  697.     cp    opt        ; Told by orig cmd line option
  698.     jp    nz,gnbdisk    ; Get next char from disk buffer if not from user
  699.     call    gnbkbd        ; Get a byte from kbd input
  700.     jp    gnbxit        ; Then leave
  701. ;
  702. ;    GET NEXT BYTE FROM DISK FILE
  703. ;
  704. gnbdisk:
  705.     ld    a,(ibp)        ; Get buffer pointer
  706.     cp    128        ; Need another block from disk?
  707.     jp    c,gnbd1        ; Continue
  708.     call    fill        ; Get next block
  709.     jp    z,gnbd1        ; Continue if not empty
  710.     ld    a,1ah        ; Fake eof
  711.     jp    gnbxit
  712. gnbd1:
  713.     ld    e,a        ; Put offset in de
  714.     ld    d,0
  715.     inc    a        ; Point to next byte
  716.     ld    (ibp),a        ; Save for next
  717.     ld    hl,tbuf        ; Now offset into buffer
  718.     add    hl,de
  719.     ld    a,(hl)        ; Get char
  720. gnbxit:
  721.     pop    bc        ; Restore everybody
  722.     pop    de
  723.     pop    hl
  724.     or    a        ; Turn on carry
  725.     ret
  726. ;
  727. ;    FILL INPUT BUFFER FROM DISK
  728. ;
  729. fill:
  730.     xor    a        ; Clear input buffer ptr
  731.     ld    (ibp),a
  732.     ld    de,fcb        ; Pt to fcb
  733.     ld    c,readf        ; Bdos read block function
  734.     call    bdos
  735.     or    a        ; Return z if eof
  736.     ld    a,0        ; Set ptr to first char
  737.     ret
  738. ;
  739. ;    GET NEXT BYTE FROM USER (KEYBOARD INPUT)
  740. ;
  741. gnbkbd:
  742.     ld    hl,(clptr)    ; Pt to next char
  743.     ld    a,(hl)        ; Get it
  744.     inc    hl        ; Pt to following
  745.     ld    (clptr),hl    ; Reset ptr
  746.     cp    cr        ; End of line?
  747.     ret    nz
  748.     call    clfill        ; Get new line
  749.     jp    z,gkend        ; Empty line input - return eof
  750.     ld    a,cr        ; Return cr to indicate end of line
  751.     ret
  752. gkend:
  753.     ld    a,1ah        ; Return eof
  754.     ret
  755. ;
  756. ;    FILL THE COMMAND LINE FROM THE USER
  757. ;
  758. clfill:
  759.     call    print
  760.     db    cr,lf,' Command Line? ',0
  761.     ld    hl,(clbuf)    ; Now fill the buffer
  762.     ex    de,hl        ; De pts to it
  763.     ld    c,rdbuf
  764.     call    bdos
  765.     ld    hl,(clbuf)    ; Pt to command line buffer
  766.     inc    hl
  767.     ld    a,(hl)        ; Get char count
  768.     inc    hl
  769.     ld    (clptr),hl    ; Reset the command line ptr
  770.     or    a        ; Set zero flag
  771.     push    af        ; Save a
  772.     add    a,l        ; Pt to after last char
  773.     ld    l,a
  774.     ld    a,h
  775.     adc    0
  776.     ld    h,a
  777.     ld    (hl),cr        ; Set eol char
  778.     pop    af        ; Get char count
  779.     ret
  780. ;
  781. ;    MAKE SURE NO MEMORY OVERFLOW
  782. ;
  783. size:
  784.     ld    a,(bdos+2)    ; Highest page pointer
  785.     sub    9        ; Make it be under ccp
  786.     cp    h        ; Check it against current page
  787.     ret    nc        ; Nc=all okay
  788.     jp    memerr        ; Otherwise abort
  789. ;
  790. ;    SET UP THE $$$.SUB FILE
  791. ;    FOR WRITING
  792. ;
  793. wrset:
  794.     call    print
  795.     db    cr,lf,' Writing Command File to Disk',0
  796.  
  797.     ld    e,0        ; Set user 0
  798.     ld    c,20h
  799.     call    bdos
  800.  
  801.     ld    de,subfcb
  802.     ld    c,openf
  803.     call    bdos        ; Open the file
  804.     inc    a        ; Check cpm return
  805.     jp    z,none1        ; None exists already
  806. ;
  807. ;    $$$.SUB EXISTS, SO SET
  808. ;    FCB TO APPEND TO IT
  809. ;
  810.  
  811.     ld    de,subfcb    ;TEC Point to submit file FCB
  812.     ld    c,23h        ;TEC "Compute file size" bdos call no.
  813.     call    bdos        ;TEC Get file size in subfr
  814.     ld    hl,(subfr)    ;TEC Get file size
  815.     dec    hl        ;TEC Decrement to get last record no.
  816.     ld    (oldfsz),hl    ;TEC Save present file last record no.
  817.     ld    (subfr),hl    ;TEC Replace in random record field
  818.     ld    de,subfcb    ;TEC Point to submit file FCB again
  819.     ld    c,21h        ;TEC "Read random" bdos call no.
  820.     call    bdos        ;TEC Random read last record
  821.     ld    hl,(tbuf)    ;TEC Get current "last record" pointer
  822.     dec    hl        ;TEC Decr. to point to last unprocessed record
  823.     ld    (subfr),hl    ;TEC Now read "last record"
  824.     ld    de,subfcb    ;TEC Point to submit file FCB again
  825.     ld    c,21h        ;TEC "Read random" bdos call no.
  826.     call    bdos        ;TEC Random read record
  827.     ld    de,subfcb    ;TEC Prepare for sequential (re)write to update
  828.     ld    c,15h        ;TEC ... DOS pointers for further writes
  829.     call    bdos        ;TEC Write same info back to set DOS pointers
  830. ;TEC    ld    a,(subfcb+fcbrc) ; Get record count
  831. ;TEC    ld    (subfcb+fcbnr),a ; Make next record
  832.     ret
  833. oldfsz:    ds    2        ;TEC space for "old file size"
  834. ;
  835. ;    COME HERE WHEN NO $$$.SUB EXISTS
  836. ;
  837. none1:
  838.     xor    a        ;TEC
  839.     ld    (oldfsz),a    ;TEC Zero "old file size" since it did'nt exist
  840.     ld    (oldfsz+1),a    ;TEC
  841.     ld    de,subfcb
  842.     ld    c,makef
  843.     call    bdos
  844.     inc    a
  845.     jp    z,nomake    ; 0ffh=can't create file
  846.     ret
  847. ;
  848. ;    WRITE THE "$$$.SUB" FILE
  849. ;
  850. wrsub:
  851.     ld    hl,(prev)    ; This code scans backward
  852.     ld    a,h        ; Thru the file stored in
  853.     or    l        ; Memory to the first non-
  854.     jp    z,notext    ; Null line.  if none is
  855.     ld    e,(hl)        ; Found, aborts
  856.     inc    hl
  857.     ld    d,(hl)        ; Here, we pick up pntr to prev line
  858.     inc    hl        ; Now we point to length
  859.     ex    de,hl        ; We need to store away
  860.     ld    (prev),hl    ; Pointer to prev line
  861.     ex    de,hl
  862.     ld    a,(hl)        ; Now pick up the length
  863.     or    a        ; Set z flag on length
  864.     jp    nz,wrntry    ; Got line w/length: go do it
  865.     ld    hl,(linnum)    ; Nothing here, fix line number
  866.     dec    hl        ; (working backward now)
  867.     ld    (linnum),hl
  868.     jp    wrsub
  869. wrlop:
  870.     ld    hl,(prev)    ; Get prev line pointer
  871.     ld    a,h
  872.     or    l        ; If there is no prev line
  873.     jp    z,close        ; Then we are done
  874.     ld    e,(hl)        ; Else set up prev for next
  875.     inc    hl        ; Pass thru here
  876.     ld    d,(hl)
  877.     inc    hl
  878.     ex    de,hl        ; Now store it away
  879.     ld    (prev),hl
  880.     ex    de,hl
  881. wrntry:
  882.     call    putlin        ; Write the line to the file
  883.     ld    hl,(linnum)    ; Bump the line number
  884.     dec    hl        ; Down (working back now)
  885.     ld    (linnum),hl
  886.     jp    wrlop
  887. ;
  888. ;    $$$.SUB IS WRITTEN, CLOSE THE FILE
  889. ;
  890. close:
  891.     ld    de,subfcb    ;TEC
  892.     ld    c,24h        ;TEC Set random record number for record after
  893.     call    bdos        ;TEC ... last write
  894.     ld    hl,(subfr)    ;TEC Get rndm record no. for last record write
  895.     ld    (tbuf),hl    ;TEC Place in write buffer
  896.     ld    de,(oldfsz)    ;TEC DE = old last record number
  897.     xor    a        ;TEC Clear carry bit
  898.     sbc    hl,de        ;TEC Is new last record number >= old?
  899.     jr    nc,nfeok    ;TEC New file end O.K.
  900.     ld    (subfr),de    ;TEC ... else use old last record number
  901. nfeok:    ld    de,subfcb    ;TEC
  902.     ld    c,22h        ;TEC "Write random" bdos call no.
  903.     call    bdos        ;TEC Write current record no. to last record.
  904.     ld    de,subfcb
  905.     ld    c,closef
  906.     jp    bdos
  907. ;
  908. ;    THIS SUBROUTINE WRITES A LINE
  909. ;    TO THE $$$.SUB FILE BUFFER,
  910. ;    AND FLUSHES THE BUFFER AFTER
  911. ;    THE LINE IS WRITTEN.
  912. ;
  913. putlin:
  914.     ld    a,(hl)        ; Pick up length byte
  915.     inc    hl        ; Point past it
  916.     or    a
  917.     ret    z        ; Don't output 0 length line
  918.     ld    (getcnt),a    ; Make a count for "GET"
  919.     ld    (getptr),hl    ; Make a pointer for "GET"
  920.     ld    hl,tbuf+1    ; Text goes after length
  921.     ld    (putptr),hl    ; Make pointer for "PUT"
  922.     ld    a,1        ; Initialize put count
  923.     ld    (putcnt),a
  924.     ld    b,l        ; Count for clear loop
  925. clr:
  926.     ld    (hl),0        ; Zero out buffer loc
  927.     inc    hl
  928.     inc    b        ; Count
  929.     jp    nz,clr
  930. ;
  931. ;    THIS LOOP COLLECTS CHARACTERS
  932. ;    FROM THE LINE STORED IN MEMORY
  933. ;    AND WRITES THEM TO THE FILE.
  934. ;    IF THE "$" PARAMETER SPECIFIER
  935. ;    IS ENCOUNTERED, PARAMETER SUB-
  936. ;    STITUTION IS DONE
  937. ;
  938. putlp:
  939.     call    getchr        ; Pick up a character
  940.     jp    c,flush        ; Cy = no more char in line
  941.     cp    '^'        ; Control-char translate prefix?
  942.     jp    nz,notcx
  943.     call    getchr        ; Yes, get the next
  944.     jp    c,ccerr        ; Error: early end of input
  945.     cp    '^'        ; If "^^" just put "^" in text
  946.     jp    z,notcx
  947.     sub    '@'        ; Make it a control-char
  948.     jp    c,ccerr        ; Error: too small
  949.     cp    ' '
  950.     jp    nc,ccerr    ; Error: too large
  951. notcx:
  952.     cp    pdelim        ; Parameter specifier?
  953.     jp    nz,stobyt    ; If not, just write char
  954.     ld    a,(option)    ; Check option: '$' doesn't
  955.     cp    opt        ; Count in opt mode
  956.     ld    a,pdelim    ; (restore the '$')
  957.     jp    z,stobyt
  958.     call    lkahed        ; Peek at next char
  959.     jp    c,parerr    ; Line ending means param err
  960.     cp    pdelim        ; Another "$"?
  961.     jp    nz,subs        ; If not then go do substitution
  962.     call    getchr        ; Get the 2nd "$" (we only looked
  963.                 ; Ahead before)
  964. stobyt:
  965.     call    putchr        ; Write char to file
  966.     jp    putlp
  967. ;
  968. ;    PARAMETER SUBSTITUTION...LOOKS UP THE
  969. ;    PARAMETER # AFTER THE "$" AND PLUGS IT
  970. ;    IN IF IT EXISTS.
  971. ;
  972. subs:
  973.     call    numtst        ; It better be a number
  974.     jp    c,parerr    ; Otherwise param error
  975.     ld    b,0        ; Initialize parm #
  976.     jp    lpntry        ; We join loop in progress...
  977. sublp:
  978.     call    lkahed        ; Look at next char
  979.     jp    c,dosubs    ; If line empty, then plug in parm
  980.     call    numtst        ; Check for numeric
  981.     jp    c,dosubs    ; Done if not
  982. lpntry:
  983.     call    getchr        ; Now remove the char from input stream
  984.     sub    '0'        ; Remove ascii bias
  985.     ld    c,a        ; Save it
  986.     ld    a,b        ; Our accumulated count
  987.     add    a,a        ; Multiply  by ten
  988.     add    a,a
  989.     add    a,b
  990.     add    a,a
  991.     add    a,c        ; Then add in new digit
  992.     ld    b,a        ; Restore count
  993.     jp    sublp
  994. ;
  995. ;    PERFORM THE SUBSTITUTION
  996. ;
  997. dosubs:
  998.     ld    a,b        ; Get parm #
  999.     dec    a        ; Make zero relative
  1000.     jp    m,parerr    ; Oops
  1001.     call    lookup        ; Look it up in parm table
  1002.     jp    c,parerr    ; It's not there
  1003.     ld    b,a        ; Length in b
  1004. sublp1:
  1005.     inc    b        ; Test b for zero
  1006.     dec    b
  1007.     jp    z,putlp        ; Done
  1008.     ld    a,(hl)        ; Get char of real parameter
  1009.     inc    hl        ; Point past for next time
  1010.     push    hl        ; Save real parm pointer
  1011.     call    putchr        ; Put it in the file
  1012.     pop    hl        ; Get back real parm pointer
  1013.     dec    b        ; Countdown
  1014.     jp    sublp1
  1015. ;
  1016. ;    COME HERE WHEN A LINE IS FINISHED,
  1017. ;    AND WE NEED TO WRITE THE BUFFER TO DISK
  1018. ;
  1019. flush:
  1020.     ld    hl,putcnt
  1021.     dec    (hl)        ; Adjust length
  1022.     ld    de,subfcb
  1023.     ld    c,writef
  1024.     call    bdos
  1025.     or    a
  1026.     jp    nz,wrerr    ; Cpm returned a write error
  1027.     ret
  1028. ;
  1029. ;    GETCHR GETS ONE CHAR FROM
  1030. ;    LINE STORED IN MEMORY
  1031. ;
  1032. getchr:
  1033.     ld    hl,getcnt
  1034.     ld    a,(hl)        ; Pick up count
  1035.     dec    a        ; Remove this char
  1036.     scf            ; Preset error
  1037.     ret    m        ; Return cy if out of chars
  1038.     ld    (hl),a        ; Update count
  1039.     ld    hl,(getptr)    ; Current char pointer
  1040.     ld    a,(hl)        ; Pick up char
  1041.     inc    hl        ; Bump pointer
  1042.     ld    (getptr),hl    ; Put it back
  1043.     ccf            ; Turn carry off
  1044.     ret
  1045. ;
  1046. ;    PUTCHR PUTS ONE CHAR TO
  1047. ;    THE OUTPUT BUFFER
  1048. ;
  1049. putchr:
  1050.     ld    hl,putcnt
  1051.     inc    (hl)        ; Increment count
  1052.     jp    m,lenerr    ; Line went to > 127 chars
  1053.     ld    hl,(putptr)    ; Get buffer pointer
  1054.     and    7fh        ; Mask out msb
  1055.     ld    (hl),a        ; Put char there
  1056.     inc    hl        ; Bump pointer
  1057.     ld    (putptr),hl    ; Put it back
  1058.     ret            ; All done
  1059. ;
  1060. ;    LOOK AHEAD ONE CHAR IN
  1061. ;    THE INPUT STREAM.  SET
  1062. ;    CARRY IF NONE LEFT.
  1063. ;
  1064. lkahed:
  1065.     ld    a,(getcnt)
  1066.     or    a        ; See if count is down to zero
  1067.     scf            ; Pre set indicator
  1068.     ret    z
  1069.     ld    a,(hl)        ; Pick up char
  1070.     ccf            ; Turn off carry flag
  1071.     ret
  1072. ;
  1073. ;    LOOK UP PARAMETER WITH NUMBER IN
  1074. ;    A REG. RETURN A=LENGTH OF PARM,
  1075. ;    AND HL => PARAMETER
  1076. ;
  1077. lookup:
  1078.     cp    npar
  1079.     jp    nc,parovf    ; Parm # too high
  1080.     ld    l,a
  1081.     ld    h,0        ; Now have 16 bit number
  1082.     add    hl,hl        ; Double for word offset
  1083.     ld    de,table
  1084.     add    hl,de        ; Do the offset
  1085.     ld    e,(hl)        ; Get address of parm
  1086.     inc    hl
  1087.     ld    d,(hl)
  1088.     ld    a,d        ; Anything there?
  1089.     or    e
  1090.     jp    nz,lkupok
  1091.     xor    a        ; No, zero length
  1092.     ret
  1093. lkupok:
  1094.     ex    de,hl        ; Now in de
  1095.     ld    a,(hl)        ; Pick up length
  1096.     inc    hl        ; Point past length
  1097.     ret
  1098. ;
  1099. ;    UTILITY COMPARE SUBROUTINE
  1100. ;
  1101. compar:
  1102.     ld    a,(de)
  1103.     cp    (hl)
  1104.     ret    nz
  1105.     inc    hl
  1106.     inc    de
  1107.     dec    b
  1108.     jp    nz,compar
  1109.     ret
  1110. ;
  1111. ;    NUMERIC TEST UTILITY SUBROUTINE
  1112. ;
  1113. numtst:
  1114.     cp    '0'
  1115.     ret    c
  1116.     cp    '9'+1
  1117.     ccf
  1118.     ret
  1119. ;
  1120. ;    ERROR HANDLERS
  1121. ;
  1122. wrerr:
  1123.     call    errxit
  1124.     db    'Disk Full',0
  1125. nomake:
  1126.     call    errxit
  1127.     db    'Dir Full',0
  1128. memerr:
  1129.     call    errxit
  1130.     db    'Mem Full',0
  1131. notfnd:
  1132.     call    errxit
  1133.     db    'SUB File Not Found',0
  1134. parerr:
  1135.     call    errxit
  1136.     db    'Param',0
  1137. parovf:
  1138.     call    errxit
  1139.     db    'Too Many Params',0
  1140. lenerr:
  1141.     call    errxit
  1142.     db    'Line too Long',0
  1143. notext:
  1144.     call    errxit
  1145.     db    'SUB File Empty',0
  1146. ccerr:
  1147.     call    errxit
  1148.     db    'Ctrl Char',0
  1149. errxit:
  1150.     call    crlf        ; New line
  1151.     pop    hl
  1152.     call    pstr        ; Print message
  1153.     call    print
  1154.     db    ' Error on Line ',0
  1155.     ld    hl,(linnum)    ; Tell line number
  1156.     call    phldc
  1157.     call    crlf
  1158.     ld    de,subfcb    ; Delete the $$$.sub file
  1159.     ld    c,deletf
  1160.     call    bdos
  1161.     jp    cpbase
  1162. ;
  1163. ;    INITIALIZE ALL VARIABLES
  1164. ;
  1165. initvar:
  1166.     ld    hl,var
  1167.     ld    bc,endvar-var
  1168. initlp:
  1169.     ld    (hl),0        ; Zero entire var area
  1170.     inc    hl
  1171.     dec    bc
  1172.     ld    a,b
  1173.     or    c
  1174.     jp    nz,initlp
  1175.     ld    hl,table    ; Init parm table pointer
  1176.     ld    (tblptr),hl
  1177.     ld    hl,0ffffh    ; Mark end of table
  1178.     ld    (endtbl),hl
  1179.     ld    hl,(fremem)    ; Free memory starts txt area
  1180.     ld    (txtptr),hl
  1181.     ret
  1182. ;
  1183. ; PRINT HELP WITH PROGRAM OPTIONS
  1184. ;
  1185. help:
  1186.     call    print
  1187.     db    cr,lf,'Syntax:'
  1188.     db    cr,lf,'  SUB                    - Print this HELP Message'
  1189.     db    cr,lf,'  SUB /A <text>          - Abort of SUBMIT File'
  1190.     db    cr,lf,'  SUB /AB <text> - Abort and Ring Bell'
  1191.     db    cr,lf,'  SUB /I<CR>             - Go into Interactive mode'
  1192.     db    cr,lf,'  SUB <FILE> <PARMS>     - Standard SUB File'
  1193.     db    0
  1194. gozcpr:
  1195.     ld    hl,(spsave)    ; Return to opsys
  1196.     ld    sp,hl
  1197.     ret
  1198. ;
  1199. ;    VARIABLE STORAGE
  1200. ;
  1201. var    equ    $
  1202. ;
  1203. aflag:
  1204.     db    0        ; Abort flag (0=no)
  1205. txtptr:
  1206.     dw    0        ; Free memory pointer
  1207. tblptr:
  1208.     dw    0        ; Pointer to parm table
  1209. duser:
  1210.     db    0        ; Default user number
  1211. linnum:
  1212.     dw    0        ; Current line number
  1213. prev:
  1214.     dw    0        ; Pointer to prev line
  1215. getcnt:
  1216.     db    0        ; Counter for 'get'
  1217. getptr:
  1218.     dw    0        ; Pointer for 'get'
  1219. putptr:
  1220.     dw    0        ; Pointer for 'put'
  1221. ibp:
  1222.     db    0        ; Input buffer pointer
  1223. clptr:
  1224.     dw    0        ; Command line pointer
  1225. bell$flag:
  1226.     db    0        ; Ring bell on abort flag
  1227. option:
  1228.     db    0        ; Opt option flag store
  1229. table:
  1230.     ds    npar*3        ; Parameter table
  1231. endtbl:
  1232.     dw    0ffffh        ; End of parameter table
  1233. ;
  1234. endvar    equ    $
  1235. spsave:
  1236.     dw    0        ; Stack pointer save
  1237. ;
  1238. ;
  1239. ;    FCB FOR $$$.SUB
  1240. ;
  1241. subfcb:
  1242.     db    1        ; Drive specifier (a selected)
  1243.     db    '$$$     '
  1244. subtyp:
  1245.     db    'SUB'
  1246.     dw    0,0,0,0        ; Initialize rest of fcb
  1247.     dw    0,0,0,0
  1248. ;TEC    dw    0,0,0,0
  1249.     dw    0,0        ;TEC
  1250.     db    0        ;TEC
  1251. subfr:    dw    0        ;TEC
  1252.     db    0        ;TEC
  1253. ;
  1254. clbuf:    ds    2        ; Ptr to command line buffer
  1255. fremem:    ds    2        ; Ptr to free memory area
  1256. ;
  1257.     end
  1258.  
  1259.