home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / NSTAR / NEWFRM14.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  10KB  |  344 lines
  1. ;**********************************************************
  2. ; WILL work with North Star Hard Disk
  3. ;                              *
  4. ;            NEWFORM  VERSION 1.4          *
  5. ;             12/02/82              *
  6. ;               R. L. Plouffe               *
  7. ;                              *
  8. ;    A patch overlay file for adding alternate      *
  9. ;    disk formats to North Star CP/M vers 1.1.0      *
  10. ;                              *
  11. MSIZE    EQU    32        ;MEMORY SIZE THIS VERS      *
  12.                 ;CHANGE TO YOUR SIZE HERE *
  13. OVERLAY    EQU    OVERLAY        ;COMPUTED SYSGEN OVERLAY  *
  14. ;                              *
  15. ;**********************************************************
  16. ;
  17. ; Vers 1.4 Changed location of F35 and F40 labels so that
  18. ; North Star Hard Disk will work properly. Must now use
  19. ; NEWCPY and NEWFMT versions (copier and formatter) that
  20. ; sign on and say 'as of Dec 2, 1982' or later.
  21. ;
  22. ; Vers 1.3 Fixed address in image of call argument to INIT
  23. ; routine. Marked @1.3
  24. ;
  25. ; Vers 1.2 Added conditional assembly for selection of one
  26. ; or both of the alternate formats.  Stuffed code so that
  27. ; the support code for hard disk users is left intact ex-
  28. ; cept for the last 80H of USER area which is overwritten
  29. ; by the directory buffer if the OCTAL equ is set true.
  30. ; That code is not used after boot anyhow and the dirbuf is
  31. ; not written until after boot. So, it doesn't hurt anything.
  32. ; If the alternate OCTAL format is selected, the 'ILLEGAL
  33. ; ACCESS' message in the bios is changed to 'NO'. (Done to 
  34. ; make some code space available for ALTOCTL rtne.)   rlp
  35. ; 
  36. ; Vers 1.1  Fixed bug that prevented proper reading of a 
  37. ; Quad disk formatted for 80 tracks when mounted in an
  38. ; Octal drive and accessing files above 70 tracks.  Changes
  39. ; are marked by ;@1.1            rlp
  40. ;
  41. ;    *****This patch file was previously called
  42. ;    ALTFORM, ALTFRM, or ALTFOR with various version
  43. ;    numbers.  Those versions did not achieve the
  44. ;    complete degree of compatibility between all
  45. ;    of the disk formats supported by N* and this
  46. ;    patch.  This version DOES, so it is renamed
  47. ;    to NEWFORM and version number reset to 1.0.
  48. ;    PLEASE throw away previously named versions
  49. ;    and start over again with this one.
  50. ;
  51. ;    THIS VERSION ALSO NOW SUPPORTS AN ADDITIONAL
  52. ;    FORMAT FOR QUAD DRIVES THAT GIVES 40 TRACKS
  53. ;    PER SIDE AND IS COMPATIBLE WITH NORTH STAR
  54. ;    FORMAT FOR 35 TRACKS/SIDE. FORMAT BYTE IS D0H.
  55. ;
  56. ;    PATCH THIS INTO THE DISTRIBUTION VERSION
  57. ;    OF NORTH STAR CP/M VERSION 1.1.0 TO PROVIDE
  58. ;    AN ALTERNATE FORMAT WITH 2KB BLOCKS VS 4KB
  59. ;    FOR 96 TPI DRIVES.  YOUR FORMATTER MUST BE
  60. ;    MODIFIED TO PROVIDE A FORMAT BYTE = 0D2H.
  61. ;    SEE NEWFRMAT.COM FOR A FORMATTER THAT WILL
  62. ;    DO THIS. ALSO SEE NEWCOPY.COM FOR A COPY
  63. ;    PROGRAM THAT TOLERATES THE D0/D2H FORMAT BYTES.
  64. ;    MUST USE GENSYS41 TO WRITE TO YOUR SYSTEM TRACKS.
  65. ;
  66. ;    BY DISTRIBUTION VERSION, I MEAN WITH A USER
  67. ;    AREA **EXACTLY** AS GENERATED BY CPMGEN. OTHERWISE
  68. ;    YOU ARE ON YOUR OWN FOR FINDING A PLACE IN YOUR
  69. ;    CBIOS FOR THE 'NEWFORM' ROUTINES AND A SPACE OF
  70. ;    80H BYTES (CAN BE UNITIALIZED RAM) FOR REDIRECTING
  71. ;    THE DIRECTORY BUFFER IF 'OCTAL' IS SET TRUE.
  72. ;
  73. ;    CALL ME FOR A SOURCE OF NEWFRMT.COM, NEWCOPY.COM
  74. ;    AND GENSYS41.COM     703-524-2549 (it's a computer)
  75. ;
  76. ;    Thanks to Sigi Kluger and Frank Wancho for their help
  77. ;    in debugging this code.            RLP
  78. ;
  79. ;**********************************************************
  80. ;
  81. ;        EQUATES
  82. ;
  83. FALSE    EQU    0
  84. TRUE    EQU    NOT FALSE
  85. ;
  86. OCTAL    EQU    TRUE        ;Want alternate octal format
  87.                 ;for 2kb directory blocks?
  88. QUAD    EQU    TRUE        ;Want alternate quad format
  89.                 ;for 80 tracks?
  90. ;
  91. ;***********************************************************
  92. ;If you have a Hard Disk system, you will have to adjust the
  93. ;addresses of the CCP, BIOS and BDOS for a given MSIZE, and
  94. ;in any case you will have to adjust these components if
  95. ;you split the system around the disk controller PROM.
  96. ;
  97. BIOS    EQU    (MSIZE*1024)-0D00H    ;BASE OF BIOS
  98. CCP    EQU    BIOS-1600H
  99. BDOS    EQU    CCP+800H
  100. OVERLAY    EQU    2B00H-BIOS    ;COMPUTED OVERLAY
  101. USER    EQU    BIOS+700H    ;USER PATCH AREA
  102.     ;
  103. BUF    EQU    USER+200H
  104. JRZ    EQU    28H
  105. JRNZ    EQU    20H        ;z80 relative jumps
  106. JR    EQU    18H
  107. DPB3    EQU    BIOS+50EH    ;Quad
  108. DPB4    EQU    BIOS+51EH    ;N-drive (Octal)
  109. SEKTRK    EQU    BIOS+0CAEH
  110. TINUIT    EQU    BIOS+5ACH
  111. WRTDPH    EQU    BIOS+444H    ;routine in bios to
  112.                 ;write the Disk Parm Header
  113. ;
  114. ;**********************************************************
  115. ;This overlays the jump table at the base of the BIOS so
  116. ;that the code space used for jumps at the base of the
  117. ;USER area is free (24 bytes) for our use. Addresses must
  118. ;point to your routines if different from distribution
  119. ;version.
  120. ;
  121.     IF    QUAD
  122.     ORG    BIOS    
  123.     DS    3        ;boot
  124.     DS    3        ;wboot
  125.     JMP    BIOS+74DH    ;const
  126.     JMP    BIOS+71EH    ;conin
  127.     DS    3        ;consout
  128.     JMP    BIOS+763H    ;prtser
  129.     JMP    BIOS+756H    ;punch
  130.     JMP    BIOS+71EH    ;reader
  131.     DS    3        ;home
  132.     DS    3        ;seldsk
  133.     DS    3        ;settrk
  134.     DS    3        ;setsec
  135.     DS    3        ;setdma
  136.     DS    3        ;read
  137.     DS    3        ;write
  138.     JMP    BIOS+78AH    ;listst
  139. ;
  140.     ORG    BIOS+54BH
  141.     DW    BIOS+756H    ;address of CONOUT
  142.     ORG    CCP-100H+56H    ;arg of call to INIT @1.3
  143.     DW    BIOS+78CH    ;address of INIT routine
  144. ;
  145. ;**********************************************************
  146. ;Routine to patch and unpatch the Bios
  147. ;
  148.     ORG    USER
  149. STOREM:
  150.     STA    BIOS+105H
  151.     INR    A
  152.     STA    BIOS+10BH
  153.     STA    BIOS+668H
  154.     STA    BIOS+68EH
  155.     RAL            ;@1.1
  156.     ADI    3FH        ;@1.1
  157.     STA    BIOS+66DH    ;@1.1
  158.     RET
  159.     DB    0,0,0,0        ;do not expand - 24 bytes here
  160.     ENDIF    ;QUAD
  161. ;
  162. ;**********************************************************
  163. ;Alternate Disk Parameter Block for 96 tpi drives.  This
  164. ;version of NEWFORM now permits support of the original
  165. ;North Star format for N-drives as well as this one.
  166. ;
  167.     ORG    BIOS+32AH
  168.     IF    OCTAL
  169.     ;Double    density, double sided (2.x)
  170.     ;Format byte = D2H
  171.     ;Double track (96/in.)
  172.     ;
  173. N5    EQU    160    ;number of tracks
  174. SPT5    EQU    40    ;CPM sectors per track
  175. DRM5    EQU    127    ;directory size-1
  176. BLS5    EQU    2    ;block size (kbytes)
  177. SYSTRK5    EQU    2    ;reserved tracks
  178.     ;
  179. DSM5    EQU    -1+(((N5-SYSTRK5)*SPT5)/(8*BLS5))
  180. ;
  181.     DB    8*BLS5
  182.     ;
  183. DPB5:
  184.     DW    SPT5    ;SPT-sectors/track
  185.     DB    04    ;BSH-block shift factor
  186.     DB    8*BLS5-1;BLM-block mask
  187.     DB    BLS5-1-BLS5/2
  188.             ;EXM-null mask
  189.     DW    DSM5    ;DSM-disk size-1
  190.     DW    DRM5    ;DRM-directory max
  191.     DB    192    ;AL0-allocation 0
  192.     DB    0    ;AL1-allocation 1
  193.     DW    (DRM5+1)/4
  194.             ;CKS-check size
  195.     DW    SYSTRK5    ;OFF-track offset
  196.     ENDIF    ;OCTAL
  197. ;
  198. ;**********************************************************
  199. ;Alternate Disk Parameter Block for QUAD (48tpi) drives. This
  200. ;version of NEWFORM now permits support of the original
  201. ;North Star format for Quad drives as well as this one.
  202. ;
  203.     IF    QUAD
  204.     ;Double    density, double sided (2.x)
  205.     ;Format byte = D0H
  206.     ;
  207. N6    EQU    80    ;number of tracks
  208. SPT6    EQU    40    ;CPM sectors per track
  209. DRM6    EQU    63    ;directory size-1
  210. BLS6    EQU    2    ;block size (kbytes)
  211. SYSTRK6    EQU    2    ;reserved tracks
  212.     ;
  213. DSM6    EQU    -1+(((N6-SYSTRK6)*SPT6)/(8*BLS6))
  214. ;
  215.     DB    8*BLS6
  216.     ;
  217. DPB6:
  218.     DW    SPT6    ;SPT-sectors/track
  219.     DB    04    ;BSH-block shift factor
  220.     DB    8*BLS6-1;BLM-block mask
  221.     DB    BLS6-1    ;EXM-null mask
  222.     DW    DSM6    ;DSM-disk size-1
  223.     DW    DRM6    ;DRM-directory max
  224.     DB    128    ;AL0-allocation 0
  225.     DB    0    ;AL1-allocation 1
  226.     DW    (DRM6+1)/4
  227.             ;CKS-check size
  228.     DW    SYSTRK6    ;OFF-track offset
  229.     ENDIF    ;QUAD
  230. ;
  231.     IF    OCTAL
  232. ILLEGAL:
  233.     DB    'NO',80H
  234.             ;do not expand - 35 bytes here
  235. ;
  236. ;**********************************************************
  237. ;These routines are in-line with the bios SELDSK routine
  238. ;and permit the alternate formats above if your formatter
  239. ;is modified to place a 0D2H at the format byte location
  240. ;and formats 160 tracks for 96 tpi drives; and, a 0D0H
  241. ;format byte with formatting of 80 tracks for Quad drives.
  242. ;
  243.     ORG    BIOS+6A9H
  244. ALTOCTL:
  245.     MOV    A,B    ;get the format byte
  246.     LXI    D,DPB4-1
  247.     ANI    20H    ;see which format
  248. DB    JRNZ,    GODPH1-$-1
  249.     LXI    D,DPB5-1
  250. GODPH1:    JMP    WRTDPH    ;go write the Disk Parm Header
  251.     DB    0    ;do not expand - 15 bytes here
  252.     ENDIF    ;OCTAL
  253. ;
  254.     IF    QUAD
  255.     ORG    USER+115H
  256. ALTQUAD:
  257.     MOV    A,B    ;get the format byte
  258.     ANI    40H    ;see if double sided
  259. DB    JRZ,    GODPH2-$-1
  260.     MOV    A,B    ;get the format byte again
  261.     ANI    20H    ;see which format
  262. DB    JRNZ,    GODPH2-$-1
  263.     LXI    D,DPB6-1;point to Disk Parm Block for this
  264.             ;format.
  265. GODPH2:    JMP    WRTDPH    ;go write the Disk Parameter Header
  266. ;
  267. ;**********************************************************
  268. ;Routine to test for 80 track format and to patch or unpatch
  269. ;depending on 80/70 tracks.
  270. ;
  271. CKQUAD80:
  272.     LDA    F35
  273.     CALL    STOREM
  274.     LDA    BDOS+0DC6H ;get the disk size byte for
  275.                ;current disk access
  276.     CPI    DSM6
  277. DB    JRNZ,    COMRDWR-$-1
  278.     LDA    F40
  279.     CALL    STOREM
  280. COMRDWR
  281.     LHLD    SEKTRK
  282.     JMP    TINUIT
  283.     DB    0,0       ;do not expand - 43 bytes here
  284.     ENDIF    ;QUAD
  285. ;
  286. ;**********************************************************    
  287. ;These patches provide for moving the directory buffer so
  288. ;that the necessary scratch space for the disk allocation
  289. ;vectors (ALV's) is there. The ALV space is now 39H for
  290. ;each drive instead of 19H as in original N* release.  The
  291. ;Directory buffer has been moved to the last 80H of the 
  292. ;USER patch area since the support code contained therein
  293. ;is expendable after you have booted your system.
  294. ;The Disk Parameter Headers which get written by the BIOS 
  295. ;are moved down by 80H to provide for the expanded ALV space.
  296. ;ALV SPACE IS THUSLY EXPANDED **ONLY** IF YOU SELECT THE
  297. ;ALTERNATE OCTAL FORMAT TO BE TRUE.
  298. ;
  299.     IF    OCTAL
  300.     ORG    BIOS+460H
  301.     DW    DIRBUF
  302.     ORG    BIOS+46CH
  303.     DW    003DH
  304.     ORG    BIOS+481H
  305.     DW    DPBASE0-6AH
  306.     ORG    BIOS+484H
  307.     DW    006AH
  308.  
  309. DPBASE0    EQU    BUF+200H
  310. DIRBUF    EQU    USER+180H
  311. ;
  312.     ORG    BIOS+441H
  313.     JMP    ALTOCTL    ;puts the ALTOCTL routine in-line
  314.             ;with the SELDSK routine in bios.
  315.     ENDIF    ;OCTAL
  316. ;
  317.     IF    QUAD
  318. ;patches for quad drives to give 40 tracks per side
  319.     ORG    BIOS+437H
  320.     DW    ALTQUAD    ;to check for alt Quad format
  321. ;
  322.     ORG    BIOS+43EH
  323.     DW    ALTQUAD
  324. ;
  325.     ORG    BIOS+5A9H
  326.     JMP    CKQUAD80
  327.     ENDIF    ;QUAD
  328. ;
  329.     ORG    BIOS+6E5H
  330. ;These 2 bytes are used in the alternate Quad formatting scheme
  331. ;and are manipulated by the formatter, NEWFRMAT.COM.  So don't
  332. ;change or delete these bytes or their location.
  333. F35:    DB    22H
  334. F40:    DB    27H
  335. ;
  336.     IF    OCTAL
  337.     ORG    BIOS+693H
  338.     DW    ILLEGAL
  339.     ENDIF    ;OCTAL
  340. ;
  341. ;**********************************************************
  342. ;
  343.     END
  344.