home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / PROGRAMS / BKGRONDR / BGK84SCR.LBR / K84SCRN.AZM / K84SCRN.ASM
Assembly Source File  |  2000-06-30  |  26KB  |  1,438 lines
  1.     .title    "K84SCRN.ASM Kaypro '83 screen driver 11/8/86"
  2.     .sbttl    "Copyright (c) 1986  Plu*Perfect Systems"
  3.  
  4. noatt = 1        ;nul return-attribute function to save space
  5.  
  6. DEBUG =    0
  7.  
  8. .remark \==
  9. Source code for CDL/TDL Z80 assembler (AZM.COM).
  10.  
  11. ; production by:
  12. ;
  13. AZM k84scrn
  14. ZLINK
  15. *k84.com=k84scrn.rel
  16. */locate .prog.=3f80;
  17. *q
  18. ZSID k84.com
  19. m3f80 4500 100
  20. ^C
  21. SAVE 5 k84scrn.drv
  22.  
  23. ==\
  24. ; revision history:
  25. ;
  26. ; v 1.0: no scroll on line 24 in cut
  27. ;      id imbedded in string 
  28. ;     most data put in-line to save bytes
  29.  
  30. .XLIST
  31.  
  32. .ifg DEBUG, [
  33.     bios =\  'Base of bios = ?'
  34.     ]
  35.  
  36. .remark \===
  37.  
  38. The first sections of code are generic (except for some terminal equates);
  39. beginning at 'STMRKS' it is terminal-specific.
  40.  
  41. Particular features of Kaypro '84 code:
  42.  
  43. 1. Video ram must be accessed via video controller.
  44. 2. We store screen attributes as nybbles.
  45. 3. Cursor-movement sequences are all single-byte control characters.
  46.  
  47. Space is very tight; in-line data used extensively.
  48.  
  49. ===\
  50.  
  51. .ifg    DEBUG, [
  52. codloc    =    100h
  53. .phex
  54. .psym
  55. .pabs
  56. consta    =    bios +06h
  57. conin    =    bios +09h
  58. conout    =    bios +0ch
  59.     ]
  60. ;
  61.     [
  62. .prel
  63. .ident    SCRK84
  64.  
  65. consta    =    0
  66. conin    =    0
  67. conout    =    0
  68. outch    =    0
  69. puts    =    0
  70. bwrch    =    0
  71. bflush    =    0
  72.     ]
  73.  
  74. .xsym
  75. .sall
  76. ;
  77.  
  78. ; ascii equates
  79. ;
  80. NUL    =    00h
  81. BELL    =    07h
  82. BS    =    08h
  83. CR    =    0dh
  84. LF    =    0ah
  85. ESC    =    1bh
  86. SPACE    =    20h
  87. DEL    =    7fh
  88. ;
  89. ; CUT command characters
  90. ;
  91. HOME    =    'H'        ;home the cursor
  92. LOHOME    =    'h'
  93. MARK    =    'X'        ;set a mark
  94. LOMARK    =    'x'
  95. PASTE    =    'P'-'@'        ;paste region at cursor
  96. CANCEL    =    'C'-'@'        ;cancel cut command
  97. ;
  98. ;
  99. ; TERMINAL-SPECIFIC EQUATES
  100. ;
  101. ; kaypro cursor controls
  102. ;
  103. LEFT    =    08H
  104. RIGHT    =    'L'-'@'
  105. UP    =    'K'-'@'
  106. DOWN    =    0AH
  107. ;
  108. LEFT8    =    82h        ;kaypro raw keypad arrow values...
  109. RIGHT8    =    83h
  110. UP8    =    80h
  111. DOWN8    =    81h
  112. ;
  113. HOMEC    =    1eh        ;home cursor
  114. ;
  115.  
  116. ; Kaypro '84 screen parameters
  117. ;
  118. NCOLS    =    80
  119. NROWS    =    25
  120. NROW24    =    24        ;# rows excluding status line
  121. ;
  122. SCRSIZ    =    NCOLS*NROWS
  123. ;
  124. ; Kaypro '84 controller ports
  125. ;
  126. vcbase    =    1ch
  127. vccmd    =    vcbase
  128. vcstat    =    vcbase
  129. vcrdat    =    vcbase+1
  130. vcdata    =    vcbase+3
  131. ;
  132. ; controller register numbers
  133. ;
  134. cstart    =    10        ;cursor start
  135. cstop    =    11        ;cursor stop
  136. hiadd    =    18        ;hi address byte - update register
  137. loadd    =    19        ;lo ""
  138. ;
  139. scrcmd    =    12        ;"scroll" set home addr
  140. curcmd    =    14        ;place cursor
  141. rwcmd    =    18        ;read/write
  142. strcmd    =    31        ;strobe
  143. ;
  144. ;=========================
  145.  
  146. .ifg DEBUG, [
  147.     .loc    codloc
  148.     ]
  149. ;
  150.     [
  151.     .loc    .PROG.
  152.     ]
  153. ;
  154. ;------------------------------------------------------------
  155. ;
  156. ; id sector - nul-terminated string - at 3f80h
  157. ;
  158. sdid:    .ascii    "Kaypro '84 driver v 1.0"
  159.     db    0            ;NUL terminator
  160. idlen = . - sdid
  161.     ds    80h-idlen        ;total of 80h bytes
  162.  
  163. ;
  164. START:
  165. ;
  166. ;
  167. ; Start of Screen Module.  Assemble to run at 4000h.
  168. ;
  169. ;***** MODULE ENTRY HEADER
  170. ;
  171. ; EXTERNAL ADDRESSES, supplied by loader
  172. ;
  173. jjcons:    jmp    consta        ;bios constat
  174. jjconi:    jmp    conin        ;bios conin
  175. jjouta:    jmp    outch        ;A to conout, preserving bc,de,hl
  176. jjputs:    jmp    puts        ;hl-string to conout, NUL/bit-7 term.
  177.                 ; preserving bc,de,hl
  178. jjbrdc:    jmp    0000        ;buffered read char from cut-swp
  179. jjbwrc:    jmp    bwrch        ;buffered write char to cut-swp
  180. jjbflu:    jmp    bflush        ;flush (write) buffer
  181. ;
  182. ; INTERNAL ENTRY POINTS
  183. ;
  184. savscr:    jmp    savpag        ;save screen 
  185. resscr:    jmp    respag        ;restore saved screen
  186. lastnb:    jmp    lstnbl        ;last non-blank char in rows 1-24
  187. dmpchr:    jmp    retnch        ;return next screen char
  188. dmpcur:    jmp    retncu        ;return buffer cursor
  189. dmpatt:    jmp    retnat        ;return next screen attribute
  190. setmrk:    jmp    stmrks        ;set region marks, move cursor
  191. cutrg:    jmp    docut        ;cut region
  192. pastrg:    jmp    dopast        ;paste region
  193. ininpd:    jmp    ininot        ;initialize notepad
  194. putnpd:    jmp    putnch        ;put char to notepad
  195. ;
  196. ;========================================
  197. ; generic
  198. ;
  199. ININOT:
  200. ;
  201. ; Initiate Notepad - clear screen, print banner.
  202. ;
  203.     lxi    h,Zbanner
  204.     jr    jjputs
  205. ;
  206. ;========================================
  207. ; generic
  208. ;
  209. PUTNCH:
  210. ;
  211. ; Put char in A  to notepad (screen)
  212. ; Convert CR to CRLF, DEL to rubout.
  213. ;
  214.     cpi    CR
  215.     lxi    h,Zcrlf        ;convert CR to CR,LF
  216.     jrz    jjputs
  217.     cpi    DEL
  218.     lxi    h,Zrub
  219.     jrz    jjputs
  220.     jr    jjouta
  221.  
  222. ;========================================
  223. ; generic
  224. ;
  225. RETNCU:
  226. ;
  227. ; Return buffer cursor as row/col.
  228. ;
  229. ; ret: D = binary row, E= binary col
  230. ;      L =  ascii row, H = ascii col (for shld ...)
  231. ;
  232.     lhld    bcursor
  233. ;
  234. ; Convert offset to col/row.
  235. ; exit: D = binary row, E = binary col
  236. ;    H = ascii col,  L = ascii row <-- NOTE ORDER
  237. ;
  238. off2cr:    mvi    b,0        ;convert to row,col
  239.     lxi    d,-NCOLS
  240. ..1:    dad    d
  241.     jrnc    ..2
  242.     inr    b        ;row count++
  243.     jr    ..1
  244. ..2:    lxi    d,NCOLS
  245.     dad    d
  246.     mov    a,l        ;col
  247.     mov    e,a        ;binary col in E
  248.     mov    d,b        ;binary row in D
  249.     adi    SPACE        ; + bias
  250.     mov    h,a        ;H = ascii col
  251.     mov    a,b        ;row
  252.     adi    SPACE        ; +bias
  253.     mov    l,a        ;L = ascii row
  254.     ret
  255. ;
  256. ;========================================
  257. ; generic
  258. ;
  259. DOPASTE:
  260. ;
  261. ; Paste the last-cut region onto active screen at the current cursor.
  262. ;
  263. ; 1. Get previously-cut region from external routine
  264. ; 2. Send chars to screen, avoiding boundary overflows. 
  265. ;
  266. ; 'savpag' not needed if terminal supports 'send cursor address'
  267. ;;--    call    savpag        ;get current screen,
  268.                 ;in order to find cursor
  269.     mvi    b,4        ;read 4 data bytes
  270. ..0:    push    b
  271.     call    jjbrdc
  272.     pop    b
  273.     djnz    ..0
  274. ;
  275.     mov    b,a        ;4th byte is # rows
  276.     push    b
  277.     call    crs2hl        ;current cursor's row/col to hl
  278.     pop    b
  279. ;
  280. ; loop over rows
  281. ;
  282. ..rowlp:push    b
  283.     push    h
  284.     mov    e,l        ;e = col no.
  285.     push    d
  286.     call    stcrshl        ;set cursor at h,l
  287. ..collp:call    jjbrdc        ;read char from cut-swp
  288.     cpi    CR
  289.     jrz    ..rend
  290.     mov    c,a        ;save char
  291.     pop    d        ;check for off screen
  292.     mov    a,e
  293.     cpi    NCOLS
  294.     inr    e
  295.     push    d        ;row/col to stack
  296.     cc    sendc        ;to conout, unless off edge
  297.     jr    ..collp
  298. ;
  299. ..rend:    pop    d        ;clear row/col
  300.     pop    h
  301.     pop    b
  302.     inr    h        ;bump row
  303.     mov    a,h        ;check for off bottom of screen
  304.     cpi    NROWS
  305.     jrnc    ..xit
  306.     djnz    ..rowlp
  307. ..xit:    xra    a
  308.     ret
  309. ;
  310. ;========================================
  311. ; generic
  312. ;
  313. DOCUT:
  314. ;
  315. ; Cut rectangular region defined by keypresses.
  316. ; 1. Parse keypresses to move cursor and mark corners.
  317. ;    Highlight region as cursor is moved.
  318. ; 2. Send the marked region, row-wise to external routine.
  319. ;    Append CR after each row.
  320. ;
  321. ; Data structure is:
  322. ;    size (word)
  323. ;    # columns (byte)
  324. ;    # rows (byte)
  325. ;    row 1
  326. ;    CR
  327. ;    row 2
  328. ;    CR
  329. ;    ....
  330. ;
  331. .ifg DEBUG, [
  332. ;for debugging, use cutbuf for output
  333.     lxi    h,cutbuf    ;set ptr
  334.     shld    dbgptr
  335.     ]
  336. ;
  337.     xra    a
  338.     sta    mrkcnt        ;init for next time
  339. ;
  340. ;
  341. ; set ctcols = # cols, ctrows = # rows
  342. ; (assumes mark2 is SE of mark1)
  343. ;
  344. mark1 = .+1
  345. mark1r = .+2
  346. corners:lxi    d,0000    ;binary col, then row of upperleft mark
  347. ;
  348. mark2 = .+1
  349. mark2r = .+2
  350.     lxi    h,0000            ;lower right mark
  351.     mov    a,h    ;# rows = 1 + mark2row -mark1row    
  352.     inr    a
  353.     sub    d
  354.     mov    h,a
  355.     mov    a,l    ;# cols = 1 + mark2col -mark1col
  356.     inr    a
  357.     sub    e
  358.     mov    l,a
  359.     shld    ctcols
  360. ;
  361. ; cut rectangle [mark1...mark2]  & copy to buffer
  362. ; append CR at end of each row
  363. ;
  364.     xchg
  365.     push    h        ;mark1
  366.     call    wrpara        ;write parameters
  367.     pop    h        ;mark1
  368.     call    rc2off        ;convert to scr addr
  369.     lda    ctrows        ;get # rows
  370.     mov    b,a
  371. ;
  372. ; write the cut region to external buffer
  373. ;
  374. ..rowlp:push    b        ;(+1
  375.     push    h        ;(+2
  376.     lxi    d,buf        ;fetch from screen buffer
  377.     dad    d
  378. ;
  379. ; write 1 row of cut region to external buffer
  380. ;
  381.     lda    ctcols
  382.     mov    b,a        ;b = # cols
  383. ;
  384. ; buffered write B chars at hl, ascii only
  385. ;
  386. ..bwrt:    push    b
  387.     push    h
  388.     mov    a,m
  389.     cpi    DEL
  390.     jrnc    ..mksp
  391.     cpi    SPACE        ;convert graphics
  392.     jrnc    ..1
  393. ..mksp:    mvi    a,SPACE        ; to space
  394. ..1:    mov    c,a
  395.     call    jjbwrch
  396.     pop    h
  397.     pop    b
  398.     inx    h
  399.     djnz    ..bwrt
  400. ;
  401.     mvi    c,CR        ;append CR to each row
  402.     call    jjbwrch
  403.     pop    h        ;(+1
  404.     pop    b        ;(+0
  405.     lxi    d,NCOLS        ;bump to next row
  406.     dad    d
  407.     djnz    ..rowlp        ; and loop
  408.     jmp    jjbflu        ;flush the write buffer
  409. ;
  410. ;
  411. ; write parameters: size, # cols, # rows to swp file
  412. ; de = ctcols
  413. ;
  414. wrpara:    mov    b,d        ;# rows
  415.     mvi    d,0
  416.     inr    e        ;+1 for CR
  417.     lxi    h,0        ;accum.
  418. ..0:    dad    d
  419.     djnz    ..0
  420.     call    bwhl        ;write word
  421. ctcols = .+1
  422. ctrows = .+2
  423.     lxi    h,0000        ;now #cols, # rows
  424. ;
  425. bwhl:    push    h
  426.     mov    c,l
  427.     call    jjbwrch
  428.     pop    h
  429.     mov    c,h
  430.     jmp    jjbwrch
  431.  
  432. ;========================================
  433. ; generic
  434. ;
  435. LSTNBL:
  436. ;
  437. ; Find last non-blank line (1-24 only) in current scr buffer.
  438. ; Graphics and 8-bit characters are considered blanks.
  439. ; If B=0ff, save screen first.
  440. ;
  441. ; ret:    H=row, L=col of last non-blank char in rows 1-24
  442. ;
  443.     inr    b
  444.     cz    savpag
  445.     lxi    b,NROW24*100h + NCOLS    ;b=# rows, c=# cols
  446.     lxi    d,buf
  447.     lxi    h,0
  448. ..lp:    ldax    d
  449.     cpi    SPACE+1        ;don't count cntl chars or SPACE
  450.     jrc    ..1
  451.     cpi    DEL        ; or DEL or graphics 8-bit
  452.     jrnc    ..1
  453.     shld    savrc
  454. ..1:    inx    d
  455.     inr    l
  456.     dcr    c
  457.     jrnz    ..lp        ;loop over cols
  458.     inr    h
  459.     mov    l,c        ;0
  460.     mvi    c,NCOLS
  461.     djnz    ..lp        ;loop over rows
  462. savrc = .+1
  463.     lxi    h,0000        ;hl = last non-blank
  464.     ret        
  465.  
  466. ;----------------------------------------
  467. ;
  468. xring:    mvi    c,BELL
  469. ;
  470. ; send C to screen, exit Z, no CY
  471. ;
  472. sendc:    mov    a,c
  473.  
  474. ; send A to screen, exit Z, no CY
  475. ; (this will scroll, however!)
  476. ;
  477. send:    call    jjouta
  478.     xra    a        ;Z, no CY
  479.     ret
  480. ;========================================
  481. ;
  482. ; end of generic code
  483. ;
  484. ;========================================
  485. ; specific
  486. ;
  487. ; bump row/col  var that tracks actual cursor
  488. ; if mark not yet, send cntl char
  489. ; ret NZ if mark is set
  490. ;
  491. inrsnd:    inr    m        ;next row/col
  492.     call    anymrk
  493.     cz    sendc
  494. ;
  495. ; nz if a mark has been set
  496. ;
  497. mrkcnt = .+1
  498. anymrk:    mvi    a,00
  499.     ora    a
  500.     ret
  501. ;
  502. STMRKS:
  503. ;
  504. ; Move cursor and set marks. Return CY clear until exit.
  505. ;
  506. ; 1. move cursor, until:
  507. ; 2. 'X' = set 1st mark
  508. ;    turn on hiliting, set mark, keep cursor at mark
  509. ; 3. move cursor right/down only
  510. ; 4. 'X' = set 2nd mark
  511. ;    turn off hiliting, set 2nd mark
  512. ;    exit CY (done)
  513. ; 5. cntl-C = CANCEL. 
  514. ;    turn off hilighting, set CY, exit
  515. ;
  516. ;
  517.     lxi    h,bincol    ;load ptr to actual col/row
  518.     cpi    CANCEL
  519.     jrz    abort
  520.     cpi    LEFT
  521.     jrz    jjlef8        ;;jz    golef8
  522.     cpi    LEFT8
  523. jjlef8:    jz    golef8
  524. ;
  525.     cpi    UP
  526.     jrz    jjup8        ;;jz    goup
  527.     cpi    UP8
  528. jjup8:    jz    goup8
  529. ;
  530.     cpi    RIGHT
  531.     jrz    jjrt8        ;;jz    gort
  532.     cpi    RIGHT8
  533. jjrt8:    jz    gort8
  534. ;
  535.     cpi    DOWN
  536.     jrz    jjdn8        ;;jz    godn
  537.     cpi    DOWN8
  538. jjdn8:    jz    godn8
  539. ;
  540.     cpi    CR
  541.     jrz    ..mrk
  542. ;
  543.     ani    5fh        ;convert rest to uppercase
  544.     cpi    HOME
  545.     jrz    gohome
  546. ;
  547.     cpi    MARK
  548.     jrz    ..mrk
  549.     xra    a        ;no action
  550.     ret
  551. ..mrk:    lxi    h,mrkcnt    ;if no mark yet set
  552.     mov    a,m
  553.     ora    a
  554.     mvi    m,1
  555.     jrz    mk1        ;..set mark1
  556.     call    mk2        ;else set mark2
  557. mrkxit:    xra    a
  558.     sta    mrkcnt        ;init for next time
  559.     stc            ;CY = all done
  560.     ret
  561. ;
  562. abort:    call    normal        ;restore normal video
  563.     jr    mrkxit
  564.  
  565. ;-------------------------------------------
  566. ;
  567. ; set 1st mark, turn on rev. video, don't move cursor
  568. ;
  569. mk1:    call    crs2hl
  570.     shld    mark1
  571.     shld    mark2               
  572.     shld    curcol        ;L->curcol,H->currow
  573.     push    h
  574.     call    reverse        ;reverse video on
  575. ;
  576. ; Hilite the marked char.
  577. ;
  578.     pop    h        ;mark1
  579.     mvi    a,1        ;blink 1 char
  580.     sta    colct
  581.     sta    rowct
  582.     call    showro
  583.     jmp    sendbs
  584. ;
  585. ; set 2nd mark, restore normal video, set CY
  586. ;
  587. mk2:    call    normal        ;dummy - restore normal video
  588.     stc            ;CY = all done
  589.     ret
  590. ;
  591. ;======================
  592. ; for H19, etc that use ESC sequences,
  593. ; change these routines to send ESC, then the byte.
  594. ;
  595. gohome:    mvi    c,HOMEC        ;convert to video driver's cntl char
  596.     call    anymrk        ;if mark set,
  597.     jnz    xring        ;..error
  598.     mov    h,a        ;set row=col=0
  599.     mov    l,a
  600.     shld    bincol
  601. jjsndc:    jmp    sendc
  602. ;
  603. ; cursor left and cursor up:
  604. ;    send if not at top or left margin
  605. ;
  606. golef8:    mvi    a,LEFT        ;convert to 7-bit char
  607. ;
  608. goleft:                ;hl = bincol
  609. ;
  610. zck:    mov    c,a        ;save char in c
  611.     call    anymrk
  612.     rnz
  613.     cmp    m        ;ck col/row == 0
  614.     jz    xring        ;..error
  615.     dcr    m        ;dcr col/row
  616.     jr    jjsndc
  617. ;
  618. goup8:    mvi    a,UP        ;7-bit code
  619. goup:    inx    h        ;binrow
  620.     jr    zck        ;ck for top row and send
  621. ;
  622. ; cursor right and cursor down:
  623. ;    if mark is not set, move cursor
  624. ;    if mark is set, expand region and highlight
  625. ;    keep track of cursor location in both cases
  626. ;    don't move if it would scroll
  627. ;
  628. ; move cursor right
  629. ;
  630. gort8:    mvi    a,RIGHT        ;convert to 7-bit code
  631. ;
  632. gort:    mov    c,a        ;save in c
  633.     mvi    a,NCOLS-2
  634.     cmp    m
  635. jcxrng:    jc    xring
  636.     call    inrsnd        ;bump col & send if mrk not set
  637.     rz            ;rtn if mark not yet set
  638. ;
  639. ;  hilite marked column
  640. ;
  641. gort1:    lxi    h,mark2
  642.     inr    m        ;bump 2nd mark-row
  643.     lxi    h,curcol    ;bump col
  644.     inr    m
  645.     mov    l,m
  646.     lda    mark1r        ;top row
  647.     mov    h,a        ;h=row, l=col for col to hilite
  648. rowct = .+1
  649.     mvi    b,00
  650. ;
  651. ; loop over each row in cut region
  652. ; 
  653. ..rlp:    push    b
  654.     push    h        ;save binary row/col
  655.     mvi    a,1        ;display 1 char in each row
  656.     call    showhi
  657.     pop    h
  658.     pop    b
  659.     inr    h        ;next row
  660.     djnz    ..rlp
  661.     lxi    h,colct        ;prepare to bump col cnt & exit
  662.     jr    inrmbs
  663. ;
  664. ; move cursor down
  665. ;
  666. godn8:    mvi    a,DOWN        ;7bit code
  667. godn:    mov    c,a        ;save char
  668.     inx    h        ;binrow
  669.     mvi    a,NROW24-2    ;ck if already on bottom row
  670.     cmp    m
  671.     jc    jcxrng
  672.     call    inrsnd         ;bump row & send
  673.     rz            ;rtn if mark not yet set
  674. ;
  675. ;  hilite marked row
  676. ;
  677. godn1:    lxi    h,mark2r    ;row
  678.     inr    m        ;bump 2nd mark-col
  679.     lxi    h,currow    ;bump row
  680.     inr    m
  681.     mov    h,m
  682.     lda    mark1        ;left col
  683.     mov    l,a        ;h=row, l=col for row to hilite
  684.     call    showro        ;display 1 cut row
  685.     lxi    h,rowct        ;bump row cnt
  686. inrmbs:    inr    m        ; and exit
  687. sendbs:    mvi    a,BS        ;back up cursor
  688.     jmp    send
  689. ;
  690. .remark \====
  691. For Kaypro '84,  use bios conout.
  692.  
  693. if down:    set cur at next row, left col
  694.         send partial row
  695.         rowcnt++
  696.         BS (back up 1)
  697.  
  698. if right:    set cur at toprow, next col
  699.         send partial column
  700.         colcnt++
  701. ====\
  702. ;
  703. ; enter: H = binary row, L= binary col 
  704. ;
  705. showro:
  706. colct = .+1
  707.     mvi    a,00
  708. ;
  709. ; Fetch A chars at H=binary row, L=binary col from buffer.
  710. ; Put chars to screen, setting BLINK attribute.
  711. ;
  712. showhi:    push    psw
  713.     push    h
  714.     call    stcrshl        ;set cursor at h,l
  715.     pop    h
  716.     call    rc2off
  717.     lxi    d,buf        ;fetch from screen buffer
  718.     dad    d    
  719.     pop    psw        ;#chars
  720.     mov    b,a
  721. ..lp:    mov    a,m
  722.     inx    h
  723.     call    jjouta
  724.     djnz    ..lp
  725.     ora    a
  726.     ret
  727. ;
  728. ;========================================
  729. ;
  730. RETNCH:    
  731. ;
  732. ; Return next screen char.
  733. ;
  734. ; enter:
  735. ;    d = row, e = col
  736. ;    b = FF ==> read screen
  737. ;    c = FF ==> set bufptr
  738. ; exit:
  739. ;    A = char, CY set if good
  740. ;    DE -> row,col of next char, HL -> buf of next char
  741. ;    CY clear if out of range
  742. ;
  743.     xra    a
  744.     call    stdump
  745.     rnc
  746.     mov    a,m        ;get char
  747.     inx    h        ;bump bufptr
  748.     ret
  749. ;
  750. ;========================================
  751. ;
  752. .slist
  753. .list
  754. RETNAT:
  755. ;
  756. .ifg noatt, [
  757. ; save space with a NUL FUNCTION
  758.     xra    a        ;clear CY
  759.     ret
  760.     ]
  761.     [
  762. ;
  763. ;--------------------
  764. ; Return next screen attribute.
  765. ;
  766. ; enter:
  767. ;    d = row, e = col
  768. ;    b = FF ==> read screen
  769. ;    c = FF ==> set bufptr
  770. ; exit:
  771. ;    A = attr, CY set if good
  772. ;    DE -> row,col of next char, HL -> buf of next char
  773. ;    CY clear if out of range
  774. ;
  775.     mvi    a,0ffh
  776.     call    stdump
  777.     rnc
  778. ;
  779. ; fetch attr from buffer, advance hl every 2 
  780. ;
  781.     mov    a,m        ;fetch attr byte from buffer
  782.     bit    0,e
  783.     jrnz    ..podd        ;DE here is CHAR addr, not attr +1
  784.     rar
  785.     rar
  786.     rar
  787.     rar
  788.     jr    ..done
  789. ..podd:    inx    h        ;bump hl
  790. ..done:    ani    0fh
  791.     ret
  792. ;
  793.     ]
  794. .rlist
  795. ;--------------------
  796. ;
  797. ; ret: NC if out of range
  798. ;
  799. stdump:    sta    attflg
  800.     inr    b
  801.     jrnz    ..0
  802.     push    b
  803.     push    d
  804.     call    savpag
  805.     pop    d
  806.     pop    b
  807. ..0:    inr    c
  808.     jrnz    ..1
  809.     call    conv
  810.     rnc            ;out of range
  811. ..1:    inx    d        ;col++
  812.     mov    a,e
  813.     cpi    NCOLS
  814.     rc
  815.     mvi    e,0        ;col = 0
  816.     inr    d        ;row++
  817.     mov    a,d    
  818.     cpi    NROWS
  819.     ret            ;NC if out of range
  820. ;
  821. ; enter: d = row, e = col
  822. ; exit: hl -> buffer address, cy set
  823. ;    de preserved
  824. ;    CY clear if  error (off screen)
  825. ;
  826. conv:    mov    a,d
  827.     cpi    NROWS
  828.     jrnc    cnvbad
  829.     mov    a,e
  830.     cpi    NCOLS
  831.     jrnc    cnvbad
  832.     lxi    h,buf
  833.     mov    a,d
  834.     lxi    b,NCOLS        ;row*(cols per row)
  835.     inr    a
  836. ..lp:    dcr    a
  837.     jrz    ..2
  838.     dad    b
  839.     jr    ..lp
  840. ..2:    mvi    d,0        ;+ col #
  841.     dad    d
  842. attflg    = .+1
  843.     mvi    a,00
  844.     ora    a
  845.     stc
  846.     rz
  847.     lxi    b,SCRSIZ    ;bump ptr to attributes
  848.     dad    b
  849.     stc
  850.     ret
  851. cnvbad:    xra    a
  852.     ret
  853. ;
  854. ;========================================
  855. ;
  856. SAVPAG:
  857. ;
  858. ; Save screen to buffer.
  859. ;
  860.     xra    a
  861.     call    iscr
  862.     call    crs2off        ;find screen cursor
  863.     shld    bcursor
  864.     push    h
  865.     push    d
  866.     call    off2cr
  867.     sded    bincol        ;save binary col/row
  868.     pop    d
  869.     pop    h
  870. ;
  871. ;--------------------
  872. ;
  873. doscr:    lxi    b,SCRSIZ
  874.     push    b        ;save count
  875.     push    d        ;save addr
  876. ;
  877. ; first the characters
  878. ;
  879. ..0:    call    datadr        ;set  addr
  880.     call    vch        ;r/w char
  881.     inx    d
  882.     dcx    b
  883.     mov    a,b
  884.     ora    c
  885.     jrnz    ..0
  886.     pop    d        ;addr
  887.     pop    b        ;count
  888. ;
  889. ; now the attributes
  890. ;
  891.     inx    d        ;attributes lead 1 byte
  892. ..2:    call    attadr
  893.     call    vat
  894.     inx    d
  895.     dcx    b
  896.     mov    a,b
  897.     ora    c
  898.     jrnz    ..2
  899.     ret
  900. ;
  901. ;========================================
  902. ;
  903. RESPAG:
  904. ;
  905. ; Restore saved screen from buffer.
  906. ;
  907. ; First, set any attribute so we undo the effect of a clearscreen.
  908. ; This ensures that the restored screen, if it has
  909. ; attributes set, will get cleared by a clearscreen or ^X or whatever.
  910. ;
  911. ;put1att:
  912.     call    svcrsor
  913.     lxi    h,Zoneat
  914.     call    jjputs
  915.     call    cursbak
  916. ;
  917.     mvi    a,0ffh
  918.     call    iscr
  919.     call    gethome        ;get current top of screen
  920.     xchg            ; to de
  921.     call    doscr        ;put buffer to screen
  922.     lhld    bcursor        ;and set the cursor
  923. ;
  924. ; Set cursor on screen by direct cursor addressing.
  925. ; enter: HL = cursor offset relative to 0000
  926. ;    
  927. stcrs:    call    off2cr        ;convert from offset to ascii col/row
  928. stcoro:    shld    colrow        ;put ascii col/row into string
  929.     lxi    h,Zcurs        ;send set-cursor string
  930.     jmp    jjputs
  931. ;
  932. ; Set cursor on screen.
  933. ; enter: H=binary row, L = binary col
  934. ;
  935. stcrshl:call    rc2off
  936.     jr    stcrs
  937. ;
  938. ;--------------------
  939. ;
  940. ; CONVERSION ROUTINES
  941. ;
  942. ; Get current cursor position to H=binary row, L=binary col
  943. ;
  944. crs2hl:    call    crs2off        ;get cursor by ...84 method
  945.     call    off2cr        ;returns binary in de
  946.     xchg
  947.     ret
  948. ;
  949. ; convert H=binary row, L=binary col to hl= offset
  950. ; (hl =  row*NCOLS + col)
  951. ; uses bc,de,hl
  952. ;
  953. rc2off:    mov    b,h        ;b=row
  954.     mov    c,l        ;c=col
  955.     lxi    h,0
  956.     inr    b
  957.     lxi    d,NCOLS
  958.     jr    ..bot
  959. ..0:    dad    d        ;rows*NCOLS
  960. ..bot:    djnz    ..0
  961.     dad    b        ;+ col
  962.     ret
  963. ;
  964. ; get raw relative cursor to HL
  965. ;
  966. crs2off:
  967.     call    gethome        ;get top of scr addr
  968.     xchg            ;keep in de
  969.     call    gcur        ;get cursor addr
  970. ;
  971. mod800:    ora    a
  972.     dsbc    d
  973. mod8ck:    rnc
  974.     lxi    d,800h
  975.     dad    d
  976.     ret
  977. ;
  978. ;--------------------
  979. ;initialize for screen
  980. ;
  981. iscr:    sta    putflg        ;0=save, 0ff=restore
  982.     lxi    h,buf        ;init char ptr
  983.     jr    shcptr
  984. ;
  985. ;
  986. ; read/write 1 char from video controller, to/from buffer
  987. ; status must already be checked and ok
  988. ;
  989. vch:    lhld    cptr
  990.     lda    putflg
  991.     ora    a
  992.     jrnz    vchput
  993.     in    vcdata        ;get char from screen
  994.     mov    m,a        ; & put into buffer
  995. inxcpt:    inx    h
  996. shcptr:    shld    cptr
  997.     ret
  998. ;
  999. vchput:    mov    a,m        ;fetch char from buffer
  1000.     call    inxcpt
  1001.     out    vcdata        ; & put to screen
  1002.     ret
  1003. ;
  1004. ; read/write 1 attribute nybble to/from buffer
  1005. ; stored: upper nybble = 00, lower nybble = 01, upper = 02,...
  1006. ;
  1007. cptr = .+ 1
  1008. vat:    lxi    h,0000        ;char ptr
  1009. ;
  1010. putflg = .+1
  1011.     mvi    a,00        ;NZ to restore(put) screen from buf
  1012.     ora    a
  1013.     jrnz    ..put
  1014. ;
  1015. ; get attribute from screen, store in buffer
  1016. ;
  1017. ..get:    bit    0,e        ;test for even col (de leads 1 )
  1018.     jrz    ..odd
  1019.     rld            ;a->lo, lo->hi
  1020.     in    vcdata        ;get char from screen
  1021.     rrd            ;a->hi, hi back to lo    
  1022.     ret
  1023. ..odd:    rrd            ;do low nybble, a->hi, hi->lo
  1024.     in    vcdata
  1025.     rld
  1026.     jr    inxcpt        ;and bump ptr
  1027. ;
  1028. ; fetch attr from buffer, advance hl every 2, put to screen
  1029. ;
  1030. ..put:    mov    a,m        ;fetch attr byte from buffer
  1031.     bit    0,e
  1032.     jrz    ..podd        ;DE leads 1 
  1033.     rar
  1034.     rar
  1035.     rar
  1036.     rar
  1037.     jr    ..done
  1038. ..podd:    inx    h        ;bump hl
  1039.     shld    cptr
  1040. ..done:    ani    0fh
  1041.     out    vcdata        ; & put to screen
  1042.     ret
  1043. ;
  1044. ;
  1045. gethome:call    svcrsor        ;save cursor in bios rom
  1046.     mvi    a,HOMEC        ;home it
  1047.     call    jjouta
  1048.     call    gcur
  1049. ;
  1050. cursbak:push    h
  1051.     lxi    h,Zrestc    ;restore bios copy of cursor addr
  1052.     call    jjputs
  1053.     pop    h        ;ret home addr in hl
  1054. ;
  1055. ; v 1.4a FIX turborom v2.6.  Restore cursor calls ldcursor
  1056. ; w/o waiting for good status. The next controller read cause
  1057. ; cursor-type byte to be written to screen.
  1058. ;---
  1059. fixtrb:    push    h
  1060.     lxi    d,SCRSIZ
  1061.     dad    d        ;point at 1st char in gap
  1062.     xchg
  1063.     call    datadr        ;set  addr
  1064.     in    vcdata        ;read the controller to flush
  1065.     pop    h        ;the cursor-type byte.
  1066. ;---
  1067.     ret
  1068. ;
  1069. ; HL = raw cursor read from video controller
  1070. ; uses h,l,a
  1071. ;
  1072. gcur:    mvi    a,curcmd
  1073.     out    vccmd        ;to get scrolling address
  1074.     call    vwait        ; may be unnecessary ??
  1075.     in    vcrdat
  1076.     mov    h,a
  1077.     mvi    a,curcmd+1    ;get low byte
  1078.     out    vccmd
  1079.     call    vwait
  1080.     in    vcrdat
  1081.     mov    l,a
  1082.     ret
  1083. ;
  1084. ;--------------------
  1085. ;
  1086. ; wait, set DE attribute addr, stroke
  1087. ;
  1088. attadr:    mov    a,d        ;qualify D for attribute space
  1089.     ani    07h
  1090.     ori    08h
  1091.     jr    xadr1
  1092. ;
  1093. ; wait, set DE data address, stroke
  1094. ;
  1095. datadr:    mov    a,d        ;qualify DE for data space
  1096.     ani    07h
  1097. xadr1:    mov    d,a
  1098. xadr2:    in    vcstat
  1099.     ral
  1100.     jrnc    xadr2
  1101. ;
  1102. ;send DE to reg A, A+1, stroke & wait
  1103. ;
  1104. ;setrw:
  1105.     mvi    a,hiadd
  1106.     out    vccmd
  1107.     mov    a,d
  1108.     out    vcrdat
  1109.     mvi    a,loadd
  1110.     out    vccmd
  1111.     mov    a,e
  1112.     out    vcrdat
  1113.     mvi    a,strcmd    ;stroke chip
  1114.     out    vccmd
  1115. vwait:    in    vcstat
  1116.     ral
  1117.     jrnc    vwait
  1118.     ret
  1119.  
  1120. ;----------------------------------------
  1121. ;
  1122. ; DATA AREA
  1123.  
  1124. bincol:    db    0    ;pair
  1125. binrow:    db    0
  1126. ;
  1127. curcol:    db    0
  1128. currow:    db    0
  1129. ;
  1130. Zrub:    db    BS,SPACE,BS+80H    ;rub-out previous char
  1131. ;
  1132. ;****************************************
  1133. ;
  1134. ;  TERMINAL-SPECIFIC data
  1135. ;
  1136. svcrsor:lxi    h,Zsavec    ;save cursor & push state in bios rom
  1137.     jr    jputs
  1138. ;
  1139. ; turn on normal video
  1140. ;
  1141. normal:    lxi    h,Znorm
  1142. jputs:    call    jjputs
  1143.     ora    a        ;clr CY
  1144.     ret
  1145. ;
  1146. ; turn on reverse video
  1147. ;
  1148. reverse:lxi    h,Zrev
  1149.     jr    jputs
  1150. ;
  1151.  
  1152. ; Kaypro '84 video strings
  1153. ;
  1154. Zsavec:    .ascis    [1bh]'B6'    ;save cursor location
  1155. Zrestc:    .ascis    [1bh]'C6'    ;restore it
  1156. ;
  1157. Zcurs:    .ascii    [1bh]'='    ;set cursor to
  1158. colrow:    db    SPACE,SPACE    ; row,col - modified in-line
  1159.     db    NUL        ;must have following NUL
  1160. ;
  1161. Zrev:    .ascii    [1bh]'B0'    ; reverse video
  1162.     .ascis    [1bh]'B1'    ; with 1/2 intensity
  1163. Znorm:    .ascii    [1bh]'C0'    ; normal video
  1164.     .ascis    [1bh]'C1'    ; with full intensity
  1165. ;
  1166. ; !! this causes momentary flashing, can we do it elsewhere?
  1167. ;
  1168. Zoneat:    .ascii    [1bh]'B3 '
  1169.     .ascis    [1bh]'C3'
  1170. ;
  1171. .ifg DEBUG, [ 
  1172. Zclr:    db    1Ah,NUL        ;kaypro
  1173.     ]
  1174. ;
  1175. ;
  1176. ;================================
  1177. ;
  1178. ; JOTPAD BANNER - just 2 lines' worth
  1179. ;
  1180. ; 1. Clear screen.
  1181. ; 2. Remind user of usage, to extent space is available.
  1182. ;    The editing keys are those supported by the terminal itself.
  1183. ;
  1184. Zbanner:
  1185.     db    1ah        ;clear screen KAYPRO-SPECIFIC
  1186. ;
  1187. .ascii    'JOT: <SUSPEND>=exit, ^Paste'
  1188.     db    CR,LF
  1189. .ascii    'ESC E/ESC R=ins/del line'
  1190.  
  1191. ; NO ROOM FOR THIS !
  1192. ; if turborom-->
  1193. ;.ascii    'Cntl-A = insert char.  Cntl-B = delete char.         '
  1194. ;
  1195. Zcrlf:    db    CR,LF+80h
  1196.  
  1197. ;
  1198. .slist
  1199. .list
  1200. codlen = .-start        ;length of code
  1201. .rlist
  1202. ;
  1203. ;++++++++++++++++++++++++++++++
  1204. .remark \==
  1205. Debugging stragegy:
  1206.     Assemble screendriver at 100h.
  1207.     Load with Z80 debugger.
  1208.     Clear ram buffers.
  1209.     Set breakpoints as needed.
  1210.     Call these test routines and inspect buffers.
  1211. ==\
  1212.  
  1213. .ifg DEBUG, [
  1214. dbg0 = .
  1215. ;
  1216. ; these emulate the external BGii routines
  1217. ; using ram buffers for debugging
  1218. ;
  1219. bwrch:    push    h
  1220.     lhld    dbgptr        ;put to debug cut buffer
  1221.     mov    m,c
  1222.     inx    h
  1223.     shld    dbgptr
  1224.     pop    h
  1225.     ret
  1226. ;
  1227. bflush:    ret
  1228. ;
  1229.  
  1230. ;bios display-a-string
  1231. ;    nul/8-bit terminated string at hl
  1232. ;    preserves bc,de,hl
  1233. ;
  1234. puts:    push    h    ;save hl, outch save bc,de
  1235. ..0:    mov    a,m
  1236.     rlc
  1237.     srlr    a    ;shift right logical (register) A
  1238.     inx    h
  1239.     jrz    ..1
  1240.     push    psw
  1241.     call    outch
  1242.     pop    psw
  1243.     jrnc    ..0
  1244. ..1:    pop    h
  1245.     ret
  1246. ;
  1247. ; char in A to conout, preserve bc,de,hl 
  1248. ;
  1249.  
  1250. outch:    push    b
  1251.     push    d
  1252.     push    h
  1253.     mov    c,a
  1254.     call    conout
  1255.     pop    h
  1256.     pop    d
  1257.     pop    b
  1258.     ret
  1259. ;
  1260. ; Various routines for debugging in ram.
  1261. ;
  1262. TSTACK = 05000h        ;test stack, above bank-switching
  1263.  
  1264. tdump:    lxi    b,0ffffh    ;fetch scr, set ptr
  1265.     lxi    d,0        ;from row 0,col 0
  1266.     call    dmpchr
  1267. ;
  1268. tdump2:    lxi    b,0
  1269.     call    dmpchr
  1270. ;
  1271. tdump3:    lxi    d,100h + 0
  1272.     lxi    b,00ffh
  1273.     call    dmpchr
  1274. ;
  1275. tdump4:    lxi    d,3000h        ;out of range test
  1276.     lxi    b,00ffh
  1277.     call    dmpchr
  1278.     rst    7
  1279. ;
  1280. ;
  1281. clear:    lxi    h,Zclr        ;clear screen
  1282.     call    jjputs
  1283.     rst    7
  1284. ;
  1285. flood:    lxi    h,Zflood    ;write to screen
  1286.     call    jjputs
  1287.     rst    7
  1288. Zflood:    .ascii    '=======TESTING======='
  1289.     db    0
  1290. ;
  1291. tsave:    lxi    sp,TSTACK    ;save screen
  1292.     call    savscr
  1293.     rst    7
  1294.  
  1295. trest:    lxi    sp,TSTACK    ;restore screen
  1296.     call    resscr
  1297.     rst    7
  1298.  
  1299. tmark:    lxi    sp,TSTACK    ;set a mark
  1300.     call    savscr
  1301.     call    sttop        ;so debugger doesn't scroll screen
  1302. ..0:    call    conin
  1303.     call    setmrk
  1304.     jnc    ..0
  1305. ;    rst    7
  1306.     nop
  1307. ;
  1308. tcut:    lxi    h,cutbuf        ;clear buffer
  1309.     mvi    m,0
  1310.     lxi    d,cutbuf+1
  1311.     lxi    b,2*80h
  1312.     ldir
  1313.     call    cutrg            ;cut region
  1314.     call    setbot            ;put cursor out of way
  1315.     rst    7
  1316.  
  1317. ; place cursor nerar bottom or top
  1318. ;
  1319. setbot:    lxi    h,100h*(20h+18) +20h
  1320.     jr    sttop1
  1321. sttop:    lxi    h,2020h
  1322. sttop1:    shld    colrow
  1323.     lxi    h,Zcurs        ;send set-cursor string
  1324.     jmp    jjputs
  1325. ;
  1326. dbgptr:    dw    0
  1327. .slist
  1328. .list
  1329. dbglen = . - dbg0
  1330. .rlist
  1331.     ]
  1332. ;++++++++++++++++++++++++++++++
  1333. ;
  1334. .list
  1335.  
  1336. ; SCREEN BUFFER STRUCTURE
  1337. ;
  1338. ; The rest of the 4K block is available
  1339. ; for the screen image and other data.
  1340.  
  1341. xbreq    = 2 + NROWS*NCOLS + (NROWS*NCOLS)/2    ;required space
  1342. ;
  1343.  
  1344. .ifg    DEBUG, [
  1345. ;
  1346. ; put buffer on even byte ( for attributes)
  1347. bstart    =    start + 800h    ;make some room
  1348.     ]
  1349. ;
  1350.     [
  1351. ; put buffer at end of 4K area, to just fit
  1352. bstart    =    (start + 400h) + (3*400h-xbreq)
  1353.  
  1354. short =    start+codlen-bstart
  1355. xfree = - short
  1356.  
  1357. .ifg (short), [
  1358.     .prntx    '[07]Code overflows buffer!'
  1359.     ]
  1360.  
  1361.     ]
  1362.  
  1363. ;
  1364. ; addresses:
  1365. ;
  1366. bcursor =    bstart        ;cursor location in saved screen
  1367. buf    =    bcursor+2    ;start of screen buffer
  1368. ;
  1369. ;buffer uses (25 lines x 80 chars) + 1/2 that for attributes
  1370. ;
  1371. bufend    =    buf + 25*80 + (25*80)/2    
  1372.                     
  1373. ;
  1374. .ifg DEBUG, [
  1375. ;
  1376. ; put cutbuffer in ram for debugging
  1377. ;
  1378. datcut    =    bstart+10h+3*400h
  1379. cutbuf    =    datcut
  1380.     ]
  1381.  
  1382. .xlist
  1383. .remark \======================
  1384.  
  1385. This routine is needed to calculate locations of mark1, mark2
  1386. if cursor movements are not restricted to DOWN and RIGHT after
  1387. 1st mark is set.  Not used in current implementation.
  1388. ; 
  1389. ; Code for minimum calc::
  1390. ;
  1391. ; stored row, col
  1392. ; set    mark1(row,col) = min row,min col
  1393. ;    mark2(row,col) = max row,max col
  1394. ;    ctcols = #cols, ctrows = # rows
  1395. ;
  1396. corners:lxi    d,mark1
  1397.     lxi    h,mark2
  1398.     ldax    d        ;col 1 = min(col1,col2)
  1399.     mov    b,m
  1400.     cmp    b
  1401.     jrc    ..1        ;cy if 1 < 2
  1402.     mov    m,a        ;exchange
  1403.     mov    a,b
  1404.     stax    d
  1405. ..1:    inx    h        ;row 1...
  1406.     inx    d
  1407.     ldax    d        ;row 1 = min(row1,row2)
  1408.     mov    b,m
  1409.     cmp    b
  1410.     jrc    ..2
  1411.     mov    m,a
  1412.     mov    a,b
  1413.     stax    d
  1414. ..2:    ldax    d        ;row1
  1415.     sub    m        ; - row2
  1416.     cma            ; gives (row2 - row1 - 1)
  1417.     inr    a
  1418.     inr    a
  1419.     sta    ctrows
  1420.     dcx    h
  1421.     dcx    d
  1422.     ldax    d
  1423.     sub    m
  1424.     cma
  1425.     inr    a
  1426.     inr    a
  1427.     sta    ctcols
  1428.     ret
  1429. ;
  1430. =========================\
  1431.  
  1432.     .end    jjcons
  1433. 0 + (25*80)/2    
  1434.                     
  1435. ;
  1436. .ifg DEBUG, [
  1437. ;
  1438. ; put c