home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / PROGRAMS / WSTAR / WSLOAD.LBR / WSLOAD.AQM / WSLOAD.ASM
Assembly Source File  |  2000-06-30  |  13KB  |  625 lines
  1. ; WSLOAD ------------------------ A WordStar Utility
  2. ; 
  3. ; This utility is described fully in WSLOAD.DOC within the library.  
  4. ; The source code here is included in the event that you need to reset 
  5. ; the OFFSET variable to a higher address.  The code below will 
  6. ; assemble correctly with either MicroSoft's M80 or with the fine 
  7. ; public domain assmebler Z80MR.  If you have problems or need special 
  8. ; assistance, I will be glad to do what I can.  Please send a SAS 
  9. ; envelope and/or disk.
  10. ; 
  11. ; Lindsay Haisley
  12. ; 14206 Spreading Oaks
  13. ; Leander, TX  78641
  14. ;
  15. ;
  16. ; ****  THE OFFSET VARIABLE:
  17. ; --------------------------
  18. ;
  19. ; The offset variable below is the address of the end of your current 
  20. ; version of WordStar.  The is usually 4600 hex but if the area beyond 
  21. ; this address is already in use for an initialization routine, you must 
  22. ; find an area of free memory above this routine for WSLOAD to use. 
  23. ;
  24. ; WSLOAD will give you a "MORPAT OVERLAY" error if an init routine 
  25. ; already occupies the area above the current value of the offset.  You 
  26. ; must use DDT, Z8E, ZSID or some similar utility to find a string of 
  27. ; null or unused bytes above the offset address and reset "offset" to 
  28. ; the address of this string.  You may need to load WordStar and SAVE a 
  29. ; page or two more than the usual 70.  Make sure you have 200 bytes of 
  30. ; free space available for WSLOAD to occupy.
  31.  
  32. offset    equ    4600h
  33.     
  34.  
  35. ; -----------------------------------------------------------------------
  36.     
  37. aseg    
  38. .z80    ; IGNORE THIS ERROR WITH Z80MR
  39.  
  40. ; WordStar user patch area equates
  41.     
  42. inisub    equ    0287h
  43. morpat    equ    02CBh
  44. fnwscm    equ    0400h
  45.     
  46. loadpt    equ    1100h        ; Address of WordStar in memory for this prog.
  47.  
  48. loadref    equ    loadpt-100h
  49.     
  50.  
  51. ; CODE STARTS HERE
  52.     
  53.     org    100h
  54.     jp    ustart
  55.  
  56.     
  57. fcb1:    defb    0,20h,20h,20h,20h,20h,20h,20h,20h,20h,20h,20h,0,0,0,0
  58.     defb    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  59. fcb2:    defb    0,20h,20h,20h,20h,20h,20h,20h,20h,20h,20h,20h,0,0,0,0
  60.     defb    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  61. fcb3:    defb    0,20h,20h,20h,20h,20h,20h,20h,20h,20h,20h,20h,0,0,0,0
  62.     defb    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  63.     
  64. cflag:    defb    '+'
  65.     defb    0
  66.     
  67. fnbuf:    defb    0,0,0,0,0,0,0,0,0,0,0,0,0,0
  68. endbuf:    defb    0
  69.  
  70. getmsg:    defb    0dh,0ah,'Enter the filename of your version of WordStar => ',0
  71. outmsg:    defb    0dh,0ah,'Enter the name you want for WordStar with WSLOAD'
  72.     defb    ' installed => ',0
  73. csmsg1: defb    0dh,0ah,'Enter the character you want to preceed overlay '
  74.     defb    'filenames => ',0
  75. csmsg2:    defb    0dh,0ah,0ah,'All configuration overlays (except '
  76.     defb    'the default) must start with '''
  77.     defb    0
  78. csmsg3:    defb    '''',0dh,0ah,0
  79. e1msg:    defb    0dh,0ah,'File ',0
  80. e2msg:    defb    ' not found',0dh,0ah,0    
  81. dnmsg:    defb    0dh,0ah,'Modified WordStar written to disk as ',0
  82. mpemsg:    defb    0dh,0ah,'MORPAT ERROR - Reset patch location',0dh,0ah,0 
  83. cremsg:    defb    0dh,0ah,'Out of directory space.  Can''t create output file.'
  84.     defb    0dh,0ah,0
  85. wremsg:    defb    0dh,0ah,'Disk full. Operation aborted.',0dh,0ah,0
  86. defmsg:    defb    0dh,0ah,'Enter the default configuration filename => ',0
  87. bktxt:    defb    08h,20h,08h,0
  88. nline:    defb    0dh,0ah,0    
  89.  
  90. ; PROGRAM STARTS HERE
  91.  
  92. ustart:    ld    de,getmsg     ; Ask for filename
  93.     call    zprt
  94.     call    getname
  95.     cp    03h
  96.     jp    z,0000
  97.     ld    a,(fnbuf)
  98.     or    a
  99.     ret    z        ; Return to system if none given
  100.     ld    hl,fcb1
  101.     call    xfer    
  102.     ld    c,0fh        ; Now open the file, if possible
  103.     ld    de,fcb1
  104.     call    5
  105.     inc    a
  106.     jr    nz,ffound
  107.     ld    de,e1msg    ; If no find, report and quit
  108.     call    zprt
  109.     ld    de,fcb1
  110.     call    fnshow
  111.     ld    de,e2msg
  112.     call    zprt
  113.     ret            ; No Wordstar, no work !! (I quit!)
  114.     
  115. ffound:    ld    hl,fcb1        ; Save open fcb for output if necessary
  116.     ld    de,fcb3
  117.     ld    bc,24h
  118.     ldir
  119.     
  120.     ld    de,loadpt    ; Read the input file to memory
  121.     call    readfile
  122.     push    hl        ; Save size of file
  123.     
  124.     ld    de,outmsg    ; Get name of output file
  125.     call    zprt
  126.     call    getname
  127.     cp    03h
  128.     jp    z,0000
  129.     ld    hl,fcb2
  130.     call    xfer
  131.     
  132.     ld    de,fcb1        ; Is input same as output
  133.     ld    hl,fcb2
  134.     call    namecmp
  135.     jr    z,same
  136.     
  137.     ld    a,(fcb2+1)    ; Or is no filename specified
  138.     cp    20h
  139.     jr    nz,notsme
  140. same:    ld    hl,fcb3        ; Restore FCB opened for input to output FCB
  141.     ld    de,fcb2
  142.     ld    bc,24h
  143.     ldir
  144.     jr    creok
  145.     
  146.     
  147.     
  148. notsme:    ld    c,13h        ; Erase any file of similar name
  149.     ld    de,fcb2
  150.     call    5
  151.     ld    c,16h        ; Create the file
  152.     ld    de,fcb2
  153.     call    5
  154.     inc    a
  155.     jr    nz,creok    ; If directory full, say so and quit
  156.     pop    de
  157.     ld    de,cremsg
  158.     call    zprt
  159.     ret
  160.     
  161. creok:    ld    de,defmsg     ; Get the default config. filename
  162.     call    zprt
  163.     call    getname
  164.     cp    03h
  165.     jp    z,0000
  166.     ld    hl,dnme
  167.     call    xfer
  168.     
  169. getflg:    ld    de,csmsg1    ; Get the flag character
  170.     call    zprt
  171.     ld    c,01
  172.     call    5
  173.     call    upcase
  174.     cp    0dh
  175.     jr    z,ffdef        ; If none given, use default
  176.     cp    21h        ; Don't accept control characters
  177.     jr    nc,ffok
  178.     call    bell
  179.     jp    getflg
  180.  
  181. ffok:    ld    (cflag),a    ; Tell about the flag
  182. ffdef:    ld    de,csmsg2
  183.     call    zprt
  184.     ld    de,cflag
  185.     call    zprt
  186.     ld    de,csmsg3
  187.     call    zprt
  188.     
  189.     
  190. ; ACTUAL MODS TO WORDSTAR START HERE
  191.     
  192.     ld    a,(inisub+loadref)
  193.     cp    0c3h            ; See if JP instruction in INISUB
  194.     jr    nz,okini
  195.     ld    hl,(inisub+loadref+1)    ; If so, see where it JP's to
  196.     and    a
  197.     ld    de,offset
  198.     sbc    hl,de
  199.     jp    c,morpok
  200.     ld    de,mpemsg
  201.     call    zprt
  202.     pop    de
  203.     ret                ; If inisub too hi, quit
  204.     
  205. okini:    ld    a,0c3h            ; Put a JP in inisub
  206.     ld    (inisub+loadref),a
  207.     ld    a,0c9h        ; RETurn instruction instead of a JP to MORPAT
  208.     ld    (retins),a    ; 
  209.     
  210. morpok:    add    hl,de
  211.     ld    de,offset
  212.     ld    (inisub+loadref+1),de    ; Set up a patch and return situation
  213.     ld    (retad),hl
  214.     
  215.     ld    a,(cflag)    ; Enter the flag character into the overlay
  216.     ld    (f1+1),a
  217.     ld    (f2+1),a
  218.  
  219.     ld    hl,fcb2        ; Save the filename for later use by WordStar
  220.     ld    de,nme
  221.     ld    bc,12
  222.     ldir
  223.     
  224. ; Now move the working code into WordStar image
  225.     
  226.     ld    hl,patstrt
  227.     ld    de,loadref+offset
  228.     ld    bc,patend-patstrt
  229.     ldir
  230.  
  231. ; Now write the image back to a file
  232.     
  233.     ld    de,loadpt
  234.     pop    bc
  235.     call    writfile    ; Write the file
  236.     jr    z,alldn
  237.     ld    de,fcb2
  238.     ld    c,13h
  239.     call    5
  240.     ld    de,wremsg    ; If error, say so
  241.     call    zprt
  242.     ret
  243.     
  244. ; All done, so say so and quit
  245.     
  246. alldn:    ld    de,dnmsg
  247.     call    zprt
  248.     ld    de,fcb2
  249.     call    fnshow
  250.     ld    de,nline
  251.     call    zprt
  252.     ret
  253.         
  254.     
  255. ; ++++++++++++++++++++++++ SUBROUTINES ++++++++++++++++++++++++++
  256.  
  257. getname:    ; Get a valid CP/M filename to fnbuf
  258.     
  259.     xor    a        ; Zero fnbuf
  260.     ld    hl,fnbuf
  261.     ld    de,fnbuf+1
  262.     ld    (hl),a
  263.     ld    bc,11
  264.     ldir
  265.     ld    hl,fnbuf
  266.     
  267. fnloop:    ld    de,06        ; Use BIOS to fetch character
  268.     call    ubios    
  269.     cp    03h
  270.     ret    z
  271.     cp    0dh        ; Check for CR to mark end of string
  272.     jr    nz,morget
  273.     ld    (hl),0
  274.     ld    de,nline    ; If end, go on
  275.     call    zprt
  276.     ret
  277. morget:    call    upcase        ; Convert to Upper case, if approp.
  278.     jr    c,okchar    ; If conversion done, character must be OK
  279.     cp    7fh        ; Is it a DEL
  280.     jr    z,bsordl
  281.     cp    08h        ; Or is it a BS
  282.     jr    nz,notbs
  283. bsordl:    ld    de,fnbuf    ; Ignore if start of buffer
  284.     and    a
  285.     push    hl
  286.     sbc    hl,de
  287.     pop    hl
  288.     jr    z,fnloop    
  289.     dec    hl
  290.     ld    de,bktxt
  291.     push    hl
  292.     call    zprt
  293.     pop    hl
  294.     jr    fnloop
  295.     
  296. notbs:    cp    21h        ; Don't accept other control characters
  297.     jr    c,fnloop
  298.     
  299. okchar:    ld    de,endbuf    ; Check to see if end of buffer reached
  300.     and    a
  301.     push    hl
  302.     sbc    hl,de
  303.     pop    hl
  304.     jr    c,sizok
  305.     call    bell
  306.     jr    fnloop
  307. sizok:    ld    (hl),a        
  308.     inc    hl
  309.     ld    c,a
  310.     ld    de,09h
  311.     call    ubios
  312.     jr    fnloop
  313.     
  314. ; --------------------------------------------------------------
  315. xfer:        ; Transfer filename in FNBUF to (hl) in FCB format
  316.  
  317.     push    hl
  318.     xor    a        ; Clean and prep area to recieve transfer
  319.     ld    (dotflg),a
  320.     ld    (hl),a        ; 0 for disk
  321.     inc    hl
  322.     ld    (hl),20h
  323.     push    hl
  324.     pop    de
  325.     inc    de
  326.     ld    bc,10
  327.     ldir
  328.     
  329.     pop    hl
  330.     ld    de,fnbuf    ; Do disk desig, if there is one
  331.     ld    a,(fnbuf+1)
  332.     cp    ':'
  333.     jr    nz,nodisk
  334.     ld    a,(de)
  335.     sub    40h
  336.     ld    (hl),a
  337.     inc    de
  338.     inc    de
  339. nodisk:    inc    hl
  340.     ld    b,8
  341. xlup:    ld    a,(de)        ; Then copy characters
  342.     or    a
  343.     ret    z
  344.     cp    '.'        ; Check for a dot
  345.     jr    nz,nodot
  346.     ld    a,(dotflg)    ; Make sure only one dot
  347.     or    a
  348.     ret    nz
  349.     dec    a
  350.     ld    (dotflg),a
  351.     inc    de
  352.     ld    c,b        ; Set to copy extent, if any
  353.     ld    b,0
  354.     add    hl,bc
  355.     ld    b,3
  356.  
  357. nodot:    ld    a,b
  358.     or    a
  359.     jr    z,lulu
  360.     ld    a,(de)
  361.     ld    (hl),a
  362.     dec    b
  363.     inc    hl
  364. lulu:    inc    de
  365.     jr    xlup
  366.     
  367. dotflg:    defb    00        ; Flag to prevent multiple dots in name
  368.     
  369. ; ---------------------------------------------------------------
  370. readfile:    ; Load file spec in FCB1 to mem starting at (de)
  371.         ; Return number of sectors loaded in hl
  372.     
  373.     ld    bc,00
  374.  
  375. rloop:    push    de
  376.     push    bc        ; Save sector counter
  377.     ld    c,1ah
  378.     call    5        ; Set DMA as per reg de
  379.     ld    c,14h
  380.     ld    de,fcb1
  381.     call    5        ; Read a Sector
  382.     pop    bc
  383.     pop    de
  384.     or    a
  385.     jr    nz,lfdone
  386.     
  387.     ld    hl,80h        ; Bump the DMA pointer
  388.     add    hl,de        
  389.     ex    de,hl
  390.     
  391.     inc    bc        ; Bump the sector counter
  392.     jr    rloop        ; Go back for more
  393.     
  394. lfdone:    ld    h,b        
  395.     ld    l,c    
  396.     ret
  397.     
  398. ; --------------------------------------------------------------------
  399. writfile:    ; Writes (bc) sectors from memory, starting at (de) to
  400.         ; the file spec in FCB2.  Closes the file when done.
  401.     
  402.     ld    a,c
  403.     or    b
  404.     jr    z,wfdone    ; Check up on the sector count
  405.     push    de
  406.     push    bc        ; Set the DMA
  407.     ld    c,1ah
  408.     call    5
  409.     ld    c,15h        ; Write a record
  410.     ld    de,fcb2
  411.     call    5
  412.     pop    bc
  413.     pop    de
  414.     and    a
  415.     ret    nz
  416.     
  417.     ld    hl,80h        ; Bump the DMA pointer
  418.     add    hl,de        
  419.     ex    de,hl
  420.  
  421.     dec    bc
  422.     jr    writfile    
  423.     
  424. wfdone:    ld    c,10h        ; Close the file
  425.     ld    de,fcb2
  426.     call    5
  427.     xor    a
  428.     ret
  429.     
  430. ; --------------------------------------------------------------------
  431. namecmp:    ; Compares two names in FCB (12) bytes.  Returns zflg 
  432.         ; according to results of compare
  433.     
  434.     ld    b,12
  435. cmplup:    ld    a,(de)
  436.     cp    (hl)
  437.     ret    nz
  438.     inc    de
  439.     inc    hl
  440.     dec    b
  441.     jr    nz,cmplup
  442.     ret
  443.     
  444.     
  445. ; --------------------------------------------------------------------
  446. ubios:    push    hl        ; Use a BIOS direct call.  Save hl reg.
  447.     ld    hl,(001)    ; de contains offset from BIOS start
  448.     add    hl,de
  449.     ld    (bi1),hl
  450. bi1    equ    $+1
  451.     call    0000        ; Self mod code
  452.     pop    hl
  453.     ret
  454.     
  455. ; ---------------------------------------------------------------------
  456. zprt:    ld    a,(de)        ; print null term string
  457.     or    a
  458.     ret    z
  459.     push    de
  460.     ld    c,2
  461.     ld    e,a
  462.     call    5
  463.     pop    de
  464.     inc    de
  465.     jr    zprt
  466.  
  467. ; ---------------------------------------------------------------------
  468. fnshow:        ; Show a file name in *.* format from FCB format (in de)
  469.  
  470.     ex    de,hl
  471.     ld    a,(hl)
  472.     cp    0
  473.     jp    z,nfndsk
  474.     add    a,40h
  475.     push    hl
  476.     ld    e,a
  477.     ld    c,2
  478.     call    5
  479.     ld    e,':'
  480.     ld    c,2
  481.     call    5
  482.     pop    hl
  483. nfndsk:    inc    hl
  484.     ld    b,8
  485.     call    nfnlup
  486. doext:    ld    c,b
  487.     ld    b,0
  488.     add    hl,bc
  489.     ld    a,(hl)
  490.     cp    20h
  491.     ret    z
  492.     ld    e,'.'
  493.     ld    c,2
  494.     push    hl
  495.     call    5
  496.     pop    hl
  497.     ld    b,3
  498.     call    nfnlup
  499.     ret
  500.     
  501. nfnlup:    ld    e,(hl)
  502.     ld    a,20h
  503.     cp    e
  504.     ret    z
  505.     push    bc
  506.     push    hl
  507.     ld    c,2
  508.     call    5
  509.     pop    hl
  510.     pop    bc
  511.     inc    hl
  512.     dec    b
  513.     jr    nz,nfnlup
  514.     ret    
  515.     
  516. ; ---------------------------------------------------------------------
  517. upcase:    cp    61h        ; Convert to upper case
  518.     jr    c,notlo
  519.     cp    7bh
  520.     ret    nc
  521.     and    01011111b    ; If it is, uppercase it
  522.     and    a
  523. notlo:    ccf
  524.     ret
  525.  
  526. ; ---------------------------------------------------------------------
  527. bell:    push    hl        ; Ring the bell !!
  528.     ld    c,02
  529.     ld    e,07
  530.     call    5
  531.     pop    hl
  532.     ret
  533.     
  534. ; ----------------------------------------------------
  535. ; THE FOLLOWING IS THE PATCH TO THE END OF WORDSTAR
  536. ; ----------------------------------------------------    
  537.     
  538. patstrt    equ    $
  539.     ld    hl,05dh            ; find an argument, if any
  540.     ld    a,(hl)
  541. f1:    cp    0
  542.     jr    z,isarg-offset+patstrt
  543.     ld    hl,06dh
  544.     ld    a,(hl)
  545. f2:    cp    0
  546.     jr    z,isarg-offset+patstrt
  547.     jr    godef-offset+patstrt    ; if none, try for the default fnme
  548.     
  549. isarg    equ    $+offset-patstrt
  550.     dec    hl
  551.     push    hl
  552.     ld    de,fcb            ; move the filename to the fcb
  553.     ld    bc,12
  554.     ldir
  555.     pop    de
  556.     ld    a,e
  557.     cp    05ch            ; If first arg, substitute second arg
  558.     jr    nz,nomove-offset+patstrt
  559.     ld    hl,06ch
  560.     ld    bc,12
  561.     ldir
  562.     
  563. nomove    equ    $+offset-patstrt
  564.     call    open            ; open the file
  565.     jr    nz,pgodef-offset+patstrt
  566. godef    equ    $+offset-patstrt    ; If not found, try the default fnme
  567.     ld    hl,defnme
  568.     ld    de,fcb
  569.     ld    bc,12
  570.     ldir
  571.     call    open
  572.     jr    z,jrret-offset+patstrt    ; Can't find anything, so just do WS
  573.     
  574. pgodef    equ    $+offset-patstrt
  575.     ld    de,80h            ; Get set to loop
  576.     push    de
  577.  
  578. lloop     equ    $+offset-patstrt
  579.     pop    hl
  580.     ld    de,80h
  581.     add    hl,de        
  582.     ex    de,hl
  583.     push    de
  584.     ld    c,1ah
  585.     call    5        ; Advance DMA by 80h bytes
  586.     ld    c,14h
  587.     ld    de,fcb  
  588.     call    5        ; Read a Sector
  589.     or    a
  590.     jr    z,lloop-offset+patstrt    ; Until no more to read
  591.     pop    de
  592.     ld    de,80h        ; Restore DMA
  593.     ld    c,1ah
  594.     call    5
  595.     
  596.     ld    de,fnwscm    ; Move the filename into WordStar
  597.     ld    hl,wsname
  598.     ld    bc,12
  599.     ldir
  600.  
  601. retins    equ    $
  602. jrret    equ    $+offset-patstrt
  603.     jp    0000
  604. retad    equ    $-2
  605.  
  606. open    equ    $+offset-patstrt
  607.     ld    c,0fh
  608.     ld    de,fcb
  609.     call    5
  610.     inc    a
  611.     ret
  612.  
  613.     
  614. fcb    equ    $+offset-patstrt
  615.     defb    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  616.     defb    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  617. wsname    equ    $+offset-patstrt
  618. nme:    defb    0,0,0,0,0,0,0,0,0,0,0,0
  619.     defb    0
  620. defnme    equ    $+offset-patstrt
  621. dnme:    defb    0,'           '
  622.     defb    0
  623. patend    equ    $
  624.     end
  625.