home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / TURBOPAS / TP-UTIL.ARK / SCRNBLT.ASM < prev    next >
Assembly Source File  |  1986-01-06  |  7KB  |  190 lines
  1. ;===========================================================================
  2. ;
  3. ;    S C R N B L T  -  Graphics Screen Block Transfer for Turbo Pascal
  4. ;
  5. ;===========================================================================
  6. ;
  7. ;     by Larry Stone      21-Jul-84
  8. ;
  9. ; SCRNBLT is written to be called from Turbo Pascal V2.0 using the
  10. ; EXTERNAL procedure convention.  It will copy the contents of the
  11. ; video graphics display buffer (either low or high resolution) to
  12. ; a designated memory location on a virtual "pad" of set dimensions.
  13. ; 
  14. ; To use SCRNBLT, the following lines must be included in your Turbo
  15. ; Pascal program.  The type "padtype" demonstrates how a PAD data type
  16. ; may be declared. When the PAD type is declared, the dimensions of
  17. ; the array must be as shown here.  It should also be specified ABSOLUTE
  18. ; with the initial offset 0, so that all of a 64K segment is available
  19. ; to it.
  20. ;
  21. ;  PROCEDURE SCRNBLT( MOVDIR, PADX, PADY : INTEGER; VAR PAD : PADARRAY );
  22. ;      EXTERN 'SCRNBLT';
  23. ;
  24. ;  TYPE
  25. ;    padtype = ARRAY [0..159, 0..399] OF BYTE;
  26. ;  VAR
  27. ;       pad : padtype ABSOLUTE $BA00 : $0000;    (* sample declaration *)
  28. ;
  29. ;  SCRNBLT(0, x, y, pad);   (* sample call; saves screen on pad(x,y) *)
  30. ;
  31. ; The parameters PADX and PAXY are specified as absolute coordinates
  32. ; on the pad, exactly as screen coordinates would be specified.  The
  33. ; X-coordinates correspond to the bits on the pad, not the bytes.
  34. ;
  35. ; The first parameter, "MOVDIR", determines the direction of the transfer.
  36. ; If 0 is specified, the contents of the screen are transferred to the
  37. ; designated area of the pad; if a nonzero number is specified, 
  38. ; the designated area of the pad is transferred to the screen buffer.
  39. ;
  40. ; SCRNBLT transfers the contents of the screen as a rectangular block,
  41. ; 80 bytes wide by 200 bytes high, to a rectangular area of the pad
  42. ; at the designated x,y coordinates.  The pad area is not organized
  43. ; exactly like the display buffer; odd and even lines are interleaved
  44. ; in a more straightforward fashion to allow the offset of an x,y location
  45. ; in the pad to be calculated as  (y * padwidth) + x.  
  46. ;
  47. ; To use SCRNBLT with a Turbo Program:
  48. ;-------------------------------------
  49. ; 1. Assemble this file with MASM.  "A> MASM SCRNBLT;"
  50. ; 2. Link it into a .EXE file.      "A> LINK SCRNBLT;"
  51. ; 3. Use EXE2BIN to make a .COM file. "A> EXE2BIN SCRNBLT.EXE SCRNBLT.COM"
  52. ; 4. Declare as shown in your Turbo Pascal program.
  53. ; 5. Ignore any minor diagnostic messages that may be generated when
  54. ;    this file is assembled and linked.  EXE2BIN is supplied with the
  55. ;    supplemental programs for PC-DOS; see the DOS manual.
  56. ;
  57.  
  58. ; 
  59. ; EQUATES TO DEFINE GRAPHICS CONSTANTS
  60. ;
  61. PADWD    EQU    160            ; WIDTH OF VIRTUAL PAD, BYTES
  62. SCRNWD    EQU    80            ; WIDTH OF REAL SCREEN
  63. SCRNWD2    EQU    40            ; HALF OF SCREEN WIDTH
  64. HALFSC    EQU    100            ; LINES FOR HALF OF SCREEN
  65. EVENSC    EQU    0B800H            ; ADDRESS OF EVEN HALF OF SCREEN
  66. ODDSC    EQU    02000H            ; OFFSET OF ODD HALF OF SCREEN
  67.  
  68. CODE    SEGMENT PUBLIC
  69.     ASSUME  CS:CODE
  70.     PUBLIC  SCRNBLT
  71. ;
  72. ; EQUATES FOR ARGUMENTS TO SCRNBLT
  73. ;
  74. PADOFS    EQU    4[BP]            ; OFFSET OF PAD ORIGIN
  75. PADSEG    EQU    6[BP]            ; SEGMENT OF PAD 
  76. PADY    EQU    8[BP]            ; Y-COORD IN PAD
  77. PADX    EQU    10[BP]            ; X-COORD IN PAD
  78. MOVDIR  EQU     12[BP]            ; MOVE DIRECTION (0 = TO SCREEN) 
  79.  
  80. SCRNBLT    PROC    NEAR
  81.     PUSH    BP
  82.     MOV    BP,SP            ; CALLING CONVENTION
  83.     PUSH    DS            ; SAVE DS
  84. ;
  85. ; COMPUTE THE ADDRESS OF THE ORIGIN OF THE PAD AREA DESIGNATED BY
  86. ; PADX, PADY.  LOC = PAD_OFFSET + (PADY * PADWD) + (PADX / 8)
  87. ;
  88.     MOV    AX,PADY            ; PREPARE PADY * PADX
  89.     MOV    BX,PADWD    
  90.     MUL    BX            ; AX = PADY * PADX (DX TRASHED)
  91.     MOV    BX,PADX            ; ADD IN X COMPONENT:
  92.     MOV    CL,3            ; (PREPARE TO SHIFT BY 3)
  93.     SHR    BX,CL            ;  DIV BY 8 SO WE MOVE BY BYTE
  94.     ADD    AX,BX            ;  ADD IT IN.
  95.     ADD     AX,PADOFS    
  96.     CMP    WORD PTR MOVDIR,0    ; IS MOVDIR 0?
  97.     JE    BACKWRD            ; IF SO, DO BACKWARDS MOVE.
  98. ;----------------------------------------------------
  99. ; MOVE "FORWARD" : FROM PAD TO REAL SCREEN
  100. ;----------------------------------------------------
  101. ;  MOVE THE EVEN LINES OF THE SCREEN. THE LOOP IS CONTROLLED BY
  102. ;  THE HALFSC VALUE IN DX; A REP MOVSW IS USED TO MOVE THE SCREEN
  103. ;  LINES A WORD AT A TIME (PROBABLY NO MORE EFFICIENT ON AN 8088..)
  104. ;
  105.     CLD                ; BE SURE DIR. FLAG IS 0
  106.     MOV    BX,PADSEG        ; SOURCE IS PAD, SO SET DS TO
  107.     MOV    DS,BX            ;  PAD SEGMENT
  108.     MOV     SI,AX            ;  AND DI TO OFFSET IN PAD
  109.     MOV    BX,EVENSC        ; DEST IS SCREEN, SET ES TO SCREEN
  110.     MOV    ES,BX            ;  SEGMENT.
  111.     MOV    DI,0            ;  AND INDEX OF 0
  112. ;
  113. ; LOOP TO COPY EVEN LINES
  114. ;
  115.     MOV     CX,HALFSC        ; PREPARE LOOP COUNTER
  116. EVEN:    MOV    DX,CX            ; RECORD LOOP COUNTER
  117.     MOV    CX,SCRNWD2        ; SET UP COUNTER
  118.     REP    MOVSW            ; DO THE MOVE
  119.     ADD    SI,PADWD+PADWD-SCRNWD    ; MOVE SI TO NEXT SCREEN LINE
  120.     MOV    CX,DX
  121.     LOOP     EVEN
  122. ;
  123. ; NOW SET UP FOR ODD LINES AND COPY THOSE
  124. ;
  125.     MOV    DI,ODDSC        ; SET DI TO ODD SCREEN OFFSET
  126.     MOV    SI,AX
  127.     ADD    SI,PADWD        ; SET SI TO FIRST ODD LINE
  128. ;
  129. ; COPY ODD LINES
  130. ; 
  131.     MOV    CX,HALFSC        ; LOAD COUNTER
  132. ODD:    MOV    DX,CX            ; SAVE COUNTER
  133.     MOV    CX,SCRNWD2        ; SET UP LINE COUNTER
  134.     REP    MOVSW
  135.     ADD    SI,PADWD+PADWD-SCRNWD    ; MOVE SI TO NEXT SCREEN LINE
  136.     MOV    CX,DX            ; GET LOOP COUNTER
  137.     LOOP    ODD
  138.     JMP    BYE            ; LEAVE
  139. ;----------------------------------------------------
  140. ; MOVE "BACKWARD" : FROM REAL SCREEN TO PAD
  141. ;----------------------------------------------------
  142. ;  THIS IS ALMOST EXACTLY LIKE THE CODE ABOVE THAT MOVES
  143. ;  FROM THE VIRTUAL SCREEN TO THE DISPLAY BUFFER
  144. ;
  145. BACKWRD:
  146.     CLD                ; BE SURE DIR. FLAG IS 0
  147.     MOV    BX,PADSEG        ; DEST IS PAD, SO SET ES TO
  148.     MOV    ES,BX            ;  PAD SEGMENT
  149.     MOV    DI,AX            ; SET UP SOURCE INDEX
  150.     MOV    BX,EVENSC        ; SET DS TO SCREEN SEGMENT
  151.     MOV    DS,BX            ;  FOR EVEN LINES OF SCREEN
  152.     MOV    SI,0            ;  AND SOURCE INDEX
  153. ;
  154. ; LOOP TO COPY EVEN LINES
  155. ;
  156.     MOV     CX,HALFSC        ; PREPARE LOOP COUNTER
  157. BEVEN:    MOV    DX,CX            ; RECORD LOOP COUNTER
  158.     MOV    CX,SCRNWD2        ; SET UP COUNTER
  159.     REP    MOVSW            ; DO THE MOVE
  160.     ADD    DI,PADWD+PADWD-SCRNWD    ; MOVE SI TO NEXT SCREEN LINE
  161.     MOV    CX,DX
  162.     LOOP     BEVEN
  163. ;
  164. ; NOW SET UP FOR ODD LINES AND COPY THOSE
  165. ;
  166.     MOV    SI,ODDSC        ; SET DI TO ODD SCREEN OFFSET
  167.     MOV    DI,AX
  168.     ADD    DI,PADWD        ; SET SI TO FIRST ODD LINE
  169. ;
  170. ; COPY ODD LINES
  171. ; 
  172.     MOV    CX,HALFSC        ; LOAD COUNTER
  173. BODD:    MOV    DX,CX            ; SAVE COUNTER
  174.     MOV    CX,SCRNWD2        ; SET UP LINE COUNTER
  175.     REP    MOVSW
  176.     ADD    DI,PADWD+PADWD-SCRNWD    ; MOVE SI TO NEXT SCREEN LINE
  177.     MOV    CX,DX            ; GET LOOP COUNTER
  178.     LOOP    BODD
  179. ;
  180. ; DONE.. CLEAN UP THE STACK AND LEAVE
  181. ;
  182. BYE:    POP    DS            ; RESTORE DS
  183.     MOV    SP,BP
  184.     POP    BP            ; CONVENTIONAL RETURN
  185.     RET     10            ; TRASH 10 BYTES FOR PARMS
  186.  
  187. SCRNBLT    ENDP
  188. CODE    ENDS
  189.     END
  190.