home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / RCPM / ZMD150.LBR / ZMD.ZZ0 / ZMD.Z80
Text File  |  2000-06-30  |  134KB  |  4,856 lines
  1. ;
  2.  
  3.     TITLE  ZMD.Z80    - 09/29/88 - Z80 RCP/M File Transfer Program
  4. ;                     Copyrighted (c) 1987, 1988
  5. ;                     Robert W. Kramer III
  6.  
  7.     PAGE
  8. ;-                                     -;
  9. ;                         Update History                                  ;
  10. ;                                                                         ;
  11. ;    Date    Release                 Comments                     ;
  12. ;  --------    -------      ----------------------------------------------  ;
  13. ;                                      ;
  14. ;  09/29/88    v1.50    - If an LBR/ARK/ARC member extraction is being      ;
  15. ;              made, a check at OPNOK5: determines if (FCB+9)  ;
  16. ;              is an 'L' for a .LBR member extraction.  If so, ;
  17. ;              ZMD informs the receiver that the file is ready ;
  18. ;              for downloading.  If (FCB+9) is other than an      ;
  19. ;              'L' an ARC/ARK member extraction is assumed and ;
  20. ;              the receiver is told to name the received file  ;
  21. ;              accordingly.  Extractions on LBR/ARC/ARK files  ;
  22. ;              with the high bit set in (FCB+9) triggers this  ;
  23. ;              test unreliable.  The simple fix has been made, ;
  24. ;              which strips the parity bit of (FCB+9) before      ;
  25. ;              anylizing it.                      ;
  26. ;            - Fixed a problem that caused some systems to      ;
  27. ;              ignore the first character typed in some ZMD      ;
  28. ;              utilities.  The modification was made at the      ;
  29. ;              TYPE: routine in ZMDSUBS.  Instead of using      ;
  30. ;              BDOS function 2 to display a character, we are  ;
  31. ;              now using BDOS call 6.              ;
  32. ;            - Fixed CONSTAT: routine in ZMDSUBS to properly      ;
  33. ;              react to cancel requests from Sysop.          ;
  34. ;            - Modified all low level I/O routines to preserve ;
  35. ;              HL, DE, and BC registers.  Whether you're using ;
  36. ;              BYE's extended BDOS calls or have a custom I/O  ;
  37. ;              overlay installed in ZMD, those registers are      ;
  38. ;              will return intact.  This allows those writing  ;
  39. ;              overlays to not have to worry about register      ;
  40. ;              integrity.                      ;
  41. ;            - Single file Receive now defaults to 1k blocks.  ;
  42. ;            - Library extractions now default to 1k blocks.      ;
  43. ;            - Fixed bugs in the handshaking that have been      ;
  44. ;              around since 1k Batch was implemented on CPM      ;
  45. ;              systems.  This required several modifications      ;
  46. ;              to the SNDFIL routines.  All of them were      ;
  47. ;              modified specifically for the Batch routines,      ;
  48. ;              however, other Send routines were directly      ;
  49. ;              effected by them.                  ;
  50. ;                                      ;
  51. ;                 1.    ZMD does not use the BDOS call 35 to get  ;
  52. ;                the file size since this information is      ;
  53. ;                supplied in the directory entry for each  ;
  54. ;                extent retreived during filename lookup.  ;
  55. ;                                      ;
  56. ;                 2. We no longer open a file to send until      ;
  57. ;                the receiver has ACKnowledged header 0      ;
  58. ;                *AND* sent his invitation for CRC ('C').  ;
  59. ;                Previously, opening the file immediately  ;
  60. ;                after the header 0 ACK caused the 'C' to  ;
  61. ;                be missed during the time the sender is      ;
  62. ;                opening the file and filling his transmit ;
  63. ;                buffer.                      ;
  64. ;                                      ;
  65. ;                 3. I personally feel there is no need to      ;
  66. ;                purge the line of incoming characters at  ;
  67. ;                anytime during a batch session. All of the;
  68. ;                occurences of CALL CATCH have been removed;
  69. ;                from the Send batch routines with the      ;
  70. ;                exception of the GTACK routine, in which  ;
  71. ;                case a call to CATCH is only made if the  ;
  72. ;                current byte received is other than an      ;
  73. ;                ACK, NAK, 7Bh, FBh, or a CANCEL.      ;
  74. ;                                      ;
  75. ;                I do not have the resources to change all ;
  76. ;                the other CP/M file transfer utilities      ;
  77. ;                floating around, so you may still notice  ;
  78. ;                some minor delays between files in BATCH  ;
  79. ;                protocol.  Since most of the problem was  ;
  80. ;                in the Send routines, you'll not notice      ;
  81. ;                lengthy delays when using ZMD to send.      ;
  82. ;                Delays when using ZMD to receive will be  ;
  83. ;                dependant upon what software the sender      ;
  84. ;                is using.  (IBM comm programs don't seem  ;
  85. ;                to have this problem, however all CP/M      ;
  86. ;                comm programs will have these irritating  ;
  87. ;                delays - except ZMD).              ;
  88. ;                                      ;
  89. ;            - Added code to initialize KDRV with current      ;
  90. ;              drive at program startup.  CPM3 systems were      ;
  91. ;              experiencing problems with BDOS 46.          ;
  92. ;            - CPM3 BDOS call 46 returns the current disk space;
  93. ;              free in the first 3 bytes of the currently set  ;
  94. ;              DMA.  This was being done during a check for      ;
  95. ;              the batch intention and destroying the current  ;
  96. ;              command line buffer (at 80h where DMA address is;
  97. ;              usually set).  CPM3 systems should now have no  ;
  98. ;              problems with ZMD.                  ;
  99. ;            - Fixed bug to allow 255 files to be transferred  ;
  100. ;              when descriptions are disabled (either by the      ;
  101. ;              ZINSTL program or by using the 'RW' option).      ;
  102. ;            - Added CKWILD routine to prevent commands such   ;
  103. ;              as 'ZMD R *.*' enter '*.*' into the directory.  ;
  104. ;              Using any wildcards in the filename or extent   ;
  105. ;              of the receive filename will trigger YMODEM 1k  ;
  106. ;              Batch.                      ;
  107. ;            - Log file routines were writing some filename      ;
  108. ;              attributes to the log file.  Fixed at PUTLOG:      ;
  109. ;            - Modified ZMDSUBS.REL and send/send Batch code   ;
  110. ;              to take care of incorrect drive display problem ;
  111. ;              for local terminal.  Created new subroutine to  ;
  112. ;              poke the current binary 'BDOS' drive/user area  ;
  113. ;              into (DUU) and (DUD) in both SNDFIL: and SBTCH: ;
  114. ;              routines.  Both DUD and DUU have been moved to  ;
  115. ;              the ZMDSUBS file for global use.          ;
  116. ;            - Fixed EDATE routines for LOG and FOR files.      ;
  117. ;              Previously, the EDATE setting had no effect on  ;
  118. ;              the ZMD.Z80 program.                  ;
  119. ;            - Fixed message upload routine at RCVFL to check  ;
  120. ;              for access restrictions.  If ACCESS is set to      ;
  121. ;              NO, the message upload will be accepted, else      ;
  122. ;              bit 3 of AFBYTE will be anylized.          ;
  123. ;                                      ;
  124. ;  03/18/88    v1.49    - No change(s) made to this file          ;
  125. ;  03/13/88    v1.48    - Had a small problem with TPA fix which has been ;
  126. ;              corrected.  CHKTPA was calculating the total      ;
  127. ;              number of bytes available for DBUF, but wasn't  ;
  128. ;              clearing register L (forcing an even amount of  ;
  129. ;              sectors before initializing OUTSIZ buffer limit ;
  130. ;              comparison word).  This may have introduced      ;
  131. ;              minimal garbage to your FOR file if your FOR      ;
  132. ;              file is large enough to fill available TPA with ;
  133. ;              ZMD, ZFORS or to the log file if running ZMDEL. ;
  134. ;            - Rewrote OUTCHR routine in ZMDSUBS.          ;
  135. ;            - Redefined buffer table at end of programs. STACK;
  136. ;              and filename buffers now EQUated with offsets      ;
  137. ;              from the last switch/toggle in program instead  ;
  138. ;              of with DS directive.                  ;
  139. ;            - Some systems which do NOT have an interrupt      ;
  140. ;              driven keyboard may have noticed problems when  ;
  141. ;              an invalid key was entered in the ZNEWP, ZFORP  ;
  142. ;              and ZMDEL programs.  In ZNEWP and ZFORP, if a   ;
  143. ;              CR was entered to pause the output, output was  ;
  144. ;              limited to one line at a time per key pressed.  ;
  145. ;              If an invalid key was hit, output would have      ;
  146. ;              remained in a paused state until one of the      ;
  147. ;              abort keys were pressed.  This was difficult to ;
  148. ;              find since my keyboard is interrupt driven and  ;
  149. ;              I could not duplicate the problem on my own      ;
  150. ;              system.                      ;
  151. ;            - Fixed a problem in the MODE parsing routines      ;
  152. ;              that caused ZMD to default to 128 byte blocks      ;
  153. ;              in single file SEND mode.  Now defaults to 1k      ;
  154. ;              YMODEM.                      ;
  155. ;  02/25/88    v1.47    - Fixed a problem that caused only partial display;
  156. ;              of the help guide if an invalid command such as ;
  157. ;              ZMD RPC with no filename was entered.       ;
  158. ;            - Repaired routine that loads access flags byte      ;
  159. ;              into AFBYTE.  If ACCESS was disabled and BYE      ;
  160. ;              was running, a check for a modem overlay was      ;
  161. ;              being made that caused a system hang up.  v1.46 ;
  162. ;              was the only version with this problem.      ;
  163. ;            - And then there were TPA problems. Past versions ;
  164. ;              of ZMD required at least 48k TPA to run.  If      ;
  165. ;              your system has less, and descriptions enabled, ;
  166. ;              you most likely had a system hang up during the ;
  167. ;              FOR file read/write operations.  This version      ;
  168. ;              will run on any system with as little as 24k of ;
  169. ;              available TPA.  Maximum number of uploads is      ;
  170. ;              automatically calculated according to your TPA  ;
  171. ;              limitations.  If upload descriptions have been  ;
  172. ;              disabled (either during installation or during  ;
  173. ;              program execution with the RW or RP options),   ;
  174. ;              as many as 255 files may be uploaded.          ;
  175. ;            - Fixed time out error in CRC receive routine.      ;
  176. ;              Register B contains the number of seconds to      ;
  177. ;              wait for a character on entry to RECV and some- ;
  178. ;              how I inadvertanly removed the line that loads  ;
  179. ;              this value on entry. (Label RCVCRC2)          ;
  180. ;            - Fixed description routine so that the caller      ;
  181. ;              will be asked for the category of each uploaded ;
  182. ;              file if ASKAREA is disabled. Problem caused ZMD ;
  183. ;              to ask only 1 time for the file descriptor of      ;
  184. ;              uploaded files - no matter how many of them      ;
  185. ;              there were.                      ;
  186. ;  01/27/88    v1.46    - Fixed BYE time routines.  Now displays correct  ;
  187. ;              time on system when exiting.              ;
  188. ;            - Fixed SUBS file so that discrepency check will  ;
  189. ;              not turn off CLOCK, and DSTAMP if MODE is set      ;
  190. ;              to 255.  (So ZFORS and ZFORP can react to the      ;
  191. ;              clock related features without BYE running).      ;
  192. ;            - Added prompt to tell remote when ZMD is waiting ;
  193. ;              for him to come back to terminal mode.  Gets      ;
  194. ;              redisplayed every 3 seconds for a total of      ;
  195. ;              approximately 30 seconds before continuing on      ;
  196. ;              automatically.                     ;
  197. ;            - Added code to SUBS file that determines if we   ;
  198. ;              are in private mode or not. If so, only private ;
  199. ;              drive/user information is displayed when asking ;
  200. ;              for file descriptors/categories choice.  If in  ;
  201. ;              regular mode or in SPACE routines only the      ;
  202. ;              regular drive/user is shown.  Fix is for upload ;
  203. ;              routing routines.                    ;
  204. ;            - Repaired message file exit routine.  Command      ;
  205. ;              line wasn't being properly built.            ;
  206. ;            - Fixed so that batch mode is not valid with the  ;
  207. ;              RM option.  (Slipped by during a rewrite of the ;
  208. ;              command tail parsing routines).          ;
  209. ;  01/17/88    v1.45    - First public release                  ;
  210. ;  01/14/88     v1.43    - Removed MBYE/BYE3 specific switches in ZMDHDR.  ;
  211. ;              Added new switch CLOCK.  Removed Extended BDOS  ;
  212. ;              calls from time and date routines.  Rewrote for ;
  213. ;              100% compatibility with BYE5/MBYE/BYE3 remote      ;
  214. ;              console programs.  RTC switch can be set for       ;
  215. ;              user defined time and date routines at RTCTIM      ;
  216. ;              in ZMDHDR.Z80                      ;
  217. ;            - Fixed an error in send routines that allowed       ;
  218. ;              FCB+9-FCB+12 to remain initialized to nulls, if ;
  219. ;              file requested had less than 3 characters in      ;
  220. ;              the filename extent.                    ;
  221. ;  12/29/87    v1.41    - Removed and rewrote description routines to be  ;
  222. ;              universal with ZMD, ZFORS and ZINSTL programs.  ;
  223. ;              Routine is now requested from ZMDSUBS.REL      ;
  224. ;  12/23/87    v1.40    - Fixed numerous trivial bugs.              ;
  225. ;            - Rewrote the help and time/date routines.      ;
  226. ;            - Added code to determine if BIOS local console      ;
  227. ;              output address has been included in the modem      ;
  228. ;              overlay and if not calculate it according to      ;
  229. ;              standard CP/M specifications and store it for      ;
  230. ;              program use.                      ;
  231. ;  12/13/87    v1.39    - Rewrote common subroutines for inclusion in      ;
  232. ;              ZMDSUBS.REL subroutines file.              ;
  233. ;  12/07/87    v1.38    - Modified to support drive/user area requests      ;
  234. ;              in SEND BATCH mode.  Drive/user restrictions      ;
  235. ;              remain enforced.                  ;
  236. ;  10/02/87    v1.37    - Wrote code for automatic host disk block size   ;
  237. ;              detection.  All file sizes (and total file      ;
  238. ;              sizes) are rounded to reflect this block size.  ;
  239. ;  08/29/87    V1.36    - Rewrote all time routines.  Moved RTC reader      ;
  240. ;              code insert address to ZMDHDR.  Moved all date  ;
  241. ;              and time routines together to be updated all      ;
  242. ;              in same pass.  Values stored at end of program  ;
  243. ;              to free up registers and retain values for any  ;
  244. ;              subsequent use.                  ;
  245. ;  08/14/87    v1.35    - Removed access restriction routines and rewrote ;
  246. ;              completely.  Access switches now bit mapped.      ;
  247. ;  07/24/87    v1.34    - Updated to detect and process batch filename      ;
  248. ;              requests automatically.  (AUTO-BATCH).      ;
  249. ;            - Removed entire SBTCH routines and threw away.      ;
  250. ;              Rewrote from scratch to enhance speed,      ;
  251. ;              efficiency, readability, and user friendliness. ;
  252. ;              ZMD is capable of locating multiple filenames      ;
  253. ;              on multiple drive user areas with full drive      ;
  254. ;              and user area, filename, and time restrictions  ;
  255. ;              in force in 5 seconds (all other CP/M file      ;
  256. ;              transfer programs take 7 minutes or more) to      ;
  257. ;              find maximum 255 filenames.              ;
  258. ;            - Complete rewrites of: command line parsing,      ;
  259. ;              exit, abort, credit and descriptions routines.  ;
  260. ;  06/18/87    v1.30    - Removed conditional assembly and modified to      ;
  261. ;              support .COM file installation/reconfiguration  ;
  262. ;              without reassembling.                  ;
  263. ;  06/17/87    v1.29    - Converted entire program to Microsoft MACRO-80  ;
  264. ;              language.  Programs no longer compatible with      ;
  265. ;              8080 microcomputers.                  ;
  266. ;-                                                                       -;
  267.  
  268. ;-------------------------------------------------------------------------;
  269. ; EXTERNAL Declarations:                          |
  270. ;-------------------------------------------------------------------------
  271. ;
  272.  
  273.     EXTRN    BCDBIN,BLKSIZ,BUFSTR,BYECHK,CATCH,CHARLN,CKDIR,CLEARIT
  274.     EXTRN    CMDBUF,CNREC,CONIN,CONONL,CONSTAT,CPDEHL,CPM3,CRCCHK
  275.     EXTRN    CRCVAL,DATDEC,DATMSG,DBUF,DECOUT,DELAY,DIVREC,DSCFLG
  276.     EXTRN    DSKSAV,DVHLDE,ERXIT,EXIT,FILCNT,FILTM1,FINCRC,FUNCHK
  277.     EXTRN    GETDSC,GETKIND,GETOFF,GETSPD,GTCURDU,HEXO,ILPRT,ILPRTB
  278.     EXTRN    ILPRTL,INCRNO,INITFCB,INITFLG,INITIT,INPUT,KDRV,KIND
  279.     EXTRN    KSHOW,KTIM,LBRARC,LCASE,LOGBUF,LOW41K,MATCH,MCHFTYP
  280.     EXTRN    MEMFCB,MODE,MOVFCB,MSGFLG,NAMBUF,NOARK,OLDDRV
  281.     EXTRN    OLDUSR,PGSIZE,PRINTV,PRIVATE,RDARC,RDCOUNT,RECAR1
  282.     EXTRN    RECARE,RECDR1,RECDRX,RECTBL,RECV,RENFCB,RENTYP,RSDMA
  283.     EXTRN    RSTLCK,SEND,SENDBEL,SETLCK,SHOCAT,SHONM,SHONM3,SHOSPD
  284.     EXTRN    SNDABT,SPCDRV,STACK,STDMA,STORTM,TYPE,UCASE,USRSAV
  285.     EXTRN    WAIT1,WHLCHK,XTIM,NEWNAM,SHONM4,NOROOM,BYEBDOS,BATCH
  286.     EXTRN    FILIMT,PUPFLG,CHKTPA
  287.  
  288. ;
  289. ;-------------------------------------------------------------------------;
  290. ; PUBLIC Declarations:                              |
  291. ;-------------------------------------------------------------------------;
  292. ;
  293.  
  294.     PUBLIC    KTABLE,XTABLE,KECTBL,DONE,EOTFLG,ABORT,ABORTX,HELP
  295.     PUBLIC    KFLG,FCBBUF,HDRADR,RCNT,RECDNO,SAVEHL,RCDCNT,TIME
  296.  
  297. ;
  298. ;-------------------------------------------------------------------------;
  299. ; Program Starts Here                              |
  300. ;-------------------------------------------------------------------------;
  301.  
  302.  
  303.        .Z80
  304.     ASEG
  305.     ORG    100H        ; Program starts 
  306.     JP    BEGIN        ; Jump around configuration table
  307.     INCLUDE    ZMDHDR.Z80    ; Include the ZMD header overlay
  308.        .REQUEST ZMDSUBS        ; Include the ZMD subroutines
  309.  
  310. ;
  311. ;
  312. ; Save current CP/M stack address
  313. ;
  314. BEGIN:    LD    (STACK),SP    ; Save current CP/M stack address
  315.     LD    SP,STACK    ; Initialize new one for ZMD
  316.  
  317. ;
  318. ; Save current drive and user area for later
  319. ;
  320.     LD    A,255
  321.     CALL    RECAR1        ; Get current user
  322.     LD    (OLDUSR),A    ; Save current user
  323.     LD    C,CURDRV    ; Current drive
  324.     CALL    BDOS
  325.     LD    (OLDDRV),A    ; Save current drive
  326.     ADD    A,'A'        ; Make it ASCII
  327.     LD    (KDRV),A    ; And store as default drive for DPB info
  328.  
  329. ;
  330. ; Display signon message and check environmental discrepencies
  331. ;
  332.     LD    HL,ZMDNAM    ; Point to this program's name
  333.     CALL    PRINTV        ; Display it and version number
  334.  
  335. ;
  336. ; If running under CPM3 tell rest of program
  337. ;
  338.     LD    C,GETVER    ; Get CPM version
  339.     CALL    BDOS
  340.     CP    48        ; Version 3.0?
  341.     JR    C,$+5        ; No, it's 2.n so skip next
  342.     LD    (CPM3),A    ; Else set CPM3 switch on
  343.  
  344. ;
  345. ; Locate modem I/O routines
  346. ;
  347.     CALL    BYECHK        ; BYE extended BDOS valid?
  348.     CP    5
  349.     JR    NZ,BEGIN0    ; No, check for I/O overlay
  350.     LD    A,255
  351.     LD    (BYEBDOS),A    ; Enable BYE extended BDOS for modem I/O
  352.     JR    BEGIN1
  353.  
  354. BEGIN0:    LD    A,(MDINP+2)    ; Check for MDINP address
  355.     OR    A        ; Anything there?
  356.     JP    Z,NOIO        ; No overlay either, bitch then exit
  357.     LD    (INITFLG),A    ; Tell exit routine to 'UNINIT'
  358.     CALL    MINIT        ; Initialize system routine (if included)
  359.  
  360. ;
  361. ; Get bit mapped access flags byte
  362. ;
  363. BEGIN1:    LD    A,(ACCESS)    ; Using access flags byte?
  364.     OR    A
  365.     JR    Z,BEGIN3    ; No
  366.  
  367.     CALL    BYECHK        ; Check version of BYE
  368.     CP    5        ; BYE5?
  369.     JR    NZ,BEGIN2    ; No
  370.  
  371.     LD    E,255
  372.     LD    C,85        ; Get access flags byte
  373.     CALL    BDOS
  374.     LD    (AFBYTE),A    ; Store it
  375.     JR    BEGIN3
  376.  
  377. BEGIN2:    LD    DE,ACBOFF    ; Offset to access flags byte
  378.     CALL    GETOFF        ; Get address
  379.     LD    A,(HL)        ; HL points to access flags byte
  380.     LD    (AFBYTE),A    ; Store it
  381.  
  382. ;
  383. ; Set WRTLOC, display time on system
  384. ;
  385. BEGIN3:    CALL    SETLCK        ; Set WRTLOC if needed
  386.     CALL    CATCH        ; Gobble up garbage characters from line
  387.     CALL    TIME        ; Get clock values and display time on
  388.  
  389. ;
  390. ;-------------------------------------------------------------------------;
  391. ; P a r s e   ' M o d e '   f r o m   C o m m a n d   T a i l          |
  392. ;-------------------------------------------------------------------------;
  393. ;
  394. ; Second character in CP/M FCB contains program mode
  395. ;
  396.     LD    HL,FCB+1
  397.     LD    A,(HL)        ; Get the main option
  398.     LD    (MODE),A    ; Save it for later use
  399.     CP    'F'        ; Free space?
  400.     JP    Z,SPACE        ; Yes
  401.     CP    'A'        ; .ARC/.ARK member extraction?
  402.     JP    Z,CKSND-3    ; Yes
  403.     CP    'L'        ; .LBR member extraction?
  404.     JP    Z,CKSND-3    ; Yes
  405.     CP    'S'        ; Send a file?
  406.     JP    Z,CKSND        ; Yes
  407.     CP    'R'        ; Receive a file?
  408.     JP    NZ,HELP        ; No, show help guide
  409.  
  410. ;
  411. ; Check additional 'R'eceive mode options
  412. ;
  413.     INC    HL        ; Point to next option
  414.     LD    A,(HL)        ; Put in A
  415.     CP    'P'        ; Receive Private?
  416.     JR    Z,CKRCV2-3    ; Yes
  417.     CP    'W'        ; Receive Privileged?  (No descriptions)
  418.     JR    NZ,CKRCV1    ; No
  419.     LD    A,(PUPOPT)    ; Is >0 if allowing privileged uploads
  420.     LD    (PUPFLG),A    ; Sets our flag this way
  421.     OR    A        ; Allowed?
  422.     JP    Z,HELP        ; No, show help guide
  423.     JR    CKRCV2        ; Else get next option
  424.  
  425. CKRCV1:    CP    'M'        ; Receive message?
  426.     JR    NZ,CKRCV3    ; No
  427.     LD    A,(FCB1+1)    ; See if a filename was requested
  428.     CP    ' '
  429.     JP    Z,HELP        ; No, batch mode not allowed
  430.     LD    A,(MSGFIL)    ; Is >0 if allowing message uploads
  431.     LD    (MSGFLG),A     ; Sets our flag this way
  432.     OR    A        ; Allowed?
  433.     JP    Z,HELP        ; No, show help guide
  434.     LD    A,'P'        ; Else...
  435.     LD    (PRIVATE),A    ; Set the private flag
  436.  
  437. CKRCV2:    INC    HL        ; Point to next option
  438.     LD    A,(HL)        ; Put in A
  439.  
  440. CKRCV3:    CP    ' '        ; Anything there?
  441.     JP    Z,BCHMSG    ; No, see if requesting Batch
  442.     CP    'B'        ; Batch mode?
  443.     JP    Z,BCHMSG    ; Yes
  444.     CP    'C'        ; Force Checksum?
  445.     JP    Z,CHKMSG    ; Yes
  446.     CP    'X'        ; Force 128 byte packets?
  447.     JP    Z,XMDMSG    ; Yes
  448.     CP    'K'        ; Force 1k packets?
  449.     JP    Z,YMDMSG    ; Yes
  450.     JP    HELP        ; Invalid option, show help guide
  451.  
  452. ;
  453. ; Check additional 'S'end mode options
  454. ;
  455.     LD    (LBRARC),A    ; Set .LBR/.ARK/.ARC extraction flag
  456.  
  457. CKSND:    INC    HL        ; Next option on command line
  458.     LD    A,(LBRARC)    ; Get the member extraction flag
  459.     OR    A        ; Is is set?
  460.     JR    Z,CKSND0    ; No, we can check for batch
  461.     LD    A,(HL)        ; Get the character
  462.      CP    ' '        ; Any more options?
  463.     JP    Z,YMDMSG    ; No, and batch not used with extractions
  464.  
  465. CKSND0:    LD    A,(HL)        ; Get the character back
  466.     CP    ' '        ; Any more options?
  467.     JR    Z,BCHMSG    ; No, check for batch intention
  468.     CP    'C'        ; Force checksums?
  469.     JP    Z,CHKMSG    ; Show protocol
  470.     CP    'X'        ; Force XMODEM protocol?
  471.     JP    Z,XMDMSG    ; Show protocol
  472.     CP    'K'        ; Force 1k protocol?
  473.     JP    Z,YMDMSG    ; Show protocol
  474.     LD    A,(LBRARC)    ; Get LBR/ARC extraction flag
  475.     OR    A        ; Enabled?
  476.     JP    NZ,NOMSG    ; Yes, ignore Batch
  477.     LD    A,(HL)        ; Get option back
  478.     CP    'B'        ; Forcing batch?
  479.     JR    NZ,CKSND1    ; No
  480.     LD    A,(PRIVATE)    ; Get special download area flag
  481.     OR    A        ; Enabled?
  482.     JP    NZ,NOMSG    ; Yes, don't allow batch
  483.     JP    BCMSG2        ; Go set batch flag and display mode
  484.  
  485. CKSND1:    CP    'P'        ; Send private?
  486.     JP    NZ,HELP        ; No
  487.     LD    (PRIVATE),A    ; Enable private download
  488.     JR    CKSND        ; Loop for more options
  489.  
  490. ;
  491. ; Display the currently selected (or default) protocol.
  492. ;
  493. BCHMSG:    LD    A,(MODE)    ; Get main option again
  494.     CP    'R'        ; Receiving?
  495.     JR    NZ,BCMSG1    ; No
  496.     LD    A,(FCB1+1)    ; Was a file requested?
  497.     CP    ' '
  498.     JR    Z,BCMSG2    ; No, in batch receive
  499.  
  500.     LD    HL,FCB1+1    ; Point to secondary FCB
  501.     CALL    CKWILD        ; Check for wildcards
  502.     LD    A,(BATCH)    ; Batch enabled now?
  503.     OR    A
  504.     JR    NZ,BCMSG2    ; Yes, report protocol
  505.     JR    YMDMSG        ; Else, single file receive.  Default to 1k
  506.  
  507. ;
  508. ; Scan the command line to see if there was any intention of batch and if
  509. ; so, set program environment to Ymodem 1k batch protocol.
  510. ;
  511. BCMSG1:    XOR    A        ; Clear accumulator
  512.     LD    (MODE),A    ; Gets us back from the SBTCH routines
  513.     CALL    SBTCH        ; Check for batch intention
  514.     LD    A,'S'
  515.     LD    (MODE),A    ; Fix the transfer mode flag
  516.     LD    A,(BATCH)    ; Get the batch mode flag
  517.     OR    A        ; Was it enabled?
  518.     JR    Z,YMDMSG    ; No, sending single file.  Default to 1k
  519.  
  520. BCMSG2:    CALL    LOW41K        ; 1k packets allowed?
  521.     JP    C,TOOSLOW    ; No, can't use batch
  522.     LD    A,1
  523.     LD    (BATCH),A    ; Enable batch
  524.     CALL    ILPRTB
  525.     DB    '1k Batch',0
  526.     JR    MSGEND
  527.  
  528. YMDMSG:    CALL    LOW41K        ; 1k packets allowed?
  529.     JR    C,NOMSG        ; No
  530.     LD    (KFLG),A    ; Enable 1k
  531.     CALL    ILPRTB
  532.     DB    '1k',0
  533.     JR    MSGEND
  534.  
  535. XMDMSG:    XOR    A        ; Clear accumulator
  536.     LD    (KFLG),A    ; Disable 1k blocks
  537.     CALL    ILPRTB
  538.     DB    '128 byte CRC',0
  539.     JR    MSGEND
  540.  
  541. CHKMSG:    XOR    A        ; Clear accumulator
  542.     LD    (CRCFLG),A    ; Disable CRC
  543.     LD    (KFLG),A    ; Disable 1k blocks (not allowed in Checksum)
  544.     CALL    ILPRTB
  545.     DB    '128 byte Checksum',0
  546.  
  547. MSGEND:    CALL    ILPRTB
  548.     DB    ' enabled',0
  549.  
  550. NOMSG:    CALL    CHKTPA        ; Calculate TPA limitations
  551.     CALL    ILPRTB
  552.     DB    CR,LF,0
  553.     LD    A,(MODE)    ; Get transfer mode
  554.     CP    'R'        ; Receiving?
  555.     JP    Z,RCVFL        ; Yes
  556.     LD    A,'S'
  557.     LD    (MODE),A    ; Else make mode an 'S' (send mode)
  558.  
  559. ;
  560. ;-------------------------------------------------------------------------;
  561. ; ----> SNDFIL  -  S e n d  f i l e ( s )                  |
  562. ;-------------------------------------------------------------------------;
  563. ;
  564. ; The file specified in the ZMD command line is transferred over the phone
  565. ; to another computer with modem using the "S"end option. The data is sent
  566. ; 1 record at a time with headers, checksums, and retransmission on errors.
  567. ;
  568. SNDFIL:    LD    A,(BATCH)    ; Batch mode requested?
  569.     OR    A
  570.     JP    NZ,SBTCH    ; Yes, go handle batch mode
  571.  
  572. ;
  573. ; Take care of single file transfer - not in batch
  574. ;
  575.     CALL    LOGDU        ; Log into drive and get DPB info
  576.     CALL    GTCDUD        ; Get current binary drive/user in DUU/DUD
  577.     CALL    CNREC        ; Calculate number of records (unless LBRARC)
  578.     CALL    CATCH        ; Clear the decks
  579.     CALL    OPNFIL        ; Open the file and check restrictions
  580.  
  581. ;
  582. ; Loop back here for the start of each BATCH file sent
  583. ;
  584. SNDFL1:    LD    E,60        ; Number of seconds to wait for initial 'NAK'
  585.  
  586. SNDFL2:    CALL    FUNCHK        ; Check for function keys
  587.     CALL    SNDABT        ; Local abort?
  588.     LD    B,1
  589.     CALL    RECV        ; Wait 1 second for initial NAK
  590.     JR    C,SNDFL3    ; No character
  591.     CP    CRC        ; CRC request?
  592.     JR    Z,SNDFL4    ; Yes
  593.     CP    KSND        ; 1k request?
  594.     JR    Z,SNDFL7    ; Yes
  595.     CP    NAK        ; NAK for checksum?
  596.     JR    Z,SNDFL8    ; Yes
  597.     CP    CANCEL        ; Cancel?
  598.     JP    Z,ABORT        ; Yes
  599.  
  600. SNDFL3:    DEC    E        ; One less second
  601.     JP    Z,ABORT        ; Abort if 0
  602.     JR    SNDFL2        ; Else wait some more
  603.  
  604. ;
  605. ; Got a 'C', now wait up to 1 second for 'K'
  606. ;
  607. SNDFL4:    LD    A,(BATCH)    ; In batch mode?
  608.     OR    A
  609.     JR    NZ,SNDFL7    ; Yes, don't wait for 'K'
  610.     LD    B,1
  611.     CALL    RECV        ; Get character from remote
  612.     JR    C,SNDFL5    ; No character received, so not using 1k
  613.     AND    7FH        ; Strip high bit
  614.     CP    '{'
  615.     JR    Z,SNDFL4    ; Disregard noisy lines
  616.     CP    KSND        ; Requesting 1k?
  617.     JR    Z,SNDFL7    ; Exit if yes, otherwise set CRC
  618.  
  619. ;
  620. ; Turn on the flag for CRC
  621. ;
  622. SNDFL5:    LD    A,(KFLG)    ; KFLG manually set from 'SK'?
  623.     OR    A
  624.     JR    NZ,SNDFL7    ; If yes, keep it set
  625.  
  626. SNDFL6:    XOR    A
  627.     LD    (KFLG),A    ; Defaults to 128 character blocks
  628.     INC    A
  629.     LD    (CRCFLG),A    ; Insures in CRC mode
  630.     CALL    ILPRTL
  631.     DB    CR
  632.     DB    'CRC',0
  633.     JP    SNDFL10
  634.  
  635. ;
  636. ; Turn on the flag for 1k blocks and insure in CRC mode
  637. ;
  638. SNDFL7:    CALL    LOW41K        ; 1k packets allowed?
  639.     JP    C,SNDFL6    ; No
  640.     LD    (KFLG),A    ; Set the flag for 1k blocks
  641.     LD    (CRCFLG),A    ; Insures in CRC mode
  642.     LD    A,(BATCH)    ; In Ymodem Batch?
  643.     OR    A
  644.     CALL    NZ,OPNFIL    ; Yes, then open file/check restrictions
  645.     CALL    ILPRTL
  646.     DB    CR
  647.     DB    'Ymodem',0
  648.     JR    SNDFL10
  649.  
  650. ;
  651. ; Turn on checksum flag, insure sending 128 character blocks
  652. ;
  653. SNDFL8:    LD    A,(BATCH)    ; In batch mode now?
  654.     OR    A
  655.     JR    NZ,SNDFL9    ; If yes, exit
  656.     XOR    A
  657.     LD    (CRCFLG),A    ; Make sure in checksum mode
  658.     LD    (KFLG),A    ; Defaults to 128 character blocks
  659.     CALL    ILPRTL
  660.     DB    CR
  661.     DB    'Checksum',0
  662.     JR    SNDFL10
  663.  
  664. SNDFL9:    CALL    ILPRTL
  665.     DB    CR
  666.     DB    '-- Checksum not used in batch'
  667.     DB    CR,LF,0
  668.     JP    SNDFL2        ; If yes, ignore checksum request
  669.  
  670. SNDFL10:CALL    ILPRTL
  671.     DB    ' requested '
  672.     DB    CR,LF,0
  673.     CALL    RDBLOK        ; Put up to 16k from file into buffer
  674.     CALL    SETFLG        ; Disable 1k if less than 8 records left
  675.  
  676. ;
  677. ; Loop back here to send the next 1k/128 byte block after a successful trans-
  678. ; mission.  If using 1k blocks, check the ACK ratio.  Check total error count
  679. ; vs. records sent, and switch from 1k to 128 byte transmissions if higher.
  680. ;
  681. SNDLP:    LD    A,(KFLG)    ; Using 1k blocks?
  682.     OR    A
  683.     JP    Z,RDRECD    ; If not, skip checking 1k error ratio
  684.     LD    A,(ERRCNT)    ; See if we got any errors last record
  685.     CP    4        ; 4 or more?
  686.     JR    NC,SNDLP1    ; Yes, switch to 128 size
  687.     LD    A,(ACCERR)    ; See if up to minimum errors yet
  688.     CP    3        ; Had as many as three errors yet?
  689.     JR    C,RDRECD    ; If not, don't get excited too quickly
  690.  
  691.     LD    HL,(RECDNO)    ; Get current record number increment
  692.     LD    DE,65528    ; Have not successfully sent this 1k yet
  693.     ADD    HL,DE        ; Subtract the current increment, then
  694.     LD    DE,(ACCERR)    ; Number of non-'ACK' errors in HL
  695.     CALL    DVHLDE        ; Get ratio in BC of records/hit
  696.     CALL    GETSPD        ; Get current speed
  697.     CP    5        ; 1200 baud?
  698.     LD    A,70        ; for 1200 bps
  699.     JR    Z,$+4        ; If 1200, skip next line
  700.     LD    A,42        ; for 2400 bps
  701.     CP    C        ; Compare with actual ratio
  702.     JR    C,RDRECD    ; Continue if less hits than allowed
  703.  
  704. SNDLP1:    XOR    A        ; Clear A
  705.     LD    (KFLG),A    ; Reset system to 128 byte blocks
  706.     CALL    ILPRTL        ; Inform locally
  707.     DB    ' - YMODEM 1k blocks disabled'
  708.     DB    CR,LF,0
  709.  
  710. ;
  711. ; Read a record, refill buffer if empty, update record read
  712. ;
  713. RDRECD:    LD    A,(RECNBF)    ; Any records in the buffer?
  714.     OR    A
  715.     JR    Z,RDBLOCK    ; No, go get some
  716.     LD    A,(KFLG)    ; Using 1k blocks?
  717.     OR    A
  718.     JR    Z,RDREC1    ; No, exit
  719.     LD    A,(RECNBF)    ; See how many records in buffer
  720.     CP    8        ; 8 or more records?
  721.     JR    NC,RDREC2    ; Yes, stay in 1k blocks
  722.     XOR    A
  723.     LD    (KFLG),A    ; Reset the 1k flag for 128 byte
  724.  
  725. RDREC1:    LD    A,(RECNBF)    ; Point to number of records in buffer
  726.     DEC    A        ; Decrement it for 128 character blocks
  727.     LD    (RECNBF),A    ; Store it
  728.     JP    SNDLP2        ; Send it
  729.  
  730. RDREC2:    SUB    8        ; Subtract 8 records (1k worth)
  731.     LD    (RECNBF),A    ; Store it
  732.     JP    SNDLP2        ; Send it
  733.  
  734. ;
  735. ; Buffer is empty - read in another block of 16k
  736. ;
  737. RDBLOCK:LD    A,(EOFLG)    ; Get 'EOF' flag
  738.     CP    1        ; Is it set?
  739.     SCF            ; To show 'EOF'
  740.     JP    Z,SNDLP2    ; Got 'EOF'
  741.     CALL    RDBLOK        ; Read up to 16k into DBUF
  742.     JR    RDRECD        ; Pass record to caller
  743.  
  744. ;
  745. ; Read up to 16k from the disk file into the buffer, ready to send
  746. ;
  747. RDBLOK:    LD    C,0        ; Set number of records in block to 0
  748.     LD    DE,DBUF        ; Point to disk buffer as destination
  749.  
  750. RDBLOK1:PUSH    BC
  751.     PUSH    DE
  752.     LD    A,(LBRARC)    ; Get ARK/ARC/LBR extraction flag
  753.     OR    A        ; Enabled?
  754.     JR    Z,RDBLOK2    ; No, skip next
  755.     LD    A,(FCB+9)    ; Get filetype byte 1
  756.     AND    7FH        ; Strip high bit
  757.     CP    'A'        ; Is it an ARK/ARC extraction?
  758.     CALL    Z,RDARC        ; Yes, (flags saved at RDARC)
  759.     JR    Z,RDBLOK3    ; Same flags
  760.  
  761. RDBLOK2:CALL    STDMA        ; Set DMA address
  762.     LD    C,READ
  763.     LD    DE,FCB
  764.     CALL    BDOS
  765.  
  766. RDBLOK3:POP    DE
  767.     POP    BC
  768.     OR    A        ; Read ok?
  769.     JR    NZ,RDBLOK5    ; If not, error or end of file
  770.     LD    HL,128        ; Add length of one record
  771.     ADD    HL,DE        ; To next buffer
  772.     EX    DE,HL        ; Buffer to 'DE'
  773.     INC    C        ; More records?
  774.     LD    A,(BUFSIZ)
  775.     ADD    A,A
  776.     ADD    A,A
  777.     ADD    A,A
  778.     CP    C
  779.     JR    NZ,RDBLOK1    ; Read more
  780.  
  781. ;
  782. ; Buffer is full or got EOF
  783. ;
  784. RDBLOK4:LD    (RECNBF),A    ; Store record count
  785.     LD    HL,DBUF        ; Get the beginning buffer address
  786.     LD    (RECPTR),HL    ; Save for next record
  787.     JP    RSDMA        ; Reset DMA address to default
  788.  
  789. RDBLOK5:DEC    A        ; 'EOF'?
  790.     JR    NZ,READERR    ; Got 'EOF'
  791.  
  792. RDBLOK6:INC    A
  793.     LD    (EOFLG),A    ; Set EOF flag
  794.     LD    A,C
  795.     JR    RDBLOK4
  796.  
  797. READERR:CALL    ILPRTB
  798.     DB    CR,LF
  799.     DB    '-- Read Error: ',0
  800.     CALL    SHONM3
  801.     JP    EXIT
  802.  
  803. ;
  804. ; Now send the next record
  805. ;
  806. SNDLP2:    JP    C,SNDEOF    ; Send 'EOF' if done
  807.     CALL    INCRNO        ; Bump record number if sent ok
  808.     XOR    A        ; Initialize error count to zero
  809.     LD    (ERRCNT),A
  810.  
  811. SNDRPT:    CALL    CKABORT        ; Check for remote abort
  812.     CALL    SNDABT        ; Check for local abort
  813.     CALL    SNDHDR        ; Send a header
  814.     CALL    SNDREC        ; Send data record
  815.     CALL    SNDCHK        ; Send CRC or checksum value
  816.     CALL    GTACK        ; Get the 'ACK'
  817.     CP    ACK        ; ACK?
  818.     JR    NZ,SNDRPT    ; No, repeat transmission
  819.     LD    DE,128        ; For 128 character blocks
  820.     LD    A,(KFLG)    ; See if last block sent was 1k
  821.     OR    A
  822.     JR    Z,$+5        ; No, skip next line
  823.     LD    DE,1024        ; Else set for 1024 character blocks
  824.     LD    HL,(RECPTR)    ; Get the buffer pointer
  825.     ADD    HL,DE        ; Increment for the record just sent
  826.     LD    (RECPTR),HL    ; New buffer address for next block
  827.     LD    A,(LBRARC)    ; Get LBR/ARC/ARK extraction flag
  828.     OR    A        ; Enabled?
  829.     JP    Z,SNDLP        ; No
  830.     LD    A,(KFLG)    ; 1k enabled?
  831.     LD    DE,65535    ; 128 byte
  832.     OR    A
  833.     JR    Z,$+5
  834.     LD    DE,65528    ; 1k
  835.     LD    HL,(RCNT)    ; Alter the records-sent count
  836.     ADD    HL,DE
  837.     LD    (RCNT),HL    ; One less transmission to go
  838.     OR    A        ; 'K' flag set?
  839.     CALL    NZ,SETFLG    ; Yes, see if enough records for 1k packet
  840.     LD    HL,(RCNT)    ; See if anything was actually sent
  841.     LD    A,H
  842.     OR    L        ; L and H both zero now?
  843.     JP    NZ,SNDLP    ; No, continue
  844.  
  845. ;
  846. ; End of Transmission (Send mode)
  847. ;
  848. SNDEOF:    LD    A,(LOGLDS)    ; Counting transfers?
  849.     OR    A
  850.     JR    Z,SNDEOF1    ; No
  851.     LD    A,(PRIVATE)    ; Is this a private transfer?
  852.     OR    A
  853.     JR    NZ,SNDEOF1    ; Yes, don't increment download count
  854.     LD    IY,(DNLDS)    ; Get Downloads counter address
  855.     INC    (IY)        ; One more download since log in
  856.  
  857. SNDEOF1:CALL    LOGCALL        ; Log transfer if supposed to
  858.     CALL    EOFSND
  859.     CALL    ADDTON        ; Update BYE's time on byte if supposed to
  860.     CALL    ALLDON
  861.     JP    DONE
  862.  
  863. ;
  864. ; See if enough records left to use 1k protocol
  865. ;
  866. SETFLG:    LD    HL,(RCNT)
  867.     LD    A,H        ; Anything in the 'H' register?
  868.     OR    A
  869.     RET    NZ        ; Yes, enough records for another 1k packet
  870.     LD    A,L        ; Get number of records in 'L' register
  871.     CP    8        ; At least 8 yet?
  872.     RET    NC        ; Yes, keep going
  873.     XOR    A        ; Reset the 'K' flag
  874.     LD    (KFLG),A
  875.     RET
  876.  
  877. ;
  878. ; HL points to filename FCB - now search for it wildcards.  If any, enable
  879. ; BATCH flag and pad with '?' as needed
  880. ; 
  881. CKWILD:    LD    B,8        ; Check first 8 bytes
  882.     CALL    CKWLD1
  883.     LD    B,3        ; And check filetype
  884.  
  885. CKWLD1:    LD    A,(HL)        ; Get the character
  886.     CP    '*'        ; '*'?
  887.     JR    NZ,CKWLD2    ; No, check for little wildcards
  888.     LD    (BATCH),A    ; Enable AUTO-BATCH
  889.     LD    A,'?'        ; Fill rest with '?' character
  890.     JP    INITIT        ; Initialize
  891.  
  892. CKWLD2:    CP    '?'        ; '?'?
  893.     JR    NZ,$+5        ; No, don't enable AUTO-BATCH
  894.     LD    (BATCH),A    ; Enable AUTO-BATCH
  895.     INC    HL        ; Point to next character
  896.     DJNZ    CKWLD1        ; Loop until B=0
  897.     RET
  898.  
  899. ;
  900. ; Get the current drive/user
  901. ;
  902. GTCDUD:    LD    A,0FFH        ; Stuffed into E at RECAR1
  903.     CALL    RECAR1        ; Get current user area
  904.     LD    (DUU),A        ; Store it
  905.     LD    C,CURDRV    ; Get current drive
  906.     CALL    BDOS
  907.     LD    (DUD),A     ; Store it
  908.     RET
  909.  
  910. ;
  911. ;-------------------------------------------------------------------------;
  912. ; S e n d   B a t c h                              |
  913. ;-------------------------------------------------------------------------;
  914. ;
  915. ; Copy original command line buffer to internal work buffer
  916. ;
  917. SBTCH:    LD    A,(FSTFLG)    ; If first time through
  918.     OR    A
  919.     JP    NZ,SBTCH1    ; If not first time, exit
  920.  
  921.     LD    HL,TBUF        ; Source
  922.     LD    DE,CMDBUF    ; Destination
  923.     LD    BC,128        ; Count
  924.     LDIR            ; Move
  925.  
  926. ;
  927. ; Locate end of command line and place a ' ' as a delimiter
  928. ;
  929.     LD    HL,CMDBUF    ; Point to number of bytes in line
  930.     LD    B,0        ; Zero high order
  931.     LD    C,(HL)        ; Number of characters in command line
  932.     INC    HL        ; Point to start of line
  933.     ADD    HL,BC        ; Plus number of characters equals end of line
  934.     LD    (HL),' '    ; Place the delimiter at end of line
  935.     INC    BC        ; Increment character count for delimiter
  936.  
  937. ;
  938. ; Count ambiguous/unambiguous filenames in command line
  939. ;
  940.     XOR    A        ; Clear accumulator
  941.     LD    (FILCNT),A    ; Reset the file count
  942.     LD    (NAMECT),A    ; Reset name count (used in parsing routines)
  943.     LD    HL,CMDBUF+2    ; Point to command tail option
  944.     LD    A,' '        ; Looking for space/non-space characters
  945.     CPIR            ; On command option, look for next space
  946.     JP    PO,SCANDN    ; If at end of line, done
  947.     CPI            ; Find first character of first name
  948.     JP    PO,SCANDN    ; If at end of line, done
  949.     JR    Z,$-5        ; Eat extra spaces
  950.     DEC    HL        ; CPI is one ahead of us, so back up
  951.     LD    (BGNMS),HL    ; Store address of beginning name
  952.     INC    HL        ; And it was supposed to be, so restore it
  953.  
  954. SCANLP:    CPIR            ; Move to end of current name (next space)
  955.     EX    AF,AF'        ; Save A (match char) & current flags (result)
  956.     LD    A,(NAMECT)    ; Get current name count
  957.     INC    A        ; Bump it one
  958.     LD    (NAMECT),A    ; Put it back
  959.     CP    255        ; 255 names?
  960.     JR    Z,SCANDN    ; Yes, that's all we allow
  961.     EX    AF,AF'        ; Restore A and old flags
  962.     JP    PO,SCANDN    ; If at end of line, done
  963.     CPI            ; Find next non-space character
  964.     JP    PO,SCANDN    ; If at end of line, done
  965.     JR    Z,$-5        ; Was a space, keep looking
  966.     JR    SCANLP        ; Found next non-space, find next name
  967.  
  968. SCANDN:    LD    A,(NAMECT)    ; Get the ambiguous filename count
  969.     OR    A        ; Were there any?
  970.     JP    Z,HELP        ; No, they must need help
  971.     CP    1        ; Just 1 name?
  972.     JR    Z,$+5        ; If only 1, don't force AUTO-BATCH here
  973.     LD    (BATCH),A    ; Else set batch mode flag (for AUTO-BATCH)
  974.     LD    HL,NAMBUF    ; Get start of batch filename buffer
  975.     LD    (NBSAVE),HL    ; Save as address of the first name
  976.  
  977. ;
  978. ; Place a name in work buffer 
  979. ;
  980. TNLP:    LD    B,0        ; Initialize character count
  981.     LD    HL,(BGNMS)    ; Source is address of first name
  982.     LD    DE,FCBBUF+2    ; Destination
  983.  
  984. TNLP1:    LD    A,(HL)        ; Get a byte in A
  985.     CP    ' '        ; A space?
  986.     JR    Z,TNLP2        ; Yes, done with name
  987.     LD    (DE),A        ; Move character to FCB buffer
  988.     INC    HL        ; Increment pointers
  989.     INC    DE
  990.     INC    B        ; Bump count of characters in name
  991.     JR    TNLP1        ; Loop until space
  992.  
  993. TNLP2:    INC    HL        ; Point to next character
  994.     LD    A,(HL)        ; Put it in A
  995.     CP    ' '        ; Is it a ' '?
  996.     JR    Z,TNLP2        ; Yes, eat extra spaces
  997.     LD    (BGNMS),HL    ; Store address of next name
  998.     LD    HL,FCBBUF+1    ; # characters in filename
  999.     LD    (HL),B        ; Before name
  1000.  
  1001. ;
  1002. ; Initialize FCB for search routines
  1003. ;
  1004.     LD    A,0        ; String of all 0's for intitialization
  1005.     LD    HL,FCB        ; Destination
  1006.     LD    B,16        ; 16 bytes
  1007.     CALL    INITIT        ; Initialize FCB
  1008.  
  1009.     LD    HL,FCBBUF+1    ; Point to # of bytes in command line
  1010.     LD    D,0        ; Zero high order
  1011.     LD    E,(HL)        ; Load DE pair with # bytes
  1012.     INC    HL        ; Increment to start of command line
  1013.     ADD    HL,DE        ; Point to byte after last character
  1014.     LD    (HL),CR        ; Store CR for delimiter
  1015.  
  1016. ;
  1017. ; Check for valid drive/user combination and move filename to FCB
  1018. ;
  1019.     LD    HL,FCBBUF+2    ; Start of filename
  1020.     LD    DE,DUSAVE    ; Isolate possible 'duu:'
  1021.     LD    BC,4        ; Up to 4 bytes
  1022.     LDIR            ; For logging into specified d/u
  1023.  
  1024.     LD    HL,FCBBUF+1    ; Point to amount of characters in filename
  1025.     LD    B,(HL)        ; In B for d/u parsing routines
  1026.     INC    B        ; Increment character count for CR terminator
  1027.     INC    HL        ; And point to start filename again
  1028.     LD    (SAVEHL),HL    ; Initialize 'current' address pointer
  1029.  
  1030.     LD    A,(MODE)    ; Get transfer mode
  1031.     PUSH    AF        ; Save it while checking valid d/u
  1032.     XOR    A         ; Zero accumulator for new mode
  1033.     LD    (MODE),A    ; Save it (keeps us out of trouble in LGDU1:)
  1034.     CALL    LGDU1        ; Check valid d/u and copy filename to FCB
  1035.     CALL    GTCDUD        ; Get current binary drive user in DUU/DUD
  1036.     POP    AF        ; Get possible previously determined mode
  1037.     LD    (MODE),A    ; Restore
  1038.     LD    HL,FCB+1    ; Filename FCB
  1039.     CALL    CKWILD        ; Check it for wildcards, enable Batch if any
  1040.  
  1041.     LD    A,(MODE)    ; Get file transfer mode
  1042.     OR    A        ; 0=checking batch intention
  1043.     RET    Z        ; All done if so
  1044.  
  1045. ;
  1046. ; Now search directory and store first matching filename
  1047. ;
  1048.     CALL    RSDMA        ; Reset to default memory address
  1049.     LD    A,'?'
  1050.      LD    (FCBEXT),A    ; Fetch all extents of matching filenames
  1051.     XOR    A
  1052.     LD    (FCBRNO),A    ; Clear FCB record number byte
  1053.     LD    DE,FCB        ; Use default FCB for search
  1054.     LD    C,SRCHF        ; Search for first occurence
  1055.     CALL    BDOS
  1056.     CP    0FFH        ; Anything found?
  1057.     JP    Z,NEXTNM    ; No, go get next ambiguous filename
  1058.     LD    HL,(LIST)    ; Initialize list pointer parameters
  1059.     LD    (LISTPOS),HL    ; Save current position of list
  1060.  
  1061. ;
  1062. ; Calculate offset to matched directory entry
  1063. ;
  1064. FNDENT:    AND    3        ; Zero based, two bit index
  1065.     ADD    A,A        ; *2
  1066.     ADD    A,A        ; *4
  1067.     ADD    A,A        ; *8
  1068.     ADD    A,A        ; *16
  1069.     ADD    A,A        ; *32 to make position index
  1070.     LD    C,A        ; Put in BC
  1071.     XOR    B        ; Clear MSB
  1072.     LD    HL,TBUF        ; Address of default command line buffer
  1073.     ADD    HL,BC        ; And offset to matched directory entry
  1074.     LD    A,(DUD)        ; Get drive number
  1075.     LD    (HL),A        ; Put in front of name in name buffer
  1076.  
  1077. ;
  1078. ; Check the match for download restrictions
  1079. ;
  1080.     PUSH    HL        ; Save address of matched entry
  1081.     PUSH    HL        ; Save another copy
  1082.     POP    IX        ; As address of filename to check
  1083.     CALL    RESTRCT        ; Check for download restrictions
  1084.     POP    HL        ; Get our matched entry address back
  1085.     JP    NZ,DONEXT    ; NZ=entry not allowed
  1086.  
  1087. ;
  1088. ; Trap zero length file before adding to list
  1089. ;
  1090.     PUSH    HL        ; Save matched entry address
  1091.     POP    IY        ; Get a copy in IY
  1092.     LD    A,(IY+12)    ; Get the extent byte
  1093.     OR    A        ; Is this the first extent?  (#0)
  1094.     JR    NZ,COPYNM    ; No, can't be 0 length (at least 16k already)
  1095.     LD    A,(IY+15)    ; Get it
  1096.     OR    A        ; Any records?
  1097.     JP    Z,DONEXT    ; No, zero length, but in batch so no messages
  1098.  
  1099. ;
  1100. ; Copy the name to list
  1101. ;
  1102. COPYNM:    LD    A,(FSTFLG)    ; Displayed the following message yet?
  1103.     OR    A
  1104.     JR    NZ,NAM2LST    ; Yes, they alreay know to wait
  1105.     PUSH    HL        ; Save matched entry address
  1106.     CALL    ILPRTB
  1107.     DB    CR,LF
  1108.     DB    'Locating selection(s)...',0
  1109.     LD    A,1
  1110.     LD    (FSTFLG),A    ; Set so message don't show again
  1111.     POP    HL        ; Restore matched entry address
  1112.  
  1113. NAM2LST:LD    DE,(LISTPOS)    ; Pointer to current load point in list
  1114.     LD    B,12        ; Move drive number and name to list
  1115.  
  1116. NM2LST1:LD    A,(HL)        ; HL contains address of entry
  1117.     AND    7FH        ; All done with high bits
  1118.     LD    (DE),A        ; Move it to list
  1119.     INC    HL        ; Increment pointer
  1120.     INC    DE
  1121.     DJNZ    NM2LST1        ; Loop until B equals 0
  1122.     LD    A,(HL)        ; Get the EX byte
  1123.     LD    (DE),A        ; Put it in list
  1124.     INC    HL        ; Increment to RC byte
  1125.     INC    HL
  1126.     INC    HL
  1127.     INC    DE
  1128.     LD    A,(HL)        ; Get it
  1129.     LD    (DE),A        ; Put it in list
  1130.     INC    DE        ; Point to start of next name in list
  1131.     LD    A,(DUU)
  1132.     LD    (DE),A
  1133.     INC    DE
  1134.     INC    DE
  1135.     LD    (LISTPOS),DE    ; Store address of next load point
  1136.  
  1137. ;
  1138. ; Search for next occurance of specified filename
  1139. ;
  1140. DONEXT:    LD    C,SRCHN        ; Search next function code
  1141.     LD    DE,FCB        ; Filename specification field
  1142.     CALL    BDOS
  1143.     CP    0FFH        ; See if all through directory yet
  1144.     JP    NZ,FNDENT    ; If not, calculate code offset and add 2 list
  1145.  
  1146. ;
  1147. ; Trap conditions of 0 files found
  1148. ;
  1149.      LD    HL,(LISTPOS)    ; Get the end of list address
  1150.     LD    DE,(LIST)     ; Get beginning of list address
  1151.     CALL    CPDEHL        ; Are they the same?
  1152.     JP    Z,NEXTNM    ; Yes, none of the files found were allowed
  1153.  
  1154. ;
  1155. ; Prepare associated sort parameters
  1156. ;
  1157.     LD    HL,(LIST)    ; Adjust I and J pointers for initial sort
  1158.     LD    (LISTI),HL    ; Beginning of list
  1159.     LD    DE,ITEMSZ    ; Get offset to next name
  1160.     ADD    HL,DE        ; Add the offset
  1161.     LD    (LISTJ),HL    ; Into J variable
  1162.  
  1163. ;
  1164. ; Don't need a sort if only 1 file extent found
  1165. ;
  1166.     LD    HL,(LIST)    ; Was there more than one entry found?
  1167.     LD    BC,ITEMSZ
  1168.     ADD    HL,BC
  1169.     EX    DE,HL
  1170.     LD    HL,(LISTPOS)    ; Next load name of list is start of buffer
  1171.     LD    (LISTEND),HL    ; Set list end marker
  1172.     CALL    CPDEHL        ; Compare DE address with HL address
  1173.     JP    Z,MINNN        ; If same, no sort needed
  1174.  
  1175. ;
  1176. ; Sort the list by disk, filename, and EX byte.
  1177. ;
  1178. SORT:    LD    HL,(LISTI)    ; Compare entries I and J
  1179.     LD    DE,(LISTJ)
  1180.     LD    B,13        ; Number of bytes to compare
  1181.     CALL    MATCH        ;
  1182.     JR    NC,SORT1    ; Swap entries if J is larger than I
  1183.     LD    HL,(LISTI)    ; Get our original pointers back
  1184.     LD    DE,(LISTJ)
  1185.     LD    B,ITEMSZ    ; Counter for number of bytes to swap
  1186.  
  1187. SWAP:    LD    C,(HL)        ; Get character from string 1
  1188.     LD    A,(DE)        ; And one from other string
  1189.     LD    (HL),A        ; Second into first
  1190.     LD    A,C        ; First into second
  1191.     LD    (DE),A
  1192.     INC    HL        ; Bump swap pointers
  1193.     INC    DE
  1194.     DJNZ    SWAP        ; Loop until B=0
  1195.  
  1196. SORT1:    LD    HL,(LISTJ)    ; Increment J pointer
  1197.     LD    DE,ITEMSZ    ; By the amount of items per entry
  1198.     ADD    HL,DE
  1199.     LD    (LISTJ),HL
  1200.     LD    DE,(LISTEND)    ; Get the address of the end of list
  1201.     CALL    CPDEHL        ; DE and HL the same?
  1202.     JR    NZ,SORT        ; No, so more J loop
  1203.  
  1204.     LD    HL,(LISTI)    ; Get the I pointer
  1205.     LD    DE,ITEMSZ    ; Get offset to next name
  1206.     ADD    HL,DE        ; Add
  1207.     LD    (LISTI),HL 
  1208.     ADD    HL,DE        ; Add offset to next name
  1209.     LD    (LISTJ),HL    ; Start J loop over again
  1210.     LD    DE,(LISTEND)    ; Get the address of the end of list
  1211.     CALL    CPDEHL        ; DE and HL the same?
  1212.     JR    NZ,SORT        ; No, must be more I loop to go
  1213.  
  1214. ;
  1215. ; List minimization loop
  1216. ;
  1217.     LD    HL,(LIST)    ; Point to the beginning of our list
  1218.     LD    (LISTI),HL    ; Initialize current name pointer
  1219.     LD    DE,ITEMSZ    ; Get offset to next name
  1220.     ADD    HL,DE        ; Add it to current name address
  1221.     LD    (LISTJ),HL    ; Store as next name
  1222.  
  1223. MINCL:    LD    DE,(LISTEND)    ; End of list address
  1224.     LD    HL,(LISTJ)    ; Next name address
  1225.     CALL    CPDEHL        ; Are they the same?
  1226.     JR    Z,MINNN        ; Yes, go set kbytes on last name (End of list)
  1227.  
  1228.     LD    DE,(LISTJ)    ; Next name address
  1229.     LD    HL,(LISTI)    ; Current name address
  1230.     LD    B,12        ; # of bytes to check
  1231.     CALL    MATCH        ; Are they the same?
  1232.     JR    NZ,MINNN    ; No, go set kbytes on last extent (Next name)
  1233.  
  1234. ;
  1235. ; Increment next name pointer and get parameter bytes
  1236. ;
  1237.     LD    HL,(LISTJ)    ; Fetch EX and RC from next name
  1238.     LD    DE,ITEMSZ    ; Offset to next name
  1239.     ADD    HL,DE        ; Add it
  1240.     LD    (LISTJ),HL    ; Save bumped J value
  1241.  
  1242.     DEC    HL        ; Point to parameter bytes of previous name
  1243.     DEC    HL
  1244.     DEC    HL
  1245.     LD    B,(HL)        ; Save the RC byte
  1246.     DEC    HL
  1247.     LD    C,(HL)        ; Save the EX number
  1248.  
  1249.     LD    HL,(LISTI)    ; Point at current name
  1250.     ADD    HL,DE        ; Point at current name info bytes
  1251.     DEC    HL
  1252.     DEC    HL
  1253.     DEC    HL
  1254.     LD    D,(HL)        ; Fetch that RC byte
  1255.     DEC    HL
  1256.     LD    E,(HL)        ; Fetch current EX byte
  1257.  
  1258.     LD    A,E        ; Check if new EXtent is bigger than last
  1259.     CP    C
  1260.     JR    NC,MINCL    ; Skip using size of a less or equal EX
  1261.     LD    (HL),C        ; Put new sizes into the location
  1262.     INC    HL
  1263.     LD    (HL),B        ; New RC byte too
  1264.     JR    MINCL        ; Continue handling as current file
  1265.  
  1266. ;
  1267. ; File size computation loop
  1268. ;
  1269. MINNN:    LD    HL,(LISTI)    ; Point to name to convert records
  1270.     LD    DE,ITEMSZ-4    ; Index to largest extent number
  1271.     ADD    HL,DE        ; Add the offset
  1272.     LD    B,(HL)        ; Get the extent number for a loop counter
  1273.     INC    HL        ; Bump to the last extent RC byte
  1274.     PUSH    HL        ; Save pointer to list parameters
  1275.     LD    HL,0        ; Zero extent total record count
  1276.     LD    DE,128        ; Set size of one extent
  1277.  
  1278. ;
  1279. ; Calculate total number of 128 byte records
  1280. ;
  1281. MINEL:    LD    A,B        ; Get the number of extents left
  1282.     OR    A        ; Any more?
  1283.     JR    Z,MINELD    ; No, done with 128 multiply
  1284.     ADD    HL,DE        ; Else add another 128 to HL
  1285.     DEC    B        ; 1 less extent left
  1286.     JR    MINEL        ; Loop until no more
  1287.  
  1288. MINELD:    EX    DE,HL        ; Total extent size to DE
  1289.     POP    HL        ; Get back RC byte pointer
  1290.     LD    B,0
  1291.     LD    C,(HL)        ; Get final extent size to BC
  1292.     EX    DE,HL        ; Add remainder to total records in DE
  1293.     ADD    HL,BC
  1294.     LD    B,H        ; Move total record count to BC
  1295.     LD    C,L
  1296.     LD    HL,(TOTREC)    ; Get current total records
  1297.     ADD    HL,BC        ; Add records of this file
  1298.     LD    (TOTREC),HL    ; And save it for later display
  1299.     EX    DE,HL        ; Get table entry pointer back in HL
  1300.     CALL    ROUNDK        ; Get disk space needed for file DE
  1301.     LD    (HL),D        ; Put kilobyte count in table
  1302.     DEC    HL
  1303.     LD    (HL),E
  1304.     LD    A,(FILCNT)    ; Bump the file count
  1305.     CP    255        ; 255 file names yet?
  1306.     JR    Z,MINN0        ; Yes, that's all we allow
  1307.     INC    A        ; Else bump it one
  1308.     LD    (FILCNT),A    ; Store it
  1309.     LD    HL,(FILEK)    ; Get current total file kilobytes
  1310.     ADD    HL,DE        ; Add in the current file's kilobyte size
  1311.     LD    (FILEK),HL    ; And store it
  1312.     LD    HL,(LISTI)    ; Source
  1313.     LD    DE,(NBSAVE)    ; Destination
  1314.     LD    BC,16        ; 16 byte count
  1315.     LDIR            ; Move filename to names buffer
  1316.     LD    (NBSAVE),DE    ; And store address to put next filename
  1317.  
  1318. MINN0:    LD    DE,(LISTJ)    ; Done with all names
  1319.     LD    HL,(LISTEND)    ; Check if at end of list
  1320.     CALL    CPDEHL
  1321.     JR    Z,NEXTNM    ; Get next ambiguous filename, if finished
  1322.     LD    HL,(LISTI)    ; Point to LISTI value
  1323.     LD    DE,ITEMSZ    ; Point to next position
  1324.     ADD    HL,DE
  1325.     LD    (LISTI),HL    ; Set new working LISTI
  1326.     LD    DE,(LISTI)
  1327.     LD    HL,(LISTJ)    ; Next name position to copy from
  1328.     CALL    CPDEHL        ; See if pointers only one apart
  1329.     JR    Z,MINN1        ; If so, don't cover up one name
  1330.     LD    BC,ITEMSZ
  1331.     LDIR            ; Move that name up there
  1332.     JR    MINN2
  1333.  
  1334. MINN1:    LD    DE,ITEMSZ    ; No open slot, so just move LISTJ up one slot
  1335.     ADD    HL,DE
  1336.  
  1337. MINN2:    LD    (LISTJ),HL
  1338.     JP    MINCL        ; Go to MIN NAME start of loop
  1339.  
  1340. NEXTNM:    LD    A,(OLDDRV)
  1341.     CALL    RECDRX        ; Restore default drive
  1342.     LD    A,(OLDUSR)
  1343.     CALL    RECAR1        ; Restore default user
  1344.     LD    A,(NAMECT)    ; Get number of names found
  1345.     DEC    A        ; Decrement it
  1346.     LD    (NAMECT),A    ; Put it back
  1347.     JP    NZ,TNLP        ; Loop until zero
  1348.     LD    (FSTFLG),A    ; Done with first time flag, reinitialize it
  1349.     LD    HL,NAMBUF    ; Save start of buffer
  1350.     LD    (NBSAVE),HL
  1351.  
  1352.     LD    A,(FILCNT)    ; Get total files
  1353.     LD    (SHOCNT),A
  1354.     OR    A        ; Were there any?
  1355.     JR    NZ,NXTNM1    ; Yes
  1356.     CALL    ILPRT
  1357.     DB    CR,LF,0
  1358.     JP    NOFILE        ; No
  1359.  
  1360. NXTNM1:    CALL    ILPRTB
  1361.     DB    CR
  1362.     DB    'Number of files found    > ',0
  1363.     LD    A,(SHOCNT)
  1364.     LD    L,A
  1365.     LD    H,0
  1366.     CALL    DECOUT        ; Show number of files found
  1367.     LD    HL,(TOTREC)
  1368.     LD    (RCNT),HL
  1369.     LD    A,1
  1370.     LD    (SBSHOW),A    ; Get's us back early
  1371.     CALL    OPNOK2        ; Go show total file stats
  1372.     XOR    A
  1373.     LD    (SBSHOW),A
  1374.  
  1375. SBTCH1:    LD    A,(FILCNT)    ; Get the count of files to send
  1376.     OR    A        ; Is there any?
  1377.     JP    Z,SNDFN        ; No
  1378.     LD    A,(FSTFLG)    ; Past first batch file yet?
  1379.     LD    (CONONL),A    ; Toggle to local display only
  1380.     OR    A
  1381.     CALL    NZ,CLEARIT    ; Else show local
  1382.     CALL    ILPRT
  1383.     DB    CR,LF,LF
  1384.     DB    'Total transfer time      > ',0
  1385.     CALL    GETSPD        ; Get speed indicator
  1386.     CP    1        ; Are we at 300 bps?
  1387.     LD    HL,XTABLE    ; This gives us 128-byte transfer time
  1388.     JR    Z,$+5        ; Yes, skip next line, show 128-byte time
  1389.     LD    HL,KTABLE    ; This gives us 1k transfer time
  1390.     LD    D,0
  1391.     LD    E,A        ; Set up for table access
  1392.     ADD    HL,DE        ; Index to proper factor
  1393.     ADD    HL,DE
  1394.     LD    E,(HL)
  1395.     INC    HL
  1396.     LD    D,(HL)
  1397.     LD    HL,(TOTREC)    ; Get number of records
  1398.     CALL    FILTM1
  1399.     CALL    XFRTIM        ; Check for time restrictions
  1400.     CALL    ILPRT
  1401.     DB    CR,LF,0
  1402.     LD    A,(FSTFLG)
  1403.     OR    A
  1404.     CALL    Z,DLRDY
  1405.  
  1406. ;
  1407. ; Send the batch filename to remote
  1408. ;
  1409. SNDFN:    CALL    CKABORT        ; Check for remote abort
  1410.     LD    HL,FCB
  1411.     CALL    INITFCB        ; Initialize FCB
  1412.     XOR    A
  1413.     LD    (ERRCNT),A    ; Reset the error count
  1414.     INC    A
  1415.     LD    (CONONL),A    ; Set to local display only
  1416.     LD    A,(FILCNT)    ; Get file count
  1417.     OR    A
  1418.     JP    Z,CCHECK    ; No more files, exit
  1419.     LD    A,1
  1420.     LD    (CRCFLG),A    ; Make sure in CRC mode
  1421.  
  1422.     LD    A,0FFH
  1423.     CALL    RECAR1        ; Get the current user area
  1424.     LD    B,A        ; Save current user area
  1425.     PUSH    BC        ; On stack
  1426.     LD    HL,(NBSAVE)    ; Get start of filename
  1427.     LD    BC,14        ; Offset to user area
  1428.     ADD    HL,BC        ; Point to binary user area
  1429.     LD    A,(HL)        ; Get it
  1430.     POP    BC        ; Get current user area back
  1431.     CP    B        ; Same?
  1432.     CALL    NZ,RECAR1    ; No, but it is now
  1433.     CALL    SPCDRV        ; Get disk parameter block info
  1434.  
  1435.     LD    HL,(NBSAVE)    ; Get address of next batch filename
  1436.     INC    (HL)        ; Escape default situation in FCB drive byte
  1437.     LD    DE,FCB        ; Where to put it
  1438.     LD    BC,12        ; 12 bytes for drive and filename
  1439.     LDIR            ; Move
  1440.     LD    BC,4        ; Next filename is 4 bytes away
  1441.     ADD    HL,BC        ; Add offset
  1442.     LD    (NBSAVE),HL    ; Store address for next filename
  1443.     LD    HL,(RECPTR)    ; Where to load the 0 block
  1444.     EX    DE,HL        ; Put into DE
  1445.     LD    HL,FCB+1    ; Get the start of the filename in HL
  1446.     LD    B,8
  1447.  
  1448. SZMD1:    LD    A,(HL)
  1449.     AND    7FH        ; Strip any high bit set
  1450.     OR    A
  1451.     JR    Z,SZMD6        ; Null pathname
  1452.     CP    ' '
  1453.     JR    Z,SZMD3
  1454.  
  1455. SZMD2:    CALL    LCASE        ; Put file name in lower case for UNIX
  1456.     LD    (DE),A
  1457.     INC    HL
  1458.     INC    DE
  1459.     DJNZ    SZMD1
  1460.     JR    SZMD4
  1461.  
  1462. SZMD3:    INC    HL        ; Skip over spaces if short name
  1463.     DJNZ    SZMD3
  1464.  
  1465. SZMD4:    LD    A,(HL)
  1466.     CP    ' '
  1467.     JR    Z,SZMD6        ; Missing file type field
  1468.     LD    A,'.'        ; Send name-type seperator
  1469.     LD    (DE),A
  1470.     INC    DE
  1471.     LD    B,3
  1472.  
  1473. SZMD5:    LD    A,(HL)
  1474.     AND    7FH        ; Strip any high bit set
  1475.     CP    ' '
  1476.     JR    Z,SZMD6
  1477.     CALL    LCASE        ; Put in lower case for UNIX
  1478.     LD    (DE),A
  1479.     INC    HL
  1480.     INC    DE
  1481.     DJNZ    SZMD5
  1482.  
  1483. SZMD6:    EX    DE,HL        ; Get the address back to HL
  1484.     LD    (HL),0
  1485.     INC    HL
  1486.     LD    (HDRADR),HL
  1487.     CALL    CNREC        ; Get number of records in this file
  1488.     CALL    CHARLN        ; Include the ASCII character length
  1489.  
  1490. SZMD7:    LD    (HL),0        ; Fill rest with zeroes
  1491.     INC    L        ; Pad to end of block with binary 0
  1492.     JR    NZ,SZMD7
  1493.     LD    HL,(RCNT)
  1494.     LD    (BUFSTR),HL    ; Store the file length at end of block
  1495.     XOR    A        ; Make sure the header starts with Zero
  1496.     LD    (RCDCNT),A
  1497.  
  1498. ;
  1499. ; Wait for 'C' from remote to indicate he is ready
  1500. ;
  1501. CCHECK:    LD    E,60        ; Wait up to 60 seconds to abort
  1502.  
  1503. CCHECK1:CALL    CKABORT        ; Manually requesting an abort?
  1504.     LD    B,3
  1505.     CALL    RECV        ; Wait up to 5 seconds for a character
  1506.     JR    C,CCHECK2    ; No character, decrement counter
  1507.     CP    CANCEL        ; If they sent a CTL-X, abort now
  1508.     CALL    Z,CKCAN
  1509.     CP    CRC        ; If they sent a CRC, go to work
  1510.     JR    Z,SZMD8
  1511.     JR    CCHECK        ; None of these, wait some more
  1512.  
  1513. CCHECK2:DEC    E        ; One less to go
  1514.     JR    NZ,CCHECK1
  1515.     JP    ACKMSG        ; Abort if timed out and no character
  1516.  
  1517. SZMD8:    LD    A,(FILCNT)    ; Any files to send?
  1518.     OR    A
  1519.     JR    NZ,SZMD9    ; Yes, continue
  1520.     XOR    A        ; Reset the pointers
  1521.     LD    (ACKCHK),A    ; Reset flag for normal GTACK use
  1522.     LD    (RCDCNT),A    ; Reset the record counter
  1523.     LD    (KFLG),A    ; Show in 128 size now
  1524.     LD    HL,(RECPTR)
  1525.     LD    (HL),A        ; Reset record pointer
  1526.     LD    A,SOH        ; Send a start of header
  1527.     CALL    SEND
  1528.     CALL    SNDHNM        ; This header is a zero count
  1529.     CALL    SNDREC        ; Send an empty record
  1530.     CALL    SNDCRC        ; Send the CRC for the empty record
  1531.     LD    A,(GOTONE)    ; Did we actually send at least one?
  1532.     OR    A
  1533.     JP    Z,ABORT        ; If not, don't act like we did
  1534.     CALL    EOFSND        ; No more files so send EOT to finish
  1535.     CALL    XFRDON
  1536.     JP    EXIT
  1537.  
  1538. ;
  1539. ; Now send the 128 byte filename record
  1540. ;
  1541. SZMD9:    DEC    A        ; Decrement file count for this one
  1542.     LD    (FILCNT),A    ; Store it
  1543.  
  1544. SZMD10:    XOR    A
  1545.     LD    (KFLG),A
  1546.     LD    A,SOH        ; Send SOH
  1547.     LD    (ACKCHK),A
  1548.     CALL    SEND        ; Send SOH character to the modem
  1549.     CALL    SNDHNM        ; Send header (record number, inverse)
  1550.     CALL    SNDREC        ; Send a 128 byte record
  1551.     CALL    SNDCRC        ; Send a two byte CRC
  1552.     CALL    GTACK
  1553.     CP    ACK
  1554.     JR    NZ,SZMD10    ; Not an ACK, send it again
  1555.     XOR    A
  1556.     LD    (ACKCHK),A    ; Reset flag for normal GTACK use
  1557.     CALL    LOW41K        ; Check speed being used
  1558.     JR    C,$+7        ; Don't allow 1k blocks if less than MINKSPD
  1559.     LD    A,1
  1560.     LD    (KFLG),A    ; Change to 1k for normal file xfer
  1561.     XOR    A        ; Clear A
  1562.     LD    (ERRCNT),A    ; Start fresh for the main file
  1563.     JP    SNDFL1
  1564.  
  1565. ;
  1566. ; Send EOT.  Get Acknowledgement from remote.  Try up to 4 times then abort.
  1567. ;
  1568. EOFSND:    LD    A,EOT        ; Send an 'EOT'
  1569.     CALL    SEND
  1570.     LD    A,(CHKEOT)    ; Did not get an ACK, try again
  1571.     INC    A
  1572.     LD    (CHKEOT),A    ; Limit number of retries to 4
  1573.     CP    4        ;    (to prevent possible 'lock-up')
  1574.     RET    NC        ; Quit if already sent 4 or more
  1575.     CALL    GTACK        ; Get the ACK
  1576.     CP    ACK
  1577.     JR    NZ,EOFSND    ; Resend if no ACK
  1578.     RET
  1579.  
  1580. ALLDON:    LD    A,(BATCH)    ; In batch mode?
  1581.     OR    A
  1582.     RET    NZ        ; If yes, ignore message
  1583.     CALL    ILPRT        ; (Want to keep this a separate message)
  1584.     DB    CR,LF,0
  1585.  
  1586. XFRDON:    CALL    ILPRTL
  1587.     DB    CR,LF
  1588.     DB    '-- Transfer completed'
  1589.     DB    CR,LF,0
  1590.     RET
  1591.  
  1592. ;
  1593. ;-------------------------------------------------------------------------;
  1594. ; ---->  RCVFL  -  R e c e i v e   f i l e ( s )              |
  1595. ;-------------------------------------------------------------------------;
  1596. ;
  1597. ; The filename specified in ZMD command line is transferred over the phone
  1598. ; from the user's computer to the RCPM system via modem using the 'R'
  1599. ; (receive) option.  The data is sent one record at a time, with headers
  1600. ; and checksums and retransmissions on errors.  'RM' option is disallowed
  1601. ; at time of command tail parsing at beginning of program (MSGFLG cannot
  1602. ; be set unless MSGFIL is enabled).
  1603. ;
  1604. RCVFL:    LD    A,(MSGFLG)    ; Get message file upload flag
  1605.     OR    A        ; Enabled?
  1606.     JR    Z,RCVF2        ; No, skip the rest
  1607.     CALL    WHLCHK        ; Yes, WHEEL byte set?
  1608.     JR    NZ,RCVF1    ; Yes, turn it off and skip access check
  1609.  
  1610.     LD    A,(ACCESS)    ; Checking access restrictions?
  1611.     OR    A
  1612.     JR    Z,RCVF3        ; No
  1613.     LD    A,(AFBYTE)    ; Get access flags byte
  1614.     AND    8        ; Test for write access (bit 3)
  1615.     JP    Z,NOACC        ; Not allowed to write messages
  1616.  
  1617. RCVF1:    XOR    A        ; Clear A
  1618.     LD    HL,(WHEEL)    ; Point to WHEEL byte
  1619.     LD    (HL),A        ; And stuff a 0 to turn WHEEL off
  1620.     JR    RCVF3        ; WHEEL 'was' on, so skip access check
  1621.  
  1622. ;
  1623. ; Check additional receive flags
  1624. ;
  1625. RCVF2:    LD    A,(ACCESS)    ; Checking access restrictions?
  1626.     OR    A
  1627.     JR    Z,RCVF3        ; No
  1628.     CALL    WHLCHK        ; SYSOP online?
  1629.     JR    NZ,RCVF3    ; Yep, skip all this checking
  1630.     LD    A,(PUPFLG)    ; Privileged transfer option request?
  1631.     OR    A
  1632.     LD    A,(AFBYTE)    ; Get access flags byte
  1633.     JR    Z,$+7        ; No
  1634.     AND    80H        ; Test for privileged user access (bit 7)
  1635.     JP    Z,NOACC        ; Not allowed to use "RW" option
  1636.     AND    40H        ; Test for upload access (bit 6)
  1637.     JP    Z,NOACC        ; Not allowed to upload files
  1638.  
  1639. ;
  1640. ; User has the access he asked for
  1641. ;
  1642. RCVF3:    LD    A,(BATCH)    ; Requesting batch mode?
  1643.     OR    A
  1644.     JP    NZ,RBTCH    ; Yes, go do batch stuff first
  1645.     CALL    RCVFL1        ; Find drive/user/filetype permitted
  1646.     LD    IX,FCB
  1647.     CALL    RESTRCT        ; Check restrictions on uploads
  1648.     CALL    CONTIN        ; Display drive/user area
  1649.     CALL    MAKEFIL        ; Open the file, ready to receive
  1650.  
  1651. ;
  1652. ; Receive records until EOT
  1653. ;
  1654. RCVLP:    XOR    A
  1655.     LD    (ERRCNT),A    ; Initialize error count to zero
  1656.     CALL    RCVRECD        ; Receive a record
  1657.     JR    NC,RCVLP1    ; If not EOT, store this record and get next
  1658.     LD    HL,(RECDNO)    ; Get number of records
  1659.     LD    A,H
  1660.     OR    L        ; 0 length file?
  1661.     JP    Z,ABORT        ; Yes, abort and erase file
  1662.     LD    A,(EOTFLG)    ; This the first EOT character?
  1663.     OR    A
  1664.     JP    NZ,RCVEOT    ; No, exit
  1665.     LD    A,NAK
  1666.     LD    (EOTFLG),A    ; Set the flag
  1667.     CALL    SEND        ; Send a NAK
  1668.     JR    RCVLP        ; Go wait another EOT
  1669.  
  1670. ;
  1671. ; Increment record number
  1672. ;
  1673. RCVLP1:    CALL    INCRNO        ; Bump record number, if received ok
  1674.     LD    HL,(RECPTR)    ; Get buffer address
  1675.     LD    DE,128        ; 128 chars/record
  1676.     LD    A,(KFLG)    ; Using 1k blocks?
  1677.     OR    A
  1678.     JR    Z,$+5        ; If not, skip next line
  1679.     LD    DE,1024        ; 1k/record
  1680.     ADD    HL,DE        ; To next buffer
  1681.     LD    (RECPTR),HL    ; Save buffer address
  1682.     LD    A,(KFLG)    ; Using 1k blocks?
  1683.     OR    A
  1684.     LD    A,(RECNBF)    ; Get number of records in buffer
  1685.     JR    Z,$+6        ; If not, skip next 2 lines
  1686.     ADD    A,8        ; Increment it 8 records for 1k
  1687.     JR    $+3        ; Skip next line
  1688.     INC    A        ; Else only 1 record
  1689.     LD    (RECNBF),A    ; Store new record count
  1690.  
  1691. ;
  1692. ; If 16k in buffer, write to disk
  1693. ;
  1694.     LD    C,A        ; Put the record count in C
  1695.     LD    A,(BUFSIZ)    ; Buffer size in A
  1696.     ADD    A,A
  1697.     ADD    A,A
  1698.     ADD    A,A
  1699.     CP    C        ; Is the buffer full, yet?
  1700.     CALL    Z,WRBLOCK    ; No, return
  1701.     CALL    SNDACK        ; Ack the record
  1702.     JP    RCVLP        ; Loop until 'EOF'
  1703.  
  1704. ;
  1705. ; End of transmission received
  1706. ;
  1707. RCVEOT:    CALL    SNDACK        ; ACK the record
  1708.     CALL    WRBLOCK
  1709.     JP    RCVEOT0
  1710.  
  1711. WRBLOCK:LD    A,(RECNBF)    ; Number of records in the buffer
  1712.     OR    A        ; 0 means end of file
  1713.     RET    Z        ; None to write
  1714.     LD    C,A        ; Save count
  1715.     LD    DE,DBUF        ; Point to disk buff
  1716.  
  1717. WRBLOK1:PUSH    HL
  1718.     PUSH    DE
  1719.     PUSH    BC
  1720.     CALL    STDMA        ; Set DMA
  1721.     LD    DE,FCB        ; Then write the block
  1722.     LD    C,WRITE
  1723.     CALL    BDOS
  1724.     POP    BC
  1725.     POP    DE
  1726.     POP    HL
  1727.     OR    A        ; Write error?
  1728.     JR    Z,WRBLOK2    ; No
  1729.     CALL    RSDMA        ; Reset DMA to normal
  1730.     LD    A,CANCEL    ; Cancel
  1731.     CALL    SEND        ; Sender
  1732.     CALL    SEND
  1733.     CALL    SEND
  1734.     CALL    CLOSFIL        ; Kill received file
  1735.     CALL    ILPRTB        ; Exit with msg:
  1736.     DB    CR,LF
  1737.     DB    '-- Write Error: ',0
  1738.     CALL    SHONM3
  1739.     JP    EXIT
  1740.  
  1741. WRBLOK2:LD    HL,128        ; Length of 1 record
  1742.     ADD    HL,DE        ; 'HL'= next buff
  1743.     EX    DE,HL        ; To 'DE' for setdma
  1744.     DEC    C        ; More records?
  1745.     JR    NZ,WRBLOK1    ; Yes, loop
  1746.     XOR    A        ; Get a zero
  1747.     LD    (RECNBF),A    ; Reset number of records
  1748.     LD    HL,DBUF        ; Reset buffer
  1749.     LD    (RECPTR),HL    ; Save buffer address
  1750.     JP    RSDMA
  1751.  
  1752. ;
  1753. ; Write record to log file if LOGCAL is YES
  1754. ;
  1755. RCVEOT0:CALL    CLOSFIL        ; Close the file
  1756.     LD    HL,(RECDNO)    ; Get # of records
  1757.     LD    (RCNT),HL    ; Stuff in RCNT
  1758.     CALL    XTIM        ; Calculate approximate transfer time
  1759.     CALL    STORTM        ; Store time
  1760.     CALL    LOGCALL        ; Log transfer if supposed to
  1761.  
  1762. RCVEOT1:LD    A,(LOGLDS)    ; Counting uploads?
  1763.     OR    A
  1764.     JR    Z,RCVEOT2    ; No
  1765.     LD    A,(PRIVATE)    ; Private upload?
  1766.     OR    A
  1767.     JR    NZ,RCVEOT2    ; Yes, no credit for private uploads
  1768.     LD    IY,(UPLDS)    ; Get Upload Counter
  1769.     INC    (IY)        ; One more upload since log in
  1770.  
  1771. RCVEOT2:CALL    ALLDON        ; If not in BATCH, print transfer complete
  1772.     JP    CRED        ; Credit upload time and ask for descriptions
  1773.  
  1774. ;
  1775. ;-------------------------------------------------------------------------;
  1776. ; R e c e i v e   B a t c h                          |
  1777. ;-------------------------------------------------------------------------;
  1778. ;
  1779. RBTCH:    XOR    A        ; Using batch so reset some flags
  1780.     LD    (FRSTIM),A    ; Needs to be reset for each new file
  1781.     LD    A,(FSTFLG)    ; First batch file?
  1782.     OR    A
  1783.     JR    Z,RBTCH0    ; Yes, give them time to setup
  1784.     LD    A,CRC
  1785.     CALL    SEND        ; In case he's quick like us
  1786.     JP    RBTCH1
  1787.  
  1788. ;
  1789. ; Initial setup only
  1790. ;
  1791. RBTCH0:    CALL    RCVFL1        ; Find drive/user/filetype permitted
  1792.     CALL    CONTIN        ; Display drive/user area
  1793.     LD    HL,NAMBUF
  1794.     LD    (NBSAVE),HL
  1795.     LD    A,1
  1796.     LD    (FSTFLG),A    ; No need to run those routines again
  1797.  
  1798. ;
  1799. ; Get the batch file name and display
  1800. ;
  1801. RBTCH1:    LD    HL,FCB
  1802.     CALL    INITFCB        ; Initialize FCB
  1803.     XOR    A
  1804.     LD    (RCVTRY),A
  1805.     INC    A        ; Set to local display only
  1806.     LD    (CONONL),A
  1807.  
  1808. RBTCH2:    CALL    CKABORT        ; Check for user abort
  1809.     LD    B,5
  1810.     CALL    RECV        ; Wait up to 5 seconds for SOH from remote
  1811.     JR    C,RBTCH3    ; No character, decrement counter
  1812.     CP    CANCEL        ; Was it a CTL-X for cancel?
  1813.     CALL    Z,CKCAN        ; Check for abort
  1814.     CP    SOH
  1815.     JR    Z,RBTCH5    ; Got SOH
  1816.     JR    RBTCH2        ; None of these, wait some more
  1817.  
  1818. RBTCH3:    LD    A,CRC        ; Send a 'C'
  1819.     CALL    SEND
  1820.  
  1821. RBTCH4:    LD    A,(RCVTRY)
  1822.     INC    A
  1823.     LD    (RCVTRY),A
  1824.     CP    20
  1825.     JR    C,RBTCH2
  1826.     JP    ABORT        ; Quit and try to force him to quit also
  1827.  
  1828. RBTCH5:    LD    B,5
  1829.     CALL    RECV        ; Wait up to 5 seconds for sector number
  1830.     JP    C,TOTERR
  1831.     LD    D,A        ; Save sector number in D
  1832.     OR    A        ; Must be a 0 if sending batch
  1833.     JP    NZ,WRGHDR
  1834.     LD    B,5
  1835.     CALL    RECV        ; Wait up to 5 seconds for reciprocal
  1836.     JP    C,TOTERR
  1837.     CPL            ; Invert it and compare to sector #
  1838.     CP    D
  1839.     JP    NZ,CRCERR    ; Bad match
  1840.     LD    HL,0
  1841.     LD    (CRCVAL),HL    ; Clear CRC counter
  1842.     LD    E,128        ; Expecting a 128 character block
  1843.     LD    HL,(RECPTR)    ; Point to the buffer address
  1844.  
  1845. RBTCH6:    LD    B,5
  1846.     CALL    RECV        ; Up to 5 seconds for 128 byte header block
  1847.     JP    C,TOTERR    ; Exit if no character
  1848.     LD    (HL),A        ; Store the character
  1849.     INC    HL        ; Point to next buffer location
  1850.     DEC    E        ; One less to go
  1851.     JR    NZ,RBTCH6 
  1852.     LD    E,2        ; Number of CRC bytes to get
  1853.  
  1854. RBTCH7:    LD    B,5
  1855.     CALL    RECV        ; Up to 5 seconds for CRC bytes
  1856.     JP    C,TOTERR
  1857.     DEC    E        ; Done?
  1858.     JR    NZ,RBTCH7    ; No
  1859.     CALL    CRCCHK        ; Compare CRC received against ours
  1860.     OR    A        ; Ok?
  1861.     JP    NZ,CRCERR    ; No
  1862.     CALL    SNDACK        ; Yes, acknowledge to remote
  1863.  
  1864. ;
  1865. ; Decode pathname into CPM format
  1866. ;
  1867.     LD    DE,FCB+1    ; Where to put it
  1868.     LD    HL,(RECPTR)    ; Where to get it
  1869.     LD    B,8        ; Filename length
  1870.  
  1871. RBTCH8:    LD    A,(HL)        ; Get the character from the buffer
  1872.     OR    A        ; Was it a zero?
  1873.     JR    Z,RBTCH12    ; If yes, all done
  1874.     CP    '.'        ; Was it a delimiter?
  1875.     JR    Z,RBTCH9
  1876.     CALL    UCASE        ; Insure name is in upper case
  1877.     CP    '_'        ; Is it an underline?
  1878.     JR    NZ,$+4        ; No
  1879.     LD    A,'-'        ; Else make it a dash
  1880.     LD    (DE),A        ; Store filename character in FCB
  1881.     INC    DE        ; Increment pointers
  1882.     INC    HL
  1883.     DJNZ    RBTCH8        ; If not 8, keep going
  1884.     LD    A,(HL)        ; Get the character back
  1885.     OR    A        ; We had 8, was there an extent?
  1886.     JR    Z,RBTCH11    ; If zero, was all done
  1887.     JR    RBTCH10        ; Else must be a '.'
  1888.  
  1889. RBTCH9:    LD    A,' '        ; Spaces to make up 8 spaces for name
  1890.     LD    (DE),A        ; Store space character in FCB
  1891.     INC    DE        ; Increment pointers
  1892.     DJNZ    RBTCH9        ; Keep going until in extent area
  1893.  
  1894. RBTCH10:INC    HL        ; Skip the '.' position
  1895.     LD    B,3        ; Extent length
  1896.  
  1897. RBTCH11:LD    A,(HL)        ; Get the character from the buffer
  1898.     OR    A        ; Was it a zero?
  1899.     JR    Z,RBTCH12    ; If yes, all done
  1900.     CALL    UCASE        ; Insure extent is in upper case
  1901.     LD    (DE),A        ; Store extent character
  1902.     INC    DE        ; Increment pointers
  1903.     INC    HL
  1904.     DJNZ    RBTCH11        ; Keep going until finished
  1905.  
  1906. RBTCH12:LD    A,(FCB+1)    ; See if there was any filename at all
  1907.     CP    ' '
  1908.     JP    Z,RBCHDON    ; No, all done, no more files
  1909.     CALL    CLEARIT        ; Clear screen locally if suppose to
  1910.  
  1911. RBTCH13:LD    HL,(BUFSTR)    ; Get the file length, if provided
  1912.     LD    A,H
  1913.     OR    L
  1914.     JR    NZ,$+7        ; If not both zero, length is provided 
  1915.     CALL    SHONM        ; Else show the filename
  1916.     JR    RBTCH14        ; And wait to receive
  1917.     LD    (RCNT),HL    ; Store the file length
  1918.     CALL    OPNOK1        ; Show filename and file sizes
  1919.     CALL    ILPRTL
  1920.     DB    CR,LF
  1921.     DB    'Ymodem transfer time     > ',0
  1922.     CALL    GETSPD        ; Get speed indicator
  1923.     CP    5        ; Are we less than 1200 bps?
  1924.     JR    C,$+7        ; Yes, skip 1k time
  1925.     CALL    KTIM        ; Get 1k transfer time
  1926.     JR    $+5        ; Skip 128 byte transfer time
  1927.     CALL    XTIM        ; Get 128 byte transfer time
  1928.     CALL    XFRTIM        ; Display transfer time
  1929.  
  1930. RBTCH14:CALL    ILPRTL
  1931.     DB    CR,LF,LF,0    ; Finish the filename line
  1932.     XOR    A        ; Reset the carry flag
  1933.     LD    (RCVTRY),A    ; Reset the error counter
  1934.     LD    IX,FCB
  1935.     CALL    RESTRCT        ; Check restrictions on uploads
  1936.     CALL    CHEKFIL        ; Already have a file with that name?
  1937.     CALL    MAKEFIL        ; If not, make it
  1938.     CALL    BCHINR
  1939.     CALL    WAITMSG        ; Display '[ waiting ]' message locally
  1940.     LD    A,CRC
  1941.     CALL    SEND
  1942.     JP    RCVLP        ; Start receiving the file
  1943.  
  1944. RBCHDON:XOR    A        ; Zero the batch mode flag
  1945.     LD    (BATCH),A
  1946.     LD    A,(GOTONE)    ; Were there any files received?
  1947.     OR    A
  1948.     JP    Z,ABORT        ; No, abort
  1949.     CALL    XFRDON        ; Show transmission is finished
  1950.     JP    CRED        ; Ask for descriptions
  1951.  
  1952. CRCERR:    CALL    ILPRTL
  1953.     DB    '-- CRC error'
  1954.     DB    CR,LF,0
  1955.     JP    INCERR
  1956.  
  1957. WRGHDR:    CALL    ILPRTL
  1958.     DB    '-- Wrong header type'
  1959.     DB    CR,LF,0
  1960.     JR    INCERR
  1961.  
  1962. TOTERR:    CALL    ILPRTL
  1963.     DB    '-- Timeout receiving filename'
  1964.     DB    CR,LF,0
  1965.  
  1966. INCERR:    CALL    WAIT1        ; Make sure sender has stopped
  1967.     LD    A,NAK        ; Tell sender it was not successful
  1968.     CALL    SEND
  1969.     LD    A,(RCVTRY)    ; Increment the error counter
  1970.     INC    A
  1971.     LD    (RCVTRY),A
  1972.     CP    33
  1973.     JP    C,RBTCH4    ; Send a NAK and tell him to try again
  1974.     JP    ABORT        ; Else abort
  1975.  
  1976. ;
  1977. ;-------------------------------------------------------------------------;
  1978. ; C r e d i t   R o u t i n e s                          |
  1979. ;-------------------------------------------------------------------------;
  1980. ;
  1981. ; The following credits the caller for the amount of time spent uploading
  1982. ; any non-private files with descriptions.
  1983. ;
  1984. CRED:    LD    A,(BATCH)
  1985.     OR    A
  1986.     JR    NZ,CRED0A
  1987.     LD    E,10        ; Set up for a 30 second wait
  1988.  
  1989. CRED0:    LD    B,3        ; 3 seconds to receive a character
  1990.     CALL    RECV
  1991.     JR    NC,CRED0A    ; Got one, continue
  1992.     CALL    ILPRTB        ; Make sure this goes to modem
  1993.     DB    CR
  1994.     DB    '-- Hit a key'
  1995.     DB    CR,0        ; Let them know we're waiting
  1996.     DEC    E        ; 2 less seconds
  1997.     JR    NZ,CRED0    ; Wait until 0
  1998.  
  1999. CRED0A:    LD    A,(CREDIT)    ; Credit caller with upload time?
  2000.     OR    A
  2001.     JP    Z,CRED2        ; No
  2002.     CALL    WHLCHK        ; WHEEL byte set?
  2003.     JP    NZ,CRED2    ; Yes, skip credit
  2004.     LD    A,(PUPFLG)    ; Privileged transfer request?
  2005.     OR    A
  2006.     JP    NZ,CRED2    ; Yes, skip credit
  2007.     LD    A,(PRIVATE)    ; Was this a private file?
  2008.     OR    A
  2009.     JP    NZ,CRED2    ; Yes, skip credit
  2010.     LD    A,(BATCH)    ; In batch mode now?
  2011.     OR    A
  2012.     JP    NZ,CRED1    ; If yes, skip following messages
  2013.  
  2014.     CALL    ILPRTB        ; Show to remote also
  2015.     DB    CR,LF
  2016.     DB    'Thanks for the ',0
  2017.     CALL    SHOCAT        ; Show upload area descriptor, if supposed to
  2018.     CALL    ILPRTB
  2019.     DB    'upload(s)!',CR,LF,0
  2020.     CALL    ILPRTB
  2021.     DB    'Upload time has been credited to time left.',0
  2022.  
  2023. CRED1:    LD    A,(MAXTOS)    ; Get maximum time allowed
  2024.     OR    A        ; Unlimited?
  2025.     JR    Z,CRED2        ; Yes, skip credit
  2026.     LD    HL,(RECDNO)    ; Else get the number of records
  2027.     LD    (RCNT),HL 
  2028.     CALL    XTIM        ; Get transfer time in C
  2029.     LD    A,(MAXTOS)    ; Get maximum time allowed back
  2030.     INC    A        ; Increment to next full minute
  2031.     ADD    A,C        ; Add upload time
  2032.     LD    (MAXTOS),A    ; Save for internal use
  2033.  
  2034. ;
  2035. ; If not still in BATCH mode, ask for file description
  2036. ;
  2037. CRED2:    LD    A,(BATCH)    ; Still in batch?
  2038.     OR    A
  2039.     JP    NZ,DONE        ; Yes, see if anymore files left
  2040.     LD    A,(HIDEIT)    ; Did we make this upload a $SYS file?
  2041.     OR    A
  2042.     JR    Z,CRED3        ; No, skip all this
  2043.     CALL    WHLCHK        ; Wheel byte set?
  2044.     JR    NZ,CRED3    ; Yes, file not set to $SYS
  2045.     LD    A,(PRIVATE)    ; Was this a private upload?
  2046.     OR    A
  2047.     JR    NZ,CRED3    ; Yes, file not set to $SYS
  2048.     CALL    ILPRTB
  2049.     DB    CR,LF
  2050.     DB    'Uploads remain hidden until cleared by Sysop.',0
  2051.  
  2052. CRED3:    CALL    ILPRTB
  2053.     DB    CR,LF,LF,0
  2054.     CALL    RSTLCK        ; Clear WRTLOC before descriptions
  2055.     CALL    ADDTON        ; Update BYE's time on byte if supposed to
  2056.  
  2057. ;
  2058. ;-------------------------------------------------------------------------;
  2059. ; D e s c r i p t i o n   R o u t i n e s                  |
  2060. ;-------------------------------------------------------------------------;
  2061.  
  2062. ASK:    LD    A,(PRIVATE)    ; Private upload?
  2063.     OR    A
  2064.     JP    NZ,EXIT        ; Yes, no descriptions
  2065.     LD    A,(PUPFLG)    ; Privileged transfer request?
  2066.     OR    A
  2067.     JP    NZ,EXIT        ; Yes, no descriptions
  2068.     LD    A,(DESCRIB)    ; Requiring descriptions?
  2069.     OR    A
  2070.     JR    NZ,ASK1        ; Yes
  2071.  
  2072.     LD    A,(MSGDESC)    ; To BBS message base?
  2073.     OR    A
  2074.     JP    Z,EXIT        ; No
  2075.     LD    (DSCFLG),A    ; Set flag to show message base descriptions
  2076.     LD    A,(PRUSR)    ; Get the private user
  2077.     LD    (USER),A    ; FOR destination
  2078.     LD    A,(PRDRV)    ; Get the private drive
  2079.     LD    (DRIVE),A    ; FOR destination
  2080.  
  2081. ASK1:    CALL    GETTIME
  2082.     LD    HL,DATMSG+6
  2083.  
  2084.     LD    A,(EDATE)    ; European date format?
  2085.     OR    A
  2086.     JR    Z,ASK1A        ; No
  2087.     LD    A,(DAY)
  2088.     CALL    DATDEC        ; Print DD
  2089.     INC    HL
  2090.     LD    A,(MONTH)    ; Print MM
  2091.     JR    ASK1B        ; And finish with YY
  2092.  
  2093. ASK1A:    LD    A,(MONTH)
  2094.     CALL    DATDEC        ; Print MM
  2095.     INC    HL
  2096.     LD    A,(DAY)
  2097.  
  2098. ASK1B:    CALL    DATDEC        ; Print DD
  2099.     INC    HL
  2100.     LD    A,(YEAR)
  2101.     CALL    DATDEC        ; Print YY
  2102.  
  2103.     LD    A,(FILCNT)    ; Any batch filenames?
  2104.     OR    A
  2105.     JR    Z,ASK3        ; No
  2106.     LD    HL,NAMBUF    ; Point to name buffer
  2107.     LD    (NBSAVE),HL
  2108.  
  2109. ASK2:    LD    IY,FILCNT    ; One less file to describe
  2110.     DEC    (IY)
  2111.     LD    HL,(NBSAVE)    ; Get address of next batch filename
  2112.     LD    DE,FCB        ; Where to put it
  2113.     LD    BC,12
  2114.     LDIR
  2115.     LD    (NBSAVE),HL    ; Store address for next filename
  2116.  
  2117. ASK3:    LD    A,(DESCRIB)    ; FOR file descriptions?
  2118.     OR    A
  2119.     JR    Z,ASK6        ; No
  2120.  
  2121.     LD    A,(ASKAREA)    ; Using upload routing?
  2122.     OR    A
  2123.     JR    Z,ASK4        ; No, KIND contents doesn't matter
  2124.  
  2125.     LD    A,(KIND)    ; Do we have a the upload area yet?
  2126.     OR    A
  2127.     JR    NZ,ASK6        ; Yes, don't ask them twice
  2128.  
  2129.     CALL    ILPRTB
  2130.     DB    CR,LF,LF
  2131.     DB    'Upload category: '
  2132.     DB    CR,LF,0
  2133.     JR    ASK5
  2134.  
  2135. ASK4:    LD    A,(ASKIND)    ; Need file descriptors for FOR entries?
  2136.     OR    A
  2137.     JR    Z,ASK6        ; No
  2138.  
  2139.     CALL    ILPRTB
  2140.     DB    CR,LF,LF,0
  2141.     CALL    SHONM3        ; Show the file name
  2142.  
  2143.     CALL    ILPRTB
  2144.     DB    ' - this file is for:'
  2145.     DB    CR,LF,0
  2146.  
  2147. ASK5:    CALL    GETKIND        ; Get file category for description header
  2148.     CALL    TYPE        ; Output to both consoles
  2149.  
  2150. ASK6:    CALL    ILPRTB
  2151.     DB    CR
  2152.     DB    'Describe ',0
  2153.     CALL    SHONM3        ; Show the filename
  2154.     CALL    ILPRTB
  2155.     DB    ' - 7 lines or less - ^W disables WRAP - CR when done',0
  2156.  
  2157.     LD    HL,FCB+1    ; FCB contains current filename
  2158.     LD    DE,NEWNAM    ; Needed in here for description routines
  2159.     LD    B,8        ; Filename is up to 8 bytes long
  2160.     CALL    ASK7        ; Go store it until a space
  2161.  
  2162.     LD    A,'.'
  2163.     LD    (DE),A        ; Add seperator
  2164.  
  2165.     INC    DE
  2166.     LD    HL,FCB+9    ; Point to file extent at FCB
  2167.     LD    B,3        ; File extent is up to 3 bytes long
  2168.     CALL    ASK7        ; Go store until space or B=3
  2169.  
  2170.     LD    A,LF        ; Stuff Terminator
  2171.     LD    (DE),A
  2172.  
  2173.     CALL    GETDSC        ; Show typing guide and get upload description
  2174.     JP    Z,ASK2        ; If we got a description, get next
  2175.     JP    ASK3        ; Else get this one over again
  2176.  
  2177. ;
  2178. ; Small subroutine to store the filename located at FCB+1 into buffer area
  2179. ; located at DE
  2180. ;
  2181. ASK7:    LD    A,(HL)        ; Get character
  2182.     AND    7FH        ; Done with high bits
  2183.     CP    ' '        ; A space?
  2184.     RET    Z        ; Yes, all done
  2185.     LD    (DE),A        ; Else store it in destination
  2186.     INC    HL        ; Increment source pointer
  2187.     INC    DE        ; Increment destination
  2188.     DJNZ    ASK7        ; Keep looping until B=0 or (HL)=' '
  2189.     RET
  2190.  
  2191. ;
  2192. ;-----------------------
  2193. ; Set upload drive/user
  2194. ;
  2195. RCVFL1:    CALL    LOGDU        ; Select drive/user for upload
  2196.     LD    A,(PUPFLG)    ; Place "RW" file as needed
  2197.     OR    A        ; Can only be set if user is privileged
  2198.     JR    NZ,RCVFL2    ; Privileged, else check if sysop...
  2199.     CALL    WHLCHK        ; Let WHEEL user put file wherever he wants
  2200.     JR    Z,RCVFL6    ; If WHEEL byte not set, stay normal
  2201.  
  2202. RCVFL2:    LD    A,(RCVDRV)
  2203.     OR    A
  2204.     JR    Z,RCVFL3
  2205.     SUB    'A'        ; Convert ASCII drive to binary
  2206.     JR    RCVFL4
  2207.  
  2208. RCVFL3:    LD    A,(OLDDRV)
  2209.  
  2210. RCVFL4:    INC    A
  2211.     LD    (FCB),A
  2212.     ADD    A,'A'-1        ; Convert binary to ASCII
  2213.     LD    (DRV),A        ; Drive
  2214.     LD    A,(RCVDRV)    ; See if a drive was requested
  2215.     OR    A
  2216.     LD    A,(OLDUSR)    ; Current user
  2217.     JR    Z,RCVFL5    ; If not, use current user
  2218.     LD    A,(RCVUSR)    ; Else get requested user
  2219.  
  2220. RCVFL5:    LD    (USR),A        ; User
  2221.     RET
  2222.  
  2223. RCVFL6:    LD    A,(SETAREA)
  2224.     OR    A
  2225.     JR    NZ,RCVFL7
  2226.     LD    A,(ASKAREA)
  2227.     OR    A
  2228.     JR    Z,RCVFL8
  2229.  
  2230. RCVFL7:    LD    A,(DRV)
  2231.     SUB    40H
  2232.     LD    (FCB),A
  2233.  
  2234. RCVFL8:    LD    A,(PRIVATE)    ; Receiving to a private area?
  2235.     OR    A
  2236.     RET    Z        ; If not, exit
  2237.     LD    A,(PRDRV)    ; Private area takes precedence
  2238.     SUB    40H        ; Convert to binary
  2239.     LD    (FCB),A        ; Store drive to be used
  2240.     RET
  2241.  
  2242. ;
  2243. ; Display where file(s) will go, open file and display name
  2244. ;
  2245. CONTIN:    LD    A,(ASKAREA)    ; Upload routing enabled?
  2246.     OR    A
  2247.     JR    NZ,CONT0    ; No
  2248.     LD    A,(ASKIND)
  2249.     OR    A
  2250.     JR    Z,CONT1
  2251.  
  2252. CONT0:    CALL    WHLCHK        ; Is WHEEL byte set?
  2253.     JR    NZ,CONT1    ; No, skip this
  2254.     CALL    GETKIND        ; Get upload area
  2255.     LD    A,CR        ; So the line feed (LF) doesn't get printed
  2256.     LD    (CONT1+4),A
  2257.  
  2258. CONT1:    CALL    ILPRTB
  2259.     DB    CR,LF
  2260.     DB    'Receiving on:  Drive ',0
  2261.     LD    A,(PRIVATE)    ; Private upload?
  2262.     OR    A
  2263.     LD    A,(PRUSR)    ; Get private user area
  2264.     LD    B,A        ; Put in B for now
  2265.     LD    A,(PRDRV)    ; Get private drive
  2266.     JR    NZ,CONT2+3    ; Yes, priority 1
  2267.     LD    A,(USR)        ; Get the regular user area
  2268.     LD    B,A        ; And put it in B
  2269.     LD    A,(PUPFLG)    ; Privileged upload?
  2270.     OR    A
  2271.     JR    NZ,CONT2    ; Yes, priority 2
  2272.     CALL    WHLCHK        ; WHEEL set?
  2273.     JR    NZ,CONT2    ; Yes, priority 3
  2274.     LD    A,(SETAREA)    ; Uploading to designated drive/user?
  2275.     OR    A
  2276.     JR    NZ,CONT2    ; Yes, priority 4
  2277.     LD    A,(ASKAREA)    ; Upload routing enabled?
  2278.     OR    A
  2279.     JR    Z,CONT3        ; No
  2280.  
  2281. CONT2:    LD    A,(DRV)        ; Get regular upload drive
  2282.     PUSH    AF        ; Save ASCII upload drive
  2283.     SUB    40H        ; Convert drive to binary
  2284.     LD    (FCB),A        ; Store it in File Control Block
  2285.     POP    AF        ; Get ASCII drive back
  2286.     JR    CONT4        ; All done, now display it
  2287.  
  2288. CONT3:    LD    A,(OLDUSR)    ; Get current user area for default
  2289.     LD    B,A        ; Save in B
  2290.     DB    0,0        ; Contains 'LD B,n' (DUU) from GETDU
  2291.     LD    A,(OLDDRV)    ; Get current drive for default
  2292.     ADD    A,'A'        ; Convert to ASCII
  2293.     DB    0,0        ; Contains 'LD A,n' (DUD) from GETDU
  2294.  
  2295. CONT4:    LD    (KDRV),A    ; Save it for KSHOW
  2296.     CALL    TYPE        ; Print the drive to store on
  2297.     CALL    ILPRTB
  2298.     DB    ', User ',0
  2299.     LD    A,B        ; B contains the user area
  2300.     LD    (USR),A        ; Save for MSGDESC upload info
  2301.     LD    H,0
  2302.     LD    L,A        ; Binary user area in L
  2303.     CALL    DECOUT        ; Decimal output
  2304.     CALL    ILPRTB
  2305.     DB    '.  (',0
  2306.     CALL    KSHOW        ; Show available space remaining
  2307.     CALL    ILPRTB
  2308.     DB    ')',0
  2309.     CALL    CHEKFIL        ; See if file exists
  2310.  
  2311.     LD    A,(DESCRIB)    ; Descriptions enabled?
  2312.     OR    A
  2313.     JR    NZ,CONT5    ; Yes
  2314.     LD    A,(MSGDESC)    ; Message base descriptions?
  2315.     OR    A
  2316.     JR    Z,CONT6        ; No
  2317.  
  2318. CONT5:    LD    A,(PRIVATE)    ; Private upload?
  2319.     OR    A
  2320.     JR    NZ,CONT6    ; Yes, no descriptions
  2321.     LD    A,(PUPFLG)    ; Privileged upload?
  2322.     OR    A
  2323.     JR    NZ,CONT6    ; Yes, no descriptions
  2324.     CALL    ILPRTB
  2325.     DB    CR,LF
  2326.     DB    'Description(s) needed - ',0
  2327.     JR    CONT7
  2328.  
  2329. CONT6:    CALL    ILPRTB
  2330.     DB    CR,LF,0
  2331.  
  2332. CONT7:    CALL    ILPRTB
  2333.     DB    'Abort: ^X pause ^X'
  2334.     DB    CR,LF,LF,0
  2335.     CALL    WAITMSG
  2336.     RET
  2337.  
  2338. ;
  2339. ; Increment the file count
  2340. ;
  2341. BCHINR:    LD    HL,(NBSAVE)    ; Where to put the name
  2342.     LD    DE,FCB        ; Where to get the name
  2343.     EX    DE,HL
  2344.     LD    BC,12        ; Move current filename to buffer for ASK:
  2345.     LDIR
  2346.     EX    DE,HL
  2347.     LD    (NBSAVE),HL    ; Store address for next filename
  2348.     LD    A,(FILCNT)    ; Increment the file count
  2349.     INC    A
  2350.     LD    (FILCNT),A
  2351.     RET
  2352.  
  2353. ;
  2354. ;-------------------------------------------------------------------------;
  2355. ; T r a n s f e r   c o m p l e t e                      |
  2356. ;-------------------------------------------------------------------------;
  2357. ;
  2358. ; Done transferring current file.  Check to see if in BATCH mode and if so,
  2359. ; display filename transferred and reset flags for next possible file.
  2360. ; Otherwise eat garbage from line, reset WRTLOC, do timekeeping and exit
  2361. ; to CP/M (Forward text file to BBS message base if supposed to).
  2362. ;
  2363. DONE:    LD    A,(BATCH)    ; Still in batch mode?
  2364.     OR    A
  2365.     JP    Z,EXIT        ; No.  All done
  2366.     LD    A,(OLDDRV)    ; Restore the original drive
  2367.     CALL    RECDRX
  2368.     LD    A,(OLDUSR)    ; Restore the original number
  2369.     CALL    RECAR1
  2370.     CALL    RSDMA        ; Reset to default DMA address
  2371.     LD    A,1        ; Display filename locally only
  2372.     LD    (GOTONE),A    ; Indicates there was a file handled
  2373.     CALL    ILPRTL        ; Display the file name
  2374.     DB    CR,LF,0
  2375.     CALL    SHONM3        ; Show the filename at FCB+1
  2376.     CALL    ILPRT
  2377.     DB    ' transferred',CR,LF,0
  2378.  
  2379. ;
  2380. ; Now reset some flags for another possible batch file
  2381. ;
  2382.     XOR    A
  2383.     LD    (EOFLG),A    ; Clear end of file flag
  2384.     LD    (EOTFLG),A    ; And end of transmission flag
  2385.     LD    (CHKEOT),A    ; Clear the "resend EOT" flag
  2386.     LD    HL,0
  2387.     LD    (ACCERR),HL    ; Reset the accumulate error count
  2388.     LD    (RECNBF),HL    ; Zero number of records in the buffer
  2389.     LD    (RECDNO),HL    ; Zero the current record number
  2390.     LD    (RCDCNT),HL    ; Zero the transmit record counter
  2391.     LD    HL,DBUF        ; Reset buffer pointers
  2392.     LD    (RECPTR),HL
  2393.     LD    A,(MODE)    ; Get transfer mode
  2394.     CP    'S'        ; Sending files?
  2395.     JP    Z,SNDFIL    ; Yes
  2396.  
  2397.     LD    A,(FILIMT)    ; Maximum upload (TPA limitation)
  2398.     LD    B,A        ; Into B for comparison
  2399.     LD    A,(FILCNT)    ; Get current count received
  2400.     CP    B        ; Received BATCH transfer limit yet?
  2401.     JP    C,RCVFL
  2402.     LD    A,CANCEL
  2403.     CALL    SEND
  2404.     CALL    SEND
  2405.     CALL    SEND
  2406.     CALL    WAIT1
  2407.  
  2408.     CALL    ILPRTB
  2409.     DB    CR,LF
  2410.     DB    '-- ',0
  2411.     LD    A,(FILIMT)
  2412.     LD    H,0
  2413.     LD    L,A
  2414.     CALL    DECOUT
  2415.     CALL    ILPRTB
  2416.     DB    ' file limit in BATCH receive',CR,LF,0
  2417.  
  2418.     XOR    A
  2419.     LD    (BATCH),A    ; Reset the batch mode flag to zero
  2420.     JP    CRED3        ; Go back and ask for descriptions
  2421.  
  2422. ;
  2423. ;-------------------------------------------------------------------------;
  2424. ; C o m m o n  S u b r o u t i n e s                      |
  2425. ;-------------------------------------------------------------------------;
  2426. ;
  2427. ; Universal access check routine checks restrictions of current file being
  2428. ; considered for transfer.
  2429. ;
  2430. ; On entry:  IX  = start address of byte before filename
  2431. ; On exit:    Z  = File ok to send/receive
  2432. ;         NZ     = Transfer denied
  2433. ;
  2434. ; Each bit of this word contains an image of the high bit within the filename
  2435. ; pointed to by IX+1 on entry.
  2436. ; 
  2437. HBITMAP:DW    0000000000000000B
  2438.  
  2439. ;
  2440. ; First, make a bit map containing an image of the high bits in the filename
  2441. ; pointed to by IX+1 on entry.
  2442. ;
  2443. RESTRCT:LD    B,11        ; Number of bytes to map
  2444.     LD    HL,0        ; Initialize destination for bit map
  2445.     PUSH    IX        ; Save current filename address
  2446.     INC    IX        ; Skip past drive indicator
  2447.  
  2448. ACCMASK:LD    A,(IX)        ; Get next character of filename
  2449.     AND    80H        ; Isolate attribute bit
  2450.     RLCA            ; Move MS bit into LS bit
  2451.     OR    L        ; OR in any previously set bits
  2452.     LD    L,A        ; Save result
  2453.     ADD    HL,HL        ; Shift HL left one bit for next time
  2454.     INC    IX        ; IY+1 equals next character in filename-type
  2455.     DJNZ    ACCMASK        ; Loop through all 11 bytes
  2456.     POP    IX        ; Get our original filename pointer back
  2457.  
  2458. ;
  2459. ; Most significant bit will already be in bit 11 of HL, so only 4 shifts are
  2460. ; necessary
  2461. ;
  2462.     ADD    HL,HL        ; 000?????$??????00
  2463.     ADD    HL,HL        ; 00??????$?????000
  2464.     ADD    HL,HL        ; 0???????$????0000
  2465.     ADD    HL,HL        ; ????????$???00000
  2466.     LD    (HBITMAP),HL    ; Store filename high bit image
  2467.  
  2468. ;
  2469. ; See which (if any) restrictions we need to enforce
  2470. ;
  2471.     CALL    WHLCHK        ; WHEEL byte set?
  2472.     JP    NZ,SENDOK    ; Yes, transfer is approved
  2473.     LD    A,(ACCMAP)    ; Get user defined restriction flags
  2474.     LD    B,A
  2475.     LD    A,(MODE)    ; Get the file transfer mode
  2476.     CP    'S'        ; Sending?
  2477.     JR    Z,RSTRCT2    ; Yes, check send restrictions
  2478.  
  2479. ;
  2480. ; Check RECEIVE restrictions
  2481. ;
  2482.     LD    IX,FCB
  2483.     BIT    NOCOMR,B    ; Rename '.COM' uploads to '.OBJ'?
  2484.     JR    Z,RSTRCT1    ; No, check for ZCPR restrictions
  2485.     LD    DE,COMCHG    ; Compare to 'COM'
  2486.     CALL    MCHFTYP        ; Are they the same?
  2487.     CALL    Z,RENTYP    ; Yes, rename it to 'OBJ'
  2488.  
  2489. RSTRCT1:BIT    ZCPR,B        ; Using with ZCPR?
  2490.     RET    Z        ; No, all done
  2491.     LD    DE,SYSCHK    ; Compare to 'SYS'
  2492.     CALL    MCHFTYP        ; Are they the same?
  2493.     JR    Z,FTYPERR    ; Yes, tell them to use a different filetype
  2494.     LD    DE,NDRCHK    ; Compare to 'NDR'
  2495.     CALL    MCHFTYP        ; ...
  2496.     JR    Z,FTYPERR    ; ...
  2497.     LD    DE,RCPCHK    ; Compare to 'RCP'
  2498.     CALL    MCHFTYP        ; ...
  2499.     RET    NZ        ; If no match, filetype is ok to receive
  2500.  
  2501. FTYPERR:CALL    ERXIT
  2502.     DB    CR,LF
  2503.     DB    '-- Use a different file extent','$'
  2504.  
  2505. ;
  2506. ; Check SEND restrictions
  2507. ;
  2508. RSTRCT2:LD    A,(BATCH)    ; In BATCH?
  2509.     OR    A
  2510.     JR    NZ,RSTRT2A    ; Yes, require send access for any batch file
  2511.     BIT    DWNTAG,B    ; Allow F3 tagged file regardless of access?
  2512.     JR    Z,RSTRT2A    ; No, skip this
  2513.     BIT    5,H        ; Byte 3 of filename set?
  2514.     JP    NZ,SENDOK    ; Yes, send it immediately
  2515.  
  2516. RSTRT2A:LD    A,(ACCESS)
  2517.     OR    A
  2518.     JR    Z,RSTRCT3
  2519.     LD    A,(AFBYTE)    ; Get BYE or BBS bit mapped access flag
  2520.     AND    20H        ; Download access allowed?
  2521.     JP    Z,NOACC        ; No, inform user of restricted function
  2522.  
  2523. RSTRCT3:LD    A,(LBRARC)    ; Get member extraction flag
  2524.     OR    A        ; Enabled?
  2525.     JR    NZ,RSTRCT4    ; Yes, skip these restrictions
  2526.     BIT    TAGFIL,B    ; Restricting tagged files?
  2527.     JR    Z,RSTRCT4    ; No
  2528.     BIT    7,H        ; First byte of filename set?
  2529.     JR    NZ,NOSEND    ; Yes, can't send it
  2530.  
  2531. RSTRCT4:BIT    NOSYS,B        ; Restricting $SYS files?
  2532.     JR    Z,RSTRCT5    ; No
  2533.     BIT    6,L        ; First byte of filetype set?
  2534.     JR    NZ,NOSEND    ; Yes, can't send
  2535.  
  2536. RSTRCT5:LD    A,(LBRARC)    ; Get member extraction flag
  2537.     OR    A        ; Enabled?
  2538.     RET    NZ        ; Yes, and file was not tagged (returning NZ)
  2539.     BIT    NOLBS,B        ; Restricting files with labels (#)?
  2540.     JR    Z,RSTRCT6    ; No
  2541.     LD    A,(IX+11)    ; Get possible label
  2542.     AND    7FH        ; Strip the high bit
  2543.     CP    '#'        ; Labeled?
  2544.     JR    Z,NOSEND    ; Yes, can't send
  2545.  
  2546. RSTRCT6:BIT    NOCOMS,B    ; Allow sending 'COM' files?
  2547.     JP    Z,SENDOK    ; Yes
  2548.     LD    DE,COMCHG    ; Point to string to compare with
  2549.     CALL    MCHFTYP        ; Is it a .COM file?
  2550.     JP    NZ,SENDOK    ; No
  2551.  
  2552. ;
  2553. ; Common exit point
  2554. ; 
  2555. COMTRY:    LD    A,(BATCH)    ; In batch mode?
  2556.     OR    A
  2557.     JP    NZ,NOSND2    ; Yes, just set flag to not include (NZ)
  2558.     POP    HL        ; Remove call from OPNOK from stack
  2559.     CALL    ERXIT
  2560.     DB    CR,LF
  2561.     DB    '-- Can''t send .COM files','$'
  2562.  
  2563. NOSEND:    LD    A,(BATCH)    ; Are we in batch mode?
  2564.     OR    A
  2565.     JP    NZ,NOSND2    ; Yes, no error messages, just checking
  2566.     LD    DE,LBRNAM
  2567.     CALL    NOSND0
  2568.     JR    Z,NOSND1
  2569.     LD    DE,ARKNAM
  2570.     CALL    NOSND0
  2571.     JR    Z,NOSND1
  2572.     LD    DE,ARCNAM
  2573.     CALL    NOSND0
  2574.     JR    Z,NOSND1
  2575.     CALL    ERXIT
  2576.     DB    CR,LF
  2577.     DB    '-- File is not for distribution','$'
  2578.  
  2579. NOSND0:    LD    B,3
  2580.     LD    HL,FCB+9
  2581.     CALL    MATCH
  2582.     RET
  2583.  
  2584. NOSND1:    CALL    ERXIT
  2585.     DB    CR,LF
  2586.     DB    '-- Individual members only','$'
  2587.  
  2588. NOSND2:    LD    A,1        ; Return NZ if file not allowed
  2589.     OR    A
  2590.     RET
  2591.  
  2592. SENDOK:    XOR    A        ; Return Z if file is ok
  2593.     RET
  2594.  
  2595. ;
  2596. ; See if next character is ' ' or non ' '.  File name error if no ASCII
  2597. ; character.
  2598. ;
  2599. CHKFSP:    LD    A,(BATCH)    ; Requesting batch mode now?
  2600.     OR    A
  2601.     JR    Z,CHKFSP2    ; Exit if not
  2602.     LD    A,(MODE)    ; Sending batch?
  2603.     CP    'S'
  2604.     JR    Z,CHKFSP2    ; If yes, exit
  2605.     DEC    B
  2606.     JR    Z,CHKFSP1
  2607.     INC    B
  2608.     JR    CHKFSP2
  2609.  
  2610. CHKFSP1:POP    HL        ; Do not return to LOGDU
  2611.     RET            ; Return instead to SNDFIL
  2612.  
  2613. CHKFSP2:DEC    B
  2614.     JP    Z,NFN1        ; Error if end of chars.
  2615.     LD    A,(HL)
  2616.     CP    ' '+1
  2617.     RET    NC        ; Ok if valid character so return
  2618.     INC    HL
  2619.     JR    CHKFSP
  2620.  
  2621. ;
  2622. ; Check next character to see if a space or non-space, go to menu if a command
  2623. ; error.
  2624. ;
  2625. CHKSP:    LD    A,(BATCH)    ; Requesting batch mode?
  2626.     OR    A
  2627.     JR    Z,CHKSP2    ; Exit if not
  2628.     LD    A,(MODE)    ; Sending in batch mode now?
  2629.     CP    'S'
  2630.     JR    Z,CHKSP2    ; If yes, exit
  2631.     DEC    B
  2632.     JR    Z,CHKSP1
  2633.     INC    B
  2634.     JR    CHKSP2
  2635.  
  2636. CHKSP1:    POP    HL        ; Don't return to LOGDU
  2637.     RET            ; Return to SNDFIL
  2638.  
  2639. CHKSP2:    DEC    B
  2640.     JP    Z,HELP
  2641.     INC    HL
  2642.     LD    A,(HL)        ; Get the character there
  2643.     CP    ' '        ; Space character?
  2644.     RET            ; Z = space, NZ = non-space
  2645.  
  2646. ;
  2647. ; Determine the amount of disk storage needed for the current file.  On
  2648. ; entry:  BC = total record count of file
  2649. ;
  2650. ROUNDK:    LD    DE,(BLKSIZ)    ; Fetch block size in kilobytes
  2651.     PUSH    DE        ; Save block size
  2652.     PUSH    BC        ; Save file record count
  2653.     LD    B,3        ; Make a mask for size limit
  2654.  
  2655. MSKCMP:    OR    A        ; Clear carry
  2656.     RL    E        ; Make mask for size limit
  2657.     RL    D        ; Shift until
  2658.     DJNZ    MSKCMP        ; Shift until DE is A
  2659.     DEC    DE        ; Mask of records per block
  2660.     POP    BC        ; Get a copy of file record count
  2661.     PUSH    BC
  2662.  
  2663.     LD    A,C        ; Mask file size with block size mask
  2664.     AND    E
  2665.     LD    C,A
  2666.     LD    A,B
  2667.     AND    D
  2668.     OR    C        ; Zero result indicates no block
  2669.     POP    BC
  2670.     PUSH    AF        ; Remainder in file size
  2671.     LD    A,D        ; Compliment mask and zero file size
  2672.     CPL            ; Remainder in BC
  2673.     AND    B
  2674.     LD    B,A
  2675.     LD    A,E
  2676.     CPL
  2677.     AND    C
  2678.     LD    C,A
  2679.     LD    E,3        ; Shift count to divide masked file
  2680.  
  2681. MINKL:    OR    A        ; Clear carry
  2682.     RR    B        ; Rotate high byte through carry
  2683.     RR    C
  2684.     DEC    E        ; Decrement shift count
  2685.     JR    NZ,MINKL
  2686.  
  2687.     POP    AF        ; Check if even block size
  2688.     POP    DE        ; Get back block size
  2689.     PUSH    HL        ; Save kilobyte insert address
  2690.     LD    HL,0        ; Initial zero of remainderI
  2691.     JR    Z,MINKS        ; Zero if even
  2692.     EX    DE,HL        ; Block size to HL if remainder
  2693.  
  2694. MINKS:    ADD    HL,BC        ; Add in total kilobyte count
  2695.     EX    DE,HL        ; Total size to DE
  2696.     POP    HL        ; Get back load address
  2697.     RET
  2698.  
  2699. ;
  2700. ; Log into drive and user
  2701. ;
  2702. ; (If specified).  If none mentioned, falls through to 'TRAP' routine for
  2703. ; normal use.
  2704. ;
  2705. LOGDU:    LD    HL,TBUF        ; Point to default buffer command line
  2706.     LD    B,(HL)        ; Store number of characters in command
  2707.     INC    B        ; Add in current location
  2708.     CALL    CHKSP        ; Skip spaces to find 1st command
  2709.     JR    Z,$-3        ; Loop until non-space character
  2710.     CALL    CHKSP        ; Skip 1st command (non-spaces)
  2711.     JR    NZ,$-3        ; Loop until a space
  2712.     INC    HL
  2713.     CALL    CHKFSP        ; Skip spaces to find 2nd command
  2714.     LD    (SAVEHL),HL    ; Save start address of the 2nd command
  2715.  
  2716. ;
  2717. ; Now pointing to the first byte in the argument.  (If it was of a format
  2718. ; similar to: 'B6:HELLO.DOC' then we point at the drive character 'B'.  Then
  2719. ; transfer up to 4 bytes from the command line buffer (pointed at by HL) to
  2720. ; the drive/user storage buffer pointed at by DE
  2721. ;
  2722. LGDU1:    PUSH    HL        ; Save command line position
  2723.     PUSH    BC        ; And character count
  2724.     LD    DE,DUSAVE    ; Destination buffer
  2725.     LD    C,4        ; Drive/user is 4 characters maximum 'B15:'
  2726.  
  2727. LGDU2:    LD    A,(HL)        ; Get character
  2728.     CP    ' '+1        ; Space or return?
  2729.     JP    C,TRAP        ; Yes, all done
  2730.     LD    (DE),A        ; Else store it in DUSAVE
  2731.     INC    HL        ; Increment to next argument
  2732.     INC    DE        ; Increment DUSAVE
  2733.     CP    ':'        ; Was it a colon?
  2734.     JR    Z,LGDU3        ; Yes, was drive/user requested
  2735.     DEC    B        ; One less position to check
  2736.     DEC    C        ; One less to go
  2737.     JR    NZ,LGDU2    ; Loop until a colon or C=0
  2738.     JP    TRAP        ; Move name to FCB
  2739.  
  2740. ;
  2741. ; Get Disk and User from DUSAVE and log in if valid.
  2742. ;
  2743. LGDU3:    EXX            ; Save HL (buffer) pointer and BC (char count)
  2744.     POP    BC        ; We don't need these back, but fix the stack
  2745.     POP    HL
  2746.     EXX            ; And get HL and BC back to continue
  2747.     LD    A,(BATCH)    ; Requesting batch mode?
  2748.     OR    A
  2749.     JR    Z,LGDU4        ; No
  2750.     LD    A,(MODE)    ; Get program transfer mode
  2751.     CP    'R'        ; Receiving batch?
  2752.     JR    Z,LGDU5        ; Yes, skip next two lines
  2753.  
  2754. LGDU4:    CALL    CHKFSP        ; See if a file name is included
  2755.     LD    (SAVEHL),HL    ; Save location of the filename
  2756.  
  2757. LGDU5:    LD    A,(PRIVATE)    ; Uploading to a private area?
  2758.     OR    A
  2759.     JP    NZ,TRAP2    ; If yes, going to a specified area
  2760.  
  2761.     LD    A,(OLDDRV)    ; Get current drive
  2762.     LD    (DUD),A
  2763.     ADD    A,'A'
  2764.     LD    (RCVDRV),A
  2765.  
  2766.     LD    HL,DUSAVE    ; Point to drive/user
  2767.     LD    A,(HL)        ; Get 1st character
  2768.     CP    '0'        ; It is a ' ', CR or LF?
  2769.     JR    C,LGDU6        ; Yes, skip next 2 lines
  2770.     CP    '9'+1        ; Is it an ASCII number 0-9?
  2771.     JR    C,LGDU10
  2772.  
  2773. LGDU6:    LD    (RCVDRV),A    ; Allows SYSOP to upload to any drive
  2774.     CP    'A'-1
  2775.     JR    C,LGDU9        ; Satisfied with current drive
  2776.     SUB    'A'
  2777.     LD    (DUD),A
  2778.  
  2779.     LD    A,(PUPFLG)    ; Privileged user upload request?
  2780.     OR    A
  2781.     LD    A,(DUD)
  2782.     JR    NZ,LGDU8    ; Yes
  2783.  
  2784.     CALL    WHLCHK
  2785.     LD    A,(DUD)
  2786.     JR    NZ,LGDU8
  2787.  
  2788.     LD    A,(USEMAX)    ; Using ZCPR low memory bytes?
  2789.     OR    A
  2790.     JR    NZ,LGDU7    ; Yes
  2791.     LD    A,(MAXDRV)
  2792.     LD    C,A
  2793.     LD    A,(DUD)
  2794.     CP    C
  2795.     JP    NC,ILLDU    ; Drive selection not available
  2796.     JR    LGDU8
  2797.  
  2798. LGDU7:    LD    A,(DUD)        ; Get the drive back
  2799.     LD    IY,(DRIVMAX)    ; Point to max drive byte
  2800.     INC    (IY)
  2801.     CP    (IY)        ; And check it
  2802.     PUSH    AF        ; Save flags from the CP
  2803.     DEC    (IY)        ; Restore max drive to normal
  2804.     POP    AF        ; Restore flags from the CP
  2805.     JP    NC,ILLDU
  2806.  
  2807. LGDU8:    INC    HL        ; Get 2nd character
  2808.  
  2809. LGDU9:    LD    A,(HL)
  2810.     CP    ':'
  2811.     JP    Z,LGDU17    ; Colon for drive only, no user number
  2812.     CALL    CKNUM        ; Check if numeric
  2813.  
  2814. LGDU10:    SUB    '0'        ; Convert ASCII to binary
  2815.     LD    (DUU),A        ; Save it
  2816.     INC    HL        ; Get 3rd character if any
  2817.     LD    A,(HL)
  2818.     CP    ':'
  2819.     JR    Z,LGDU11
  2820.     LD    A,(DUU)
  2821.     CP    1        ; Is first number a '1'?
  2822.     JP    NZ,ILLDU
  2823.     LD    A,(HL)
  2824.     CALL    CKNUM
  2825.     SUB    38
  2826.     LD    (DUU),A
  2827.     INC    HL        ; Get 4th (and last character) if any
  2828.     LD    A,(HL)
  2829.     CP    ':'
  2830.     JP    NZ,ILLDU
  2831.  
  2832. LGDU11:    LD    A,(MODE)
  2833.     CP    'R'        ; Receiving a file?
  2834.     LD    A,(DUU)
  2835.     JR    Z,LGDU12
  2836.     LD    A,(SPLDRV)
  2837.     SUB    'A'
  2838.     LD    C,A
  2839.     LD    A,(DUD)
  2840.     CP    C
  2841.     JR    NZ,LGDU12
  2842.     LD    A,(SPLUSR)
  2843.     LD    C,A
  2844.     LD    A,(DUU)
  2845.     CP    C
  2846.     JR    Z,LGDU15
  2847.  
  2848. LGDU12:    CALL    WHLCHK        ; SYSOP using the system?
  2849.     JR    Z,LGDU13
  2850.     LD    A,(DUU)        ; Restore desired user area
  2851.     LD    (RCVUSR),A    ; Allows SYSOP to upload anywhere
  2852.     JR    NZ,LGDU15    ; If yes, let him have all user areas
  2853.  
  2854. LGDU13:    LD    A,(USEMAX)    ; Using ZCPR low memory bytes?
  2855.     OR    A
  2856.     JR    NZ,LGDU14    ; Yes
  2857.     LD    A,(MAXUSR)    ; Check for maximum user download area
  2858.     ADD    A,1
  2859.     LD    C,A
  2860.     LD    A,(DUU)
  2861.     CP    C
  2862.     JP    NC,ILLDU    ; Error if more (and not special area)
  2863.     JR    LGDU15
  2864.  
  2865. LGDU14:    LD    A,(DUU)
  2866.     LD    IY,(USRMAX)    ; Point at maximum user byte
  2867.     CP    (IY)        ; And check it
  2868.     JP    NC,ILLDU
  2869.  
  2870. LGDU15:    LD    E,A
  2871.     LD    A,(SETAREA)    ; Using designated drv/usr for reg. uploads?
  2872.     OR    A
  2873.     JR    NZ,LGDU16    ; Yes
  2874.     LD    A,(ASKAREA)    ; Using upload routing?
  2875.     OR    A
  2876.     JR    NZ,LGDU16    ; Yes
  2877.     LD    A,E
  2878.     LD    (CONT3+5),A    ; Store requested user area
  2879.     LD    A,6        ; 'LD B,n' instruction
  2880.     LD    (CONT3+4),A
  2881.  
  2882. LGDU16:    LD    C,SETUSR    ; Set to requested user area
  2883.     CALL    BDOS
  2884.  
  2885. LGDU17:    LD    A,(DUD)        ; Get drive
  2886.     LD    E,A
  2887.     LD    A,(SETAREA)    ; Using designated drv/usr for reg. uploads?
  2888.     OR    A
  2889.     JR    NZ,LGDU18    ; Yes
  2890.     LD    A,(ASKAREA)    ; Using upload routing?
  2891.     OR    A
  2892.     JR    NZ,LGDU18    ; Yes
  2893.     LD    A,E
  2894.     ADD    A,'A'
  2895.     LD    (CONT3+12),A    ; Store requested drive
  2896.     LD    A,3EH        ; 'LD A,n' instruction
  2897.     LD    (CONT3+11),A
  2898.  
  2899. LGDU18:    LD    C,SELDSK    ; Set to requested drive
  2900.     CALL    BDOS
  2901.     JR    TRAP2        ; Now find file selected
  2902.  
  2903. ;
  2904. ; If we get here, no d/u was specified.  Restore original command line pointer
  2905. ; and character count and move name to FCB.
  2906. ;
  2907. TRAP:    POP    BC        ; Get original character count back
  2908.     POP    HL        ; And original command line buffer position
  2909.  
  2910. ;
  2911. ; Check for no file name or ambiguous name
  2912. ;
  2913. TRAP1:    LD    A,(PRIVATE)    ; Get the private transfer flag
  2914.     OR    A        ; Is it enabled?
  2915.     JR    Z,TRAP2        ; No, current du stays normal
  2916.     LD    A,(SPLUSR)    ; Get the special download user area
  2917.     CALL    RECAR1        ; Set user area to special download user
  2918.     LD    A,(SPLDRV)    ; Get the special download drive
  2919.     CALL    RECDR1        ; Set drive to special download drive
  2920.  
  2921. TRAP2:    CALL    SPCDRV        ; Keep DPB info straight
  2922.     LD    HL,FCB
  2923.     CALL    INITFCB        ; Make sure FCB initialized
  2924.     CALL    MOVFCB        ; Move the filename into the file block
  2925.     LD    HL,FCB+1    ; Point to file name
  2926.     LD    A,(HL)        ; Get first character
  2927.     CP    ' '        ; Any there?
  2928.     JR    NZ,TRAP3    ; Yes, check wildcards
  2929.     LD    HL,FCB+9    ; Else point to file extent
  2930.     LD    A,(HL)        ; Get character
  2931.     CP    ' '        ; Space also?
  2932.     JP    Z,NFN        ; Yes, we have no filename, exit with error
  2933.     LD    HL,FCB+1    ; Else point to start again
  2934.  
  2935. TRAP3:    LD    A,(PRIVATE)    ; Get the private transfer flag
  2936.     OR    A        ; Is it enabled?
  2937.     RET    Z        ; No, then don't trap wildcards
  2938.     LD    B,11        ; Else check all 11 characters of filename
  2939.  
  2940. TRAP4:    LD    A,(HL)        ; Get char from FCB
  2941.     CP    '?'        ; Ambiguous?
  2942.     JR    Z,NOWILD    ; Yes, exit with error message
  2943.     CP    '*'        ; Even more ambiguous?
  2944.     JR    Z,NOWILD    ; Yes, exit with error message
  2945.     INC    HL        ; Point to next character
  2946.     DJNZ    TRAP4        ; Not done, check some more
  2947.     RET
  2948.  
  2949. CKNUM:    CP    '0'
  2950.     JR    C,ILLDU        ; Error if less than ascii '0'
  2951.     CP    '9'+1
  2952.     RET    C        ; Error if more than ascii '9'
  2953.  
  2954. ILLDU:    CALL    ERXIT
  2955.     DB    CR,LF
  2956.     DB    '-- Unauthorized drive/user','$'
  2957.  
  2958. NFN:    CALL    ILPRT
  2959.     DB    CR,LF,0
  2960.  
  2961. NFN1:    CALL    ERXIT        ; Print message, exit
  2962.     DB    '-- No filename(s) requested','$'
  2963.  
  2964. NOWILD:    CALL    ERXIT        ; Print message, exit
  2965.     DB    CR,LF
  2966.     DB    '-- Wildcards not valid for PRIVATE downloads','$'
  2967.  
  2968. ;
  2969. ; Previous record repeated, due to the last ACK being garbaged.  ACK it so the
  2970. ; sender will catch up
  2971. ;
  2972. RCVACK:    CALL    SNDACK        ; Send the ACK
  2973.     XOR    A
  2974.     LD    (ERRCNT),A    ; Reset the error count
  2975.  
  2976. ;
  2977. ; Receive a record - returns with carry bit set if EOT received
  2978. ;
  2979. RCVRECD:CALL    FUNCHK        ; Check function keys
  2980.     CALL    SNDABT        ; See if wanting to abort
  2981.     LD    A,(FRSTIM)    ; Have we started, yet?
  2982.     OR    A
  2983.     LD    B,10        ; Check every ten seconds if already started
  2984.     JR    Z,$+4        ; If yes, skip next line
  2985.     LD    B,5        ; Check every 5 seconds until started
  2986.     CALL    RECV        ; Get character
  2987.     JP    C,RCVSTOT    ; Timeout error if no character received
  2988.     CP    SOH        ; SOH?
  2989.     JP    Z,RCVSOH    ; Yes, get record
  2990.     CP    STX        ; STX for 1k blocks?
  2991.     JR    NZ,$+11        ; No
  2992.     LD    (KFLG),A    ; Set the 1k flag
  2993.     LD    (CRCFLG),A    ; Insure in CRC mode for 1k blocks
  2994.     JP    RCVS1
  2995.  
  2996.     CP    CANCEL        ; Was it a CTL-X to abort?
  2997.     CALL    Z,CKCAN        ; If yes, check for aborting
  2998.     OR    A        ; Get another character, if a null
  2999.     JR    Z,RCVRECD
  3000.     CP    7BH        ; V.22 synch character, ignore
  3001.     JR    Z,RCVRECD
  3002.     CP    0FBH        ; V.22 synch character with high bit set
  3003.     JR    Z,RCVRECD
  3004.     CP    EOT        ; See if end of transmission
  3005.     SCF            ; Set carry
  3006.     RET    Z        ; Return with carry set
  3007.     CP    CRC        ; Ignore our own character coming back
  3008.     JR    Z,RCVRECD
  3009.     CP    KSND        ; Ignore our own character coming back
  3010.     JR    Z,RCVRECD
  3011.     CP    NAK        ; Ignore our own character coming back
  3012.     JR    Z,RCVRECD
  3013.     CALL    ILPRTL        ; Show locally only
  3014.     DB    CR,'-- ',0
  3015.     LD    A,B
  3016.     CALL    HEXO
  3017.     CALL    ILPRTL
  3018.     DB    'H received not SOH',CR,LF,0
  3019.     JR    RCVSR
  3020.  
  3021. ;
  3022. ; Checksum error
  3023. ;
  3024. CKSMERR:CALL    ILPRTL
  3025.     DB    ' - Checksum error',CR,LF,0
  3026.     JR    RCVSR        ; Go check the error limit and send NAK
  3027.  
  3028. ;
  3029. ; Bad record number in header error
  3030. ;
  3031. HDRERR:    CALL    ILPRTL
  3032.     DB    ' - Error in header',CR,LF,0
  3033.     JR    RCVSR        ; Go check error limit and send NAK
  3034.  
  3035. ;
  3036. ; Timed out on receive error
  3037. ;
  3038. RCVSTOT:LD    A,(FRSTIM)    ; First time flag set yet?
  3039.     OR    A
  3040.     JR    Z,RCVSR        ; If not, don't show an error
  3041.     CALL    TOTMSG
  3042.  
  3043. ;
  3044. ; Didn't get SOH or EOT or did not get valid header so purge the line,  then
  3045. ; send NAK.
  3046. ;
  3047. RCVSR:    CALL    WAIT1        ; Get anything coming in and discard
  3048.     CALL    SNDABT        ; See if wanting to abort
  3049.     LD    A,(FRSTIM)    ; Get first time switch
  3050.     OR    A        ; Has first 'SOH' been received?
  3051.     LD    A,NAK
  3052.     JR    NZ,RCVSR1    ; Yes, then send 'NAK'
  3053.     LD    A,(CRCFLG)    ; Get the 'CRC' flag
  3054.     OR    A        ; 'CRC' in effect?
  3055.     LD    A,NAK        ; Put 'NAK' in 'A' register
  3056.     JR    Z,RCVSR1    ; No, send the 'NAK' for checksum
  3057.     LD    A,CRC        ; Tell sender we have 'CRC'
  3058.     CALL    SEND
  3059.     LD    A,(KFLG)    ; Requesting 1k transmissions?
  3060.     OR    A
  3061.     JR    Z,RCVSR1    ; If not, exit
  3062.     LD    A,KSND        ; Tell sender we also have 1k capability
  3063.  
  3064. RCVSR1:    CALL    SEND        ; The 'NAK' or 'CRC' request
  3065.     LD    A,(ERRCNT)    ; Get the error count
  3066.     INC    A        ; Increment error count
  3067.     LD    (ERRCNT),A    ; Store new value
  3068.     LD    B,A        ; Keep the error count for now
  3069.     LD    A,(FRSTIM)    ; Have we gotten under way yet?
  3070.     OR    A
  3071.     LD    A,B        ; get the value back
  3072.     JR    Z,RCVSR2    ; If not, exit
  3073.     CP    10        ; 10 errors the limit, once under way
  3074.     JP    NC,ABORT    ; Abort if over the limit
  3075.     CALL    RDCOUNT        ; Display record count before repeating
  3076.     JP    RCVRECD        ; Less than 10, keep going
  3077.  
  3078. RCVSR2:    CP    7        ; 7 times for 1k/CRC yet? (40 seconds)
  3079.     JP    C,RCVRECD    ; Keep trying if less
  3080.     XOR    A        ; Else flip to checksum mode
  3081.     LD    (CRCFLG),A
  3082.     LD    A,B        ; Get the count back
  3083.     CP    3        ; Another 3 times for checksum?
  3084.     JP    C,RCVRECD    ; If less, try again, quit at 60 seconds
  3085.     JP    ABORT
  3086.  
  3087. ;
  3088. ; Aborts with 1 CTL-X if first time flag is not set, two otherwise
  3089. ;
  3090. CKCAN:    LD    A,(FRSTIM)    ; First time flag set yet?
  3091.     OR    A
  3092.     JR    Z,CKCAN1    ; If not, abort
  3093.     LD    B,2
  3094.     CALL    RECV        ; Maximum of 2 seconds for extra ^X
  3095.     RET    C        ; No additional character, ignore single ^X
  3096.     CP    CANCEL        ; Got a character, is it a ^X?
  3097.     RET    NZ        ; No, ignore 1st ^X and return
  3098.  
  3099. CKCAN1:    POP    HL        ; Reset stack for CALL    CKCAN
  3100.     JP    ABORT        ; Got 2nd ^X, abort and close file
  3101.  
  3102. ;
  3103. ; Got SOH - get block number (complemented)
  3104. ;
  3105. RCVSOH:    XOR    A
  3106.     LD    (KFLG),A    ; If SOH, clear the 1k flag
  3107.  
  3108. RCVS1:    LD    A,1        ; Get something to store
  3109.     LD    (FRSTIM),A    ; Indicate first 'SOH' or 'STX' recvd.
  3110.     LD    B,5
  3111.     CALL    RECV        ; Wait up to 5 seconds for block number
  3112.     JP    C,RCVSTOT    ; Got timeout
  3113.     LD    D,A        ; Save block number
  3114.     LD    B,5
  3115.     CALL    RECV        ; 5 seconds for complimented record number
  3116.     JP    C,RCVSTOT    ; Timeout
  3117.     CPL            ; Get the complement
  3118.     CP    D        ; Same as original block number?
  3119.     JP    NZ,HDRERR    ; No, go report bad record number in header
  3120.     LD    A,D        ; Get record number
  3121.     LD    (RCVCNT),A    ; Save it
  3122.     LD    C,0        ; Initialize checksum
  3123.     LD    HL,0        ; Initialize CRC
  3124.     LD    (CRCVAL),HL    ; Clear CRC counter
  3125.     LD    DE,128        ; For 128 character blocks
  3126.     LD    A,(KFLG)    ; Using 1k blocks?
  3127.     OR    A
  3128.     JR    Z,$+5        ; If not, skip next line
  3129.     LD    DE,1024        ; If using 1k blocks
  3130.     LD    HL,(RECPTR)    ; Get buffer address
  3131.  
  3132. RCVCHR:    LD    B,5
  3133.     CALL    RECV        ; 5 seconds for character
  3134.     JP    C,RCVSTOT    ; Timeout
  3135.     LD    (HL),A        ; Store the character
  3136.     INC    HL        ; Point to next character
  3137.     DEC    DE        ; One less to go
  3138.     LD    A,E        ; See if 'D' and 'E' are both empty
  3139.     OR    D
  3140.     JR    NZ,RCVCHR    ; No, get next character
  3141.     LD    A,(CRCFLG)    ; Using 'CRC'?
  3142.     OR    A
  3143.     JP    NZ,RCVCRC    ; If yes go get 'CRC'
  3144.  
  3145. ;
  3146. ; Verify checksum
  3147. ;
  3148.     LD    D,C        ; Save checksum
  3149.     LD    B,5
  3150.     CALL    RECV        ; Up to 5 seconds for checksum
  3151.     JP    C,RCVSTOT    ; Timeout
  3152.     CP    D        ; Checksum ok?
  3153.     JP    NZ,CKSMERR    ; No, report error
  3154.  
  3155. ;
  3156. ; Got a record, it's a duplicate if equal to the previous number, it's OK if
  3157. ; previous + 1 record
  3158. ;
  3159. CHKSNUM:LD    A,(RCVCNT)    ; Get received record number
  3160.     LD    B,A        ; Save it
  3161.     LD    A,(RCDCNT)    ; Get previous record number
  3162.     CP    B        ; Previous record repeated?
  3163.     JP    Z,RCVACK    ; If yes 'ACK' to catch up
  3164.     INC    A        ; Increment by 1 for 120 character block
  3165.     CP    B        ; Match this one we just got?
  3166.     JP    NZ,ABORT    ; No match, stop the sender, exit
  3167.     RET            ; Else return with carry not set, was ok
  3168.  
  3169. ;
  3170. ; Receive the Cyclic Redundancy Check characters (2 bytes) and see if the CRC
  3171. ; received matches the one calculated.    If they match,  get next record, else
  3172. ; send a NAK requesting the record be sent again.
  3173. ;
  3174. RCVCRC:    LD    E,2        ; Number of bytes to receive
  3175.  
  3176. RCVCRC2:LD    B,5
  3177.     CALL    RECV        ; Up to 5 seconds for CRC byte
  3178.     JP    C,RCVSTOT    ; Timeout
  3179.     DEC    E        ; Decrement the number of bytes
  3180.     JR    NZ,RCVCRC2    ; Get both bytes
  3181.     CALL    CRCCHK        ; Check received CRC against calc'd CRC
  3182.     OR    A        ; Is CRC okay?
  3183.     JR    Z,CHKSNUM    ; Yes, go check record numbers
  3184.     CALL    ILPRTL        ; Show locally only 
  3185.     DB    ' - CRC error',CR,LF,0
  3186.     JP    RCVSR        ; Go check error limit and send NAK
  3187.  
  3188. ;
  3189. ;------------------
  3190. ; Send subroutines
  3191. ;------------------
  3192. ;
  3193. ; Send an ACK for the record
  3194. ;
  3195. SNDACK:    LD    A,ACK        ; Get 'ACK'
  3196.     JP    SEND        ; And send it
  3197.  
  3198. ;
  3199. ; Send SOH, block number and complemented block number (3 bytes total)
  3200. ;
  3201. SNDHDR:    LD    A,(KFLG)    ; Sending 1k blocks?
  3202.     OR    A
  3203.     LD    A,STX        ; If yes, send a STX rather than SOH
  3204.     JR    NZ,$+4
  3205.     LD    A,SOH        ; Send start of header
  3206.     CALL    SEND
  3207.  
  3208. SNDHNM:    LD    A,(RCDCNT)    ; Send the current record number
  3209.     CALL    SEND
  3210.     LD    A,(RCDCNT)    ; Get the record number again
  3211.     CPL            ; Complemented
  3212.     JP    SEND        ; From SENDHDR
  3213.  
  3214. ;
  3215. ; Send data record
  3216. ;
  3217. SNDREC:    LD    C,0        ; Initialize checksum
  3218.     LD    HL,0        ; Initialize CRC
  3219.     LD    (CRCVAL),HL
  3220.     LD    A,(KFLG)    ; Sending 1k blocks?
  3221.     OR    A
  3222.     LD    DE,1024
  3223.     JR    NZ,$+5        ; If yes, skip the next line
  3224.     LD    DE,128
  3225.     LD    HL,(RECPTR)    ; Get buffer address
  3226.  
  3227. SENDC:    LD    A,(HL)        ; Get a character
  3228.     CALL    SEND        ; Send it
  3229.     INC    HL        ; Point to next character
  3230.     DEC    DE
  3231.     LD    A,E
  3232.     OR    D
  3233.     JR    NZ,SENDC    ; If DE not zero, keep going
  3234.     RET            ; From SENDREC
  3235.  
  3236. ;
  3237. ; Send the CRC or checksum value
  3238. ;
  3239. SNDCHK:    LD    A,(CRCFLG)    ; See if sending 'CRC' or 'checksum'
  3240.     OR    A
  3241.     JR    NZ,SNDCRC    ; If not zero, send the 'CRC' value
  3242.  
  3243. ;
  3244. ; Send Checksum
  3245. ;
  3246. SNDCKS:    LD    A,C        ; Send the checksum
  3247.     JP    SEND        ; From SNDCKS
  3248.  
  3249. ;
  3250. ; Send CRC (2 characters).  Call FINCRC to calculate the CRC which will be
  3251. ; in 'DE' upon return.
  3252. ;
  3253. SNDCRC:    CALL    FINCRC        ; Calculate the 'CRC' for this record
  3254.     LD    A,D        ; Put first 'CRC' byte in accumulator
  3255.     CALL    SEND        ; Send it
  3256.     LD    A,E        ; Put second 'CRC' byte in accumulator
  3257.     CALL    SEND        ; Send it
  3258.     XOR    A        ; Set zero return code
  3259.     RET
  3260.  
  3261. ;
  3262. ; Get acknowlegement
  3263. ;
  3264. ; After a record is sent, a character is returned telling if it was received
  3265. ; properly or not.  An ACK allows the next record to be sent.  A NAK causes
  3266. ; the current record to be resent.  If no character (or any character other
  3267. ; than ACK or NAK) is received after a short wait (10-12 seconds), a timeout
  3268. ; error message is shown and the record will be resent.
  3269. ;
  3270. GTACK:    LD    B,12
  3271.     CALL    RECV        ; Wait up to 12 seconds for ACK or NAK
  3272.     JR    NC,GTACK1    ; Got one
  3273.     CALL    TOTMSG
  3274.     JP    ACKERR        ; Set the carry bit and return
  3275.  
  3276. GTACK1:    CP    ACK        ; See if an ACK already
  3277.     RET    Z        ; If yes, return
  3278.     CP    NAK        ; See if a NAK
  3279.     JR    Z,GTACK2    ; If yes, print error, then resend
  3280.     CP    07BH        ; V.22 synch character?
  3281.     JR    Z,GTACK        ; If yes, ignore it
  3282.     CP    0FBH        ; V.22 synch character?
  3283.     JR    Z,GTACK        ; If yes, ignore it
  3284.     CP    CANCEL        ; CTL-X to cancel attempt?
  3285.     CALL    Z,CKCAN
  3286.  
  3287. GTACK2:    LD    B,A        ; Save the character
  3288.     LD    A,(CHKEOT)    ; Sending EOT?
  3289.     OR    A
  3290.     JP    NZ,ACKERR    ; If yes, don't show error (for ZMD)
  3291.     CALL    ILPRTL
  3292.     DB    ' - ',0
  3293.     LD    A,B
  3294.     CP    NAK
  3295.     JR    Z,GTACK3
  3296.     CALL    HEXO
  3297.     CALL    ILPRTL
  3298.     DB    'H',0
  3299.     JR    GTACK4
  3300.  
  3301. GTACK3:    CALL    ILPRTL
  3302.     DB    'NAK',0
  3303.  
  3304. GTACK4:    CALL    ILPRTL
  3305.     DB    ' received not ACK',CR,LF,0
  3306.     CALL    CATCH        ; None of them, establish clear line again
  3307.  
  3308. ;
  3309. ; Timeout or error on ACK - bump error count then resend the record if
  3310. ; error limit is not exceeded
  3311. ;
  3312. ACKERR:    LD    A,(ACCERR)    ; Count accumulated errors on ACK
  3313.     INC    A        ; Add in this error
  3314.     LD    (ACCERR),A
  3315.     LD    A,(ERRCNT)    ; Get count
  3316.     INC    A        ; Bump it
  3317.     LD    (ERRCNT),A    ; Save back
  3318.     CP    10        ; At limit?
  3319.     JR    NC,ACKMSG    ; If yes, send error message and abort
  3320.     LD    A,(ACKCHK)    ; Checking after a batch header?
  3321.     OR    A
  3322.     CALL    Z,RDCOUNT    ; Yes, show the record count for repeat
  3323.  
  3324.     LD    A,B        ; Get character back
  3325.     CP    NAK        ; NAK?
  3326.     JP    NZ,GTACK    ; No, ignore and wait for ACK or NAK
  3327.     RET            ; And go back
  3328.  
  3329. ;
  3330. ; Reached error limit
  3331. ;
  3332. ACKMSG:    CALL    WAIT1        ; Wait for any input to stop
  3333.     LD    A,CANCEL    ; Tell remote we are quitting
  3334.     CALL    SEND
  3335.     CALL    SEND
  3336.     CALL    SEND
  3337.     LD    B,2
  3338.     CALL    RECV        ; Up to 2 seconds for remote to quit too
  3339.     LD    A,BS
  3340.     CALL    SEND        ; Clear any CTL-X from buffer
  3341.     CALL    SEND
  3342.     CALL    SEND
  3343.     CALL    ERXIT
  3344.     DB    CR
  3345.     DB    '-- File transfer aborted','$'
  3346.  
  3347. ;
  3348. ; Routines to trap abort conditions
  3349. ;
  3350. ; Check to see if a cancel requested.  Fall through to ABORT if so.
  3351. ;
  3352. CKABORT:CALL    CONSTAT
  3353.     OR    A
  3354.     RET    Z
  3355.     CALL    CONIN
  3356.     CP    CANCEL
  3357.     RET    NZ
  3358.  
  3359. ;
  3360. ; Aborts send or receive routines and returns to command line
  3361. ;
  3362. ABORT:    CALL    WAIT1        ; 1- second delay to clear input
  3363.     CALL    CATCH
  3364.     LD    A,(EOTFLG)    ; Timed out after only 1 EOT?
  3365.     OR    A
  3366.     JP    NZ,RCVEOT+3    ; Accept as valid EOT then
  3367.     LD    A,CANCEL    ; Show you are cancelling
  3368.     CALL    SEND        ; They may quit also with enough CTL-X
  3369.     CALL    SEND
  3370.     CALL    SEND
  3371.     CALL    WAIT1        ; 1-second delay to clear input
  3372.     CALL    CATCH
  3373.     LD    A,BS
  3374.     CALL    SEND
  3375.     CALL    SEND
  3376.     CALL    SEND
  3377.  
  3378. ABORTX:    CALL    CATCH        ; Eat garbage characters
  3379.     CALL    ABRTMSG        ; Show we have aborted
  3380.     LD    A,(MODE)    ; Get file transfer mode
  3381.     CP    'R'        ; Sending a file?
  3382.     JP    NZ,EXIT        ; Yes, quit to CP/M
  3383.  
  3384. ;
  3385. ; Take care of received file (if any).
  3386. ;
  3387. CLOSFIL:LD    C,CLOSE        ; Get function
  3388.     LD    DE,FCB        ; Point to file
  3389.     CALL    BDOS        ; Close it
  3390.     INC    A        ; Close ok?
  3391.     JR    NZ,CLOSFL1    ; Yes
  3392.     CALL    ILPRT        ; No, abort
  3393.     DB    CR,LF
  3394.     DB    '-- Received file not closed',0
  3395.     JP    NTDEL1
  3396.  
  3397. CLOSFL1:LD    A,(EOTFLG)    ; Get end of transmission flag
  3398.     OR    A        ; Received entire file?
  3399.     RET    NZ        ; Yes, return to RCVEOT routines
  3400.     CALL    ILPRTB
  3401.     DB    CR,LF
  3402.     DB    '-- Upload has been cancelled',0
  3403.  
  3404. ;
  3405. ; Delete the received file
  3406. ;
  3407.     LD    C,DELETE    ; Get function
  3408.     LD    DE,FCB        ; Point to file
  3409.     CALL    BDOS        ; Delete it
  3410.     INC    A        ; Delete ok?
  3411.     JR    Z,NOTDEL    ; No
  3412.     CALL    ERXIT        ; Print second half of message
  3413.     DB    CR,LF
  3414.     DB    '-- Partial file is deleted','$'
  3415.  
  3416. ;
  3417. ; Unsuccessful delete
  3418. ;
  3419. NOTDEL:    CALL    ILPRT
  3420.     DB    CR,LF
  3421.     DB    '-- Received file not deleted'
  3422.  
  3423. NTDEL1: CALL    ERXIT
  3424.     DB    ' or no file received','$'
  3425.  
  3426. ;
  3427. ; See if a file exists.  If it exists, ask for a different name.
  3428. ;
  3429. CHEKFIL:LD    A,(SETAREA)    ; Uploading to designated drive/user?
  3430.     OR    A
  3431.     JR    NZ,CHEKF1    ; Yes
  3432.     LD    A,(ASKAREA)    ; Upload routing enabled?
  3433.     OR    A
  3434.     JR    NZ,CHEKF1    ; Yes
  3435.     LD    A,(PRIVATE)    ; Receiving in private area?
  3436.     OR    A
  3437.     JR    Z,$+5        ; No
  3438.  
  3439. CHEKF1:    CALL    RECARE        ; Set the designated area up
  3440.     LD    C,SRCHF        ; See if it exists
  3441.     LD    DE,FCB        ; Point to control block
  3442.     CALL    BDOS
  3443.     INC    A        ; Found?
  3444.     RET    Z        ; No, return
  3445.     LD    A,CANCEL    ; Tell the remote we are aborting
  3446.     CALL    SEND        ; Send several cancel requests
  3447.     CALL    SEND
  3448.     CALL    SEND
  3449.  
  3450. CHEKF2:    LD    B,1
  3451.     CALL    RECV        ; Up to 1 seconds for character
  3452.     JR    NC,CHEKF2    ; Wait until no more characters
  3453.     LD    A,(BATCH)    ; Using batch mode now?
  3454.     LD    (CONONL),A    ; If not, send message to modem also
  3455.     OR    A
  3456.     JR    Z,CHEKF3    ; If not, exit
  3457.     LD    A,CANCEL
  3458.     CALL    SEND
  3459.     CALL    SEND
  3460.     CALL    SEND
  3461.     LD    A,BS
  3462.     CALL    SEND
  3463.  
  3464. CHEKF3:    CALL    ERXIT        ; Exit, print error message
  3465.     DB    CR,LF
  3466.     DB    '-- File already exists','$'
  3467.  
  3468. ;
  3469. ; Make the file to be received
  3470. ;
  3471. MAKEFIL:XOR    A        ; Set extent and record number to 0
  3472.     LD    (FCBEXT),A
  3473.     LD    (FCBRNO),A
  3474.     LD    A,(HIDEIT)
  3475.     OR    A
  3476.     JR    Z,MAKEF1    ; HIDEIT not enabled, skip all this
  3477.     CALL    WHLCHK
  3478.     JR    NZ,MAKEF1    ; Don't make it $SYS if SYSOP online
  3479.     LD    A,(PRIVATE)
  3480.     OR    A
  3481.     JR    NZ,MAKEF1    ; Don't make it $SYS if private upload
  3482.  
  3483.     LD    DE,FCB+10    ; Point at second char of file extent
  3484.     LD    A,(DE)
  3485.     OR    80H        ; And turn on the high bit (Make file $SYS)
  3486.     LD    (DE),A        ; Put it back
  3487.  
  3488. MAKEF1:    LD    C,MAKE        ; Get BDOS FNC
  3489.     LD    DE,FCB        ; Point to FCB
  3490.     CALL    BDOS        ; To the make
  3491.     PUSH    AF        ; Save MAKE error code
  3492.  
  3493.     LD    C,SETFILE    ; Set up for BDOS FUNCTION 30
  3494.     LD    DE,FCB
  3495.     CALL    BDOS        ; Set file attributes
  3496.     POP    AF        ; Error code from BDOS make function
  3497.     INC    A        ; 0FFH=bad?
  3498.     RET    NZ        ; Open ok
  3499.  
  3500.     LD    HL,FCB+1
  3501.     JP    NOROOM        ; Tell them directory might be full
  3502.  
  3503. ;
  3504. ; Open file to be sent
  3505. ;
  3506. OPNFIL:    XOR    A        ; Zero accumulator
  3507.     LD    (FCBEXT),A    ; Set extent to 0
  3508.     LD    (FCBRNO),A    ; Set record number to 0
  3509.     LD    DE,FCB        ; Point to file
  3510.     LD    C,OPEN        ; Open it
  3511.     CALL    BDOS
  3512.     INC    A        ; Open ok?
  3513.     JR    NZ,OPNOK    ; Yes, check restrictions
  3514.  
  3515.     LD    A,(LBRARC)    ; Get extraction flag
  3516.     OR    A        ; Enabled?
  3517.     JP    Z,NOFILE    ; No, abort
  3518.     LD    HL,ARCNAM    ; Force .ARC filetype
  3519.     CALL    CHNGEXT        ; Try to open it
  3520.     JR    NZ,OPNOK    ; File found
  3521.     LD    HL,ARKNAM    ; Force .ARK filetype
  3522.     CALL    CHNGEXT        ; Try to open it
  3523.     JR    NZ,OPNOK    ; File found
  3524.     LD    HL,LBRNAM    ; Force .LBR filetype
  3525.     CALL    CHNGEXT        ; Try to open it
  3526.     JR    NZ,OPNOK    ; File found
  3527.     JP    NOARK        ; Not found and no more filetypes to try
  3528.  
  3529. CHNGEXT:LD    DE,FCB+9
  3530.     LD    BC,3
  3531.     LDIR
  3532.     LD    C,OPEN
  3533.     LD    DE,FCB
  3534.     CALL    BDOS
  3535.     INC    A
  3536.     RET            ; Z flag set=file not found
  3537.  
  3538. ;
  3539. ; Requested file was found, now check some restrictions
  3540. ;
  3541. OPNOK:    LD    IX,FCB        ; Point to filename
  3542.     CALL    RESTRCT        ; Check it for restrictions
  3543.     LD    A,(LBRARC)    ; Get the member extraction flag
  3544.     OR    A        ; Enabled?
  3545.     JR    Z,OPNOK1    ; No, skip this
  3546.     CALL    RSDMA        ; Reset to default DMA address
  3547.     LD    C,READ        ; Read first file record
  3548.     LD    DE,FCB
  3549.     CALL    BDOS
  3550.     OR    A        ; Read ok?
  3551.     JP    NZ,READERR    ; If not, error
  3552.     CALL    CKDIR        ; Take care of LBR stuff
  3553.  
  3554. OPNOK1:    LD    HL,(RCNT)    ; Get record count
  3555.     LD    A,H
  3556.     OR    L
  3557.     JP    Z,ZEROLN    ; Can't send 0-length files
  3558.     LD    A,(BATCH)
  3559.     OR    A
  3560.     JR    Z,OPNOK1A    ; Don't clear screen unless in BATCH mode
  3561.     LD    A,(FSTFLG)    ; Get first file sent flag
  3562.     OR    A        ; Sent it already?
  3563.     LD    A,1        ; Show we have for next time
  3564.     LD    (FSTFLG),A
  3565.     CALL    Z,CLEARIT    ; No, need to clear screen here first time
  3566.  
  3567. OPNOK1A:CALL    SHONM        ; Show the name of this file
  3568.     CALL    LOW41K        ; Less than MINKSPD?
  3569.     JR    C,OPNOK3    ; Yes, don't show 1k packets
  3570.  
  3571. OPNOK2:    CALL    ILPRT
  3572.     DB    CR,LF
  3573.     DB    'Ymodem packets total     > ',0
  3574.     LD    HL,(RCNT)    ; Get record count
  3575.     CALL    DIVREC        ; Divide number of records by 8
  3576.     CALL    DECOUT        ; Show # of 1k packets
  3577.  
  3578. OPNOK3:    CALL    ILPRT
  3579.     DB    CR,LF
  3580.     DB    'Xmodem packets total     > ',0
  3581.     LD    HL,(RCNT)    ; Get original count
  3582.     CALL    DECOUT        ; Show # of 128 byte packets
  3583.     LD    A,(MODE)    ; Get transfer mode
  3584.     CP    'R'        ; Receiving?
  3585.     RET    Z        ; Yes, all done
  3586.  
  3587.     CALL    ILPRT
  3588.     DB    CR,LF
  3589.     DB    'Disk space you need      > ',0
  3590.  
  3591.     LD    A,(SBSHOW)    ; Displaying intial BATCH screen to remote?
  3592.     OR    A
  3593.     PUSH    AF        ; Save answer
  3594.     LD    HL,(FILEK)    ; Get precalculated total 'k' for all files
  3595.     JR    NZ,OPNOK4    ; Go show it
  3596.     LD    BC,(RCNT)    ; Else get single file record count back
  3597.     CALL    ROUNDK        ; Round disk space needed
  3598.     EX    DE,HL
  3599. ;
  3600. OPNOK4:    CALL    DECOUT        ; Decimal output
  3601.     CALL    ILPRT
  3602.     DB    'k  (',0
  3603.     LD    HL,(BLKSIZ)    ; Get host disk block size
  3604.     CALL    DECOUT        ; Decimal output
  3605.     CALL    ILPRT
  3606.     DB    'k blocks)',0
  3607.     POP    AF        ; Displaying initial BATCH screen to remote?
  3608.     RET    NZ        ; Yes, then we're done in here
  3609.  
  3610. ;
  3611. ; Show transfer time, first for 1k blocks, then for 128-byte blocks. If we are
  3612. ; at 300 bps, report both transfer times the same.  (skip the 1k times for
  3613. ; speeds slower than MINKSPD bps.)
  3614. ;
  3615. KSPD:    CALL    LOW41K        ; Less than MINKSPD?
  3616.     JR    C,XSPD        ; Yes, skip 1k display
  3617.     CALL    ILPRT
  3618.     DB    CR,LF
  3619.     DB    'Ymodem time / 1k         > ',0
  3620.     CALL    GETSPD        ; Get current modem speed
  3621.     CP    1        ; At 300 bps?
  3622.     JR    Z,KSPD1        ; 1k transfer time in BC (minutes) if >300
  3623.     CALL    KTIM
  3624.     JR    KSPD2
  3625.  
  3626. KSPD1:    LD    HL,XECTBL
  3627.     LD    (RECTBL+1),HL
  3628.     CALL    XTIM
  3629.  
  3630. KSPD2:    CALL    STORTM        ; Store it
  3631.     CALL    XFRTIM        ; Display it
  3632.  
  3633. XSPD:    CALL    ILPRT
  3634.     DB    CR,LF
  3635.     DB    'Xmodem time / 128 byte   > ',0
  3636.     LD    HL,XECTBL    ; 128 size values (300 bps)
  3637.     LD    (RECTBL+1),HL
  3638.     CALL    XTIM        ; Xmodem transfer time
  3639.     LD    A,(KFLG)    ; If 'SK' set, 1k time already stored
  3640.     OR    A
  3641.     CALL    Z,STORTM
  3642.     CALL    XFRTIM
  3643.     LD    HL,KECTBL    ; Restore to original 1k values
  3644.     LD    (RECTBL+1),HL
  3645.     CALL    ILPRT
  3646.     DB    CR,LF,0
  3647.  
  3648.     LD    A,(BATCH)    ; In batch mode?
  3649.     OR    A
  3650.     JP    Z,OPNOK5    ; No, couldn't have been here before
  3651.     LD    A,(FSTFLG)    ; Yes, been here before?
  3652.     OR    A
  3653.     JP    Z,OPNOK5    ; No, following gets shown next time
  3654.  
  3655. ;
  3656. ; In batch, show files remaining after this one is sent
  3657. ;
  3658.     CALL    ILPRTL
  3659.     DB    CR,LF
  3660.     DB    'Files remaining          > ',0
  3661.     LD    A,(SHOCNT)    ; Get cumulative files
  3662.     DEC    A
  3663.     LD    (SHOCNT),A    ; Less one
  3664.     LD    L,A
  3665.     LD    H,0
  3666.     CALL    DECOUT
  3667.  
  3668.     CALL    ILPRTL
  3669.     DB    CR,LF
  3670.     DB    'Ymodem packets remaining > ',0
  3671.     LD    HL,(RCNT)    ; Get this file's record count again
  3672.     EX    DE,HL        ; Put in DE
  3673.     LD    HL,(TOTREC)    ; Total records remaining
  3674.     LD    A,L
  3675.     SUB    E
  3676.     LD    L,A
  3677.     LD    A,H
  3678.     SBC    A,D
  3679.     LD    H,A
  3680.     JR    NC,$+5
  3681.     LD    HL,0        ; In case of a slightly negative number
  3682.     PUSH    HL        ; Save it for Xmodem packets show
  3683.     CALL    DIVREC        ; Divide number of records by 8
  3684.     CALL    DECOUT
  3685.  
  3686.     CALL    ILPRTL
  3687.     DB    CR,LF
  3688.     DB    'Xmodem packets remaining > ',0
  3689.     POP    HL        ; Get total records remaining after this file
  3690.     LD    (TOTREC),HL
  3691.     CALL    DECOUT        ; Show remote remaining records
  3692.     CALL    ILPRTL
  3693.     DB    CR,LF,LF,0
  3694.     CALL    WAITMSG        ; Display '[ waiting ]' message locally
  3695.     RET
  3696.  
  3697. ;
  3698. ; If sending an ARC or ARK file, tell user to rename to .ARK or .ARC file type.
  3699. ;
  3700. OPNOK5:    LD    A,(LBRARC)    ; Get extraction flag
  3701.     OR    A        ; Enabled?
  3702.     JP    Z,DLRDY        ; No, skip this
  3703.     LD    A,(FCB+9)    ; Point to member filetype
  3704.     AND    7FH        ; Strip parity
  3705.     CP    'L'        ; LBR member extraction?
  3706.     JP    Z,DLRDY        ; Yes, skip this
  3707.     CALL    ILPRTB
  3708.     DB    CR,LF
  3709.     DB    'You MUST name file       > ',0
  3710.     LD    D,8        ; Filename count - ignore filetype
  3711.     LD    HL,MEMFCB    ; Get requested member name
  3712.  
  3713. OPNOK6:    LD    A,(HL)
  3714.     CP    ' '        ; Short filename?
  3715.     JR    Z,OPNOK7    ; If so, fill in type
  3716.     CALL    TYPE
  3717.  
  3718.     DEC    D        ; One less...
  3719.     INC    HL        ; Next character
  3720.     JR    NZ,OPNOK6    ; Loop until done
  3721.  
  3722. OPNOK7:    LD    A,(FCB+11)    ; Get last character of parent filetype
  3723.     LD    ($+9),A        ; Stuff it below to display
  3724.     CALL    ILPRTB
  3725.     DB    '.AR?'        ; Either a 'C' or a 'K' gets poked at '?'
  3726.     DB    CR,LF,0
  3727.     CALL    DLRDY        ; Tell them their download(s) are ready
  3728.     RET
  3729.  
  3730. ;
  3731. ; These routines display the transfer time in minutes & seconds and check for
  3732. ; time restrictions,  if a clock is enabled.
  3733. ;
  3734. XFRTIM:    PUSH    HL        ; Save seconds in 'L'
  3735.     CALL    WHLCHK        ; Sysop online?
  3736.     JR    NZ,SKPTIM    ; Yes, then skip the limit
  3737.  
  3738.     LD    A,(MAXTOS)
  3739.     OR    A
  3740.     JR    Z,SKPTIM
  3741.     LD    D,C        ; Save minutes for now
  3742.     INC    D        ; Increment to next full minute
  3743.     LD    A,(TIMEON)    ; Using TIMEON?
  3744.     OR    A
  3745.     LD    A,D        ; Get length of this program
  3746.     JR    Z,XFRTM1    ; No, don't increment time
  3747.     LD    HL,TON        ; Point to time on system
  3748.     ADD    A,(HL)        ; Else add time on system to transfer time
  3749.  
  3750. XFRTM1:    LD    (XFRMIN),A    ; Store it
  3751.     OR    A
  3752.     LD    A,B        ; Get hours in A
  3753.     JR    NZ,$+3        ; Don't increment if not zero
  3754.     INC    A        ; Increment to next full minute
  3755.     LD    (XFRMIN+1),A
  3756.  
  3757. SKPTIM:    LD    H,B        ; Get most significant in H (hours)
  3758.     LD    L,C        ; Get least significant byte of minutes in L
  3759.     CALL    DECOUT        ; Print decimal number of minutes
  3760.     CALL    ILPRT
  3761.     DB    ':',0
  3762.     POP    HL        ; Get seconds back
  3763.     LD    A,L        ; Get the number of seconds
  3764.     CP    10        ; 10 seconds or more?
  3765.     JR    NC,$+7        ; If yes, disregard next two lines
  3766.     CALL    ILPRT
  3767.     DB    '0',0
  3768.     CALL    DECOUT        ; Print decimal number of seconds
  3769.     CALL    ILPRT
  3770.     DB    ' at ',0
  3771.     CALL    GETSPD        ; Get modem speed value in A
  3772.     CALL    SHOSPD        ; Display in BPS
  3773.  
  3774. ;
  3775. ; Determine if the caller has enough time left online to make the
  3776. ; requested download(s).
  3777. ;
  3778. XFRTM3:    LD    A,(MODE)    ; Get transfer mode
  3779.     CP    'R'        ; Receiving?
  3780.     RET    Z        ; Yes, all done
  3781.  
  3782.     LD    A,(MAXTOS)    ; Get maximum time allowed
  3783.     OR    A        ; Unlimited?
  3784.     RET    Z        ; Yes, skip time restriction
  3785.  
  3786.     LD    A,(XFRMIN+1)    ; Get most significant byte of minutes
  3787.     OR    A        ; 0?
  3788.     JR    NZ,OVERTM    ; If not, over 255 minutes
  3789.     LD    A,(XFRMIN)    ; Get least significant byte of minute count
  3790.     LD    B,A        ; Put in B
  3791.     LD    A,(MAXTOS)    ; Get maximum time allowed
  3792.     INC    A
  3793.     SBC    A,B
  3794.     RET    NC
  3795.  
  3796. ;
  3797. ; There is not enough time to download the requested file(s). Inform user and
  3798. ; abort to CP/M.
  3799. ;
  3800. OVERTM:    CALL    ILPRTB
  3801.     DB    CR,LF,LF,0
  3802.     CALL    ABRTMSG        ; Display both local and remote we aborted
  3803.     CALL    ILPRTB
  3804.     DB    CR,LF,LF
  3805.     DB    'Required send time exceeds the ',0
  3806.     LD    A,(TLOS)    ; Get time left on system
  3807.     LD    H,0        ; Zero H
  3808.     LD    L,A        ; Time left on system in L
  3809.     CALL    DECOUT        ; Decimal output routine
  3810.     CALL    ERXIT        ; Display following message and abort to CP/M
  3811.     DB    ' minutes allowed','$'
  3812.  
  3813. ;
  3814. ;-------------------------------------------------------------------------;
  3815. ; L o g   F i l e   T r a n s f e r                      |
  3816. ;-------------------------------------------------------------------------;
  3817. ;
  3818. ; Main log file routine, adds record to log file
  3819. ;
  3820. LOGCALL:LD    A,(LOGCAL)    ; Logging file transfers?
  3821.     OR    A
  3822.     RET    Z        ; No
  3823.     CALL    GTCURDU        ; Get current drive/user in USRSAV and DSKSAV
  3824.  
  3825.     LD    HL,FCBCLR    ; FCB to initialize
  3826.     LD    DE,LSTCLR    ; Filename to insert
  3827.     CALL    RENFCB        ; Initialize FCB
  3828.  
  3829.     LD    A,(LASTDRV)
  3830.     SUB    'A'
  3831.     LD    (DEFDSK),A
  3832.     LD    A,(LASTUSR)
  3833.     LD    (DEFUSR),A
  3834.     LD    DE,FCBCLR
  3835.     CALL    OPENF        ; Open LASTCALR file
  3836.     JR    NZ,LGCAL1
  3837.     CALL    ILPRT
  3838.     DB    CR,LF
  3839.     DB    '-- File not Found: LASTCALR.???'
  3840.     DB    CR,LF,0
  3841.     RET            ; Now go send EOT
  3842.  
  3843. LGCAL1:    LD    C,SETRRD    ; Get random record #
  3844.     LD    DE,FCBCLR    ; (for first record in file)
  3845.     CALL    BDOS
  3846.  
  3847.     LD    DE,DBUF        ; Set DMA to DBUF
  3848.     CALL    STDMA
  3849.  
  3850.     LD    C,RRDM        ; Read first (and only) record
  3851.     LD    DE,FCBCLR
  3852.     CALL    BDOS
  3853.  
  3854.     LD    HL,DBUF        ; Set pointer to beginning of record
  3855.     LD    A,(CLOCK)    ; Is there a clock installed?
  3856.     OR    A
  3857.     JR    Z,LGCAL2    ; No, skip this then
  3858.     LD    DE,0        ; Zero DE
  3859.     LD    A,(LCNAME)    ; Offset to start of caller's name
  3860.     LD    E,A        ; To E
  3861.     ADD    HL,DE        ; HL now points to start of name
  3862.  
  3863. LGCAL2:    LD    (CLRPTR),HL
  3864.     LD    DE,LOGBUF    ; Set DMA address to LOGBUF
  3865.     CALL    STDMA
  3866.  
  3867.     LD    HL,FCBLOG    ; FCB to initialize
  3868.     LD    DE,LOGNAM    ; Filename to insert
  3869.     CALL    RENFCB        ; Initialize FCB
  3870.  
  3871.     LD    A,(LOGDRV)
  3872.     SUB    'A'
  3873.     LD    (DEFDSK),A
  3874.     LD    A,(LOGUSR)
  3875.     LD    (DEFUSR),A
  3876.     LD    DE,FCBLOG
  3877.     CALL    OPENF        ; Open log file
  3878.     JR    NZ,LGCAL5    ; If file exists, skip create
  3879.     LD    DE,FCBLOG
  3880.     LD    C,MAKE        ; Create a new file if needed
  3881.     CALL    BDOS
  3882.     INC    A
  3883.     JR    NZ,LGCAL3    ; No error, continue
  3884.     CALL    ILPRT        ; File create error
  3885.     DB    CR,LF
  3886.     DB    '-- Directory Full: ',0
  3887.     LD    HL,LOGNAM
  3888.     CALL    SHONM4
  3889.     RET            ; Go back and send EOT
  3890.  
  3891. LGCAL3:    LD    DE,LOGBUF    ; Set DMA back to LOGBUF 
  3892.     CALL    STDMA
  3893.  
  3894.     LD    C,SETRRD    ; Set random record #
  3895.     LD    DE,FCBLOG    ; (for first record in file)
  3896.     CALL    BDOS
  3897.  
  3898. LGCAL4:    LD    A,EOF
  3899.     LD    (LOGBUF),A
  3900.     JR    LGCAL6
  3901.  
  3902. LGCAL5:    LD    DE,LOGBUF    ; Set DMA to LOGBUF
  3903.     CALL    STDMA
  3904.  
  3905.     LD    C,FILSIZ    ; Get file length
  3906.     LD    DE,FCBLOG
  3907.     CALL    BDOS
  3908.     LD    HL,(FCBLOG+33)    ; Back up to last record
  3909.     LD    A,L
  3910.     OR    H
  3911.     JR    Z,LGCAL4    ; Unless zero length file
  3912.     DEC    HL
  3913.     LD    (FCBLOG+33),HL
  3914.     LD    DE,FCBLOG
  3915.     LD    C,RRDM        ; And read it
  3916.     CALL    BDOS
  3917.  
  3918. LGCAL6:    CALL    RSTLP        ; Initialize LOGPTR and LOGCNT
  3919.  
  3920. LGCAL7:    LD    A,(LOGCNT)
  3921.     INC    A
  3922.     LD    (LOGCNT),A
  3923.     CP    129
  3924.     JR    NZ,LGCAL8
  3925.     LD    HL,(FCBLOG+33)
  3926.     INC    HL
  3927.     LD    (FCBLOG+33),HL
  3928.     LD    HL,LOGBUF+1
  3929.     LD    (LOGPTR),HL
  3930.     LD    A,1
  3931.     LD    (LOGCNT),A
  3932.     LD    A,EOF
  3933.     JR    LGCAL8A
  3934.  
  3935. LGCAL8:    LD    HL,(LOGPTR)
  3936.     LD    A,(HL)
  3937.     INC    HL
  3938.     LD    (LOGPTR),HL
  3939.  
  3940. LGCAL8A:CP    EOF
  3941.     JR    NZ,LGCAL7    ; Until EOF
  3942.     LD    A,(LOGCNT)    ; Then backup one character
  3943.     DEC    A
  3944.     LD    (LOGCNT),A
  3945.     LD    HL,(LOGPTR)
  3946.     DEC    HL
  3947.     LD    (LOGPTR),HL
  3948.  
  3949. ;
  3950. ; Print file transfer mode to LOG file (R, S, P, A, L)
  3951. ;
  3952.     LD    A,(PUPFLG)
  3953.     OR    A        ; Privileged upload option request?
  3954.     JR    Z,LGCAL8B    ; No, skip next 2 lines
  3955.     LD    A,'P'        ; Else,
  3956.     JR    LGCAL9        ; Show as private upload for log file
  3957.  
  3958. LGCAL8B:LD    A,(PRIVATE)
  3959.     OR    A
  3960.     JR    NZ,LGCAL9
  3961.     LD    A,(MODE)    ; Get transfer mode back and put in file
  3962.  
  3963. LGCAL9:    CALL    PUTLOG
  3964.  
  3965. ;
  3966. ; Print baud rate to LOG file
  3967. ;
  3968.     CALL    GETSPD        ; Get speed factor
  3969.     ADD    A,30H
  3970.     CALL    PUTLOG
  3971.     CALL    PUTSP        ; Blank
  3972.  
  3973. ;
  3974. ; Print program size (in minutes and seconds) to LOG file
  3975. ;
  3976.     LD    A,(PGSIZE)    ; Now the program size in minutes..
  3977.     CALL    PNDEC        ; Of transfer time (mins)
  3978.     LD    A,':'
  3979.     CALL    PUTLOG        ; ':'
  3980.     LD    A,(PGSIZE+2)
  3981.     CALL    PNDEC        ; And seconds
  3982.     CALL    PUTSP        ; Blank
  3983.  
  3984. ;
  3985. ; Log the drive and user area as a prompt
  3986. ;
  3987.     LD    A,(FCB)
  3988.     OR    A
  3989.     JR    NZ,WDRV
  3990.     LD    A,(DSKSAV)
  3991.     INC    A
  3992.  
  3993. WDRV:    ADD    A,'A'-1
  3994.     CALL    PUTLOG
  3995.     LD    A,(USRSAV)
  3996.     CALL    PNDEC
  3997.     LD    A,'>'        ; Make it look like a prompt
  3998.     CALL    PUTLOG
  3999.     LD    A,(LBRARC)
  4000.     OR    A        ; Member extraction?
  4001.     JR    Z,WDRV1        ; No, won't be member name
  4002.     LD    HL,MEMFCB    ; Name of file in library
  4003.     LD    B,11
  4004.     CALL    PUTSTR
  4005.     CALL    PUTSP        ; ' '
  4006.  
  4007. ;
  4008. ; Put filename in LOG file
  4009. ;
  4010. WDRV1:    LD    HL,FCB+1    ; Now the name of the file
  4011.     LD    B,11
  4012.     CALL    PUTSTR
  4013.     LD    A,(LBRARC)
  4014.     OR    A        ; Member extraction?
  4015.     JR    Z,WDRV2        ; No, won't be member name
  4016.     LD    C,1
  4017.     JR    SPLOOP
  4018.  
  4019. WDRV2:    LD    C,13
  4020.  
  4021. SPLOOP:    PUSH    BC
  4022.     CALL    PUTSP        ; Put ' '
  4023.     POP    BC
  4024.     DEC    C
  4025.     JR    NZ,SPLOOP
  4026.  
  4027. ;
  4028. ; Print number of 'k' to LOG file
  4029. ;
  4030.     LD    HL,(RECDNO)    ; Get record count
  4031.     CALL    DIVREC        ; Divide record count by 8
  4032.  
  4033. EXKB2:    CALL    PNDEC3        ; Print to log file (right just xxxk)
  4034.     LD    HL,LOGK        ; 'k '
  4035.     LD    B,2
  4036.     CALL    PUTSTR
  4037.     XOR    A
  4038.     LD    (COMMA),A    ; Reset field counter
  4039.  
  4040. ;
  4041. ; Print date and time of transfer to LOG file
  4042. ;
  4043.     LD    A,(CLOCK)    ; Clock available in BYE?
  4044.     OR    A
  4045.     JR    NZ,EXKB3    ; Yes, continue
  4046.     LD    A,(RTC)        ; Else how about an RTC overlay?
  4047.     OR    A
  4048.     JR    Z,CLOOP        ; Nope, foget date and time
  4049.  
  4050. EXKB3:    CALL    GETTIME        ; Get CURRENT time for log
  4051.  
  4052.     LD    A,(EDATE)    ; European date format?
  4053.     OR    A
  4054.     JR    Z,EXKB4        ; No
  4055.  
  4056.     LD    A,(DAY)
  4057.     CALL    PNDEC        ; Print DD
  4058.     LD    A,'/'        ; '/'
  4059.     CALL    PUTLOG
  4060.     LD    A,(MONTH)
  4061.     CALL    PNDEC        ; Print MM
  4062.     JR    EXKB5
  4063.  
  4064. EXKB4:    LD    A,(MONTH)
  4065.     CALL    PNDEC        ; Print MM
  4066.     LD    A,'/'        ; '/'
  4067.     CALL    PUTLOG
  4068.     LD    A,(DAY)
  4069.     CALL    PNDEC        ; Print DD
  4070.  
  4071. EXKB5:    LD    A,'/'        ; '/'
  4072.     CALL    PUTLOG
  4073.     LD    A,(YEAR)
  4074.     CALL    PNDEC        ; Print YY
  4075.     CALL    PUTSP        ; ' '
  4076.     LD    A,(HOUR)    ; Get current hour
  4077.     CALL    PNDEC        ; Print hr to file
  4078.     LD    A,':'        ; With ':'
  4079.     CALL    PUTLOG        ; Between HH:MM
  4080.     LD    A,(MINUTE)    ; Get min
  4081.     CALL    PNDEC        ; And print min
  4082.     CALL    PUTSP        ; Print a space
  4083.  
  4084. ;
  4085. ; Print name of caller to LOG file
  4086. ;
  4087. CLOOP:    LD    HL,(CLRPTR)
  4088.     LD    A,(HL)
  4089.     INC    HL
  4090.     LD    (CLRPTR),HL
  4091.     CP    EOF        ; End of file?
  4092.     JR    Z,QUIT        ; Yes
  4093.     CP    CR        ; Do not print 2nd line of 'LASTCALR'
  4094.     JR    NZ,CLOP1
  4095.  
  4096. CEND:    CALL    PUTLOG
  4097.     LD    A,LF
  4098.     CALL    PUTLOG        ; And add a LF
  4099.     JR    QUIT
  4100.  
  4101. CLOP1:    CP    ' '        ; Space?
  4102.     JR    NZ,CLOP1A    ; No, check for comma
  4103.     LD    A,','        ; Convert space to comma for field checking
  4104.  
  4105. CLOP1A:    CP    ','        ; Comma?
  4106.     JR    NZ,CLOP2
  4107.     LD    A,(COMMA)
  4108.     CP    1        ; Is this the second comma or space?
  4109.     JR    NZ,CLOP1B    ; No, bump the counter
  4110.     LD    A,CR
  4111.     JR    CEND        ; Yes, stop taking data from lastcalr
  4112.  
  4113. CLOP1B:    INC    A        ; Bump it one
  4114.     LD    (COMMA),A
  4115.     LD    A,' '        ; Instead send a ' '
  4116.  
  4117. CLOP2:    CALL    PUTLOG
  4118.     JR    CLOOP
  4119.  
  4120. QUIT:    LD    A,EOF        ; Put in EOF
  4121.     CALL    PUTLOG
  4122.     LD    A,(LOGCNT)    ; Check count of chars in buffer
  4123.     CP    1
  4124.     JR    NZ,QUIT        ; Fill last buffer & write it
  4125.     LD    DE,FCBCLR    ; Close lastcaller file
  4126.     LD    C,CLOSE
  4127.     CALL    BDOS
  4128.     INC    A
  4129.     JR    Z,QUIT1
  4130.     LD    HL,(FCBLOG+33)    ; Move pointer back to show
  4131.     DEC    HL        ; Actual file size
  4132.     LD    (FCBLOG+33),HL
  4133.     LD    DE,FCBLOG    ; Close log file
  4134.     LD    C,CLOSE
  4135.     CALL    BDOS
  4136.     INC    A
  4137.     RET    NZ        ; If OK, return now...
  4138.  
  4139. QUIT1:    CALL    ILPRT        ; If error, oops
  4140.     DB    CR,LF
  4141.     DB    '-- Close Error: ',0
  4142.     LD    HL,LOGNAM
  4143.     CALL    SHONM4
  4144.     RET            ; Go back and send EOT
  4145.  
  4146. ;
  4147. ;------------------------- 
  4148. ; LOGCAL Support Routines
  4149. ;
  4150. ; Open file with FCB pointed to by DE (disk/user passed in DEFDSK and DEFUSR)
  4151. ;
  4152. OPENF:    PUSH    DE        ; Save FCB address
  4153.     LD    A,(DEFDSK)     ; Get disk for file
  4154.     CALL    RECDRX        ; Log into it
  4155.     LD    A,(DEFUSR)     ; Get default user
  4156.     CALL    RECAR1        ; Log into it
  4157.     POP    DE        ; Get FCB address
  4158.     LD    A,(CPM3)    ; Using with CPM3?
  4159.     OR    A
  4160.     JR    Z,OPENF1    ; No
  4161.     PUSH    DE        ; Save FCB address
  4162.     CALL    RSDMA        ; Set DMA to 80H
  4163.     POP    DE        ; Get back pointer to FCB
  4164.     PUSH    DE        ; Save FCB pointer again
  4165.     LD    C,SRCHF        ; Search for first match
  4166.     CALL    BDOS
  4167.     INC    A        ; Did file match?
  4168.     POP    DE
  4169.     RET    Z        ; No, return
  4170.     PUSH    DE
  4171.     DEC    A        ; A=directory code (0-3)
  4172.     ADD    A,A        ; *2
  4173.     ADD    A,A        ; *4
  4174.     ADD    A,A        ; *8
  4175.     ADD    A,A        ; *16
  4176.     ADD    A,A        ; *32
  4177.     LD    E,A
  4178.     LD    D,0
  4179.     LD    HL,TBUF        ; Add (32*dir code) to default DMA
  4180.     ADD    HL,DE        ; to find first match filename
  4181.     POP    DE        ; DE=FCB
  4182.     PUSH    DE        ; Save DE again
  4183.     INC    HL        ; Move HL past user # byte in buffer
  4184.     INC    DE        ; Move DE past drive # byte in FCB
  4185.     LD    BC,11
  4186.     LDIR            ; Move name found to FCB
  4187.     POP    DE        ; And continue with open
  4188.  
  4189. OPENF1:    LD    C,OPEN        ; Open file
  4190.     CALL    BDOS
  4191.     CP    0FFH        ; Not present?
  4192.     RET            ; Return to caller
  4193.  
  4194. ;
  4195. ; Write character to log file
  4196. ;
  4197. PUTLOG:    LD    HL,(LOGPTR)    ; Get pointer
  4198.     AND    7FH        ; Strip any attributes
  4199.     LD    (HL),A        ; Put data
  4200.     INC    HL        ; Increment pointer
  4201.     LD    (LOGPTR),HL    ; Update pointer
  4202.     LD    B,A        ; Save character in B
  4203.     LD    A,(LOGCNT)    ; Get count
  4204.     INC    A        ; Increment it
  4205.     LD    (LOGCNT),A    ; Update count
  4206.     CP    129        ; Check it
  4207.     RET    NZ        ; If not EOB, return
  4208.     PUSH    BC        ; Save character
  4209.     LD    DE,FCBLOG    ; Else, write this sector
  4210.     LD    C,WRDM
  4211.     CALL    BDOS
  4212.     OR    A
  4213.     JR    Z,ADVRCP    ; If ok, cont.
  4214.     CALL    ILPRT
  4215.     DB    CR,LF
  4216.     DB    '-- Disk Full: ',0
  4217.     LD    HL,LOGNAM
  4218.     CALL    SHONM4
  4219.     RET
  4220.  
  4221. ADVRCP:    LD    HL,(FCBLOG+33)    ; Advance record number
  4222.     INC    HL
  4223.     LD    (FCBLOG+33),HL
  4224.     CALL    RSTLP        ; Reset buffer pointers
  4225.     POP    AF        ; Get saved character
  4226.     JP    PUTLOG        ; Put it in buffer and return
  4227.  
  4228. RSTLP:    LD    HL,LOGBUF    ; Reset pointers
  4229.     LD    (LOGPTR),HL    ; And return
  4230.     LD    A,0
  4231.     LD    (LOGCNT),A
  4232.     RET
  4233.  
  4234. ;
  4235. ; Print number in decimal format (into log file)  IN: HL=binary number
  4236. ; OUT: nnn=right justified with spaces
  4237. ;
  4238. PNDEC3:    LD    A,H        ; Check high byte
  4239.     OR    A
  4240.     JR    NZ,DECOT    ; If on, is at least 3 digits
  4241.     LD    A,L        ; Else, check low byte
  4242.     CP    100
  4243.     JR    NC,TEN
  4244.     CALL    PUTSP
  4245.  
  4246. TEN:    CP    10
  4247.     JR    NC,DECOT
  4248.     CALL    PUTSP
  4249.     JR    DECOT
  4250.  
  4251. ;
  4252. ; Print number in decimal format (into log file)
  4253. ;
  4254. PNDEC:    CP    10        ; Two column decimal format routine
  4255.     JR    C,ONE        ; One or two digits to area number?
  4256.     JR    TWO
  4257.  
  4258. ONE:    PUSH    AF
  4259.     LD    A,'0'
  4260.     CALL    PUTLOG
  4261.     POP    AF
  4262.  
  4263. TWO:    LD    H,0
  4264.     LD    L,A
  4265.  
  4266. DECOT:    PUSH    BC
  4267.     PUSH    DE
  4268.     PUSH    HL
  4269.     LD    BC,-10
  4270.     LD    DE,-1
  4271.  
  4272. DECOT2:    ADD    HL,BC
  4273.     INC    DE
  4274.     JR    C,DECOT2
  4275.     LD    BC,10
  4276.     ADD    HL,BC
  4277.     EX    DE,HL
  4278.     LD    A,H
  4279.     OR    L
  4280.     CALL    NZ,DECOT
  4281.     LD    A,E
  4282.  
  4283. DECOT3:    ADD    A,'0'
  4284.     CALL    PUTLOG
  4285.  
  4286. DECOT4:    POP    HL
  4287.     POP    DE
  4288.     POP    BC
  4289.     RET
  4290.  
  4291. ;
  4292. ; Put string to log file
  4293. ;
  4294. PUTSTR:    LD    A,(HL)
  4295.     PUSH    HL
  4296.     PUSH    BC
  4297.     CALL    PUTLOG
  4298.     POP    BC
  4299.     POP    HL
  4300.     INC    HL
  4301.     DJNZ    PUTSTR
  4302.     RET
  4303.  
  4304. ;
  4305. ; Puts a single space in log file, saves PSW/HL
  4306. ;
  4307. PUTSP:    PUSH    AF
  4308.     PUSH    HL
  4309.     LD    A,' '
  4310.     CALL    PUTLOG
  4311.     POP    HL
  4312.     POP    AF
  4313.     RET
  4314.  
  4315. ;
  4316. ;-------------------------------------------------------------------------;
  4317. ; T I M E   &   D A T E      R o u t i n e s                    |
  4318. ;-------------------------------------------------------------------------;
  4319. ;
  4320. ; Get RTCBUF address if running BYE
  4321. ;
  4322. TIME:    LD    A,(CLOCK)    ; Clock in BYE?
  4323.     OR    A
  4324.     JR    Z,TIME1        ; No
  4325.     LD    DE,25        ; Offset to RTCBUF address
  4326.     CALL    GETOFF        ; Point to JP COLDBOOT + offset in DE
  4327.     LD    E,(HL)        ; HL points to RTCBUF address
  4328.     INC    HL        ; To most significant byte of address
  4329.     LD    D,(HL)
  4330.     EX    DE,HL        ; Back to HL
  4331.     LD    (RTCBUF),HL    ; Save for later use
  4332.     CALL    GETTIME        ; Store RTCBUF contents internally
  4333.  
  4334.     LD    HL,(RTCBUF)    ; Get RTC buffer address
  4335.     LD    DE,7        ; Offset to time on system (TOS) word
  4336.     ADD    HL,DE        ; Address in HL
  4337.     LD    A,(HL)        ; Get minutes on system
  4338.     LD    (TON),A        ; Store time on system for SHOWTOS
  4339.  
  4340. ;
  4341. ; Get MAXTOS if restricting downloads to time left
  4342. ;
  4343.     LD    A,(TIMEON)    ; Policing time on system?
  4344.     OR    A
  4345.     JP    Z,SHOWTOS    ; No
  4346.     LD    DE,24        ; Offset to maximum time allowed
  4347.     CALL    GETOFF        ; Point to JP COLDBOOT + offset in D
  4348.  
  4349.     LD    A,(MODE)    ; Exiting? (Gets set NZ in exit routine)
  4350.     OR    A
  4351.     JR    Z,TIME0        ; No, skip next
  4352.     LD    A,(MAXTOS)    ; Reset maximum time allowed
  4353.     LD    (HL),A
  4354.     JR    TIME0A
  4355.  
  4356. TIME0:    LD    A,(HL)        ; Get maximum time allowed
  4357.     LD    (MAXTOS),A    ; Store it
  4358.     LD    (HL),0        ; Disable BYE from checking time for now
  4359.  
  4360. TIME0A:    LD    A,(TON)
  4361.     LD    B,A        ; Save time on system for comparison
  4362.     LD    A,(MAXTOS)    ; Get maximum time allowed
  4363.     SUB    B        ; Get time left on system
  4364.     LD    (TLOS),A    ; Store time left on system
  4365.     JP    SHOWTOS        ; Go show TON
  4366.  
  4367. ;
  4368. ; Get TON if RTC
  4369. ;
  4370. TIME1:    LD    A,(RTC)        ; Clock reader code installed in ZMD?
  4371.     OR    A
  4372.     JP    Z,SHOWTOS    ; No
  4373.     CALL    GETTIME
  4374.  
  4375.     LD    HL,(LHOUR)    ; Get address to logon hour
  4376.     LD    A,(HOUR)
  4377.     CP    (HL)        ; Same as current hour?
  4378.     INC    HL        ; Point to logon minute
  4379.     LD    D,(HL)        ; Get it in D
  4380.     JR    NZ,TIME2    ; No, not the same
  4381.     LD    A,(MINUTE)    ; Else get current minute
  4382.     SUB    D        ; Subtract logon minute
  4383.     LD    (TON),A        ; Store it as time on system
  4384.     JR    TIME3        ; Get maximum allowed
  4385.  
  4386. TIME2:    LD    A,60        ; Fake an hour
  4387.     SUB    D        ; Subtract logon minute
  4388.     LD    HL,MINUTE    ; Point to current minute
  4389.     ADD    A,(HL)        ; Add them
  4390.     LD    (TON),A        ; Store as current time on system
  4391.  
  4392. ;
  4393. ; Get MAXTOS if TIMEON
  4394. ;
  4395. TIME3:    LD    A,(TIMEON)    ; Restricting downloads to time left?
  4396.     OR    A
  4397.     JR    Z,SHOWTOS    ; No
  4398.     CALL    WHLCHK        ; WHEEL byte set?
  4399.     JR    NZ,SHOWTOS    ; Yes, just display time on system
  4400.     LD    A,(MODE)    ; Else been here before?
  4401.     OR    A
  4402.     JR    NZ,TIME4    ; Yes (MODE is 0 first time through)
  4403.     LD    A,(MAXMIN)
  4404.     LD    (MAXTOS),A    ; Else set maximum time allowed
  4405.     LD    (TLOS),A    ; And current time left on system
  4406.  
  4407. TIME4:    LD    A,(MAXTOS)    ; Get current maximum time allowed
  4408.     OR    A        ; Unlimited?
  4409.     JR    Z,SHOWTOS    ; Yes, just display time on system
  4410.     LD    A,(MAXMIN)    ; Else get original maximum minutes allowed
  4411.     LD    B,A        ; Into B
  4412.     LD    A,(TON)        ; Get current time on system
  4413.     SUB    B        ; Time up?
  4414.     JR    C,SHOWTOS    ; No, just display time on system
  4415.  
  4416.     CALL    ILPRTB
  4417.     DB    CR,LF,LF
  4418.     DB    '-- Your time is up, please share the system with others'
  4419.     DB    CR,LF,0
  4420.     POP    HL
  4421.     LD    A,0CDH
  4422.     LD    (0),A
  4423.     JP    0
  4424.  
  4425. ;
  4426. ; Display the time on system
  4427. ;
  4428. SHOWTOS:LD    A,(DSPTOS)    ; Display time on system message?
  4429.     OR    A
  4430.     RET    Z        ; No, all done
  4431.     LD    A,(MODE)    ; Else exiting?
  4432.     OR    A
  4433.     JR    Z,SHOTOS1    ; Yes, no line feed
  4434.     CALL    ILPRTB
  4435.     DB    CR,LF,0
  4436.  
  4437. SHOTOS1:CALL    ILPRTB
  4438.     DB    'Online ',0
  4439.     LD    A,(TON)        ; Get time on system
  4440.     LD    H,0        ; Zero H
  4441.     LD    L,A        ; TON in L
  4442.     CALL    DECOUT        ; Decimal output
  4443.     CALL    ILPRTB
  4444.     DB    ' minute',0
  4445.     LD    A,(TON)        ; Get time on system
  4446.     CP    1        ; 1?
  4447.     JR    Z,SHOTOS2    ; Yes, leave display as 'minute'
  4448.     CALL    ILPRTB
  4449.     DB    's',0        ; Else make it plural
  4450.  
  4451. SHOTOS2:LD    A,(MODE)
  4452.     OR    A
  4453.     RET    NZ
  4454.     CALL    ILPRT
  4455.     DB    CR,LF,0
  4456.     RET
  4457.  
  4458. ;
  4459. ; Transfer BYE's RTCBUF contents to internal storage
  4460. ;
  4461. GETTIME:LD    A,(RTC)        ; User installed clock routines?
  4462.     OR    A
  4463.     JP    NZ,RTCTIM    ; Yes, go do it
  4464.     LD    HL,(RTCBUF)
  4465.  
  4466.     LD    A,(HL)        ; 00:
  4467.     CALL    BCDBIN        ; Convert to binary
  4468.     LD    (HOUR),A    ; Save
  4469.  
  4470.     CALL    GETTIM3        ; :00
  4471.     LD    (MINUTE),A    ; Save
  4472.  
  4473.     INC    HL        ; Skip seconds
  4474.     INC    HL        ; Skip '19'nn
  4475.     CALL    GETTIM3        ; YY
  4476.     LD    (YEAR),A    ; Save
  4477.  
  4478.     CALL    GETTIM3        ; MM
  4479.     LD    (MONTH),A    ; Save
  4480.  
  4481.     CALL    GETTIM3        ; DD
  4482.     LD    (DAY),A        ; Save
  4483.     RET            ; And return
  4484.  
  4485. GETTIM3:INC    HL        ; Increment to next RTC byte value
  4486.     LD    A,(HL)        ; Get it
  4487.     JP    BCDBIN        ; Return with binary value in A
  4488.  
  4489. ;
  4490. ; Add the time of the last upload/download to BYE's time on system byte
  4491. ;
  4492. ADDTON:    LD    A,(TIMEON)    ; Using TIMEON?
  4493.     OR    A
  4494.     RET    Z
  4495.  
  4496.     CALL    BYECHK        ; If so, see if BYE is running
  4497.     OR    A        ; 0 if no clock, or 0 if no BYE.
  4498.     LD    HL,TON        ; Prepare for internal RTC
  4499.     JR    Z,ADDTN1
  4500.  
  4501.     LD    HL,(RTCBUF)    ; Get RTC buffer address
  4502.     LD    DE,7        ; Get offset to TOS word
  4503.     ADD    HL,DE        ; Add offset, HL contains TON address
  4504.  
  4505. ADDTN1:    PUSH    HL        ; Save it
  4506.     LD    HL,(RECDNO)
  4507.     LD    (RCNT),HL
  4508.     CALL    XTIM        ; Calculate transfer time
  4509.     POP    HL        ; Restore TON address
  4510.     LD    A,(HL)        ; Get time on in A
  4511.     LD    B,A        ; Save it
  4512.     LD    A,(MODE)    ; Get current transfer mode
  4513.     CP    'S'        ; Is this a download?
  4514.     JR    Z,ADDTN2    ; Yes, subtract download time
  4515.     LD    A,(CREDIT)    ; Else crediting upload time?
  4516.     OR    A
  4517.     RET    Z        ; No, skip this
  4518.     LD    A,B        ; Else get time on system back
  4519.     SUB    C        ; Subtract upload time
  4520.     LD    (HL),A        ; Store it
  4521.     RET    
  4522.  
  4523. ADDTN2:    LD    A,B
  4524.     INC    A        ; Bump it one
  4525.     ADD    A,C        ; Add transfer time
  4526.     LD    (HL),A        ; Put it back for BYE
  4527.     RET
  4528.  
  4529. ;
  4530. ;-------------------------------------------------------------------------;
  4531. ; A v a i l a b l e   U p l o a d   S p a c e                  |
  4532. ;-------------------------------------------------------------------------;
  4533. ;
  4534. ; This routine is called with the 'F' option from both CP/M (with 'ZMD F')
  4535. ; or from The HELP Guide routines.  First determine where uploads are
  4536. ; suppose to go.
  4537. ;
  4538. SPACE:    CALL    RSTLCK        ; Go reset WRTLOC if needed
  4539.     CALL    WHLCHK        ; WHEEL byte set?
  4540.     JR    NZ,SPACE1    ; Yes, give space for current drive/user
  4541.     LD    A,(ASKAREA)
  4542.     OR    A
  4543.     JR    NZ,SPACE2
  4544.     LD    A,(SETAREA)
  4545.     OR    A
  4546.     JR    NZ,SPACE2    ; Yes
  4547.  
  4548. SPACE1:    LD    A,(OLDDRV)    ; Get currently logged drive
  4549.     ADD    A,'A'        ; Make it ASCII
  4550.     LD    (DRV),A
  4551.     LD    (KDRV),A    ; Store it for KSHOW
  4552.     LD    A,(OLDUSR)    ; Get currently logged user
  4553.     LD    (USR),A        ; Store it for KSHOW
  4554.  
  4555. SPACE2:    CALL    WHLCHK
  4556.     CALL    Z,GETKIND    ; Get upload area if ASKAREA
  4557.     CALL    ILPRTB
  4558.     DB    CR
  4559.     DB    '  Regular ',0
  4560.     CALL    SPACE8
  4561.     CALL    ILPRTB
  4562.     DB    CR,LF
  4563.     DB    '  Private ',0
  4564.     LD    A,1
  4565.     LD    (PRVSPC),A
  4566.     CALL    SPACE8
  4567.     JP    EXIT        ; Exit to CP/M
  4568.  
  4569. ;
  4570. ; Displays the file descriptor/category when showing available upload space.
  4571. ;
  4572. SPACE8:    CALL    WHLCHK
  4573.     CALL    Z,SHOCAT    ; Show upload area descriptor, if supposed to
  4574.     CALL    ILPRTB
  4575.     DB    'uploads received on ',0
  4576.     LD    A,(PRVSPC)    ; Want private area space?
  4577.     OR    A
  4578.     JR    NZ,SPACE9    ; Yes, do private stuff
  4579.     LD    A,(DRV)        ; Get drive to receive regular upload
  4580.     LD    (KDRV),A    ; Store it for KSHOW
  4581.     CALL    TYPE        ; Output to modem
  4582.     LD    A,(USR)        ; Get user area to receive regular upload
  4583.     JR    SPACE10        ; Go show free space
  4584.  
  4585. SPACE9:    LD    A,(PRDRV)    ; Get drive to receive private upload
  4586.     LD    (KDRV),A    ; Store it for KSHOW
  4587.     CALL    TYPE        ; Output to modem
  4588.     LD    A,(PRUSR)    ; Get user area to receive private upload
  4589.  
  4590. SPACE10:LD    H,0
  4591.     LD    L,A        ; User area in L
  4592.     CALL    DECOUT        ; Decimal output
  4593.     CALL    ILPRTB
  4594.     DB    ':',0
  4595.     LD    A,(PRVSPC)    ; Getting private info?
  4596.     OR    A
  4597.     JR    Z,SPACE11    ; No
  4598.     LD    A,(DRV)        ; Else get regular drive
  4599.     LD    HL,PRDRV    ; Point to private drive
  4600.     CP    (HL)        ; Private same as regular drive?
  4601.     RET    Z        ; Yes, don't report 'k' this time
  4602.  
  4603. SPACE11:CALL    ILPRTB
  4604.     DB    '   (',0
  4605.     LD    A,(KDRV)    ; Get upload drive
  4606.     CALL    KSHOW        ; Show available space for drive
  4607.     CALL    ILPRTB
  4608.     DB    ')',0
  4609.     RET
  4610.  
  4611. ;
  4612. ;-------------------------------------------------------------------------;
  4613. ; R u n t i m e   H e l p   G u i d e                      |
  4614. ;-------------------------------------------------------------------------;
  4615. ;
  4616. ; Either 'ZMD' was entered by itself from CP/M, or an invalid option
  4617. ; given.
  4618. ;
  4619. HELP:    CALL    ILPRTB
  4620.     DB    CR,LF,'                 mode   drive/user'
  4621.     DB    CR,LF,'                /      /'
  4622.     DB    CR,LF,'Usage:  ZMD    SK   {du:}   <fn>'
  4623.     DB    CR,LF,'               /             /'
  4624.     DB    CR,LF,'       protocol      filename'
  4625.     DB    CR,LF
  4626.     DB    CR,LF,'Mode:                             Protocol:'
  4627.     DB    CR,LF,'  S  - Send file from BBS           '
  4628.     DB    'X  - Xmodem 128 byte blocks  (CRC)'
  4629.     DB    CR,LF,'  SP - Send from private area       '
  4630.     DB    'C  - Xmodem 128 byte blocks  (Checksum)'
  4631.       DB    CR,LF,'  A  - Send ARK/ARC/LBR member      '
  4632.     DB    'K  - Ymodem 1024 byte blocks (CRC only)'
  4633.     DB    CR,LF,'  R  - Receive file from YOU'
  4634.       DB    CR,LF,'  RP - Receive in private area',0
  4635.  
  4636.  
  4637.     CALL    ILPRTB
  4638.     DB    CR,LF,0
  4639.     LD    A,(MSGFIL)
  4640.     OR    A
  4641.     JR    Z,HELP1 
  4642.       CALL    ILPRTB
  4643.     DB    '  RM - Receive preformatted message base upload',0
  4644.  
  4645. HELP1:    CALL    ILPRTB
  4646.     DB    CR,LF,0
  4647.     CALL    WHLCHK
  4648.     JR    Z,HELP2
  4649.     CALL    ILPRTB
  4650.     DB    '  RW - Receive without description(s)',0
  4651.  
  4652. HELP2:    CALL    ILPRTB
  4653.     DB    CR,LF,'  F  - Displays available upload space'
  4654.     DB    CR,LF
  4655.     DB    CR,LF
  4656.     DB    CR,LF
  4657.     DB    '--SPACE BAR displays specific examples--',0
  4658.  
  4659.     CALL    INPUT
  4660.     CP    ' '
  4661.     JP    NZ,EXIT
  4662.  
  4663.     LD    HL,ZMDNAM
  4664.     CALL    PRINTV
  4665.     CALL    ILPRTB
  4666.     DB    'Usage examples:'
  4667.     DB    CR,LF
  4668.     DB    CR,LF,' ZMD S   filename.ext         '
  4669.     DB    'Send single file        (Automatic detect)'
  4670.     DB    CR,LF,' ZMD S   B4:filename.ext      '
  4671.     DB    'Send single file        (Automatic detect)'
  4672.      DB    CR,LF,' ZMD SK  filename.ext         '
  4673.     DB    'Send single file        (Ymodem 1k)'
  4674.      DB    CR,LF,' ZMD S   filename.*           '
  4675.     DB    'Send from current d/u   (Ymodem 1k Batch)'
  4676.      DB    CR,LF,' ZMD S   D1:*.*  B9:*.doc     '
  4677.     DB    'Send from multiple d/u  (Ymodem 1k Batch)'
  4678.     DB    CR,LF,' ZMD A   librnam lbrmber.ext  '
  4679.     DB    'Send ARK/ARC/LBR member (Automatic detect)'
  4680.      DB    CR,LF,' ZMD AK  librnam lbrmber.ext  '
  4681.     DB    'Send ARK/ARC/LBR member (Ymodem 1k)'
  4682.     DB    CR,LF
  4683.     DB    CR,LF,' ZMD R   filename.ext         '
  4684.     DB    'Receive single file     (Automatic detect)'
  4685.      DB    CR,LF,' ZMD R                        '
  4686.     DB    'Receive multiple files  (Ymodem 1k Batch)'
  4687.      DB    CR,LF,' ZMD RPC filename.ext         '
  4688.     DB    'Receive to private area (Checksum)'
  4689.     DB    CR,LF,LF
  4690.      DB    'Protocol may be omitted for automatic protocol detection.'
  4691.      DB    CR,LF
  4692.     DB    'Ymodem 1k Batch is enabled upon detection of wildcards or'
  4693.     DB    ' multiple'
  4694.     DB    CR,LF
  4695.         DB    '   filenames on command line (can also be forced with'
  4696.     DB    ' ''SB'' mode).',0
  4697.     JP    EXIT 
  4698.  
  4699.  
  4700. ABRTMSG:CALL    ILPRTB
  4701.     DB    CR
  4702.     DB    '-- ZMD Aborted',0
  4703.     RET
  4704.  
  4705. NOACC:    CALL    SENDBEL        ; Send a bell out modem only
  4706.     CALL    ERXIT
  4707.     DB    CR,LF
  4708.     DB    '-- Restricted Function - Access Denied','$'
  4709.  
  4710. ZEROLN:    CALL    ERXIT
  4711.     DB    CR,LF
  4712.     DB    '-- File empty - ZMD aborted','$'
  4713.  
  4714. NOFILE:    CALL    ERXIT
  4715.     DB    CR
  4716.     DB    '-- No matching filename(s) found','$'
  4717.  
  4718. NOIO:    XOR    A
  4719.     LD    (RTC),A
  4720.     LD    (TIMEON),A
  4721.     LD    (DSPTOS),A
  4722.     LD    (CLOCK),A
  4723.     CALL    ERXIT
  4724.     DB    BELL
  4725.     DB    '-- Modem I/O unavailable - Aborting','$'
  4726.  
  4727. TOOSLOW:CALL    ERXIT
  4728.     DB    CR,LF,LF
  4729.     DB    '-- YMODEM 1k/BATCH not valid - Modem speed too slow','$'
  4730.  
  4731.  
  4732. TOTMSG:    CALL    ILPRTL
  4733.     DB    ' - Timeout, no character received',CR,LF,0
  4734.     RET
  4735.  
  4736. DLRDY:    CALL    ILPRT
  4737.     DB    CR,LF
  4738.     DB    'Your file(s) now ready to download',0
  4739.     CALL    CONT6
  4740.     RET
  4741.  
  4742. WAITMSG:CALL    ILPRTL
  4743.     DB    ' -- Waiting --'
  4744.     DB    CR,0
  4745.     RET
  4746.  
  4747. ;
  4748. ;-------------------------------
  4749. ; File type restriction storage
  4750. ;-------------------------------
  4751. ;
  4752. ; Don't allow ___                (If ZCPR is YES)
  4753. ;         \
  4754. SYSCHK:    DB    'SYS'
  4755. NDRCHK:    DB    'NDR'
  4756. RCPCHK:    DB    'RCP'
  4757.  
  4758. ;
  4759. ; If receiving __     change it to __       (If NOCOMR is YES)
  4760. ;         \             \
  4761. COMCHG:    DB    'COM',            'OBJ'
  4762. PRLCHG:    DB    'PRL',            'OBP'
  4763.  
  4764. ;
  4765. ; If the library extraction flag (LBRARC) is set and an unsuccessful open with
  4766. ; the default filetype occurs, the following file types are copied to FCB+9
  4767. ; and the open attempt is repeated.
  4768. ; 
  4769. ARCNAM:    DB    'ARC'        ; Copied to FCB+9
  4770. LBRNAM:    DB    'LBR'        ; Copied to FCB+9
  4771. ARKNAM:    DB    'ARK'        ; Copied to FCB+9
  4772.  
  4773. ;
  4774. ;---------------------
  4775. ; LOGCALL allocations
  4776. ;---------------------
  4777. ;
  4778. DEFDSK:    DB    0        ; Disk for open stored here
  4779. DEFUSR:    DB    0        ; User for open stored here
  4780. CLRPTR:    DW    LOGBUF
  4781. LOGPTR:    DW    DBUF
  4782. LOGCNT:    DB    0
  4783. LOGK:    DB    'k '
  4784. DUSAVE:    DB    0,0,0,0        ; Buffer for drive/user
  4785.  
  4786. ;
  4787. ;------------------
  4788. ; Time allocations
  4789. ;------------------
  4790. ;
  4791. MAXTOS:    DB    0        ; Maximum time left on system
  4792. RTCBUF:    DW    0        ; RTCBUF address
  4793. TLOS:    DB    0        ; Current time left on system
  4794. TON:    DB    0        ; Current time on system
  4795.  
  4796. ;
  4797. XTABLE:    DW    5,   13,  19,  25,  30,  48,  85, 141, 210, 280,   0
  4798. KTABLE:    DW    5,   14,  21,  27,  32,  53, 101, 190, 330, 525,   0
  4799. XECTBL:    DB    192, 74,  51,  38,  32,  20,  11,   8,   5,   3,   0
  4800. KECTBL:    DB    192, 69,  46,  36,  30,  18,  10,   5,   3,   2,   0
  4801.  
  4802. ;
  4803. ;--------------------
  4804. ; Batch mode storage
  4805. ;--------------------
  4806. ;
  4807. BGNMS:    DW    0        ; Start address of filenames in TBUFF
  4808. LIST:    DW    DBUF        ; Filename storage in send batch mode
  4809. LISTPOS:DW    0        ; Next position to store matching filename
  4810. LISTEND:DW    0        ; Address of last matching filename
  4811. LISTI:    DW    0        ; Pointer 1 for two-dimensional bubble sort
  4812. LISTJ:    DW    0        ; Pointer 2 for two-dimensional bubble sort
  4813. FILEK:    DW    0        ; Total kilobytes  of files found (send batch)
  4814. FCBBUF:    DS    21        ; Batch filename from command line
  4815. FSTFLG:    DB    0        ; Set to 1 when command line scan done
  4816. NAMECT:    DB    0        ; # of names on command line
  4817. NBSAVE:    DW    0        ; Start address in NAMBUF for next file
  4818. SBSHOW:    DB    0        ; Set shows partial stat display in batch
  4819. SHOCNT:    DB    0        ; Counter to show files left
  4820. TOTREC:    DW    0        ; Total records to be sent
  4821.  
  4822. ;
  4823. ;------------------------
  4824. ; Temporary storage area
  4825. ;------------------------
  4826. ;
  4827. ACKCHK:    DB    0        ; Lets batch header user GTACK routine
  4828. AFBYTE:    DB    0        ; Access flags byte storage
  4829. CHKEOT:    DB    0        ; Prevents locking up after an EOT
  4830. COMMA:    DB    0        ; Field counter for logcal
  4831. CRCFLG:    DB    1        ; For sending checksum rather than CRC
  4832. EOFLG:    DB    0        ; EOF (End of file) flag
  4833. EOTFLG:    DB    0        ; EOT (End of transmission) status flag
  4834. ERRCNT:    DB    0        ; Error count
  4835. FRSTIM:    DB    0        ; Turned on after first 'SOH' received
  4836. GOTONE:    DB    0        ; Prevents asking for a description
  4837. KFLG:    DB    1        ; For sending 1k blocks (Defaults to 1k)
  4838. PRVSPC:    DB    0        ; Shows in private display in SPACE: if set
  4839. RCVCNT:    DB    0        ; Record number received
  4840. RCVTRY:    DB    0        ; Keeps track of number of attempts
  4841. RCVDRV:    DB    0        ; Requested drive number
  4842. RCVUSR:    DB    0        ; Requested user number
  4843.  
  4844. ACCERR:    DW    0        ; No 'ACK' error count for 1k ratio
  4845. HDRADR:    DW    0        ; Current location in batch header block
  4846. RCNT:    DW    0        ; Record count
  4847. RECDNO:    DW    0        ; Current record number
  4848. RCDCNT:    DW    0        ; Used in sending the record header
  4849. RECPTR:    DW    DBUF
  4850. RECNBF:    DW    0        ; Number of records in the buffer
  4851. SAVEHL:    DW    0        ; Saves TBUF command line address
  4852. XFRMIN:    DW    0        ; Transfer time in mins for TIMEON
  4853.  
  4854. ;
  4855.     END            ; 'Almost'...
  4856.