home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / UTILS / HDUTL / BIGBURST.AQM / BIGBURST.ASM
Assembly Source File  |  2000-06-30  |  12KB  |  610 lines
  1. ; BIGBURST--BIG FILE BACKUP/RESTORE
  2. ; COPYRIGHT 1982, G. YOUNG, INC. 
  3. ; UPDATED 10/9/82
  4. * 
  5. * TO EXECUTE, ENTER THE PROGRAM NAME FOLLOWED BY THE FILE MASK:
  6. *       A>BIGBURST FILENAME.TYP/B (FOR BACKUP) OR
  7. *       A>BIGBURST FILENAME.TYP/R (FOR RESTORE)
  8. * THE PURPOSE OF THIS PROGRAM IS TO BACKUP AND RESTORE FILES FROM/TO
  9. * A HARD DISK WHERE THE FILE IS TOO BIG TO FIT ON ONE FLOPPY DISK.
  10. * IT BACKS UP BY COPYING THE LARGE FILE TO MULTIPLE SMALL FILES
  11. * WHICH WILL FIT ON THE FLOPPY.  THE FILE TYPE OF EACH OF THESE SMALL
  12. * FILES IS A SEQUENTIAL NUMBER FROM 001 TO 255 WITH THE LAST RECORD
  13. * ON THE LAST FILE CONTAINING AN INDICATOR THAT THIS IS THE LAST FILE.
  14. * THE RESTORE PROCESS IS DONE BY COMBINING THESE SMALL FILES BACK INTO
  15. * THE LARGE FILE.
  16. * CHANGED 10/9/82 TO ASK QUESTIONS ON FLOPPY DRIVE #
  17.  
  18. * WRITTEN BY GARY YOUNG, BOX 3218, NO. HOLLYWOOD, CA 91609
  19.  
  20.     TITLE    '*** BIG FILE BACKUP/RESTORE ***'
  21. BDOS    EQU    5
  22. CR    EQU    0DH
  23. LF    EQU    0AH
  24. TBUF    EQU    80H
  25. TFCB    EQU    5CH
  26. BOOT    EQU    0
  27.     ORG    100H
  28.     JMP    START
  29.     DB    'COPYRIGHT 1982, G. YOUNG, INC.'
  30. START    LXI    SP,STACK+80
  31.     LDA    TFCB+1        ;SEE IF A MASK WAS ENTERED
  32.     CPI    20H        ;BUFFER WILL BE BLANK IF NOT
  33.     JZ    INPUTERR
  34.     LXI    H,TFCB        ;SAVE THE INPUT FILE NAME
  35.     LXI    D,HOLDFCB
  36.     MVI    B,16
  37.     CALL    MOVE
  38.     LXI    D,HOLDFCB+16
  39.     MVI    B,20
  40.     CALL    CLEAR
  41.     LXI    H,TBUF        ;SEARCH FOR /B OR /R
  42.     MVI    B,80
  43. FINDSLSH MOV    A,M
  44.     CPI    '/'
  45.     JZ    BORR
  46.     INX    H
  47.     DCR    B
  48.     JNZ    FINDSLSH
  49. INPUTERR LXI    D,ERROR1
  50. ERROR    CALL    OUTPUT
  51.     JMP    BOOT
  52. BORR    INX    H        ;NEXT CHAR MUST BE A B OR R
  53.     MOV    A,M
  54.     CPI    'B'
  55.     JZ    QUEST1
  56.     CPI    'R'
  57.     JNZ    INPUTERR
  58. QUEST2    LXI    D,SRCFLPMSG
  59.     CALL    QUESTION
  60.     ORA    A
  61.     JNZ    QUEST2A
  62.     LDA    SRCFLP
  63.     JMP    QUEST2B
  64. QUEST2A LDA    INREC
  65. QUEST2B    STA    FLOPPY
  66.     JMP    RESTORE
  67.  
  68. QUEST1    LXI    D,DESTFLPMSG
  69.     CALL    QUESTION
  70.     ORA    A
  71.     JNZ    QUEST1A
  72.     LDA    DESTFLP
  73.     JMP    QUEST1B
  74. QUEST1A    LDA    INREC
  75. QUEST1B    STA    FLOPPY
  76.     JMP    BACKUP
  77.  
  78. RESTORE LXI    H,TFCB
  79.     LXI    D,HDFCB
  80.     MVI    B,12        ;CREATE A HARD DISK FCB
  81.     CALL    MOVE
  82.     LXI    D,HDFCB+12
  83.     MVI    B,24
  84.     CALL    CLEAR
  85.     LXI    H,0000
  86.     SHLD    RECCNT
  87.     XRA    A
  88.     STA    FILECNT
  89.     MVI    A,'$'        ;CREATE A TEMPORARY FILE
  90.     STA    HDFCB+9
  91.     STA    HDFCB+10
  92.     STA    HDFCB+11
  93.     LXI    H,MSG3A        ;MARK AS "RESTORE" IN MESSAGE
  94.     LXI    D,MSG3
  95.     MVI    B,8
  96.     CALL    MOVE
  97.     LXI    H,MSG0A
  98.     LXI    D,MSG0        ;CHANGE THE PROMPT MESSAGE
  99.     MVI    B,10
  100.     CALL    MOVE
  101.     LXI    D,HDFCB        ;SEE IF THE TEMP FILE IS THERE ON
  102.     MVI    C,0FH        ;THE HARD DISK
  103.     CALL    BDOS
  104.     INR    A
  105.     JZ    MAKEHD
  106.     LXI    D,HDFCB        ;DELETE IT IF IT IS
  107.     MVI    C,13H
  108.     CALL    BDOS
  109. MAKEHD    LXI    D,HDFCB        ;MAKE THE HARD DISK FILE
  110.     MVI    C,16H
  111.     CALL    BDOS
  112.     LXI    D,ERROR4    ;ERROR IF DIRECTORY FULL
  113.     INR    A
  114.     JZ    ERROR
  115. LOADFLP    CALL    GENFCB
  116. LOAD2    CALL    MOUNT
  117.     LXI    D,FLPFCB    ;SEE IF FLOPPY FILE IS ON THAT DISK
  118.     MVI    C,0FH
  119.     CALL    BDOS
  120.     INR    A
  121.     JNZ    OPEN2        ;YES, THE RIGHT ONE IS MOUNTED
  122.     LXI    D,MESSAGE2    ;NO, WRONG DISK IS MOUNTED
  123.     CALL    OUTPUT
  124.     JMP    LOAD2
  125. OPEN2    LXI    D,HDFCB+12    ;OPEN THE HARD DISK AGAIN
  126.     MVI    B,24
  127.     CALL    CLEAR
  128.     LXI    D,HDFCB
  129.     MVI    C,0FH
  130.     CALL    BDOS
  131.     LHLD    RECCNT        ;POSITION TO END OF FILE
  132.     SHLD    HDFCB+33
  133.     LXI    D,HDFCB        ;RANDOM READ
  134.     MVI    C,21H
  135.     CALL    BDOS
  136. COPYLOOP2 CALL    LOADBUFF2    ;ACTUAL COPY IS DONE HERE
  137.     CALL    WRITEBUF2
  138.     CALL    DEBUG
  139.     LDA    EOF
  140.     CPI    2
  141.     JZ    ENDOFFILE2
  142.     CPI    1
  143.     JZ    DISKMPTY
  144.     JMP    COPYLOOP2
  145. ENDOFFILE2 LXI    D,HDFCB        ;CLOSE HARD DISK
  146.     MVI    C,10H
  147.     CALL    BDOS
  148.     LXI    D,HOLDFCB    ;SEE IF THE FILE IS THERE
  149.     MVI    C,0FH
  150.     CALL    BDOS
  151.     INR    A
  152.     JZ    RENAME        ;NO, RENAME THE TEMP VERSION AS THE FINAL NAME
  153.     LXI    D,BAKFCB    ;SEE IF THERE IS A BACKUP FILE NAME THERE
  154.     MVI    B,36
  155.     CALL    CLEAR
  156.     LXI    H,HOLDFCB
  157.     LXI    D,BAKFCB
  158.     MVI    B,36
  159.     CALL    MOVE
  160.     LXI    H,BAK
  161.     LXI    D,BAKFCB+9
  162.     MVI    B,3
  163.     CALL    MOVE        ;CREATE THE BACKUP FILE NAME
  164.     LXI    D,BAKFCB    ;DELETE IT IF IT IS THERE
  165.     MVI    C,13H
  166.     CALL    BDOS
  167.     LXI    H,BAKFCB
  168.     LXI    D,HOLDFCB+16
  169.     MVI    B,16
  170.     CALL    MOVE
  171.     LXI    D,HOLDFCB    ;RENAME THE FINAL FILE NAME AS .BAK
  172.     MVI    C,17H
  173.     CALL    BDOS
  174. RENAME    LXI    H,HOLDFCB
  175.     LXI    D,HDFCB+16    ;RENAME THE TEMP FILE TO THE PERMANENT NAME
  176.     MVI    B,16
  177.     CALL    MOVE
  178.     LXI    D,HDFCB
  179.     MVI    C,17H        ;RENAME .$$$ AS .XXX (FINAL NAME)
  180.     CALL    BDOS
  181.     LXI    D,ERROR5    ;FINISHED
  182.     JMP    ERROR
  183. DISKMPTY    LXI    D,FLPFCB    ;CLOSE THE CURRENT FLOPPY FILE
  184.     MVI    C,10H
  185.     CALL    BDOS
  186.     LXI    D,HDFCB        ;CLOSE THE HARD DISK FILE ALSO, WILL OPEN
  187.     MVI    C,10H        ;AGAIN LATER, BUT MOUNTING THE NEW FLOPPY
  188.     CALL    BDOS        ;REQUIRES A RESET WHICH ASSUMES ALL CLOSED
  189.     JMP    LOADFLP
  190.  
  191.  
  192.  
  193. BACKUP LXI    H,TFCB
  194.     LXI    D,HDFCB
  195.     MVI    B,12
  196.     CALL    MOVE
  197.     LXI    D,HDFCB+12
  198.     MVI    B,24
  199.     CALL    CLEAR
  200.     LXI    H,0000
  201.     SHLD    RECCNT
  202.           LXI    D,HDFCB        ;MAKE SURE HARD DISK FILE IS THERE
  203.     MVI    C,0FH
  204.     CALL    BDOS
  205.     INR    A
  206.     JNZ    CLEARCNT
  207.     LXI    D,ERROR2    ;FILE NOT FOUND
  208.     JMP    ERROR
  209. CLEARCNT XRA    A
  210.     STA    FILECNT
  211. CREATEFLP CALL    GENFCB        ;CREATE FLOPPY FCB
  212.     CALL    MOUNT
  213.           LHLD    RECCNT        ;POSITION FILE
  214.     SHLD    HDFCB+33
  215.     LXI    D,HDFCB        ;RANDOM READ
  216.     MVI    C,21H
  217.     CALL    BDOS
  218.     LXI    D,FLPFCB    ;LOOK FOR FLOPPY NAME
  219.     MVI    C,0FH
  220.     CALL    BDOS
  221.     INR    A
  222.     JZ    MAKEFLOP
  223.     LXI    D,FLPFCB    ;DELETE IT IF IT IS THERE
  224.     MVI    C,13H
  225.     CALL    BDOS
  226. MAKEFLOP LXI    D,FLPFCB    ;CREATE THE FILE
  227.     MVI    C,16H
  228.     CALL    BDOS
  229.     LXI    D,ERROR4
  230.     INR    A
  231.     JZ    ERROR        ;DIRECTORY FULL
  232. COPYLOOP1 CALL    LOADBUFF1    ;DO ACTUAL COPYING HERE
  233.     CALL    WRITEBUF1
  234.     CALL    DEBUG
  235.     LDA    EOF
  236.     CPI    1
  237.     JZ    ENDOFFILE1
  238.     CPI    2
  239.     JZ    DISKFULL
  240.     JMP    COPYLOOP1
  241. ENDOFFILE1    LXI    D,LASTREC    ;ADD END OF ALL FILES RECORD
  242.     MVI    C,1AH
  243.     CALL    BDOS
  244.     LXI    D,FLPFCB
  245.     MVI    C,15H        ;WRITE IT
  246.     CALL    BDOS
  247.     LXI    D,FLPFCB
  248.     MVI    C,10H        ;CLOSE FLOPPY
  249.     CALL    BDOS
  250.     LXI    D,ERROR5
  251.     JMP    ERROR        ;FINISHED
  252. DISKFULL LXI    D,FLPFCB
  253.     MVI    C,10H        ;CLOSE FLOPPY
  254.     CALL    BDOS
  255.     JMP    CREATEFLP 
  256.  
  257. GENFCB    LXI    D,FLPFCB    ;CREATE THE FLOPPY NAME
  258.     MVI    B,36
  259.     CALL    CLEAR
  260.     LXI    H,HOLDFCB+1
  261.     LXI    D,FLPFCB+1
  262.     MVI    B,11
  263.     CALL    MOVE
  264.     LDA    FLOPPY
  265.     ANI    0FH
  266.     STA    FLPFCB
  267.     LXI    D,ERROR3
  268.     LDA    FILECNT
  269.     INR    A
  270.     STA    FILECNT
  271.     JZ    ERROR        ;TOO MANY FLOPPIES
  272.     MVI    H,0
  273.     MOV    L,A
  274.     SHLD    MPTY
  275.     LXI    D,FLPFCB+9    ;SET FILE TYPE TO SEQUENCE NUMBER
  276.     LXI    H,64H
  277.     SHLD    TEMP2
  278.     CALL    DIVID2
  279.     LXI    H,0AH
  280.     SHLD    TEMP2
  281.     CALL    DIVID2
  282.     LDA    MPTY
  283.     ADI    '0'
  284.     STAX    D
  285.     RET
  286.  
  287. DEBUG    LHLD    RECCNT        ;THIS PRINTS THE RECORD # JUST WRITTEN
  288.     SHLD    MPTY        ;FOR DEBUG PURPOSES
  289.     LXI    D,DBMSG+2
  290.     LXI    H,2710H
  291.     SHLD    TEMP2
  292.     CALL    DIVID2
  293.     LXI    H,03E8H
  294.     SHLD    TEMP2
  295.     CALL    DIVID2
  296.     LXI    H,64H
  297.     SHLD    TEMP2
  298.     CALL    DIVID2
  299.     LXI    H,0AH
  300.     SHLD    TEMP2
  301.     CALL    DIVID2
  302.     LDA    MPTY
  303.     ADI    '0'
  304.     STAX    D
  305.     LXI    D,DBMSG
  306.     CALL    OUTPUT
  307.     RET
  308.  
  309. DIVID2    PUSH    D
  310.     MVI    E,0
  311.     LHLD    MPTY
  312.     SHLD    TEMP
  313. SB22    LXI    B,TEMP
  314.     LXI    H,TEMP2
  315.     XRA    A
  316.     LDAX    B
  317.     SBB    M
  318.     STAX    B
  319.     INX    B
  320.     INX    H
  321.     LDAX    B
  322.     SBB    M
  323.     STAX    B
  324.     JC    NEG2
  325.     INR    E
  326.     PUSH    H
  327.     LHLD    TEMP
  328.     SHLD    MPTY
  329.     POP    H
  330.     JMP    SB22
  331. NEG2    MOV    A,E
  332. DIV2    ADI    '0'
  333.     POP    D
  334.     STAX    D
  335.     INX    D
  336.     RET
  337.  
  338. MOUNT    LXI    H,FLPFCB+1
  339.     LXI    D,MSG1
  340.     MVI    B,8
  341.     CALL    MOVE
  342.     LXI    D,MSG4
  343.     CALL    MOVE
  344.     LXI    H,FLPFCB+9
  345.     LXI    D,MSG2
  346.     MVI    B,3
  347.     CALL    MOVE
  348.     LXI    D,MSG5
  349.     CALL    MOVE
  350.     LXI    D,MESSAGE1
  351.     CALL    OUTPUT
  352.     LXI    D,INBUF
  353.     MVI    C,0AH
  354.     CALL    BDOS
  355.     MVI    C,0DH        ;RESET THE DISK SYSTEM
  356.     CALL    BDOS
  357.     RET
  358.  
  359. CLEAR    XRA    A
  360. CLEAR2    STAX    D
  361.     INX    D
  362.     DCR    B
  363.     JNZ    CLEAR2
  364.     RET
  365.  
  366. ;FOR BACKUP...LOAD FROM HARD DISK, WRITE TO FLOPPY
  367. LOADBUFF1 EQU    $    ;THIS ROUTINE LOADS AS MUCH OF
  368.     LXI    H,0000        ;MEMORY WITH THE FILE AS POSSIBLE
  369.     SHLD    MAX1
  370.     LXI    H,ADDR3
  371.     SHLD    TEMP
  372.     XRA    A
  373.     STA    EOF        ;CLEAR EOF FLAG
  374. LOADNEXT    LHLD    TEMP
  375.     XCHG            ;SET DMA ADDRESS
  376.     MVI    C,1AH
  377.     CALL    BDOS
  378.     LXI    D,HDFCB        ;READ HARD DISK
  379.     MVI    C,14H
  380.     CALL    BDOS
  381.     ORA    A
  382.     JNZ    HDEOF        ;EOF?
  383.     LHLD    MAX1
  384.     INX    H        ;INCREMENT RECORD COUNT
  385.     SHLD    MAX1
  386.     LHLD    TEMP        ;SEE IF NEXT RECORD WOULD EXCEED THE
  387.     LXI    D,128        ;TPA AREA
  388.     DAD    D
  389.     SHLD    TEMP
  390.     DAD    D        ;WILL THE NEXT RECORD OVERWRITE BDOS?
  391.     XCHG
  392.     LHLD    BDOS+1        ;FIND THE TOP OF MEMORY
  393.     CALL    COMPREG        ;COMPARE REGISTERS
  394.     RC            ;RETURN IF MEMORY ALREADY FULL
  395.     JMP    LOADNEXT    ;GET ANOTHER RECORD
  396. HDEOF    MVI    A,1        ;SET FILE EOF
  397.     STA    EOF
  398.     RET
  399.  
  400. WRITEBUF1 EQU    $    ;WRITE FROM THE MEMORY BUFFER
  401.     LXI    H,ADDR3
  402.     SHLD    TEMP
  403.     LHLD    MAX1        ;ALLOW FOR FILES THAT HAVE NO 
  404.     LXI    D,0000        ;RECORDS SUCH AS RESTART
  405.     CALL    COMPREG
  406.     RZ
  407. WRITENEXT    LHLD    TEMP
  408.     XCHG            ;SET DMA ADDRESS
  409.     MVI    C,1AH
  410.     CALL    BDOS
  411.     LXI    D,FLPFCB
  412.     MVI    C,15H        ;WRITE SEQUENTIAL
  413.     CALL    BDOS
  414.     ORA    A
  415.     JNZ    FPFULL2
  416.     LHLD    RECCNT
  417.     INX    H
  418.     SHLD    RECCNT
  419.     LHLD    MAX1        ;DECREASE RECORD COUNT
  420.     DCX    H
  421.     SHLD    MAX1
  422.     LXI    D,0000        ;CHECK FOR NO MORE TO WRITE
  423.     CALL    COMPREG
  424.     RZ
  425.     LHLD    TEMP
  426.     LXI    D,128        ;INCREMENT WRITE ADDRESS
  427.     DAD    D
  428.     SHLD    TEMP
  429.     JMP    WRITENEXT
  430. FPFULL2    MVI    A,2        ;FULL DISKETTE
  431.     STA    EOF
  432.     RET
  433.  
  434. ;FOR RESTORE, LOAD FROM FLOPPY, WRITE TO HARD DISK
  435. LOADBUFF2 EQU    $    ;THIS ROUTINE LOADS AS MUCH OF
  436.     LXI    H,0000        ;MEMORY WITH THE FILE AS POSSIBLE
  437.     SHLD    MAX1
  438.     LXI    H,ADDR3
  439.     SHLD    TEMP
  440.     XRA    A
  441.     STA    EOF        ;CLEAR EOF FLAG
  442. LOADNEXT2 LHLD    TEMP
  443.     XCHG            ;SET DMA ADDRESS
  444.     MVI    C,1AH
  445.     CALL    BDOS
  446.     LXI    D,FLPFCB    ;READ THE FLOPPY
  447.     MVI    C,14H
  448.     CALL    BDOS
  449.     ORA    A
  450.     JNZ    HDEOF2        ;EOF?
  451.     LHLD    TEMP
  452.     LXI    D,LASTREC
  453.     MVI    B,26        ;SEE IF THIS IS THE LASTREC OF LAST FILE
  454.     CALL    COMPARE
  455.     JZ    EOFHD 
  456.     LHLD    MAX1
  457.     INX    H        ;INCREMENT RECORD COUNT
  458.     SHLD    MAX1
  459.     LHLD    TEMP        ;SEE IF NEXT RECORD WOULD EXCEED THE
  460.     LXI    D,128        ;TPA AREA
  461.     DAD    D
  462.     SHLD    TEMP
  463.     DAD    D        ;WILL THE NEXT RECORD OVERWRITE BDOS?
  464.     XCHG
  465.     LHLD    BDOS+1        ;FIND THE TOP OF MEMORY
  466.     CALL    COMPREG        ;COMPARE REGISTERS
  467.     RC            ;RETURN IF MEMORY ALREADY FULL
  468.     JMP    LOADNEXT2    ;GET ANOTHER RECORD
  469. EOFHD    MVI    A,2
  470.     STA    EOF
  471.     RET
  472. HDEOF2    MVI    A,1        ;SET FILE EOF
  473.     STA    EOF
  474.     RET
  475.  
  476. WRITEBUF2 EQU    $    ;WRITE FROM THE MEMORY BUFFER
  477.     LXI    H,ADDR3
  478.     SHLD    TEMP
  479.     LHLD    MAX1        ;ALLOW FOR FILES THAT HAVE NO 
  480.     LXI    D,0000        ;RECORDS SUCH AS RESTART
  481.     CALL    COMPREG
  482.     RZ
  483. WRITENEXT2 LHLD    TEMP
  484.     XCHG            ;SET DMA ADDRESS
  485.     MVI    C,1AH
  486.     CALL    BDOS
  487.     LXI    D,HDFCB
  488.     MVI    C,15H        ;WRITE SEQUENTIAL
  489.     CALL    BDOS
  490.     ORA    A
  491.     JNZ    FPFULL        ;FLOPPY DISK FULL
  492.     LHLD    RECCNT
  493.     INX    H
  494.     SHLD    RECCNT
  495.     LHLD    MAX1        ;DECREASE RECORD COUNT
  496.     DCX    H
  497.     SHLD    MAX1
  498.     LXI    D,0000        ;CHECK FOR NO MORE TO WRITE
  499.     CALL    COMPREG
  500.     RZ
  501.     LHLD    TEMP
  502.     LXI    D,128        ;INCREMENT WRITE ADDRESS
  503.     DAD    D
  504.     SHLD    TEMP
  505.     JMP    WRITENEXT2
  506. FPFULL    MVI    A,2        ;FULL DISKETTE
  507.     STA    EOF
  508.     RET
  509.  
  510. COMPREG    MOV    A,H        ;COMPARE HL TO DE
  511.     CMP    D
  512.     RNZ
  513.     MOV    A,L
  514.     CMP    E
  515.     RET
  516.  
  517. OUTPUT    PUSH    D        ;PUT OUT A CRLF
  518.     LXI    D,CRLF
  519.     MVI    C,09
  520.     CALL    BDOS
  521.     POP    D        ;NOW PUT OUT THE MESSAGE
  522. OUT1    MVI    C,09
  523.     JMP    BDOS
  524.  
  525.  
  526. QUESTION    CALL    OUTPUT    ;PUT OUT THE QUESTION
  527.     LXI    D,INBUF
  528.     MVI    C,0AH        ;INPUT THE REPLY
  529.     CALL    BDOS
  530.     LDA    INCNT
  531.     RET
  532.  
  533. MOVE    PUSH    H        ;MOVE DATA POINTED TO IN HL
  534.     PUSH    D        ;TO THE AREA POINTED TO IN DE
  535.     PUSH    B        ;BY THE BYTE COUNT IN B
  536. MOVE1    MOV    A,M
  537.     STAX    D
  538.     INX    H
  539.     INX    D
  540.     DCR    B
  541.     JNZ    MOVE1
  542.     POP    B        ;RESTORE THE TOTAL ENVIRONMENT
  543.     POP    D
  544.     POP    H
  545.     RET
  546.  
  547. COMPARE    PUSH    H        ;COMPARE THE STRINGS POINTED TO IN HL
  548.     PUSH    D        ;TO THE STRING POINTED TO IN DE
  549.     PUSH    B        ;FOR A LENGTH OF B CHARACTERS
  550. COMP1    LDAX    D        ; JC IF HL > DE
  551.     CMP    M        ; JZ IF HL = DE
  552.     JNZ    COMP2        ;JNC IF HL < DE
  553.     INX    H
  554.     INX    D
  555.     DCR    B
  556.     JNZ    COMP1
  557. COMP2    POP    B
  558.     POP    D
  559.     POP    H
  560.     RET
  561.  
  562.  
  563. CRLF    DB    CR,LF,'$'
  564. ERROR1    DB    'INPUT ERROR...ENTER FILENAME.TYP/B OR /R',CR,LF,LF,'$'
  565. ERROR2    DB    'FILE NOT FOUND',CR,LF,LF,'$'
  566. ERROR3    DB    'NEEDS MORE THAN 255 FLOPPY DISKS',CR,LF,LF,'$'
  567. ERROR4    DB    'DIRECTORY FULL',CR,LF,LF,'$'
  568. ERROR5    DB    'FINISHED',CR,LF,LF,'$'
  569. MSG0A    DB    'CONTAINING'
  570. BAK    DB    'BAK'
  571. MSG3A    DB    'RESTORE '
  572. LASTREC    DB    'ENDENDENDBIGBURSTENDENDEND'
  573. MESSAGE1 DB    CR,LF,LF,'MOUNT THE DISKETTE '
  574. MSG0    DB    'TO CONTAIN '
  575. MSG1    DS    8
  576.     DB    '.'
  577. MSG2    DS    3
  578.     DB    ' FOR '
  579. MSG3    DB    'BACKUP  '
  580.     DB    'AND HIT RETURN$'
  581. MESSAGE2 DB    CR,LF,'FILE '
  582. MSG4    DS    8
  583.     DB    '.'
  584. MSG5    DS    3
  585.     DB    ' IS NOT ON THIS DISKETTE$'
  586. SRCFLPMSG DB    'SOURCE FLOPPY DRIVE (DEFAULT='
  587. SRCFLP    DB    'D) $'
  588. DESTFLPMSG DB    'DESTINATION FLOPPY DRIVE (DEFAULT='
  589. DESTFLP    DB    'D) $'
  590. DBMSG    DB    CR,LF
  591.     DB    '00000$'
  592. INBUF    DB    30
  593. INCNT    DS    1
  594. INREC    DS    30
  595. FLOPPY    DS    1
  596. RECCNT    DS    2
  597. HOLDFCB    DS    36
  598. HDFCB    DS    36
  599. BAKFCB    DS    48
  600. FILECNT    DS    1
  601. FLPFCB    DS    36
  602. TEMP    DS    2
  603. TEMP2    DS    2
  604. MPTY    DS    2
  605. MAX1    DS    2
  606. EOF    DS    1
  607. STACK    DS    90
  608. ADDR3    EQU    $
  609.     END    100H
  610.