home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / PROGRAMS / CLOCKK / LB-TSTP1.LBR / TMSTP-LB.ZZ0 / TMSTP-LB.Z80
Text File  |  2000-06-30  |  11KB  |  450 lines
  1. Title Time stamp   VERS:- 01.01  DATE:- 01/07/88  TIME:- 18:54:34
  2.  
  3. ;************************************************************
  4. ;*
  5. ;*    File Tracking Program
  6. ;*    by Eric Forbes
  7. ;*    c/o Mississauga, Ont. Canada RCP/M System
  8. ;*     (416) 826-5394
  9. ;*
  10. ;************************************************************
  11. ;Copyright (c) 1982, E. Forbes; permission granted to use,
  12. ;copy and distribute for non-commercial purposes.
  13. ;
  14. ;
  15. ;QUICK VIEW:  Increment version and insert date and time each
  16. ;          time a file is assembled / edited. See top line
  17. ;          of this listing.
  18. ;
  19. ;To use the 'DATE:- ' and 'TIME:- ' functions, this program
  20. ;expects to find three consecutive bytes at MONTH and HOUR,
  21. ;in BCD format. E.G. to print the date 07/31/82, the bytes
  22. ;07H 31H 82H should be available at MONTH, MONTH+1 and MONTH+2.
  23. ;
  24. ;If you do not have a clock ignore the 'month' and 'hour'
  25. ;equates. They are both read only and will only be read if
  26. ;'DATE:- ' or 'TIME:- ' is found in the 1st record of the file
  27. ;
  28. ;See TIMESTMP.DOC for further deatails
  29. ;
  30. ;
  31.       page
  32. ;********************************************************************
  33. ;
  34. ;     DAYDATE code:
  35. ; 
  36. ;       Gets date and time from BIOS software real-time clock,
  37. ;       converts to BCD and places it in a 6-byte string
  38. ;       in format mmddyyhhmmss at location 'month'.
  39. ;
  40. ;       This version is customized for the AMPRO Little Board Z-80
  41. ;       by Larry Sonderling
  42. ;
  43. ;********************************************************************
  44. ;
  45. daydate:    call    getbios       ; get BIOS jump tables into local storage
  46.         call    j2md          ; convert Julian date to month/day
  47. ;
  48.         ld    a,(tmonth)    ; convert each value to BCD
  49.         call    binbcd        ; and store in output string
  50.         ld    (month),a     ; for TIMESTMP to use.
  51. ;    
  52.         ld    a,(tday)
  53.         call    binbcd
  54.         ld    (month+1),a
  55. ;
  56.         ld    a,(year)
  57.         call    binbcd
  58.         ld    (month+2),a
  59. ;
  60.         ld    a,(bhour)
  61.         call    binbcd
  62.         ld    (month+3),a
  63. ;
  64.         ld    a,(bmin)
  65.         call    binbcd
  66.         ld    (month+4),a
  67. ;
  68.         ld    a,(bsec)
  69.         call    binbcd
  70.         ld    (month+5),a
  71. ;
  72.         jp      timestmp      ; jump to main code
  73. ;
  74. ;
  75. month        ds    6     ; output string for TIMESTMP main code
  76. ;
  77. ;********************************************************************
  78. ;
  79. ;    Error exits for uninstalled clock or wrong BIOS version.
  80. ;
  81. ;********************************************************************
  82. ;
  83. ; Time of day TOD jmp was not in bios
  84. ;
  85. NOCLK:    CALL    PRINT0
  86.     DEFB    'Clock not installed',CR,LF,0
  87.     JP    0
  88. ;
  89. ; wrong BIOS version
  90. ;
  91. BADVER:    CALL    PRINT0
  92.     DEFB    'Requires Bios 3.6 or higher.',CR,LF,0
  93.     JP    0     
  94. ;
  95. ;********************************************************************;
  96. ;
  97. GETBIOS:LD      DE,WBOOT    ; build bios entry table
  98.     LD    HL,(1)        ; get bios start
  99.     LD    BC,51        ; bytes to move
  100.     LDIR
  101.     CALL    GETTBL        ; get address of next jmp tbl
  102.     CP    36        ; must be bios ver 3.6 or higher
  103.     JR    C,BADVER    ; give message and exit
  104.     LD    DE,NXTTBL    ; 'hl' has bios nxttbl address
  105.     LD    BC,15        ; 
  106.     LDIR                ; move the table
  107.     LD    HL,0        ; make sure that clock is enabled
  108.     CALL    TOD        ; get clock base address
  109.     LD    A,L        ; see if address of tick was returned
  110.     OR    H
  111.     JR    Z,NOCLK        ; exit if clock not enabled
  112. ;
  113. ; 'HL' has address of clock
  114. ;
  115.     LD    DE,BSEC        ; move time and date to work area
  116.     LD    BC,6
  117.     LDIR
  118.         RET
  119. ;
  120. ;****************************************************************
  121. ;                 convert julian to month/day
  122. ;****************************************************************
  123. ;
  124. J2MD:    LD    DE,MTHS        ; int month pointer
  125.     LD    HL,(JDAY)    ; julian day in 'hl'
  126.     INC    HL        ; adjust for ordinal 0
  127.     XOR    A
  128.     LD    B,A        ; init high byte of sub with 0
  129.     INC    A
  130.     LD    (TMONTH),A    ; init month to 1
  131.  
  132. J2MD1:    LD    A,(DE)
  133.     OR    A        ; clear carry
  134.     LD    C,A
  135.     LD    A,L        ; may be day
  136.     SBC     HL,BC
  137.     JR    C,J2MD2
  138.     JR    Z,J2MD2
  139.     LD    A,(TMONTH)
  140.     INC    A        ; update month
  141.     LD    (TMONTH),A
  142.     INC    DE
  143.     JR    J2MD1
  144.  
  145. J2MD2:    LD    (TDAY),A    ; set day
  146.     RET
  147. ;
  148. ;***************************************************************
  149. ;        convert binary to BCD
  150. ; in:    a  - binary value
  151. ; out:    a  - BCD equivalent
  152. ;***************************************************************
  153. ;
  154. BINBCD:    LD    C,0        ; init count for MSD
  155.     LD    B,10            ; divisor
  156.  
  157. BIN1:    SUB    B               ; divide by 10
  158.     JR    C,BINEXT        ; finished if underflow
  159.     INC    C               ; else incr MSD and
  160.     JR    BIN1            ; loop back for another one
  161.  
  162. BINEXT:    ADD    A,B        ; A = ones digit  C = tens digit
  163.     AND    0FH             ; zero high nibble
  164.     SLA     C               ; shift MSD to high nibble
  165.     SLA     C
  166.     SLA    C
  167.     SLA     C
  168.         OR      C               ; insert MSD
  169.     RET                     ; done
  170. ;
  171. ;     Print a null-terminated string on the console
  172. ;
  173. print0:       pop     hl              ; get address of string
  174.               ld      a,(hl)          ; load the character
  175.               and     a               ; test for null
  176.               jr      z,prnend        ; quit if null
  177.               push    hl              ; else save the pointer
  178.               ld      c,a             ; and print to console
  179.               call    conout
  180.           pop     hl              ; restore pointer
  181.               inc     hl              ; bump to next address
  182.               jr      print0+1        ; go back again
  183.  
  184. prnend:       push    hl              ; at end HL is return address
  185.               ret
  186. ;
  187. ;**************************************************************************
  188. ;
  189. ;     Table of lengths of months
  190. ;
  191. MTHS:    DEFB    31,29,31,30,31,30,31,31,30,31,30,31
  192. ;
  193. ; bios entry table
  194. ;
  195. WBOOT:    DEFS    3        ; Warm start
  196. CONST:    DEFS    3        ; Console status
  197. CONIN:    DEFS    3        ; Console character in
  198. CONOUT:    DEFS    3        ; Console character out
  199. LIST:    DEFS    3        ; List character out
  200. PUNCH:    DEFS    3        ; Punch character out
  201. READER:    DEFS    3        ; Reader character in
  202. HOME:    DEFS    3        ; Seek to home position
  203. SELDSK:    DEFS    3        ; Select disk
  204. SETTRK:    DEFS    3        ; Set track number
  205. SETSEC:    DEFS    3        ; Set sector number
  206. SETDMA:    DEFS    3        ; Set DMA address
  207. READ:    DEFS    3        ; Read disk
  208. WRITE:    DEFS    3        ; Write disk
  209. LISTST:    DEFS    3        ; Return list status
  210. SECTRAN:DEFS    3        ; Sector translate
  211. GETTBL:    DEFS    3        ; Point to more jumps, returns bioss
  212.                 ; version in 'a'.
  213. ;
  214. ;     Extended BIOS jump table - AMPRO LB specific
  215. ;
  216. NXTTBL:    
  217. SWAP:    DEFS    3        ; jmp swap
  218. HD$INF:    DEFS    3        ; get hd table info
  219. PHTBAC:    DEFS    3        ; get/set phytab acces
  220. PAGET:    DEFS    3        ; get phytab entry address
  221. TOD:    DEFS    3        ; get base address of clock tick
  222.  
  223. BSEC:    DEFS    1             ; binary seconds
  224. BMIN:    DEFS    1             ; binary minutes
  225. BHOUR:    DEFS    1             ; binary hours
  226. JDAY:    DEFS    2             ; Julian day
  227. YEAR:    DEFS    1             ; binary year
  228.  
  229. TMONTH:    DEFS    1             ; binary month
  230. TDAY:    DEFS    1             ; binary day
  231. TYEAR:    DEFS    1             ; not used
  232. ;
  233. ;********************************************************************
  234. ;********************************************************************
  235.       page
  236. ;********************************************************************
  237. ;     some equates
  238. ;********************************************************************
  239. ;
  240. false    equ    0
  241. true    equ    not false
  242. hour    equ    month+3        ; hour byte in bios
  243. base    equ    0        ; standard CP/M
  244. recsiz    equ    128        ; record length
  245. bell    equ    7
  246. bdos    equ    base+5
  247. tail    equ    base+80h    ; command line
  248. endasm    equ    base+100h    ; org if stand alone
  249. fcb    equ    base+5ch    ; use default fcb
  250. cr    equ    0dh        ; carriage return
  251. lf    equ    0ah        ; line feed
  252. ;
  253. ;********************************************************************
  254. ;
  255. ;     BC = Count of characters in command line tail.
  256. ;     DE = File control block.
  257. ;     HL = Command line tail.
  258. ;
  259. ;********************************************************************
  260. ;    Main TIMESTMP code begins here
  261. ;********************************************************************
  262. ;
  263. timestmp:
  264.     ld    de,crlf
  265.     ld    c,9        ;new line
  266.     call    bdos
  267.     ld    a,(base+6dh)    ;get option ' ' or 'M'
  268.     ld    (major),a    ;save it
  269.     ld    bc,3
  270.     ld    de,fcb+9    ;set up to
  271.     ld    hl,ext        ;make default ext 'Z80'
  272.     ld    a,(de)
  273.     cp    ' '        ;jump if ext not ' '
  274.     jr    nz,start3
  275.     ldir            ;ext = 'Z80'
  276. ;
  277. start3:    ld    de,fcb        ;open input file
  278.     ld    c,15
  279.     call    bdos
  280.     ld    de,nofile    ;report if can't open and
  281.     inc    a        ;exit to CP/M
  282.     jp    z,error
  283.     ld    de,buff
  284.     ld    c,26        ;setdma
  285.     call    bdos
  286. ;
  287.     ld    de,fcb
  288.     ld    c,20        ;read record 1
  289.     call    bdos
  290. ;
  291.     ld    de,verstx
  292.     call    find        ;update version
  293.     ld    de,novers
  294.     call    nz,print
  295.     call    z,versn
  296. ;
  297.     ld    de,datetx
  298.     call    find        ;update date
  299.     ld    de,nodate
  300.     call    nz,print
  301.     call    z,date
  302. ;
  303.     ld    de,timetx
  304.     call    find        ;update time
  305.     ld    de,notime
  306.     call    nz,print
  307.     call    z,time
  308. ;
  309. ;write record back into file and exit to assembler or CP/M
  310. ;The file is not closed, 'cos that would reduce it to a
  311. ;single record.
  312. ;
  313.     xor    a
  314.     ld    (fcb+32),a    ;zero the record count
  315.     ld    de,fcb
  316.     ld    c,21
  317.     call    bdos
  318.     ld    de,donmsg
  319. error:    call    print        ;print error message and exit.
  320.                 ;also normal exit
  321.     ret            ;back to CP/M
  322. ;
  323. print:    push    af
  324.     ld    c,9
  325.     call    bdos
  326.     ld    hl,fcb+1
  327.     ld    de,prtnam
  328.     ld    bc,11
  329.     ldir
  330.     ld    de,prtfil
  331.     ld    c,9
  332.     call    bdos        ;print file name
  333.     pop    af
  334.     ret
  335. ;
  336. ;Increment the version number
  337. ;
  338. versn:    inc    hl        ;hl --> units of major change
  339.     ld    a,(major)    ;is a major change requested
  340.     cp    'M'
  341.     call    z,twoinc    ;inc major change number
  342.     jr    z,zeromn    ;zero minor change number
  343.     cp    'N'        ;do not change version if
  344.     ret    z        ;'n' option given
  345.     inc    hl
  346.     inc    hl
  347.     inc    hl        ;hl --> units of vers no.
  348. ;
  349. twoinc:    push    af        ;increment a 2 digit field
  350.     push    hl
  351.     ld    b,2
  352.     ld    a,'9'+1        ;hl --> units position
  353. two1:    inc    (hl)
  354.     cp    (hl)
  355.     jr    nz,twox        ;exit if not > 9 ascii
  356.     ld    (hl),'0'    ;else zero the units
  357.     dec    hl        ;and inc the tens
  358.     djnz    two1
  359. twox:    pop    hl
  360.     pop    af
  361.     ret
  362. ;
  363. zeromn:    inc    hl        ;zero minor version
  364.     inc    hl
  365.     ld    (hl),'0'    ;used when major changes
  366.     inc    hl
  367.     ld    (hl),'0'
  368.     ret
  369. ;
  370. date:    ld    de,month    ;insert m/d/y
  371.     ld    b,2
  372. date1:    call    unpack
  373.     ld    (hl),'/'
  374.     inc    hl
  375.     djnz    date1
  376.     call    unpack
  377.     ret
  378. ;
  379. time:    ld    de,hour
  380.     ld    b,2
  381. time1:    call    unpack        ;insert h:m:s
  382.     ld    (hl),':'
  383.     inc    hl
  384.     djnz    time1
  385.     call    unpack
  386.     ret
  387. ;
  388. ;find the first character of string in de (V, D or T)
  389. ;
  390. find:    ld    hl,buff        ;de = compare string
  391.     ld    bc,recsiz    ;limit search to 1 rec
  392. trynxt:    ld    a,(de)        ;get 1st char to find
  393.     cpir
  394.     ret    po        ;ret nz set = not found
  395. ;
  396. ;see if the rest of the string compares equal. Retry til we
  397. ;get to the end of the buffer
  398. ;
  399.     push    bc
  400.     push    de
  401.     ld    b,6        ;compare next 6 chars
  402. find2:    inc    de
  403.     ld    a,(de)
  404.     cp    (hl)
  405.     jr    nz,tryagn    ;try for another string
  406.     inc    hl
  407.     djnz    find2        ;keep comparing til b = 0
  408.     pop    de
  409.     pop    bc
  410.     ret            ;ret with z set
  411. ;
  412. tryagn:    pop    de        ;Found the 1st character, but
  413.     pop    bc        ;there was a bad compare in
  414.     jr    trynxt        ;the next 6 characters.
  415. ;
  416. unpack:    ld    a,(de)        ;unpack the BCD time & date
  417.     inc    de        ;and put the ASCII characters
  418.     push    af        ;in the buffer.
  419.     rrca
  420.     rrca
  421.     rrca            ;move high nibble to low
  422.     rrca
  423.     call    unpak1
  424.     pop    af        ;do the low nibble
  425. unpak1:    and    0fh
  426.     add    a,'0'        ;make it an ASCII number
  427.     ld    (hl),a
  428.     inc    hl
  429.     ret
  430. ;
  431. donmsg:    db    '++ Date stamped$'
  432. nofile:    db    '++ No source$'
  433. novers:    db    '++ No '
  434. verstx:    db    'VERS:- '
  435.     db    'in$'
  436. nodate:    db    '++ No '
  437. datetx:    db    'DATE:- '    
  438.     db    'in$'
  439. notime:    db    '++ No ' 
  440. timetx:    db    'TIME:- '    
  441.     db    'in$'
  442. crlf:    db    cr,lf,'$'
  443. major:    db    0
  444. ext:    db    'Z80'
  445. buff:    ds    recsiz
  446. prtfil:    db    ' File:- '
  447. prtnam:    db    '           ',cr,lf,lf,'$'
  448.     end
  449.  
  450.