home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / PROGRAMS / BKGRONDR / BGIIDRV.LBR / K8384FNK.AQM / K8384FNK.ASM
Assembly Source File  |  2000-06-30  |  7KB  |  379 lines
  1. .title    "K8384FNK.asm Kaypro function key overlay for BGii 11/8/86"
  2. .sbttl    "Copyright (c) 1986  Plu*Perfect Systems"
  3. ;
  4. ;
  5. ; NOTE >>>  Kaypro Universal rom not supported - just a dummy routine
  6. ;
  7. ; 8080 instruction set for CDL/TDL assembler.
  8. ;
  9. .ident    KAYFNK
  10. .pabs
  11. .phex
  12. .xsym
  13. .xlist
  14.  
  15. ; This overlay customizes the terminal's function keys for BGii.
  16. ;
  17. ; The first sector is an ascii identification.
  18. ;
  19. ; The next two sectors are a table of 8-bit codes
  20. ; for each function key, and an associated 4-character label.
  21. ;
  22. ; The following sectors are the function-key overlay.  It is called to:
  23. ;
  24. ; 1. initialize the terminal's function keys to the 8-bit codes
  25. ; 2. to shift (activate) the 8-bit codes
  26. ; 3. to unshift the 8-bit codes, restoring whatever codes were there
  27. ; 4. to save/restore those codes for each task
  28. ; 5. to deinitialize, restoring the user's codes when BG is removed.
  29. ;
  30. ; 
  31. MAXLEN    equ    6*80H        ;MAX SIZE OF OVERLAY
  32. MAXCOD    equ    200h        ;MAX size of code & initialized data
  33. ;
  34. FNKSIZ    equ    18        ;18 arrow and numeric keypad keys
  35. MAXTAB    equ    3*FNKSIZ
  36. ;
  37. release    equ    '0'
  38. vers    equ    '5'
  39. ;
  40. NUL    EQU    0
  41. TRUE    EQU    0FFh
  42. ;
  43. ;===============================
  44. ; Identification sector at 3e80h
  45. ;
  46.     .loc    3e80h
  47. fnkyid:    .ascii    "Kaypro '83 & '84 fn-key overlay v. "
  48.     db    RELEASE
  49.     db    '.'
  50.     db    VERS
  51.     db    0        ;NUL-terminated string
  52. ;
  53. ;================================== 
  54. ; Table of Function-key 8-bit codes and associated labels at 3f00h.
  55. ; Each entry is a 1-byte key value, followed by a 4-byte ascii label.
  56. ;
  57.     .loc    3f00h
  58. ;
  59. labtbl:    db    nm8kys        ;number of keys
  60. ;
  61. fstky:    db    80h        ;1st 8-bit code
  62.     .ascii    "UP  "        ;its label
  63.     db    81h
  64.     .ascii    "DOWN"
  65.     db    82h
  66.     .ascii    "LEFT"
  67.     db    83h
  68.     .ascii    "RGHT"
  69.     db    84h
  70.     .ascii    "key0"
  71.     db    85h
  72.     .ascii    "key1"
  73.     db    86h
  74.     .ascii    "key2"
  75.     db    87h
  76.     .ascii    "key3"
  77.     db    88h
  78.     .ascii    "key4"
  79.     db    89h
  80.     .ascii    "key5"
  81.     db    8ah
  82.     .ascii    "key6"
  83.     db    8bh
  84.     .ascii    "key7"
  85.     db    8ch
  86.     .ascii    "key8"
  87.     db    8dh
  88.     .ascii    "key9"
  89.     db    8eh
  90.     .ascii    "key-"
  91.     db    8fh
  92.     .ascii    "key,"
  93.     db    90h
  94.     .ascii    "ENTR"
  95.     db    91h
  96.     .ascii    "key."
  97. ;
  98. nm8kys     equ    (.-fstky)/(1+4)
  99. ;
  100. .ifg (. - labtbl - 100h), [
  101.     .prntx    "Overflow in label table"
  102.     ]
  103.  
  104. .ifn (.-fstky)@(1+4), [
  105.     .prntx    "alignment error in labels"
  106.     ]
  107. ;
  108. ;
  109. ;==================================
  110. ; The function-key overlay at 4000h.
  111. ;
  112.     .loc    4000h
  113. ;
  114. ; Enter A = 0 ... 7 function number.
  115. ; After exit, this overlay is written to swap file to preserve
  116. ; changed data.
  117. ;
  118. START:    ora    a        ;*** patched to RET if u-rom, 
  119.                 ;as temporary measure
  120.     jz    init    ;0
  121.     dcr    a
  122.     jz    deinit    ;1
  123.     dcr    a
  124.     jz    ashft    ;2
  125.     dcr    a
  126.     jz    bshft    ;3
  127.     dcr    a
  128.     jz    aunshft    ;4
  129.     dcr    a
  130.     jz    bunshft    ;5
  131.     dcr    a
  132.     jz    asave    ;6
  133.     dcr    a
  134.     jz    bsave    ;7
  135.     dcr    a
  136.     jz    arest    ;8
  137.     dcr    a
  138.     jz    brest    ;9
  139.     ret        ;not supported
  140. ;
  141. ;-----------------
  142. ; Function 0. INIT.
  143. ; This routine is called when BG is first loaded.
  144. ;
  145. ; Determine version of Kaypro bios and parameter values/addresses.
  146. ; Save initial state of function keys.
  147. ; Install 8-bit function key codes for BG.
  148. ;
  149. INIT:    call    ckurom        ;check type of Kaypro bios
  150.     jnz    iniuro
  151. ;
  152. ; Non-U-rom Kaypro bios.
  153. ; It has 18 1-byte function key table at bios + 35h.
  154. ;
  155. ;
  156. notu:    lxi    h,FNKSIZ    ;table size is 17 bytes
  157.     shld    tabsiz
  158.     lhld    0001h        ;table is at bios+35h
  159.     mvi    l,35h
  160.     shld    tabptr
  161.     xra    a        ;set flag
  162.     sta    uromq
  163. ;
  164.     push    h        ;save initial table
  165.     lxi    d,usrtab
  166.     call    movit
  167.     pop    h
  168.     push    h
  169.     lxi    d,Atab
  170.     call    movit
  171.     pop    h
  172.     lxi    d,Btab
  173.     call    movit
  174. ;
  175. ; set bios function key table to these 8-bit single characters:
  176. ;     80h ... 91h sequential bytes
  177. ;
  178. set8b:    lda    uromq
  179.     ora    a
  180.     jnz    set8u
  181. ;
  182. ; Non-u rom. install sequential 80h ... 91h bytes
  183. ;
  184.     lhld    tabptr
  185.     mvi    a,80h
  186. st8lp:    mov    m,a
  187.     inx    h
  188.     inr    a
  189.     cpi    80h+FNKSIZ
  190.     jnz    st8lp
  191.     ret
  192. ;
  193. ;------------------------------
  194. ; >>>> CODE FOR A "Kaypro Universal Rom" is incomplete. <<<<
  195. ;
  196. ; At the moment is makes the functionkey driver simply do nothing
  197. ; and return on all calls.
  198. ;
  199. ; U-rom.  Set bios function-key table to send 80h ... 91h .
  200. ;
  201. set8u:
  202.     ret
  203. ;
  204. ;
  205. ;
  206. ; Check for U-rom.     Exit: NZ if u-rom.
  207. ;
  208. ; Turborom has 8-byte checksummed "PPS" signature at 0fff8h.
  209. ; U-rom has 8-byte checksummed area at same address.
  210. ;
  211. ckurom:    lxi    h,0FFF8h    ;checksum top 8 bytes of ram
  212.     mov    a,m
  213.     ora    a
  214.     rz            ;NUL is no signature
  215.     push    h
  216.     xra    a
  217.     mvi    b,8
  218. cks1:    add    m
  219.     inx    h
  220.     dcr    b
  221.     jnz    cks1
  222.     ora    a
  223.     pop    h
  224.     jz    ckturb        ;cksum is ok
  225.     xra    a        ;return Z
  226.     ret
  227. ckturb:    mov    a,m        ;checksum is ok, see if "PPS"
  228.     cpi    'P'        ;signature for Turborom
  229.     rnz            ;assume universal rom if not
  230.     inx    h
  231.     mov    a,m
  232.     cpi    'P'
  233.     rnz
  234.     inx    h
  235.     mov    a,m
  236.     cpi    'S'
  237.     ret
  238. ;
  239.     
  240. ; U-rom Kaypro bios
  241. ; It has a structure of 18 variable-length strings.
  242. ; Structure (appears to be):
  243. ;    cnt byte
  244. ;    index byte
  245. ;    ....
  246. ;    string 0
  247. ;    string 1
  248. ;    ...
  249. ;
  250. ;  -- FILL THIS IN !
  251. ;
  252. iniuro:
  253.     mvi    a,RET        ;******* TEMPORARY -- FORCE
  254.     sta    start        ;THIS MODULE TO DO NOTHING AT ALL
  255.     ret
  256. ;
  257. ; -- FIX THIS
  258. ;...
  259.     lxi    h,3*FNKSIZ    ; CORRECT ??
  260.     shld    tabsiz
  261. ; set ptr
  262. ; ;    lxi    h,???
  263. ;;    shld    tabptr
  264.     xra    a        ;set flag
  265.     dcr    a
  266.     sta    uromq
  267.     ret
  268. ;
  269.  
  270. ; 
  271.     lxi    d,usrtab
  272.     call    movit
  273. ; + ......
  274.  
  275.     ret
  276.  
  277. ;-----------------------------
  278. ; save key table from bios to (DE)
  279. ;
  280. savtab:    lhld    tabptr
  281. ;
  282. ; move 'tabsiz' bytes from (hl) to (de)
  283. ;
  284. movit:    lbcd    tabsiz
  285.     ldir
  286.     ret
  287. ;
  288. ;-------------------
  289. ; Function 1. DEINIT.
  290. ; Restore user's function key table when BG was loaded.
  291. ;
  292. DEINIT:    lxi    h,usrtab        ;reinstall user's keys
  293. ;
  294. ; put table at (HL) into bios
  295. ;
  296. puttab:    lded    tabptr
  297.     jmp    movit
  298. ;
  299. ;----------------------
  300. ; Functions 2, 3. SHIFT.
  301. ; Save current bios function keys.
  302. ; Set bios to 8-bit function key mode.
  303. ; 
  304. ; "A" refers to the initial task, "B" to the Alternate task.
  305. ;
  306. ASHFT:    lxi    d,Atab        ;buffer address
  307. ashft1:    call    savtab        ;save bios keys there
  308.     jmp    set8b        ;and set 8bit keys
  309. ;
  310. BSHFT:    lxi    d,Btab
  311.     jmp    ashft1
  312. ;
  313. ;------------------------
  314. ; Functions 4, 5. UNSHIFT.
  315. ; Restore current bios function keys.
  316. ; 
  317. ;
  318. AUNSHF:    lxi    h,Atab
  319.     jmp    puttab
  320.  
  321. ;
  322. BUNSHF:    lxi    h,Btab
  323.     jmp    puttab
  324. ;
  325. ;---------------------
  326. ; Functions 6, 7. SAVE.
  327. ; Save current bios function keys in preparation for task swap.
  328. ;
  329. ASAVE:    lxi    d,Asvtab
  330.     jmp    savtab
  331. ;
  332. BSAVE:    lxi    d,Bsvtab
  333.     jmp    savtab
  334. ;
  335. ;------------------------
  336. ; Functions 8, 9. RESTORE.
  337. ; Restore current bios function keys following task swap.
  338. ;
  339. AREST:    lxi    h,Asvtab
  340.     jmp    puttab
  341. ;
  342. BREST:    lda    Bfirst        ;on first swap,
  343.     ora    a        ; there's nothing to restore
  344.     mvi    a,0
  345.     sta    Bfirst
  346.     rnz
  347.     lxi    h,Bsvtab
  348.     jmp    puttab
  349. ;
  350. ;--------------------------
  351. ;
  352. tabptr:    dw    0
  353. tabsiz:    dw    0        ;length of function key table
  354. uromq:    db    0        ;NZ if urom
  355. Bfirst:    db    TRUE        ;static TRUE
  356. ;
  357. undata equ .
  358. .ifg (undata - start - MAXCOD), [
  359.     .PRNTX    "Code exceeds maximum!"
  360.     ]
  361. ;
  362. ; Unitialized Data area.
  363. ;
  364. Usrtab:    ds    MAXTAB
  365. Atab:    ds    MAXTAB
  366. Btab:    ds    MAXTAB
  367. Asvtab:    ds    MAXTAB
  368. Bsvtab:    ds    MAXTAB
  369. ;
  370. .slist
  371. .list
  372. LENGTH equ . - START
  373. .ifg (length - MAXLEN), [
  374.     .prntx    "Overflow in Key Overlay module!"
  375.     ]
  376. .rlist
  377.     .end
  378.  
  379. jmp    pu