home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / ZCPR2 / ZCPR8080.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  58KB  |  2,351 lines
  1.  
  2. *************************************************************************
  3. *  Z C P R 8080 -- Translation to 8080 code - see below            *
  4. *                                    *
  5. *  Z C P R 2 -- Z80-Based Command Processor Replacement, Version 2.0    *
  6. *                                    *
  7. *  Copyright (c) 1982, 1983 by Richard Conn                *
  8. *  All Rights Reserved                            *
  9. *                                    *
  10. *  ZCPR2 was written by Richard Conn, who assumes no responsibility    *
  11. *  or liability for its use.  ZCPR2 is released to the public       *
  12. *  domain for non-commercial use only.                    *
  13. *                                    *
  14. *  The public is encouraged to freely copy and use this program for    *
  15. *  non-commercial purposes.  Any commercial use of ZCPR2 is prohibited    *
  16. *  unless approved by the author, Richard Conn, in writing.        *
  17. *                                    *
  18. *  This is Mod 0.3 to the RELEASE VERSION of ZCPR2.            *
  19. *                                    *
  20. *  Translated to 8080 code - see below                    *
  21. *                                    *
  22. *************************************************************************
  23.  
  24. ;
  25. ;  ZCPR2 -- CP/M Z80 Command Processor Replacement (ZCPR) Version 2.0
  26. ;
  27. ;    ZCPR2 is based upon ZCPR
  28. ;
  29. ;    ZCPR2 was an individual effort by Richard Conn, with comments,
  30. ; recommendations, and some beta testing by the following people:
  31. ;        Frank Wancho
  32. ;        Charlie Strom
  33. ;        Hal Carter
  34. ;
  35. ;    Extensive documentation on ZCPR2 and the utilities in the ZCPR2
  36. ; System can be found in the following manuals:
  37. ;        ZCPR2 Concepts Manual
  38. ;        ZCPR2 Installation Manual
  39. ;        ZCPR2 User's Guide
  40. ;        ZCPR2 Rationale
  41. ;***********************8080 IMPLEMENTATION NOTE***************************
  42. ;
  43. ;     Note: ZCPR has been translated to 8080 code; this version will
  44. ; run on 8080/8085 CPU's. All Z80 relative jumps were converted to
  45. ; absolute jumps; the balance of Z80 opcodes used were translated to
  46. ; short 8080 code routines, each of which is clearly commented. The
  47. ; translation requires expansion of te CCP and in the tested implemen-
  48. ; tation, SUBMIT processing was turned off and mutiple command line
  49. ; buffer, external stack, external FCB and external path specification
  50. ; were enabled. It is fortunate that the implementation of the latter
  51. ; advanced features are accompanied by a reduction of space required in
  52. ; the CCP proper. See the ZCPR2 Installation Manual for details.
  53. ;
  54. ;    The ZCPR2 utilities are all writtten in 8080 code and will
  55. ; therefore operate properly with the following exceptions: DU2, HELP2,
  56. ; LRUNZ. 8080 versions of these utilities are now available.
  57. ;
  58. ;                    Charles H. Strom
  59. ;                    May 11, 1983
  60. ;
  61. ; LDIR replacement changed to subroutine (LDIRSB) to save space (CHS-5/22/83)
  62. ;
  63. ;**************************************************************************
  64. ;
  65. ; 
  66. ;******** Structure Notes ********
  67. ;
  68. ;    ZCPR2 is divided into a number of major sections.  The following
  69. ; is an outline of these sections and the names of the major routines
  70. ; located therein.
  71. ;
  72. ; Section    Function/Routines
  73. ; -------    -----------------
  74. ;
  75. ;   --        Opening Comments, Equates, and Macro Definitions
  76. ;
  77. ;    0        JMP Table into ZCPR2
  78. ;
  79. ;    1        Buffers
  80. ;
  81. ;    2        CPR Starting Modules
  82. ;            CPR1    CPR    CONT    RESTRT    RS1
  83. ;            CAPBUF    RSTCPR    RCPRNL    ERROR    PRNNF
  84. ;
  85. ;    3        Utilities
  86. ;            CRLF    CONOUT    CONIN    LCOUT    LSTOUT
  87. ;            PAGER    READF    READ    BDOSB    PRINTC
  88. ;            PRINT    PRIN1    GETDRV    DEFDMA    DMASET
  89. ;            RESET    BDOSJP    LOGIN    OPENF    OPEN
  90. ;            GRBDOS    CLOSE    SEARF    SEAR1    SEARN
  91. ;            SUBKIL    DELETE    GETUSR    SETUSR
  92. ;
  93. ;     4        CPR Utilities
  94. ;            SETUD    UCASE    REDBUF    BREAK    SDELM
  95. ;            ADVAN    SBLANK    ADDAH    NUMBER    NUMERR
  96. ;            HEXNUM    DIRPTR    SLOGIN    DLOGIN    SCANLOG
  97. ;            SCANER    SCANX    SCANF    CMDSER
  98. ;
  99. ;     5        CPR-Resident Commands and Functions
  100. ;     5A        DIR    DIRPR    PRFN    GETSBIT    FILLQ
  101. ;     5B        ERA
  102. ;     5C        LIST
  103. ;     5D        TYPE
  104. ;     5E        SAVE    EXTEST
  105. ;     5F        REN
  106. ;     5G        JUMP
  107. ;     5H        GO
  108. ;     5I        COM    CALLPROG
  109. ;     5J        GET    MLOAD    PRNLE    PATH
  110. ;
  111. ;
  112. FALSE    EQU    0
  113. TRUE    EQU    NOT FALSE
  114. ;
  115. ;  The following MACLIB statement loads all the user-selected equates
  116. ; which are used to customize ZCPR2 for the user's working environment.
  117. ;
  118.     MACLIB    ZCPRHDR
  119. ;
  120. CR    EQU    0DH
  121. LF    EQU    0AH
  122. TAB    EQU    09H
  123. ;
  124. WBOOT    EQU    BASE+0000H        ;CP/M WARM BOOT ADDRESS
  125. UDFLAG    EQU    BASE+0004H        ;USER NUM IN HIGH NYBBLE, DISK IN LOW
  126. BDOS    EQU    BASE+0005H        ;BDOS FUNCTION CALL ENTRY PT
  127. TFCB    EQU    BASE+005CH        ;DEFAULT FCB BUFFER
  128. TBUFF    EQU    BASE+0080H        ;DEFAULT DISK I/O BUFFER
  129. TPA    EQU    BASE+0100H        ;BASE OF TPA
  130. ;
  131. ;
  132. ;**** Section 0 ****
  133. ;
  134.     ORG    CPRLOC
  135. ;
  136. ;  ENTRY POINTS INTO ZCPR2
  137. ;
  138. ;    IF MULTCMD (MULTIPLE COMMANDS ON ONE LINE) is FALSE:
  139. ;    If ZCPR2 is entered at location CPRLOC (at the JMP to CPR), then
  140. ; the default command in CMDLIN will be processed.  If ZCPR2 is entered
  141. ; at location CPRLOC+3 (at the JMP to CPR1), then the default command in
  142. ; CMDLIN will NOT be processed.
  143. ;    NOTE:  Entry into ZCPR2 at CPRLOC is permitted, but in order for this
  144. ; to work, CMDLIN MUST be initialized to contain the command line (ending in 0)
  145. ; and the C register MUST contain a valid User/Disk Flag
  146. ; (the most significant nybble contains the User Number and the least
  147. ; significant nybble contains the Disk Number).
  148. ;    Some user programs (such as SYNONYM3) attempt to use the default
  149. ; command facility.  Under the original CPR, it was necessary to initialize
  150. ; the pointer after the reserved space for the command buffer to point to
  151. ; the first byte of the command buffer.  The NXTCHR (NeXT CHaRacter pointer)
  152. ; is located to be compatable with such programs (if they determine the buffer
  153. ; length from the byte at BUFSIZ [CPRLOC + 6]), but under ZCPR2
  154. ; this is no longer necessary.  ZCPR2 automatically initializes
  155. ; this buffer pointer in all cases if MULTCMD is not enabled.
  156. ;
  157. ;    IF MULTCMD is TRUE:
  158. ;    Entry at CPR or CPR1 has the same effect.  Multiple command processing
  159. ; will still continue.
  160. ;    Hence, if MULTCMD is FALSE, a user program need only load the buffer
  161. ; CMDLIN with the desired command line, terminated by a zero, in order to
  162. ; have this command line executed.  If MULTCMD is TRUE, a user program must
  163. ; load this buffer as before, but he must also set the NXTCHR pointer to
  164. ; point to the first character of the command line.
  165. ;    NOTE:  ***** (BIG STAR) ***** Programs such as SYNONYM3 will fail if
  166. ; multiple commands are enabled, but this feature is so very useful that I
  167. ; feel it is worth the sacrifice.  The ZCPR2 utilities of STARTUP and MENU
  168. ; require multiple commands, and this feature also permits simple chaining
  169. ; of programs to be possible under the ZCPR2 environment.
  170. ;
  171. ;    Enjoy using ZCPR2!
  172. ;            Richard Conn
  173. ;
  174. ENTRY:
  175.     JMP    CPR    ; Process potential default command
  176.     JMP    CPR1    ; Do NOT process potential default command
  177. ;
  178. ;**** Section 1 ****
  179. ; BUFFERS ET AL
  180. ;
  181. ; INPUT COMMAND LINE AND DEFAULT COMMAND
  182. ;   The command line to be executed is stored here.  This command line
  183. ; is generated in one of three ways:
  184. ;    (1) by the user entering it through the BDOS READLN function at
  185. ; the du> prompt [user input from keyboard]
  186. ;    (2) by the SUBMIT File Facility placing it there from a $$$.SUB
  187. ; file
  188. ;    (3) by an external program or user placing the required command
  189. ; into this buffer
  190. ;   In all cases, the command line is placed into the buffer starting at
  191. ; CMDLIN.  This command line is terminated by a binary zero.  ZCPR2 then
  192. ; parses, interprets, and executes the command line.
  193. ;   Case is not significant in the command line.  ZCPR2 converts all lower-case
  194. ; letters to upper-case.
  195. ;   If MULTCMD is TRUE, then the user must set a pointer to the first
  196. ; character of the command line into the buffer NXTCHR.  If MULTCMD is FALSE,
  197. ; no action other than placing a zero-terminated command line into the buffer
  198. ; starting at CMDLIN is required on the part of the user.
  199. ;
  200.     IF    MULTCMD        ;MULTIPLE COMMANDS ALLOWED?
  201. ;
  202. ; For Multiple Commands, the command line buffer (CMDLIN) is located external
  203. ; to ZCPR2 so that it is not overlayed during Warm Boots; the same is true
  204. ; for NXTCHR, the 2nd key buffer.  BUFSIZ and CHRCNT are not important and
  205. ; are provided so the BDOS READLN function can load CMDLIN directly and
  206. ; a user program can see how much space is available in CMDLIN for its text.
  207. ;
  208. NXTCHR    EQU    CLBASE        ;NXTCHR STORED EXTERNALLY (2 bytes)
  209. BUFSIZ    EQU    NXTCHR+2    ;BUFSIZ STORED EXTERNALLY (1 byte)
  210. CHRCNT    EQU    BUFSIZ+1    ;CHRCNT STORED EXTERNALLY (1 byte)
  211. CMDLIN    EQU    CHRCNT+1    ;CMDLIN STORED EXTERNALLY (long)
  212. ;
  213.     ELSE
  214. ;
  215. ; If no multiple commands are permitted, these buffers are left internal
  216. ; to ZCPR2 so that the original CCP command line facility (as used by
  217. ; programs like SYNONYM3) can be left intact.
  218. ;
  219. BUFLEN    EQU    80        ;MAXIMUM BUFFER LENGTH
  220. BUFSIZ:
  221.     DB    BUFLEN        ;MAXIMUM BUFFER LENGTH
  222. CHRCNT:
  223.     DB    0        ;NUMBER OF VALID CHARS IN COMMAND LINE
  224. CMDLIN:
  225.     DB    '               '    ;DEFAULT (COLD BOOT) COMMAND
  226.     DB    0            ;COMMAND STRING TERMINATOR
  227.     DS    BUFLEN-($-CMDLIN)+1    ;TOTAL IS 'BUFLEN' BYTES
  228. ;
  229. NXTCHR:
  230.     DW    CMDLIN        ;POINTER TO COMMAND INPUT BUFFER
  231. ;
  232.     ENDIF        ;MULTCMD
  233. ;
  234.  
  235. ;
  236. ; FILE TYPE FOR COMMAND
  237. ;
  238. COMMSG:
  239.     COMTYP            ;USE MACRO FROM ZCPRHDR.LIB
  240. ;
  241.     IF    SUBON        ;IF SUBMIT FACILITY ENABLED ...
  242. ;
  243. ; SUBMIT FILE CONTROL BLOCK
  244. ;
  245. SUBFCB:
  246.     DB    1        ;DISK NAME SET TO DEFAULT TO DRIVE A:
  247.     DB    '$$$'        ;FILE NAME
  248.     DB    '     '
  249.     SUBTYP            ;USE MACRO FROM ZCPRHDR.LIB
  250.     DB    0        ;EXTENT NUMBER
  251.     DB    0        ;S1
  252. SUBFS2:
  253.     DS    1        ;S2
  254. SUBFRC:
  255.     DS    1        ;RECORD COUNT
  256.     DS    16        ;DISK GROUP MAP
  257. SUBFCR:
  258.     DS    1        ;CURRENT RECORD NUMBER
  259. ;
  260.     ENDIF        ;SUBON
  261. ;
  262. ; COMMAND FILE CONTROL BLOCK
  263. ;
  264.     IF    EXTFCB        ;MAY BE PLACED EXTERNAL TO ZCPR2
  265. ;
  266. FCBDN    EQU    FCBADR        ;DISK NAME
  267. FCBFN    EQU    FCBDN+1        ;FILE NAME
  268. FCBFT    EQU    FCBFN+8        ;FILE TYPE
  269. FCBDM    EQU    FCBFT+7        ;DISK GROUP MAP
  270. FCBCR    EQU    FCBDM+16    ;CURRENT RECORD NUMBER
  271. ;
  272.     ELSE            ;OR INTERNAL TO ZCPR2
  273. ;
  274. FCBDN:
  275.     DS    1        ;DISK NAME
  276. FCBFN:
  277.     DS    8        ;FILE NAME
  278. FCBFT:
  279.     DS    3        ;FILE TYPE
  280.     DS    1        ;EXTENT NUMBER
  281.     DS    2        ;S1 AND S2
  282.     DS    1        ;RECORD COUNT
  283. FCBDM:
  284.     DS    16        ;DISK GROUP MAP
  285. FCBCR:
  286.     DS    1        ;CURRENT RECORD NUMBER
  287. ;
  288.     ENDIF        ;EXTFCB
  289. ;
  290.  
  291. ;
  292. ; LINE COUNT BUFFER
  293. ;
  294. PAGCNT:
  295.     DB    NLINES-2    ;LINES LEFT ON PAGE
  296.  
  297. ;
  298. ; CPR COMMAND NAME TABLE
  299. ;   EACH TABLE ENTRY IS COMPOSED OF THE 4-BYTE COMMAND AND 2-BYTE ADDRESS
  300. ;
  301. CMDTBL:
  302.     CTABLE        ;DEFINE COMMAND TABLE VIA MACRO IN ZCPRHDR FILE
  303. ;
  304. NCMNDS    EQU    ($-CMDTBL)/(NCHARS+2)
  305. ;
  306.  
  307. ;
  308. ;**** Section 2 ****
  309. ; ZCPR2 STARTING POINTS
  310. ;
  311. ; START ZCPR2 AND DON'T PROCESS DEFAULT COMMAND STORED IF MULTIPLE COMMANDS
  312. ; ARE NOT ALLOWED
  313. ;
  314. CPR1:
  315. ;
  316.     IF    NOT MULTCMD    ;IF MULTIPLE COMMANDS NOT ALLOWED
  317. ;
  318.     XRA    A        ;SET END OF COMMAND LINE SO NO DEFAULT COMMAND
  319.     STA    CMDLIN        ;FIRST CHAR OF BUFFER
  320. ;
  321.     ENDIF        ;NOT MULTCMD
  322. ;
  323. ; START ZCPR2 AND POSSIBLY PROCESS DEFAULT COMMAND
  324. ;
  325. ; NOTE ON MODIFICATION BY Ron Fowler:  BDOS RETURNS 0FFH IN
  326. ; ACCUMULATOR WHENEVER IT LOGS IN A DIRECTORY, IF ANY
  327. ; FILE NAME CONTAINS A '$' IN IT.  THIS IS NOW USED AS
  328. ; A CLUE TO DETERMINE WHETHER OR NOT TO DO A SEARCH
  329. ; FOR SUBMIT FILE, IN ORDER TO ELIMINATE WASTEFUL SEARCHES.
  330. ;
  331. CPR:
  332.     LXI    SP,STACK    ;RESET STACK
  333. ;
  334.     IF    NOT MULTCMD    ;ONLY ONE COMMAND PERMITTED
  335. ;
  336.     LXI    H,CMDLIN    ;SET PTR TO BEGINNING OF COMMAND LINE
  337.     SHLD    NXTCHR
  338. ;
  339.     ENDIF        ;NOT MULTCMD
  340. ;
  341.     PUSH    B
  342.     MOV    A,C        ;C=USER/DISK NUMBER (SEE LOC 4)
  343.     RAR            ;EXTRACT USER NUMBER
  344.     RAR
  345.     RAR
  346.     RAR
  347.     ANI    0FH
  348.     STA    CURUSR        ;SET USER
  349.     CALL    SETUSR        ;SET USER NUMBER
  350.     CALL    RESET        ;RESET DISK SYSTEM
  351. ;
  352.     IF    SUBON        ;IF SUBMIT FACILITY ENABLED
  353. ;
  354.     STA    RNGSUB        ;SAVE SUBMIT CLUE FROM DRIVE A:
  355. ;
  356.     ENDIF        ;SUBON
  357. ;
  358.     POP    B
  359.     MOV    A,C        ;C=USER/DISK NUMBER (SEE LOC 4)
  360.     ANI    0FH        ;EXTRACT CURRENT DISK DRIVE
  361.     STA    CURDR        ;SET IT
  362.     CNZ    LOGIN        ;LOG IN DEFAULT DISK IF NOT ALREADY LOGGED IN
  363.     CALL    SETUD        ;SET USER/DISK FLAG
  364.     CALL    DEFDMA        ;SET DEFAULT DMA ADDRESS
  365. ;
  366.     IF    SUBON        ;CHECK FOR $$$.SUB IF SUBMIT FACILITY IS ON
  367. ;
  368.     LXI    D,SUBFCB    ;CHECK FOR $$$.SUB ON CURRENT DISK
  369. RNGSUB    EQU    $+1        ;POINTER FOR IN-THE-CODE MODIFICATION
  370.     MVI    A,0        ;2ND BYTE (IMMEDIATE ARG) IS THE RNGSUB FLAG
  371.     ORA    A        ;SET FLAGS ON CLUE
  372.     CNZ    SEAR1
  373.     STA    RNGSUB        ;SET FLAG (0=NO $$$.SUB)
  374. ;
  375.     ENDIF        ;SUBON
  376. ;
  377.     IF    MULTCMD
  378. ;
  379. ;  TEST FOR NEXT COMMAND IN CONT LOOP IF MULTIPLE COMMAND LINE BUFFER
  380. ;    IS ENABLED
  381. ;
  382. CONT:
  383. ;
  384.     ENDIF        ;MULTCMD
  385. ;
  386.     LHLD    NXTCHR        ;PT TO NEXT CHARACTER TO PROCESS
  387.     MOV    A,M        ;GET IT
  388.     CPI    3        ;RESTART IF ^C
  389.     JZ    RESTRT
  390.     ORA    A        ;0 IF NO COMMAND LINE PRESENT
  391.     JNZ    RS1
  392. ;
  393.     IF    NOT MULTCMD
  394. ;
  395. ;  TEST FOR ANY DEFAULT COMMAND BEFORE CONT LOOP IS
  396. ;    ENTERED IF MULTIPLE COMMAND LINE BUFFER IS DISABLED
  397. ;
  398. CONT:
  399. ;
  400.     ENDIF        ;NOT MULTCMD
  401. ;
  402. ; PROMPT USER AND INPUT COMMAND LINE FROM HIM
  403. ;
  404. RESTRT:
  405.     LXI    SP,STACK    ;RESET STACK
  406. ;
  407. ; PRINT PROMPT (DU>)
  408. ;
  409.     CALL    CRLF        ;PRINT PROMPT
  410. ;
  411.     IF    DUPRMPT        ;IF DRIVE IN PROMPT
  412.     LDA    CURDR        ;CURRENT DRIVE IS PART OF PROMPT
  413.     ADI    'A'        ;CONVERT TO ASCII A-P
  414.     CALL    CONOUT
  415. ;
  416.     LDA    CURUSR        ;GET USER NUMBER
  417. ;
  418.     IF    SUPRES        ;IF SUPPRESSING USR # REPORT FOR USR 0
  419. ;
  420.     ORA    A
  421.     JZ    RS000
  422. ;
  423.     ENDIF        ;SUPRES
  424. ;
  425.     CPI    10        ;USER < 10?
  426.     JC    RS00
  427.     SUI    10        ;SUBTRACT 10 FROM IT
  428.     PUSH    PSW        ;SAVE IT
  429.     MVI    A,'1'        ;OUTPUT 10'S DIGIT
  430.     CALL    CONOUT
  431.     POP    PSW
  432. RS00:
  433.     ADI    '0'        ;OUTPUT 1'S DIGIT (CONVERT TO ASCII)
  434.     CALL    CONOUT
  435. ;
  436.     ENDIF        ;DUPRMPT
  437. ;
  438. ; READ INPUT LINE FROM USER OR $$$.SUB
  439. ;
  440. RS000:
  441.     LXI    H,CMDLIN    ;SET POINTER TO FIRST CHAR IN COMMAND LINE
  442.     SHLD    NXTCHR        ;POINTER TO NEXT CHARACTER TO PROCESS
  443.     MVI    M,0        ;ZERO OUT COMMAND LINE IN CASE OF WARM BOOT
  444.     PUSH    H        ;SAVE PTR
  445.     CALL    REDBUF        ;INPUT COMMAND LINE FROM USER (OR $$$.SUB)
  446.     POP    H        ;GET PTR
  447.     MOV    A,M        ;CHECK FOR COMMENT LINE
  448.     CPI    COMMENT        ;BEGINS WITH COMMENT CHAR?
  449.     JZ    RESTRT        ;INPUT ANOTHER LINE IF SO
  450.     ORA    A        ;NO INPUT?
  451.     JZ    RESTRT
  452. ;
  453. ; PROCESS INPUT LINE; HL PTS TO FIRST LETTER OF COMMAND
  454. ;
  455. RS1:
  456.     LXI    SP,STACK    ;RESET STACK
  457. ;
  458.     IF    MULTCMD        ;MULTIPLE COMMANDS ALLOWED?
  459. ;
  460.     MOV    A,M        ;GET FIRST CHAR OF COMMAND
  461.     CPI    CMDSEP        ;IS IT A COMMAND SEPARATOR?
  462.     JNZ    RS2
  463.     INX    H        ;SKIP IT IF IT IS
  464.     SHLD    NXTCHR        ;SET PTR BACK
  465. ;
  466.     ENDIF        ;MULTCMD
  467. ;
  468. ; SET POINTER FOR MULTIPLE COMMAND LINE PROCESSING TO FIRST CHAR OF NEW CMND
  469. ;
  470. RS2:
  471.     SHLD    CMDCH1        ;SET PTR TO FIRST CHAR OF NEW COMMAND LINE
  472. ;
  473. ; CAPITALIZE COMMAND LINE
  474. ;
  475. CAPBUF:
  476.     MOV    A,M        ;CAPITALIZE COMMAND CHAR
  477.     CALL    UCASE
  478.     MOV    M,A
  479.     INX    H        ;PT TO NEXT CHAR
  480.     ORA    A        ;EOL?
  481.     JNZ    CAPBUF
  482.     CALL    SCANER        ;PARSE COMMAND NAME FROM COMMAND LINE
  483.     JNZ    ERROR        ;ERROR IF COMMAND NAME CONTAINS A '?'
  484.     LXI    D,RSTCPR    ;PUT RETURN ADDRESS OF COMMAND
  485.     PUSH    D        ;ON THE STACK
  486. COLON    EQU    $+1        ;FLAG FOR IN-THE-CODE MODIFICATION
  487.     MVI    A,0        ;COMMAND OF THE FORM 'DU:COMMAND'?
  488.     ORA    A        ;0=NO
  489.     JNZ    COM        ;PROCESS AS COM FILE IF NOT
  490.     CALL    CMDSER        ;SCAN FOR CPR-RESIDENT COMMAND
  491.     JNZ    COM        ;NOT CPR-RESIDENT
  492.     MOV    A,M        ;FOUND IT:  GET LOW-ORDER PART
  493.     INX    H        ;GET HIGH-ORDER PART
  494.     MOV    H,M        ;STORE HIGH
  495.     MOV    L,A        ;STORE LOW
  496.     PCHL            ;EXECUTE CPR ROUTINE
  497. ;
  498. ; ENTRY POINT FOR RESTARTING CPR AND LOGGING IN DEFAULT DRIVE
  499. ;
  500. RSTCPR:
  501.     CALL    DLOGIN        ;LOG IN CURRENT USER/DISK
  502. ;
  503. ; ENTRY POINT FOR RESTARTING CPR WITHOUT LOGGING IN DEFAULT DRIVE
  504. ;
  505. RCPRNL:
  506.     CALL    SCANER        ;EXTRACT NEXT TOKEN FROM COMMAND LINE
  507.     LDA    FCBFN        ;GET FIRST CHAR OF TOKEN
  508.     CPI    ' '        ;ANY CHAR?
  509.     JZ    CONT        ;CONTINUE WITH NEXT COMMAND IF NO ERROR
  510.  
  511. ;
  512. ; INVALID COMMAND -- PRINT IT
  513. ;
  514. ERROR:
  515.     CALL    CRLF        ;NEW LINE
  516. CURTOK    EQU    $+1        ;POINTER FOR IN-THE-CODE MODIFICATION
  517.     LXI    H,0        ;PT TO BEGINNING OF COMMAND LINE
  518. ERR1:
  519.     MOV    A,M        ;GET CHAR
  520.     CPI    ' '+1        ;SIMPLE '?' IF <SP> OR LESS
  521.     JC    ERR2
  522.     CALL    CONOUT        ;PRINT COMMAND CHAR
  523.     INX    H        ;PT TO NEXT CHAR
  524.     JMP    ERR1        ;CONTINUE
  525. ERR2:
  526.     CALL    PRINT        ;PRINT '?'
  527.     DB    '?'+80H
  528. ERR3:
  529.     CALL    DLOGIN        ;PANIC RESTORE OF DEFAULT USER/DISK
  530. ;
  531.     IF    SUBON        ;IF SUBMIT FACILITY IS ON
  532. ;
  533.     CALL    SUBKIL        ;TERMINATE ACTIVE $$$.SUB IF ANY
  534. ;
  535.     ENDIF        ;SUBON
  536. ;
  537.     JMP    RESTRT        ;RESTART CPR
  538.  
  539. ;
  540. ; No File Error Message
  541. ;
  542. PRNNF:
  543.     CALL    PRINTC        ;NO FILE MESSAGE
  544.     DB    'No Fil','e'+80H
  545.     RET
  546. ;
  547. ;**** Section 3 ****
  548. ; I/O UTILITIES
  549. ;
  550. ; OUTPUT CHAR IN REG A TO CONSOLE AND DON'T CHANGE BC
  551. ;
  552. ;
  553. ; OUTPUT <CRLF>
  554. ;
  555. CRLF:
  556.     MVI    A,CR
  557.     CALL    CONOUT
  558.     MVI    A,LF
  559.     JMP    CONOUT
  560. ;
  561. CONIN:
  562.     MVI    C,1    ;INPUT CHAR
  563.     CALL    BDOS    ;GET INPUT CHAR WITH ^S PROCESSING AND ECHO
  564.     JMP    UCASE    ;CAPITALIZE
  565. ;
  566. CONOUT:
  567.     PUSH    B    ;EXX REPLACEMENT
  568.     PUSH    D
  569.     PUSH    H
  570.     MVI    C,2
  571. OUTPUT:
  572.     MOV    E,A
  573.     CALL    BDOS
  574.     POP    H    ;EXX REPLACEMENT
  575.     POP    D
  576.     POP    B
  577.     RET
  578. ;
  579. LCOUT:
  580.     PUSH    PSW    ;OUTPUT CHAR TO CON: OR LST: DEP ON PRFLG
  581. PRFLG    EQU    $+1    ;POINTER FOR IN-THE-CODE MODIFICATION
  582.     MVI    A,0    ;2ND BYTE (IMMEDIATE ARG) IS THE PRINT FLAG
  583.     ORA    A    ;0=TYPE
  584.     JZ    LC1
  585.     POP    PSW    ;GET CHAR
  586. ;
  587. ; OUTPUT CHAR IN REG A TO LIST DEVICE
  588. ;
  589. LSTOUT:
  590.     PUSH    B    ;EXX REPLACEMENT
  591.     PUSH    D    ;SAVE REGS
  592.     PUSH    H
  593.     MVI    C,5
  594.     JMP    OUTPUT
  595. LC1:
  596.     POP    PSW    ;GET CHAR
  597.     PUSH    PSW
  598.     CALL    CONOUT    ;OUTPUT TO CON:
  599.     POP    PSW
  600.     CPI    LF    ;CHECK FOR PAGING
  601.     RNZ
  602. ;
  603. ; PAGING ROUTINES
  604. ;   PAGER COUNTS DOWN LINES AND PAUSES FOR INPUT (DIRECT) IF COUNT EXPIRES
  605. ;   PAGSET SETS LINES/PAGE COUNT
  606. ;
  607. PAGER:
  608.     PUSH    H
  609.     LXI    H,PAGCNT    ;COUNT DOWN
  610.     DCR    M
  611.     JNZ    PAGER1        ;JUMP IF NOT END OF PAGE
  612.     MVI    M,NLINES-2    ;REFILL COUNTER
  613. ;
  614. PGFLG    EQU    $+1        ;POINTER TO IN-THE-CODE BUFFER PGFLG
  615.     MVI    A,0        ;0 MAY BE CHANGED BY PGFLG EQUATE
  616.     CPI    PGDFLG        ;PAGE DEFAULT OVERRIDE OPTION WANTED?
  617. ;
  618.     IF    PGDFLT        ;IF PAGING IS DEFAULT
  619. ;
  620.     JZ    PAGER1        ;  PGDFLG MEANS NO PAGING, PLEASE
  621. ;
  622.     ELSE            ;IF PAGING NOT DEFAULT
  623. ;
  624.     JNZ    PAGER1        ;  PGDFLG MEANS PLEASE PAGINATE
  625. ;
  626.     ENDIF        ;PGDFLG
  627. ;
  628.     PUSH    B        ;SAVE REG
  629.     CALL    BIOS+9        ;BIOS CONSOLE INPUT ROUTINE
  630.     POP    B        ;GET REG
  631.     CPI    'C'-'@'     ;^C
  632.     JZ    RSTCPR        ;RESTART CPR
  633. PAGER1:
  634.     POP    H        ;RESTORE HL
  635.     RET
  636. ;
  637. ; READ FILE BLOCK FUNCTION
  638. ;
  639. READF:
  640.     LXI    D,FCBDN ;FALL THRU TO READ
  641. READ:
  642.     MVI    C,14H    ;FALL THRU TO BDOSB
  643. ;
  644. ; CALL BDOS AND SAVE BC
  645. ;
  646. BDOSB:
  647.     PUSH    B
  648.     CALL    BDOS
  649.     POP    B
  650.     ORA    A
  651.     RET
  652. ;
  653. ; PRINT STRING (ENDING IN CHAR WITH MSB SET) PTED TO BY RET ADR
  654. ; START WITH <CRLF>
  655. ;
  656. PRINTC:
  657.     CALL    CRLF        ;NEW LINE
  658. ;
  659. PRINT:
  660.     XTHL            ;GET PTR TO STRING
  661.     CALL    PRIN1        ;PRINT STRING
  662.     XTHL            ;RESTORE HL AND RET ADR
  663.     RET
  664. ;
  665. ; PRINT STRING (ENDING IN 0 OR BYTE WITH MSB SET) PTED TO BY HL
  666. ;
  667. PRIN1:
  668.     MOV    A,M        ;GET NEXT BYTE
  669.     INX    H        ;PT TO NEXT BYTE
  670.     ORA    A        ;END OF STRING?
  671.     RZ            ;STRING TERMINATED BY BINARY 0
  672.     PUSH    PSW        ;SAVE FLAGS
  673.     ANI    7FH        ;MASK OUT MSB
  674.     CALL    CONOUT        ;PRINT CHAR
  675.     POP    PSW        ;GET FLAGS
  676.     RM            ;STRING TERMINATED BY MSB SET
  677.     JMP    PRIN1
  678. ;
  679. ; BDOS FUNCTION ROUTINES
  680. ;
  681. ;
  682. ; RETURN NUMBER OF CURRENT DISK IN A
  683. ;
  684. GETDRV:
  685.     MVI    C,19H
  686.     JMP    BDOSJP
  687. ;
  688. ; SET 80H AS DMA ADDRESS
  689. ;
  690. DEFDMA:
  691.     LXI    D,TBUFF     ;80H=TBUFF
  692. DMASET:
  693.     MVI    C,1AH
  694.     JMP    BDOSJP
  695. ;
  696. RESET:
  697.     MVI    C,0DH
  698. BDOSJP:
  699.     JMP    BDOS
  700. ;
  701. LOGIN:
  702.     MOV    E,A
  703.     MVI    C,0EH
  704.     JMP    BDOSJP    ;SAVE SOME CODE SPACE
  705. ;
  706. OPENF:
  707.     XRA    A
  708.     STA    FCBCR
  709.     LXI    D,FCBDN ;FALL THRU TO OPEN
  710. ;
  711. OPEN:
  712.     MVI    C,0FH    ;FALL THRU TO GRBDOS
  713. ;
  714. GRBDOS:
  715.     CALL    BDOS
  716.     INR    A    ;SET ZERO FLAG FOR ERROR RETURN
  717.     RET
  718. ;
  719. CLOSE:
  720.     MVI    C,10H
  721.     JMP    GRBDOS
  722. ;
  723. SEARF:
  724.     LXI    D,FCBDN ;SPECIFY FCB
  725. SEAR1:
  726.     MVI    C,11H
  727.     JMP    GRBDOS
  728. ;
  729. SEARN:
  730.     MVI    C,12H
  731.     JMP    GRBDOS
  732. ;
  733. ; CHECK FOR SUBMIT FILE IN EXECUTION AND ABORT IT IF SO
  734. ;
  735.     IF    SUBON        ;ENABLE ONLY IF SUBMIT FACILITY IS ENABLED
  736. ;
  737. SUBKIL:
  738.     LXI    H,RNGSUB    ;CHECK FOR SUBMIT FILE IN EXECUTION
  739.     MOV    A,M
  740.     ORA    A        ;0=NO
  741.     RZ
  742.     MVI    M,0        ;ABORT SUBMIT FILE
  743.     LXI    D,SUBFCB    ;DELETE $$$.SUB
  744. ;
  745.     ENDIF        ;SUBON
  746. ;
  747. DELETE:
  748.     MVI    C,13H
  749.     JMP    BDOSJP    ;SAVE MORE SPACE
  750. ;
  751. ;  GET/SET USER NUMBER
  752. ;
  753. GETUSR:
  754.     MVI    A,0FFH        ;GET CURRENT USER NUMBER
  755. SETUSR:
  756.     MOV    E,A        ;USER NUMBER IN E
  757.     MVI    C,20H        ;SET USER NUMBER TO VALUE IN E (GET IF E=FFH)
  758.     JMP    BDOSJP        ;MORE SPACE SAVING
  759. ;
  760. ; END OF BDOS FUNCTIONS
  761. ;
  762. ;
  763. ;**** Section 4 ****
  764. ; ZCPR2 UTILITIES
  765. ;
  766. ; SET USER/DISK FLAG TO CURRENT USER AND DEFAULT DISK
  767. ;
  768. SETUD:
  769.     CALL    GETUSR        ;GET NUMBER OF CURRENT USER
  770.     ANI    0FH        ;MASK SURE 4 BITS
  771.     ADD    A        ;PLACE IT IN HIGH NYBBLE
  772.     ADD    A
  773.     ADD    A
  774.     ADD    A
  775.     LXI    H,CURDR        ;MASK IN CURRENT DRIVE NUMBER (LOW NYBBLE)
  776.     ORA    M        ;MASK IN
  777.     STA    UDFLAG        ;SET USER/DISK NUMBER
  778.     RET
  779. ;
  780. ; CONVERT CHAR IN A TO UPPER CASE
  781. ;
  782. UCASE:
  783.     ANI    7FH        ;MASK OUT MSB
  784.     CPI    61H        ;LOWER-CASE A
  785.     RC
  786.     CPI    7BH        ;GREATER THAN LOWER-CASE Z?
  787.     RNC
  788.     ANI    5FH        ;CAPITALIZE
  789.     RET
  790. ;
  791. ; INPUT NEXT COMMAND TO CPR
  792. ;    This routine determines if a SUBMIT file is being processed
  793. ; and extracts the command line from it if so or from the user's console
  794. ;
  795. REDBUF:
  796. ;
  797.     IF    SUBON        ;IF SUBMIT FACILITY IS ENABLED, CHECK FOR IT
  798. ;
  799.     LDA    RNGSUB        ;SUBMIT FILE CURRENTLY IN EXECUTION?
  800.     ORA    A        ;0=NO
  801.     JZ    RB1        ;GET LINE FROM CONSOLE IF NOT
  802.     LXI    D,SUBFCB    ;OPEN $$$.SUB
  803.     PUSH    D        ;SAVE DE
  804.     CALL    OPEN
  805.     POP    D        ;RESTORE DE
  806.     JZ    RB1        ;ERASE $$$.SUB IF END OF FILE AND GET CMND
  807.     LDA    SUBFRC        ;GET VALUE OF LAST RECORD IN FILE
  808.     DCR    A        ;PT TO NEXT TO LAST RECORD
  809.     STA    SUBFCR        ;SAVE NEW VALUE OF LAST RECORD IN $$$.SUB
  810.     CALL    READ        ;DE=SUBFCB
  811.     JNZ    RB1        ;ABORT $$$.SUB IF ERROR IN READING LAST REC
  812.     LXI    D,CHRCNT     ;COPY LAST RECORD (NEXT SUBMIT CMND) TO CHRCNT
  813.     LXI    H,TBUFF     ;  FROM TBUFF
  814.     LXI    B,BUFLEN    ;NUMBER OF BYTES
  815.     CALL    LDIRSB        ;LDIR REPLACEMENT SUBROUTINE
  816.     LXI    H,SUBFS2    ;PT TO S2 OF $$$.SUB FCB
  817.     MVI    M,0        ;SET S2 TO ZERO
  818.     INX    H        ;PT TO RECORD COUNT
  819.     DCR    M        ;DECREMENT RECORD COUNT OF $$$.SUB
  820.     LXI    D,SUBFCB    ;CLOSE $$$.SUB
  821.     CALL    CLOSE
  822.     JZ    RB1        ;ABORT $$$.SUB IF ERROR
  823.     MVI    A,SPRMPT    ;PRINT SUBMIT PROMPT
  824.     CALL    CONOUT
  825.     LXI    H,CMDLIN    ;PRINT COMMAND LINE FROM $$$.SUB
  826.     CALL    PRIN1
  827.     CALL    BREAK        ;CHECK FOR ABORT (ANY CHAR)
  828.     RNZ            ;IF NO ^C, RETURN TO CALLER AND RUN
  829.     CALL    SUBKIL        ;KILL $$$.SUB IF ABORT
  830.     JMP    RESTRT        ;RESTART CPR
  831. ;
  832. ; INPUT COMMAND LINE FROM USER CONSOLE
  833. ;
  834. RB1:
  835.     CALL    SUBKIL        ;ERASE $$$.SUB IF PRESENT
  836. ;
  837.     ENDIF        ;SUBON
  838. ;
  839.     MVI    A,CPRMPT    ;PRINT PROMPT
  840.     CALL    CONOUT
  841.     MVI    C,0AH        ;READ COMMAND LINE FROM USER
  842.     LXI    D,BUFSIZ
  843.     CALL    BDOS
  844. ;
  845. ; STORE ZERO AT END OF COMMAND LINE
  846. ;
  847.     LXI    H,CHRCNT    ;PT TO CHAR COUNT
  848.     MOV    A,M        ;GET CHAR COUNT
  849.     INX    H        ;PT TO FIRST CHAR OF COMMAND LINE
  850.     CALL    ADDAH        ;PT TO AFTER LAST CHAR OF COMMAND LINE
  851.     MVI    M,0        ;STORE ENDING ZERO
  852.     RET
  853. ;
  854. ; CHECK FOR ANY CHAR FROM USER CONSOLE; RET W/ZERO SET IF NONE
  855. ;
  856. BREAK:
  857.     PUSH    B        ;EXX REPLACEMENT
  858.     PUSH    D        ;SAVE REGS
  859.     PUSH    H
  860.     CALL    BIOS+6        ;CONSOLE STATUS CHECK
  861.     ORA    A        ;SET FLAGS
  862.     CNZ    BIOS+9        ;GET INPUT CHAR WITH ^S PROCESSING
  863.     CPI    'S'-'@'        ;PAUSE IF ^S
  864.     CZ    BIOS+9        ;GET NEXT CHAR
  865.     POP    H        ;RESTORE REGS
  866.     POP    D
  867.     POP    B
  868.     CPI    'C'-'@'        ;CHECK FOR ABORT
  869.     RET
  870.  
  871. ;
  872. ; CHECK TO SEE IF DE PTS TO DELIMITER; IF SO, RET W/ZERO FLAG SET
  873. ;
  874. SDELM:
  875.     LDAX    D
  876.     ORA    A        ;0=DELIMITER
  877.     RZ
  878.     CPI    ' '+1        ;DELIM IF <= <SP>
  879.     JC    ZERO
  880.     CPI    '='        ;'='=DELIMITER
  881.     RZ
  882.     CPI    5FH        ;UNDERSCORE=DELIMITER
  883.     RZ
  884.     CPI    '.'        ;'.'=DELIMITER
  885.     RZ
  886.     CPI    ':'        ;':'=DELIMITER
  887.     RZ
  888.     CPI    ','        ;','=DELIMITER
  889.     RZ
  890.     CPI    ';'        ;';'=DELIMITER
  891.     RZ
  892.     CPI    '<'        ;'<'=DELIMITER
  893.     RZ
  894.     CPI    '>'        ;'>'=DELIMITER
  895. ;
  896.     IF    MULTCMD        ;MULTIPLE COMMANDS ALLOWED?
  897. ;
  898.     RZ
  899.     CPI    CMDSEP        ;COMMAND SEPARATOR
  900. ;
  901.     ENDIF        ;MULTCMD
  902. ;
  903.     RET
  904. ZERO:
  905.     XRA    A    ;SET ZERO FLAG
  906.     RET
  907.  
  908. ;
  909. ; ADVANCE INPUT PTR TO FIRST NON-BLANK AND FALL THROUGH TO SBLANK
  910. ;
  911. ADVAN:
  912.     XCHG        ;START LDED REPLACEMENT
  913.     LHLD    NXTCHR    ;PT TO NEXT CHAR
  914.     XCHG        ;END LDED REPLACEMENT
  915. ;
  916. ; SKIP STRING PTED TO BY DE (STRING ENDS IN 0 OR CMDSEP) UNTIL END OF STRING
  917. ;   OR NON-DELIM ENCOUNTERED (BEGINNING OF TOKEN)
  918. ;
  919. SBLANK:
  920.     LDAX    D    ;GET CHAR
  921.     ORA    A    ;ZERO?
  922.     RZ
  923. ;
  924.     IF    MULTCMD    ;MULTIPLE COMMANDS ALLOWED?
  925. ;
  926.     CPI    CMDSEP    ;COMMAND SEPARATOR?
  927.     RZ
  928. ;
  929.     ENDIF        ;MULTCMD
  930. ;
  931.     CALL    SDELM    ;SKIP OVER DELIMITER
  932.     RNZ
  933.     INX    D    ;ADVANCE TO NEXT CHAR
  934.     JMP    SBLANK
  935. ;
  936. ; ADD A TO HL (HL=HL+A)
  937. ;
  938. ADDAH:
  939.     ADD    L
  940.     MOV    L,A
  941.     RNC
  942.     INR    H
  943.     RET
  944. ;
  945. ; EXTRACT DECIMAL NUMBER FROM COMMAND LINE
  946. ;   RETURN WITH VALUE IN REG A; ALL REGISTERS MAY BE AFFECTED
  947. ;
  948. NUMBER:
  949.     CALL    SCANER        ;PARSE NUMBER AND PLACE IN FCBFN
  950.     LXI    H,FCBFN+10     ;PT TO END OF TOKEN FOR CONVERSION
  951.     MVI    B,11        ;11 CHARS MAX
  952. ;
  953. ; CHECK FOR SUFFIX FOR HEXADECIMAL NUMBER
  954. ;
  955. NUMS:
  956.     MOV    A,M        ;GET CHARS FROM END, SEARCHING FOR SUFFIX
  957.     DCX    H        ;BACK UP
  958.     CPI    ' '        ;SPACE?
  959.     JNZ    NUMS1        ;CHECK FOR SUFFIX
  960.     DCR    B        ;LDIR REPLACEMENT
  961.     JNZ    NUMS        ;COUNT DOWN
  962.     JMP    NUM0        ;BY DEFAULT, PROCESS
  963. NUMS1:
  964.     CPI    NUMBASE        ;CHECK AGAINST BASE SWITCH FLAG
  965.     JZ    HNUM0
  966. ;
  967. ; PROCESS DECIMAL NUMBER
  968. ;
  969. NUM0:
  970.     LXI    H,FCBFN        ;PT TO BEGINNING OF TOKEN
  971. NUM0A:
  972.     LXI    B,1100H        ;C=ACCUMULATED VALUE, B=CHAR COUNT
  973.                 ; (C=0, B=11)
  974. NUM1:
  975.     MOV    A,M        ;GET CHAR
  976.     CPI    ' '        ;DONE IF <SP>
  977.     JZ    NUM2
  978.     CPI    ':'        ;DONE IF COLON
  979.     JZ    NUM2
  980.     INX    H        ;PT TO NEXT CHAR
  981.     SUI    '0'        ;CONVERT TO BINARY (ASCII 0-9 TO BINARY)
  982.     CPI    10        ;ERROR IF >= 10
  983.     JNC    NUMERR
  984.     MOV    D,A        ;DIGIT IN D
  985.     MOV    A,C        ;NEW VALUE = OLD VALUE * 10
  986.     RLC            ;*2
  987.     JC    NUMERR
  988.     RLC            ;*4
  989.     JC    NUMERR
  990.     RLC            ;*8
  991.     JC    NUMERR
  992.     ADD    C        ;*9
  993.     JC    NUMERR
  994.     ADD    C        ;*10
  995.     JC    NUMERR
  996.     ADD    D        ;NEW VALUE = OLD VALUE * 10 + DIGIT
  997.     JC    NUMERR        ;CHECK FOR RANGE ERROR
  998.     MOV    C,A        ;SET NEW VALUE
  999.     DCR    B        ;DJNZ REPLACEMENT
  1000.     JNZ    NUM1        ;COUNT DOWN
  1001. ;
  1002. ; RETURN FROM NUMBER
  1003. ;
  1004. NUM2:
  1005.     MOV    A,C        ;GET ACCUMULATED VALUE
  1006.     RET
  1007. ;
  1008. ; NUMBER ERROR ROUTINE FOR SPACE CONSERVATION
  1009. ;
  1010. NUMERR:
  1011.     JMP    ERROR        ;USE ERROR ROUTINE - THIS IS RELATIVE PT
  1012. ;
  1013. ; EXTRACT HEXADECIMAL NUMBER FROM COMMAND LINE
  1014. ;   RETURN WITH VALUE IN REG A; ALL REGISTERS MAY BE AFFECTED
  1015. ;
  1016. HEXNUM:
  1017.     CALL    SCANER        ;PARSE NUMBER AND PLACE IN FCBFN
  1018. HNUM0:
  1019.     LXI    H,FCBFN        ;PT TO TOKEN FOR CONVERSION
  1020.     LXI    D,0        ;DE=ACCUMULATED VALUE
  1021.     MVI    B,11        ;B=CHAR COUNT
  1022. HNUM1:
  1023.     MOV    A,M        ;GET CHAR
  1024.     CPI    ' '        ;DONE?
  1025.     JZ    HNUM3        ;RETURN IF SO
  1026.     CPI    NUMBASE        ;DONE IF NUMBASE SUFFIX
  1027.     JZ    HNUM3
  1028.     SUI    '0'        ;CONVERT TO BINARY
  1029.     JC    NUMERR        ;RETURN AND DONE IF ERROR
  1030.     CPI    10        ;0-9?
  1031.     JC    HNUM2
  1032.     SUI    7        ;A-F?
  1033.     CPI    10H        ;ERROR?
  1034.     JNC    NUMERR
  1035. HNUM2:
  1036.     INX    H        ;PT TO NEXT CHAR
  1037.     MOV    C,A        ;DIGIT IN C
  1038.     MOV    A,D        ;GET ACCUMULATED VALUE
  1039.     RLC            ;EXCHANGE NYBBLES
  1040.     RLC
  1041.     RLC
  1042.     RLC
  1043.     ANI    0F0H        ;MASK OUT LOW NYBBLE
  1044.     MOV    D,A
  1045.     MOV    A,E        ;SWITCH LOW-ORDER NYBBLES
  1046.     RLC
  1047.     RLC
  1048.     RLC
  1049.     RLC
  1050.     MOV    E,A        ;HIGH NYBBLE OF E=NEW HIGH OF E,
  1051.                 ;  LOW NYBBLE OF E=NEW LOW OF D
  1052.     ANI    0FH        ;GET NEW LOW OF D
  1053.     ORA    D        ;MASK IN HIGH OF D
  1054.     MOV    D,A        ;NEW HIGH BYTE IN D
  1055.     MOV    A,E
  1056.     ANI    0F0H        ;MASK OUT LOW OF E
  1057.     ORA    C        ;MASK IN NEW LOW
  1058.     MOV    E,A        ;NEW LOW BYTE IN E
  1059.     DCR    B        ;DJNZ REPLACEMENT
  1060.     JNZ    HNUM1        ;COUNT DOWN
  1061. ;
  1062. ; RETURN FROM HEXNUM
  1063. ;
  1064. HNUM3:
  1065.     XCHG            ;RETURNED VALUE IN HL
  1066.     MOV    A,L        ;LOW-ORDER BYTE IN A
  1067.     RET
  1068. ;
  1069. ; PT TO DIRECTORY ENTRY IN TBUFF WHOSE OFFSET IS SPECIFIED BY A AND C
  1070. ;
  1071. DIRPTR:
  1072.     LXI    H,TBUFF     ;PT TO TEMP BUFFER
  1073.     ADD    C        ;PT TO 1ST BYTE OF DIR ENTRY
  1074.     CALL    ADDAH        ;PT TO DESIRED BYTE IN DIR ENTRY
  1075.     MOV    A,M        ;GET DESIRED BYTE
  1076.     RET
  1077. ;
  1078. ; CHECK FOR SPECIFIED DRIVE AND LOG IT IN
  1079. ;
  1080. SLOGIN:
  1081.     XRA    A        ;A=0 FOR DEFAULT DISK
  1082.     STA    FCBDN        ;SELECT DEFAULT DISK SINCE USER/DISK
  1083.                 ;  SPECIFICALLY SELECTED BY THIS ROUTINE
  1084. TEMPDR    EQU    $+1        ;POINTER FOR IN-THE-CODE MODIFICATION
  1085.     MVI    A,0        ;2ND BYTE (IMMEDIATE ARG) IS TEMPDR
  1086.     ORA    A        ;0=CURRENT DRIVE
  1087.     JNZ    SLOG1
  1088.     LDA    CURDR        ;LOG IN CURRENT DRIVE
  1089.     INR    A        ;ADD 1 FOR NEXT DCR
  1090. SLOG1:
  1091.     DCR    A        ;ADJUST FOR PROPER DISK NUMBER (A=0)
  1092.     CALL    LOGIN        ;LOG IN NEW DRIVE
  1093. TEMPUSR    EQU    $+1        ;POINTER FOR IN-THE-CODE MODIFICATION
  1094.     MVI    A,0        ;2ND BYTE IS USER TO BE SELECTED
  1095.     JMP    SETUSR        ;LOG IN NEW USER
  1096.  
  1097. ;
  1098. ; CHECK FOR SPECIFIED DRIVE AND LOG IN DEFAULT DRIVE IF SPECIFIED<>DEFAULT
  1099. ;
  1100. DLOGIN:
  1101. CURDR    EQU    $+1        ;POINTER FOR IN-THE-CODE MODIFICATION
  1102.     MVI    A,0        ;PREP TO LOG IN CURRENT DRIVE
  1103.     CALL    LOGIN        ;LOGIN CURRENT DRIVE
  1104. CURUSR    EQU    $+1        ;POINTER FOR IN-THE-CODE MODIFICATION
  1105.     MVI    A,0        ;PREP TO LOG IN CURRENT USER NUMBER
  1106.     JMP    SETUSR        ;LOG IN NEW USER
  1107.  
  1108. ;
  1109. ;  ROUTINE TO CHECK FOR A WHEEL BYTE AS NON-ZERO
  1110. ;    IF WHEEL BYTE IS ZERO, THEN ABORT (POP STACK AND RETURN)
  1111. ;
  1112. ;
  1113.     IF    WHEEL        ;WHEEL FACILITY?
  1114. ;
  1115. WHLCHK:
  1116.     LDA    WHLADR        ;GET WHEEL BYTE
  1117.     ORA    A        ;ZERO?
  1118.     RNZ            ;OK IF NOT
  1119.     JMP    ERROR        ;PROCESS AS ERROR
  1120. ;
  1121.     ENDIF        ;WHEEL
  1122. ;
  1123.  
  1124. ;
  1125. ; EXTRACT TOKEN FROM COMMAND LINE AND PLACE IT INTO FCBDN;
  1126. ;   FORMAT FCBDN FCB IF TOKEN RESEMBLES FILE NAME AND TYPE (FILENAME.TYP);
  1127. ;   ON INPUT, NXTCHR PTS TO CHAR AT WHICH TO START SCAN;
  1128. ;   ON OUTPUT, NXTCHR PTS TO CHAR AT WHICH TO CONTINUE AND ZERO FLAG IS RESET
  1129. ;     IF '?' IS IN TOKEN
  1130. ;
  1131. ; ENTRY POINTS:
  1132. ;    SCANLOG - LOAD TOKEN INTO FIRST FCB AND LOG IN TEMP USER/DISK
  1133. ;    SCANER - LOAD TOKEN INTO FIRST FCB
  1134. ;    SCANX - LOAD TOKEN INTO FCB PTED TO BY HL
  1135. ;
  1136. SCANLOG:
  1137.     CALL    SCANER        ;DO SCAN
  1138.     PUSH    PSW        ;SAVE FLAG
  1139.     CALL    SLOGIN        ;LOG IN TEMPORARY USER/DISK
  1140.     POP    PSW        ;GET FLAG
  1141.     RET
  1142. SCANER:
  1143.     LXI    H,FCBDN     ;POINT TO FCBDN
  1144. SCANX:
  1145.     XRA    A        ;A=0
  1146.     STA    TEMPDR        ;SET TEMPORARY DRIVE NUMBER TO DEFAULT
  1147.     MOV    M,A        ;SET FIRST BYTE OF FCBDN AS DEFAULT DRIVE
  1148.     STA    COLON        ;SET NO COLON FLAG
  1149.     LDA    CURUSR        ;GET CURRENT USER
  1150.     STA    TEMPUSR        ;SET TEMPUSR
  1151.     CALL    ADVAN        ;SKIP TO NON-BLANK OR END OF LINE
  1152.     XCHG            ;START SDED REPLACEMENT
  1153.     SHLD    CURTOK        ;SET PTR TO NON-BLANK OR END OF LINE
  1154.     XCHG            ;END SDED REPLACEMENT
  1155.     MVI    B,11        ;PREP FOR POSSIBLE SPACE FILL
  1156.     JZ    SCAN4        ;DONE IF EOL
  1157. ;
  1158. ;  SCAN TOKEN FOR DU: FORM, WHICH MEANS WE HAVE A USER/DISK SPECIFICATION
  1159. ;    DE PTS TO NEXT CHAR IN LINE, HL PTS TO FCBDN
  1160. ;
  1161.     PUSH    D        ;SAVE PTR TO FIRST CHAR
  1162.     CALL    SDELM        ;CHECK FOR DELIMITER AND GET FIRST CHAR
  1163.     CPI    'A'        ;IN LETTER RANGE?
  1164.     JC    SCAN1
  1165.     CPI    'P'+1        ;IN LETTER RANGE?
  1166.     JC    SCAN1A
  1167. SCAN1:
  1168.     CPI    '0'        ;CHECK FOR DIGIT RANGE
  1169.     JC    SCAN2
  1170.     CPI    '9'+1        ;IN DIGIT RANGE?
  1171.     JNC    SCAN2
  1172. SCAN1A:
  1173.     INX    D        ;PT TO NEXT CHAR
  1174.     CALL    SDELM        ;CHECK FOR DELIMITER; IF NOT, CHECK FOR DIGIT
  1175.     JMP    SCAN1
  1176. SCAN2:
  1177.     POP    D        ;RESTORE PTR TO FIRST CHAR
  1178.     CPI    ':'        ;WAS DELIMITER A COLON?
  1179.     JNZ    SCAN3        ;DONE IF NO COLON
  1180.     STA    COLON        ;SET COLON FOUND
  1181. ;
  1182. ;  SCAN FOR AND EXTRACT USER/DISK INFO
  1183. ;    ON ENTRY, HL PTS TO FCBDN, DE PTS TO FIRST CHAR, AND A CONTAINS FIRST CHAR
  1184. ;
  1185.     LDAX    D        ;GET FIRST CHAR
  1186.     CPI    'A'        ;CONVERT POSSIBLE DRIVE SPEC TO NUMBER
  1187.     JC    SUD1        ;IF LESS THAN 'A', MUST BE DIGIT
  1188. ;
  1189. ;  SET DISK NUMBER (A=1)
  1190. ;
  1191.     SUI    'A'-1        ;CONVERT DRIVE NUMBER TO 1-16
  1192.     CPI    MAXDISK+1    ;WITHIN RANGE?
  1193.     JNC    ERROR        ;INVALID DISK NUMBER
  1194.     STA    TEMPDR        ;SET TEMPORARY DRIVE NUMBER
  1195.     MOV    M,A        ;SET FCBDN
  1196.     INX    D        ;PT TO NEXT CHAR
  1197.     LDAX    D        ;SEE IF IT IS A COLON (:)
  1198.     CPI    ':'
  1199.     JZ    SUD2        ;DONE IF NO USER NUMBER (IT IS A COLON)
  1200. ;
  1201. ;  SET USER NUMBER
  1202. ;
  1203. SUD1:
  1204.     PUSH    H        ;SAVE PTR TO FCBDN
  1205.     XCHG            ;HL PTS TO FIRST DIGIT
  1206.     CALL    NUM0A        ;GET NUMBER
  1207.     XCHG            ;DE PTS TO TERMINATING COLON
  1208.     POP    H        ;GET PTR TO FCBDN
  1209.     CPI    MAXUSR+1    ;WITHIN LIMIT?
  1210.     JNC    ERROR
  1211. ;
  1212.     IF    USERON        ;ALLOW USER CHANGE ONLY IF USER IS ALLOWED
  1213. ;
  1214.     STA    TEMPUSR        ;SAVE USER NUMBER
  1215. ;
  1216.     ENDIF
  1217. ;
  1218. SUD2:
  1219.     INX    D        ;PT TO CHAR AFTER COLON
  1220. ;
  1221. ; EXTRACT FILENAME FROM POSSIBLE FILENAME.TYP
  1222. ;   DE PTS TO NEXT CHAR TO PROCESS, HL PTS TO FCBDN
  1223. ;
  1224. SCAN3:
  1225.     XRA    A        ;A=0
  1226.     STA    QMCNT        ;INIT COUNT OF NUMBER OF QUESTION MARKS IN FCB
  1227.     MVI    B,8        ;MAX OF 8 CHARS IN FILE NAME
  1228.     CALL    SCANF        ;FILL FCB FILE NAME
  1229. ;
  1230. ; EXTRACT FILE TYPE FROM POSSIBLE FILENAME.TYP
  1231. ;
  1232.     MVI    B,3        ;PREPARE TO EXTRACT TYPE
  1233.     LDAX    D        ;GET LAST CHAR WHICH STOPPED SCAN
  1234.     CPI    '.'        ;IF (DE) DELIMITER IS A '.', WE HAVE A TYPE
  1235.     JNZ    SCAN4        ;FILL FILE TYPE BYTES WITH <SP>
  1236.     INX    D        ;PT TO CHAR IN COMMAND LINE AFTER '.'
  1237.     CALL    SCANF        ;FILL FCB FILE TYPE
  1238.     JMP    SCAN5        ;SKIP TO NEXT PROCESSING
  1239. SCAN4:
  1240.     CALL    SCANF4        ;SPACE FILL
  1241. ;
  1242. ; FILL IN EX, S1, S2, AND RC WITH ZEROES
  1243. ;
  1244. SCAN5:
  1245.     MVI    B,4        ;4 BYTES
  1246.     XRA    A        ;A=0
  1247.     CALL    SCANF5        ;FILL WITH ZEROES
  1248. ;
  1249. ; SCAN COMPLETE -- DE PTS TO DELIMITER BYTE AFTER TOKEN
  1250. ;
  1251.     XCHG            ;START SDED REPLACEMENT
  1252.     SHLD    NXTCHR
  1253.     XCHG            ;END SDED REPLACEMENT
  1254. ;
  1255. ; SET ZERO FLAG TO INDICATE PRESENCE OF '?' IN FILENAME.TYP
  1256. ;
  1257. QMCNT    EQU    $+1        ;POINTER FOR IN-THE-CODE MODIFICATION
  1258.     MVI    A,0        ;NUMBER OF QUESTION MARKS
  1259.     ORA    A        ;SET ZERO FLAG TO INDICATE ANY '?'
  1260.     RET
  1261.  
  1262. ;
  1263. ;  SCANF -- SCAN TOKEN PTED TO BY DE FOR A MAX OF B BYTES; PLACE IT INTO
  1264. ;    FILE NAME FIELD PTED TO BY HL; EXPAND AND INTERPRET WILD CARDS OF
  1265. ;    '*' AND '?'; ON EXIT, DE PTS TO TERMINATING DELIMITER
  1266. ;
  1267. SCANF:
  1268.     CALL    SDELM        ;DONE IF DELIMITER ENCOUNTERED - <SP> FILL
  1269.     JZ    SCANF4
  1270.     INX    H        ;PT TO NEXT BYTE IN FCBDN
  1271.     CPI    '*'        ;IS (DE) A WILD CARD?
  1272.     JNZ    SCANF1        ;CONTINUE IF NOT
  1273.     MVI    M,'?'        ;PLACE '?' IN FCB AND DON'T ADVANCE DE IF SO
  1274.     CALL    SCQ        ;SCANNER COUNT QUESTION MARKS
  1275.     JMP    SCANF2
  1276. SCANF1:
  1277.     MOV    M,A        ;STORE FILENAME CHAR IN FCB
  1278.     INX    D        ;PT TO NEXT CHAR IN COMMAND LINE
  1279.     CPI    '?'        ;CHECK FOR QUESTION MARK (WILD)
  1280.     CZ    SCQ        ;SCANNER COUNT QUESTION MARKS
  1281. SCANF2:
  1282.     DCR    B        ;DJNZ REPLACEMENT
  1283.     JNZ    SCANF        ;DECREMENT CHAR COUNT UNTIL 8 ELAPSED
  1284. SCANF3:
  1285.     CALL    SDELM        ;8 CHARS OR MORE - SKIP UNTIL DELIMITER
  1286.     RZ            ;ZERO FLAG SET IF DELIMITER FOUND
  1287.     INX    D        ;PT TO NEXT CHAR IN COMMAND LINE
  1288.     JMP    SCANF3
  1289. ;
  1290. ;  FILL MEMORY POINTED TO BY HL WITH SPACES FOR B BYTES
  1291. ;
  1292. SCANF4:
  1293.     MVI    A,' '        ;<SP> FILL
  1294. SCANF5:
  1295.     INX    H        ;PT TO NEXT BYTE IN FCB
  1296.     MOV    M,A        ;FILL WITH BYTE IN A
  1297.     DCR    B        ;DJN REPLACEMENT
  1298.     JNZ    SCANF5
  1299.     RET
  1300. ;
  1301. ;  INCREMENT QUESTION MARK COUNT FOR SCANNER
  1302. ;    THIS ROUTINE INCREMENTS THE COUNT OF THE NUMBER OF QUESTION MARKS IN
  1303. ;    THE CURRENT FCB ENTRY
  1304. ;
  1305. SCQ:
  1306.     PUSH    H        ;SAVE HL
  1307.     LXI    H,QMCNT        ;GET COUNT
  1308.     INR    M        ;INCREMENT
  1309.     POP    H        ;GET HL
  1310.     RET
  1311. ;
  1312. ; CMDTBL (COMMAND TABLE) SCANNER
  1313. ;   ON RETURN, HL PTS TO ADDRESS OF COMMAND IF CPR-RESIDENT
  1314. ;   ON RETURN, ZERO FLAG SET MEANS CPR-RESIDENT COMMAND
  1315. ;
  1316. CMDSER:
  1317.     LXI    H,CMDTBL    ;PT TO COMMAND TABLE
  1318.     MVI    C,NCMNDS    ;SET COMMAND COUNTER
  1319.     MOV    A,C        ;CHECK NUMBER OF COMMANDS
  1320.     ORA    A        ;IF NONE, THEN ABORT
  1321.     JZ    CMS5
  1322. CMS1:
  1323.     LXI    D,FCBFN     ;PT TO STORED COMMAND NAME
  1324.     MVI    B,NCHARS    ;NUMBER OF CHARS/COMMAND (8 MAX)
  1325. CMS2:
  1326.     LDAX    D        ;COMPARE AGAINST TABLE ENTRY
  1327.     CMP    M
  1328.     JNZ    CMS3        ;NO MATCH
  1329.     INX    D        ;PT TO NEXT CHAR
  1330.     INX    H
  1331.     DCR    B        ;DJNZ REPLACEMENT
  1332.     JNZ    CMS2        ;COUNT DOWN
  1333.     LDAX    D        ;NEXT CHAR IN INPUT COMMAND MUST BE <SP>
  1334.     CPI    ' '
  1335.     JNZ    CMS4
  1336.     RET            ;COMMAND IS CPR-RESIDENT (ZERO FLAG SET)
  1337. CMS3:
  1338.     INX    H        ;SKIP TO NEXT COMMAND TABLE ENTRY
  1339.     DCR    B        ;DJNZ REPLACEMENT
  1340.     JNZ    CMS3
  1341. CMS4:
  1342.     INX    H        ;SKIP ADDRESS
  1343.     INX    H
  1344.     DCR    C        ;DECREMENT TABLE ENTRY NUMBER
  1345.     JNZ    CMS1
  1346. CMS5:
  1347.     INR    C        ;CLEAR ZERO FLAG
  1348.     RET            ;COMMAND IS DISK-RESIDENT (ZERO FLAG CLEAR)
  1349. ;
  1350. ;**** Section 5 ****
  1351. ; CPR-Resident Commands
  1352. ;
  1353. ;
  1354. ;Section 5A
  1355. ;Command: DIR
  1356. ;Function:  To display a directory of the files on disk
  1357. ;Forms:
  1358. ;    DIR <afn>    Displays the DIR files
  1359. ;    DIR <afn> S    Displays the SYS files
  1360. ;    DIR <afn> A    Display both DIR and SYS files
  1361. ;Notes:
  1362. ;    The flag SYSFLG defines the letter used to display both DIR and
  1363. ;        SYS files (A in the above Forms section)
  1364. ;    The flag SOFLG defines the letter used to display only the SYS
  1365. ;        files (S in the above Forms section)
  1366. ;    The flag WIDE determines if the file names are spaced further
  1367. ;        apart (WIDE=TRUE) for 80-col screens
  1368. ;    The flag FENCE defines the character used to separate the file
  1369. ;        names
  1370. ;
  1371.     IF    DIRON        ;DIR ENABLED
  1372. ;
  1373. DIR:
  1374.     CALL    SCANLOG        ;EXTRACT POSSIBLE D:FILENAME.TYP TOKEN AND LOG
  1375.     LXI    H,FCBFN     ;MAKE FCB WILD (ALL '?') IF NO FILENAME.TYP
  1376.     MOV    A,M        ;GET FIRST CHAR OF FILENAME.TYP
  1377.     CPI    ' '        ;IF <SP>, ALL WILD
  1378.     CZ    FILLQ
  1379.     CALL    ADVAN        ;LOOK AT NEXT INPUT CHAR
  1380.     MVI    B,80H        ;PREPARE FOR DIR-ONLY SELECTION
  1381.     JZ    DIRDN        ;THERE IS NO FLAG, SO DIR ONLY
  1382.     MVI    B,1        ;SET FOR BOTH DIR AND SYS FILES
  1383.     CPI    SYSFLG        ;SYSTEM AND DIR FLAG SPECIFIER?
  1384.     JZ    GOTFLG        ;GOT SYSTEM SPECIFIER
  1385.     CPI    SOFLG        ;SYS ONLY?
  1386.     JNZ    DIRDN
  1387.     DCR    B        ;B=0 FOR SYS FILES ONLY
  1388. GOTFLG:
  1389.     INX    D        ;PT TO CHAR AFTER FLAG
  1390. DIRDN:
  1391.     XCHG            ;START SDED REPLACEMENT
  1392.     SHLD    NXTCHR        ;SET PTR FOR NEXT PASS
  1393.     XCHG            ;END SDED REPLACEMENT
  1394.                 ;DROP INTO DIRPR TO PRINT DIRECTORY
  1395.                 ; THEN RESTART CPR
  1396. ;
  1397.     ENDIF            ;DIRON
  1398. ;
  1399. ; DIRECTORY PRINT ROUTINE; ON ENTRY, B REG IS SET AS FOLLOWS:
  1400. ;    0 FOR ONLY SYSTEM FILES, 80H FOR ONLY DIR FILES, 1 FOR BOTH
  1401. ;
  1402.     IF    DIRON OR ERAON
  1403. ;
  1404. DIRPR:
  1405.     MOV    A,B        ;GET FLAG
  1406.     STA    SYSTST        ;SET SYSTEM TEST FLAG
  1407.     MVI    E,0        ;SET COLUMN COUNTER TO ZERO
  1408.     PUSH    D        ;SAVE COLUMN COUNTER (E)
  1409.     CALL    SEARF        ;SEARCH FOR SPECIFIED FILE (FIRST OCCURRANCE)
  1410.     JNZ    DIR3
  1411.     CALL    PRNNF        ;PRINT NO FILE MSG; REG A NOT CHANGED
  1412.     XRA    A        ;SET ZERO FLAG
  1413.     POP    D        ;RESTORE DE
  1414.     RET
  1415. ;
  1416. ; ENTRY SELECTION LOOP; ON ENTRY, A=OFFSET FROM SEARF OR SEARN
  1417. ;
  1418. DIR3:
  1419.     CALL    GETSBIT        ;GET AND TEST FOR TYPE OF FILES
  1420.     JZ    DIR6
  1421.     POP    D        ;GET ENTRY COUNT (=<CR> COUNTER)
  1422.     MOV    A,E        ;ADD 1 TO IT
  1423.     INR    E
  1424.     PUSH    D        ;SAVE IT
  1425.     ANI    03H        ;OUTPUT <CRLF> IF 4 ENTRIES PRINTED IN LINE
  1426.     JNZ    DIR4
  1427.     CALL    CRLF        ;NEW LINE
  1428.     JMP    DIR5
  1429. DIR4:
  1430.     CALL    PRINT
  1431. ;
  1432.     IF    WIDE
  1433. ;
  1434.     DB    '  '        ;2 SPACES
  1435.     DB    FENCE        ;THEN FENCE CHAR
  1436.     DB    ' ',' '+80H    ;THEN 2 MORE SPACES
  1437. ;
  1438.     ELSE
  1439. ;
  1440.     DB    ' '        ;SPACE
  1441.     DB    FENCE        ;THEN FENCE CHAR
  1442.     DB    ' '+80H        ;THEN SPACE
  1443. ;
  1444.     ENDIF            ;WIDE
  1445. ;
  1446. DIR5:
  1447.     MVI    B,01H        ;PT TO 1ST BYTE OF FILE NAME
  1448.     MOV    A,B        ;A=OFFSET
  1449.     CALL    DIRPTR        ;HL NOW PTS TO 1ST BYTE OF FILE NAME
  1450.     CALL    PRFN        ;PRINT FILE NAME
  1451. DIR6:
  1452.     CALL    BREAK        ;CHECK FOR ABORT
  1453.     JZ    DIR7
  1454.     CALL    SEARN        ;SEARCH FOR NEXT FILE
  1455.     JNZ    DIR3        ;CONTINUE IF FILE FOUND
  1456. DIR7:
  1457.     POP    D        ;RESTORE STACK
  1458.     MVI    A,0FFH        ;SET NZ FLAG
  1459.     ORA    A
  1460.     RET
  1461. ;
  1462.     ENDIF            ;DIRON OR ERAON
  1463. ;
  1464. ;  PRINT FILE NAME PTED TO BY HL
  1465. ;
  1466. PRFN:
  1467.     MVI    B,8    ;8 CHARS
  1468.     CALL    PRFN1
  1469.     MVI    A,'.'    ;DOT
  1470.     CALL    CONOUT
  1471.     MVI    B,3    ;3 CHARS
  1472. PRFN1:
  1473.     MOV    A,M    ; GET CHAR
  1474.     INX    H    ; PT TO NEXT
  1475.     CALL    CONOUT    ; PRINT CHAR
  1476.     DCR    B    ; COUNT DOWN
  1477.     JNZ    PRFN1
  1478.     RET
  1479. ;
  1480. ; AFTER A SEARCH, RETURN NZ SET IF DESIRED TYPE OF FILE FOUND, Z IF NOT
  1481. ;   THIS ALGORITHM LOOKS AT THE SYSTEM BIT OF THE LOCATED FILE; THIS
  1482. ;   BIT IS SET TO 1 IF THE FILE IS A SYSTEM FILE AND 0 IF NOT A SYSTEM
  1483. ;   FILE.  THE FOLLOWING EXCLUSIVE OR MASKS ARE APPLIED TO RETURN Z OR NZ
  1484. ;   AS REQUIRED BY THE CALLING PROGRAM:
  1485. ;
  1486. ;    SYSTEM BYTE: X 0 0 0  0 0 0 0   (AFTER 80H MASK, X=1 IF SYS, 0 IF DIR)
  1487. ;
  1488. ;    SYS-ONLY   : 0 0 0 0  0 0 0 0   (XOR 0 = 0 if X=0, = 80H if X=1)
  1489. ;    DIR-ONLY   : 1 0 0 0  0 0 0 0   (XOR 80H = 80h if X=0, = 0 if X=1)
  1490. ;    BOTH       : 0 0 0 0  0 0 0 1   (XOR 1 = 81H or 1H, NZ in both cases)
  1491. ;
  1492. GETSBIT:
  1493.     DCR    A        ;ADJUST TO RETURNED VALUE
  1494.     RRC            ;CONVERT NUMBER TO OFFSET INTO TBUFF
  1495.     RRC
  1496.     RRC
  1497.     ANI    60H
  1498.     MOV    C,A        ;OFFSET INTO TBUFF IN C (C=OFFSET TO ENTRY)
  1499.     MVI    A,10        ;ADD 10 TO PT TO SYSTEM FILE ATTRIBUTE BIT
  1500.     CALL    DIRPTR        ;A=SYSTEM BYTE
  1501.     ANI    80H        ;LOOK AT ONLY SYSTEM BIT
  1502. SYSTST    EQU    $+1        ;IN-THE-CODE VARIABLE
  1503.     XRI    0        ; IF SYSTST=0, SYS ONLY; IF SYSTST=80H, DIR
  1504.                 ; ONLY; IF SYSTST=1, BOTH SYS AND DIR
  1505.     RET            ;NZ IF OK, Z IF NOT OK
  1506. ;
  1507. ; FILL FCB @HL WITH '?'
  1508. ;
  1509. FILLQ:
  1510.     MVI    B,11        ;NUMBER OF CHARS IN FN & FT
  1511. FQLP:
  1512.     MVI    M,'?'        ;STORE '?'
  1513.     INX    H
  1514.     DCR    B        ;DJNZ REPLACEMENT
  1515.     JNZ    FQLP
  1516.     RET
  1517. ;
  1518. ;Section 5B
  1519. ;Command: ERA
  1520. ;Function:  Erase files
  1521. ;Forms:
  1522. ;    ERA <afn>    Erase Specified files and print their names
  1523. ;    ERA <afn> V    Erase Specified files and print their names, but ask
  1524. ;                for verification before Erase is done
  1525. ;Notes:
  1526. ;    Several Key Flags affect this command:
  1527. ;        ERAV - If TRUE, the V option is enabled, and the character
  1528. ;            which turns it on (the V) is defined by ERDFLG
  1529. ;        ERAOK - If TRUE, the OK? prompt is enabled
  1530. ;    If ERAOK is FALSE, the verification feature is disabled regardless
  1531. ;        of what value ERAV has
  1532. ;    If ERAOK is TRUE, then:
  1533. ;        If ERAV is TRUE, verification is requested only if the V
  1534. ;            flag (actual letter defined by ERDFLG) is in the
  1535. ;            command line
  1536. ;        If ERAV is FALSE, verification is always requested, and a
  1537. ;            V flag in the command line will cause an error
  1538. ;            message to be printed (V?) after the ERA is completed
  1539. ;
  1540.     IF    ERAON        ;ERA ENABLED?
  1541. ;
  1542. ERA:
  1543. ;
  1544.     IF    WERA        ;WHEEL FACILITY ENABLED?
  1545. ;
  1546.     CALL    WHLCHK        ;CHECK FOR IT
  1547. ;
  1548.     ENDIF        ;WERA
  1549. ;
  1550.     CALL    SCANLOG        ;PARSE FILE SPECIFICATION AND LOG IN USER/DISK
  1551. ;
  1552.     IF    ERAV AND ERAOK    ;V FLAG AND OK? ENABLED?
  1553. ;
  1554.     CALL    ADVAN        ;GET ERAFLG IF IT'S THERE
  1555.     STA    ERAFLG        ;SAVE IT AS A FLAG
  1556.     JZ    ERA1        ;JUMP IF INPUT ENDED
  1557.     INX    D        ;PUT NEW BUF POINTER
  1558. ERA1:
  1559.     XCHG            ;PUT PTR IN HL
  1560.     SHLD    NXTCHR        ;SET PTR TO BYTE FOR NEXT COMMAND PROCESSING
  1561. ;
  1562.     ENDIF            ;ERAV
  1563. ;
  1564.     MVI    B,1        ;DISPLAY ALL MATCHING FILES
  1565.     CALL    DIRPR        ;PRINT DIRECTORY OF ERASED FILES
  1566.     RZ            ;ABORT IF NO FILES
  1567. ;
  1568.     IF    ERAOK        ;PRINT PROMPT
  1569. ;
  1570.     IF    ERAV        ;TEST VERIFY FLAG
  1571. ;
  1572. ERAFLG    EQU    $+1        ;ADDRESS OF FLAG
  1573.     MVI    A,0        ;2ND BYTE IS FLAG
  1574.     CPI    ERDFLG        ;IS IT A VERIFY OPTION?
  1575.     JNZ    ERA2        ;SKIP PROMPT IF IT IS NOT
  1576. ;
  1577.     ENDIF            ;ERAV
  1578. ;
  1579.     CALL    PRINTC
  1580.     DB    'OK to Erase','?'+80H
  1581.     CALL    CONIN        ;GET REPLY
  1582.     CPI    'Y'        ;YES?
  1583.     RNZ            ;ABORT IF NOT
  1584. ;
  1585.     ENDIF            ;ERAOK
  1586. ;
  1587. ERA2:
  1588.     LXI    D,FCBDN     ;DELETE FILE SPECIFIED
  1589.     CALL    DELETE
  1590.     RET            ;REENTER CPR
  1591. ;
  1592.     ENDIF            ;ERAON
  1593. ;
  1594. ;Section 5C
  1595. ;Command: LIST
  1596. ;Function:  Print out specified file on the LST: Device
  1597. ;Forms:
  1598. ;    LIST <ufn>    Print file (NO Paging)
  1599. ;Notes:
  1600. ;    The flags which apply to TYPE do not take effect with LIST
  1601. ;
  1602.     IF    LTON        ;LIST AND TYPE ENABLED?
  1603. ;
  1604. LIST:
  1605.     MVI    A,0FFH        ;TURN ON PRINTER FLAG
  1606.     JMP    TYPE0
  1607. ;
  1608. ;Section 5D
  1609. ;Command: TYPE
  1610. ;Function:  Print out specified file on the CON: Device
  1611. ;Forms:
  1612. ;    TYPE <ufn>    Print file
  1613. ;    TYPE <ufn> P    Print file with paging flag    
  1614. ;Notes:
  1615. ;    The flag PGDFLG defines the letter which toggles the paging
  1616. ;        facility (P in the forms section above)
  1617. ;    The flag PGDFLT determines if TYPE is to page by default
  1618. ;        (PGDFLT=TRUE if TYPE pages by default); combined with
  1619. ;        PGDFLG, the following events occur --
  1620. ;            If PGDFLT = TRUE, PGDFLG turns OFF paging
  1621. ;            If PGDFLT = FALSE, PGDFLG turns ON paging
  1622. ;
  1623. TYPE:
  1624.     XRA    A        ;TURN OFF PRINTER FLAG
  1625. ;
  1626. ; ENTRY POINT FOR CPR LIST FUNCTION (LIST)
  1627. ;
  1628. TYPE0:
  1629.     STA    PRFLG        ;SET FLAG
  1630. ;
  1631.     IF    WLT    ;WHEEL ON?
  1632. ;
  1633.     CALL    WHLCHK        ;CHECK WHEEL BYTE
  1634. ;
  1635.     ENDIF        ;WLT
  1636. ;
  1637.     CALL    SCANLOG        ;EXTRACT FILENAME.TYP TOKEN AND LOG USER/DISK
  1638.     JNZ    ERROR        ;ERROR IF ANY QUESTION MARKS
  1639.     CALL    ADVAN        ;GET PGDFLG IF IT'S THERE
  1640.     STA    PGFLG        ;SAVE IT AS A FLAG
  1641.     JZ    TYPE1        ;JUMP IF INPUT ENDED
  1642.     INX    D        ;PUT NEW BUF POINTER
  1643. TYPE1:
  1644.     XCHG            ;START SDED REPLACEMENT
  1645.     SHLD    NXTCHR        ;SET PTR TO BYTE FOR NEXT COMMAND PROCESSING
  1646.     XCHG            ;END SDED REPLACEMENT
  1647.     CALL    OPENF        ;OPEN SELECTED FILE
  1648.     JZ    ERROR        ;ABORT IF ERROR
  1649.     CALL    CRLF        ;NEW LINE
  1650.     MVI    A,NLINES-1    ;SET LINE COUNT
  1651.     STA    PAGCNT
  1652.     LXI    B,080H        ;SET CHAR POSITION AND TAB COUNT
  1653.                 ;  (B=0=TAB, C=080H=CHAR POSITION)
  1654. ;
  1655. ;  MAIN LOOP FOR LOADING NEXT BLOCK
  1656. ;
  1657. TYPE2:
  1658.     MOV    A,C        ;GET CHAR COUNT
  1659.     CPI    80H
  1660.     JC    TYPE3
  1661.     PUSH    H        ;READ NEXT BLOCK
  1662.     PUSH    B
  1663.     CALL    READF
  1664.     POP    B
  1665.     POP    H
  1666.     JNZ    TYPE7        ;ERROR?
  1667.     MVI    C,0        ;SET CHAR COUNT
  1668.     LXI    H,TBUFF        ;PT TO FIRST CHAR
  1669. ;
  1670. ;  MAIN LOOP FOR PRINTING CHARS IN TBUFF
  1671. ;
  1672. TYPE3:
  1673.     MOV    A,M        ;GET NEXT CHAR
  1674.     ANI    7FH        ;MASK OUT MSB
  1675.     CPI    1AH        ;END OF FILE (^Z)?
  1676.     RZ            ;RESTART CPR IF SO
  1677. ;
  1678. ; OUTPUT CHAR TO CON: OR LST: DEVICE WITH TABULATION
  1679. ;
  1680.     CPI    CR        ;RESET TAB COUNT?
  1681.     JZ    TYPE4
  1682.     CPI    LF        ;RESET TAB COUNT?
  1683.     JZ    TYPE4
  1684.     CPI    TAB        ;TAB?
  1685.     JZ    TYPE5
  1686. ;
  1687. ;  OUTPUT CHAR AND INCREMENT CHAR COUNT
  1688. ;
  1689.     CALL    LCOUT        ;OUTPUT CHAR
  1690.     INR    B        ;INCREMENT TAB COUNT
  1691.     JMP    TYPE6
  1692. ;
  1693. ;  OUTPUT <CR> OR <LF> AND RESET TAB COUNT
  1694. ;
  1695. TYPE4:
  1696.     CALL    LCOUT        ;OUTPUT <CR> OR <LF>
  1697.     MVI    B,0        ;RESET TAB COUNTER
  1698.     JMP    TYPE6
  1699. ;
  1700. ;  TABULATE
  1701. ;
  1702. TYPE5:
  1703.     MVI    A,' '        ;<SP>
  1704.     CALL    LCOUT
  1705.     INR    B        ;INCR POS COUNT
  1706.     MOV    A,B
  1707.     ANI    7
  1708.     JNZ    TYPE5
  1709. ;
  1710. ; CONTINUE PROCESSING
  1711. ;
  1712. TYPE6:
  1713.     INR    C        ;INCREMENT CHAR COUNT
  1714.     INX    H        ;PT TO NEXT CHAR
  1715.     CALL    BREAK        ;CHECK FOR ABORT
  1716.     RZ            ;RESTART IF SO
  1717.     JMP    TYPE2
  1718. TYPE7:
  1719.     DCR    A        ;NO ERROR?
  1720.     RZ            ;RESTART CPR
  1721.     JMP    ERROR
  1722. ;
  1723.     ENDIF            ;LTON
  1724. ;
  1725. ;Section 5E
  1726. ;Command: SAVE
  1727. ;Function:  To save the contents of the TPA onto disk as a file
  1728. ;Forms:
  1729. ;    SAVE <Number of Pages> <ufn>
  1730. ;                Save specified number of pages (start at 100H)
  1731. ;                from TPA into specified file; <Number of
  1732. ;                Pages> is in DCR
  1733. ;    SAVE <Number of Sectors> <ufn> S
  1734. ;                Like SAVE above, but numeric argument specifies
  1735. ;                number of sectors rather than pages
  1736. ;Notes:
  1737. ;    The MULTCMD flag (Multiple Commands Allowed) expands the code slightly,
  1738. ;        but is required to support multiple commands with SAVE
  1739. ;    The SECTFLG defines the letter which indicates a sector count
  1740. ;        (S in the Forms section above)
  1741. ;
  1742.     IF    SAVEON        ;SAVE ENABLED?
  1743. ;
  1744. SAVE:
  1745. ;
  1746.     IF    WSAVE    ;WHEEL FACILITY?
  1747. ;
  1748.     CALL    WHLCHK        ;CHECK FOR WHEEL BYTE
  1749. ;
  1750.     ENDIF        ;WSAVE
  1751. ;
  1752.     CALL    NUMBER        ;EXTRACT NUMBER FROM COMMAND LINE
  1753.     MOV    L,A        ;HL=PAGE COUNT
  1754.     MVI    H,0
  1755.     PUSH    H        ;SAVE PAGE COUNT
  1756.     CALL    EXTEST        ;TEST FOR EXISTENCE OF FILE AND ABORT IF SO
  1757.     MVI    C,16H        ;BDOS MAKE FILE
  1758.     CALL    GRBDOS
  1759.     POP    H        ;GET PAGE COUNT
  1760.     JZ    SAVE3        ;ERROR?
  1761.     XRA    A        ;SET RECORD COUNT FIELD OF NEW FILE'S FCB
  1762.     STA    FCBCR
  1763.     CALL    ADVAN        ;LOOK FOR 'S' FOR SECTOR OPTION
  1764.     INX    D        ;PT TO AFTER 'S' TOKEN
  1765.     CPI    SECTFLG
  1766.     JZ    SAVE0
  1767.     DCX    D        ;NO 'S' TOKEN, SO BACK UP
  1768.     DAD    H        ;DOUBLE IT FOR HL=SECTOR (128 BYTES) COUNT
  1769. SAVE0:
  1770.     XCHG            ;START SDED REPLACEMENT
  1771.     SHLD    NXTCHR        ;SET PTR TO BAD TOKEN OR AFTER GOOD TOKEN
  1772.     XCHG            ;END SDED REPLACEMENT
  1773.     LXI    D,TPA        ;PT TO START OF SAVE AREA (TPA)
  1774. SAVE1:
  1775.     MOV    A,H        ;DONE WITH SAVE?
  1776.     ORA    L        ;HL=0 IF SO
  1777.     JZ    SAVE2
  1778.     DCX    H        ;COUNT DOWN ON SECTORS
  1779.     PUSH    H        ;SAVE PTR TO BLOCK TO SAVE
  1780.     LXI    H,128        ;128 BYTES PER SECTOR
  1781.     DAD    D        ;PT TO NEXT SECTOR
  1782.     PUSH    H        ;SAVE ON STACK
  1783.     CALL    DMASET        ;SET DMA ADDRESS FOR WRITE (ADDRESS IN DE)
  1784.     LXI    D,FCBDN     ;WRITE SECTOR
  1785.     MVI    C,15H        ;BDOS WRITE SECTOR
  1786.     CALL    BDOSB        ;SAVE BC
  1787.     POP    D        ;GET PTR TO NEXT SECTOR IN DE
  1788.     POP    H        ;GET SECTOR COUNT
  1789.     JNZ    SAVE3        ;WRITE ERROR?
  1790.     JMP    SAVE1        ;CONTINUE
  1791. SAVE2:
  1792.     LXI    D,FCBDN     ;CLOSE SAVED FILE
  1793.     CALL    CLOSE
  1794.     INR    A        ;ERROR?
  1795.     JNZ    SAVE4
  1796. SAVE3:
  1797.     CALL    PRNLE        ;PRINT 'NO SPACE' ERROR
  1798. SAVE4:
  1799.     JMP    DEFDMA        ;SET DMA TO 0080 AND RESTART CPR
  1800. ;
  1801.     ENDIF            ;SAVEON
  1802. ;
  1803. ; Test File in FCB for existence, ask user to delete if so, and abort if he
  1804. ;  choses not to
  1805. ;
  1806.     IF    SAVEON OR RENON    ;FOR SAVE AND REN FUNCTIONS
  1807. ;
  1808. EXTEST:
  1809.     CALL    SCANLOG        ;EXTRACT FILE NAME AND LOG IN USER/DISK
  1810.     JNZ    ERROR        ;'?' IS NOT PERMITTED
  1811.     CALL    SEARF        ;LOOK FOR SPECIFIED FILE
  1812.     LXI    D,FCBDN        ;PT TO FILE FCB
  1813.     RZ            ;OK IF NOT FOUND
  1814.     PUSH    D        ;SAVE PTR TO FCB
  1815.     CALL    PRINTC
  1816.     DB    'Erase',' '+80H
  1817.     LXI    H,FCBFN        ;PT TO FILE NAME FIELD
  1818.     CALL    PRFN        ;PRINT IT
  1819.     MVI    A,'?'        ;PRINT QUESTION
  1820.     CALL    CONOUT
  1821.     CALL    CONIN        ;GET RESPONSE
  1822.     POP    D        ;GET PTR TO FCB
  1823.     CPI    'Y'        ;KEY ON YES
  1824.     JNZ    ERR3        ;RESTART AS ERROR IF NO
  1825.     PUSH    D        ;SAVE PTR TO FCB
  1826.     CALL    DELETE        ;DELETE FILE
  1827.     POP    D        ;GET PTR TO FCB
  1828.     RET
  1829. ;
  1830.     ENDIF            ;SAVEON OR RENON
  1831. ;
  1832. ;Section 5F
  1833. ;Command: REN
  1834. ;Function:  To change the name of an existing file
  1835. ;Forms:
  1836. ;    REN <New ufn>=<Old ufn>    Perform function
  1837. ;
  1838.     IF    RENON        ;REN ENABLED?
  1839. ;
  1840. REN:
  1841. ;
  1842.     IF    WREN        ;WHEEL FACILITY?
  1843. ;
  1844.     CALL    WHLCHK        ;CHECK FOR WHEEL BYTE
  1845. ;
  1846.     ENDIF        ;WREN
  1847. ;
  1848.     CALL    EXTEST        ;TEST FOR FILE EXISTENCE AND RETURN
  1849.                 ; IF FILE DOESN'T EXIST; ABORT IF IT DOES
  1850.     LDA    TEMPDR        ;SAVE SELECTED DISK
  1851.     PUSH    PSW        ;SAVE ON STACK
  1852. REN0:
  1853.     LXI    H,FCBDN     ;SAVE NEW FILE NAME
  1854.     LXI    D,FCBDM
  1855.     LXI    B,16        ;16 BYTES
  1856.     CALL    LDIRSB        ;LDIR REPLACEMENT SUBROUTINE
  1857.     CALL    ADVAN        ;ADVANCE TO NEXT CHARACTER (NON-DELIM)
  1858.     JZ    REN4        ;ERROR IF NONE
  1859. ;
  1860. ;  PERFORM RENAME FUNCTION
  1861. ;
  1862. REN1:
  1863.     XCHG            ;START SDED REPLACMENT
  1864.     SHLD    NXTCHR        ;SAVE PTR TO OLD FILE NAME
  1865.     XCHG            ;END SDED REPLACEMENT
  1866.     CALL    SCANER        ;EXTRACT FILENAME.TYP TOKEN
  1867.     JNZ    REN4        ;ERROR IF ANY '?'
  1868.     POP    PSW        ;GET OLD DEFAULT DRIVE
  1869.     MOV    B,A        ;SAVE IT
  1870.     LXI    H,TEMPDR    ;COMPARE IT AGAINST SELECTED DRIVE
  1871.     MOV    A,M        ;DEFAULT?
  1872.     ORA    A
  1873.     JZ    REN2
  1874.     CMP    B        ;CHECK FOR DRIVE ERROR (LIKE REN A:T=B:S)
  1875.     JNZ    REN4
  1876. REN2:
  1877.     MOV    M,B
  1878.     XRA    A
  1879.     STA    FCBDN        ;SET DEFAULT DRIVE
  1880.     LXI    D,FCBDN     ;RENAME FILE
  1881.     MVI    C,17H        ;BDOS RENAME FCT
  1882.     CALL    GRBDOS
  1883.     RNZ
  1884. REN3:
  1885.     CALL    PRNNF        ;PRINT NO FILE MSG
  1886. REN4:
  1887.     JMP    ERROR
  1888. ;
  1889.     ENDIF            ;RENON
  1890. ;
  1891. RSTJMP:
  1892.     JMP    RCPRNL        ;RESTART CPR
  1893. ;
  1894. ;Section 5G
  1895. ;Command: JUMP
  1896. ;Function:  To Call the program (subroutine) at the specified address
  1897. ;         without loading from disk
  1898. ;Forms:
  1899. ;    JUMP <adr>        Call at <adr>;<adr> is in HEX
  1900. ;
  1901.     IF    JUMPON        ;JUMP ENABLED?
  1902. ;
  1903. JUMP:
  1904. ;
  1905.     IF    WJUMP    ;WHEEL FACILITY?
  1906. ;
  1907.     CALL    WHLCHK        ;CHECK FOR WHEEL BYTE
  1908. ;
  1909.     ENDIF        ;WJUMP
  1910. ;
  1911.     CALL    HEXNUM        ;GET LOAD ADDRESS IN HL
  1912.     JMP    CALLPROG    ;PERFORM CALL
  1913. ;
  1914.     ENDIF            ;JUMPON
  1915. ;
  1916. ;Section 5H
  1917. ;Command: GO
  1918. ;Function:  To Call the program in the TPA without loading
  1919. ;         loading from disk. Same as JUMP 100H, but much
  1920. ;         more convenient, especially when used with
  1921. ;         parameters for programs like STAT. Also can be
  1922. ;         allowed on remote-access systems with no problems.
  1923. ;
  1924. ;Form:
  1925. ;    GO <parameters like for COMMAND>
  1926. ;
  1927.     IF    GOON        ;GO ENABLED?
  1928. ;
  1929. GO:
  1930. ;
  1931.     IF    WGO    ;WHEEL FACILITY?
  1932. ;
  1933.     CALL    WHLCHK        ;CHECK FOR WHEEL BYTE
  1934. ;
  1935.     ENDIF        ;WGO
  1936. ;
  1937.     LXI    H,TPA        ;Always to TPA
  1938.     JMP    CALLPROG    ;Perform call
  1939. ;
  1940.     ENDIF            ;GOON
  1941. ;
  1942. ;Section 5I
  1943. ;Command: COM file processing
  1944. ;Function:  To load the specified COM file from disk and execute it
  1945. ;Forms:  <command line>
  1946. ;Notes:
  1947. ;    COM files are processed as follows --
  1948. ;        1. File name buffers are initialized and a preliminary
  1949. ;            error check is done
  1950. ;        2. MLOAD is used to search for the file along the Path
  1951. ;            and load it into the TPA
  1952. ;        3. CALLPROG is used to set up the buffers to be used by
  1953. ;            the transient (FCB at 5CH, FCB at 6CH, BUFF at 80H)
  1954. ;            and run the program
  1955. ;    The flag MULTCMD comes into play frequently here; it mainly serves
  1956. ;        to save space if MULTCMD is FALSE and enables Multiple
  1957. ;        Commands on the same line if MULTCMD is TRUE
  1958. ;
  1959. COM:
  1960.     LDA    FCBFN        ;ANY COMMAND?
  1961.     CPI    ' '        ;' ' MEANS COMMAND WAS 'D:' TO SWITCH
  1962.     JNZ    COM1        ;NOT <SP>, SO MUST BE TRANSIENT OR ERROR
  1963. ;
  1964. ;  ENTRY POINT TO SELECT USER/DISK
  1965. ;
  1966. ;
  1967.     IF    WDU    ;WHEEL FACILITY?
  1968. ;
  1969.     CALL    WHLCHK        ;CHECK FOR WHEEL BYTE
  1970. ;
  1971.     ENDIF        ;WDU
  1972. ;
  1973.     LDA    COLON        ;LOOK FOR COLON FLAG
  1974.     ORA    A        ;IF ZERO, JUST BLANK
  1975.     RZ            ;RETURN TO MAIN ROUTINE IF NOTHING SPECIFIED
  1976. ;
  1977. ;  COMMAND IS DU:, SO LOG IN USER/DISK
  1978. ;
  1979.     LDA    TEMPUSR        ;GET SELECTED USER
  1980.     CPI    10H        ;MAKE SURE 4 BITS
  1981.     JNC    ERROR        ;RANGE ERROR?
  1982.     STA    CURUSR        ;SET CURRENT USER
  1983.     CALL    SLOGIN        ;LOG IN USER/DISK AS IF TEMPORARILY
  1984. ;
  1985. ;  NOW, MAKE LOGIN PERMANENT
  1986. ;
  1987.     LDA    TEMPDR        ;GET SELECTED DRIVE
  1988.     ORA    A        ;IF 0 (DEFAULT), NO CHANGE
  1989.     JZ    COM0
  1990.     DCR    A        ;ADJUST FOR LOG IN
  1991.     STA    CURDR        ;SET CURRENT DRIVE
  1992. COM0:
  1993.     JMP    SETUD        ;SET CURRENT USER/DISK AND RET THRU DLOGIN
  1994. ;
  1995. ;  PROCESS COMMAND
  1996. ;
  1997. COM1:
  1998.     LXI    D,FCBFT        ;PT TO FILE TYPE
  1999.     LDAX    D        ;GET FIRST CHAR OF FILE TYPE
  2000.     CPI    ' '        ;MUST BE BLANK, OR ERROR
  2001.     JNZ    ERROR
  2002.     LXI    H,COMMSG    ;PLACE DEFAULT FILE TYPE (COM) INTO FCB
  2003.     LXI    B,3        ;3 BYTES
  2004.     CALL    LDIRSB        ;LDIR REPLACEMENT SUBROUTINE
  2005.     LXI    H,TPA        ;SET EXECUTION/LOAD ADDRESS
  2006.     PUSH    H        ;SAVE FOR EXECUTION
  2007. ;
  2008.     IF    CMDRUN        ;COMMAND RUN FACILITY AVAILABLE?
  2009. ;
  2010.     MVI    A,0FFH        ;USE IT IF AVAILABLE
  2011. ;
  2012.     ENDIF        ;CMDRUN
  2013. ;
  2014.     CALL    MLOAD        ;LOAD MEMORY WITH FILE SPECIFIED IN CMD LINE
  2015.     POP    H        ;GET EXECUTION ADDRESS
  2016. ;
  2017. ; CALLPROG IS THE ENTRY POINT FOR THE EXECUTION OF THE LOADED
  2018. ;   PROGRAM; ON ENTRY TO THIS ROUTINE, HL MUST CONTAIN THE EXECUTION
  2019. ;   ADDRESS OF THE PROGRAM (SUBROUTINE) TO EXECUTE
  2020. ;
  2021. CALLPROG:
  2022.     SHLD    EXECADR        ;PERFORM IN-LINE CODE MODIFICATION
  2023.     CALL    SCANER        ;SEARCH COMMAND LINE FOR NEXT TOKEN
  2024.     LXI    H,TEMPDR    ;SAVE PTR TO DRIVE SPEC
  2025.     PUSH    H
  2026.     MOV    A,M        ;SET DRIVE SPEC
  2027.     STA    FCBDN
  2028.     LXI    H,FCBDN+10H    ;PT TO 2ND FILE NAME
  2029.     CALL    SCANX        ;SCAN FOR IT AND LOAD IT INTO FCB+16
  2030.     POP    H        ;SET UP DRIVE SPECS
  2031.     MOV    A,M
  2032.     STA    FCBDM
  2033.     XRA    A
  2034.     STA    FCBCR
  2035.     LXI    D,TFCB        ;COPY TO DEFAULT FCB
  2036.     LXI    H,FCBDN     ;FROM FCBDN
  2037.     LXI    B,33        ;SET UP DEFAULT FCB
  2038.     CALL    LDIRSB        ;LDIR REPLACEMENT SUBROUTINE
  2039. CMDCH1    EQU    $+1        ;IN-THE-CODE BUFFER FOR ADDRESS OF 1ST CHAR
  2040.     LXI    H,CMDLIN
  2041. CALLP1:
  2042.     MOV    A,M        ;SKIP TO END OF 2ND FILE NAME
  2043.     ORA    A        ;END OF LINE?
  2044.     JZ    CALLP2
  2045. ;
  2046.     IF    MULTCMD        ;MULTIPLE COMMANDS ALLOWED?
  2047. ;
  2048.     CPI    CMDSEP        ;COMMAND SEPARATOR?
  2049.     JZ    CALLP2
  2050. ;
  2051.     ENDIF        ;MULTCMD
  2052. ;
  2053.     CPI    ' '        ;END OF TOKEN?
  2054.     JZ    CALLP2
  2055.     INX    H
  2056.     JMP    CALLP1
  2057. ;
  2058. ; LOAD COMMAND LINE INTO TBUFF
  2059. ;
  2060. CALLP2:
  2061.     MVI    B,0        ;SET CHAR COUNT
  2062.     LXI    D,TBUFF+1    ;PT TO CHAR POS
  2063. CALLP3:
  2064.     MOV    A,M        ;COPY COMMAND LINE TO TBUFF
  2065.     STAX    D
  2066.     ORA    A        ;DONE IF ZERO
  2067.     JZ    CALLP5
  2068. ;
  2069.     IF    MULTCMD        ;MULTIPLE COMMANDS ALLOWED?
  2070. ;
  2071.     CPI    CMDSEP        ;DONE IF COMMAND SEPARATOR
  2072.     JZ    CALLP4
  2073. ;
  2074.     ENDIF        ;MULTCMD
  2075. ;
  2076.     INR    B        ;INCR CHAR COUNT
  2077.     INX    H        ;PT TO NEXT
  2078.     INX    D
  2079.     JMP    CALLP3
  2080. ;
  2081.     IF    MULTCMD        ;MULTIPLE COMMANDS ALLOWED?
  2082. ;
  2083. CALLP4:
  2084.     XRA    A        ;STORE ENDING ZERO
  2085.     STAX    D        ;INSTEAD OF CMDSEP
  2086. ;
  2087.     ENDIF        ;MULTCMD
  2088. ;
  2089. ; RUN LOADED TRANSIENT PROGRAM
  2090. ;
  2091. CALLP5:
  2092. ;
  2093.     IF    MULTCMD        ;MULTIPLE COMMANDS ALLOWED?
  2094. ;
  2095.     SHLD    NXTCHR        ;SAVE PTR TO CONTINUE PROCESSING
  2096. ;
  2097.     ENDIF        ;MULTCMD
  2098. ;
  2099.     MOV    A,B        ;SAVE CHAR COUNT
  2100.     STA    TBUFF
  2101.     CALL    CRLF        ;NEW LINE
  2102.     CALL    DEFDMA        ;SET DMA TO 0080
  2103. ;
  2104. ; EXECUTION (CALL) OF PROGRAM (SUBROUTINE) OCCURS HERE
  2105. ;
  2106. EXECADR    EQU    $+1        ;CHANGE ADDRESS FOR IN-LINE CODE MODIFICATION
  2107.     CALL    TPA        ;CALL TRANSIENT
  2108.     CALL    DEFDMA        ;SET DMA TO 0080, IN CASE PROG CHANGED IT
  2109.     CALL    DLOGIN        ;LOGIN CURRENT USER/DISK
  2110.     JMP    CONT        ;RESTART CPR AND CONTINUE COMMAND PROCESSING
  2111. ;
  2112. ;Section 5J
  2113. ;Command: GET
  2114. ;Function:  To load the specified file from disk to the specified address
  2115. ;Forms:
  2116. ;    GET <adr> <ufn>    Load the specified file at the specified page;
  2117. ;            <adr> is in HEX
  2118. ;
  2119.     IF    GETON        ;GET ENABLED?
  2120. ;
  2121. GET:
  2122. ;
  2123.     IF    WGET    ;WHEEL ON?
  2124. ;
  2125.     CALL    WHLCHK        ;CHECK WHEEL BYTE
  2126. ;
  2127.     ENDIF        ;WGET
  2128. ;
  2129.     CALL    HEXNUM        ;GET LOAD ADDRESS IN HL
  2130.     PUSH    H        ;SAVE ADDRESS
  2131.     CALL    SCANER        ;GET FILE NAME
  2132.     POP    H        ;RESTORE ADDRESS
  2133.     JNZ    ERROR        ;MUST BE UNAMBIGUOUS
  2134. ;
  2135. ; FALL THRU TO MLOAD
  2136. ;
  2137.     IF    CMDRUN        ;COMMAND RUN FACILITY AVAILABLE?
  2138. ;
  2139.     XRA    A        ;NO CMDRUN IF FACILITY IS THERE
  2140. ;
  2141.     ENDIF            ;CMDRUN
  2142. ;
  2143.     ENDIF            ;GETON
  2144.  
  2145. ;
  2146. ;  MEMORY LOAD SUBROUTINE
  2147. ;
  2148. ; LOAD MEMORY WITH THE FILE WHOSE NAME IS SPECIFIED IN THE COMMAND LINE
  2149. ;   ON INPUT, HL CONTAINS STARTING ADDRESS TO LOAD
  2150. ;
  2151. ;    EXIT POINTS ARE A RETURN AND LOG IN CURRENT USER/DISK IF NO ERROR,
  2152. ; A JMP TO ERROR IF COM FILE NOT FOUND OR A MESSAGE AND ABORT IF MEMORY FULL
  2153. ;
  2154. MLOAD:
  2155. ;
  2156.     IF    CMDRUN    ;CMDRUN FACILITY?
  2157. ;
  2158.     STA    CRFLAG    ;SAVE FLAG
  2159. ;
  2160.     ENDIF        ;CMDRUN
  2161. ;
  2162.     SHLD    LOADADR        ;SET LOAD ADDRESS
  2163. ;
  2164. ;   MLA is a reentry point for a non-standard CP/M Modification
  2165. ; The PATH command-search is implemented by this routine
  2166. ;
  2167. MLA:
  2168. ;
  2169.     IF    DRVPREFIX    ;IF DRIVE PREFIX ALLOWED ...
  2170. ;
  2171.     MVI    A,DRVPFATT    ;SET FLAG PER USER SPEC FOR SYS/NON-SYS
  2172.     STA    SYSTST        ;TEST FLAG IN GETSBIT
  2173.     CALL    SLOGIN        ;LOOK UNDER TEMPORARY USER/DISK
  2174.     CALL    SEARF        ;LOOK FOR FILE
  2175. MLARUN:
  2176.     LXI    H,PATH        ;PT TO PATH FOR FAILURE POSSIBILITY
  2177.     JNZ    MLA4        ;FOUND IT -- LOAD IT AND RUN
  2178. ;
  2179.     ELSE            ;NO DRIVE PREFIX
  2180. ;
  2181. MLARUN:
  2182.     LXI    H,PATH        ;POINT TO PATH
  2183. ;
  2184.     ENDIF        ;DRVPREFIX
  2185. ;
  2186. MLA0:
  2187.     MOV    A,M        ;GET DRIVE
  2188.     ORA    A        ;0=DONE=COMMAND NOT FOUND
  2189. ;
  2190.     IF    CMDRUN        ;COMMAND RUN FACILITY
  2191. ;
  2192.     JNZ    NOCRUN        ;NOT READY FOR CMD RUN YET
  2193. CRFLAG    EQU    $+1        ;POINTER FOR IN-THE-CODE MODIFICATION
  2194.     MVI    A,0        ;CHECK CRFLAG
  2195.     ORA    A        ;0=NO
  2196.     JZ    ERROR        ;PROCESS AS ERROR IF CMD RUN EXHAUSTED
  2197. ;
  2198.     IF    ROOTONLY    ;ONLY LOOK FOR EXT COMMAND PROCESSOR AT ROOT
  2199. ;
  2200.     PUSH    H
  2201. ;
  2202.     ENDIF        ;ROOTONLY
  2203. ;
  2204.     XRA    A        ;DO NOT REENTER THIS CODE
  2205.     STA    CRFLAG        ;SET ZERO FOR NO ENTRY
  2206.     LHLD    CMDCH1        ;GET PTR TO FIRST CHAR OF COMMAND
  2207.     DCX    H        ;PT TO CHAR COUNT
  2208.     MVI    M,' '        ;STORE LEADING SPACE
  2209.     SHLD    CMDCH1        ;POINT TO LEADING SPACE AS FIRST CHAR
  2210.     SHLD    NXTCHR        ;NEXT CHAR IS FIRST CHAR OF COMMAND
  2211.     LXI    H,CFCB        ;SET CFCB AS COMMAND
  2212.     LXI    D,FCBDN        ;... BY COPYING IT INTO FCBDN
  2213.     LXI    B,12        ;ONLY 12 BYTES REQUIRED
  2214.     CALL    LDIRSB        ;LDIR REPLACEMENT SUBROUTINE
  2215. ;
  2216.     IF    ROOTONLY    ;LOOK FOR EXT COMMAND PROCESSOR AT ROOT ONLY?
  2217. ;
  2218.     JMP    MLA3RT
  2219. ;
  2220.     ELSE            ;FOLLOW PATH LOOKING FOR EXT COMMAND PROCESSOR
  2221. ;
  2222.     XRA    A        ;A=0
  2223.     JMP    MLARUN        ;NOW TRY THE RUN
  2224. ;
  2225.     ENDIF        ;ROOTONLY
  2226. ;
  2227. CFCB:
  2228.     CMDFCB            ;FCB DEFINING INITIAL COMMAND
  2229. NOCRUN:
  2230. ;
  2231.     ELSE
  2232. ;
  2233.     JZ    ERROR        ;TRANSIENT LOAD ERROR -- FILE NOT FOUND
  2234. ;
  2235.     ENDIF        ;CMDRUN
  2236. ;
  2237. ; LOOK FOR COMMAND IN DIRECTORY PTED TO BY HL; DRIVE IN A
  2238. ;
  2239.     CPI    CURIND        ;CURRENT DRIVE SPECIFIED?
  2240.     JNZ    MLA1        ;SKIP DEFAULT DRIVE SELECTION IF SO
  2241.     LDA    CURDR        ;GET CURRENT DRIVE
  2242.     INR    A        ;SET A=1
  2243. MLA1:
  2244.     STA    TEMPDR        ;SELECT DIFFERENT DRIVE IF NOT CURRENT
  2245.     MVI    A,1        ;PREPARE TO ACCEPT BOTH SYSTEM AND DIR FILES
  2246.     STA    SYSTST        ;TEST FLAG IS 1 FOR BOTH
  2247.     INX    H        ;PT TO USER NUMBER
  2248.     MOV    A,M        ;GET USER NUMBER
  2249.     INX    H        ;PT TO NEXT ENTRY IN PATH
  2250.     PUSH    H        ;SAVE PTR
  2251.     ANI    7FH        ;MASK OUT SYSTEM BIT
  2252.     CPI    CURIND        ;CURRENT USER SPECIFIED?
  2253.     JNZ    MLA2        ;DO NOT SELECT CURRENT USER IF SO
  2254.     LDA    CURUSR        ;GET CURRENT USER NUMBER
  2255. MLA2:
  2256.     STA    TEMPUSR        ;SET TEMPORARY USER NUMBER
  2257.     CMA            ;FLIP BITS SO SYSTEM BIT IS 0 IF SYS-ONLY
  2258.     ANI    80H        ;MASK FOR ONLY NOT OF SYSTEM BIT TO SHOW
  2259.     JNZ    MLA3        ;DON'T SET FLAG IS ORIGINALLY SYSTEM BIT=0
  2260.     STA    SYSTST        ;TEST FLAG IS 0 FOR SYS-ONLY, 1 FOR BOTH
  2261. MLA3:
  2262.     CALL    SLOGIN        ;LOG IN PATH-SPECIFIED USER/DISK
  2263. MLA3RT:
  2264.     CALL    SEARF        ;LOOK FOR FILE
  2265.     POP    H        ;GET PTR TO NEXT PATH ENTRY
  2266.     JZ    MLA0        ;CONTINUE PATH SEARCH IF SEARCH FAILED
  2267.                 ;LOAD IF SEARCH SUCCEEDED
  2268. ;
  2269. ; FILE FOUND -- PERFORM SYSTEM TEST AND PROCEED IF APPROVED
  2270. ;
  2271. MLA4:
  2272.     PUSH    H        ;SAVE PTR
  2273.     CALL    GETSBIT        ;CHECK SYSTEM BIT
  2274.     POP    H        ;GET PTR
  2275.     JZ    MLA0        ;CONTINUE IF NO MATCH
  2276.     CALL    OPENF        ;OPEN FILE FOR INPUT
  2277. LOADADR    EQU    $+1        ;MEMORY LOAD ADDRESS (IN-LINE CODE MOD)
  2278.     LXI    H,TPA        ;SET START ADDRESS OF MEMORY LOAD
  2279. MLA5:
  2280.     MVI    A,ENTRY/256-1    ;GET HIGH-ORDER ADR OF JUST BELOW CPR
  2281.     CMP    H        ;ARE WE GOING TO OVERWRITE THE CPR?
  2282.     JC    PRNLE        ;ERROR IF SO
  2283.     PUSH    H        ;SAVE ADDRESS OF NEXT SECTOR
  2284.     XCHG            ;... IN DE
  2285.     CALL    DMASET        ;SET DMA ADDRESS FOR LOAD
  2286.     LXI    D,FCBDN     ;READ NEXT SECTOR
  2287.     CALL    READ
  2288.     POP    H        ;GET ADDRESS OF NEXT SECTOR
  2289.     JNZ    MLA6        ;READ ERROR OR EOF?
  2290.     LXI    D,128        ;MOVE 128 BYTES PER SECTOR
  2291.     DAD    D        ;PT TO NEXT SECTOR IN HL
  2292.     JMP    MLA5
  2293. ;
  2294. MLA6:
  2295.     DCR    A        ;LOAD COMPLETE
  2296.     JZ    DLOGIN        ;OK IF ZERO, ELSE FALL THRU TO PRNLE
  2297.  
  2298. ;
  2299. ; LOAD ERROR
  2300. ;
  2301. PRNLE:
  2302.     CALL    PRINTC
  2303.     DB    'Ful','l'+80H
  2304.     CALL    DLOGIN        ;RESTORE CURRENT USER/DISK
  2305.     JMP    RESTRT        ;RESTART ZCPR
  2306.  
  2307. ;*****
  2308. ;
  2309. LDIRSB:    PUSH    PSW        ;START LDIR REPLACEMENT
  2310. LDIR1:    MOV    A,M
  2311.     STAX    D
  2312.     INX    D
  2313.     INX    H
  2314.     DCX    B
  2315.     MOV    A,B
  2316.     ORA    C
  2317.     JNZ    LDIR1
  2318.     POP    PSW        ;END LDIR REPLACEMENT
  2319.     RET
  2320. ;
  2321. ;
  2322. ;  DEFAULT PATH USED FOR PATH COMMAND-SEARCH
  2323. ;
  2324.     IF    INTPATH        ;USE THIS PATH?
  2325. ;
  2326. PATH:
  2327.     IPATH            ;PATH DEFINED IN ZCPRHDR.LIB
  2328. ;
  2329.     ENDIF        ;INTPATH
  2330.  
  2331. ;*****
  2332.     IF    INTSTACK    ;INTERNAL STACK
  2333. ;
  2334. ;  STACK AREA
  2335. ;
  2336.     DS    48        ;STACK AREA
  2337. STACK    EQU    $        ;TOP OF STACK
  2338. ;
  2339.     ENDIF        ;INTSTACK
  2340. ;
  2341.  
  2342. ;
  2343. ;    The following will cause an error message to appear if
  2344. ; the size of ZCPR2 is over 2K bytes.
  2345. ;
  2346.     IF    ($ GT CPRLOC+800H)
  2347. ZCPR2ER    EQU    NOVALUE        ;ZCPR2 IS LARGER THAN 2K BYTES
  2348.     ENDIF
  2349.  
  2350.     END
  2351.