home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / RCPM / LUX80.ARK / LUXCHK10.MAC < prev    next >
Text File  |  1987-02-02  |  7KB  |  314 lines
  1. ;    LUXCHK10.MAC  V1.0   LUX utility CHEK transient        1/25/84 mah
  2. ;
  3. ;    This program is based on Sigi Kluger's LCHEK11, and is not intended
  4. ;    to be a replacement or improvement upon it's antecedent.  It has
  5. ;    modified only to dovetail with the LUX format.  This transient
  6. ;    generates a CRC value that is compatible with CHEK.
  7. ;
  8. ;    Modification history in reverse order:
  9. ;
  10. ; 01-25-84    Reformatted messages for LUX.  Renamed to LUXCHKxx to
  11. ; LUXCHK10    mimic other LUX transients.  - Mark Howard
  12. ;
  13. ; 01-24-84    Rewritten for M80/L80.  Fixed bug in DU: routine. - S. Kluger
  14. ; LCHEK11
  15. ;
  16. ; 01-07-84    Initially written by Sigi Kluger - SYSOP El Paso RCP/M
  17. ; LCHEK10                         915-598-1668
  18. ; 
  19.     EXTRN    COUT    ;SYSLIB character out (convert ctl chars)
  20.     EXTRN    CIN    ;SYSLIB character in
  21.     EXTRN    CRLF    ;SYSLIB newline
  22.     EXTRN    F$OPEN    ;SYSLIB open file
  23.     EXTRN    F$READ    ;SYSLIB file read
  24.     EXTRN    BDOS    ;SYSLIB BDOS call
  25.     EXTRN    FNAME    ;SYSLIB file name parser
  26.     EXTRN    PHL4HC    ;SYSLIB print HL in hex
  27.     EXTRN    PUTUD    ;SYSLIB save current DU
  28.     EXTRN    GETUD    ;SYSLIB restore default DU
  29.     EXTRN    LOGUD    ;SYSLIB log drive/user
  30.     EXTRN    PRINT    ;SYSLIB print routine
  31.     EXTRN    RETUD    ;SYSLIB return drive/user
  32.     EXTRN    CRCCLR    ;SYSLIB clear crc acc
  33.     EXTRN    CRCUPD    ;SYSLIB update CRC
  34.     EXTRN    CRCDONE ;SYSLIB finish CRC
  35. ;
  36. cr    equ    0dh
  37. lf    equ    0ah
  38. ;
  39. dbuf    equ    80h    ;default buffer
  40. dfcb    equ    5ch    ;default fcb
  41. ;
  42. begin:    jmp    skipc        ;skip config parameters
  43. ;
  44. maxdrv:    db    1+'P'-40H    ;highest accessible drive + 1 (A=2)
  45. maxusr:    db    1+15        ;highest accessible user + 1
  46. ;
  47. skipc:    lxi    h,0        ;save CP/M stack pointer
  48.     dad    sp
  49.     shld    stack
  50.     lxi    sp,stack    ;set up local stack
  51.     call    putud        ;save default DU
  52.     lda    dfcb+1        ;check if no file name specified
  53.     cpi    ' '
  54.     jz    what        ;give help if no argument
  55.     call    retud        ;get current drive/user
  56.     mov    h,b
  57.     mov    l,c
  58.     shld    userno        ;save current DU
  59.     lxi    h,dbuf+2    ;point to argument
  60.     lxi    d,fcb        ;hopefully .lbr file
  61.     call    fname        ;parse file name
  62.     jz    what        ;not a valid file name
  63.     mov    a,m        ;get delimiter
  64.     cpi    ' '        ;more to come
  65.     jnz    nomem        ;nope, complain
  66.     inx    h        ;get next char
  67.     lxi    d,memfcb    ;point to member fcb
  68.     push    b        ;save drive/user
  69.     call    fname        ;parse member name
  70.     lxi    h,fcb+1
  71.     call    ckamb        ;check ambiguity
  72.     lxi    h,memfcb+1
  73.     call    ckamb
  74.     pop    b        ;get drive/user back
  75.     inx    b        ;check if current DU:
  76.     mov    a,b
  77.     ora    c
  78.     dcx    b        ;restore DU: value
  79.     jz    currdu        ;skip this if current
  80.     mov    a,b        ;get specified drive
  81.     dcr    b        ;get into range 0..f
  82.     cpi    0ffh        ;ff means current drive
  83.     lxi    h,maxdrv
  84.     jnz    newdsk        ;skip if different
  85.     lda    driveno
  86.     mov    b,a
  87.     jmp    curdsk
  88. ;
  89. newdsk:    cmp    m
  90.     jnc    illdu        ;yes - complain
  91. curdsk:    mov    a,c        ;get specified user area
  92.     cpi    '?'        ;all user areas???
  93.     jz    illdu        ;yes - complain
  94.     cpi    0ffh        ;current user area?
  95.     jnz    newusr
  96.     lda    userno
  97.     mov    c,a
  98.     jmp    curusr
  99. ;
  100. newusr:    inx    h        ;illegal user specified?
  101.     cmp    m
  102.     jnc    illdu        ;yes - complain
  103. curusr:    call    logud        ;log into specified DU:
  104. currdu:    lxi    h,FCB+9        ;default to .LBR
  105.     mvi    m,'L'
  106.     inx    h
  107.     mvi    m,'B'
  108.     inx    h
  109.     mvi    m,'R'
  110.     lxi    d,fcb
  111.     call    f$open        ;attempt to open file
  112.     inr    a
  113.     jz    nofile        ;barf if not found
  114.     call    f$read        ;read directory into default buffer
  115.     lxi    h,dbuf        ;point to dbuf
  116.     lxi    d,dirname    ;point to 8 blanks
  117.     call    cpfn        ;compare
  118.     jnz    nolbr        ;not equal
  119.     lxi    d,14
  120.     dad    d
  121.     mov    a,m
  122.     sta    dirsiz        ;directory size
  123.     xra    a
  124.     sta    memfcb
  125.     jmp    c00        ;skip into directory check
  126. ;
  127. dirlp:    lxi    d,fcb
  128.     call    f$read
  129. c00:    lxi    b,20h
  130.     lxi    h,dbuf
  131.     lxi    d,memfcb
  132.     call    cpfn
  133.     jz    found
  134.     dad    b
  135.     call    cpfn
  136.     jz    found
  137.     dad    b
  138.     call    cpfn
  139.     jz    found
  140.     dad    b
  141.     call    cpfn
  142.     jz    found
  143.     lda    dirs
  144.     inr    a
  145.     sta    dirs
  146.     mov    b,a
  147.     lda    dirsiz
  148.     cmp    b
  149.     jnz    dirlp
  150.     call    print
  151.     db    cr,lf
  152.     db    'File not found.',cr,lf,0
  153.     jmp    quit
  154. ;
  155. ; Found the member file name in the LDIR
  156. ;
  157. found:    lxi    d,12
  158.     dad    d
  159.     push    h        ;save pointer for now,
  160.     inx    h        ;point to size
  161.     inx    h
  162.     push    d
  163.     mov    e,m        ;get low byte
  164.     inx    h
  165.     mov    d,m        ;if a=0 then file is 0k
  166.     xchg
  167.     shld    msize        ;save member size
  168.     pop    d
  169.     mov    a,h
  170.     ora    l
  171.     jz    nullen        ;go complain
  172.     pop    h        ;get pointer back
  173.     mov    a,m        ;get file address
  174.     inx    h
  175.     mov    h,m
  176.     mov    l,a
  177.     shld    fcb+33
  178.     lxi    d,fcb
  179.     call    rndread        ;read first buffer full
  180.     call    crcclr        ;now clear the crc accumulator
  181.     call    print
  182.     db    cr,lf,'CRC value for ',0
  183.     lxi    h,memfcb+1
  184.     mvi    b,8
  185. fnlp:    mov    a,m
  186.     call    cout
  187.     inx    h
  188.     dcr    b
  189.     jnz    fnlp
  190.     mvi    a,'.'
  191.     call    cout
  192.     mvi    b,3
  193. ftlp:    mov    a,m
  194.     call    cout
  195.     inx    h
  196.     dcr    b
  197.     jnz    ftlp
  198.     call    print
  199.     db    '  =  ',0
  200. slp:    call    f$read        ;else read next sector (de still FCB)
  201.     call    ccrc        ;compute crc for sector
  202.     lhld    msize
  203.     dcx    h
  204.     shld    msize
  205.     mov    a,h
  206.     ora    l
  207.     jnz    slp
  208. ;
  209. ; all sectors have been read and computed
  210. ;
  211.     call    crcdone        ;finish up, return crc
  212.     call    phl4hc        ;print hl in hex
  213.     call    crlf
  214.     jmp    quit
  215. ;
  216. ; compute crc for sector
  217. ;
  218. ccrc:    lxi    h,dbuf
  219. ccrc1:    mov    a,m
  220.     call    crcupd
  221.     inr    l
  222.     jnz    ccrc1
  223.     ret
  224. ;
  225. ; Read random record, save all regs
  226. ;
  227. rndread:push    psw
  228.     push    b
  229.     push    d
  230.     push    h
  231.     mvi    c,33
  232.     call    bdos
  233.     pop    h
  234.     pop    d
  235.     pop    b
  236.     pop    psw
  237.     ret
  238. ;
  239. ; Here are the messages
  240. ;
  241. illdu:    call    print
  242.     db    cr,lf
  243.     db    'Drive/user out of bounds',cr,lf,0
  244.     jmp    what
  245. ;
  246. nofile:    call    print
  247.     db    cr,lf
  248.     db    'No such file on disk',cr,lf,0
  249.     jmp    what
  250. ;
  251. cpfn:    push    h
  252.     push    d
  253.     push    b
  254.     mvi    b,12    ;12 characters
  255. clpcp:    ldax    d
  256.     cmp    m    ;check file name
  257.     jnz    qcpfn    ;no match - quit
  258.     inx    d
  259.     inx    h
  260.     dcr    b
  261.     jnz    clpcp
  262. qcpfn:    pop    b
  263.     pop    d
  264.     pop    h
  265.     ret
  266. ;
  267. ckamb:    mvi    a,'?'        ;see if there is any...
  268.     mvi    e,11        ;...ambiguity in the file spec
  269. ckamlp:    cmp    m
  270.     jz    noamb        ;complain if ambiguous fn
  271.     inx    h
  272.     dcr    e
  273.     jnz    ckamlp
  274.     ret
  275. ;
  276. nolbr:    call    print
  277.     db    cr,lf
  278.     db    'LBR directory may be damaged - aborting',cr,lf,0
  279.     jmp    quit
  280. ;
  281. nomem:    call    print
  282.     db    cr,lf
  283.     db    'No member file name specified.',cr,lf,0
  284.     jmp    what
  285. ;
  286. nullen:    call    print
  287.     db    cr,lf
  288.     db    'Member file is 0k - CRC is 00 00.',cr,lf,0
  289.     jmp    quit
  290. ;
  291. noamb:    call    print
  292.     db    cr,lf
  293.     db    'No ambiguous file names allowed.',cr,lf,0
  294. what:    call    print
  295.     db    cr,lf
  296.     db    'CHEK - check CRC of member file in a LBR',cr,lf
  297.     db    'USAGE: CHEK mbrname.typ',cr,lf,0
  298. quit:    call    getud        ;restore default DU
  299.     lhld    stack
  300.     sphl
  301.     ret
  302. ;
  303. dirs:    db    0        ;# of dir sectors processed
  304. dirsiz:    db    0        ;# of total dir sectors
  305. msize:    dw    0        ;member size in sectors
  306. userno:    db    0        ;current user #
  307. driveno:db    0        ;current drive
  308. fcb:    ds    36        ;out fcb
  309. memfcb:    ds    12
  310.     ds    40        ;20 level stack
  311. stack:    dw    0        ;save CP/M stack pointer here
  312. dirname:db    0,'           '
  313.     end
  314.