home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / MODEMS / XMODEM / XMOX-2.AQM / XMOX-2.ASM
Assembly Source File  |  2000-06-30  |  8KB  |  233 lines
  1.  
  2. ; XMOX-2.ASM - XMODEMxx overlay file for the Osborne Executive    05/31/84
  3. ;
  4. ; This file adapts XMODEMxx to the Executive computer.  To use, first edit
  5. ; any options desired into XMODEMxx.ASM, then assemble (can use MAC.COM)
  6. ; and load to get XMODEMxx.COM.  Then edit this file as needed (check
  7. ; the CONOUT routine if you want to locally see file transfer time and
  8. ; the record count while programs are being sent or insure that USECON
  9. ; on ByeII or BYE3 is set YES.)  Then assemble (can use MAC.COM) and
  10. ; merge via SID:
  11. ;
  12. ;    B>SID XMODEMxx.COM
  13. ;    CP/M 3 SID - VERSION 3.0
  14. ;    NEXT MSZE  PC  END
  15. ;    1600 1600 0100 ????
  16. ;    -RXMOX-1.HEX        (loads the .HEX file)
  17. ;    NEXT MSZE  PC  END
  18. ;    ???? 1600 0100 ????
  19. ;   *    -WXMODEMxx.COM,100,15FF    (save the updated .COM file)
  20. ;    -G0            (return to CP/M)
  21. ;
  22. ; * If the MSZE value is not 1600, adjust the WXMODEMxx .... command as
  23. ;   necessary.
  24. ;
  25. ;=======================================================================
  26. ;
  27. ; -2 05/31/84    Updated to remove the USECON restriction    GFP
  28. ; -1 05/11/84    Initial installation                 George F Peace
  29. ;
  30. ;=======================================================================
  31. ; 
  32. ; Define True and False
  33. ;
  34. YES:      EQU    0FFH
  35. NO:      EQU    0
  36. ;
  37. ;=======================================================================
  38. ;
  39. ; Modem & Data Equates
  40. ;
  41. MODDATP:  EQU    0CH        ;data in port for the Osborne Executive
  42. MODCTLP:  EQU    MODDATP+1    ;control/status port
  43. MODSNDB:  EQU    04H        ;bit to test for send
  44. MODSNDR:  EQU    04H        ;value when ready
  45. MODRCVB:  EQU    01H        ;bit to test for receive
  46. MODRCVR:  EQU    01H        ;value when ready
  47. MODDCDB:  EQU    08H        ;carrier detect bit
  48. MODDCDA:  EQU    08H        ;value when active
  49. MODPARE:  EQU    10H        ;value for parity error
  50. MODOVRE:  EQU    20H        ;value for overrun error
  51. MODFRME:  EQU    40H        ;value for framing error
  52. MODRESI:  EQU   10H        ;reset external status/interrupts
  53. MODERES:  EQU   30H        ;error reset
  54. ;
  55. ;
  56. LSPEED:      EQU    YES        ;true if using by2-17ks or any bye2-xx
  57.                 ;false if using 'SPEED' manual selection
  58. MSPEED:      EQU    3CH        ;location of baud rate factor (set by
  59. ;                ;'BYE')  SET LOCATION IN 'BYE' TO AGREE.
  60. ;                ;3DH AND 3EH OFTEN USED BY NEWER VER-
  61. ;                ;SIONS OF 'ZCPR'.
  62. XSPEED:      EQU    1        ;speed for file time transfer without
  63. ;                ;AUTO-SET.  USE ONE OF THE FOLLOWING:
  64. ;                ;0=110 1=300 2=450 3=600 4=710 5=1200
  65. BASE:      EQU    100H        ;start of cp/m normal program area
  66. ;
  67. ;=======================================================================
  68. ;
  69. ; Jump table: The jump table must be in exactly the same sequence as the
  70. ; one in XMODEM.
  71. ;
  72.       ORG    BASE+3        ;start after 'JMP BEGIN'
  73. ;
  74. CONOUT:   JMP    0000H        ;must be 00000h if not used, see below
  75. PMINIT:      JMP    MINIT        ;initialization routine (if needed)
  76. PUNINIT:  JMP    UNINIT        ;undo whatever 'MINIT' did (or return)
  77. PSENDR:      JMP    SENDR        ;send character (via pop psw)
  78. PCAROK:      JMP    CAROK        ;test for carrier
  79. PMDIN:      JMP    MDIN        ;receive data byte
  80. PGETCHR:  JMP    GETCHR        ;get character from modem
  81. PRCVRDY:  JMP    RCVRDY        ;check receive ready
  82. PSNDRDY:  JMP    SNDRDY        ;check send ready
  83. PSPEED:      JMP    SPEED        ;get speed value for file transfer time
  84. PEXTRA1:  JMP    EXTRA1        ;extra for custom routine
  85. PEXTRA2:  JMP    EXTRA2        ;extra for custom routine
  86. PEXTRA3:  JMP    EXTRA3        ;extra for custom routine
  87. ;
  88. ;=======================================================================
  89. ;
  90. ; -- To Display the Record Count on the CRT During Program Transfers --
  91. ;
  92. ;    The CRTOUT routine below may be used if you know the ports used
  93. ; by your CRT for status and data.  (Cannot be used with memory mapped
  94. ; displays.)  If using the CRTOUT routine, skip rest of this discussion.
  95. ;
  96. ;    This one addition requires some work on the part of the user.
  97. ; When "BYE" is added, CP/M is normally moved lower to accomodate the
  98. ; new program above CP/M.  Whenever BYE is called to enable the RCPM
  99. ; capability, it steals some of the addresses contained in the BIOS jump
  100. ; vector table.  In order to display on the CRT during program transfers
  101. ; you need to get into the BIOS console output routine directly, else
  102. ; what is being displayed also tries to go out the modem.  This is a big
  103. ; NO-NO at that time.  (This cannot be done automatically by XMODEM,
  104. ; since BYE has already taken the address we need to find, by the time
  105. ; XMODEM is automatically activated by the remote station.)
  106. ;
  107. ;    So with the disk containing BYE, but prior to activating BYE, do
  108. ; this:
  109. ;        1) Cold reboot to move CP/M (and BIOS) to the new area
  110. ;            needed when BYE is activated on the same disk.
  111. ;        2) Use DDT and dump the area from 0000H to 0002H.  This
  112. ;                   gives the warm reboot address in BIOS.
  113. ;        3) Add 9 Bytes to that address to get your console out-
  114. ;             put jump vector.
  115. ;        4) Pick off the address contained in the jump vector and
  116. ;             install that in "CONOUT", below.  Example of one
  117. ;             system in use:
  118. ;
  119. ;            FIRST, COLD REBOOT WITH DISK CONTAINING "BYE"
  120. ;
  121. ;      0000  C3 03 E0    (location of warm reboot on disk with BYE
  122. ;
  123. ;            PRIOR TO ACTIVATING BYE BUT ON SAME DISK
  124. ;
  125. ;      E003  C3 E9 E0    (BIOS warm reboot jump vector on this disk)
  126. ;      E006  C3 00 E9    (BIOS get console status routine)
  127. ;      E009  C3 B7 E1    (BIOS console input routine)
  128. ;      E00C  C3 D4 E1    (BIOS console output routine)
  129. ;
  130. ;        The address we need is thus E1D4.  Put that below, in
  131. ;        our example it would be:    CONOUT   JMP   0E1D4H
  132. ;
  133. ;
  134. ;    CONOUT:      JMP    00000H    ;If you wish to show the record count
  135. ;                ;during program transfer, fill in this
  136. ;                ;address at 'CONOUT' above.
  137. ;
  138. ;                    - Irv Hoff
  139. ;
  140. ;=======================================================================
  141. ;
  142. ; ---> CAROK - check for presence of carrier.  RET with Z = carrier on
  143. ;
  144. CAROK:
  145.     MVI    A,MODRESI    ;reset external status/interrupts
  146.     OUT    MODCTLP
  147.     IN    MODCTLP        ;get status
  148.     ANI    MODDCDB        ;get carrier detect bit
  149.     CPI    MODDCDA        ;test bit
  150.     RET
  151. ;
  152. ;=======================================================================
  153. ;
  154. EXTRA1:    RET            ;for later use
  155. EXTRA2:    RET            ;for later use
  156. EXTRA3:    RET            ;for later use
  157. ;
  158. ;=======================================================================
  159. ;
  160. ; ---> GETCHR - get a character, same as MDIN
  161. ; ---> MDIN - - get a character, same as GETCHR
  162. ;
  163. GETCHR:
  164. MDIN:    IN    MODDATP        ;get character from data in port
  165.     RET
  166. ;
  167. ;=======================================================================
  168. ;
  169. MINIT:    RET            ;no initialization required
  170. ;
  171. ;=======================================================================
  172. ;
  173. ; ---> RCVRDY - check receive ready.  RET with Z = character available.
  174. ;            Return with error code in A-reg.
  175. ;
  176. RCVRDY:    IN    MODCTLP        ;get modem status
  177.     PUSH    B        ;save scratch register
  178.     PUSH    PSW
  179.     MVI    A,1+MODRESI    ;select read register 1
  180.     OUT    MODCTLP
  181.     IN    MODCTLP        ;read the error status
  182.     ANI    MODFRME+MODOVRE+MODPARE
  183.     MOV    B,A        ;save it for a moment
  184.     MVI    A,MODERES
  185.     OUT    MODCTLP        ;do an error reset command
  186.     POP    PSW        ;now get modem status back
  187.     ANI    MODRCVB        ;isolate ready bit
  188.     CPI    MODRCVR        ;test it
  189.     MOV    A,B        ;get the error code char. back
  190.     POP    B
  191.     RET
  192. ;
  193. ;=======================================================================
  194. ;
  195. ; ---> SENDR - send character
  196. ;
  197. SENDR:    POP    PSW        ;get the character back
  198.     OUT    MODDATP        ;send it to the modem output
  199.     RET
  200. ;
  201. ;=======================================================================
  202. ;
  203. ; ---> SNDRDY - check if ready to send.
  204. ;
  205. SNDRDY:    IN    MODCTLP        ;get status byte
  206.     ANI    MODSNDB        ;isolate ready bit
  207.     CPI    MODSNDR        ;ready to send?
  208.     RET
  209. ;
  210. ;=======================================================================
  211. ;
  212. ; ---> SPEED - sets the time shown for program transfer.
  213. ;
  214. SPEED:    EQU    $
  215. ;
  216.      IF    LSPEED
  217.     LDA    MSPEED        ;get index for baud rate from 'BYE'
  218.      ENDIF
  219. ;
  220.      IF     NOT LSPEED
  221.     MVI    A,XSPEED    ;get index for baud rate from 'XSPEED'
  222.      ENDIF
  223. ;
  224.     RET
  225. ;
  226. ;=======================================================================
  227. ;
  228. UNINIT:    RET            ;not initialized, so no 'UN-INITIALIZE'
  229. ;
  230. ;=======================================================================
  231. ;
  232.     END
  233.