home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / UTILS / HDUTL / FLOPCOPY.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  17KB  |  709 lines
  1. ; FLOPPY DISK COPY PROGRAM
  2. ; COPYRIGHT 1982, G. YOUNG, INC. 
  3. ; UPDATED 10/9/82
  4. * 
  5. * TO EXECUTE, ENTER THE PROGRAM NAME FOLLOWED BY THE FILE MASK:
  6. *       A>FLOPCOPY *.COM
  7. *
  8. * THE PRIMARY PURPOSE OF THIS PROGRAM IS TO COPY A FLOPPY DISK ON  
  9. * SYSTEMS THAT HAVE ONLY ONE FLOPPY DISK AND A HARD DISK.  THIS IS DONE
  10. * BY READING THE DIRECTORY ON THE FLOPPY AND CREATING A LIST OF FILES TO
  11. * TO BE COPIED, THEN COPY ALL THE FILES TO THE HARD DISK. A BLANK  
  12. * DISK IS THEN INSERTED AND THE FILES ARE COPIED TO THE BLANK FLOPPY
  13. * AND DELETED OFF THE HARD DISK.  THIS PROCEDURE IS USED INSTEAD OF
  14. * THE "SINGLE.COM" PROGRAM BECAUSE THERE IS MORE THAN 1 FILE SO "SINGLE"
  15. * CANNOT BE USED WITHOUT MODIFICATIONS AND EVEN THEN MANY, MANY DISKETTE 
  16. * MOUNTS WOULD HAVE TO BE DONE.  THIS WAY, ONLY 1 DISKETTE MOUNT NEEDS
  17. * TO BE DONE FOR EACH DISK THAT IS COPIED.
  18. * 8/26/82...IF DISKETTE IS FULL, ASK FOR ANOTHER, DO NOT ABORT
  19. * THIS ALLOWS COPYING DOUBLE DENSITY DISKS ON TO MULTIPLE SINGLE DENSITY DISKS
  20. * 10/9/82 ASK FOR SOURCE/DESTINATION/HARD DISK DRIVE # AND NOT HARD CODED
  21.  
  22. * WRITTEN BY GARY YOUNG, BOX 3218, NO. HOLLYWOOD, CA 91609
  23.  
  24.     TITLE    '*** FLOPPY DISK COPY PROGRAM ***'
  25. BDOS    EQU    5
  26. RECSIZE EQU    12
  27. BOOT    EQU    0
  28.     ORG    100H
  29.     JMP    START
  30.     DB    'COPYRIGHT 1982, G. YOUNG, INC.'
  31. START    LXI    SP,STACK+80
  32.     LDA    5DH        ;SEE IF A MASK WAS ENTERED
  33.     CPI    20H        ;BUFFER WILL BE BLANK IF NOT
  34.     JZ    NOMASK
  35.     MVI    C,0DH        ;DISK RESET
  36.     CALL    BDOS
  37.     LXI    H,RAM        ;SET UP TABLE ADDRESS
  38.     SHLD    TABADDR
  39.     LXI    H,0000H
  40.     SHLD    TABCNT
  41.     XRA    A        ;THE TABLE REFERS TO THE REMAINING AREA
  42.     STA    ABORT        ;OF RAM TO HOLD AS MANY DIRECTORY ENTRIES
  43.     STA    EOF        ;AS POSSIBLE
  44.     LXI    D,SIGNON    ;PRINT SIGNON MESSAGE
  45.     CALL    OUTPUT
  46.     LXI    D,SRCFLPMSG    ;GET SOURCE DRIVE
  47.     CALL    QUESTION
  48.     ORA    A
  49.     JZ    QUEST2
  50.     LDA    INREC
  51.     STA    SRCFLP
  52. QUEST2 LXI    D,DESTFLPMSG
  53.     CALL    QUESTION
  54.     ORA    A
  55.     JZ    QUEST3
  56.     LDA    INREC
  57.     STA    SRCFLP
  58. QUEST3    LXI    D,HDMSG
  59.     CALL    QUESTION
  60.     ORA    A
  61.     JZ    QUEST4
  62.     LDA    INREC
  63.     STA    HDTEMP
  64. QUEST4    LDA    HDTEMP
  65.     ANI    0FH
  66.     STA    HDTEMP
  67.     LDA    SRCFLP
  68.     ANI    0FH
  69.     STA    SRCFLP
  70.     LDA    DESTFLP
  71.     ANI    0FH
  72.     STA    DESTFLP
  73.     CALL    EXTRACT        ;GET DIRECTORY ENTRIES
  74.     LDA    ABORT        ;SEE IF TOO MANY ENTRIES FOR MEMORY SIZE
  75.     ORA    A        ;SHOULD BE ZERO TO BE OK
  76.     JZ    NOMORE
  77.     LXI    D,TABFULL    ;REPORT WILL NOT BE COMPLETE
  78.     CALL    OUTPUT        ;MEMORY FULL ERROR
  79. NOMORE    CALL    SORT
  80.     CALL    KILLDUPS    ;REMOVE ENTRIES FROM MULTIPLE EXTENTS
  81.           LDA    SRCFLP      ;FLOPPY IS THE SOURCE DRIVE
  82.     STA    SRCE
  83.     LDA    HDTEMP        ;HARD DISK IS THE DESTINATION
  84.     STA    DEST
  85.     CALL    CPYFILE    
  86. AGAIN    LXI    D,MNTBLANK
  87.     CALL    QUESTION
  88.     MVI    C,0DH
  89.     CALL    BDOS
  90.     LDA    HDTEMP
  91.     STA    SRCE
  92.     LDA    DESTFLP 
  93.     STA    DEST
  94.     CALL    CPYFILE
  95. MSG3    LXI    D,ANOTHER
  96.     CALL    QUESTION
  97.     ORA    A
  98.     JZ    WIPEOUT
  99.     LDA    INREC
  100.     CPI    'N'
  101.     JZ    WIPEOUT
  102.     CPI    'Y'
  103.     JNZ    MSG3
  104.     JMP    AGAIN
  105. WIPEOUT    CALL    ERASE
  106.     JMP    BOOT        ;RESET AND RETURN TO CPM
  107. NOMASK    LXI    D,ERRNOMSK
  108.     CALL    OUTPUT
  109.     JMP    BOOT
  110. *
  111. * THE EXTRACT ROUTINE SCANS THE DIRECTORY ON THE FLOPPY DISK 
  112. * AND CREATES A LIST OF FILES TO BE COPIED.  AFTERS SORTING,
  113. * DUPLICATE ENTRIES RESULTING FROM MULTIPLE EXTENT ENTRIES WILL 
  114. * BE REMOVED.
  115. *
  116. * THE DUMMYFCB SETS UP A SKELETON TO READ ALL FILES ON THE DIRECTORY
  117. * TO BE MODIFIED BY THE SKELATON SETUP IN THE CALL (EX: FLOPCOPY *.ASC).
  118. *
  119. DUMMYFCB    DB    0,'????????????',0,0,0,0,0,0,0,0,0
  120.         DB    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  121. EXTRACT    EQU    $
  122.     LXI    D,DUMMYFCB    ;COPY THE MASK SET UP BY CCP
  123.     LXI    H,5CH        ;OVER THE DUMMY FCB TO LIMIT WHAT IS COPIED
  124.     MVI    B,12
  125.     CALL    MOVE
  126.     LDA    SRCFLP      ;FORCE THE DRIVE TO BE FLOPPY DRIVE
  127.     STA    DUMMYFCB
  128.     ORI    40H
  129.     STA    RDISK
  130.     LXI    D,DISKBUF    ;SET A DMA ADDRESS FOR DIRECTORY ENTRIES
  131.     MVI    C,1AH
  132.     CALL    BDOS        ;SET DMA
  133.     LXI    D,DUMMYFCB    ;GET FIRST DIRECTORY ENTRY
  134.     MVI    C,11H
  135.     CALL    BDOS        ;GET DIRECTORY
  136.     INR    A
  137.     RZ
  138.     JMP    GETFCB        ;EXTRACT DATA FROM FCB
  139. NEXTFCB    LXI    D,DUMMYFCB    ;GET NEXT ENTRY AFTER THE FIRST
  140.     MVI    C,12H
  141.     CALL    BDOS
  142.     INR    A
  143.     RZ
  144. GETFCB    LXI    D,32        ;EACH ENTRY IS 32 BYTES LONG
  145.     LXI    H,DISKBUF    ;DIRECTORY RECORD IS IN DISKBUF
  146.     CPI    1        ;FIRST ENTRY IN RECORD???
  147.     JZ    FORMREC        ;YES
  148.     DAD    D        ;ADD 32 TO ADDRESS IN RECORD
  149.     CPI    2        ;SECOND ENTRY IN RECORD???
  150.     JZ    FORMREC
  151.     DAD    D        ;ADD 64 TO ADDRESS OF RECORD
  152.     CPI    3        ;THIRD ENTRY IN RECORD???
  153.     JZ    FORMREC
  154.     DAD    D        ;ADD 96 TO ADDRESS OF RECORD
  155. FORMREC    INX    H        ;PASS DRIVE BYTE
  156.     LXI    D,RFILE        ;MOVE FILE NAME
  157.     MVI    B,8        ;MOVE 8 CHARACTERS
  158.     CALL    MOVE
  159.     LXI    D,8        ;POSITION PAST NAME TO TYPE
  160.     DAD    D
  161.     LXI    D,RTYPE        ;MOVE TYPE
  162.     MVI    B,3        ;MOVE 3 CHARACTERS
  163.     CALL    MOVE
  164.     INX    H        ;POSITION TO THE EXTENT NUMBER
  165.     INX    H
  166.     INX    H
  167.     LXI    H,RTYPE        ;STRIP OFF THE HIGH BIT SET BY
  168.     MVI    B,11        ;THE VERSION PROGRAM
  169. STRIP    MOV    A,M
  170.     ANI    07FH
  171.     MOV    M,A
  172.     INX    H
  173.     DCR    B
  174.     JNZ    STRIP
  175.     LXI    H,RTYPE        ;SKIP OVER JUNK DISK ENTRIES
  176.     MVI    B,11        ;CONTAINING NONPRINTING CHARACTERS
  177. NONPRNT MOV    A,M
  178.     CPI    20H        ;ANY CHAR LESS THAN A BLANK
  179.     JC    NEXTFCB        ;GO TO NEXT ONE IF SO
  180.     INX    H
  181.     DCR    B
  182.     JNZ    NONPRNT
  183. FIRSTEXT    EQU    $    ;GOT THE FIRST EXTENT
  184.     LHLD    TABADDR        ;GET MEMORY TABLE ADDRESS
  185.     LXI    D,RTYPE        ;GET MEMORY RECORD ADDRESS
  186.     XCHG            ;RTYPE (HL) TO TABADDR (DE)
  187.     MVI    B,RECSIZE    ;MOVE RECSIZE BYTES
  188.     CALL    MOVE
  189.     LHLD    TABADDR        ;INCREMENT FOR NEXT ENTRY
  190.     LXI    D,RECSIZE        ;RECSIZE BYTES IN RECORD
  191.     DAD    D
  192.     SHLD    TABADDR        ;SAVE NEW ADDRESS
  193.     MVI    M,1AH        ;SET AN END-OF-TABLE INDICATOR
  194.     LHLD    TABCNT        ;GET RECORD COUNT
  195.     INX    H
  196.     SHLD    TABCNT        ;INCREMENT RECORD COUNT
  197.     LHLD    TABADDR        ;SEE IF NEW ADDRESS IS GREATER
  198.     XCHG            ;THAN THE TOP OF TPA-128
  199.     LHLD    BDOS+1        ;HL=TOP...DE=TABLE+RECSIZE
  200.     LXI    B,-128
  201.     DAD    B        ;SUBTRACT 128 FROM TOP
  202.     CALL    COMPREG        ;COMPARE REGISTER VALUES
  203.     JNC    NEXTFCB        ;THERE IS ROOM FOR MORE
  204.     MVI    A,1        ;NO MORE ROOM...ABORT NOW
  205.     STA    ABORT
  206.     RET
  207.  
  208. * COPY THE FILE FROM ONE DISK TO ANOTHER
  209. * THIS CODE WAS TAKEN FROM BACKUP.ASM SO HDFCB REFERS TO THE SOURCE DISK
  210. * AND FPFCB REFERS TO THE DESTINATION DISK REGARDLESS OF FLOPPY OR HARD.
  211.  
  212. CPYFILE    EQU    $
  213.     LHLD    ADDR2        ;GET THE CURRENT END OF TABLE
  214.     INX    H        ;PLUS ONE FOR THE START OF THE
  215.     SHLD    ADDR3        ;READ/WRITE BUFFER
  216.     LXI    H,RAM        ;SET THE ADDRESS OF THE FIRST ENTRY
  217.     SHLD    ADDR1
  218.     JMP    PASSMOVE
  219. NEXTFILE    EQU    $
  220.     LHLD    ADDR1
  221.     LXI    D,RECSIZE
  222.     DAD    D
  223.     SHLD    ADDR1
  224. PASSMOVE LHLD    ADDR1
  225.     MOV    A,M
  226.     CPI    1AH
  227.     RZ
  228. FORMFCB    LXI    D,HDFCB        ;CLEAR THE FCB
  229.     MVI    B,36
  230.     XRA    A
  231. ZEROFCB    STAX    D
  232.     INX    D
  233.     DCR    B
  234.     JNZ    ZEROFCB
  235.     LHLD    ADDR1        ;GET ADDRESS OF TABLE ENTRY
  236.     LXI    D,HDTYPE    ;MOVE IN THE TYPE
  237.     MVI    B,3
  238.     CALL    MOVE
  239.     INX    H
  240.     INX    H        ;POSITION TO NAME
  241.     INX    H
  242.     LXI    D,HDFILE    ;MOVE THE FILE NAME
  243.     MVI    B,8
  244.     CALL    MOVE
  245.     LXI    D,8
  246.     DAD    D        ;POSITION TO DISK ID, A:, B: ETC
  247.     LDA    SRCE
  248.     STA    HDFCB
  249.     LXI    D,FPFCB        ;COPY THE HDFCB TO THE FLOPPY FCB
  250.     LXI    H,HDFCB
  251.     MVI    B,36
  252.     CALL    MOVE
  253.     LDA    DEST
  254.     STA    FPFCB
  255.     LHLD    ADDR1
  256.     CALL    FORMAT
  257.     LXI    D,PRNTREC
  258.     CALL    OUTPUT
  259.     LXI    D,HDFCB        ;OPEN THE SOURCE FILE DRIVE
  260.     MVI    C,0FH
  261.     CALL    BDOS        
  262.     INR    A
  263.     JZ    NOTFOUND
  264.     LXI    D,FPFCB        ;SEE IF THE FILE IS ON THE DESTINATION DRV
  265.     MVI    C,0FH
  266.     CALL    BDOS        ;DUMMY OPEN
  267.     INR    A
  268.     JZ    MAKEIT        ;NOT THERE...MAKE IT
  269.     LHLD    ADDR1        ;SET THE DRIVE BYTE (#12) TO '*' TO MARK 
  270.     LXI    D,RECSIZE-1    ;THE FILE AS ALREADY BEING THERE SO THAT
  271.     DAD    D        ;THE ERASE ROUTINE WILL NOT ERASE IT
  272.     MVI    A,'*'        ;LATER WHEN REMOVING FILES
  273.     MOV    M,A
  274. HUH2    LXI    D,ALRDYEXT    ;FILE ALREADY EXISTS ON DESTINATION.  ASK IF
  275.     CALL    QUESTION    ;YOU WANT TO COPY THE NEW SOURCE OVER THE
  276.     CPI    1        ;EXISTING COPY
  277.     JNZ    HUH2
  278.     LDA    INREC
  279.     CPI    'Y'
  280.     JZ    ERAIT        ;ERASE IT
  281.     CPI    'N'        ;NO, USE THE COPY ALREADY ON THE DESTINATION
  282.     JZ    NEXTFILE
  283.     JMP    HUH2
  284. ERAIT    EQU    $
  285.      LXI    D,FPFCB        ;DELETE THE FILE ON FLOPPY IF IT
  286.     MVI    C,13H        ;EXISTS
  287.     CALL    BDOS
  288. MAKEIT    EQU    $
  289.     LXI    D,FPFCB        ;CREATE THE FILE ON FLOPPY 
  290.     MVI    C,16H
  291.     CALL    BDOS        ;MAKE FILE
  292.     INR    A
  293.     JZ    DISKFULL
  294. COPYLOOP    CALL    LOADBUFF    ;LOAD MEMORY WITH FILE
  295.     CALL    WRITEBUF        ;WRITE MEMORY FILE
  296.     LDA    EOF
  297.     CPI    1
  298.     JZ    ENDOFFILE
  299.     CPI    2
  300.     JZ    DISKFULL
  301.     JMP    COPYLOOP
  302. ENDOFFILE    LXI    D,FPFCB        ;CLOSE FLOPPY FILE
  303.     MVI    C,10H
  304.     CALL    BDOS            ;CLOSE
  305.     JMP    NEXTFILE
  306. DISKFULL    LXI    D,FPFCB
  307.     MVI    C,13H        ;DELETE FILE ON FLOPPY
  308.     CALL    BDOS
  309.     LXI    D,DSKFULL    ;PRINT DISK FULL MESSAGE
  310.     CALL    QUESTION
  311.     MVI    C,0DH        ;RESET DISKS
  312.     CALL    BDOS
  313.     JMP    FORMFCB
  314. NOTFOUND LHLD    ADDR1
  315.     CALL    FORMAT
  316.     LXI    D,NFMSG
  317.     CALL    OUTPUT
  318.     LXI    D,PRNTREC
  319.     CALL    OUTPUT
  320.     RET
  321.  
  322. ERASE     EQU    $
  323. HUH    LXI    D,ERAMSG    ;ASK IF YOU WANT THEM ERASED
  324.     CALL    QUESTION
  325.     ORA    A
  326.     JZ    ERAALL
  327.     LDA    INREC
  328.     CPI    'Y'
  329.     JZ    ERAALL
  330.     CPI    'N'
  331.     RZ
  332.     JMP    HUH
  333. ERAALL    EQU    $
  334.     LXI    H,RAM        ;SET THE ADDRESS OF THE FIRST ENTRY
  335.     SHLD    ADDR1
  336.     JMP    PASSMOVEX
  337. ERANEXT EQU    $
  338.     LHLD    ADDR1
  339.     LXI    D,RECSIZE
  340.     DAD    D
  341.     SHLD    ADDR1
  342. PASSMOVEX LHLD    ADDR1
  343.     MOV    A,M
  344.     CPI    1AH
  345.     RZ
  346.     LXI    D,RECSIZE-1    ;SEE IF THE DRIVE INDICATOR IS SET TO '*' 
  347.     DAD    D        ;MEANING THE FILE WAS ALREADY ON THE HARD DISK
  348.     MOV    A,M        ;SO IT WILL NOT BE DELETED
  349.     CPI    '*'
  350.     JZ    ERANEXT        ;YES, IT WAS THERE, SO DO NOT ERASE IT
  351. FORMFCBX    LXI    D,HDFCB        ;CLEAR THE FCB
  352.     MVI    B,36
  353.     XRA    A
  354. ZEROFCBX    STAX    D
  355.     INX    D
  356.     DCR    B
  357.     JNZ    ZEROFCBX
  358.     LHLD    ADDR1
  359.     LXI    D,HDTYPE    ;MOVE IN THE TYPE
  360.     MVI    B,3
  361.     CALL    MOVE
  362.     INX    H
  363.     INX    H        ;POSITION TO NAME
  364.     INX    H
  365.     LXI    D,HDFILE    ;MOVE THE FILE NAME
  366.     MVI    B,8
  367.     CALL    MOVE
  368.     LXI    D,8
  369.     DAD    D        ;POSITION TO DISK ID, A:, B: ETC
  370.     LDA    HDTEMP   
  371.     STA    HDFCB
  372.     LHLD    ADDR1
  373.     CALL    FORMAT
  374.     LXI    D,PRNTREC
  375.     CALL    OUTPUT
  376.     LXI    D,HDFCB        ;DELETE THE FILE ON FLOPPY IF IT
  377.     MVI    C,13H        ;EXISTS
  378.     CALL    BDOS
  379.     JMP    ERANEXT
  380.  
  381. * THE FOLLOWING ROUTINE IS A BUBBLE SORT.  IN PSEUDOBASIC
  382. * IS WOULD BE DONE AS FOLLOWS:
  383. *SORT    ADDR1=BOTTOM(RAM)-RECSIZE (RECSIZE IS COUNT OF BYTES IN ONE RECORD)
  384. *    MAX1=0
  385. *LOOP1    MAX1=MAX1+1
  386. *    ADDR1=ADDR1+RECSIZE    (FIRST TIME THIS WOULD BE THE BOTTOM)
  387. *    IF MAX1>TABCNT-1 THEN GO TO SORTED
  388. *    ADDR2=ADDR1
  389. *    MAX2=MAX1
  390. *LOOP2    MAX2=MAX2+1
  391. *    ADDR2=ADDR2+RECSIZE
  392. *    IF MAX2>TABCNT THEN GO TO LOOP1
  393. *    IF TABLE(ADDR1)<TABLE(ADDR2) THEN GO TO LOOP2
  394. *    TEMP=TABLE(ADDR1)
  395. *    TABLE(ADDR1)=TABLE(ADDR2)
  396. *    TABLE(ADDR2)=TEMP
  397. *    GO TO LOOP2
  398. *SORTED    RETURN
  399. *
  400. *NOW THAT THIS LOGIC IS INTUITIVELY OBVIOUS, HERE'S THE NOT SO
  401. *OBVIOUS CODE:
  402.  
  403. SORT    
  404.     LXI    H,0000        ;INITIALIZE COUNT
  405.     SHLD    MAX1        ;SINCE IT WILL DECREMENT FIRST
  406.     LXI    D,-RECSIZE    ;SUBTRACT RECSIZE FROM THE BEGINNING
  407.     LXI    H,RAM        ;OF THE TABLE SINCE IT WILL ADD
  408.     DAD    D        ;RECSIZE TO IT FIRST
  409.     SHLD    ADDR1
  410. LOOP1    LHLD    ADDR1        ;GET THE CURRENT ADDRESS
  411.     LXI    D,RECSIZE        ;INCREMENT IT BY RECSIZE
  412.     DAD    D        ;PAST THE NEXT ENTRY
  413.     SHLD    ADDR1
  414.     LHLD    MAX1        ;SEE IF THE COUNT HAS REACHED THE LIMIT
  415.     INX    H        ;INCREMENT THE COUNTER
  416.     SHLD    MAX1
  417.     XCHG            ;MOVE TO DE TO COMPARE TO LIMIT
  418.     LHLD    TABCNT
  419.     DCX    H        ; IS MAX1 > TABCNT - 1 ???
  420.     CALL    COMPREG        ;COMPARE DE (CURRENT COUNT) TO HL (TABCNT-1)
  421.     JC    SORTED        ;FINISHED WHEN MAX1 > TABCNT-1
  422.     LHLD    ADDR1        ;SETUP FOR THE INNER LOOP
  423.     SHLD    ADDR2
  424.     LHLD    MAX1
  425.     SHLD    MAX2
  426. LOOP2    LHLD    ADDR2        ;START WITH ONE ENTRY GREATER THEN
  427.     LXI    D,RECSIZE        ;THE OUTER LOOP AND INCREMENT
  428.     DAD    D        ;BY RECSIZE EACH TIME PAST THE NEXT RECORD
  429.     SHLD    ADDR2        ;POINTER TO THE CURRENT RECORD
  430.     LHLD    MAX2        ;LIKEWISE SEE IF THE COUNTER FOR THE
  431.     INX    H
  432.     SHLD    MAX2
  433.     XCHG
  434.     LHLD    TABCNT
  435.     CALL    COMPREG
  436.     JC    LOOP1        ;WHEN FINISHED, INCREMENT OUTER LOOP
  437.     LHLD    ADDR2
  438.     XCHG            ;ADDR2 NOW IN DE
  439.     LHLD    ADDR1
  440.     CALL    COMPARE        ;COMPARE STRINGS POINTED TO BY DE/HL
  441.     JNC    LOOP2        ;TABLE(HL) < TABLE (DE)
  442. * EXCHANGE THE TWO ENTRIES VIA A TEMPORARY RECORD
  443.     LXI    D,TEMP
  444.     LHLD    ADDR1
  445.     MVI    B,RECSIZE
  446.     CALL    MOVE        ;TEMP=TABLE(ADDR1)
  447.     XCHG            ;ADDR1=DESTINATION
  448.     LHLD    ADDR2        ;ADDR2=SOURCE
  449.     CALL    MOVE        ;TABLE(ADDR1)=TABLE(ADDR2)
  450.     XCHG            ;ADDR2 = DESTINATION
  451.     LXI    H,TEMP
  452.     CALL    MOVE        ;TABLE(ADDR2)=TEMP
  453.     JMP    LOOP2
  454. SORTED    RET            ;FINISHED SORTING
  455.  
  456.  
  457.  
  458. KILLDUPS EQU    $    ;KILL DUPLICATE ENTRIES FROM MULTIPLE EXTENTS
  459.     LXI    H,RAM
  460.     SHLD    ADDR1            ;SET THE START OF THE TABLE
  461. NEXTEQUAL    LHLD    ADDR1        ;CHECK EACH ENTRY AGAINST THE NEXT
  462.     LXI    D,RECSIZE
  463.     DAD    D
  464.     SHLD    ADDR2
  465. NEXTCHK    MOV    A,M            ;CHECK FOR END OF TABLE
  466.     CPI    1AH
  467.     RZ
  468.     XCHG
  469.     LHLD    ADDR1            ;COMPARE ADDR1 WITH ADDR2
  470.     MVI    B,RECSIZE
  471.     CALL    COMPARE
  472.     JNZ    SAVELAST
  473.     PUSH    H            ;SAVE CURRENT POSITION
  474.     LHLD    ADDR2            ;SET UP FOR MOVING LIST
  475.     SHLD    ADDR1            ;DOWN ONE ENTRY
  476.     LXI    D,RECSIZE
  477.     DAD    D            ;MOVE THIRD ENTRY TO THE SECOND
  478.     SHLD    ADDR2
  479.     CALL    MOVELIST
  480.     LHLD    TABCNT
  481.     DCX    H
  482.     SHLD    TABCNT
  483.     POP    H            ;RESTORE CURRENT POSITION
  484.     SHLD    ADDR1            ;NOW COMPARE 1ST & 3RD
  485.     JMP    NEXTEQUAL
  486. SAVELAST    LHLD    ADDR2        ;MAKE NEW ONE THE CURRENT ONE
  487.     SHLD    ADDR1
  488.     JMP    NEXTEQUAL        ;COMPARE
  489.  
  490. MOVELIST    LHLD    ADDR2        ;MOVE THE TABLE FROM ADDR2 DOWN
  491.     XCHG                ;TO ADDR1 THEREBY ELIMINATING
  492.     LHLD    ADDR1            ;UNWANTED ENTRIES
  493. MOVENEXT    LDAX    D        ;AND MAKING MORE ROOM FOR THE
  494.     MOV    M,A
  495.     CPI    1AH
  496.     RZ
  497.     INX    H
  498.     INX    D
  499.     JMP    MOVENEXT
  500.  
  501.  
  502. * ASSORTED ROUTINES
  503.  
  504.  
  505. LOADBUFF    EQU    $    ;THIS ROUTINE LOADS AS MUCH OF
  506.     LXI    H,0000        ;MEMORY WITH THE FILE AS POSSIBLE
  507.     SHLD    MAX1
  508.     LHLD    ADDR3        ;NEW TOP OF TABLE +2
  509.     SHLD    TEMP
  510.     XRA    A
  511.     STA    EOF        ;CLEAR EOF FLAG
  512. LOADNEXT    LHLD    TEMP
  513.     XCHG            ;SET DMA ADDRESS
  514.     MVI    C,1AH
  515.     CALL    BDOS
  516.     LXI    D,HDFCB        ;READ HARD DISK
  517.     MVI    C,14H
  518.     CALL    BDOS
  519.     ORA    A
  520.     JNZ    HDEOF        ;EOF?
  521.     LHLD    MAX1
  522.     INX    H        ;INCREMENT RECORD COUNT
  523.     SHLD    MAX1
  524.     LHLD    TEMP        ;SEE IF NEXT RECORD WOULD EXCEED THE
  525.     LXI    D,128        ;TPA AREA
  526.     DAD    D
  527.     SHLD    TEMP
  528.     DAD    D        ;WILL THE NEXT RECORD OVERWRITE BDOS?
  529.     XCHG
  530.     LHLD    BDOS+1        ;FIND THE TOP OF MEMORY
  531.     CALL    COMPREG        ;COMPARE REGISTERS
  532.     RC            ;RETURN IF MEMORY ALREADY FULL
  533.     JMP    LOADNEXT    ;GET ANOTHER RECORD
  534. HDEOF    MVI    A,1        ;SET FILE EOF
  535.     STA    EOF
  536.     RET
  537.  
  538. WRITEBUF    EQU    $    ;WRITE FROM THE MEMORY BUFFER
  539.     LHLD    ADDR3
  540.     SHLD    TEMP
  541.     LHLD    MAX1        ;ALLOW FOR FILES THAT HAVE NO 
  542.     LXI    D,0000        ;RECORDS SUCH AS RESTART
  543.     CALL    COMPREG
  544.     RZ
  545. WRITENEXT    LHLD    TEMP
  546.     XCHG            ;SET DMA ADDRESS
  547.     MVI    C,1AH
  548.     CALL    BDOS
  549.     LXI    D,FPFCB
  550.     MVI    C,15H        ;WRITE SEQUENTIAL
  551.     CALL    BDOS
  552.     ORA    A
  553.     JNZ    FPFULL        ;FLOPPY DISK FULL
  554.     LHLD    MAX1        ;DECREASE RECORD COUNT
  555.     DCX    H
  556.     SHLD    MAX1
  557.     LXI    D,0000        ;CHECK FOR NO MORE TO WRITE
  558.     CALL    COMPREG
  559.     RZ
  560.     LHLD    TEMP
  561.     LXI    D,128        ;INCREMENT WRITE ADDRESS
  562.     DAD    D
  563.     SHLD    TEMP
  564.     JMP    WRITENEXT
  565. FPFULL    MVI    A,2        ;FULL DISKETTE
  566.     STA    EOF
  567.     RET
  568.  
  569. FORMAT    LXI    D,PRNTYPE    ;FORMAT THE ENTRY FROM THE TABLE
  570.     MVI    B,3        ;FORMAT TO THE PRINT FORMAT
  571.     CALL    MOVE        ;THE TABLE ADDRESS IS ASSUMMED TO BE
  572.     LXI    D,3        ;IN HL. FIRST MOVE THE TYPE
  573.     DAD    D        ;NOW POSITION TO THE FILE NAME
  574.     LXI    D,PRNFILE    ;MOVE THE FILE NAME
  575.     MVI    B,8
  576.     CALL    MOVE
  577.     LXI    D,8        ;POSITION TO THE DISK ID
  578.     DAD    D
  579.     LDA    SRCE
  580.     ORI    40H
  581.     STA    PRNTREC
  582.     MVI    A,':'
  583.     STA    PRNTREC+1
  584.     MVI    A,'.'
  585.     STA    PRNTYPE-1
  586.     RET
  587.  
  588. COMPREG    MOV    A,H        ;COMPARE HL TO DE
  589.     CMP    D
  590.     RNZ
  591.     MOV    A,L
  592.     CMP    E
  593.     RET
  594.  
  595. OUTPUT    PUSH    D        ;PUT OUT A CRLF
  596.     LXI    D,CRLF
  597.     MVI    C,09
  598.     CALL    BDOS
  599.     POP    D        ;NOW PUT OUT THE MESSAGE
  600. OUT1    MVI    C,09
  601.     JMP    BDOS
  602.  
  603.  
  604. QUESTION    CALL    OUTPUT    ;PUT OUT THE QUESTION
  605.     LXI    D,INBUF
  606.     MVI    C,0AH        ;INPUT THE REPLY
  607.     CALL    BDOS
  608.     LDA    INCNT        ;SEE IF ANYTHING WAS ENTERED
  609.     RET
  610.  
  611. MOVE    PUSH    H        ;MOVE DATA POINTED TO IN HL
  612.     PUSH    D        ;TO THE AREA POINTED TO IN DE
  613.     PUSH    B        ;BY THE BYTE COUNT IN B
  614. MOVE1    MOV    A,M
  615.     ANI    7FH        ;RESET THE HIGH ORDER BIT BECAUSE IT
  616.                 ;MAY HAVE BEEN TURNED ON FOR THE TYPE
  617.     STAX    D
  618.     INX    H
  619.     INX    D
  620.     DCR    B
  621.     JNZ    MOVE1
  622.     POP    B        ;RESTORE THE TOTAL ENVIRONMENT
  623.     POP    D
  624.     POP    H
  625.     RET
  626.  
  627. COMPARE    PUSH    H        ;COMPARE THE STRINGS POINTED TO IN HL
  628.     PUSH    D        ;TO THE STRING POINTED TO IN DE
  629.     PUSH    B        ;FOR A LENGTH OF B CHARACTERS
  630. COMP1    LDAX    D        ; JC IF HL > DE
  631.     CMP    M        ; JZ IF HL = DE
  632.     JNZ    COMP2        ;JNC IF HL < DE
  633.     INX    H
  634.     INX    D
  635.     DCR    B
  636.     JNZ    COMP1
  637. COMP2    POP    B
  638.     POP    D
  639.     POP    H
  640.     RET
  641.  
  642.  
  643. SIGNON    DB    'FLOPPY DISK COPY PROGRAM '
  644.     DB    '10/9/82$'
  645. ERRNOMSK DB    'ERROR...NO FILE MASK IN COMMAND'
  646.     DB    CR,LF,'COMMAND MUST BE IN THE FORMAT "FLOPCOPY *.*"'
  647.     DB    CR,LF,'$'
  648. TABFULL    DB    'MEMORY FULL...REPORT NOT COMPLETE$'
  649. NFMSG    DB    'FILE NOT FOUND...ABORTING$'
  650. DMNTMSG    DB    'DISMOUNT DISKETTE AND ENTER RETURN$'
  651. ERAMSG    DB    'ERASE COPIES ON THE HARD DISK (Y/N)? $' 
  652. MNTBLANK DB    'MOUNT A FORMATTED BLANK DISKETTE AND ENTER RETURN$'
  653. ANOTHER DB    'WANT TO COPY THE SAME FILES ON TO ANOTHER DISKETTE (Y/N)? $'
  654. ALRDYEXT DB    'FILE ALREADY EXISTS ON DESTINATION DISK.'
  655.     DB    '  ENTER Y TO COPY OVER IT: $'
  656. DSKFULL DB    'DISKETTE FULL...MOUNT ANOTHER DISK$'
  657. PRNTREC    DS    1
  658.     DB    ':'
  659. PRNFILE    DS    8
  660.     DB    '.'
  661. PRNTYPE    DS    3
  662.     DB    '    $'
  663. CRLFLFLF    DB    0DH,0AH,0AH,0AH,'$'
  664. CRLF    DB    0DH,0AH,'$'
  665. BIGMSG    DB    0DH,0AH,'FILE TOO LARGE TO FIT ON ONE DISKETTE '
  666.     DB    'SO NOT BACKED UP **** $'
  667. SRCFLPMSG DB    'SOURCE FLOPPY DRIVE (DEFAULT='
  668. SRCFLP    DB    'D) $'
  669. DESTFLPMSG DB    'DESTINATION FLOPPY DRIVE (DEFAULT='
  670. DESTFLP    DB    'D) $'
  671. HDMSG    DB    'HARD DISK DRIVE USED AS BUFFER (DEFAULT='
  672. HDTEMP    DB    'A) $'
  673. HDFCB    DS    1
  674. HDFILE    DS    8
  675. HDTYPE    DS    3
  676.     DS    24
  677. FPFCB    DS    36
  678. SRCE    DS    1
  679. DEST    DS    1
  680. INBUF    DB    30
  681. INCNT    DS    1
  682. INREC    DS    30
  683. STACK    DS    80
  684. EOF    DS    1
  685. ABORT    DS    1
  686. LINECNT    DS    1
  687. LASTTYPE DS     3
  688. LASTFILE DS    8
  689. TABADDR    DS    2
  690. TABCNT    DS    2
  691. SELFLAG    DS    1
  692. TOOBIG    DS    1
  693. ADDR1    DS    2
  694. ADDR2    DS    2
  695. ADDR3    DS    2
  696. MAX1    DS    2
  697. MAX2    DS    2
  698. RTYPE    DS    3
  699. RFILE    DS    8
  700. RDISK    DS    3
  701.     DB    '$'
  702. TEMP    DS    RECSIZE
  703. DISKBUF    DS    128
  704. COMPSIZE DS    1
  705. CR    EQU    0DH
  706. LF    EQU    0AH
  707. RAM    EQU    $
  708.     END    100H
  709.