home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / SUBMIT / JOB15.LBR / JOB15.MQC / JOB15.MAC
Text File  |  2000-06-30  |  22KB  |  1,177 lines
  1.     title    'JOB 1.5 (86/10/15)'
  2. ; An improved submit facility for CP/m systems.
  3. ;    evolved from public domain supersub by Ron Fowler
  4. ; 
  5. ; copyright (c) 1983,1984,1986
  6. ; By C.B. Falconer,
  7. ;    680 Hartford Tpk, Hamden, CT 06517. (203) 281-1438
  8. ; released to the public domain 
  9. ;
  10. ; JOB allows parameters to be terminated by commas, thus a pair
  11. ; (i.e. ",,") can specify a null parameter.  In addition, parameters
  12. ; can be "quoted strings", to allow any input whatsoever.  In a quoted
  13. ; string a quote must be represented by two quotes.  JOB also accepts
  14. ; empty input lines (e.g. PIP exit command).
  15. ;
  16. ; JOB creates the $$$.SUB file on drive A, (user 0 as of JOB15) and
  17. ; thus can be executed with any setting of the default drive.  In
  18. ; addition JOB searches both the default and A drives for the .JOB
  19. ; file when no drive is specified in the command line, and (ver 1.4)
  20. ; if no .JOB file has yet been found searches default and system disks
  21. ; for a component of JOBS.LBR file.
  22. ;
  23. ; Thus a set of small .JOB files can be packed into JOBS.LBR and
  24. ; executed directly.  When many .JOB files are used this can
  25. ; significantly reduce disk storage
  26. ;
  27. ; An initial line in the .JOB file beginning with ";;" (double
  28. ; semi-colon) signifies that the line specifies a default set of
  29. ; parameters ($0 thru $9). These are only used when the execution
  30. ; command line does not supply parameters.
  31. ;
  32. ; JOB does not arbitrarily upshift anything, however an unmodified CCP
  33. ; will probably upshift all input lines.  CCPLUS can be set to avoid
  34. ; this upshifting.
  35. ;
  36. ; JOB will accept most files created for SUBMIT, unless supplied
  37. ; parameters include commas and quotes.  Since the reverse is not true
  38. ; JOB expects its' input files to be of type .JOB.
  39. ;
  40. ; JOB15 up is organized to co-operate with CCP+ and execute jobs thru
  41. ; changes in user number.  To perform correctly, a minor patch to BDOS
  42. ; is required, listed below.
  43. ;
  44. ; A test file to demonstrate JOB appears below (note null line):
  45.  
  46. ;;testingjob parm1, "parm2",, parm4 parm5, ," parm ""7"", "
  47. ; null defaults for parm3, parm6, parm8, parm9
  48. ;$1;
  49.  
  50. ;$2;
  51. ;$3,$4,$5,$6;
  52. ;$7;
  53. ;$8;
  54. ;$9;
  55. ;$0; <<end of test file>>
  56.  
  57. ; try A>JOB TESTJOB
  58. ;        where testjob is the above file from the ";;"
  59. ; This simply shows a set of comment commands on the console.
  60. ;
  61. ; Revision history
  62. ; ================
  63. ;
  64. ; 1.5    86/10/15 (cbf) Forced $$$.SUB file on user 0. After all, CPM
  65. ;    is a single user system.  Cooperates with CCP+ v21 up.
  66. ;    A patch for cpm2.2 for submit jobs to execute while changing
  67. ;    user numbers.  This co-operates with CCP+ v2.1 and JOB v1.5.
  68. ;
  69. ;    All values are shown for an unrelocated BDOS.  marked bytes
  70. ;    may be different by a constant
  71. ;
  72. ;    Location
  73. ;    (from start
  74. ;    of BDOS)    Was    Becomes    Comment
  75. ;    06DE        3e    7e    mvi a,0e5 --> mov a,m
  76. ;    06DF        e5    fe
  77. ;    06E0        be    e5    cmp m       --> cpi 0e5
  78. ;    06E1        ca
  79. ;    06E2        d2          jz ...   unchanged
  80. ;    06E3        06 *
  81. ;    06E4        3a    18    lda usrno --> jr $+3
  82. ;    06E5        41    01
  83. ;    06E6        03 *        (code byte skipped)
  84. ;    06E7        be    b7    cmp m     --> ora a
  85. ;        
  86. ;    The WAS items marked by '*' will vary with the location of
  87. ;    the CPM system, and should not be altered.  The patch uses
  88. ;    the Z80 JR instruction, so for Z80 systems only.  This has
  89. ;    been carefully designed to be position independant.
  90. ;
  91. ;    When completed, the original CCP will no longer execute
  92. ;    SUBMIT jobs when the user number is non-zero. It would never
  93. ;    allow a submit job to change users, which can now be done
  94. ;    when using CCP+ and JOB15.  (earlier versions of JOB will
  95. ;    work if the job is started on user 0 only.)
  96. ;
  97. ;    This causes BDOS to return 0ffh for call 13 (reset disks)
  98. ;    whenever a '$*.*' file exists on user 0.  This flag is
  99. ;    used by CCP+, ZCPR, and the original CCP to decide whether
  100. ;    to bother searching for the $$$.SUB file.  The original
  101. ;    code only returned 0ffh when the file existed on the current
  102. ;    user.
  103. ;
  104. ; 1.4    84/06/23 (cbf) Added library file search 
  105. ;
  106. ver        equ    15;    update with each revision
  107. ;
  108. cr        equ    0dh
  109. lf        equ    0ah
  110. tab        equ    9
  111. eol        equ    '$'
  112. parmchar    equ    '$'
  113. slash        equ    '/'
  114. comma        equ    ','
  115. quote        equ    '"'
  116. semi        equ    ';'
  117. blank        equ    ' '
  118. linesep        equ    '|'
  119. escape        equ    '^';    to control chars
  120. eofmark        equ    01ah;    sub=cntrl-z
  121. maxparms    equ    9
  122. ;
  123. putchar        equ    2;    cp/m functions
  124. putstring    equ    9
  125. getstring    equ    10
  126. fopen        equ    15
  127. fclose        equ    16
  128. fpurge        equ    19
  129. rdseq        equ    20
  130. wrtseq        equ    21
  131. newfile        equ    22
  132. gsuser        equ    32;    get/set user
  133. rdran        equ    33
  134. ;
  135. reboot        equ    0;    cp/m connector locations
  136. bdos        equ    00005h
  137. tfcb        equ    05ch
  138. tfcb.nam    equ    tfcb+1
  139. tfcb.ext    equ    tfcb+9
  140. cmdline        equ    080h
  141. defdma        equ    cmdline
  142. cmd.lgh        equ    cmdline
  143. cmd.chars    equ    cmdline+1
  144. ;
  145. ;
  146.     aseg
  147.     org    0100h
  148. ;
  149. begin:    lxi    h,0
  150.     dad    sp
  151.     shld    stksave    
  152.     lxi    sp,stack
  153.     mvi    a,gsuser
  154.     mvi    e,0ffh
  155.     call    dos
  156.     sta    defusr;        save input user
  157.     call    job
  158.     db    'JOB V'
  159.     db    ver / 10 + '0', '.', ver MOD 10 + '0',cr,lf,eol
  160. ;
  161. job:    pop    d
  162.     lda    tfcb.nam
  163.     cpi    blank
  164.     jz    help
  165.     mvi    a,putstring
  166.     call    dos;        sign-on
  167.     call    init
  168.     call    getcmnd
  169.     call    chkinf;        for blank or .job extension
  170.     lxi    h,0
  171.     shld    linenum    
  172.     call    openinf;    zero flag for interactive mode
  173.     cnz    freadjob;    put 1st line in buffer
  174.     jnz    jobempty;    read failed
  175.     call    default;    set default params
  176.     call    inputlns
  177.  
  178.     xra    a;        REMOVE this for use with original
  179.     mov    e,a;        CCP or ZCPR.
  180.     mvi    a,gsuser
  181.     call    dos;        jam to user 0 for subf operations
  182.  
  183.     call    opnsubf
  184.     call    wrtsubf
  185.     lda    defusr
  186.     mov    e,a
  187.     mvi    a,gsuser
  188.     call    dos;        restore entry user
  189.     jmp    reboot
  190. ;
  191. ; Check that any extension is ".JOB", or insert such
  192. ; if the supplied extension is blank.
  193. ; a,f,b,d,e,h,l
  194. chkinf:    lxi    h,tfcb.ext
  195.     mov    a,m
  196.     cpi    blank
  197.     jz    chkinf2
  198.     lxi    d,job.xt
  199.     mvi    b,3
  200.     call    qmatch
  201.     rz    
  202. ;    "    "
  203. nofile:    call    errexit;    leaves forever
  204.     db    '.'
  205. job.xt:    db    'JOB file not found',eol
  206. ;
  207. chkinf2:
  208.     xchg    
  209.     lxi    h,job.xt
  210.     mvi    b,3
  211. chkinf3:
  212.     mov    a,m;        move "JOB" into place
  213.     stax    d
  214.     inx    h
  215.     inx    d
  216.     dcr    b
  217.     jnz    chkinf3
  218.     ret
  219. ;
  220. getcmnd:
  221.     lxi    h,cmd.chars
  222.     call    skipblks
  223.     sta    mode    
  224.     rc    
  225.     cpi    slash
  226.     jnz    getcmnd3;    normal operation
  227.     inx    h
  228. getcmnd1:
  229.     shld    cursor    
  230.     mov    a,m
  231.     sta    onelnflg    
  232.     cpi    blank
  233.     rnz    
  234.     inx    h
  235.     jmp    getcmnd1
  236. getcmnd3:
  237.     call    skipblks
  238. getcmnd4:
  239.     cnc    setparm
  240.     jnc    getcmnd3
  241.     dcx    h;        back to eol mark for null param
  242.     push    h
  243.     lhld    parmindx
  244.     mov    a,m
  245.     ora    a
  246.     pop    h
  247.     jz    getcmnd4;    setup a null parameter
  248.     ret
  249. ;
  250. ; skipblanks in hl^, return 1st non blank. cy for eol, eof
  251. ; a,f,h,l
  252. skipblks:
  253.     mov    a,m
  254.     inx    h
  255.     ora    a
  256.     stc
  257.     rz    
  258.     cpi    cr
  259.     stc
  260.     rz    
  261.     cpi    eofmark
  262.     stc
  263.     rz    
  264.     cpi    blank
  265.     jz    skipblks
  266.     cpi    tab
  267.     jz    skipblks
  268.     dcx    h
  269.     ora    a
  270.     ret
  271. ;
  272. ; return carry if eol encountered
  273. setparm:
  274.     call    setdelim
  275.     push    h;        save input index
  276.     lhld    freeptr
  277.     xchg    
  278.     lhld    parmindx
  279.     mov    a,m
  280.     ora    a
  281.     jnz    manyparm
  282.     mov    m,e
  283.     inx    h
  284.     mov    m,d
  285.     inx    h
  286.     shld    parmindx    
  287.     pop    h
  288. ;    "    "
  289. ; save parameter
  290. ; (hl)^ is start of parameter string,
  291. ; (de)^ to location to save parameter
  292. savparm:
  293.     push    d
  294.     inx    d
  295.     mvi    b,0
  296. savparm1:
  297.     lda    delim
  298.     cpi    quote
  299.     jnz    savparm2;    not a quoted string
  300.     mov    a,m
  301.     inx    h
  302.     ora    a
  303.     jz    parmerr;    no terminal quote
  304.     cpi    quote
  305.     jnz    savparm4;    not terminal quote, go save char
  306.     cmp    m;        is it a double quote?
  307.     jnz    savparm5;    no, string is terminated
  308.     inx    h
  309.     jmp    savparm4;    yes, store a quote
  310. savparm2:
  311.     mov    a,m
  312.     inx    h
  313.     call    chkdelim
  314.     jz    savparm5
  315. savparm4:
  316.     stax    d
  317.     inx    d
  318.     inr    b
  319.     jmp    savparm1
  320. savparm5:
  321.     xchg    
  322.     shld    freeptr    
  323.     pop    h
  324.     mov    m,b
  325.     xchg;            pointer to terminal char
  326.     cpi    quote
  327.     jnz    savparm6;    not a quoted string
  328.     mov    a,m
  329.     cpi    comma
  330.     jnz    savparm6
  331.     inx    h;        skip terminating comma on
  332.     mov    a,m;          a quoted string
  333. savparm6:
  334.     ora    a
  335.     stc
  336.     rz    
  337.     cmc
  338.     ret
  339. ;
  340. ; setup delimiter for parameters. Advance past any initial '"'
  341. ; a,f,h,l
  342. setdelim:
  343.     mvi    a,' '
  344.     sta    delim    
  345.     mov    a,m
  346.     cpi    quote
  347.     rnz;            not a quoted string
  348.     sta    delim    
  349.     inx    h;        advance past the initial quote
  350.     ret
  351. ;
  352. ; Set up default parameters
  353. ; The first line is in defdma.  If the mode is not interactive, and
  354. ; the line begins with ";;", then replace each null parameter with
  355. ; the value in this first line, starting with 0.  Note that the 0th
  356. ; parameter is the jobfile name, and cannot be null.  The replacement
  357. ; parameters may be null. Such an initial line will be treated as a
  358. ; comment when executed by CCP, displaying the defaults.
  359. default:
  360.     lda    mode
  361.     cpi    slash
  362.     rz;            interactive mode
  363.     lda    defdma
  364.     cpi    semi
  365.     rnz;            not initial ";;"
  366.     lda    defdma+1
  367.     cpi    semi
  368.     rnz;            not initial ";;"
  369.     lxi    h,defdma+1;    before first possible character
  370.     mvi    b,0;        parameter number
  371. ; WHILE NOT eoln DO BEGIN
  372. ;   delimit_parameter;
  373. ;   IF non-null THEN
  374. ;     IF parameter (b) is null THEN BEGIN
  375. ;       expand_parm_storage
  376. ;       insert_default; END;
  377. ;     delimit next parameter; END;
  378. default1:
  379.     inx    h;        bypass previous delimiter
  380.     call    skipblks
  381.     rc;            no more
  382.     call    setdelim
  383.     call    scan;        to parm end
  384. ; now (c) is parameter lgh, (de) is start, (b) is id
  385. ; watch out for doubled quotes, counted as singles
  386. ; (hl)^ is terminating char, not part of parm
  387.     push    h
  388.     push    d
  389.     mov    a,c
  390.     ora    a
  391.     jz    default8;    default param is null
  392.     mov    a,b;        parameter id
  393.     call    findparm
  394.     ora    a
  395.     jnz    default8;    cmdline input is non-null
  396. ; now store the default parameter and
  397. ; update the index to it.  The previous
  398. ; storage for a null parameter is discarded.
  399.     lhld    freeptr
  400.     xchg    
  401.     mov    m,e
  402.     inx    h
  403.     mov    m,d
  404.     pop    h;        ^ param start
  405.     push    h
  406.     push    b
  407.     call    savparm
  408.     pop    b
  409. default8:
  410.     pop    d
  411.     pop    h
  412.     mov    a,m
  413.     call    chklnend
  414.     rz;            done
  415.     inr    b;        next parameter id
  416.     jmp    default1;    go try for next
  417. ;
  418. ; scan to parameter end. (hl)^ is start
  419. ; return (de)^ to start, (c) = length
  420. ; (hl)^ to delimiting character
  421. ; a,f,c,d,e,h,l
  422. scan:    mov    d,h
  423.     mov    e,l;        save starting point
  424.     mvi    c,0;        length, default 0
  425.     lda    delim
  426.     cpi    quote
  427.     jz    scan2;        looking for terminal quote
  428. scan1:    mov    a,l
  429.     ora    a
  430.     jz    parmerr;    no end found
  431.     mov    a,m
  432.     call    chkdelim
  433.     jz    scan9
  434.     inx    h
  435.     inr    c;        count length
  436.     jmp    scan1
  437. scan2:    mov    a,l
  438.     ora    a
  439.     jz    parmerr
  440.     mov    a,m
  441.     cpi    cr
  442.     jz    parmerr
  443.     cpi    quote
  444.     jz    scan4;        go check for double
  445. scan3:    inr    c;        count chars
  446.     inx    h
  447.     jmp    scan2
  448. scan4:    inx    h
  449.     cmp    m
  450.     jz    scan3;        double quote, keep 1 only
  451.     mov    a,m
  452.     call    chkdelim
  453.     jnz    parmerr
  454. scan9:    ret;            m points to terminating char.
  455. ;
  456. ; check (a) for possible delimiter, zero flag if so
  457. ; a,f
  458. chkdelim:
  459.     cpi    blank
  460.     rz    
  461.     cpi    tab
  462.     rz    
  463.     cpi    comma
  464.     rz    
  465. ;    "    "
  466. ; check (a) for line ending char, zero flag if so
  467. ; a,f
  468. chklnend:
  469.     cpi    cr
  470.     rz    
  471.     cpi    eofmark
  472.     rz    
  473.     ora    a
  474.     ret
  475. ;
  476. ; open input file. z flag for interactive mode
  477. openinf:
  478.     lda    mode
  479.     cpi    slash
  480.     rz;            interactive mode
  481.     lxi    d,tfcb
  482.     call    openf
  483.     rnz;            success
  484.     lxi    h,lbrfcb
  485.     call    trylb;        look in JOBS.LBR if not found
  486.     jz    nofile;        failed
  487.     ret
  488. ;
  489. ; Try to find component (de)^ in library file (hl)^
  490. ; z flag for failure
  491. ; If successful set up (de)^ [TFCB] for component access
  492. ; Note that the component size is needed in case the item
  493. ; ends on a record boundary without any eof mark.
  494. ; ** This routine needs cleanup to return component size
  495. ;    in (bc), and use only the input pointers (and defdma)
  496. ;    for access.  This will decouple it from this program. 
  497. ; a,f,b,c
  498. trylb:    xchg    
  499.     mvi    m,0;        mark default again
  500.     call    openf;        automatically tries system disk
  501.     xchg    
  502.     rz;            failed
  503.     xchg    
  504.     mvi    a,rdseq
  505.     call    dos
  506.     jnz    trylb9;        else first directory rcd read
  507.     call    chksz;        set (a) = entry count
  508.     jz    trylb9;        not a valid library
  509.     mov    b,a;        entry count
  510.     push    h;        save component id pointer
  511. trylb1:    dcr    b
  512.     jz    trylb8;        no more entries, not found
  513.     mov    a,b;        Now check (max - b)th entry
  514.     ani    3;        for the one we want
  515.     mvi    a,rdseq
  516.     cz    dos;        get next directory chunk
  517.     mov    a,b
  518.     cma
  519.     inr    a
  520.     ani    3
  521.     add    a
  522.     add    a
  523.     add    a
  524.     add    a
  525.     add    a;        * 32 bytes per entry
  526.     adi    defdma;        point to this entry
  527.     pop    h
  528.     push    h;        get component pointer
  529.     push    d
  530.     push    b;        THIS needs cleanup to use only the
  531.     xchg    
  532.     mov    l,a;        entry parameters for TFCB etc.
  533.     mvi    h,0;        and return a record count in (bc)
  534.     mvi    b,12;        Does this entry match
  535.     call    qmatch;        the one we want?
  536.     pop    b
  537.     pop    d
  538.     jnz    trylb1;        no, try next entry
  539.     mov    a,m;        yes, set up file access etc.
  540.     sta    lb.rrn;        m points to loc'n entry
  541.     inx    h
  542.     mov    a,m
  543.     sta    lb.rrn+1;        record pointer
  544.     inx    h
  545.     mov    a,m
  546.     inx    h
  547.     mov    h,m
  548.     mov    l,a;        record count
  549.     shld    maxrecs;    to force an eof when reading
  550.     xra    a
  551.     sta    lb.rrn+2;     now do a random read to set ptrs
  552.     push    d
  553.     mvi    a,rdran
  554.     lxi    d,lbrfcb
  555.     call    dos
  556.     lxi    h,tfcb
  557.     mvi    b,36
  558. trylb7:    ldax    d;        Move the complete opened fcb
  559.     mov    m,a;            to tfcb
  560.     inx    h
  561.     inx    d
  562.     dcr    b
  563.     jnz    trylb7;        More
  564.     pop    d
  565.     pop    h
  566.     ori    1
  567.     ret;            signal success
  568. trylb8:    pop    h
  569. trylb9:    xchg;            Not found, restore
  570.     mov    a,m
  571.     inr    m
  572.     ora    a;        If was default disk then
  573.     jz    trylb;        go try system disk
  574.     xra    a;        else signal failure
  575.     ret
  576. ;
  577. ; check size of library directory (de)^. 1st record in defdma
  578. ; Return (a) = count of entries (0 if not a library)
  579. ; a,f
  580. chksz:    push    b
  581.     push    d
  582.     push    h
  583.     lxi    h,defdma
  584.     mov    a,m
  585.     ora    a
  586.     jnz    chksz2
  587.     mvi    b,11
  588. chksz1:    inx    h
  589.     mov    a,m
  590.     cpi    ' '
  591.     jnz    chksz2;        invalid director
  592.     dcr    b
  593.     jnz    chksz1
  594.     inx    h
  595.     mov    a,m
  596.     inx    h
  597.     ora    m
  598.     inx    h
  599.     inx    h
  600.     ora    m
  601.     jnz    chksz2
  602.     dcx    h
  603.     mov    a,m;        get directory size
  604.     add    a
  605.     add    a;        in directory entries
  606.     jmp    chksz3;        0 causes error signal
  607. chksz2:    xra    a;        signal none
  608. chksz3:    pop    h
  609.     pop    d
  610.     pop    b
  611.     ret
  612. ;
  613. ; Open file (de)^.  Check default and system disks
  614. ; z flag for failure
  615. ; a,f
  616. openf:    push    h
  617.     lxi    h,32
  618.     dad    d
  619.     mvi    m,0;        set record pointer to zero
  620.     pop    h
  621.     mvi    a,fopen
  622.     call    dos
  623.     inr    a
  624.     rnz;            success
  625.     ldax    d
  626.     ora    a
  627.     jz    openf1;        was default, try system
  628.     xra    a
  629.     ret;            with z flag for failure
  630. openf1:    mvi    a,1;        try system disk
  631.     stax    d
  632.     jmp    openf
  633. ;
  634. inputlns:
  635.     lhld    linenum;    set up for line
  636.     inx    h
  637.     shld    linenum    
  638.     lhld    lineptr
  639.     xchg    
  640.     lhld    freeptr
  641.     shld    lineptr    
  642.     mov    m,e
  643.     inx    h
  644.     mov    m,d
  645.     inx    h
  646.     push    h
  647.     inx    h
  648.     mvi    c,0
  649. inputl3:
  650.     call    nextch;        store a line
  651.     jc    inputl5
  652.     db    0,0,0;        was call upshift
  653.     cpi    eofmark
  654.     jz    inputl5
  655.     cpi    lf
  656.     jz    inputl3
  657.     cpi    cr
  658.     jz    inputl4
  659.     mov    m,a
  660.     inx    h
  661.     call    memcheck
  662.     inr    c
  663.     jm    toolong
  664.     jmp    inputl3
  665. inputl4:
  666.     shld    freeptr    
  667.     pop    h
  668.     mov    m,c
  669.     jmp    inputlns;    next line
  670. inputl5:
  671.     shld    freeptr    
  672.     pop    h
  673.     mov    m,c
  674.     ret
  675. ;
  676. nextch:    push    h
  677.     push    d
  678.     push    b
  679.     lda    mode
  680.     cpi    slash
  681.     jnz    nextch1;    get from file
  682.     call    getch;        get from terminal
  683.     jmp    nextch3
  684. nextch1:
  685.     lda    inptr
  686.     ora    a
  687.     cm    freadjob
  688.     jnc    nextch2;    success, (a) is zero
  689.     mvi    a,eofmark
  690.     jmp    nextch3
  691. nextch2:
  692.     mov    e,a
  693.     mvi    d,0
  694.     inr    a
  695.     sta    inptr    
  696.     lxi    h,cmd.lgh
  697.     dad    d
  698.     mov    a,m
  699. nextch3:
  700.     pop    b
  701.     pop    d
  702.     pop    h
  703.     ora    a
  704.     ret
  705. ;
  706. freadjob:
  707.     mvi    a,0
  708.     sta    inptr    
  709.     lhld    maxrecs
  710.     mov    a,h
  711.     ora    l
  712.     dcx    h
  713.     shld    maxrecs    
  714.     mvi    a,1;        to signal eof if no read
  715.     mvi    a,rdseq
  716.     lxi    d,tfcb
  717.     cnz    dos;        records left
  718.     ora    a
  719.     stc
  720.     rnz;            eof
  721.     cmc
  722.     ret
  723. ;
  724. getch:    lda    onelnflg
  725.     ora    a
  726.     jnz    getch2;        one line only
  727.     lda    buf.size
  728.     ora    a
  729.     cm    userline
  730.     jc    getch3
  731.     dcr    a
  732.     sta    buf.size    
  733.     jp    getch2
  734. getch1:    mvi    a,cr
  735.     ret
  736. getch2:    lhld    cursor
  737.     mov    a,m
  738.     inx    h
  739.     shld    cursor    
  740.     cpi    linesep
  741.     jz    getch1
  742.     ora    a
  743.     rnz    
  744. getch3:    mvi    a,eofmark
  745.     ret
  746. ;
  747. userline:
  748.     lxi    d,prompter
  749.     mvi    a,putstring
  750.     call    dos
  751.     lxi    d,buf.max
  752.     mvi    a,getstring
  753.     call    dos
  754.     lda    buf.size
  755.     lxi    h,buf.data
  756.     shld    cursor    
  757.     ora    a
  758.     stc
  759.     rz    
  760.     cmc
  761.     ret
  762. ;
  763. memcheck:
  764.     lda    bdos+2
  765.     dcr    a
  766.     cmp    h
  767.     rnc    
  768.     call    errexit
  769.     db    'Memory full',eol
  770. ;
  771. opnsubf:
  772.     mvi    a,fopen
  773.     call    xsubf
  774.     inr    a
  775.     jz    opnsubf1
  776.     lda    sub.size
  777.     sta    sub.rnum;        prepare to append
  778.     ret
  779. opnsubf1:
  780.     sta    sub.rnum;        assumes (a)=0
  781.     mvi    a,newfile
  782.     call    xsubf
  783.     inr    a
  784.     rnz    
  785.     call    errexit
  786.     db    'Directory full',eol
  787. ;
  788. wrtsubf:
  789.     lhld    lineptr
  790.     mov    a,h
  791.     ora    l
  792.     jz    jobempty
  793.     mov    e,m
  794.     inx    h
  795.     mov    d,m
  796.     inx    h
  797.     xchg    
  798.     shld    lineptr    
  799.     xchg    
  800.     mov    a,m
  801.     ora    a
  802.     jz    wrtsubf3;    empty line
  803. wrtsubf1:
  804.     call    wrtln
  805.     lhld    linenum
  806.     dcx    h
  807.     shld    linenum    
  808.     lhld    lineptr
  809.     mov    a,h
  810.     ora    l
  811.     jz    wrtsubf4;    no more
  812.     mov    e,m
  813.     inx    h
  814.     mov    d,m
  815.     inx    h
  816.     xchg    
  817.     shld    lineptr    
  818.     xchg    
  819.     jmp    wrtsubf1
  820. wrtsubf3:
  821.     lhld    linenum
  822.     dcx    h
  823.     shld    linenum    
  824.     jmp    wrtsubf
  825. wrtsubf4:
  826.     mvi    a,fclose
  827. ;    "    "
  828. ; subfile operation (a)
  829. ; a,f,d,e
  830. xsubf:    lxi    d,subfcb
  831. ;    "    "
  832. ; Bdos call, function (a), return in (a), preserve registers
  833. ; Set flags on (a)
  834. ; a,f
  835. dos:    push    h
  836.     push    d
  837.     push    b
  838.     mov    c,a
  839.     call    bdos
  840.     ora    a
  841.     pop    b
  842.     pop    d
  843.     pop    h
  844.     ret
  845. ;
  846. ; Copy the line, making any parameter substitutions
  847. wrtln:    mov    a,m
  848.     inx    h
  849.     sta    chrsleft    
  850.     shld    @nextch    
  851.     lxi    h,cmd.chars
  852.     shld    putptr    
  853.     xra    a
  854.     sta    cmd.lgh    
  855.     mov    b,l
  856. wrtln1:    mov    m,a
  857.     inx    h
  858.     inr    b
  859.     jnz    wrtln1
  860. wrtln2:    call    getchar
  861.     jc    putsubf
  862.     cpi    escape
  863.     jnz    wrtln3
  864.     call    getchar
  865.     jc    cntrlch
  866.     cpi    escape
  867.     jz    wrtln3;        doubled to use escape char.
  868.     call    upshift
  869.     sui    '@'
  870.     jc    cntrlch
  871.     cpi    blank
  872.     jnc    cntrlch
  873. wrtln3:    cpi    parmchar
  874.     jnz    wrtln4
  875.     lda    mode
  876.     cpi    slash
  877.     mvi    a,parmchar;    In case interactive, use it
  878.     jz    wrtln4;        '$' not special in interactive mode
  879.     call    chknxtch
  880.     jc    parmerr
  881.     cpi    parmchar
  882.     jnz    wrtln5;        Go expand a parameter
  883.     call    getchar
  884. wrtln4:    call    putoutch
  885.     jmp    wrtln2
  886. wrtln5:    call    getchar;    a parameter identifier
  887.     call    qnum
  888.     jc    parmerr;    not numeric, no good
  889.     sui    '0';        one digit only allowed
  890.     call    findparm
  891.     jc    parmerr
  892.     mov    b,a;        length
  893.     inr    b;        may be zero
  894. wrtln6:    dcr    b
  895.     jz    wrtln2;        end of substitution
  896.     mov    a,m
  897.     inx    h
  898.     push    h
  899.     call    putoutch
  900.     pop    h
  901.     jmp    wrtln6
  902. ;
  903. putsubf:
  904.     mvi    a,wrtseq
  905.     call    xsubf
  906.     ora    a
  907.     rz    
  908.     call    errexit
  909.     db    'Disk full',eol
  910. ;
  911. getchar:
  912.     lxi    h,chrsleft
  913.     mov    a,m
  914.     dcr    a
  915.     stc
  916.     rm    
  917.     mov    m,a
  918.     lhld    @nextch
  919.     mov    a,m
  920.     inx    h
  921.     shld    @nextch    
  922.     cmc
  923.     ret
  924. ;
  925. putoutch:
  926.     lxi    h,cmd.lgh
  927.     inr    m
  928.     jm    toolong
  929.     lhld    putptr
  930.     mov    m,a
  931.     inx    h
  932.     shld    putptr    
  933.     ret
  934. ;
  935. chknxtch:
  936.     lda    chrsleft
  937.     ora    a
  938.     stc
  939.     rz    
  940.     mov    a,m
  941.     cmc
  942.     ret
  943. ;
  944. ; find parameter (a). Returns (a)=length,
  945. ; (hl)^ to start of parameter,
  946. ; (de)^ to pointer to lgh field (index table)
  947. ; a,f,d,e,h,l
  948. findparm:
  949.     cpi    maxparms+1
  950.     jnc    manyparm
  951.     mov    l,a
  952.     mvi    h,000h
  953.     dad    h
  954.     lxi    d,parmxpnd
  955.     dad    d
  956.     mov    e,m
  957.     inx    h
  958.     mov    d,m
  959.     dcx    h
  960.     xchg    
  961.     mov    a,m
  962.     inx    h
  963.     ret
  964. ;
  965. qmatch:    ldax    d
  966.     cmp    m
  967.     rnz    
  968.     inx    h
  969.     inx    d
  970.     dcr    b
  971.     jnz    qmatch
  972.     ret
  973. ;
  974. ; carry if (a) is not a numeric character
  975. ; f
  976. qnum:    cpi    '0'
  977.     rc    
  978.     cpi    '9'+1
  979.     cmc
  980.     ret
  981. ;
  982. ; write (hl) as decimal number, suppress leading zeroes
  983. tdzs:    push    psw
  984.     push    h
  985.     push    b
  986.     lxi    b,0f00ah;    c=divisor=10; b=iter.cnt=-16
  987.     xra    a;        clear
  988. tdzs1:    dad    h
  989.     ral;            shift off into (a)
  990.     cmp    c
  991.     jc    tdzs2;        no bit
  992.     sub    c
  993.     inx    h;        bit=1
  994. tdzs2:    inr    b
  995.     jm    tdzs1;        not done
  996.     pop    b
  997.     push    psw;        save output digit
  998.     mov    a,h
  999.     ora    l
  1000.     cnz    tdzs;        recursive
  1001.     pop    psw
  1002.     pop    h
  1003.     adi    '0'
  1004.     call    cout
  1005.     pop    psw
  1006.     ret
  1007. ;
  1008. ; crlf to console
  1009. ; a,f
  1010. crlf:    mvi    a,cr
  1011.     call    cout
  1012.     mvi    a,lf
  1013. ;    "    "
  1014. ; (a) to console
  1015. ; a,f
  1016. cout:    push    d
  1017.     mov    e,a
  1018.     mvi    a,putchar
  1019.     call    dos
  1020.     pop    d
  1021.     ret
  1022. ;
  1023. ; Upshift (a)
  1024. ; a,f
  1025. upshift:
  1026.     cpi    'a'
  1027.     rc    
  1028.     cpi    'z'+1
  1029.     rnc    
  1030.     ani    05fh
  1031.     ret
  1032. ;
  1033. parmerr:
  1034.     call    errexit
  1035.     db    'Parameter',eol
  1036. ;
  1037. manyparm:
  1038.     call    errexit
  1039.     db    'Too many parameters:',eol
  1040. ;
  1041. toolong:
  1042.     call    errexit
  1043.     db    'Line too long:',eol
  1044. ;
  1045. jobempty:
  1046.     call    errexit
  1047.     db    'Job file empty',eol
  1048. ;
  1049. cntrlch:
  1050.     call    errexit
  1051.     db    'Control character',eol
  1052. ;
  1053. ; Message (tos)^ and exit
  1054. errexit:
  1055.     pop    d
  1056.     mvi    a,putstring
  1057.     call    dos
  1058.     lxi    d,errmsg
  1059.     mvi    a,putstring
  1060.     call    dos
  1061.     lhld    linenum
  1062.     call    tdzs
  1063.     call    crlf
  1064.     mvi    a,fpurge
  1065.     call    xsubf
  1066.     jmp    reboot
  1067. ;
  1068. errmsg:    db    ' error on line number: ',eol
  1069. prompter:
  1070.     db    cr,lf,'*',eol
  1071. ;
  1072. init:    lxi    h,clrbegin
  1073.     lxi    b,buf.max-clrbegin
  1074. init1:    mvi    m,000h;    clear
  1075.     inx    h
  1076.     dcx    b
  1077.     mov    a,b
  1078.     ora    c
  1079.     jnz    init1
  1080.     lxi    h,parmxpnd
  1081.     shld    parmindx    
  1082.     lxi    h,-1;        mark end of parameter pointers
  1083.     shld    lastparm    
  1084.     shld    maxrecs;    allow 65535 recs on non lbr file
  1085.     lxi    h,storage
  1086.     shld    freeptr    
  1087.     mvi    a,080h
  1088.     sta    inptr    
  1089.     sta    buf.size    
  1090.     sta    buf.max    
  1091.     ret
  1092. ;
  1093. help:    lxi    d,helpmsg
  1094.     mvi    a,putstring
  1095.     call    dos
  1096.     lhld    stksave
  1097.     sphl    
  1098.     ret
  1099. ;
  1100. helpmsg:
  1101.     db    cr,lf,'How to use JOB:',cr,lf,lf
  1102.     db    'JOB<CR>            : '
  1103.     db    'print this message',cr,lf
  1104.     db    'JOB /<CR>          : '
  1105.     db    'interactive mode',cr,lf
  1106.     db    'JOB /<cmd lines>   : '
  1107.     db    'use SUMMARY mode',cr,lf
  1108.     db    'JOB <FILE> <PARMS> : as standard '
  1109.     db    'SUBMIT.COM, but JOB will search',cr,lf
  1110.     db    'for A:file.JOB after the default '
  1111.     db    'disk if no drive was specified,',cr,lf
  1112.     db    'and then as a component of "JOBS.LBR" '
  1113.     db    'if not already found.',cr,lf
  1114.     db    'The SUB file is created on "A:", '
  1115.     db    ' thus JOB may be used while any',cr,lf
  1116.     db    'drive is the default.  Parameters '
  1117.     db    'may be delimited by commas and',cr,lf
  1118.     db    'may be "quoted strings". An initial '
  1119.     db    'line beginning with ";;" can',cr,lf
  1120.     db    'be used to specify default params '
  1121.     db    '(0..9) at execution time.',cr,lf,lf
  1122.     db    'In "/" (interactive) mode,  JOB '
  1123.     db    'will prompt you a line at a time',cr,lf
  1124.     db    'for the "SUBMIT" job input. '
  1125.     db    'Logical lines may be combined on the',cr,lf
  1126.     db    'same input line by separating them '
  1127.     db    'with "|".  Example:',cr,lf
  1128.     db    '  A>JOB /STAT|DIR',cr,lf
  1129.     db    'specifies two commands on the'
  1130.     db    ' same input line.',cr,lf,lf
  1131.     db    'Submitted jobs may nest...JOB '
  1132.     db    'inserts ahead of an existing job.',cr,lf,lf
  1133.     db    'To insert a control character '
  1134.     db    'into the output, prefix it with',cr,lf
  1135.     db    'a "^" ("^^" for real "^").',cr,lf,eol
  1136. ;
  1137. lbrfcb:    db    0,'JOBS    LBR',0,0,0,0
  1138.     ds    16
  1139. lb.rno:    ds    1
  1140. lb.rrn:    ds    3;
  1141. ;
  1142. subfcb:    db    1,'$$$     SUB';    LAST initialized storage
  1143. ;
  1144. clrbegin:    ds    3;    This area cleared at initialization
  1145. sub.size:    ds    17
  1146. sub.rnum:    ds    1
  1147.         ds    3;    for  random records
  1148. ;
  1149. delim:        ds    1;    delimiter for parameter input
  1150. freeptr:    ds    2
  1151. parmindx:    ds    2
  1152. linenum:    ds    2
  1153. lineptr:    ds    2
  1154. chrsleft:    ds    1
  1155. @nextch:    ds    2
  1156. putptr:        ds    2
  1157. inptr:        ds    1
  1158. cursor:        ds    2
  1159. onelnflg:    ds    1
  1160. mode:        ds    1
  1161. maxrecs:    ds    2;    to simulate eof on .lbr file
  1162. parmxpnd:    ds    2*(maxparms+1);    a list of pointers to
  1163. ;                      lgh, char string
  1164. lastparm:    ds    2;    -1 marks end of parmxpnd array
  1165. ; End of area cleared at initialization time
  1166. ;
  1167. defusr:        ds    1;    user at initialization time
  1168. buf.max:    ds    1
  1169. buf.size:    ds    1
  1170. buf.data:    ds    128
  1171. stksave:    ds    2
  1172.         ds    200;    stack space
  1173. stack:
  1174. storage:    ds    0;    actually the rest
  1175. ;
  1176.     end
  1177. V