home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / UTILS / DIRUTL / MDIR21.AQM / MDIR21.ASM
Assembly Source File  |  2000-06-30  |  12KB  |  535 lines
  1. ;            MDIR.ASM 2.1
  2. ;             revised 02/25/82
  3. ;
  4. ;       CP/M-2 MASTER DISK DIRECTORY PROGRAM
  5. ;            by Jeff Hammersley, MD.
  6. ;
  7. ; PRINTS A COMPLETE DISK DIRECTORY INCLUDING ALL USERS,
  8. ; SORTED ALPHABETICALLY AND PRINTED 4 WIDE.
  9. ;
  10. ; Based on 'FMAP' as originally written by Ward Christensen
  11. ; and its subsequent evolution to 'SDIR' by Keith Petersen.
  12. ;
  13. ;---------------------------------------------------------------;
  14. ;                                ;
  15. ; Commands:                            ;
  16. ;                                ;
  17. ; MDIR      returns all files on the default disk under any user. ;
  18. ;                                ;
  19. ; Note: optional drive name may be specified.            ;
  20. ;                                ;
  21. ;                                ;
  22. ; MDIR FILENAME.FILETYPE    searches for all files that match    ;
  23. ;        in all user areas.                ;
  24. ;                                ;
  25. ; MDIR S???.*  returns all 4 character files with any extention ;
  26. ;        in any user areas.                ;
  27. ;                                ;
  28. ;_______________________________________________________________;
  29. ; 
  30. ; 02/25/82 FIXED PROBLEM WITH TOP-OF-MEMORY CHECK...PROGRAM NOW
  31. ;       KEEPS TRACK OF WHETHER OR NOT IT OVERWRITES CCP, AND
  32. ;       DOES A WARM BOOT IF NECESSARY.  ALSO ADDED TOP-OF-MEM
  33. ;       CHECK IN BLDORD (MISSED THAT IN VERSION 2.0).  THANKS
  34. ;       TO KEITH PETERSEN (W8SDZ) FOR POINTING OUT THESE DEF-
  35. ;       ICIENCIES.           RON FOWLER
  36. ;
  37. ; 01/11/81 FIXED PROBLEM WITH SYSTEMS USING NON-ZERO EXTENT MASKS
  38. ;       BY MODIFYING EXTENT CHECK WITHIN 80H BUFFER TO USE EXM
  39. ;       FIELD OF THE DISK PARAMETER BLOCK.
  40. ;       ALSO REMOVED "NAMES" COUNT, ADDED DYNAMIC MEMORY SIZING,
  41. ;       AND OUT-OF-MEMORY CHECK.
  42. ;       (you may wonder: "with the power of SD-4x, why bother
  43. ;       with MDIR?"...answer: "I like its simplicity.")
  44. ;       
  45. ;            -- RON FOWLER
  46. ;
  47. ;07/02/80 FIXED TO ALLOW MORE THAN 256 NAMES IN DIRECTORY,
  48. ;      PRINT DRIVE NAME, AND ALLOW SPECIFYING DRIVE.
  49. ;      BY KEITH PETERSEN, W8SDZ.
  50. ;
  51. ;07/30/80 FIXED TO ELIMINATE CRASH WHEN NO NAMES ARE IN
  52. ;      DIRECTORY. REPLACED DECIMAL OUTPUT ROUTINE WITH
  53. ;      SIMPLER ONE WHICH IS SMALLER AND ALLOWS USE OF
  54. ;      ONE LESS LEADING SPACE SO DISPLAY CAN BE PRINTED
  55. ;      ON A 72-CHARACTER PRINTER. (KBP)
  56. ;
  57. ;08/17/80 CORRECTED MISSING INR A IN SEARCH FIRST ROUTINE,
  58. ;      WHICH CAUSED DUPLICATE LISTING OF THIRD DIRECTORY
  59. ;      ENTRY. (KBP)
  60. ;
  61. BASE    SET    0
  62. ;
  63. ALTCPM    EQU    0    ;PUT 1 HERE FOR H8 OR TRS-80 CP/M
  64. ;
  65.     IF    ALTCPM
  66. BASE    SET    4200H
  67.     ENDIF
  68. ;
  69. GETVER    EQU    12    ;GET VERSION BDOS FUNCT #
  70. GETDPB    EQU    31    ;GET DPB ADRS BDOS FUNCT #
  71. ;
  72. FCB    EQU    BASE+5CH ;SYSTEM FCB
  73. NPL    EQU    4    ;NUMBER OF NAMES PER LINE
  74. CR    EQU    0DH    ;CARRIAGE RETURN
  75. LF    EQU    0AH    ;LINE FEED
  76. DELIM    EQU    ':'    ;FENCE (DELIMITER) CHARACTER
  77. ;
  78.     ORG    BASE+100H
  79. ;
  80.     JMP    START    ;JUMP AROUND I.D.
  81.     DB    'MDIR.COM 02/25/82 '
  82. ;
  83. ;SAVE THE STACK
  84. START    LXI    H,0
  85.     DAD    SP    ;H=STACK
  86.     SHLD    STACK    ;SAVE IT
  87.     LXI    SP,STACK ;GET NEW STACK
  88.     LDA    FCB
  89.     ORA    A    ;ANY DRIVE SPECIFIED?
  90.     JZ    FSPEC2
  91.     DCR    A    ;CORRECT DISK NUMBER FOR CP/M
  92.     PUSH    PSW    ;SAVE REQUESTED DISK NUMBER
  93.     MVI    C,CURDSK ;FIND OUT WHERE WE'RE LOGGED
  94.     CALL    BDOS
  95.     STA    CDSK    ;SAVE IT FOR LATER
  96.     POP    PSW    ;GET REQUESTED DISK NR.
  97.     MOV    E,A    ;TO E FOR CP/M
  98.     MVI    C,SELDSK ;SELECT DISK REQUESTED
  99.     CALL    BDOS
  100. ;
  101. FSPEC2    MVI    C,CURDSK ;FIND OUT WHERE WE'RE LOGGED
  102.     CALL    BDOS
  103.     ADI    'A'    ;MAKE PRINTABLE
  104.     STA    DRNAME
  105. ;PRINT HEADER
  106.     CALL    GETEXM    ;GET EXTENT MASK
  107.     CALL    FSPEC3
  108.     DB    CR,LF
  109.     DB    '...Master Directory - Drive '
  110. DRNAME    DB    'X:'
  111.     DB    CR,LF,CR,LF,'$'
  112. ;
  113. FSPEC3    POP    D
  114.     MVI    C,PRINT
  115.     CALL    BDOS
  116.     LXI    H,FCB+1
  117.     MOV    A,M    ;GET 1ST CHAR. OF NAME REQUEST
  118.     STA    SAVFCB    ;SAVE FOR LATER
  119. ;
  120. ;MAKE DR FIELD OF FCB '?' TO FORCE RETURN OF ALL USER ENTRIES
  121.     DCX    H    ;POINT TO DR FIELD
  122.     MVI    M,'?'    ;STORE '?' IN FCB
  123. ;
  124. ;RETURN ALL DIRECTORY ENTRIES
  125.     MVI    C,FSRCHF ;GET 'SEARCH FIRST' FNC
  126.     LXI    D,FCB
  127.     CALL    BDOS    ;READ FIRST
  128.     INR    A    ;COMPENSATE FOR LATER DCR
  129.     JMP    SOME    ;GOT SOME (BECAUSE OF ? IN DR FIELD)
  130. ;
  131. ;READ MORE DIRECTORY ENTRIES
  132. MOREDIR MVI    C,FSRCHN ;SEARCH NEXT
  133.     LXI    D,FCB
  134.     CALL    BDOS    ;READ DIR ENTRY
  135.     INR    A    ;CHECK FOR END (0FFH)
  136.     JZ    SPRINT    ;NO MORE - SORT & PRINT
  137. ;
  138. ;POINT TO DIRECTORY ENTRY 
  139. SOME    DCR    A    ;UNDO PREV 'INR A'
  140.     ANI    3    ;MAKE MODULUS 4
  141.     ADD    A    ;MULTIPLY...
  142.     ADD    A    ;..BY 32 BECAUSE
  143.     ADD    A    ;..EACH DIRECTORY
  144.     ADD    A    ;..ENTRY IS 32
  145.     ADD    A    ;..BYTES LONG
  146.     LXI    H,BASE+80H ;POINT TO BUFFER
  147.     ADD    L    ;POINT TO ENTRY
  148.     MOV    L,A    ;SAVE (CAN'T CARRY TO H)
  149. ;MOVE ENTRY TO TABLE
  150.     MOV    A,M    ;GET DR FIELD
  151.     CPI    0E5H    ;IS IT AN ERASED FILE ?
  152.     JZ    MOREDIR ;YES, IGNORE AND GET ANOTHER
  153.     XCHG        ;ENTRY TO DE
  154.     LXI    H,12    ;OFFSET TO EXTENT BYTE
  155.     DAD    D
  156.     LDA    EXTMSK    ;GET DPB EXTENT MASK
  157.     CMA        ;GET NOT(EXTMSK)
  158.     ANA    M    ;MASK OUT ZERO-EXT BITS
  159.     JNZ    MOREDIR ;IGNORE NON-ZERO PHYSICAL EXTENTS
  160.     LHLD    NEXTT    ;NEXT TABLE ENTRY TO HL
  161.     MVI    B,12    ;ENTRY LENGTH
  162.     LDA    BASE+7    ;GET TOP OF SYS PAGE #
  163.     MOV    C,A    ;INTO C REG
  164. ;
  165. TMOVE    LDAX    D    ;GET ENTRY CHAR
  166.     ANI    7FH    ;REMOVE ATTRIBUTES
  167.     MOV    M,A    ;STORE IN TABLE
  168.     INX    D
  169.     INX    H
  170.     MOV    A,H    ;SUBTRACT PTR FROM TOP
  171.     SUB    C
  172.     JNZ    OKMEM    ;JUMP, NOT OUT OF MEM
  173. ;
  174. MEMFUL: CALL    ERXIT    ;OOPS, END REACHED
  175.     DB    CR,LF,'OUT OF MEMORY'
  176.     DB    CR,LF,'$'
  177. ;
  178. OKMEM:    DCR    B    ;MORE?
  179.     JNZ    TMOVE
  180.     SHLD    NEXTT    ;SAVE UPDATED TABLE ADDR
  181.     LHLD    COUNT    ;GET PREV COUNT
  182.     INX    H    ;ADD ONE
  183.     SHLD    COUNT    ;RESAVE COUNT
  184.     JMP    MOREDIR
  185. ;
  186. ;SORT AND PRINT
  187. SPRINT    LHLD    NEXTT    ;DEFINE ORDER TABLE LOC
  188.     SHLD    ORDER
  189.     LHLD    COUNT    ;GET COUNT
  190.     MOV    A,H
  191.     ORA    L    ;CHECK FOR ZERO COUNT
  192.     JZ    NFEXIT    ;NOTHING IN DIRECTORY, EXIT
  193.     SHLD    OCOUNT    ;SAVE FOR ORDER TABLE COUNT
  194.     SHLD    SCOUNT    ;SAVE FOR SORT COUNT
  195.     LHLD    ORDER
  196.     LXI    D,TABLE
  197.     LXI    B,12    ;ENTRY LENGTH
  198. ;
  199. BLDORD    MOV    M,E    ;SAVE LO ORD ADDR
  200.     INX    H
  201.     MOV    M,D    ;SAVE HI ORD ADDR
  202.     INX    H
  203. ;
  204. ; TEST FOR MEMORY LIMIT EXCEEDED
  205. ;
  206.     LDA    BASE+7    ;GET TOP PAGE #
  207.     SUB    H    ;SUBTRACT CURRENT PAGE NUMBER
  208.     JZ    MEMFUL    ;ERROR OUT WHEN WE GET TOO HIGH
  209.     XCHG        ;TABLE ADDR TO HL
  210.     DAD    B    ;POINT TO NEXT ENTRY
  211.     XCHG        ;NEXT ENTRY TO DE
  212.     PUSH    H
  213.     LHLD    OCOUNT    ;GET COUNT
  214.     DCX    H    ;ONE LESS
  215.     SHLD    OCOUNT    ;SAVE NEW COUNT
  216.     MOV    A,L
  217.     ORA    H    ;MORE?
  218.     POP    H
  219.     JNZ    BLDORD    ;..YES
  220.     SHLD    HIMEM    ;SAVE FOR CCP REBOOT FLAG
  221.     LHLD    COUNT    ;GET COUNT
  222.     DCX    H
  223.     MOV    A,L
  224.     ORA    H    ;ONLY 1 ENTRY?
  225.     JZ    DONE    ;..YES, SO SKIP SORT
  226. ;
  227. SORT    XRA    A    ;GET A ZERO
  228.     STA    SWITCH    ;SHOW NONE SWITCHED
  229.     LHLD    SCOUNT    ;GET COUNT
  230.     DCX    H    ;USE 1 LESS
  231.     SHLD    TEMP    ;SAVE # TO COMPARE
  232.     SHLD    SCOUNT    ;SAVE HIGHEST ENTRY
  233.     MOV    A,L
  234.     ORA    H
  235.     JZ    DONE    ;EXIT IF NO MORE
  236.     LHLD    ORDER    ;POINT TO ORDER TABLE
  237. ;
  238. SORTLP    CALL    COMPR    ;COMPARE 2 ENTRIES
  239.     CM    SWAP    ;SWAP IF NOT IN ORDER
  240.     INX    H    ;BUMP ORDER
  241.     INX    H    ;..TABLE POINTER
  242.     PUSH    H
  243.     LHLD    TEMP    ;GET COUNT
  244.     DCX    H    ;ONE LESS
  245.     SHLD    TEMP    ;SAVE COUNT
  246.     MOV    A,L
  247.     ORA    H    ;DONE?
  248.     POP    H
  249.     JNZ    SORTLP    ;CONTINUE
  250. ;ONE PASS OF SORT DONE
  251.     LDA    SWITCH    ;ANY SWAPS DONE?
  252.     ORA    A
  253.     JNZ    SORT
  254. ;
  255. ;SORT IS ALL DONE - PRINT ENTRIES
  256. DONE    LHLD    ORDER
  257.     SHLD    NEXTT
  258. ;
  259. ;PRINT AN ENTRY
  260.     MVI    C,NPL    ;NR. OF NAMES PER LINE
  261. ;
  262. ENTRY:    PUSH    B
  263.     MVI    C,CONST ;CK STATUS OF KBD
  264.     CALL    BDOS    ;ANY KEY PRESSED?
  265.     POP    B
  266.     ORA    A
  267.     JNZ    ABORT    ;YES, ABORT
  268.     LHLD    NEXTT    ;GET ORDER TABLE POINTER
  269.     MOV    E,M    ;GET LO ADDR
  270.     INX    H
  271.     MOV    D,M    ;GET HI ADDR
  272.     INX    H
  273.     SHLD    NEXTT    ;SAVE UPDATED TABLE POINTER
  274.     XCHG        ;TABLE ENTRY TO HL
  275.     LDA    SAVFCB    ;GET SAVED 1ST CHAR. OF FCB
  276.     CPI    ' '    ;WAS NAME SPECIFIED?
  277.     JNZ    MATCH    ;YES, GO SEE IF PRESENT
  278. ;
  279. ;PRINT USER #
  280. PTONE    MOV    A,M    ;GET USER NUMBER
  281.     CPI    32    ;IS IT VALID ? (IE.< 32)
  282.     JNC    NULL    ; NO, IGNORE IT
  283.     ORA    A    ;IS IT USER 0 ?
  284.     JNZ    PTONE2    ;NO, SKIP NEXT ROUTINE
  285.     CALL    SPACE2    ;USER 0, FILL WITH SPACES
  286.     JMP    PTONE3    ;SKIP DECOUT PRINT
  287. ;
  288. PTONE2    PUSH    H
  289.     MVI    H,0
  290.     MOV    L,A    ;NUMBER TO L FOR DECOUT
  291.     CPI    10    ;LESS THAN 10?
  292.     CC    SPACE    ;YES, ADD ONE SPACE
  293.     CALL    DECOUT    ;PRINT USER NUMBER
  294.     POP    H
  295. ;
  296. PTONE3    CALL    SPACE    ;MAKE IT LOOK NICE
  297.     INX    H    ;POINT TO NAME
  298.     MVI    B,8    ;FILE NAME LENGTH
  299.     CALL    TYPEIT    ;TYPE FILENAME
  300.     CALL    PERIOD    ;PERIOD AFTER FN
  301.     MVI    B,3    ;GET THE FILETYPE
  302.     CALL    TYPEIT
  303.     DCR    C    ;ONE LESS ON THIS LINE
  304.     PUSH    PSW
  305.     CNZ    FENCE    ;NO CR-LF NEEDED, DO FENCE
  306.     POP    PSW
  307.     CZ    CRLF    ;CR-LF NEEDED
  308. ;
  309. ;SEE IF MORE ENTRIES
  310. NULL    PUSH    H
  311.     LHLD    COUNT
  312.     DCX    H
  313.     SHLD    COUNT
  314.     MOV    A,L
  315.     ORA    H
  316.     POP    H
  317.     JNZ    ENTRY    ;YES, MORE
  318.     JMP    EXIT
  319. ;
  320. MATCH    PUSH    D    ;SAVE DE
  321.     PUSH    H    ;SAVE HL
  322.     LXI    D,FCB    ;GET FCB REQUEST
  323.     INX    H    ;MOVE TO FN.FT
  324.     INX    D    ;
  325.     MVI    B,11    ;GET NUMBER OF CHARACTERS TO COMPARE
  326. ;
  327. MAT1    LDAX    D    ;GET CHARACTER
  328.     CPI    '*'    ;IS FILENAME OR FILETYPE AMBIGUOUS ?
  329.     JZ    WHCH    ; YES, DETERMINE WHICH ONE
  330.     CPI    '?'    ;IS IT A AMBIGUOUS CHARACTER ?
  331.     JZ    AMBC    ; YES
  332.     CMP    M    ;COMPARE TO MEMORY
  333.     JNZ    NOMATCH ;MATCH FAILURE
  334. ;
  335. AMBC    INX    D
  336.     INX    H    ;GET NEW CHARACTERS
  337.     DCR    B    ;ARE WE DONE ?
  338.     JNZ    MAT1    ;NO, COMPARE NEXT
  339. ;
  340. FTYP    POP    H
  341.     POP    D    ;RESTORE REGISTERS
  342.     JMP    PTONE    ;GO PRINT ONE
  343. ;
  344. ; SUBROUTINE TO RETRIEVE EXTENT MASK FROM DISK PARM BLK
  345. ;
  346. GETEXM: MVI    C,GETVER ;GET CP/M VERSION NUMBER
  347.     CALL    BDOS
  348.     MOV    A,H
  349.     ORA    L    ;TEST FOR VERS 1.4
  350.     JZ    PUTEXM    ;MOVE THE ZERO EXTMSK IF 1.4
  351.     MVI    C,GETDPB ;IS CPM >1.4, GET DPB ADRS
  352.     CALL    BDOS
  353.     LXI    D,4    ;INDEX TO EXTMSK
  354.     DAD    D
  355.     MOV    A,M    ;FETCH EXTENT MASK
  356. ;
  357. PUTEXM: STA    EXTMSK    ;PUT IT AWAY
  358.     RET
  359. ;
  360. WHCH    MOV    A,B    ;GET B
  361.     CPI    3    ;IS IT STILL THE FILENAME ?
  362.     JC    FTYP    ; NO, IT IS ANY TYPE SO WE ARE DONE.
  363.     MVI    B,3    ;YES, LOAD UP TO FILETYPE
  364.     JMP    MAT1    ;RETURN FOR MORE
  365. ;
  366. NOMATCH POP    H
  367.     POP    D    ;RESTORE REGISTERS
  368.     JMP    NULL    ;GET NEW FILENAME TO TRY
  369. ;
  370. PERIOD    MVI    A,'.'
  371.     JMP    TYPE
  372. ;
  373. FENCE    CALL    SPACE2
  374.     MVI    A,DELIM ;FENCE CHARACTER
  375.     JMP    TYPE
  376. ;
  377. SPACE3    CALL    SPACE
  378. ;
  379. SPACE2    CALL    SPACE
  380. ;
  381. SPACE    MVI    A,' '
  382. ;
  383. ;TYPE CHAR IN A
  384. TYPE    PUSH    B
  385.     PUSH    D
  386.     PUSH    H
  387.     MOV    E,A
  388.     MVI    C,WRCHR
  389.     CALL    BDOS
  390.     POP    H
  391.     POP    D
  392.     POP    B
  393.     RET
  394. ;
  395. TYPEIT    MOV    A,M
  396.     CALL    TYPE
  397.     INX    H
  398.     DCR    B
  399.     JNZ    TYPEIT
  400.     RET
  401. ;
  402. CRLF    MVI    A,CR    ;CARRIAGE RETURN
  403.     CALL    TYPE
  404.     MVI    A,LF    ;LINE FEED
  405.     CALL    TYPE
  406.     MVI    C,NPL    ;NUMBER OF NAMES PER LINE
  407.     RET
  408. ;
  409. ;DECIMAL OUTPUT ROUTINE
  410. ;
  411. DECOUT: PUSH    B
  412.     PUSH    D
  413.     PUSH    H
  414.     LXI    B,-10
  415.     LXI    D,-1
  416. ;
  417. DECOU2: DAD    B
  418.     INX    D
  419.     JC    DECOU2
  420.     LXI    B,10
  421.     DAD    B
  422.     XCHG
  423.     MOV    A,H
  424.     ORA    L
  425.     CNZ    DECOUT
  426.     MOV    A,E
  427.     ADI    '0'
  428.     CALL    TYPE
  429.     POP    H
  430.     POP    D
  431.     POP    B
  432.     RET
  433. ;
  434. ;COMPARE ROUTINE FOR SORT
  435. COMPR    PUSH    H    ;SAVE TABLE ADDR
  436.     MOV    E,M    ;LOAD LO
  437.     INX    H
  438.     MOV    D,M    ;LOAD HI
  439.     INX    H
  440.     MOV    C,M
  441.     INX    H
  442.     MOV    B,M
  443. ;BC, DE NOW POINT TO ENTRIES TO BE COMPARED
  444.     XCHG
  445. ;
  446. CMPLP    LDAX    B
  447.     CMP    M
  448.     INX    H
  449.     INX    B
  450.     JZ    CMPLP
  451.     POP    H
  452.     RET        ;COND CODE TELLS ALL
  453. ;
  454. ;SWAP ENTRIES IN THE ORDER TABLE
  455. SWAP    MVI    A,1
  456.     STA    SWITCH    ;SHOW A SWAP WAS MADE
  457.     MOV    C,M
  458.     INX    H
  459.     PUSH    H    ;SAVE TABLE ADDR+1
  460.     MOV    B,M
  461.     INX    H
  462.     MOV    E,M
  463.     MOV    M,C
  464.     INX    H
  465.     MOV    D,M
  466.     MOV    M,B
  467.     POP    H
  468.     MOV    M,D
  469.     DCX    H    ;BACK POINTER TO CORRECT LOC'N
  470.     MOV    M,E
  471.     RET
  472. ;
  473. NFEXIT    CALL    ERXIT
  474.     DB    '++NO FILES ON THIS DISK',CR,LF,'$'
  475. ;
  476. ;ERROR EXIT
  477. ERXIT    POP    D    ;GET MSG
  478.     MVI    C,PRINT
  479.     JMP    CALLB    ;PRINT MSG, EXIT
  480. ;
  481. ;ABORT - READ CHAR ENTERED
  482. ABORT    MVI    C,RDCHR ;DELETE THE CHAR
  483. ;
  484. CALLB    CALL    BDOS
  485. ;
  486. ;FALL INTO EXIT
  487. ;EXIT - ALL DONE, RESTORE DISK LOG IN AND STACK
  488. EXIT    LDA    CDSK    ;GET ORIGINAL DISK NR.
  489.     MOV    E,A    ;TO E FOR CP/M
  490.     MVI    C,SELDSK ;RESTORE LOG-IN TO IT
  491.     CALL    BDOS
  492.     LHLD    BASE+6    ;GET TOP-OF-MEMORY PTR
  493.     MVI    L,0    ;ROUND TO PAGE ADRS
  494.     LXI    D,-800H ;SUBTRACT SIZE OF CCP
  495.     DAD    D
  496.     XCHG        ;DE=@CCP
  497.     LHLD    HIMEM    ;FETCH OUR HIGHEST USED
  498.     MOV    A,L    ;SUBTRACT: HIMEM-CCPLOC
  499.     SUB    E
  500.     MOV    A,H
  501.     SBB    D
  502.     JC    BASE    ;MUST WARM-BOOT, CCP NOT THERE
  503.     LHLD    STACK    ;GET OLD STACK
  504.     SPHL        ;MOVE TO STACK
  505.     RET        ;..AND RETURN
  506. ;
  507. HIMEM:    DW    0    ;HIGHEST MEMORY USED
  508. EXTMSK: DB    0    ;EXTENT MASK
  509. NEXTT    DW    TABLE    ;NEXT TABLE ENTRY
  510. COUNT    DW    0    ;ENTRY COUNT
  511. SWITCH    DB    0    ;SWAP SWITCH FOR SORT
  512. SAVFCB    DS    1    ;SAVED 1ST CHAR. OF FCB
  513. CDSK    DS    1    ;CURRENTLY LOGGED DISK NUMBER
  514. OCOUNT    DS    2    ;# NAMES TO PUT IN ORDER TABLE
  515. SCOUNT    DS    2    ;# TO SORT
  516. TEMP    DS    2    ;SAVE DIR ENTRY
  517. ORDER:    DS    2    ;LOC OF ORDER TABLE (TWO BYTES PER NAME)
  518.     DS    60    ;STACK AREA
  519. STACK    DS    2    ;SAVE OLD STACK HERE
  520. TABLE    EQU    $    ;READ ENTRIES IN HERE
  521. ;
  522. ; BDOS EQUATES
  523. ;
  524. RDCHR    EQU    1    ;READ CHAR FROM CONSOLE
  525. WRCHR    EQU    2    ;WRITE CHR TO CONSOLE
  526. PRINT    EQU    9    ;PRINT CONSOLE BUFF
  527. CONST    EQU    11    ;CHECK CONS STAT
  528. SELDSK    EQU    14    ;SELECT DISK DRIVE
  529. FSRCHF    EQU    17    ;   "   "
  530. FSRCHN    EQU    18    ;   "   "
  531. CURDSK    EQU    25    ;CHECK CURRENT DISK 0=A: 1=B:, ETC.
  532. BDOS    EQU    BASE+5
  533. ;
  534.     END
  535.