home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / PACKET / PACKET89.LBR / KERNEL.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  30KB  |  993 lines
  1. ;                    PACKET89.ASM
  2. ;        Derived 12/15/89 from the MODEM Controller, MPLINK
  3. ;               (H19/H89 version of 7/1/81)
  4. ;
  5. ;PLINK IS A CP/M TRANSIENT COMMAND WHICH ALLOWS THE USER TO
  6. ;ESTABLISH A COMMUNICATIONS LINK WITH A REMOTE COMPUTER
  7. ;
  8. ;       ORIGINAL BY L.E. HUGHES    EDCAM        JULY, 1977
  9. ;
  10. ;          WITH HEATH EQUATES ADDED BY TOM JORGENSON.
  11. ;          Optional Triger characters by Steve Vinokuroff.
  12. ;
  13. ;       Revised by Ray Isenson, N6UE┼to∩ interface pacet⌠ NCN├ and
  14. ;       give control of the Lineprinter to the BDOS (12/89)
  15. ;     
  16. ;This version is modified to use the H19/H89 special function keys.
  17. ;It will run on a non-Heath CPU using the H19 terminal; however, if
  18. ;such a system is used, the following equate should be set to zero:
  19. ;
  20. H8ORH89 EQU     1       ;IF H8 OR H89 COMPUTER SET TO 1
  21. ;
  22. ;
  23. ;PLINK CURRENTLY SUPPORTS TWO WAY TRANSFER OF TEXT FILES
  24. ;BETWEEN THE CP/M DISK AND THE REMOTE COMPUTER. THE FOLLOWING
  25. ;CONTROL CODES MAY BE INITIATED FROM THE CONSOLE KEYBOARD:
  26. ;
  27. ;       ****************************************************
  28. ;       *                     COMMANDS:                    *
  29. ;       *                                                  *
  30. ;       *  F1 KEY       SAVE INCOMING ASCII IN RAM BUFFER  *
  31. ;       *               FOR LATER TRANSFER TO DISK         *
  32. ;       *  F2 KEY       WRITE RAM BUFFER TO DISK - ASKS    *
  33. ;       *               FOR DRIVE AND FILENAME.TYP         *
  34. ;       *  F3 KEY       TRANSMIT ASCII FILE TO MODEM.      *
  35. ;       *               ASKS FOR DRIVE AND FILENAME.TYP    *
  36. ;       *  F4 KEY       AUTO LOGON                         *
  37. ;       *  F5 KEY       COPY TO PRINTER SWITCH             *
  38. ;       *  RED KEY      EXIT PLINK TO CP/M WARM BOOT       *
  39. ;       *  CONTROL-C    ABORT FILE SEND TO MODEM           *
  40. ;       *  DELETE       BACKSPACE WHEN IN COMMAND MODE     *
  41. ;       *               ASKING FOR FILENAME                *
  42. ;       *  BACKSPACE    SAME AS DELETE                     *
  43. ;       *  CONTROL-U    ABORT CURRENT LINE WHEN IN COMMAND *
  44. ;       *               MODE ASKING FOR FILENAME           *
  45. ;       *                                                  *
  46. ;       ****************************************************
  47. ;
  48. ;
  49. ;SET NUMBER OF DRIVES FOR PARTICULAR SYSTEM
  50. ;       E.G. 2 = A,B    5 = A,B,C,D,E
  51. ;
  52. NUMDRV  EQU     5       ;ALLOW A: AND B: ONLY
  53. ;
  54. ;
  55. ;BDOS ENTRY POINT AND FUNCTION CODES
  56. ;
  57. BASE    SET     0       ;STANDARD CPM
  58. ;
  59. BDOS    EQU     BASE+5
  60. RESDSK  EQU     13      ;RESET DISK SYSTEM
  61. OFFC    EQU     15      ;OPEN FILE
  62. CFFC    EQU     16      ;CLOSE FILE 
  63. DFFC    EQU     19      ;DELETE FILE
  64. RRFC    EQU     20      ;READ RECORD
  65. WRFC    EQU     21      ;WRITE RECORD 
  66. MFFC    EQU     22      ;MAKE FILE
  67. LSTOUT  EQU     5       ;PRINTER OUTPUT
  68. ;
  69. ;DEFAULT FCB AND FIELD DEFINITIONS 
  70. ;
  71. FCB     EQU     BASE+5CH
  72. FN      EQU     1       ;FILE NAME FIELD (REL)
  73. FT      EQU     9       ;FILE TYPE FIELD (REL)
  74. EX      EQU     12      ;FILE EXTENT FIELD (REL)
  75. NR      EQU     32      ;NEXT RECORD FIELD (REL)
  76. DBUF    EQU     BASE+80H ;DEFAULT DISK BUFFER ADDRESS
  77. ;
  78. ;ASCII CONTROL CHARACTERS
  79. ;
  80. CR      EQU     0DH     ;CARRIAGE RETURN
  81. LF      EQU     0AH     ;LINE FEED
  82. DEL     EQU     7FH     ;DELETE (RUBOUT)
  83. BELL    EQU     07H     ;BELL SIGNAL
  84. TAB     EQU     09H     ;HORIZONTAL TAB
  85. XON     EQU     11H     ;X-ON CHARACTER
  86. NULL    EQU     00H     ;NULL CHAR
  87. ESC     EQU     1BH     ;ESCAPE
  88. BL      EQU     20H     ;BLANK (SPACE)
  89. ;
  90. ;
  91. ;SPECIAL HEATH ONLY BIOS EQUATES
  92. ;
  93. TICCNT  EQU     0BH     ;2 MSEC COUNTER
  94. ;
  95. ;
  96. ;THE FOLLOWING "TRIGER" EQUATE IS SET TO "LF" (LINEFEED)
  97. ;BY DEFAULT. AN OPTIONAL TRIGER CHAR MAY BE PASSED VIA FCB1
  98. ;
  99. ; IE: KERNEL B          WILL SET TRIGER TO "BELL"
  100. ;
  101. ;THE FOLLOWING OPTIONS ARE ALLOWED
  102. ;
  103. ;       1. B = BELL  07H
  104. ;       2. X = XON   11H
  105. ;       3. U = UPLOAD NO TRIGER CHECK AT ALL
  106. ;ANY OTHER ASCII CHARACTER MAY BE PASSED THROUGH FCB1
  107. ;
  108. ;
  109. TRIGER  EQU     LF      ;DEFAULT VALUE
  110. ;
  111. ;
  112. ;WARNING CHARACTER FOR LOW MEMORY
  113. ;
  114. WRNSIG  EQU     BELL    ;IF YOU HAVE ONE, PUT 'BELL' HERE
  115.                         ;...ELSE PUT '*' HERE.
  116. ;
  117. ;MODEM I/O PORT ADDRESSES
  118. ;
  119. MODD    EQU     330Q    ;MODEM BASE PORT
  120. MODS    EQU     MODD+5  ;MODEM STATUS PORT
  121. ;
  122. ;
  123. ;MODEM STATUS PORT BIT DEFINITIONS
  124. ;
  125. MTBE    EQU     20H     ;TRANSMITTER READY FLAG
  126. MRDA    EQU     1H      ;RECEIVER READY FLAG
  127. MXOR    EQU     21H     ;TO COMPLEMENT MTBE AND MRDA
  128. ;
  129. ;       **MAIN PROGRAM**
  130. ;
  131.         ORG     BASE+100H
  132. ;
  133. ;
  134. LINK:   CALL    INIT    ;INITIALIZE
  135. ;
  136. ;        MAIN LOOP 
  137. ;
  138. LINK3:  CALL    CITEST  ;JUMP IF NO DATA FROM CONSOLE 
  139.         JZ      LINK4
  140.         CALL    RCC     ;ELSE READ CONSOLE DATA
  141.         CPI     ESC
  142.         CZ      PCC     ;CALL PCC IF ESC (FUNCTION KEY)
  143.         JZ      LINK4   ;JUMP IF PCC HANDLED CHAR 
  144.         ORI     80H     ;ELSE SET VALID DATA BIT
  145.         STA     INCH    ;AND STORE IN INPUT CHAR BUFFER 
  146. LINK4:  LDA     OUTCH   ;JUMP IF NO DATA FOR CONSOLE
  147.         ORA     A
  148.         JP      LINK5
  149.         ANI     7FH     ;ELSE DISCARD VALID DATA BIT
  150.         CALL    WCC     ;SEND CHAR TO CONSOLE 
  151.         XRA     A       ;THEN CLEAR OUTPUT CHAR BUFFER
  152.         STA     OUTCH
  153. LINK5:  CALL    MITEST  ;JUMP IF NO DATA FROM MODEM 
  154.         JZ      LINK6
  155.         CALL    RMC2    ;ELSE READ MODEM DATA
  156.         CALL    SAVE    ;SAVE CHAR IN TEXT BUFFER IF FLAG ON
  157.         ORI     80H     ;SET DATA VALID BIT 
  158.         STA     OUTCH   ;STORE IN OUTPUT CHAR BUFFER
  159. LINK6:  CALL    MOTEST  ;JUMP IF MODEM XMIT BUFFER BUSY 
  160.         JZ      LINK7
  161.         LDA     INCH    ;JUMP IF NO DATA FOR MODEM
  162.         ORA     A
  163.         JP      LINK7
  164.         ANI     7FH     ;DISCARD VALID DATA BIT
  165.         OUT     MODD    ;OUTPUT CHAR TO MODEM 
  166.         XRA     A       ;...THEN CLEAR INPUT CHAR BUFFER 
  167.         STA     INCH 
  168. LINK7:  JMP     LINK3   ;END OF MAIN LOOP 
  169.  
  170. ;
  171. ;        PCC - PROCESS CONTROL CHARACTER 
  172. ;
  173. ;BECAUSE THIS SECTION USES THE HEATH HARDWARE CLOCK, THE PROGRAM
  174. ;WILL NOT RUN ON OTHER CP/M 2.X SYSTEMS UNLESS A SOFTWARE TIMING
  175. ;LOOP IS SUBSTITUTED FOR THE NEXT 8 STATEMENTS.  THOSE 8 STATEMENTS
  176. ;ARE NOT NECESSARY UNLESS ONE WISHES TO SEND 'ESC' CHARACTERS
  177. ;FROM THE CONSOLE TO THE MODEM.  WITHOUT THESE TIMING STATEMENTS
  178. ;'ESC' MUST BE HIT TWICE TO BE TRANSMITTED ONCE.
  179. ;
  180. PCC:    EQU     $
  181.         IF      H8ORH89
  182.         LDA     TICCNT  ;CHECK FOR SPECIAL FUNCTION KEY
  183.         ADI     10      ;WAIT 20 MSEC FOR NEXT CHAR
  184.         MOV     C,A
  185. ESCTIM: LDA     TICCNT
  186.         CMP     C
  187.         JZ      PCC6    ;IF TOO LONG, NOT SPEC FUCNTION KEY
  188.         CALL    CITEST
  189.         JZ      ESCTIM  ;LOOP UNTIL CONSOLE INPUT
  190.         ENDIF
  191.         CALL    RCC     ;ESC RECEIVED, GET NEXT CHAR FOR FUNCTION
  192.         CPI     'Q'     ;'RED' KEY MEANS EXIT TO CP/M
  193.         JNZ     PCC1 
  194.         PUSH    H
  195.         LHLD    SIZE
  196.         MOV     A,H
  197.         ORA     L
  198.         LXI     H,TBNE
  199.         CNZ     WCS     ;PRINT 'TEXT BUFFER NOT EMPTY'
  200.         LXI     H,AYS   ;PRINT 'ARE YOU SURE'
  201.         CALL    WCS
  202.         POP     H
  203.         CALL    RCC     ;GET ANSWER
  204.         CALL    WCC     ;ECHO IT
  205.         ANI     5FH     ;MAKE UPPER CASE
  206.         CPI     'Y'     ;YES?
  207.         JZ      PCCEX   ;EXIT
  208.         CALL    WCCR    ;CRLF
  209.         XRA     A       ;TELL LINK TO IGNORE THIS CHARACTER 
  210.         RET
  211. ;
  212. PCC1:   CPI     'U'     ;'F3' KEY FOR TRANSMIT FILE
  213.         JNZ     PCC2 
  214.         CALL    STF     ;TRANSMIT TEXT FILE TO MODEM
  215.         XRA     A       ;TELL LINK TO IGNORE THIS CHARACTER 
  216.         RET 
  217. ;
  218. PCC2:   CPI     'S'     ;'F1' KEY MEANS SAVE ALL IN RAM
  219.         JNZ     PCC3 
  220.         MVI     A,1     ;TURN ON TEXT SAVE FLAG 
  221.         STA     FLAG 
  222.         LXI     H,PCCMR ;PRINT 'SAVING INCOMING TEXT IN MEMORY'
  223.         CALL    WCS
  224.         XRA     A       ;TELL LINK TO IGNORE THIS CHARACTER
  225.         RET 
  226. ;
  227. PCC3:   CPI     'T'     ;'F2' KEY MEANS SAVE RAM TEXT TO FILE
  228.         JNZ     PCC4 
  229.         XRA     A       ;TURN OFF TEXT SAVE FLAG
  230.         STA     FLAG 
  231.         CALL    WTB     ;WRITE TEXT BUFFER TO DISK
  232.         XRA     A 
  233.         RET 
  234. ;
  235. PCC4:   CPI     'V'     ;'F4' KEY MEANS AUTO LOGON
  236.         JNZ     PCC5
  237.         LXI     H,ALMSG
  238.         CALL    WCS     ;PRINT 'AUTO LOGON'
  239.         LXI     H,ALBUF
  240. AUTOL:  MOV     A,M
  241.         INX     H
  242.         CPI     'Z'-40H ;AUTOLOG DONE ON ^Z
  243.         JZ      ALBRK
  244.         ANA     A       ;ZERO MEANS EOS
  245.         JZ      STRFIN
  246.         CALL    WMC
  247.         CALL    RMWC    ;READ MODEM, WCC IF AVAILABLE
  248.         JMP     AUTOL
  249. ;
  250. STRFIN: CALL    CITEST  ;INPUT FROM CONSOLE
  251.         JNZ     ALBRK   ;ABORT IF SO
  252.         CALL    MITEST
  253.         JZ      STRFIN  ;WAIT FOR CHAR FROM MODEM
  254.         CALL    RMC2
  255.         CALL    WCC
  256.         CPI     ':'     ;NEXT STRING IF MODEM SENDS ':'
  257.         JZ      AUTOL
  258.         CPI     '+'
  259.         JZ      AUTOL
  260.         JMP     STRFIN  ;KEEP WAITING FOR ':' OR '+'
  261. ;
  262. RMWC:   CALL    MITEST  ;READ MODEM & WRITE CONSOLE IF CHAR
  263.         RZ
  264.         CALL    RMC2
  265.         JMP     WCC
  266. ;
  267. ALBRK:  XRA     A
  268.         RET
  269. ;
  270. ALBUF:  DB      'A',0
  271.         DB      'CIS02',CR,0
  272.         DB      CR,0
  273.         DB      0
  274.         DB      '70000,0000',CR,0
  275.         DB      'PASSWORD',CR,0
  276.         DB      'Z'-40H
  277.         DB      0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  278. ;
  279. PCC5:   CPI     'W'     ;'F5' KEY MEANS COPY TO PRINTER
  280.         JNZ     PCC6
  281.         LXI     H,PRTFLG
  282.         MOV     A,M
  283.         CMA
  284.         MOV     M,A     ;COMPLEMENT PRINT FLAG
  285.         ANA     A
  286.         LXI     H,PRTOFF        ;PRINT 'OFF'
  287.         JZ      PRTLAB
  288.         LXI     H,PRTON         ;PRINT 'ON'
  289. PRTLAB: CALL    WCSNP
  290.         XRA     A
  291.         RET
  292. ;
  293. PCC6:   ANA     A       ;LET LINK HANDLE ALL OTHER CONT. CODES
  294.         RET 
  295. ;
  296. PCCEX:  LXI     H,DISMS ;PRINT 'EXIT TO CP/M'
  297.         CALL    WCS
  298.         JMP     BASE    ;EXIT TO WARM BOOT
  299. ;
  300. TBNE:   DB      CR,LF,BELL,'CAUTION: TEXT BUFFER NOT EMPTY',0
  301. AYS:    DB      CR,LF,'EXIT TO CP/M - ARE YOU SURE (Y OR N)?',0
  302. DISMS:  DB      CR,LF,'+++ EXIT TO CP/M +++',CR,LF
  303.         DB      ESC,'j',ESC,'Y',BL+24,BL,ESC,'l',ESC,'k',0
  304. ALMSG:  DB      CR,LF,'AUTOMATIC LOGON',CR,LF,0
  305. PCCMR:  DB      CR,LF,'SAVING INCOMING TEXT IN MEMORY',CR,LF,0
  306. ;
  307. ;        STF - SEND TEXT FILE (TO MODEM) 
  308. ;
  309. STF:    CALL    GFN     ;GET NAME OF DISK FILE TO SEND
  310.         JC      STF6    ;JUMP IF FILE NAME ERROR
  311.         CALL    OPEN    ;TRY TO OPEN SPECIFIED FILE 
  312.         CPI     255     ;JUMP IF FILE NOT FOUND 
  313.         JZ      STF7 
  314. STF1:   CALL    READ    ;READ NEXT RECORD INTO DBUF 
  315.         CPI     1       ;JUMP IF END-OF-FILE
  316.         JZ      STF5 
  317.         LXI     H,DBUF  ;POINT TO DISK BUFFER 
  318.         MVI     C,128
  319. STF2:   CALL    CCTEST  ;CHECK FOR ^C FROM CONSOLE
  320.         MOV     A,M     ;FETCH NEXT CHAR FROM DBUF
  321.         INX     H
  322.         CPI     'Z'-40H ;JUMP IF END-OF-FILE CHARACTER
  323.         JZ      STF5 
  324. OVERL2  CPI     LF      ;IGNORE LINE FEEDS
  325.         JZ      STF4 
  326.         CALL    WMC     ;WRITE CHARACTER TO MODEM 
  327.         CALL    WCC     ;WRITE CHARACTER TO CONSOLE 
  328. OVERL1  CPI     CR      ;JUMP IF NOT CARRIAGE RETURN
  329.         JNZ     STF4 
  330. STF3:   CALL    CCTEST  ;CHECK FOR ^C ABORT
  331.         CALL    MITEST  ;WAIT FOR NEXT MODEM CHARACTER
  332.         JZ      STF3
  333.         CALL    RMC2    ;CHECK MODEM FOR TRIGGER CHAR.
  334. OVERLY  CPI     TRIGER
  335.         JNZ     STF3 
  336.         CALL    WCCR    ;SEND CRLF TO CONSOLE
  337. STF4:   DCR     C       ;LOOP THRU REST OF DBUF 
  338.         JNZ     STF2 
  339.         JMP     STF1    ;GO GET NEXT RECORD FROM DISK 
  340. ;
  341. STF5:   LXI     H,STFSM ;PRINT 'FILE SEND COMPLETE'
  342.         CALL    WCS
  343.         RET 
  344. ;
  345. STF6:   LXI     H,STFS1 ;PRINT 'FILE NAME ERROR'
  346.         CALL    WCS
  347.         RET 
  348. ;
  349. STF7:   LXI     H,STFS2 ;PRINT 'FILE NOT FOUND' 
  350.         CALL    WCS
  351.         RET 
  352. ;
  353. CCTEST: CALL    CITEST  ;CHAR FROM CONSOLE?
  354.         RZ              ;IF NO
  355.         CALL    RCC
  356.         CPI     'C'-40H
  357.         RNZ             ;IGNORE IF NOT ^C
  358.         POP     PSW     ;CLEAR *RET* FROM STACK
  359.         LXI     H,STFSA ;PRINT 'FILE SEND ABORTED'
  360.         CALL    WCS
  361.         RET
  362. ;
  363. STFSM:  DB      'FILE SEND COMPLETE',CR,LF,0
  364. STFS1:  DB      'FILE NAME ERROR',CR,LF,0
  365. STFS2:  DB      'FILE NOT FOUND',CR,LF,0 
  366. STFSA:  DB      CR,LF,'FILE SEND ABORTED',CR,LF,0
  367. ;
  368. ;        SAVE - SAVE CHAR IN TEXT BUFFER IF FLAG ON
  369. ; 
  370. ;        ENTRY CONDITIONS
  371. ;               A - CHARACTER TO SAVE
  372. ;
  373. SAVE:   PUSH    PSW
  374.         LDA     FLAG 
  375.         ORA     A
  376.         JNZ     SAVE1
  377.         POP     PSW
  378.         RET 
  379. ;
  380. SAVE1:  POP     PSW
  381.         CPI     DEL     ;RUBOUT (DEL) ?
  382.         RZ              ;YES, IGNORE IT
  383.         CPI     20H     ;TEST FOR CONTROL CHARACTERS
  384.         JNC     SAVE2   ;JUMP IF NOT CONTROL CHAR.
  385.         CPI     CR      ;ALLOW CR TO BE SAVED
  386.         JZ      SAVE2
  387.         CPI     LF      ;ALLOW LF TO BE SAVED
  388.         JZ      SAVE2
  389.         CPI     TAB     ;ALLOW TAB TO BE SAVED
  390.         JZ      SAVE2
  391.         RET             ;IGNORE ALL OTHER CONTROL CHARS.
  392. ;
  393. SAVE2:  PUSH    H
  394.         LHLD    SIZE    ;SIZE = SIZE + 1
  395.         INX     H
  396.         SHLD    SIZE 
  397.         LHLD    PTR
  398.         MOV     M,A
  399.         INX     H
  400.         SHLD    PTR
  401.         PUSH    PSW
  402.         LHLD    BREM
  403.         DCX     H
  404.         SHLD    BREM
  405.         MVI     A,0FFH
  406.         CMP     H
  407.         JZ      SAVEAB  ;ABORT IF TBUF FILLED
  408.         MVI     A,3
  409.         CMP     H
  410.         MVI     A,WRNSIG  ;SIGNAL CONSOLE RUNNING OUT OF SPACE
  411.         CNC     WCC
  412.         PUSH    H       ;HL = BYTES LEFT IN BUFFER
  413.         LXI     H,BRPOS ;POSITION ON 25TH LINE
  414.         CALL    WCSNP   ;CONSOLE WRITE WITHOUT PRINTER
  415.         POP     H
  416.         CALL    DECOUT  ;OUTPUT HL AS DECIMAL
  417.         LXI     H,RESCP
  418.         CALL    WCSNP   ;RESTORE CURSOR POSITION
  419.         POP     PSW
  420.         POP     H
  421.         RET 
  422. ;
  423. BRPOS:  DB      ESC,'j',ESC,'Y',BL+24,BL+75,ESC,'p',0
  424. PRTON:  DB      ESC,'j',ESC,'Y',BL+24,BL+38,ESC,'pon',ESC,'q ',ESC,'k',0
  425. PRTOFF: DB      ESC,'j',ESC,'Y',BL+24,BL+38,ESC,'poff'
  426. RESCP:  DB      ESC,'q',ESC,'k',0
  427. ;
  428. ;       SAVEAB - RAN OUT OF ROOM, ISSUE MESSAGE AND FLOW
  429. ;                THROUGH TO DISK SAVE ROUTINE
  430. ;
  431. SAVEND: DB      BELL,CR,LF,'ABORTING - NO ROOM LEFT',0
  432. ;
  433. SAVEAB: LXI     SP,STACK+64  ;REINITIALIZE STACK
  434.         LXI     H,SAVEND  ;PRINT 'ABORTING - NO ROOM LEFT'
  435.         CALL    WCS
  436.         LXI     H,LINK  ;SET UP RETURN ADDRESS
  437.         PUSH    H       ;LEAVE IT ON THE STACK
  438. ;
  439. ;        WTB - WRITE TEXT BUFFER TO DISK 
  440. ;
  441. WTB:    LHLD    SIZE    ;JUMP IF TEXT BUFFER EMPTY
  442.         MOV     A,L
  443.         ORA     H
  444.         JZ      WTB5 
  445.         MVI     C,RESDSK ;RESET IN CASE READ-ONLY
  446.         CALL    BDOS
  447.         CALL    GFN     ;GET FILE NAME
  448.         JC      WTB6    ;JUMP IF FILE NAME ERROR
  449.         CALL    DELT    ;DELETE OLD FILE, IF ANY
  450.         CALL    MAKE    ;MAKE NEW FILE
  451.         LHLD    SIZE    ;DE = TBUF SIZE 
  452.         XCHG
  453.         LXI     H,DBUF  ;TOP OF STACK POINTS TO DBUF
  454.         PUSH    H
  455.         LXI     H,TBUF  ;HL POINTS TO TBUF
  456. WTB1:   MVI     C,128   ;DISK BUFFER SIZE 
  457. WTB2:   MOV     A,M     ;FETCH NEXT BYTE OF TBUF
  458.         INX     H
  459.         XTHL
  460.         MOV     M,A     ;STORE IN DBUF
  461.         INX     H
  462.         XTHL
  463.         DCX     D       ;SIZE = SIZE - 1
  464.         MOV     A,D     ;EXIT LOOP IF SIZE = 0
  465.         ORA     E
  466.         JZ      WTB3 
  467.         DCR     C       ;LOOP UNTIL DBUF FULL 
  468.         JNZ     WTB2 
  469.         CALL    WRITE   ;WRITE FULL DBUF TO DISK
  470.         JNZ     NOWRT   ;IF WRITE NOT SUCCESSFUL
  471.         XTHL            ;TOP OF STACK POINTS TO DBUF
  472.         LXI     H,DBUF 
  473.         XTHL
  474.         JMP     WTB1    ;LOOP UNTIL END OF TBUF 
  475. ;
  476. WTB3:   POP     H       ;HL POINTS TO CURRENT PLACE IN DBUF 
  477. WTB4:   MVI     M,'Z'-40H ;STORE EOF CODE 
  478.         INX     H
  479.         DCR     C       ;LOOP THRU REST OF DBUF 
  480.         JNZ     WTB4 
  481.         CALL    WRITE   ;WRITE LAST SECTOR TO DISK
  482.         JNZ     NOWRT1  ;IF WRITE NOT SUCCESSFUL
  483.         CALL    CLOSE   ;CLEAN UP ACT AND GO HOME 
  484.         LXI     H,TBUF  ;CLEAR TEXT BUFFER
  485.         SHLD    PTR
  486.         LXI     H,0
  487.         SHLD    SIZE 
  488.         LXI     H,BRPOS ;SET CURSOR TO WRITE BYTES REMAINING
  489.         CALL    WCSNP
  490.         LHLD    BLEN
  491.         SHLD    BREM    ;REMAINING BUFFER IF BUFFER LENGTH
  492.         CALL    DECOUT
  493.         LXI     H,RESCP ;RESTORE CURSOR POSITION
  494.         CALL    WCSNP
  495.         LXI     H,WTBSM ;PRINT 'BUFFER SAVED ON DISK'
  496.         CALL    WCS
  497.         RET 
  498. ;
  499. NOWRT:  POP     H       ;WRITE FAILS, CLEAR STACK
  500. NOWRT1: LXI     H,NWMSG
  501.         CALL    WCS     ;TELL USER TO TRY AGAIN
  502.         JMP     WTB
  503. ;
  504. WTB5:   LXI     H,WTBS1 ;PRINT 'TEXT BUFFER EMPTY'
  505.         CALL    WCS
  506.         RET 
  507. ;
  508. WTB6:   LXI     H,WTBS2 ;PRINT 'FILE NAME ERROR'
  509.         CALL    WCS
  510.         RET 
  511. ;
  512. NWMSG:  DB      CR,LF,BELL,'DISK OVERFLOW - DO AGAIN',CR,LF,0
  513. WTBSM:  DB      CR,LF,'BUFFER SAVED ON DISK',CR,LF
  514.         DB      'MEMORY SAVE CANCELLED',CR,LF,0
  515. WTBS1:  DB      'TEXT BUFFER EMPTY',CR,LF,0
  516. WTBS2:  DB      'FILE NAME ERROR',CR,LF,0
  517. ;
  518. ;        WCS - WRITE CONSOLE STRING
  519. ;
  520. ; 
  521. ;        ENTRY CONDITIONS
  522. ;               HL - POINTS TO STRING (TERM BY ZERO BYTE)
  523. ;
  524. WCS:    MOV     A,M
  525.         INX     H
  526.         ORA     A
  527.         RZ
  528.         CALL    WCC
  529.         JMP     WCS
  530. ;
  531. ;        WCSNP - WRITE CONSOLE STRING WITHOUT PRINTER OUTPUT
  532. ;
  533. ; 
  534. ;        ENTRY CONDITIONS
  535. ;               HL - POINTS TO STRING (TERM BY ZERO BYTE)
  536. ;
  537. WCSNP:  MOV     A,M
  538.         INX     H
  539.         ORA     A
  540.         RZ
  541.         CALL    WCCNP
  542.         JMP     WCSNP
  543. ;
  544. ;        WCCR - WRITE CONSOLE CARRIAGE RETURN (AND LINE FEED)
  545. ;
  546. WCCR:   MVI     A,CR 
  547.         CALL    WCC
  548.         MVI     A,LF 
  549. ;
  550. ;        WCC - WRITE CONSOLE CHARACTER 
  551. ; 
  552. ;        ENTRY CONDITIONS: 
  553. ;               A - CHARACTER TO WRITE 
  554. ;
  555. WCC:    PUSH    PSW
  556.         PUSH    B
  557.         PUSH    D
  558.         PUSH    H
  559.         MOV     C,A     ;GET CHARACTER FOR CBIOS
  560.         PUSH    B
  561. WCCAL:  CALL    $-$     ;MODIFIED BY INIT.
  562.         POP     B       ;C = CHAR
  563.         LDA     PRTFLG
  564.         ANA     A
  565.         CNZ     PRTOUT  ;IF SIMULTANEOUS LISTING WANTED
  566.         POP     H
  567.         POP     D
  568.         POP     B
  569.         POP     PSW
  570.         RET 
  571. ;
  572. ;SEND CHARACTER TO PRINTER
  573. ;       VALUE IN (C)
  574. ;
  575. ;
  576. PRTOUT: MOV     A,C     ;MOVE CHARACTER TO A
  577.         ANI     7FH     ;STRIP 8TH BIT FROM CHARACTER
  578.         MVI     C,LSTOUT;GET LIST OUTPUT FUNCTION
  579.         MOV     E,A     ;PUT CHARACTER IN E
  580.         CALL    BDOS    ;PRINT THE CHARACTER
  581.         RET
  582.  
  583. ;        WCCNP - WRITE CONSOLE CHARACTER WITHOUT PRINTER OUTPUT
  584. ; 
  585. ;        ENTRY CONDITIONS: 
  586. ;               A - CHARACTER TO WRITE 
  587. ;
  588. WCCNP:  PUSH    PSW
  589.         PUSH    B
  590.         PUSH    D
  591.         PUSH    H
  592.         MOV     C,A     ;GET CHARACTER FOR CBIOS
  593. WCCAL1: CALL    $-$     ;MODIFIED BY INIT.
  594.         POP     H
  595.         POP     D
  596.         POP     B
  597.         POP     PSW
  598.         RET 
  599. ;
  600. ;        RCS - READ CONSOLE STRING (WITH ECHO) 
  601. ; 
  602. ;        EXIT CONDITIONS 
  603. ;               B - NUMBER OF CHARACTERS READ (<255) 
  604. ;               HL - POINTS TO LAST CHAR STORED (CR) 
  605. ;
  606. RCS:    LXI     H,IBUF 
  607.         MVI     B,0
  608. RCS1:   CALL    RCC     ;READ NEXT CHAR FROM CONSOLE
  609.         CPI     DEL     ;JUMP IF NOT DEL
  610.         JNZ     RCS2 
  611.         INR     B       ;IGNORE DEL IF IBUF ALREADY EMPTY 
  612.         DCR     B
  613.         JZ      RCS1 
  614.         DCX     H       ;ELSE DISCARD LAST CHAR 
  615.         MOV     A,M     ;ECHO DISCARDED CHAR TO CONSOLE 
  616.         CALL    WCC
  617.         DCR     B       ;DECREMENT COUNT
  618.         JMP     RCS1    ;       AND LOOP 
  619. ;
  620. RCS2:   CPI     'U'-40H ;JUMP IF NOT CONTROL U
  621.         JNZ     RCS3 
  622.         CALL    WCCR    ;ELSE ABORT CURRENT LINE
  623.         JMP     RCS     ;       AND START OVER 
  624. ;
  625. RCS3:   CALL    WCC     ;ECHO CHAR TO CONSOLE 
  626.         MOV     M,A     ;STORE CHAR IN IBUF 
  627.         INR     B       ;INCREMENT COUNT
  628.         CPI     CR      ;JUMP IF CARRIAGE RETURN
  629.         JZ      RCS4
  630.         INX     H       ;ELSE ADVANCE POINTER 
  631.         JMP     RCS1    ;       AND LOOP 
  632. ;
  633. RCS4:   MVI     A,LF    ;ISSUE LINE FEED AND RETURN 
  634.         CALL    WCC
  635.         RET 
  636. ;
  637. ;        RCC - READ CONSOLE CHARACTER
  638. ; 
  639. ;        EXIT CONDITIONS 
  640. ;               A - CHARACTER READ 
  641. ;
  642. RCC:    PUSH    B
  643.         PUSH    D
  644.         PUSH    H
  645. RCCAL:  CALL    $-$     ;MODIFIED BY INIT.
  646.         POP     H
  647.         POP     D
  648.         POP     B
  649.         RET 
  650. ;
  651. ;        WMC - WRITE MODEM CHARACTER 
  652. ; 
  653. ;        ENTRY CONDITIONS
  654. ;               A - CHARACTER TO WRITE 
  655. ;
  656. ;
  657. WMC:    PUSH    PSW
  658. WMCL:   IN      MODS 
  659.         XRI     MXOR
  660.         ANI     MTBE
  661.         JNZ     WMCL
  662.         POP     PSW
  663.         ANI     7FH     ;STRIP PARITY BIT
  664.         OUT     MODD 
  665.         RET 
  666. ;
  667. WMS:    MOV     A,M     ;WRITE STRING TO MODEM
  668.         INX     H
  669.         ORA     A
  670.         RZ
  671.         CALL    WMC
  672.         JMP     WMS
  673. ;
  674. ;        RMC - READ MODEM CHARACTER
  675. ; 
  676. ;        EXIT CONDITIONS:
  677. ;               A - CHARACTER READ 
  678. ;
  679. ;
  680. RMC:    IN      MODS 
  681.         XRI     MXOR
  682.         ANI     MRDA
  683.         JNZ     RMC
  684. RMC2:   IN      MODD 
  685.         ANI     7FH 
  686.         RET 
  687. ;
  688. ;
  689. ;        GFN - GET FILE NAME 
  690. ;
  691. GFN:    LXI     H,GFNSD ;PRINT 'WHICH DRIVE?'
  692.         CALL    WCS
  693.         CALL    RCC     ;GET ANSWER FROM CONSOLE
  694.         CALL    WCC     ;ECHO IT TO CONSOLE
  695.         ANI     5FH     ;MAKE UPPER CASE
  696.         SUI     'A'-1
  697.         JC      GFN     ;REQUIRE ALPHABETIC
  698.         JZ      GFN
  699.         CPI     NUMDRV+1
  700.         JNC     GFN
  701.         STA     FCB
  702. GFNB:   LXI     H,GFNS1 ;PRINT 'FILENAME? ' 
  703.         CALL    WCS
  704.         CALL    RCS     ;READ RESPONSE INTO IBUF
  705.         LXI     H,FCB+FN  ;BLANK FILL FN AND FT FIELDS
  706.         MVI     C,11 
  707. GFN1:   MVI     M,BL
  708.         INX     H
  709.         DCR     C
  710.         JNZ     GFN1 
  711.         LXI     H,IBUF  ;POINT TO INPUT BUFFER
  712.         LXI     D,FCB+FN  ;SCAN OFF FN FIELD
  713.         MVI     C,9
  714. GFN2:   MOV     A,M     ;FETCH NEXT CHAR FROM IBUF
  715.         INX     H
  716.         CPI     61H     ;IF LC, CONVERT TO UC 
  717.         JC      GFN2A
  718.         SUI     20H
  719. GFN2A:  CPI     CR      ;JUMP IF END OF LINE
  720.         JZ      GFN5 
  721.         CPI     '.'     ;JUMP IF END OF NAME
  722.         JZ      GFN3 
  723.         STAX    D       ;ELSE STORE CHAR IN FN FIELD
  724.         INX     D
  725.         DCR     C       ;LOOP IF 8 OR LESS CHARS SO FAR
  726.         JNZ     GFN2 
  727.         JMP     GFN6    ;ELSE TAKE ERROR EXIT 
  728. ;
  729. GFN3:   LXI     D,FCB+FT  ;SCAN OFF FT FIELD
  730.         MVI     C,4
  731. GFN4:   MOV     A,M     ;FETCH NEXT CHAR FROM IBUF
  732.         INX     H
  733.         CPI     61H     ;IF LC, CONVERT TO UC 
  734.         JC      GFN4A
  735.         SUI     20H
  736. GFN4A:  CPI     CR      ;JUMP IF END OF LINE
  737.         JZ      GFN5 
  738.         STAX    D       ;ELSE STORE CHAR IN FT FIELD
  739.         INX     D
  740.         DCR     C       ;LOOP IF 3 OR LESS CHARS SO FAR
  741.         JNZ     GFN4 
  742.         JMP     GFN6    ;ELSE TAKE ERROR EXIT 
  743. ;
  744. GFN5:   XRA     A
  745.         STA     FCB+EX  ;SET EXTENT NUMBER TO ZERO
  746.         STA     FCB+NR  ;SET RECORD NUMBER TO ZERO
  747.         STC             ;CLEAR ERROR FLAG AND RETURN
  748.         CMC 
  749.         RET 
  750. ;
  751. GFN6:   STC             ;SET ERROR FLAG AND RETURN
  752.         RET 
  753. ;
  754. GFNSD:  DB      CR,LF,'WHICH DRIVE? ',0
  755. GFNS1:  DB      CR,LF,'FILENAME? ',0 
  756. ;
  757. ;        OPEN - OPEN DISK FILE 
  758. ;
  759. OPEN:   PUSH    H
  760.         PUSH    D
  761.         PUSH    B
  762.         LXI     D,FCB
  763.         MVI     C,OFFC 
  764.         CALL    BDOS 
  765.         POP     B
  766.         POP     D
  767.         POP     H
  768.         RET 
  769. ;
  770. ;        READ - READ RECORD FROM DISK FILE 
  771. ;
  772. READ:   PUSH    H
  773.         PUSH    D
  774.         PUSH    B
  775.         LXI     D,FCB
  776.         MVI     C,RRFC 
  777.         CALL    BDOS 
  778.         POP     B
  779.         POP     D
  780.         POP     H
  781.         RET 
  782. ;
  783. ;        CLOSE - CLOSE DISK FILE 
  784. ;
  785. CLOSE:  PUSH    H
  786.         PUSH    D
  787.         PUSH    B
  788.         LXI     D,FCB
  789.         MVI     C,CFFC 
  790.         CALL    BDOS 
  791.         POP     B
  792.         POP     D
  793.         POP     H
  794.         RET 
  795. ;
  796. ;        DELT - DELETE DISK FILE 
  797. ;
  798. DELT:   PUSH    H
  799.         PUSH    D
  800.         PUSH    B
  801.         LXI     D,FCB
  802.         MVI     C,DFFC 
  803.         CALL    BDOS 
  804.         POP     B
  805.         POP     D
  806.         POP     H
  807.         RET 
  808. ;
  809. ;        WRITE - WRITE RECORD TO DISK
  810. ;
  811. WRITE:  PUSH    H
  812.         PUSH    D
  813.         PUSH    B
  814.         LXI     D,FCB
  815.         MVI     C,WRFC 
  816.         CALL    BDOS 
  817.         ANA     A       ;SET 'Z' FLAG FOR ERROR
  818.         POP     B
  819.         POP     D
  820.         POP     H
  821.         RET 
  822. ;
  823. ;        MAKE - MAKE NEW DISK FILE 
  824. ;
  825. MAKE:   PUSH    H
  826.         PUSH    D
  827.         PUSH    B
  828.         LXI     D,FCB
  829.         MVI     C,MFFC
  830.         CALL    BDOS 
  831.         POP     B
  832.         POP     D
  833.         POP     H
  834.         RET 
  835. ;
  836. ;       CITEST - CHECK CONSOLE INPUT STATUS
  837. ;
  838. CITEST: PUSH    B
  839.         PUSH    D
  840.         PUSH    H
  841. CITCAL: CALL    $-$     ;MODIFIED BY INIT.
  842.         ORA     A       ;SET ZERO FLAG
  843.         POP     H
  844.         POP     D
  845.         POP     B
  846.         RET             ;ZERO FLAG CARRIES ANSWER
  847. ;
  848. ;       MITEST - CHECK MODEM INPUT STATUS
  849. ;
  850. MITEST: IN      MODS    ;GET MODEM UART STATUS
  851.         XRI     MXOR    ;INVERT HIGH-TRUE BITS
  852.         ANI     MRDA    ;ANY DATA AVAILABLE?
  853.         MVI     A,0
  854.         JNZ     MITST1
  855.         CMA
  856. MITST1: ORA     A
  857.         RET             ;ZERO FLAG CARRIES ANSWER
  858. ;
  859. ;
  860. ;       MOTEST - CHECK MODEM OUTPUT STATUS
  861. ;
  862. ;
  863. MOTEST: IN      MODS    ;GET MODEM UART STATUS
  864.         XRI     MXOR    ;INVERT HIGH-TRUE BITS
  865.         ANI     MTBE    ;UART READY FOR CHARACTER?
  866.         MVI     A,0
  867.         JNZ     MOTST1  ;ZERO FLAG CARRIES ANSWER
  868.         CMA
  869. MOTST1: ORA     A       ;SET ZERO FLAG IF READY
  870.         RET
  871. ;
  872. ;DECIMAL PRINT SUBROUTINE
  873. ;PRINTS H,L AS A DECIMAL NO.
  874. ;
  875. DECOUT  LXI     D,-10000
  876.         CALL    PRTDGT          ;PRINT 10'S OF THOUSANDS
  877.         LXI     D,-1000
  878.         CALL    PRTDGT          ;PRINT THOUSANDS
  879.         LXI     D,-100
  880.         CALL    PRTDGT          ;PRINT HUNDREDS
  881.         LXI     D,-10
  882.         CALL    PRTDGT          ;PRINT TENS
  883.         LXI     D,-1
  884. PRTDGT  MVI     C,'0'-1         ;INITIALIZE COUNT
  885.         PUSH    H               ;SO INITIAL INX SP'S WON'T HURT
  886. PRT1    INR     C               ;BUMP COUNT OF SUCCESSFUL SUBTR.
  887.         INX     SP              ;"POP" STACK W/O ALTERING REGISTERS
  888.         INX     SP
  889.         PUSH    H               ;SAVE H,L
  890.         DAD     D               ;DO 1 SUBTRACTION
  891.         JC      PRT1            ;IF RESULT STILL POS., DO IT AGAIN
  892.         POP     H               ;RESTORE LAST GOOD VALUE TO H,L
  893.         MOV     A,C
  894.         JMP     WCCNP           ;PRINT CHAR & RET
  895. ;
  896. ;        DATA AREA 
  897. ;
  898. BLEN:   DS      2       ;BUFFER LENGTH
  899. BREM:   DS      2       ;BYTES TBUF REMAINING
  900. PRTFLG: DB      0       ;PRINTER OFF IF ZERO
  901. INCH:   DS      1       ;INPUT CHAR BUFFER (TO CYBER) 
  902. OUTCH:  DS      1       ;OUTPUT CHAR BUFFER (FROM CIBER)
  903. STACK:  DS      80      ;LOCAL STACK
  904. IBUF:   DS      256     ;INPUT BUFFER 
  905. ;
  906. ;        TEXT BUFFER 
  907. ;
  908. FLAG:   DS      1       ;TEXT SAVE FLAG 
  909. PTR:    DS      2       ;TEXT BUFFER POINTER
  910. SIZE:   DS      2       ;TEXT BUFFER SIZE 
  911. TBUF:   EQU     $       ;START OF TEXT BUFFER 
  912. ;
  913. ;INITIAL CODE IS PLACED HERE TO SAVE SPACE (BUFFER OVERWRITES IT)
  914. ;
  915. INIT:   POP     H       ;SAVE RETURN ADDRESS
  916.         LXI     SP,STACK+64     ;CREATE LOCAL STACK 
  917.         PUSH    H       ;RESTORE RETURN ADDRES TO STACK
  918.         LHLD    BASE+1  ;POINT TO CP/M JMP TABLE
  919.         LXI     D,3     ;GET READY TO ADD 3
  920.         DAD     D       ;POINT TO CON STATUS JMP
  921.         SHLD    CITCAL+1 ;MODIFY CALL ADRS
  922.         DAD     D       ;POINT TO CON IN JMP
  923.         SHLD    RCCAL+1 ;MODIFY CALL ADRS
  924.         DAD     D       ;POINT TO CON OUT JMP
  925.         SHLD    WCCAL+1 ;MODIFY CALL ADRS
  926.         SHLD    WCCAL1+1
  927.         LDA     FCB+1   ;SEE IF OPTIONAL TRIGER CHAR
  928.         CPI     20H     ;BLANK.. ?
  929.         JZ      SKP     ;..BLANK SO USE DEFAULT "LF"
  930.         CPI     'B'     ;BELL WANTED
  931.         JZ      TRGBEL
  932.         CPI     'X'     ;XON WANTED
  933.         JZ      TRGXON
  934.         CPI     'U'     ;UPLOADING NO CHECKING FOR TRIGER
  935.         JZ      TRGUPL
  936. ;
  937. SETTRG  STA     OVERLY+1 ;STORE THE CHARACTER AS IS THEN
  938.         JMP     SKP
  939. ;
  940. TRGBEL  MVI     A,BELL
  941.         JMP     SETTRG
  942. ;
  943. TRGXON  MVI     A,XON
  944.         JMP     SETTRG
  945. ;
  946. TRGUPL  XRA     A               ;ZERO OUT JUMP
  947.         STA     OVERL1+1        ;CHANGE CHECK FOR C/R TO NULL
  948.         STA     OVERL2+1        ;AND SEND LINEFEEDS AS WELL
  949. ;
  950. SKP     EQU     $
  951. ;
  952. ;
  953.         XRA     A       ;CLEAR CHAR BUFFERS 
  954.         STA     INCH 
  955.         STA     OUTCH
  956.         STA     FLAG    ;CLEAR TEXT SAVE FLAG 
  957.         LXI     H,TBUF  ;SET PTR TO TBUF
  958.         SHLD    PTR
  959.         LXI     H,0     ;SIZE = 0 
  960.         SHLD    SIZE 
  961.         LHLD    BASE+6
  962.         MVI     L,0
  963.         DCR     H       ;HL = MAX TBUF TOP
  964.         LXI     D,-TBUF
  965.         DAD     D       ;HL = MAX TBUF LEN
  966.         SHLD    BLEN
  967.         SHLD    BREM    ;BUFFER BYTES REMAINING
  968.         LXI     H,LINKMS  ;PRINT SIGN-ON MESSAGE
  969.         CALL    WCSNP
  970.         LHLD    BLEN    ;PRINT BUFFER ON 25TH LINE
  971.         CALL    DECOUT
  972.         LXI     H,RESCP
  973.         CALL    WCSNP
  974.         RET             ;RETURN TO MAIN LOOP
  975. ;
  976. LINKMS: DB      ESC,'E',ESC,'Y',BL+5,BL+22
  977.         DB      'H/Z-89 TNC CONTROLLER - RSI - DEC 89'
  978.         DB      CR,LF,LF,LF
  979.         DB      ESC,'x1',ESC,'j',ESC,'Y',BL+24,BL+5
  980.         DB      ESC,'pSave',ESC,'q   '
  981.         DB      ESC,'pFile',ESC,'q   '
  982.         DB      ESC,'pSend',ESC,'q   '
  983.         DB      ESC,'pN/A',ESC,'q   '
  984.         DB      ESC,'pPrint off',ESC,'q'
  985.         DB      ESC,'Y',BL+24,BL+53,ESC,'pExit',ESC,'q         '
  986.         DB      ESC,'pBuffer = ',0
  987. ;
  988.         END     LINK0
  989. W
  990.         PUSH    B
  991.         PUSH    D
  992.         PUSH    H
  993.         MOV     C,A     ;GET CHARACTER FOR CBIOS